qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "hud/all.qh"
   4 #include "hud/panel/scoreboard.qh"
   5
   6 #include <common/mapinfo.qh>
   7
   8
   9 int mv_num_maps;
  10
  11 string mv_maps[MAPVOTE_COUNT];
  12 string mv_pics[MAPVOTE_COUNT];
  13 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  14 string mv_desc[MAPVOTE_COUNT];
  15 float mv_preview[MAPVOTE_COUNT];
  16 float mv_votes[MAPVOTE_COUNT];
  17 float mv_flags[MAPVOTE_COUNT];
  18 float mv_flags_start[MAPVOTE_COUNT];
  19 entity mv_pk3list;
  20 float mv_abstain;
  21 float mv_ownvote;
  22 float mv_detail;
  23 float mv_timeout;
  24 float mv_top2_time;
  25 float mv_top2_alpha;
  26
  27 vector mv_mousepos;
  28 int mv_selection;
  29 int mv_columns;
  30 int mv_mouse_selection;
  31 int mv_selection_keyboard;
  32
  33 float gametypevote;
  34 string mapvote_chosenmap;
  35 vector gtv_text_size;
  36 vector gtv_text_size_small;
  37
  38 const int NUM_SSDIRS = 4;
  39 string ssdirs[NUM_SSDIRS];
  40 int n_ssdirs;
  41
  42 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  43 {
  44     TC(int, id);
  45         string pre, post;
  46         pre = sprintf("%d. ", id+1);
  47         if(mv_detail)
  48         {
  49                 if(_count == 1)
  50                         post = _(" (1 vote)");
  51                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  52                         post = sprintf(_(" (%d votes)"), _count);
  53                 else
  54                         post = "";
  55         }
  56         else
  57                 post = "";
  58         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  59         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  60         return strcat(pre, map, post);
  61 }
  62
  63 vector MapVote_RGB(int id)
  64 {
  65     TC(int, id);
  66         if(!(mv_flags[id] & GTV_AVAILABLE))
  67                 return '1 1 1';
  68         if(id == mv_ownvote)
  69                 return '0 1 0';
  70         else if (id == mv_selection)
  71                 return '1 1 0';
  72         else
  73                 return '1 1 1';
  74 }
  75
  76 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  77 {
  78     TC(int, id);
  79         // Find the correct alpha
  80         float alpha;
  81         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  82                 alpha = 0.2; // The gametype isn't supported by the map
  83         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  84                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  85         else
  86                 alpha = 1; // Normal, full alpha
  87         alpha *= panel_fg_alpha;
  88
  89         // Bounding box details
  90         float rect_margin = hud_fontsize.y / 2;
  91
  92         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  93         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  94         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  95         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  96
  97         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  98         vector rect_size = '1 1 0';
  99         rect_size.x = tsize + rect_margin;
 100         rect_size.y = maxh + rect_margin;
 101
 102         // Highlight selected item
 103         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 104         {
 105                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 106         }
 107
 108         // Highlight current vote
 109         vector rgb = MapVote_RGB(id);
 110         if(id == mv_ownvote)
 111         {
 112                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 113                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 114         }
 115
 116         vector offset = pos;
 117
 118         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 119         pos.y += title_gap;
 120         maxh -= title_gap;
 121
 122         // Evaluate the image size
 123         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 124         if ( maxh < image_size.y )
 125                 image_size = '1 1 0' * maxh;
 126         image_size *= 0.8;
 127         float desc_padding = gtv_text_size.x * 0.6;
 128         pos.x += image_size.x + desc_padding;
 129         tsize -= image_size.x + desc_padding;
 130
 131         // Split the description into lines
 132         entity title;
 133         title = spawn();
 134         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 135
 136         string thelabel = mv_desc[id], ts;
 137         entity last = title;
 138         entity next = NULL;
 139         float nlines = 0;
 140         if( thelabel != "")
 141         {
 142                 float i,n = tokenizebyseparator(thelabel, "\n");
 143                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 144                 {
 145                         getWrappedLine_remaining = argv(i);
 146                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 147                         {
 148                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 149                                 if (ts != "")
 150                                 {
 151                                         next = spawn();
 152                                         next.message = ts;
 153                                         next.origin = pos-offset;
 154                                         last.chain = next;
 155                                         last = next;
 156                                         pos.y += gtv_text_size_small.y;
 157                                         nlines++;
 158                                 }
 159                         }
 160                 }
 161         }
 162
 163         // Center the contents in the bounding box
 164         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 165         if ( maxh > 0 )
 166                 offset.y += maxh/2;
 167
 168         // Draw the title
 169         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 170
 171         // Draw the icon
 172         if(pic != "")
 173                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 174
 175         // Draw the description
 176         for ( last = title.chain; last ; )
 177         {
 178                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 179                 next = last;
 180                 last = last.chain;
 181                 delete(next);
 182         }
 183
 184         // Cleanup
 185         delete(title);
 186 }
 187
 188 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 189 {
 190     TC(int, id);
 191         vector img_size = '0 0 0';
 192         string label;
 193         float text_size;
 194
 195         float rect_margin = hud_fontsize.y / 2;
 196
 197         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 198         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 199         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 200         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 201
 202         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 203         vector rect_size = '1 1 0';
 204         rect_size.x = tsize + rect_margin;
 205         rect_size.y = isize + rect_margin;
 206
 207         float img_ar = 4/3;
 208         img_size.x = min(tsize, isize * img_ar);
 209         img_size.y = img_size.x / img_ar;
 210         img_size.y -= hud_fontsize.y;
 211         img_size.x = img_size.y * img_ar;
 212
 213         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 214
 215         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 216
 217         text_size = stringwidth(label, false, hud_fontsize);
 218
 219         float save_rect_sizex = rect_size.x;
 220         rect_size.x = max(img_size.x, text_size) + rect_margin;
 221         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 222
 223         vector text_pos = '0 0 0';
 224         text_pos.x = pos.x + (tsize - text_size) / 2;
 225         text_pos.y = pos.y + img_size.y;
 226
 227         pos.x += (tsize - img_size.x) / 2;
 228
 229         float theAlpha;
 230         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 231                 theAlpha = mv_top2_alpha;
 232         else
 233                 theAlpha = 1;
 234         theAlpha *= panel_fg_alpha;
 235
 236         // Highlight selected item
 237         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 238                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 239
 240         // Highlight current vote
 241         vector rgb = MapVote_RGB(id);
 242         if(id == mv_ownvote)
 243         {
 244                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 245                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 246         }
 247
 248         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 249
 250         if(pic == "")
 251         {
 252                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 253         }
 254         else
 255         {
 256                 if(drawgetimagesize(pic) == '0 0 0')
 257                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 258                 else
 259                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 260         }
 261 }
 262
 263 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 264 {
 265     TC(int, id);
 266         vector rgb;
 267         float text_size;
 268         string label;
 269
 270         rgb = MapVote_RGB(id);
 271
 272         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 273
 274         text_size = stringwidth(label, false, hud_fontsize);
 275
 276         pos.x -= text_size*0.5;
 277         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 278 }
 279
 280 vector MapVote_GridVec(vector gridspec, int i, int m)
 281 {
 282     TC(int, i); TC(int, m);
 283         int r = i % m;
 284         return
 285                 '1 0 0' * (gridspec.x * r)
 286                 +
 287                 '0 1 0' * (gridspec.y * (i - r) / m);
 288 }
 289
 290 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 291 {
 292
 293         float c, r;
 294
 295         mv_mouse_selection = -1;
 296
 297         for (r = 0; r < rows; ++r)
 298                 for (c = 0; c < columns; ++c)
 299                 {
 300                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 301                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 302                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 303                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 304                         {
 305                                 mv_mouse_selection = r * columns + c;
 306                                 break;
 307                         }
 308                 }
 309
 310         if (mv_mouse_selection >= mv_num_maps)
 311                 mv_mouse_selection = -1;
 312
 313         if (mv_abstain && mv_mouse_selection < 0)
 314                 mv_mouse_selection = mv_num_maps;
 315
 316         if ( mv_selection_keyboard )
 317                 return mv_selection;
 318
 319         return mv_mouse_selection;
 320 }
 321
 322 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 323 void MapVote_Draw()
 324 {
 325         string map;
 326         int i;
 327         float tmp;
 328         vector pos;
 329         float center;
 330         float rows;
 331         vector dist = '0 0 0';
 332
 333         //if(intermission != 2) return;
 334         if(!mv_active)
 335                 return;
 336
 337         if(1 - scoreboard_fade_alpha <= 0)
 338                 return;
 339         HUD_Panel_UpdateCvars(1 - scoreboard_fade_alpha);
 340
 341         if (!autocvar_hud_cursormode)
 342         {
 343                 vector mpos = mv_mousepos + getmousepos();
 344                 mpos.x = bound(0, mpos.x, vid_conwidth);
 345                 mpos.y = bound(0, mpos.y, vid_conheight);
 346
 347                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 348                         mv_selection_keyboard = 0;
 349                 mv_mousepos = mpos;
 350         }
 351
 352         center = (vid_conwidth - 1)/2;
 353         xmin = vid_conwidth * 0.08;
 354         xmax = vid_conwidth - xmin;
 355         ymin = 20;
 356         ymax = vid_conheight - ymin;
 357
 358         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 359                 ymin += chat_sizey;
 360         else
 361                 ymax -= chat_sizey;
 362
 363         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 364
 365         pos.y = ymin;
 366         pos.z = 0;
 367
 368         HUD_Scale_Disable();
 369         draw_beginBoldFont();
 370
 371         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 372         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 373         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 374         pos.y += hud_fontsize.y * 2;
 375
 376         if( mapvote_chosenmap != "" )
 377         {
 378                 pos.y += hud_fontsize.y * 0.25;
 379                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 380                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 381                 pos.y += hud_fontsize.y * 1.5;
 382         }
 383         pos.y += hud_fontsize.y * 0.5;
 384
 385         draw_endBoldFont();
 386
 387         i = ceil(max(0, mv_timeout - time));
 388         map = sprintf(_("%d seconds left"), i);
 389         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 390         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 391         pos.y += hud_fontsize.y * 1.5;
 392         pos.y += hud_fontsize.y * 0.5;
 393
 394         // base for multi-column stuff...
 395         pos.y += hud_fontsize.y;
 396         pos.x = xmin;
 397         ymin = pos.y;
 398         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 399         if(mv_abstain)
 400         {
 401                 mv_num_maps -= 1;
 402                 ymax -= abstain_spacing;
 403         }
 404
 405         // higher than the image itself ratio for mapvote items to reserve space for long map names
 406         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 407         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 408         mv_columns = table_size.x;
 409         rows = table_size.y;
 410
 411         dist.x = (xmax - xmin) / mv_columns;
 412         dist.y = (ymax - pos.y) / rows;
 413
 414         // reduce size of too wide items
 415         tmp = vid_conwidth / 3; // max width
 416         if(dist.x > tmp)
 417         {
 418                 dist.x = tmp;
 419                 dist.y = min(dist.y, dist.x / item_aspect);
 420         }
 421         tmp = vid_conheight / 3; // max height
 422         if(dist.y > tmp)
 423         {
 424                 dist.y = tmp;
 425                 dist.x = min(dist.x, dist.y * item_aspect);
 426         }
 427
 428         // reduce size to fix aspect ratio
 429         if(dist.x / dist.y > item_aspect)
 430                 dist.x = dist.y * item_aspect;
 431         else
 432                 dist.y = dist.x / item_aspect;
 433
 434         // adjust table pos and size according to the new size
 435         float offset;
 436         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 437         xmin = pos.x += offset;
 438         xmax -= offset;
 439         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 440         ymax -= 2 * offset;
 441
 442         // override panel_pos and panel_size
 443         panel_pos.x = pos.x;
 444         panel_pos.y = pos.y;
 445         panel_size.x = xmax - xmin;
 446         panel_size.y = ymax - ymin;
 447         HUD_Panel_DrawBg();
 448
 449         if(panel_bg_padding)
 450         {
 451                 // FIXME item AR gets slightly changed here...
 452                 // it's rather hard to avoid it at this point
 453                 dist.x -= 2 * panel_bg_padding / mv_columns;
 454                 dist.y -= 2 * panel_bg_padding / rows;
 455                 xmin = pos.x += panel_bg_padding;
 456                 ymin = pos.y += panel_bg_padding;
 457                 xmax -= 2 * panel_bg_padding;
 458                 ymax -= 2 * panel_bg_padding;
 459         }
 460
 461         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 462
 463         if (mv_top2_time)
 464                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 465
 466         void (vector, float, float, string, string, float, float) DrawItem;
 467
 468         if(gametypevote)
 469                 DrawItem = GameTypeVote_DrawGameTypeItem;
 470         else
 471                 DrawItem = MapVote_DrawMapItem;
 472
 473         for(i = 0; i < mv_num_maps; ++i)
 474         {
 475                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 476                 map = mv_maps[i];
 477                 if(mv_preview[i])
 478                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 479                 else
 480                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 481         }
 482
 483         if(mv_abstain)
 484                 ++mv_num_maps;
 485
 486         if(mv_abstain && i < mv_num_maps) {
 487                 tmp = mv_votes[i];
 488                 pos.y = ymax + abstain_spacing;
 489                 pos.x = (xmax+xmin)*0.5;
 490                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 491         }
 492
 493         draw_cursor_normal(mv_mousepos, '1 1 1', panel_fg_alpha);
 494 }
 495
 496 void Cmd_MapVote_MapDownload(int argc)
 497 {
 498     TC(int, argc);
 499         entity pak;
 500
 501         if(argc != 2 || !mv_pk3list)
 502         {
 503                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 504                 return;
 505         }
 506
 507         int id = stof(argv(1));
 508         for(pak = mv_pk3list; pak; pak = pak.chain)
 509                 if(pak.sv_entnum == id)
 510                         break;
 511
 512         if(!pak || pak.sv_entnum != id) {
 513                 LOG_INFO(_("^1Error:^7 Couldn't find pak index.\n"));
 514                 return;
 515         }
 516
 517         if(PreviewExists(pak.message))
 518         {
 519                 mv_preview[id] = true;
 520                 return;
 521         } else {
 522                 LOG_INFO(_("Requesting preview...\n"));
 523                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 524         }
 525 }
 526
 527 void MapVote_CheckPK3(string pic, string pk3, int id)
 528 {
 529     TC(int, id);
 530         entity pak;
 531         pak = spawn();
 532         pak.netname = pk3;
 533         pak.message = pic;
 534         pak.sv_entnum = id;
 535
 536         pak.chain = mv_pk3list;
 537         mv_pk3list = pak;
 538
 539         if(pk3 != "")
 540         {
 541                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 542         }
 543         else
 544         {
 545                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 546         }
 547 }
 548
 549 void MapVote_CheckPic(string pic, string pk3, int id)
 550 {
 551     TC(int, id);
 552         // never try to retrieve a pic for the "don't care" 'map'
 553         if(mv_abstain && id == mv_num_maps - 1)
 554                 return;
 555
 556         if(PreviewExists(pic))
 557         {
 558                 mv_preview[id] = true;
 559                 return;
 560         }
 561         MapVote_CheckPK3(pic, pk3, id);
 562 }
 563
 564 void MapVote_ReadMask()
 565 {
 566         int i;
 567         if ( mv_num_maps < 24 )
 568         {
 569                 int mask, power;
 570                 if(mv_num_maps < 8)
 571                         mask = ReadByte();
 572                 else if(mv_num_maps < 16)
 573                         mask = ReadShort();
 574                 else
 575                         mask = ReadLong();
 576
 577                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 578                 {
 579                         if ( mask & power )
 580                                 mv_flags[i] |= GTV_AVAILABLE;
 581                         else
 582                                 mv_flags[i] &= ~GTV_AVAILABLE;
 583                 }
 584         }
 585         else
 586         {
 587                 for(i = 0; i < mv_num_maps; ++i )
 588                         mv_flags[i] = ReadByte();
 589         }
 590 }
 591
 592 void MapVote_ReadOption(int i)
 593 {
 594     TC(int, i);
 595         string map = strzone(ReadString());
 596         string pk3 = strzone(ReadString());
 597         int j = bound(0, ReadByte(), n_ssdirs - 1);
 598
 599         mv_maps[i] = map;
 600         mv_pk3[i] = pk3;
 601         mv_flags[i] = GTV_AVAILABLE;
 602
 603         string pic = strzone(strcat(ssdirs[j], "/", map));
 604         mv_pics[i] = pic;
 605         mv_preview[i] = false;
 606         MapVote_CheckPic(pic, pk3, i);
 607 }
 608
 609 void GameTypeVote_ReadOption(int i)
 610 {
 611     TC(int, i);
 612         string gt = strzone(ReadString());
 613
 614         mv_maps[i] = gt;
 615         mv_flags[i] = ReadByte();
 616
 617         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 618         if(precache_pic(mv_picpath) == "")
 619                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 620         string pic = strzone(mv_picpath);
 621         mv_pics[i] = pic;
 622         mv_preview[i] = PreviewExists(pic);
 623
 624         if ( mv_flags[i] & GTV_CUSTOM )
 625         {
 626                 string name = ReadString();
 627                 if ( strlen(name) < 1 )
 628                         name = gt;
 629                 mv_pk3[i] = strzone(name);
 630                 mv_desc[i] = strzone(ReadString());
 631         }
 632         else
 633         {
 634                 Gametype type = MapInfo_Type_FromString(gt);
 635                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 636                 mv_desc[i] = MapInfo_Type_Description(type);
 637         }
 638 }
 639
 640 void MapVote_Init()
 641 {
 642         mv_active = 1;
 643         if(autocvar_hud_cursormode) { setcursormode(1); }
 644         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 645         mv_selection = -1;
 646         mv_selection_keyboard = 0;
 647
 648         string s;
 649         for(n_ssdirs = 0; ; ++n_ssdirs)
 650         {
 651                 s = ReadString();
 652                 if(s == "")
 653                         break;
 654                 if(n_ssdirs < NUM_SSDIRS)
 655                         ssdirs[n_ssdirs] = s;
 656         }
 657         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 658
 659         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 660         mv_abstain = ReadByte();
 661         if(mv_abstain)
 662                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 663         mv_detail = ReadByte();
 664
 665         mv_ownvote = -1;
 666         mv_timeout = ReadCoord();
 667
 668         gametypevote = ReadByte();
 669
 670         if(gametypevote)
 671         {
 672                 mapvote_chosenmap = strzone(ReadString());
 673                 if ( gametypevote == 2 )
 674                         gametypevote = 0;
 675
 676                 gtv_text_size = hud_fontsize*1.4;
 677                 gtv_text_size_small = hud_fontsize*1.1;
 678         }
 679
 680         MapVote_ReadMask();
 681         int i;
 682         for(i = 0; i < mv_num_maps; ++i )
 683                 mv_flags_start[i] = mv_flags[i];
 684
 685         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 686         mv_pk3list = NULL; // I'm still paranoid!
 687
 688         for(i = 0; i < mv_num_maps; ++i)
 689         {
 690                 mv_votes[i] = 0;
 691
 692                 if ( gametypevote )
 693                         GameTypeVote_ReadOption(i);
 694                 else
 695                         MapVote_ReadOption(i);
 696         }
 697
 698         for(i = 0; i < n_ssdirs; ++i)
 699                 ssdirs[n_ssdirs] = string_null;
 700         n_ssdirs = 0;
 701 }
 702
 703 void MapVote_SendChoice(int index)
 704 {
 705     TC(int, index);
 706         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 707 }
 708
 709 int MapVote_MoveLeft(int pos)
 710 {
 711     TC(int, pos);
 712         int imp;
 713         if ( pos < 0 )
 714                 imp = mv_num_maps - 1;
 715         else
 716                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 717         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 718                 imp = MapVote_MoveLeft(imp);
 719         return imp;
 720 }
 721 int MapVote_MoveRight(int pos)
 722 {
 723     TC(int, pos);
 724         int imp;
 725         if ( pos < 0 )
 726                 imp = 0;
 727         else
 728                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 729         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 730                 imp = MapVote_MoveRight(imp);
 731         return imp;
 732 }
 733 int MapVote_MoveUp(int pos)
 734 {
 735     TC(int, pos);
 736         int imp;
 737         if ( pos < 0 )
 738                 imp = mv_num_maps - 1;
 739         else
 740         {
 741                 imp = pos - mv_columns;
 742                 if ( imp < 0 )
 743                 {
 744                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 745                         if ( imp >= mv_num_maps )
 746                                 imp -= mv_columns;
 747                 }
 748         }
 749         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 750                 imp = MapVote_MoveUp(imp);
 751         return imp;
 752 }
 753 int MapVote_MoveDown(int pos)
 754 {
 755     TC(int, pos);
 756         int imp;
 757         if ( pos < 0 )
 758                 imp = 0;
 759         else
 760         {
 761                 imp = pos + mv_columns;
 762                 if ( imp >= mv_num_maps )
 763                         imp = imp % mv_columns;
 764         }
 765         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 766                 imp = MapVote_MoveDown(imp);
 767         return imp;
 768 }
 769
 770 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 771 {
 772     TC(int, bInputType);
 773         float imp;
 774
 775         if (!mv_active)
 776                 return false;
 777
 778         if(bInputType == 3)
 779         {
 780                 mv_mousepos.x = nPrimary;
 781                 mv_mousepos.y = nSecondary;
 782                 mv_selection_keyboard = 0;
 783                 return true;
 784         }
 785
 786         if (bInputType != 0)
 787                 return false;
 788
 789         if ('0' <= nPrimary && nPrimary <= '9')
 790         {
 791                 imp = nPrimary - '0';
 792                 if (imp == 0) imp = 10;
 793                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 794                 return true;
 795         }
 796         switch(nPrimary)
 797         {
 798                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 799                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 800                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 801                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 802                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 803                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 804                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 805                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 806                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 807                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 808
 809                 case K_RIGHTARROW:
 810                         mv_selection_keyboard = 1;
 811                         mv_selection = MapVote_MoveRight(mv_selection);
 812                         return true;
 813                 case K_LEFTARROW:
 814                         mv_selection_keyboard = 1;
 815                         mv_selection = MapVote_MoveLeft(mv_selection);
 816                         return true;
 817                 case K_DOWNARROW:
 818                         mv_selection_keyboard = 1;
 819                         mv_selection = MapVote_MoveDown(mv_selection);
 820                         return true;
 821                 case K_UPARROW:
 822                         mv_selection_keyboard = 1;
 823                         mv_selection = MapVote_MoveUp(mv_selection);
 824                         return true;
 825                 case K_KP_ENTER:
 826                 case K_ENTER:
 827                 case K_SPACE:
 828                         if ( mv_selection_keyboard )
 829                                 MapVote_SendChoice(mv_selection);
 830                         return true;
 831         }
 832
 833         if (nPrimary == K_MOUSE1)
 834         {
 835                 mv_selection_keyboard = 0;
 836                 mv_selection = mv_mouse_selection;
 837                 if (mv_selection >= 0)
 838                 {
 839                         imp = min(mv_selection + 1, mv_num_maps);
 840                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 841                         return true;
 842                 }
 843         }
 844
 845         return false;
 846 }
 847
 848 void MapVote_UpdateMask()
 849 {
 850         MapVote_ReadMask();
 851         mv_top2_time = time;
 852 }
 853
 854 void MapVote_UpdateVotes()
 855 {
 856         int i;
 857         for(i = 0; i < mv_num_maps; ++i)
 858         {
 859                 if(mv_flags[i] & GTV_AVAILABLE)
 860                 {
 861                         if(mv_detail)
 862                                 mv_votes[i] = ReadByte();
 863                         else
 864                                 mv_votes[i] = 0;
 865                 }
 866                 else
 867                         mv_votes[i] = -1;
 868         }
 869
 870         mv_ownvote = ReadByte()-1;
 871 }
 872
 873 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 874 {
 875         make_pure(this);
 876         int sf = ReadByte();
 877         return = true;
 878
 879         if(sf & 1)
 880                 MapVote_Init();
 881
 882         if(sf & 2)
 883                 MapVote_UpdateMask();
 884
 885         if(sf & 4)
 886                 MapVote_UpdateVotes();
 887 }
 888
 889 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 890 {
 891         Net_MapVote_Picture();
 892         return true;
 893 }
 894
 895 void Net_MapVote_Picture()
 896 {
 897         int type = ReadByte();
 898         mv_preview[type] = true;
 899         mv_pics[type] = strzone(ReadPicture());
 900 }