qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15 float mv_top2_time;
  16 float mv_top2_alpha;
  17
  18 vector mv_mousepos;
  19 float mv_selection;
  20
  21 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)
  22 {
  23         string pre, post;
  24         pre = sprintf("%d. ", id+1);
  25         if(mv_detail)
  26         {
  27                 if(count == 1)
  28                         post = _(" (1 vote)");
  29                 else if(count >= 0)
  30                         post = sprintf(_(" (%d votes)"), count);
  31         }
  32         else
  33                 post = "";
  34         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);
  35         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  36         return strcat(pre, map, post);
  37 }
  38
  39 vector MapVote_RGB(float id, float count)
  40 {
  41         if(count < 0)
  42                 return '1 1 1';
  43         if(id == mv_ownvote)
  44                 return '0 1 0';
  45         else if (id == mv_selection)
  46                 return '1 1 0';
  47         else
  48                 return '1 1 1';
  49 }
  50
  51 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  52 {
  53         vector img_size;
  54         vector rgb;
  55         string label;
  56         float text_size;
  57
  58         isize -= hud_fontsize_y; // respect the text when calculating the image size
  59
  60         rgb = MapVote_RGB(id, count);
  61
  62         img_size_y = isize;
  63         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  64
  65         pos_y = pos_y + img_size_y;
  66
  67         label = MapVote_FormatMapItem(id, map, count, tsize, hud_fontsize);
  68
  69         text_size = stringwidth(label, false, hud_fontsize);
  70
  71         float theAlpha;
  72         if (count < 0 && mv_top2_alpha)
  73                 theAlpha = mv_top2_alpha;
  74         else
  75                 theAlpha = 1;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
  79
  80         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  81         pos_y = pos_y - img_size_y;
  82
  83         pos += autocvar_scoreboard_border_thickness * '1 1 0';
  84         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
  85         if(pic == "")
  86         {
  87                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
  88         }
  89         else
  90         {
  91                 if(precache_pic(pic) == "")
  92                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  93                 else
  94                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  95         }
  96
  97         if(id == mv_ownvote)
  98                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
  99         else
 100                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 101
 102         if(id == mv_selection && count >= 0)
 103                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 104 }
 105
 106 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
 107 {
 108         vector rgb;
 109         float text_size;
 110         string label;
 111
 112         rgb = MapVote_RGB(id, count);
 113
 114         pos_y = pos_y + hud_fontsize_y;
 115
 116         label = MapVote_FormatMapItem(id, _("Don't care"), count, tsize, hud_fontsize);
 117
 118         text_size = stringwidth(label, false, hud_fontsize);
 119
 120         pos_x -= text_size*0.5;
 121         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 122 }
 123
 124 vector MapVote_GridVec(vector gridspec, float i, float m)
 125 {
 126         float r;
 127         r = mod(i, m);
 128         return
 129                 '1 0 0' * (gridspec_x * r)
 130                 +
 131                 '0 1 0' * (gridspec_y * (i - r) / m);
 132 }
 133
 134 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 135 {
 136         float cell;
 137         float c, r;
 138
 139         cell = -1;
 140
 141         for (r = 0; r < rows; ++r)
 142                 for (c = 0; c < columns; ++c)
 143                 {
 144                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&
 145                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&
 146                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&
 147                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))
 148                         {
 149                                 cell = r * columns + c;
 150                                 break;
 151                         }
 152                 }
 153
 154         if (cell >= mv_num_maps)
 155                 cell = -1;
 156
 157         if (mv_abstain && cell < 0)
 158                 return mv_num_maps;
 159
 160         return cell;
 161 }
 162
 163 void MapVote_Draw()
 164 {
 165         string map;
 166         float i, tmp;
 167         vector pos;
 168         float isize;
 169         float center;
 170         float columns, rows;
 171         float tsize;
 172         vector dist;
 173
 174         if(!mv_active)
 175                 return;
 176
 177         mv_mousepos = mv_mousepos + getmousepos();
 178
 179         mv_mousepos_x = bound(0, mv_mousepos_x, vid_conwidth);
 180         mv_mousepos_y = bound(0, mv_mousepos_y, vid_conheight);
 181
 182         center = (vid_conwidth - 1)/2;
 183         xmin = vid_conwidth*0.05; // 5% border must suffice
 184         xmax = vid_conwidth - xmin;
 185         ymin = 20;
 186         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 187         if(i < 0)
 188                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 189         if(i >= 0 || ymax < (vid_conheight*0.5))
 190                 ymax = vid_conheight - ymin;
 191
 192         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 193
 194         pos_y = ymin;
 195         pos_z = 0;
 196
 197         map = _("Vote for a map");
 198         pos_x = center - stringwidth(map, false, '12 0 0');
 199         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 200         pos_y += 26;
 201
 202         i = ceil(max(0, mv_timeout - time));
 203         map = sprintf(_("%d seconds left"), i);
 204         pos_x = center - stringwidth(map, false, '8 0 0');
 205         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 206         pos_y += 22;
 207         pos_x = xmin;
 208
 209         // base for multi-column stuff...
 210         ymin = pos_y;
 211         if(mv_abstain)
 212                 mv_num_maps -= 1;
 213
 214         if(mv_num_maps > 3)
 215         {
 216                 columns = 3;
 217         } else {
 218                 columns = mv_num_maps;
 219         }
 220         rows = ceil(mv_num_maps / columns);
 221
 222         dist_x = (xmax - xmin) / columns;
 223         dist_y = (ymax - pos_y) / rows;
 224         tsize = dist_x - 10;
 225         isize = min(dist_y - 10, 0.75 * tsize);
 226
 227         mv_selection = MapVote_Selection(pos, dist, rows, columns);
 228
 229         pos_x += (xmax - xmin) / (2 * columns);
 230         pos_y += (dist_y - isize) / 2;
 231         ymax -= isize;
 232
 233         if (mv_top2_time)
 234                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 235
 236         for(i = 0; i < mv_num_maps; ++i)
 237         {
 238                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 239                 map = mv_maps[i];
 240                 if(mv_preview[i])
 241                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 242                 else
 243                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 244         }
 245
 246         if(mv_abstain)
 247                 ++mv_num_maps;
 248
 249         if(mv_abstain && i < mv_num_maps) {
 250                 tmp = mv_votes[i];
 251                 pos_y = ymax + isize - hud_fontsize_y;
 252                 pos_x = (xmax+xmin)*0.5;
 253                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 254         }
 255
 256         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', autocvar_hud_panel_fg_alpha, DRAWFLAG_NORMAL);
 257 }
 258
 259 void Cmd_MapVote_MapDownload(float argc)
 260 {
 261         float id;
 262         entity pak;
 263
 264         if(argc != 2 || !mv_pk3list)
 265         {
 266                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 267                 return;
 268         }
 269
 270         id = stof(argv(1));
 271         for(pak = mv_pk3list; pak; pak = pak.chain)
 272                 if(pak.sv_entnum == id)
 273                         break;
 274
 275         if(!pak || pak.sv_entnum != id) {
 276                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 277                 return;
 278         }
 279
 280         if(PreviewExists(pak.message))
 281         {
 282                 mv_preview[id] = true;
 283                 return;
 284         } else {
 285                 print(_("Requesting preview...\n"));
 286                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 287         }
 288 }
 289
 290 void MapVote_CheckPK3(string pic, string pk3, float id)
 291 {
 292         entity pak;
 293         pak = spawn();
 294         pak.netname = pk3;
 295         pak.message = pic;
 296         pak.sv_entnum = id;
 297
 298         pak.chain = mv_pk3list;
 299         mv_pk3list = pak;
 300
 301         if(pk3 != "")
 302         {
 303                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 304         }
 305         else
 306         {
 307                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 308         }
 309 }
 310
 311 void MapVote_CheckPic(string pic, string pk3, float id)
 312 {
 313         // never try to retrieve a pic for the "don't care" 'map'
 314         if(mv_abstain && id == mv_num_maps - 1)
 315                 return;
 316
 317         if(PreviewExists(pic))
 318         {
 319                 mv_preview[id] = true;
 320                 return;
 321         }
 322         MapVote_CheckPK3(pic, pk3, id);
 323 }
 324
 325 #define NUM_SSDIRS 4
 326 string ssdirs[NUM_SSDIRS];
 327 float n_ssdirs;
 328 void MapVote_Init()
 329 {
 330         float i, j, power;
 331         string map, pk3, s;
 332
 333         precache_sound ("misc/invshot.wav");
 334
 335         mv_active = 1;
 336
 337         mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 338         mv_selection = -1;
 339
 340         for(n_ssdirs = 0; ; ++n_ssdirs)
 341         {
 342                 s = ReadString();
 343                 if(s == "")
 344                         break;
 345                 if(n_ssdirs < NUM_SSDIRS)
 346                         ssdirs[n_ssdirs] = s;
 347         }
 348         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 349
 350         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 351         mv_abstain = ReadByte();
 352         if(mv_abstain)
 353                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 354         mv_detail = ReadByte();
 355
 356         mv_ownvote = -1;
 357         mv_timeout = ReadCoord();
 358
 359         if(mv_num_maps <= 8)
 360                 mv_maps_mask = ReadByte();
 361         else
 362                 mv_maps_mask = ReadShort();
 363
 364         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 365         mv_pk3list = world; // I'm still paranoid!
 366
 367         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 368         {
 369                 mv_votes[i] = 0;
 370
 371                 if(mv_maps_mask & power)
 372                 {
 373                         map = strzone(ReadString());
 374                         pk3 = strzone(ReadString());
 375                         j = bound(0, ReadByte(), n_ssdirs - 1);
 376
 377                         mv_maps[i] = map;
 378                         mv_pk3[i] = pk3;
 379                         map = strzone(strcat(ssdirs[j], "/", map));
 380                         mv_pics[i] = map;
 381
 382                         mv_preview[i] = false;
 383
 384                         MapVote_CheckPic(map, pk3, i);
 385                 }
 386                 else
 387                 {
 388                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 389                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 390                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 391                         mv_preview[i] = false;
 392                 }
 393         }
 394
 395         for(i = 0; i < n_ssdirs; ++i)
 396                 ssdirs[n_ssdirs] = string_null;
 397         n_ssdirs = 0;
 398 }
 399
 400 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 401 {
 402         float imp;
 403
 404         if (!mv_active)
 405                 return false;
 406
 407         if (bInputType != 0)
 408                 return false;
 409
 410         if ('0' <= nPrimary && nPrimary <= '9')
 411         {
 412                 imp = nPrimary - '0';
 413                 if (imp == 0) imp = 10;
 414                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 415                 return true;
 416         }
 417         switch(nPrimary)
 418         {
 419                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 420                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 421                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 422                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 423                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 424                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 425                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 426                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 427                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 428                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 429         }
 430
 431         if (nPrimary == K_MOUSE1)
 432                 if (mv_selection >= 0)
 433                 {
 434                         imp = min(mv_selection + 1, mv_num_maps);
 435                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 436                         return true;
 437                 }
 438
 439         return false;
 440 }
 441
 442 void MapVote_UpdateMask()
 443 {
 444         float i, power;
 445         float oldmask;
 446
 447         oldmask = mv_maps_mask;
 448         if(mv_num_maps <= 8)
 449                 mv_maps_mask = ReadByte();
 450         else
 451                 mv_maps_mask = ReadShort();
 452
 453         if(oldmask & mv_maps_mask != oldmask)
 454                 if(oldmask & mv_maps_mask == mv_maps_mask)
 455                          sound(world, CH_INFO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 456
 457         // remove votes that no longer apply
 458         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 459                 if not(mv_maps_mask & power)
 460                         mv_votes[i] = -1;
 461
 462         mv_top2_time = time;
 463 }
 464
 465 void MapVote_UpdateVotes()
 466 {
 467         float i, power;
 468         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 469         {
 470                 if(mv_maps_mask & power)
 471                 {
 472                         if(mv_detail)
 473                                 mv_votes[i] = ReadByte();
 474                         else
 475                                 mv_votes[i] = 0;
 476                 }
 477                 else
 478                         mv_votes[i] = -1;
 479         }
 480
 481         mv_ownvote = ReadByte()-1;
 482 }
 483
 484 void Ent_MapVote()
 485 {
 486         float sf;
 487
 488         sf = ReadByte();
 489
 490         if(sf & 1)
 491                 MapVote_Init();
 492
 493         if(sf & 2)
 494                 MapVote_UpdateMask();
 495
 496         if(sf & 4)
 497                 MapVote_UpdateVotes();
 498 }
 499
 500 void Net_MapVote_Picture()
 501 {
 502         float type;
 503         type = ReadByte();
 504         mv_preview[type] = true;
 505         mv_pics[type] = strzone(ReadPicture());
 506 }