qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  93         vector rect_size = '1 1 0';
  94         rect_size.x = tsize + rect_margin;
  95         rect_size.y = maxh + rect_margin;
  96
  97         // Highlight selected item
  98         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
  99         {
 100                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 101         }
 102
 103         // Highlight current vote
 104         vector rgb = MapVote_RGB(id);
 105         if(id == mv_ownvote)
 106         {
 107                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 108                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 109         }
 110
 111         vector offset = pos;
 112
 113         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 114         pos.y += title_gap;
 115         maxh -= title_gap;
 116
 117         // Evaluate the image size
 118         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 119         if ( maxh < image_size.y )
 120                 image_size = '1 1 0' * maxh;
 121         image_size *= 0.8;
 122         float desc_padding = gtv_text_size.x * 0.6;
 123         pos.x += image_size.x + desc_padding;
 124         tsize -= image_size.x + desc_padding;
 125
 126         // Split the description into lines
 127         entity title;
 128         title = spawn();
 129         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 130
 131         string thelabel = mv_desc[id], ts;
 132         entity last = title;
 133         entity next = world;
 134         float nlines = 0;
 135         if( thelabel != "")
 136         {
 137                 float i,n = tokenizebyseparator(thelabel, "\n");
 138                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 139                 {
 140                         getWrappedLine_remaining = argv(i);
 141                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 142                         {
 143                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 144                                 if (ts != "")
 145                                 {
 146                                         next = spawn();
 147                                         next.message = ts;
 148                                         next.origin = pos-offset;
 149                                         last.chain = next;
 150                                         last = next;
 151                                         pos.y += gtv_text_size_small.y;
 152                                         nlines++;
 153                                 }
 154                         }
 155                 }
 156         }
 157
 158         // Center the contents in the bounding box
 159         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 160         if ( maxh > 0 )
 161                 offset.y += maxh/2;
 162
 163         // Draw the title
 164         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 165
 166         // Draw the icon
 167         if(pic != "")
 168                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 169
 170         // Draw the description
 171         for ( last = title.chain; last ; )
 172         {
 173                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 174                 next = last;
 175                 last = last.chain;
 176                 remove(next);
 177         }
 178
 179         // Cleanup
 180         remove(title);
 181 }
 182
 183 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 184 {
 185         vector img_size = '0 0 0';
 186         vector rgb;
 187         string label;
 188         float text_size;
 189
 190         isize -= hud_fontsize.y; // respect the text when calculating the image size
 191
 192         rgb = MapVote_RGB(id);
 193
 194         img_size.y = isize;
 195         img_size.x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
 196
 197         pos.y = pos.y + img_size.y;
 198
 199         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 200
 201         text_size = stringwidth(label, false, hud_fontsize);
 202
 203         float theAlpha;
 204         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 205                 theAlpha = mv_top2_alpha;
 206         else
 207                 theAlpha = 1;
 208
 209         pos.x -= text_size*0.5;
 210         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 211
 212         pos.x = pos.x + text_size*0.5 - img_size.x*0.5;
 213         pos.y = pos.y - img_size.y;
 214
 215         pos += autocvar_scoreboard_border_thickness * '1 1 0';
 216         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
 217         if(pic == "")
 218         {
 219                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 220         }
 221         else
 222         {
 223                 if(drawgetimagesize(pic) == '0 0 0')
 224                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 225                 else
 226                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 227         }
 228
 229         if(id == mv_ownvote)
 230                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 231         else
 232                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 233
 234         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 235                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 236 }
 237
 238 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 239 {
 240         vector rgb;
 241         float text_size;
 242         string label;
 243
 244         rgb = MapVote_RGB(id);
 245
 246         pos.y = pos.y + hud_fontsize.y;
 247
 248         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 249
 250         text_size = stringwidth(label, false, hud_fontsize);
 251
 252         pos.x -= text_size*0.5;
 253         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 254 }
 255
 256 vector MapVote_GridVec(vector gridspec, int i, int m)
 257 {
 258         int r = i % m;
 259         return
 260                 '1 0 0' * (gridspec.x * r)
 261                 +
 262                 '0 1 0' * (gridspec.y * (i - r) / m);
 263 }
 264
 265 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 266 {
 267
 268         float c, r;
 269
 270         mv_mouse_selection = -1;
 271
 272         for (r = 0; r < rows; ++r)
 273                 for (c = 0; c < columns; ++c)
 274                 {
 275                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 276                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 277                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 278                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 279                         {
 280                                 mv_mouse_selection = r * columns + c;
 281                                 break;
 282                         }
 283                 }
 284
 285         if (mv_mouse_selection >= mv_num_maps)
 286                 mv_mouse_selection = -1;
 287
 288         if (mv_abstain && mv_mouse_selection < 0)
 289                 mv_mouse_selection = mv_num_maps;
 290
 291         if ( mv_selection_keyboard )
 292                 return mv_selection;
 293
 294         return mv_mouse_selection;
 295 }
 296
 297 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 298 void MapVote_Draw()
 299 {
 300         string map;
 301         int i;
 302         float tmp;
 303         vector pos;
 304         float isize;
 305         float center;
 306         float rows;
 307         float tsize;
 308         vector dist = '0 0 0';
 309
 310         if(!mv_active)
 311                 return;
 312
 313         if (!autocvar_hud_cursormode)
 314         {
 315                 vector mpos = mv_mousepos + getmousepos();
 316                 mpos.x = bound(0, mpos.x, vid_conwidth);
 317                 mpos.y = bound(0, mpos.y, vid_conheight);
 318
 319                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 320                         mv_selection_keyboard = 0;
 321                 mv_mousepos = mpos;
 322
 323         }
 324
 325         center = (vid_conwidth - 1)/2;
 326         xmin = vid_conwidth*0.05; // 5% border must suffice
 327         xmax = vid_conwidth - xmin;
 328         ymin = 20;
 329         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 330         if(i < 0)
 331                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 332         if(i >= 0 || ymax < (vid_conheight*0.5))
 333                 ymax = vid_conheight - ymin;
 334
 335         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 336
 337         pos.y = ymin;
 338         pos.z = 0;
 339
 340         draw_beginBoldFont();
 341         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 342         pos.x = center - stringwidth(map, false, '12 0 0');
 343         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 344         pos.y += 26;
 345
 346         if( mapvote_chosenmap != "" )
 347         {
 348                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize*1.5/2);
 349                 drawstring(pos, mapvote_chosenmap, hud_fontsize*1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 350                 pos.y += hud_fontsize.y*2;
 351         }
 352
 353         i = ceil(max(0, mv_timeout - time));
 354         map = sprintf(_("%d seconds left"), i);
 355         pos.x = center - stringwidth(map, false, '8 0 0');
 356         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 357         pos.y += 22;
 358         pos.x = xmin;
 359         draw_endBoldFont();
 360
 361         // base for multi-column stuff...
 362         ymin = pos.y;
 363         if(mv_abstain)
 364                 mv_num_maps -= 1;
 365
 366         int item_aspect = (gametypevote) ? 2/1 : 4/3;
 367         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 368         mv_columns = table_size.x;
 369         rows = table_size.y;
 370
 371         dist.x = (xmax - xmin) / mv_columns;
 372         dist.y = (ymax - pos.y) / rows;
 373
 374         if ( gametypevote )
 375         {
 376                 tsize = dist.x - hud_fontsize.y;
 377                 isize = dist.y;
 378                 float maxheight = (ymax - pos.y) / 3;
 379                 if ( isize > maxheight )
 380                 {
 381                         pos.x += (isize - maxheight)/2;
 382                         isize = maxheight;
 383                 }
 384                 else
 385                         dist.y += hud_fontsize.y;
 386                 pos.x = ( vid_conwidth - dist.x * mv_columns ) / 2;
 387         }
 388         else
 389         {
 390                 tsize = dist.x - 10;
 391                 isize = min(dist.y - 10, 0.75 * tsize);
 392         }
 393
 394         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 395
 396         if ( !gametypevote )
 397                 pos.x += dist.x / 2;
 398         pos.y += (dist.y - isize) / 2;
 399         ymax -= isize;
 400
 401         if (mv_top2_time)
 402                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 403
 404         void (vector, float, float, string, string, float, float) DrawItem;
 405
 406         if(gametypevote)
 407                 DrawItem = GameTypeVote_DrawGameTypeItem;
 408         else
 409                 DrawItem = MapVote_DrawMapItem;
 410
 411         for(i = 0; i < mv_num_maps; ++i)
 412         {
 413                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 414                 map = mv_maps[i];
 415                 if(mv_preview[i])
 416                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, mv_pics[i], tmp, i);
 417                 else
 418                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, "", tmp, i);
 419         }
 420
 421         if(mv_abstain)
 422                 ++mv_num_maps;
 423
 424         if(mv_abstain && i < mv_num_maps) {
 425                 tmp = mv_votes[i];
 426                 pos.y = ymax + isize - hud_fontsize.y;
 427                 pos.x = (xmax+xmin)*0.5;
 428                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 429         }
 430
 431         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 432 }
 433
 434 void Cmd_MapVote_MapDownload(float argc)
 435 {
 436         entity pak;
 437
 438         if(argc != 2 || !mv_pk3list)
 439         {
 440                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 441                 return;
 442         }
 443
 444         int id = stof(argv(1));
 445         for(pak = mv_pk3list; pak; pak = pak.chain)
 446                 if(pak.sv_entnum == id)
 447                         break;
 448
 449         if(!pak || pak.sv_entnum != id) {
 450                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 451                 return;
 452         }
 453
 454         if(PreviewExists(pak.message))
 455         {
 456                 mv_preview[id] = true;
 457                 return;
 458         } else {
 459                 print(_("Requesting preview...\n"));
 460                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 461         }
 462 }
 463
 464 void MapVote_CheckPK3(string pic, string pk3, int id)
 465 {
 466         entity pak;
 467         pak = spawn();
 468         pak.netname = pk3;
 469         pak.message = pic;
 470         pak.sv_entnum = id;
 471
 472         pak.chain = mv_pk3list;
 473         mv_pk3list = pak;
 474
 475         if(pk3 != "")
 476         {
 477                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 478         }
 479         else
 480         {
 481                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 482         }
 483 }
 484
 485 void MapVote_CheckPic(string pic, string pk3, int id)
 486 {
 487         // never try to retrieve a pic for the "don't care" 'map'
 488         if(mv_abstain && id == mv_num_maps - 1)
 489                 return;
 490
 491         if(PreviewExists(pic))
 492         {
 493                 mv_preview[id] = true;
 494                 return;
 495         }
 496         MapVote_CheckPK3(pic, pk3, id);
 497 }
 498
 499 void MapVote_ReadMask()
 500 {
 501         int i;
 502         if ( mv_num_maps < 24 )
 503         {
 504                 int mask, power;
 505                 if(mv_num_maps < 8)
 506                         mask = ReadByte();
 507                 else if(mv_num_maps < 16)
 508                         mask = ReadShort();
 509                 else
 510                         mask = ReadLong();
 511
 512                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 513                 {
 514                         if ( mask & power )
 515                                 mv_flags[i] |= GTV_AVAILABLE;
 516                         else
 517                                 mv_flags[i] &= ~GTV_AVAILABLE;
 518                 }
 519         }
 520         else
 521         {
 522                 for(i = 0; i < mv_num_maps; ++i )
 523                         mv_flags[i] = ReadByte();
 524         }
 525 }
 526
 527 void MapVote_ReadOption(int i)
 528 {
 529         string map = strzone(ReadString());
 530         string pk3 = strzone(ReadString());
 531         int j = bound(0, ReadByte(), n_ssdirs - 1);
 532
 533         mv_maps[i] = map;
 534         mv_pk3[i] = pk3;
 535         mv_flags[i] = GTV_AVAILABLE;
 536
 537         string pic = strzone(strcat(ssdirs[j], "/", map));
 538         mv_pics[i] = pic;
 539         mv_preview[i] = false;
 540         MapVote_CheckPic(pic, pk3, i);
 541 }
 542
 543 void GameTypeVote_ReadOption(int i)
 544 {
 545         string gt = strzone(ReadString());
 546
 547         mv_maps[i] = gt;
 548         mv_flags[i] = ReadByte();
 549
 550         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 551         if(precache_pic(mv_picpath) == "")
 552                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 553         string pic = strzone(mv_picpath);
 554         mv_pics[i] = pic;
 555         mv_preview[i] = PreviewExists(pic);
 556
 557         if ( mv_flags[i] & GTV_CUSTOM )
 558         {
 559                 string name = ReadString();
 560                 if ( strlen(name) < 1 )
 561                         name = gt;
 562                 mv_pk3[i] = strzone(name);
 563                 mv_desc[i] = strzone(ReadString());
 564         }
 565         else
 566         {
 567                 int type = MapInfo_Type_FromString(gt);
 568                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 569                 mv_desc[i] = MapInfo_Type_Description(type);
 570         }
 571 }
 572
 573 void MapVote_Init()
 574 {
 575         precache_sound ("misc/invshot.wav");
 576
 577         mv_active = 1;
 578         if(autocvar_hud_cursormode) { setcursormode(1); }
 579         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 580         mv_selection = -1;
 581         mv_selection_keyboard = 0;
 582
 583         string s;
 584         for(n_ssdirs = 0; ; ++n_ssdirs)
 585         {
 586                 s = ReadString();
 587                 if(s == "")
 588                         break;
 589                 if(n_ssdirs < NUM_SSDIRS)
 590                         ssdirs[n_ssdirs] = s;
 591         }
 592         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 593
 594         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 595         mv_abstain = ReadByte();
 596         if(mv_abstain)
 597                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 598         mv_detail = ReadByte();
 599
 600         mv_ownvote = -1;
 601         mv_timeout = ReadCoord();
 602
 603         gametypevote = ReadByte();
 604
 605         if(gametypevote)
 606         {
 607                 mapvote_chosenmap = strzone(ReadString());
 608                 if ( gametypevote == 2 )
 609                         gametypevote = 0;
 610
 611                 gtv_text_size = hud_fontsize*1.4;
 612                 gtv_text_size_small = hud_fontsize*1.1;
 613         }
 614
 615         MapVote_ReadMask();
 616         int i;
 617         for(i = 0; i < mv_num_maps; ++i )
 618                 mv_flags_start[i] = mv_flags[i];
 619
 620         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 621         mv_pk3list = world; // I'm still paranoid!
 622
 623         for(i = 0; i < mv_num_maps; ++i)
 624         {
 625                 mv_votes[i] = 0;
 626
 627                 if ( gametypevote )
 628                         GameTypeVote_ReadOption(i);
 629                 else
 630                         MapVote_ReadOption(i);
 631         }
 632
 633         for(i = 0; i < n_ssdirs; ++i)
 634                 ssdirs[n_ssdirs] = string_null;
 635         n_ssdirs = 0;
 636 }
 637
 638 void MapVote_SendChoice(float index)
 639 {
 640         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 641 }
 642
 643 int MapVote_MoveLeft(int pos)
 644 {
 645         int imp;
 646         if ( pos < 0 )
 647                 imp = mv_num_maps - 1;
 648         else
 649                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 650         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 651                 imp = MapVote_MoveLeft(imp);
 652         return imp;
 653 }
 654 int MapVote_MoveRight(int pos)
 655 {
 656         int imp;
 657         if ( pos < 0 )
 658                 imp = 0;
 659         else
 660                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 661         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 662                 imp = MapVote_MoveRight(imp);
 663         return imp;
 664 }
 665 int MapVote_MoveUp(int pos)
 666 {
 667         int imp;
 668         if ( pos < 0 )
 669                 imp = mv_num_maps - 1;
 670         else
 671         {
 672                 imp = pos - mv_columns;
 673                 if ( imp < 0 )
 674                 {
 675                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 676                         if ( imp >= mv_num_maps )
 677                                 imp -= mv_columns;
 678                 }
 679         }
 680         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 681                 imp = MapVote_MoveUp(imp);
 682         return imp;
 683 }
 684 int MapVote_MoveDown(int pos)
 685 {
 686         int imp;
 687         if ( pos < 0 )
 688                 imp = 0;
 689         else
 690         {
 691                 imp = pos + mv_columns;
 692                 if ( imp >= mv_num_maps )
 693                         imp = imp % mv_columns;
 694         }
 695         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 696                 imp = MapVote_MoveDown(imp);
 697         return imp;
 698 }
 699
 700 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 701 {
 702         float imp;
 703
 704         if (!mv_active)
 705                 return false;
 706
 707         if(bInputType == 3)
 708         {
 709                 mv_mousepos.x = nPrimary;
 710                 mv_mousepos.y = nSecondary;
 711                 mv_selection_keyboard = 0;
 712                 return true;
 713         }
 714
 715         if (bInputType != 0)
 716                 return false;
 717
 718         if ('0' <= nPrimary && nPrimary <= '9')
 719         {
 720                 imp = nPrimary - '0';
 721                 if (imp == 0) imp = 10;
 722                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 723                 return true;
 724         }
 725         switch(nPrimary)
 726         {
 727                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 728                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 729                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 730                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 731                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 732                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 733                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 734                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 735                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 736                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 737
 738                 case K_RIGHTARROW:
 739                         mv_selection_keyboard = 1;
 740                         mv_selection = MapVote_MoveRight(mv_selection);
 741                         return true;
 742                 case K_LEFTARROW:
 743                         mv_selection_keyboard = 1;
 744                         mv_selection = MapVote_MoveLeft(mv_selection);
 745                         return true;
 746                 case K_DOWNARROW:
 747                         mv_selection_keyboard = 1;
 748                         mv_selection = MapVote_MoveDown(mv_selection);
 749                         return true;
 750                 case K_UPARROW:
 751                         mv_selection_keyboard = 1;
 752                         mv_selection = MapVote_MoveUp(mv_selection);
 753                         return true;
 754                 case K_KP_ENTER:
 755                 case K_ENTER:
 756                 case K_SPACE:
 757                         if ( mv_selection_keyboard )
 758                                 MapVote_SendChoice(mv_selection);
 759                         return true;
 760         }
 761
 762         if (nPrimary == K_MOUSE1)
 763         {
 764                 mv_selection_keyboard = 0;
 765                 mv_selection = mv_mouse_selection;
 766                 if (mv_selection >= 0)
 767                 {
 768                         imp = min(mv_selection + 1, mv_num_maps);
 769                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 770                         return true;
 771                 }
 772         }
 773
 774         return false;
 775 }
 776
 777 void MapVote_UpdateMask()
 778 {
 779         MapVote_ReadMask();
 780         mv_top2_time = time;
 781 }
 782
 783 void MapVote_UpdateVotes()
 784 {
 785         int i;
 786         for(i = 0; i < mv_num_maps; ++i)
 787         {
 788                 if(mv_flags[i] & GTV_AVAILABLE)
 789                 {
 790                         if(mv_detail)
 791                                 mv_votes[i] = ReadByte();
 792                         else
 793                                 mv_votes[i] = 0;
 794                 }
 795                 else
 796                         mv_votes[i] = -1;
 797         }
 798
 799         mv_ownvote = ReadByte()-1;
 800 }
 801
 802 void Ent_MapVote()
 803 {
 804         int sf = ReadByte();
 805
 806         if(sf & 1)
 807                 MapVote_Init();
 808
 809         if(sf & 2)
 810                 MapVote_UpdateMask();
 811
 812         if(sf & 4)
 813                 MapVote_UpdateVotes();
 814 }
 815
 816 void Net_MapVote_Picture()
 817 {
 818         int type = ReadByte();
 819         mv_preview[type] = true;
 820         mv_pics[type] = strzone(ReadPicture());
 821 }