qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 string mv_maps[MAPVOTE_COUNT];
  16 string mv_pics[MAPVOTE_COUNT];
  17 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  18 string mv_desc[MAPVOTE_COUNT];
  19 float mv_preview[MAPVOTE_COUNT];
  20 float mv_votes[MAPVOTE_COUNT];
  21 float mv_flags[MAPVOTE_COUNT];
  22 float mv_flags_start[MAPVOTE_COUNT];
  23 entity mv_pk3list;
  24 float mv_abstain;
  25 float mv_ownvote;
  26 float mv_detail;
  27 float mv_timeout;
  28 float mv_top2_time;
  29 float mv_top2_alpha;
  30
  31 vector mv_mousepos;
  32 int mv_selection;
  33 int mv_columns;
  34 int mv_mouse_selection;
  35 int mv_selection_keyboard;
  36
  37 float gametypevote;
  38 string mapvote_chosenmap;
  39 vector gtv_text_size;
  40 vector gtv_text_size_small;
  41
  42 const int NUM_SSDIRS = 4;
  43 string ssdirs[NUM_SSDIRS];
  44 int n_ssdirs;
  45
  46 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  47 {
  48         string pre, post;
  49         pre = sprintf("%d. ", id+1);
  50         if(mv_detail)
  51         {
  52                 if(_count == 1)
  53                         post = _(" (1 vote)");
  54                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  55                         post = sprintf(_(" (%d votes)"), _count);
  56                 else
  57                         post = "";
  58         }
  59         else
  60                 post = "";
  61         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  62         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  63         return strcat(pre, map, post);
  64 }
  65
  66 vector MapVote_RGB(int id)
  67 {
  68         if(!(mv_flags[id] & GTV_AVAILABLE))
  69                 return '1 1 1';
  70         if(id == mv_ownvote)
  71                 return '0 1 0';
  72         else if (id == mv_selection)
  73                 return '1 1 0';
  74         else
  75                 return '1 1 1';
  76 }
  77
  78 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  79 {
  80         // Find the correct alpha
  81         float alpha;
  82         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  83                 alpha = 0.2; // The gametype isn't supported by the map
  84         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  85                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  86         else
  87                 alpha = 1; // Normal, full alpha
  88
  89         // Bounding box details
  90         float rect_margin = hud_fontsize.y / 2;
  91
  92         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
  93         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
  94         maxh -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  95         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
  96
  97         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  98         vector rect_size = '1 1 0';
  99         rect_size.x = tsize + rect_margin;
 100         rect_size.y = maxh + rect_margin;
 101
 102         // Highlight selected item
 103         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 104         {
 105                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 106         }
 107
 108         // Highlight current vote
 109         vector rgb = MapVote_RGB(id);
 110         if(id == mv_ownvote)
 111         {
 112                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 113                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 114         }
 115
 116         vector offset = pos;
 117
 118         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 119         pos.y += title_gap;
 120         maxh -= title_gap;
 121
 122         // Evaluate the image size
 123         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 124         if ( maxh < image_size.y )
 125                 image_size = '1 1 0' * maxh;
 126         image_size *= 0.8;
 127         float desc_padding = gtv_text_size.x * 0.6;
 128         pos.x += image_size.x + desc_padding;
 129         tsize -= image_size.x + desc_padding;
 130
 131         // Split the description into lines
 132         entity title;
 133         title = spawn();
 134         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 135
 136         string thelabel = mv_desc[id], ts;
 137         entity last = title;
 138         entity next = world;
 139         float nlines = 0;
 140         if( thelabel != "")
 141         {
 142                 float i,n = tokenizebyseparator(thelabel, "\n");
 143                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 144                 {
 145                         getWrappedLine_remaining = argv(i);
 146                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 147                         {
 148                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 149                                 if (ts != "")
 150                                 {
 151                                         next = spawn();
 152                                         next.message = ts;
 153                                         next.origin = pos-offset;
 154                                         last.chain = next;
 155                                         last = next;
 156                                         pos.y += gtv_text_size_small.y;
 157                                         nlines++;
 158                                 }
 159                         }
 160                 }
 161         }
 162
 163         // Center the contents in the bounding box
 164         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 165         if ( maxh > 0 )
 166                 offset.y += maxh/2;
 167
 168         // Draw the title
 169         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 170
 171         // Draw the icon
 172         if(pic != "")
 173                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 174
 175         // Draw the description
 176         for ( last = title.chain; last ; )
 177         {
 178                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 179                 next = last;
 180                 last = last.chain;
 181                 remove(next);
 182         }
 183
 184         // Cleanup
 185         remove(title);
 186 }
 187
 188 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 189 {
 190         vector img_size = '0 0 0';
 191         string label;
 192         float text_size;
 193
 194         float rect_margin = hud_fontsize.y / 2;
 195
 196         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
 197         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
 198         isize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
 199         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
 200
 201         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 202         vector rect_size = '1 1 0';
 203         rect_size.x = tsize + rect_margin;
 204         rect_size.y = isize + rect_margin;
 205
 206         float img_ar = 4/3;
 207         img_size.x = min(tsize, isize * img_ar);
 208         img_size.y = img_size.x / img_ar;
 209         img_size.y -= hud_fontsize.y;
 210         img_size.x = img_size.y * img_ar;
 211
 212         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 213
 214         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 215
 216         text_size = stringwidth(label, false, hud_fontsize);
 217
 218         float save_rect_sizex = rect_size.x;
 219         rect_size.x = max(img_size.x, text_size) + rect_margin;
 220         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 221
 222         vector text_pos = '0 0 0';
 223         text_pos.x = pos.x + (tsize - text_size) / 2;
 224         text_pos.y = pos.y + img_size.y;
 225
 226         pos.x += (tsize - img_size.x) / 2;
 227
 228         float theAlpha;
 229         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 230                 theAlpha = mv_top2_alpha;
 231         else
 232                 theAlpha = 1;
 233
 234         // Highlight selected item
 235         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 236                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 237
 238         // Highlight current vote
 239         vector rgb = MapVote_RGB(id);
 240         if(id == mv_ownvote)
 241         {
 242                 drawfill(rect_pos, rect_size, rgb, 0.1*theAlpha, DRAWFLAG_NORMAL);
 243                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 244         }
 245
 246         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 247
 248         if(pic == "")
 249         {
 250                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 251         }
 252         else
 253         {
 254                 if(drawgetimagesize(pic) == '0 0 0')
 255                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 256                 else
 257                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 258         }
 259 }
 260
 261 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 262 {
 263         vector rgb;
 264         float text_size;
 265         string label;
 266
 267         rgb = MapVote_RGB(id);
 268
 269         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 270
 271         text_size = stringwidth(label, false, hud_fontsize);
 272
 273         pos.x -= text_size*0.5;
 274         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 275 }
 276
 277 vector MapVote_GridVec(vector gridspec, int i, int m)
 278 {
 279         int r = i % m;
 280         return
 281                 '1 0 0' * (gridspec.x * r)
 282                 +
 283                 '0 1 0' * (gridspec.y * (i - r) / m);
 284 }
 285
 286 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 287 {
 288
 289         float c, r;
 290
 291         mv_mouse_selection = -1;
 292
 293         for (r = 0; r < rows; ++r)
 294                 for (c = 0; c < columns; ++c)
 295                 {
 296                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 297                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 298                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 299                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 300                         {
 301                                 mv_mouse_selection = r * columns + c;
 302                                 break;
 303                         }
 304                 }
 305
 306         if (mv_mouse_selection >= mv_num_maps)
 307                 mv_mouse_selection = -1;
 308
 309         if (mv_abstain && mv_mouse_selection < 0)
 310                 mv_mouse_selection = mv_num_maps;
 311
 312         if ( mv_selection_keyboard )
 313                 return mv_selection;
 314
 315         return mv_mouse_selection;
 316 }
 317
 318 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 319 void MapVote_Draw()
 320 {
 321         string map;
 322         int i;
 323         float tmp;
 324         vector pos;
 325         float center;
 326         float rows;
 327         vector dist = '0 0 0';
 328
 329         //if(intermission != 2) return;
 330         if(!mv_active)
 331                 return;
 332
 333         if (!autocvar_hud_cursormode)
 334         {
 335                 vector mpos = mv_mousepos + getmousepos();
 336                 mpos.x = bound(0, mpos.x, vid_conwidth);
 337                 mpos.y = bound(0, mpos.y, vid_conheight);
 338
 339                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 340                         mv_selection_keyboard = 0;
 341                 mv_mousepos = mpos;
 342
 343         }
 344
 345         center = (vid_conwidth - 1)/2;
 346         xmin = vid_conwidth * 0.08;
 347         xmax = vid_conwidth - xmin;
 348         ymin = 20;
 349         ymax = vid_conheight - ymin;
 350
 351         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 352                 ymin += chat_sizey;
 353         else
 354                 ymax -= chat_sizey;
 355
 356         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 357
 358         pos.y = ymin;
 359         pos.z = 0;
 360
 361         draw_beginBoldFont();
 362
 363         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 364         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 365         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
 366         pos.y += hud_fontsize.y * 2;
 367
 368         if( mapvote_chosenmap != "" )
 369         {
 370                 pos.y += hud_fontsize.y * 0.25;
 371                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 372                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 373                 pos.y += hud_fontsize.y * 1.5;
 374                 pos.y += hud_fontsize.y * 0.5;
 375         }
 376         else
 377                 pos.y += hud_fontsize.y * 0.5;
 378
 379         draw_endBoldFont();
 380
 381         i = ceil(max(0, mv_timeout - time));
 382         map = sprintf(_("%d seconds left"), i);
 383         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 384         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
 385         pos.y += hud_fontsize.y * 1.5;
 386         pos.y += hud_fontsize.y * 0.5;
 387
 388         HUD_Panel_UpdateCvars();
 389
 390         // base for multi-column stuff...
 391         pos.y += hud_fontsize.y;
 392         pos.x = xmin;
 393         ymin = pos.y;
 394         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 395         if(mv_abstain)
 396         {
 397                 mv_num_maps -= 1;
 398                 ymax -= abstain_spacing;
 399         }
 400
 401         // higher than the image itself ratio for mapvote items to reserve space for long map names
 402         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 403         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 404         mv_columns = table_size.x;
 405         rows = table_size.y;
 406
 407         dist.x = (xmax - xmin) / mv_columns;
 408         dist.y = (ymax - pos.y) / rows;
 409
 410         // reduce size of too wide items
 411         tmp = vid_conwidth / 3; // max width
 412         if(dist.x > tmp)
 413         {
 414                 dist.x = tmp;
 415                 dist.y = min(dist.y, dist.x / item_aspect);
 416         }
 417         tmp = vid_conheight / 3; // max height
 418         if(dist.y > tmp)
 419         {
 420                 dist.y = tmp;
 421                 dist.x = min(dist.x, dist.y * item_aspect);
 422         }
 423
 424         // reduce size to fix aspect ratio
 425         if(dist.x / dist.y > item_aspect)
 426                 dist.x = dist.y * item_aspect;
 427         else
 428                 dist.y = dist.x / item_aspect;
 429
 430         // adjust table pos and size according to the new size
 431         float offset;
 432         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 433         xmin = pos.x += offset;
 434         xmax -= offset;
 435         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 436         ymax -= 2 * offset;
 437
 438         // override panel_pos and panel_size
 439         panel_pos.x = pos.x;
 440         panel_pos.y = pos.y;
 441         panel_size.x = xmax - xmin;
 442         panel_size.y = ymax - ymin;
 443         HUD_Panel_DrawBg(1);
 444
 445         if(panel_bg_padding)
 446         {
 447                 // FIXME item AR gets slightly changed here...
 448                 // it's rather hard to avoid it at this point
 449                 dist.x -= 2 * panel_bg_padding / mv_columns;
 450                 dist.y -= 2 * panel_bg_padding / rows;
 451                 xmin = pos.x += panel_bg_padding;
 452                 ymin = pos.y += panel_bg_padding;
 453                 xmax -= 2 * panel_bg_padding;
 454                 ymax -= 2 * panel_bg_padding;
 455         }
 456
 457         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 458
 459         if (mv_top2_time)
 460                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 461
 462         void (vector, float, float, string, string, float, float) DrawItem;
 463
 464         if(gametypevote)
 465                 DrawItem = GameTypeVote_DrawGameTypeItem;
 466         else
 467                 DrawItem = MapVote_DrawMapItem;
 468
 469         for(i = 0; i < mv_num_maps; ++i)
 470         {
 471                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 472                 map = mv_maps[i];
 473                 if(mv_preview[i])
 474                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 475                 else
 476                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 477         }
 478
 479         if(mv_abstain)
 480                 ++mv_num_maps;
 481
 482         if(mv_abstain && i < mv_num_maps) {
 483                 tmp = mv_votes[i];
 484                 pos.y = ymax + abstain_spacing;
 485                 pos.x = (xmax+xmin)*0.5;
 486                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 487         }
 488
 489         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 490 }
 491
 492 void Cmd_MapVote_MapDownload(float argc)
 493 {
 494         entity pak;
 495
 496         if(argc != 2 || !mv_pk3list)
 497         {
 498                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 499                 return;
 500         }
 501
 502         int id = stof(argv(1));
 503         for(pak = mv_pk3list; pak; pak = pak.chain)
 504                 if(pak.sv_entnum == id)
 505                         break;
 506
 507         if(!pak || pak.sv_entnum != id) {
 508                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 509                 return;
 510         }
 511
 512         if(PreviewExists(pak.message))
 513         {
 514                 mv_preview[id] = true;
 515                 return;
 516         } else {
 517                 print(_("Requesting preview...\n"));
 518                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 519         }
 520 }
 521
 522 void MapVote_CheckPK3(string pic, string pk3, int id)
 523 {
 524         entity pak;
 525         pak = spawn();
 526         pak.netname = pk3;
 527         pak.message = pic;
 528         pak.sv_entnum = id;
 529
 530         pak.chain = mv_pk3list;
 531         mv_pk3list = pak;
 532
 533         if(pk3 != "")
 534         {
 535                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 536         }
 537         else
 538         {
 539                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 540         }
 541 }
 542
 543 void MapVote_CheckPic(string pic, string pk3, int id)
 544 {
 545         // never try to retrieve a pic for the "don't care" 'map'
 546         if(mv_abstain && id == mv_num_maps - 1)
 547                 return;
 548
 549         if(PreviewExists(pic))
 550         {
 551                 mv_preview[id] = true;
 552                 return;
 553         }
 554         MapVote_CheckPK3(pic, pk3, id);
 555 }
 556
 557 void MapVote_ReadMask()
 558 {
 559         int i;
 560         if ( mv_num_maps < 24 )
 561         {
 562                 int mask, power;
 563                 if(mv_num_maps < 8)
 564                         mask = ReadByte();
 565                 else if(mv_num_maps < 16)
 566                         mask = ReadShort();
 567                 else
 568                         mask = ReadLong();
 569
 570                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 571                 {
 572                         if ( mask & power )
 573                                 mv_flags[i] |= GTV_AVAILABLE;
 574                         else
 575                                 mv_flags[i] &= ~GTV_AVAILABLE;
 576                 }
 577         }
 578         else
 579         {
 580                 for(i = 0; i < mv_num_maps; ++i )
 581                         mv_flags[i] = ReadByte();
 582         }
 583 }
 584
 585 void MapVote_ReadOption(int i)
 586 {
 587         string map = strzone(ReadString());
 588         string pk3 = strzone(ReadString());
 589         int j = bound(0, ReadByte(), n_ssdirs - 1);
 590
 591         mv_maps[i] = map;
 592         mv_pk3[i] = pk3;
 593         mv_flags[i] = GTV_AVAILABLE;
 594
 595         string pic = strzone(strcat(ssdirs[j], "/", map));
 596         mv_pics[i] = pic;
 597         mv_preview[i] = false;
 598         MapVote_CheckPic(pic, pk3, i);
 599 }
 600
 601 void GameTypeVote_ReadOption(int i)
 602 {
 603         string gt = strzone(ReadString());
 604
 605         mv_maps[i] = gt;
 606         mv_flags[i] = ReadByte();
 607
 608         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 609         if(precache_pic(mv_picpath) == "")
 610                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 611         string pic = strzone(mv_picpath);
 612         mv_pics[i] = pic;
 613         mv_preview[i] = PreviewExists(pic);
 614
 615         if ( mv_flags[i] & GTV_CUSTOM )
 616         {
 617                 string name = ReadString();
 618                 if ( strlen(name) < 1 )
 619                         name = gt;
 620                 mv_pk3[i] = strzone(name);
 621                 mv_desc[i] = strzone(ReadString());
 622         }
 623         else
 624         {
 625                 int type = MapInfo_Type_FromString(gt);
 626                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 627                 mv_desc[i] = MapInfo_Type_Description(type);
 628         }
 629 }
 630
 631 void MapVote_Init()
 632 {
 633         precache_sound ("misc/invshot.wav");
 634
 635         mv_active = 1;
 636         if(autocvar_hud_cursormode) { setcursormode(1); }
 637         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 638         mv_selection = -1;
 639         mv_selection_keyboard = 0;
 640
 641         string s;
 642         for(n_ssdirs = 0; ; ++n_ssdirs)
 643         {
 644                 s = ReadString();
 645                 if(s == "")
 646                         break;
 647                 if(n_ssdirs < NUM_SSDIRS)
 648                         ssdirs[n_ssdirs] = s;
 649         }
 650         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 651
 652         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 653         mv_abstain = ReadByte();
 654         if(mv_abstain)
 655                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 656         mv_detail = ReadByte();
 657
 658         mv_ownvote = -1;
 659         mv_timeout = ReadCoord();
 660
 661         gametypevote = ReadByte();
 662
 663         if(gametypevote)
 664         {
 665                 mapvote_chosenmap = strzone(ReadString());
 666                 if ( gametypevote == 2 )
 667                         gametypevote = 0;
 668
 669                 gtv_text_size = hud_fontsize*1.4;
 670                 gtv_text_size_small = hud_fontsize*1.1;
 671         }
 672
 673         MapVote_ReadMask();
 674         int i;
 675         for(i = 0; i < mv_num_maps; ++i )
 676                 mv_flags_start[i] = mv_flags[i];
 677
 678         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 679         mv_pk3list = world; // I'm still paranoid!
 680
 681         for(i = 0; i < mv_num_maps; ++i)
 682         {
 683                 mv_votes[i] = 0;
 684
 685                 if ( gametypevote )
 686                         GameTypeVote_ReadOption(i);
 687                 else
 688                         MapVote_ReadOption(i);
 689         }
 690
 691         for(i = 0; i < n_ssdirs; ++i)
 692                 ssdirs[n_ssdirs] = string_null;
 693         n_ssdirs = 0;
 694 }
 695
 696 void MapVote_SendChoice(float index)
 697 {
 698         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 699 }
 700
 701 int MapVote_MoveLeft(int pos)
 702 {
 703         int imp;
 704         if ( pos < 0 )
 705                 imp = mv_num_maps - 1;
 706         else
 707                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 708         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 709                 imp = MapVote_MoveLeft(imp);
 710         return imp;
 711 }
 712 int MapVote_MoveRight(int pos)
 713 {
 714         int imp;
 715         if ( pos < 0 )
 716                 imp = 0;
 717         else
 718                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 719         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 720                 imp = MapVote_MoveRight(imp);
 721         return imp;
 722 }
 723 int MapVote_MoveUp(int pos)
 724 {
 725         int imp;
 726         if ( pos < 0 )
 727                 imp = mv_num_maps - 1;
 728         else
 729         {
 730                 imp = pos - mv_columns;
 731                 if ( imp < 0 )
 732                 {
 733                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 734                         if ( imp >= mv_num_maps )
 735                                 imp -= mv_columns;
 736                 }
 737         }
 738         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 739                 imp = MapVote_MoveUp(imp);
 740         return imp;
 741 }
 742 int MapVote_MoveDown(int pos)
 743 {
 744         int imp;
 745         if ( pos < 0 )
 746                 imp = 0;
 747         else
 748         {
 749                 imp = pos + mv_columns;
 750                 if ( imp >= mv_num_maps )
 751                         imp = imp % mv_columns;
 752         }
 753         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 754                 imp = MapVote_MoveDown(imp);
 755         return imp;
 756 }
 757
 758 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 759 {
 760         float imp;
 761
 762         if (!mv_active)
 763                 return false;
 764
 765         if(bInputType == 3)
 766         {
 767                 mv_mousepos.x = nPrimary;
 768                 mv_mousepos.y = nSecondary;
 769                 mv_selection_keyboard = 0;
 770                 return true;
 771         }
 772
 773         if (bInputType != 0)
 774                 return false;
 775
 776         if ('0' <= nPrimary && nPrimary <= '9')
 777         {
 778                 imp = nPrimary - '0';
 779                 if (imp == 0) imp = 10;
 780                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 781                 return true;
 782         }
 783         switch(nPrimary)
 784         {
 785                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 786                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 787                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 788                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 789                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 790                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 791                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 792                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 793                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 794                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 795
 796                 case K_RIGHTARROW:
 797                         mv_selection_keyboard = 1;
 798                         mv_selection = MapVote_MoveRight(mv_selection);
 799                         return true;
 800                 case K_LEFTARROW:
 801                         mv_selection_keyboard = 1;
 802                         mv_selection = MapVote_MoveLeft(mv_selection);
 803                         return true;
 804                 case K_DOWNARROW:
 805                         mv_selection_keyboard = 1;
 806                         mv_selection = MapVote_MoveDown(mv_selection);
 807                         return true;
 808                 case K_UPARROW:
 809                         mv_selection_keyboard = 1;
 810                         mv_selection = MapVote_MoveUp(mv_selection);
 811                         return true;
 812                 case K_KP_ENTER:
 813                 case K_ENTER:
 814                 case K_SPACE:
 815                         if ( mv_selection_keyboard )
 816                                 MapVote_SendChoice(mv_selection);
 817                         return true;
 818         }
 819
 820         if (nPrimary == K_MOUSE1)
 821         {
 822                 mv_selection_keyboard = 0;
 823                 mv_selection = mv_mouse_selection;
 824                 if (mv_selection >= 0)
 825                 {
 826                         imp = min(mv_selection + 1, mv_num_maps);
 827                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 828                         return true;
 829                 }
 830         }
 831
 832         return false;
 833 }
 834
 835 void MapVote_UpdateMask()
 836 {
 837         MapVote_ReadMask();
 838         mv_top2_time = time;
 839 }
 840
 841 void MapVote_UpdateVotes()
 842 {
 843         int i;
 844         for(i = 0; i < mv_num_maps; ++i)
 845         {
 846                 if(mv_flags[i] & GTV_AVAILABLE)
 847                 {
 848                         if(mv_detail)
 849                                 mv_votes[i] = ReadByte();
 850                         else
 851                                 mv_votes[i] = 0;
 852                 }
 853                 else
 854                         mv_votes[i] = -1;
 855         }
 856
 857         mv_ownvote = ReadByte()-1;
 858 }
 859
 860 void Ent_MapVote()
 861 {
 862         int sf = ReadByte();
 863
 864         if(sf & 1)
 865                 MapVote_Init();
 866
 867         if(sf & 2)
 868                 MapVote_UpdateMask();
 869
 870         if(sf & 4)
 871                 MapVote_UpdateVotes();
 872 }
 873
 874 void Net_MapVote_Picture()
 875 {
 876         int type = ReadByte();
 877         mv_preview[type] = true;
 878         mv_pics[type] = strzone(ReadPicture());
 879 }