qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "defs.qh"
   6 #include "hud/_mod.qh"
   7 #include "hud/panel/scoreboard.qh"
   8
   9 #include <common/mapinfo.qh>
  10
  11
  12 int mv_num_maps;
  13
  14 string mv_maps[MAPVOTE_COUNT];
  15 string mv_pics[MAPVOTE_COUNT];
  16 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  17 string mv_desc[MAPVOTE_COUNT];
  18 float mv_preview[MAPVOTE_COUNT];
  19 float mv_votes[MAPVOTE_COUNT];
  20 float mv_flags[MAPVOTE_COUNT];
  21 float mv_flags_start[MAPVOTE_COUNT];
  22 entity mv_pk3list;
  23 float mv_abstain;
  24 float mv_ownvote;
  25 float mv_detail;
  26 float mv_timeout;
  27 float mv_top2_time;
  28 float mv_top2_alpha;
  29
  30 int mv_selection;
  31 int mv_columns;
  32 int mv_mouse_selection;
  33 int mv_selection_keyboard;
  34
  35 float gametypevote;
  36 string mapvote_chosenmap;
  37 vector gtv_text_size;
  38 vector gtv_text_size_small;
  39
  40 const int NUM_SSDIRS = 4;
  41 string ssdirs[NUM_SSDIRS];
  42 int n_ssdirs;
  43
  44 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  45 {
  46         TC(int, id);
  47         string pre, post;
  48         pre = sprintf("%d. ", id+1);
  49         if(mv_detail)
  50         {
  51                 if(_count == 1)
  52                         post = _(" (1 vote)");
  53                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  54                         post = sprintf(_(" (%d votes)"), _count);
  55                 else
  56                         post = "";
  57         }
  58         else
  59                 post = "";
  60         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  61         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  62         return strcat(pre, map, post);
  63 }
  64
  65 vector MapVote_RGB(int id)
  66 {
  67         TC(int, id);
  68         if(!(mv_flags[id] & GTV_AVAILABLE))
  69                 return '1 1 1';
  70         if(id == mv_ownvote)
  71                 return '0 1 0';
  72         else if (id == mv_selection)
  73                 return '1 1 0';
  74         else
  75                 return '1 1 1';
  76 }
  77
  78 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  79 {
  80         TC(int, id);
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89         alpha *= panel_fg_alpha;
  90
  91         // Bounding box details
  92         float rect_margin = hud_fontsize.y / 2;
  93
  94         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  95         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  96         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  97         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  98
  99         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 100         vector rect_size = '1 1 0';
 101         rect_size.x = tsize + rect_margin;
 102         rect_size.y = maxh + rect_margin;
 103
 104         // Highlight selected item
 105         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 106         {
 107                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 108         }
 109
 110         // Highlight current vote
 111         vector rgb = MapVote_RGB(id);
 112         if(id == mv_ownvote)
 113         {
 114                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 115                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 116         }
 117
 118         vector offset = pos;
 119
 120         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 121         pos.y += title_gap;
 122         maxh -= title_gap;
 123
 124         // Evaluate the image size
 125         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 126         if ( maxh < image_size.y )
 127                 image_size = '1 1 0' * maxh;
 128         image_size *= 0.8;
 129         float desc_padding = gtv_text_size.x * 0.6;
 130         pos.x += image_size.x + desc_padding;
 131         tsize -= image_size.x + desc_padding;
 132
 133         // Split the description into lines
 134         entity title;
 135         title = spawn();
 136         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 137
 138         string thelabel = mv_desc[id], ts;
 139         entity last = title;
 140         entity next = NULL;
 141         float nlines = 0;
 142         if( thelabel != "")
 143         {
 144                 float i,n = tokenizebyseparator(thelabel, "\n");
 145                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 146                 {
 147                         getWrappedLine_remaining = argv(i);
 148                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 149                         {
 150                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 151                                 if (ts != "")
 152                                 {
 153                                         next = spawn();
 154                                         next.message = ts;
 155                                         next.origin = pos-offset;
 156                                         last.chain = next;
 157                                         last = next;
 158                                         pos.y += gtv_text_size_small.y;
 159                                         nlines++;
 160                                 }
 161                         }
 162                 }
 163         }
 164
 165         // Center the contents in the bounding box
 166         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 167         if ( maxh > 0 )
 168                 offset.y += maxh/2;
 169
 170         // Draw the title
 171         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 172
 173         // Draw the icon
 174         if(pic != "")
 175                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 176
 177         // Draw the description
 178         for ( last = title.chain; last ; )
 179         {
 180                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 181                 next = last;
 182                 last = last.chain;
 183                 delete(next);
 184         }
 185
 186         // Cleanup
 187         delete(title);
 188 }
 189
 190 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 191 {
 192         TC(int, id);
 193         vector img_size = '0 0 0';
 194         string label;
 195         float text_size;
 196
 197         float rect_margin = hud_fontsize.y / 2;
 198
 199         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 200         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 201         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 202         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 203
 204         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 205         vector rect_size = '1 1 0';
 206         rect_size.x = tsize + rect_margin;
 207         rect_size.y = isize + rect_margin;
 208
 209         float img_ar = 4/3;
 210         img_size.x = min(tsize, isize * img_ar);
 211         img_size.y = img_size.x / img_ar;
 212         img_size.y -= hud_fontsize.y;
 213         img_size.x = img_size.y * img_ar;
 214
 215         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 216
 217         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 218
 219         text_size = stringwidth(label, false, hud_fontsize);
 220
 221         float save_rect_sizex = rect_size.x;
 222         rect_size.x = max(img_size.x, text_size) + rect_margin;
 223         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 224
 225         vector text_pos = '0 0 0';
 226         text_pos.x = pos.x + (tsize - text_size) / 2;
 227         text_pos.y = pos.y + img_size.y;
 228
 229         pos.x += (tsize - img_size.x) / 2;
 230
 231         float theAlpha;
 232         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 233                 theAlpha = mv_top2_alpha;
 234         else
 235                 theAlpha = 1;
 236         theAlpha *= panel_fg_alpha;
 237
 238         // Highlight selected item
 239         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 240                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 241
 242         // Highlight current vote
 243         vector rgb = MapVote_RGB(id);
 244         if(id == mv_ownvote)
 245         {
 246                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 247                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 248         }
 249
 250         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 251
 252         if(pic == "")
 253         {
 254                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 255         }
 256         else
 257         {
 258                 if(drawgetimagesize(pic) == '0 0 0')
 259                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 260                 else
 261                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 262         }
 263 }
 264
 265 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 266 {
 267         TC(int, id);
 268         vector rgb;
 269         float text_size;
 270         string label;
 271
 272         rgb = MapVote_RGB(id);
 273
 274         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 275
 276         text_size = stringwidth(label, false, hud_fontsize);
 277
 278         pos.x -= text_size*0.5;
 279         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 280 }
 281
 282 vector MapVote_GridVec(vector gridspec, int i, int m)
 283 {
 284         TC(int, i); TC(int, m);
 285         int r = i % m;
 286         return
 287                 '1 0 0' * (gridspec.x * r)
 288                 +
 289                 '0 1 0' * (gridspec.y * (i - r) / m);
 290 }
 291
 292 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 293 {
 294
 295         float c, r;
 296
 297         mv_mouse_selection = -1;
 298
 299         for (r = 0; r < rows; ++r)
 300                 for (c = 0; c < columns; ++c)
 301                 {
 302                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
 303                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 304                                 mousepos.y >= topleft.y + cellsize.y *  r &&
 305                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
 306                         {
 307                                 mv_mouse_selection = r * columns + c;
 308                                 break;
 309                         }
 310                 }
 311
 312         if (mv_mouse_selection >= mv_num_maps)
 313                 mv_mouse_selection = -1;
 314
 315         if (mv_abstain && mv_mouse_selection < 0)
 316                 mv_mouse_selection = mv_num_maps;
 317
 318         if ( mv_selection_keyboard )
 319                 return mv_selection;
 320
 321         return mv_mouse_selection;
 322 }
 323
 324 vector prev_mousepos;
 325 // draws map vote or gametype vote
 326 void MapVote_Draw()
 327 {
 328         string map;
 329         int i;
 330         float tmp;
 331         vector pos;
 332         float center;
 333         float rows;
 334         vector dist = '0 0 0';
 335
 336         //if(intermission != 2) return;
 337         if(!mv_active)
 338                 return;
 339
 340         HUD_Panel_LoadCvars();
 341
 342         if (!autocvar_hud_cursormode)
 343         {
 344                 if (mousepos.x != prev_mousepos.x || mousepos.y != prev_mousepos.y)
 345                 {
 346                         mv_selection_keyboard = 0;
 347                         prev_mousepos = mousepos;
 348                 }
 349         }
 350
 351         center = (vid_conwidth - 1)/2;
 352         xmin = vid_conwidth * 0.08;
 353         xmax = vid_conwidth - xmin;
 354         ymin = 20;
 355         ymax = vid_conheight - ymin;
 356
 357         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 358                 ymin += chat_sizey;
 359         else
 360                 ymax -= chat_sizey;
 361
 362         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 363         if (gametypevote)
 364         {
 365                 gtv_text_size = hud_fontsize * 1.4;
 366                 gtv_text_size_small = hud_fontsize * 1.1;
 367         }
 368
 369         pos.y = ymin;
 370         pos.z = 0;
 371
 372         HUD_Scale_Disable();
 373         draw_beginBoldFont();
 374
 375         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 376         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 377         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 378         pos.y += hud_fontsize.y * 2;
 379
 380         if( mapvote_chosenmap != "" )
 381         {
 382                 pos.y += hud_fontsize.y * 0.25;
 383                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 384                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 385                 pos.y += hud_fontsize.y * 1.5;
 386         }
 387         pos.y += hud_fontsize.y * 0.5;
 388
 389         draw_endBoldFont();
 390
 391         i = ceil(max(0, mv_timeout - time));
 392         map = sprintf(_("%d seconds left"), i);
 393         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 394         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 395         pos.y += hud_fontsize.y * 1.5;
 396         pos.y += hud_fontsize.y * 0.5;
 397
 398         // base for multi-column stuff...
 399         pos.y += hud_fontsize.y;
 400         pos.x = xmin;
 401         ymin = pos.y;
 402         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 403         if(mv_abstain)
 404         {
 405                 mv_num_maps -= 1;
 406                 ymax -= abstain_spacing;
 407         }
 408
 409         // higher than the image itself ratio for mapvote items to reserve space for long map names
 410         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 411         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
 412         mv_columns = table_size.x;
 413         rows = table_size.y;
 414
 415         dist.x = (xmax - xmin) / mv_columns;
 416         dist.y = (ymax - pos.y) / rows;
 417
 418         // reduce size of too wide items
 419         tmp = vid_conwidth / 3; // max width
 420         if(dist.x > tmp)
 421         {
 422                 dist.x = tmp;
 423                 dist.y = min(dist.y, dist.x / item_aspect);
 424         }
 425         tmp = vid_conheight / 3; // max height
 426         if(dist.y > tmp)
 427         {
 428                 dist.y = tmp;
 429                 dist.x = min(dist.x, dist.y * item_aspect);
 430         }
 431
 432         // reduce size to fix aspect ratio
 433         if(dist.x / dist.y > item_aspect)
 434                 dist.x = dist.y * item_aspect;
 435         else
 436                 dist.y = dist.x / item_aspect;
 437
 438         // adjust table pos and size according to the new size
 439         float offset;
 440         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 441         xmin = pos.x += offset;
 442         xmax -= offset;
 443         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 444         ymax -= 2 * offset;
 445
 446         // override panel_pos and panel_size
 447         panel_pos.x = pos.x;
 448         panel_pos.y = pos.y;
 449         panel_size.x = xmax - xmin;
 450         panel_size.y = ymax - ymin;
 451         HUD_Panel_DrawBg();
 452
 453         if(panel_bg_padding)
 454         {
 455                 // FIXME item AR gets slightly changed here...
 456                 // it's rather hard to avoid it at this point
 457                 dist.x -= 2 * panel_bg_padding / mv_columns;
 458                 dist.y -= 2 * panel_bg_padding / rows;
 459                 xmin = pos.x += panel_bg_padding;
 460                 ymin = pos.y += panel_bg_padding;
 461                 xmax -= 2 * panel_bg_padding;
 462                 ymax -= 2 * panel_bg_padding;
 463         }
 464
 465         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 466
 467         if (mv_top2_time)
 468                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time) ** 2);
 469
 470         void (vector, float, float, string, string, float, float) DrawItem;
 471
 472         if(gametypevote)
 473                 DrawItem = GameTypeVote_DrawGameTypeItem;
 474         else
 475                 DrawItem = MapVote_DrawMapItem;
 476
 477         for(i = 0; i < mv_num_maps; ++i)
 478         {
 479                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 480                 map = mv_maps[i];
 481                 if(mv_preview[i])
 482                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 483                 else
 484                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 485         }
 486
 487         if(mv_abstain)
 488                 ++mv_num_maps;
 489
 490         if(mv_abstain && i < mv_num_maps) {
 491                 tmp = mv_votes[i];
 492                 pos.y = ymax + abstain_spacing;
 493                 pos.x = (xmax+xmin)*0.5;
 494                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 495         }
 496 }
 497
 498 void Cmd_MapVote_MapDownload(int argc)
 499 {
 500         TC(int, argc);
 501         entity pak;
 502
 503         if(argc != 2 || !mv_pk3list)
 504         {
 505                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
 506                 return;
 507         }
 508
 509         int id = stof(argv(1));
 510         for(pak = mv_pk3list; pak; pak = pak.chain)
 511                 if(pak.sv_entnum == id)
 512                         break;
 513
 514         if(!pak || pak.sv_entnum != id) {
 515                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
 516                 return;
 517         }
 518
 519         if(PreviewExists(pak.message))
 520         {
 521                 mv_preview[id] = true;
 522                 return;
 523         } else {
 524                 LOG_INFO(_("Requesting preview..."));
 525                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 526         }
 527 }
 528
 529 void MapVote_CheckPK3(string pic, string pk3, int id)
 530 {
 531         TC(int, id);
 532         entity pak;
 533         pak = spawn();
 534         pak.netname = pk3;
 535         pak.message = pic;
 536         pak.sv_entnum = id;
 537
 538         pak.chain = mv_pk3list;
 539         mv_pk3list = pak;
 540
 541         if(pk3 != "")
 542         {
 543                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 544         }
 545         else
 546         {
 547                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 548         }
 549 }
 550
 551 void MapVote_CheckPic(string pic, string pk3, int id)
 552 {
 553         TC(int, id);
 554         // never try to retrieve a pic for the "don't care" 'map'
 555         if(mv_abstain && id == mv_num_maps - 1)
 556                 return;
 557
 558         if(PreviewExists(pic))
 559         {
 560                 mv_preview[id] = true;
 561                 return;
 562         }
 563         MapVote_CheckPK3(pic, pk3, id);
 564 }
 565
 566 void MapVote_ReadMask()
 567 {
 568         int i;
 569         if ( mv_num_maps < 24 )
 570         {
 571                 int mask;
 572                 if(mv_num_maps < 8)
 573                         mask = ReadByte();
 574                 else if(mv_num_maps < 16)
 575                         mask = ReadShort();
 576                 else
 577                         mask = ReadLong();
 578
 579                 for(i = 0; i < mv_num_maps; ++i)
 580                 {
 581                         if (mask & BIT(i))
 582                                 mv_flags[i] |= GTV_AVAILABLE;
 583                         else
 584                                 mv_flags[i] &= ~GTV_AVAILABLE;
 585                 }
 586         }
 587         else
 588         {
 589                 for(i = 0; i < mv_num_maps; ++i )
 590                         mv_flags[i] = ReadByte();
 591         }
 592 }
 593
 594 void MapVote_ReadOption(int i)
 595 {
 596         TC(int, i);
 597         string map = strzone(ReadString());
 598         string pk3 = strzone(ReadString());
 599         int j = bound(0, ReadByte(), n_ssdirs - 1);
 600
 601         mv_maps[i] = map;
 602         mv_pk3[i] = pk3;
 603         mv_flags[i] = GTV_AVAILABLE;
 604
 605         string pic = strzone(strcat(ssdirs[j], "/", map));
 606         mv_pics[i] = pic;
 607         mv_preview[i] = false;
 608         MapVote_CheckPic(pic, pk3, i);
 609 }
 610
 611 void GameTypeVote_ReadOption(int i)
 612 {
 613         TC(int, i);
 614         string gt = strzone(ReadString());
 615
 616         mv_maps[i] = gt;
 617         mv_flags[i] = ReadByte();
 618
 619         string basetype = "";
 620
 621         if ( mv_flags[i] & GTV_CUSTOM )
 622         {
 623                 string name = ReadString();
 624                 if ( strlen(name) < 1 )
 625                         name = gt;
 626                 mv_pk3[i] = strzone(name);
 627                 mv_desc[i] = strzone(ReadString());
 628                 basetype = strzone(ReadString());
 629         }
 630         else
 631         {
 632                 Gametype type = MapInfo_Type_FromString(gt);
 633                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 634                 mv_desc[i] = MapInfo_Type_Description(type);
 635         }
 636
 637         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 638         if(precache_pic(mv_picpath) == "")
 639         {
 640                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 641                 if(precache_pic(mv_picpath) == "")
 642                 {
 643                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
 644                         if(precache_pic(mv_picpath) == "")
 645                         {
 646                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
 647                         }
 648                 }
 649         }
 650         string pic = strzone(mv_picpath);
 651         mv_pics[i] = pic;
 652         mv_preview[i] = PreviewExists(pic);
 653 }
 654
 655 void MapVote_Init()
 656 {
 657         mv_active = 1;
 658         if(!autocvar_hud_cursormode) mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 659         mv_selection = -1;
 660         mv_selection_keyboard = 0;
 661
 662         string s;
 663         for(n_ssdirs = 0; ; ++n_ssdirs)
 664         {
 665                 s = ReadString();
 666                 if(s == "")
 667                         break;
 668                 if(n_ssdirs < NUM_SSDIRS)
 669                         ssdirs[n_ssdirs] = s;
 670         }
 671         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 672
 673         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 674         mv_abstain = ReadByte();
 675         if(mv_abstain)
 676                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 677         mv_detail = ReadByte();
 678
 679         mv_ownvote = -1;
 680         mv_timeout = ReadCoord();
 681
 682         gametypevote = ReadByte();
 683
 684         if(gametypevote)
 685         {
 686                 mapvote_chosenmap = strzone(ReadString());
 687                 if ( gametypevote == 2 )
 688                         gametypevote = 0;
 689         }
 690
 691         MapVote_ReadMask();
 692         int i;
 693         for(i = 0; i < mv_num_maps; ++i )
 694                 mv_flags_start[i] = mv_flags[i];
 695
 696         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 697         mv_pk3list = NULL; // I'm still paranoid!
 698
 699         for(i = 0; i < mv_num_maps; ++i)
 700         {
 701                 mv_votes[i] = 0;
 702
 703                 if ( gametypevote )
 704                         GameTypeVote_ReadOption(i);
 705                 else
 706                         MapVote_ReadOption(i);
 707         }
 708
 709         for(i = 0; i < n_ssdirs; ++i)
 710                 ssdirs[n_ssdirs] = string_null;
 711         n_ssdirs = 0;
 712 }
 713
 714 void MapVote_SendChoice(int index)
 715 {
 716         TC(int, index);
 717         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 718 }
 719
 720 int MapVote_MoveLeft(int pos)
 721 {
 722         TC(int, pos);
 723         int imp;
 724         if ( pos < 0 )
 725                 imp = mv_num_maps - 1;
 726         else
 727                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 728         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 729                 imp = MapVote_MoveLeft(imp);
 730         return imp;
 731 }
 732 int MapVote_MoveRight(int pos)
 733 {
 734         TC(int, pos);
 735         int imp;
 736         if ( pos < 0 )
 737                 imp = 0;
 738         else
 739                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 740         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 741                 imp = MapVote_MoveRight(imp);
 742         return imp;
 743 }
 744 int MapVote_MoveUp(int pos)
 745 {
 746         TC(int, pos);
 747         int imp;
 748         if ( pos < 0 )
 749                 imp = mv_num_maps - 1;
 750         else
 751         {
 752                 imp = pos - mv_columns;
 753                 if ( imp < 0 )
 754                 {
 755                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 756                         if ( imp >= mv_num_maps )
 757                                 imp -= mv_columns;
 758                 }
 759         }
 760         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 761                 imp = MapVote_MoveUp(imp);
 762         return imp;
 763 }
 764 int MapVote_MoveDown(int pos)
 765 {
 766         TC(int, pos);
 767         int imp;
 768         if ( pos < 0 )
 769                 imp = 0;
 770         else
 771         {
 772                 imp = pos + mv_columns;
 773                 if ( imp >= mv_num_maps )
 774                         imp = imp % mv_columns;
 775         }
 776         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 777                 imp = MapVote_MoveDown(imp);
 778         return imp;
 779 }
 780
 781 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 782 {
 783         TC(int, bInputType);
 784
 785         static int first_digit = 0;
 786         if (!mv_active)
 787                 return false;
 788
 789         if(bInputType == 3)
 790         {
 791                 mousepos.x = nPrimary;
 792                 mousepos.y = nSecondary;
 793                 mv_selection_keyboard = 0;
 794                 return true;
 795         }
 796
 797         if (bInputType == 0)
 798         {
 799                 if (nPrimary == K_ALT) hudShiftState |= S_ALT;
 800                 if (nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 801                 if (nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 802         }
 803         else if (bInputType == 1)
 804         {
 805                 if (nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 806                 if (nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 807                 if (nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 808
 809                 if (nPrimary == K_CTRL)
 810                         first_digit = 0;
 811         }
 812
 813         if (bInputType != 0)
 814                 return false;
 815
 816         int imp = 0;
 817         switch(nPrimary)
 818         {
 819                 case K_RIGHTARROW:
 820                         mv_selection_keyboard = 1;
 821                         mv_selection = MapVote_MoveRight(mv_selection);
 822                         return true;
 823                 case K_LEFTARROW:
 824                         mv_selection_keyboard = 1;
 825                         mv_selection = MapVote_MoveLeft(mv_selection);
 826                         return true;
 827                 case K_DOWNARROW:
 828                         mv_selection_keyboard = 1;
 829                         mv_selection = MapVote_MoveDown(mv_selection);
 830                         return true;
 831                 case K_UPARROW:
 832                         mv_selection_keyboard = 1;
 833                         mv_selection = MapVote_MoveUp(mv_selection);
 834                         return true;
 835                 case K_KP_ENTER:
 836                 case K_ENTER:
 837                 case K_SPACE:
 838                         if ( mv_selection_keyboard )
 839                                 MapVote_SendChoice(mv_selection);
 840                         return true;
 841                 case '1': case K_KP_1: imp = 1; break;
 842                 case '2': case K_KP_2: imp = 2; break;
 843                 case '3': case K_KP_3: imp = 3; break;
 844                 case '4': case K_KP_4: imp = 4; break;
 845                 case '5': case K_KP_5: imp = 5; break;
 846                 case '6': case K_KP_6: imp = 6; break;
 847                 case '7': case K_KP_7: imp = 7; break;
 848                 case '8': case K_KP_8: imp = 8; break;
 849                 case '9': case K_KP_9: imp = 9; break;
 850                 case '0': case K_KP_0: imp = 10; break;
 851         }
 852
 853         if (imp && hudShiftState & S_CTRL)
 854         {
 855                 if (!first_digit)
 856                 {
 857                         first_digit = imp % 10;
 858                         return true;
 859                 }
 860                 else
 861                         imp = first_digit * 10 + (imp % 10);
 862         }
 863
 864         if (nPrimary == K_MOUSE1)
 865         {
 866                 mv_selection_keyboard = 0;
 867                 mv_selection = mv_mouse_selection;
 868                 if (mv_selection >= 0)
 869                         imp = min(mv_selection + 1, mv_num_maps);
 870         }
 871
 872         if (imp)
 873         {
 874                 if (imp <= mv_num_maps)
 875                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 876                 return true;
 877         }
 878
 879         return false;
 880 }
 881
 882 void MapVote_UpdateMask()
 883 {
 884         MapVote_ReadMask();
 885         mv_top2_time = time;
 886 }
 887
 888 void MapVote_UpdateVotes()
 889 {
 890         int i;
 891         for(i = 0; i < mv_num_maps; ++i)
 892         {
 893                 if(mv_flags[i] & GTV_AVAILABLE)
 894                 {
 895                         if(mv_detail)
 896                                 mv_votes[i] = ReadByte();
 897                         else
 898                                 mv_votes[i] = 0;
 899                 }
 900                 else
 901                         mv_votes[i] = -1;
 902         }
 903
 904         mv_ownvote = ReadByte()-1;
 905 }
 906
 907 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 908 {
 909         make_pure(this);
 910         int sf = ReadByte();
 911         return = true;
 912
 913         if(sf & 1)
 914                 MapVote_Init();
 915
 916         if(sf & 2)
 917                 MapVote_UpdateMask();
 918
 919         if(sf & 4)
 920                 MapVote_UpdateVotes();
 921 }
 922
 923 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 924 {
 925         Net_MapVote_Picture();
 926         return true;
 927 }
 928
 929 void Net_MapVote_Picture()
 930 {
 931         int type = ReadByte();
 932         mv_preview[type] = true;
 933         mv_pics[type] = strzone(ReadPicture());
 934 }