qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         float alpha;
  82         float desc_padding = gtv_text_size.x * 3;
  83         float rect_margin = hud_fontsize.y / 2;
  84         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  85         vector rect_size = '1 1 0';
  86         rect_size.x = tsize + rect_margin;
  87         rect_size.y = maxh + rect_margin;
  88         vector rgb = MapVote_RGB(id);
  89         vector offset = pos;
  90         float nlines = 0;
  91
  92         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  93                 alpha = 0.2;
  94         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  95                 alpha = mv_top2_alpha;
  96         else
  97                 alpha = 1;
  98
  99         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 100         {
 101                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 102         }
 103         if(id == mv_ownvote)
 104         {
 105                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 106                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 107         }
 108
 109         entity title;
 110         title = spawn();
 111         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 112         title.origin = pos-offset;
 113
 114         pos.y += gtv_text_size_small.y;
 115         pos.y += gtv_text_size.y/2;
 116
 117         maxh -= gtv_text_size.y;
 118
 119         entity picent = spawn();
 120         picent.origin = pos-offset;
 121         picent.maxs = '1 1 0 ' * min(maxh, desc_padding) * 0.8;
 122
 123         pos.x += desc_padding;
 124         tsize -= desc_padding;
 125
 126         string thelabel = mv_desc[id], ts;
 127         entity last = title;
 128         entity next = world;
 129         if( thelabel != "")
 130         {
 131                 float i,n = tokenizebyseparator(thelabel, "\n");
 132                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 133                 {
 134                         getWrappedLine_remaining = argv(i);
 135                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 136                         {
 137                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 138                                 if (ts != "")
 139                                 {
 140                                         next = spawn();
 141                                         next.message = ts;
 142                                         next.origin = pos-offset;
 143                                         last.chain = next;
 144                                         last = next;
 145                                         pos.y += gtv_text_size_small.y;
 146                                         nlines++;
 147                                 }
 148                         }
 149                 }
 150         }
 151
 152         maxh -= max(nlines*gtv_text_size_small.y,picent.maxs.y);
 153         if ( maxh > 0 )
 154                 offset.y += maxh/2;
 155         drawstring(title.origin+offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 156
 157         if(pic != "")
 158                 drawpic(picent.origin+offset, pic, picent.maxs, '1 1 1', alpha, DRAWFLAG_NORMAL);
 159
 160         for ( last = title.chain; last ; )
 161         {
 162                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 163                 next = last;
 164                 last = last.chain;
 165                 remove(next);
 166         }
 167
 168         remove(picent);
 169         remove(title);
 170 }
 171
 172 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 173 {
 174         vector img_size = '0 0 0';
 175         vector rgb;
 176         string label;
 177         float text_size;
 178
 179         isize -= hud_fontsize.y; // respect the text when calculating the image size
 180
 181         rgb = MapVote_RGB(id);
 182
 183         img_size.y = isize;
 184         img_size.x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
 185
 186         pos.y = pos.y + img_size.y;
 187
 188         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 189
 190         text_size = stringwidth(label, false, hud_fontsize);
 191
 192         float theAlpha;
 193         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 194                 theAlpha = mv_top2_alpha;
 195         else
 196                 theAlpha = 1;
 197
 198         pos.x -= text_size*0.5;
 199         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 200
 201         pos.x = pos.x + text_size*0.5 - img_size.x*0.5;
 202         pos.y = pos.y - img_size.y;
 203
 204         pos += autocvar_scoreboard_border_thickness * '1 1 0';
 205         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
 206         if(pic == "")
 207         {
 208                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 209         }
 210         else
 211         {
 212                 if(drawgetimagesize(pic) == '0 0 0')
 213                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 214                 else
 215                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 216         }
 217
 218         if(id == mv_ownvote)
 219                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 220         else
 221                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 222
 223         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 224                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 225 }
 226
 227 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 228 {
 229         vector rgb;
 230         float text_size;
 231         string label;
 232
 233         rgb = MapVote_RGB(id);
 234
 235         pos.y = pos.y + hud_fontsize.y;
 236
 237         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 238
 239         text_size = stringwidth(label, false, hud_fontsize);
 240
 241         pos.x -= text_size*0.5;
 242         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 243 }
 244
 245 vector MapVote_GridVec(vector gridspec, int i, int m)
 246 {
 247         int r = i % m;
 248         return
 249                 '1 0 0' * (gridspec.x * r)
 250                 +
 251                 '0 1 0' * (gridspec.y * (i - r) / m);
 252 }
 253
 254 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 255 {
 256
 257         float c, r;
 258
 259         mv_mouse_selection = -1;
 260
 261         for (r = 0; r < rows; ++r)
 262                 for (c = 0; c < columns; ++c)
 263                 {
 264                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 265                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 266                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 267                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 268                         {
 269                                 mv_mouse_selection = r * columns + c;
 270                                 break;
 271                         }
 272                 }
 273
 274         if (mv_mouse_selection >= mv_num_maps)
 275                 mv_mouse_selection = -1;
 276
 277         if (mv_abstain && mv_mouse_selection < 0)
 278                 mv_mouse_selection = mv_num_maps;
 279
 280         if ( mv_selection_keyboard )
 281                 return mv_selection;
 282
 283         return mv_mouse_selection;
 284 }
 285
 286 void MapVote_Draw()
 287 {
 288         string map;
 289         int i;
 290         float tmp;
 291         vector pos;
 292         float isize;
 293         float center;
 294         float rows;
 295         float tsize;
 296         vector dist = '0 0 0';
 297
 298         if(!mv_active)
 299                 return;
 300
 301         if (!autocvar_hud_cursormode)
 302         {
 303                 vector mpos = mv_mousepos + getmousepos();
 304                 mpos.x = bound(0, mpos.x, vid_conwidth);
 305                 mpos.y = bound(0, mpos.y, vid_conheight);
 306
 307                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 308                         mv_selection_keyboard = 0;
 309                 mv_mousepos = mpos;
 310
 311         }
 312
 313         center = (vid_conwidth - 1)/2;
 314         xmin = vid_conwidth*0.05; // 5% border must suffice
 315         xmax = vid_conwidth - xmin;
 316         ymin = 20;
 317         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 318         if(i < 0)
 319                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 320         if(i >= 0 || ymax < (vid_conheight*0.5))
 321                 ymax = vid_conheight - ymin;
 322
 323         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 324
 325         pos.y = ymin;
 326         pos.z = 0;
 327
 328         draw_beginBoldFont();
 329         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 330         pos.x = center - stringwidth(map, false, '12 0 0');
 331         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 332         pos.y += 26;
 333
 334         if( mapvote_chosenmap != "" )
 335         {
 336                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize*1.5/2);
 337                 drawstring(pos, mapvote_chosenmap, hud_fontsize*1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 338                 pos.y += hud_fontsize.y*2;
 339         }
 340
 341         i = ceil(max(0, mv_timeout - time));
 342         map = sprintf(_("%d seconds left"), i);
 343         pos.x = center - stringwidth(map, false, '8 0 0');
 344         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 345         pos.y += 22;
 346         pos.x = xmin;
 347         draw_endBoldFont();
 348
 349         // base for multi-column stuff...
 350         ymin = pos.y;
 351         if(mv_abstain)
 352                 mv_num_maps -= 1;
 353
 354         rows = ceil(mv_num_maps / mv_columns);
 355
 356         dist.x = (xmax - xmin) / mv_columns;
 357         dist.y = (ymax - pos.y) / rows;
 358
 359         if ( gametypevote )
 360         {
 361                 tsize = dist.x - hud_fontsize.y;
 362                 isize = dist.y;
 363                 float maxheight = (ymax - pos.y) / 3;
 364                 if ( isize > maxheight )
 365                 {
 366                         pos.x += (isize - maxheight)/2;
 367                         isize = maxheight;
 368                 }
 369                 else
 370                         dist.y += hud_fontsize.y;
 371                 pos.x = ( vid_conwidth - dist.x * mv_columns ) / 2;
 372         }
 373         else
 374         {
 375                 tsize = dist.x - 10;
 376                 isize = min(dist.y - 10, 0.75 * tsize);
 377         }
 378
 379         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 380
 381         if ( !gametypevote )
 382                 pos.x += dist.x / 2;
 383         pos.y += (dist.y - isize) / 2;
 384         ymax -= isize;
 385
 386         if (mv_top2_time)
 387                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 388
 389         void (vector, float, float, string, string, float, float) DrawItem;
 390
 391         if(gametypevote)
 392                 DrawItem = GameTypeVote_DrawGameTypeItem;
 393         else
 394                 DrawItem = MapVote_DrawMapItem;
 395
 396         for(i = 0; i < mv_num_maps; ++i)
 397         {
 398                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 399                 map = mv_maps[i];
 400                 if(mv_preview[i])
 401                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, mv_pics[i], tmp, i);
 402                 else
 403                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, "", tmp, i);
 404         }
 405
 406         if(mv_abstain)
 407                 ++mv_num_maps;
 408
 409         if(mv_abstain && i < mv_num_maps) {
 410                 tmp = mv_votes[i];
 411                 pos.y = ymax + isize - hud_fontsize.y;
 412                 pos.x = (xmax+xmin)*0.5;
 413                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 414         }
 415
 416         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 417 }
 418
 419 void Cmd_MapVote_MapDownload(float argc)
 420 {
 421         entity pak;
 422
 423         if(argc != 2 || !mv_pk3list)
 424         {
 425                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 426                 return;
 427         }
 428
 429         int id = stof(argv(1));
 430         for(pak = mv_pk3list; pak; pak = pak.chain)
 431                 if(pak.sv_entnum == id)
 432                         break;
 433
 434         if(!pak || pak.sv_entnum != id) {
 435                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 436                 return;
 437         }
 438
 439         if(PreviewExists(pak.message))
 440         {
 441                 mv_preview[id] = true;
 442                 return;
 443         } else {
 444                 print(_("Requesting preview...\n"));
 445                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 446         }
 447 }
 448
 449 void MapVote_CheckPK3(string pic, string pk3, int id)
 450 {
 451         entity pak;
 452         pak = spawn();
 453         pak.netname = pk3;
 454         pak.message = pic;
 455         pak.sv_entnum = id;
 456
 457         pak.chain = mv_pk3list;
 458         mv_pk3list = pak;
 459
 460         if(pk3 != "")
 461         {
 462                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 463         }
 464         else
 465         {
 466                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 467         }
 468 }
 469
 470 void MapVote_CheckPic(string pic, string pk3, int id)
 471 {
 472         // never try to retrieve a pic for the "don't care" 'map'
 473         if(mv_abstain && id == mv_num_maps - 1)
 474                 return;
 475
 476         if(PreviewExists(pic))
 477         {
 478                 mv_preview[id] = true;
 479                 return;
 480         }
 481         MapVote_CheckPK3(pic, pk3, id);
 482 }
 483
 484 void MapVote_ReadMask()
 485 {
 486         int i;
 487         if ( mv_num_maps < 24 )
 488         {
 489                 int mask, power;
 490                 if(mv_num_maps < 8)
 491                         mask = ReadByte();
 492                 else if(mv_num_maps < 16)
 493                         mask = ReadShort();
 494                 else
 495                         mask = ReadLong();
 496
 497                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 498                 {
 499                         if ( mask & power )
 500                                 mv_flags[i] |= GTV_AVAILABLE;
 501                         else
 502                                 mv_flags[i] &= ~GTV_AVAILABLE;
 503                 }
 504         }
 505         else
 506         {
 507                 for(i = 0; i < mv_num_maps; ++i )
 508                         mv_flags[i] = ReadByte();
 509         }
 510 }
 511
 512 void MapVote_ReadOption(int i)
 513 {
 514         string map = strzone(ReadString());
 515         string pk3 = strzone(ReadString());
 516         int j = bound(0, ReadByte(), n_ssdirs - 1);
 517
 518         mv_maps[i] = map;
 519         mv_pk3[i] = pk3;
 520         mv_flags[i] = GTV_AVAILABLE;
 521
 522         string pic = strzone(strcat(ssdirs[j], "/", map));
 523         mv_pics[i] = pic;
 524         mv_preview[i] = false;
 525         MapVote_CheckPic(pic, pk3, i);
 526 }
 527
 528 void GameTypeVote_ReadOption(int i)
 529 {
 530         string gt = strzone(ReadString());
 531
 532         mv_maps[i] = gt;
 533         mv_flags[i] = ReadByte();
 534
 535         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 536         if(precache_pic(mv_picpath) == "")
 537                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 538         string pic = strzone(mv_picpath);
 539         mv_pics[i] = pic;
 540         mv_preview[i] = PreviewExists(pic);
 541
 542         if ( mv_flags[i] & GTV_CUSTOM )
 543         {
 544                 mv_pk3[i] = strzone(ReadString()); // name
 545                 mv_desc[i] = strzone(ReadString()); // description
 546         }
 547         else
 548         {
 549                 int type = MapInfo_Type_FromString(gt);
 550                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 551                 mv_desc[i] = MapInfo_Type_Description(type);
 552         }
 553 }
 554
 555 void MapVote_Init()
 556 {
 557         precache_sound ("misc/invshot.wav");
 558
 559         mv_active = 1;
 560         if(autocvar_hud_cursormode) { setcursormode(1); }
 561         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 562         mv_selection = -1;
 563         mv_selection_keyboard = 0;
 564
 565         string s;
 566         for(n_ssdirs = 0; ; ++n_ssdirs)
 567         {
 568                 s = ReadString();
 569                 if(s == "")
 570                         break;
 571                 if(n_ssdirs < NUM_SSDIRS)
 572                         ssdirs[n_ssdirs] = s;
 573         }
 574         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 575
 576         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 577         mv_abstain = ReadByte();
 578         if(mv_abstain)
 579                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 580         mv_detail = ReadByte();
 581
 582         mv_ownvote = -1;
 583         mv_timeout = ReadCoord();
 584
 585         gametypevote = ReadByte();
 586
 587         float mv_real_num_maps = mv_num_maps - mv_abstain;
 588
 589         if(gametypevote)
 590         {
 591                 mapvote_chosenmap = strzone(ReadString());
 592                 if ( gametypevote == 2 )
 593                         gametypevote = 0;
 594
 595                 gtv_text_size = hud_fontsize*1.4;
 596                 gtv_text_size_small = hud_fontsize*1.1;
 597
 598                 if (mv_real_num_maps > 8 )
 599                         mv_columns = 3;
 600                 else
 601                         mv_columns = min(2, mv_real_num_maps);
 602     }
 603     else
 604         {
 605                 if (mv_real_num_maps > 16)
 606                         mv_columns = 5;
 607                 else if (mv_real_num_maps > 9)
 608                         mv_columns = 4;
 609                 else if(mv_real_num_maps > 3)
 610                         mv_columns = 3;
 611                 else
 612                         mv_columns = mv_real_num_maps;
 613         }
 614
 615         MapVote_ReadMask();
 616         int i;
 617         for(i = 0; i < mv_num_maps; ++i )
 618                 mv_flags_start[i] = mv_flags[i];
 619
 620         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 621         mv_pk3list = world; // I'm still paranoid!
 622
 623         for(i = 0; i < mv_num_maps; ++i)
 624         {
 625                 mv_votes[i] = 0;
 626
 627                 if ( gametypevote )
 628                         GameTypeVote_ReadOption(i);
 629                 else
 630                         MapVote_ReadOption(i);
 631         }
 632
 633         for(i = 0; i < n_ssdirs; ++i)
 634                 ssdirs[n_ssdirs] = string_null;
 635         n_ssdirs = 0;
 636 }
 637
 638 void MapVote_SendChoice(float index)
 639 {
 640         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 641 }
 642
 643 int MapVote_MoveLeft(int pos)
 644 {
 645         int imp;
 646         if ( pos < 0 )
 647                 imp = mv_num_maps - 1;
 648         else
 649                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 650         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 651                 imp = MapVote_MoveLeft(imp);
 652         return imp;
 653 }
 654 int MapVote_MoveRight(int pos)
 655 {
 656         int imp;
 657         if ( pos < 0 )
 658                 imp = 0;
 659         else
 660                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 661         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 662                 imp = MapVote_MoveRight(imp);
 663         return imp;
 664 }
 665 int MapVote_MoveUp(int pos)
 666 {
 667         int imp;
 668         if ( pos < 0 )
 669                 imp = mv_num_maps - 1;
 670         else
 671         {
 672                 imp = pos - mv_columns;
 673                 if ( imp < 0 )
 674                 {
 675                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 676                         if ( imp >= mv_num_maps )
 677                                 imp -= mv_columns;
 678                 }
 679         }
 680         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 681                 imp = MapVote_MoveUp(imp);
 682         return imp;
 683 }
 684 int MapVote_MoveDown(int pos)
 685 {
 686         int imp;
 687         if ( pos < 0 )
 688                 imp = 0;
 689         else
 690         {
 691                 imp = pos + mv_columns;
 692                 if ( imp >= mv_num_maps )
 693                         imp = imp % mv_columns;
 694         }
 695         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 696                 imp = MapVote_MoveDown(imp);
 697         return imp;
 698 }
 699
 700 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 701 {
 702         float imp;
 703
 704         if (!mv_active)
 705                 return false;
 706
 707         if(bInputType == 3)
 708         {
 709                 mv_mousepos.x = nPrimary;
 710                 mv_mousepos.y = nSecondary;
 711                 mv_selection_keyboard = 0;
 712                 return true;
 713         }
 714
 715         if (bInputType != 0)
 716                 return false;
 717
 718         if ('0' <= nPrimary && nPrimary <= '9')
 719         {
 720                 imp = nPrimary - '0';
 721                 if (imp == 0) imp = 10;
 722                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 723                 return true;
 724         }
 725         switch(nPrimary)
 726         {
 727                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 728                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 729                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 730                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 731                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 732                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 733                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 734                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 735                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 736                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 737
 738                 case K_RIGHTARROW:
 739                         mv_selection_keyboard = 1;
 740                         mv_selection = MapVote_MoveRight(mv_selection);
 741                         return true;
 742                 case K_LEFTARROW:
 743                         mv_selection_keyboard = 1;
 744                         mv_selection = MapVote_MoveLeft(mv_selection);
 745                         return true;
 746                 case K_DOWNARROW:
 747                         mv_selection_keyboard = 1;
 748                         mv_selection = MapVote_MoveDown(mv_selection);
 749                         return true;
 750                 case K_UPARROW:
 751                         mv_selection_keyboard = 1;
 752                         mv_selection = MapVote_MoveUp(mv_selection);
 753                         return true;
 754                 case K_KP_ENTER:
 755                 case K_ENTER:
 756                 case K_SPACE:
 757                         if ( mv_selection_keyboard )
 758                                 MapVote_SendChoice(mv_selection);
 759                         return true;
 760         }
 761
 762         if (nPrimary == K_MOUSE1)
 763         {
 764                 mv_selection_keyboard = 0;
 765                 mv_selection = mv_mouse_selection;
 766                 if (mv_selection >= 0)
 767                 {
 768                         imp = min(mv_selection + 1, mv_num_maps);
 769                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 770                         return true;
 771                 }
 772         }
 773
 774         return false;
 775 }
 776
 777 void MapVote_UpdateMask()
 778 {
 779         MapVote_ReadMask();
 780         mv_top2_time = time;
 781 }
 782
 783 void MapVote_UpdateVotes()
 784 {
 785         int i;
 786         for(i = 0; i < mv_num_maps; ++i)
 787         {
 788                 if(mv_flags[i] & GTV_AVAILABLE)
 789                 {
 790                         if(mv_detail)
 791                                 mv_votes[i] = ReadByte();
 792                         else
 793                                 mv_votes[i] = 0;
 794                 }
 795                 else
 796                         mv_votes[i] = -1;
 797         }
 798
 799         mv_ownvote = ReadByte()-1;
 800 }
 801
 802 void Ent_MapVote()
 803 {
 804         int sf = ReadByte();
 805
 806         if(sf & 1)
 807                 MapVote_Init();
 808
 809         if(sf & 2)
 810                 MapVote_UpdateMask();
 811
 812         if(sf & 4)
 813                 MapVote_UpdateVotes();
 814 }
 815
 816 void Net_MapVote_Picture()
 817 {
 818         int type = ReadByte();
 819         mv_preview[type] = true;
 820         mv_pics[type] = strzone(ReadPicture());
 821 }