qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "autocvars.qh"
   4 #include "main.qh"
   5 #include "miscfunctions.qh"
   6 #include "hud/_mod.qh"
   7 #include "hud/panel/scoreboard.qh"
   8
   9 #include <common/mapinfo.qh>
  10 #include <common/util.qh>
  11
  12 // MapVote (#21)
  13
  14 void MapVote_Draw_Export(int fh)
  15 {
  16         // allow saving cvars that aesthetically change the panel into hud skin files
  17         HUD_Write_Cvar("hud_panel_mapvote_highlight_border");
  18 }
  19
  20 int mv_num_maps;
  21
  22 string mv_maps[MAPVOTE_COUNT];
  23 string mv_pics[MAPVOTE_COUNT];
  24 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  25 string mv_desc[MAPVOTE_COUNT];
  26 float mv_preview[MAPVOTE_COUNT];
  27 float mv_votes[MAPVOTE_COUNT];
  28 float mv_flags[MAPVOTE_COUNT];
  29 float mv_flags_start[MAPVOTE_COUNT];
  30 entity mv_pk3list;
  31 float mv_abstain;
  32 float mv_ownvote;
  33 float mv_detail;
  34 float mv_timeout;
  35 float mv_top2_time;
  36 float mv_top2_alpha;
  37
  38 int mv_selection;
  39 int mv_columns;
  40 int mv_mouse_selection;
  41 int mv_selection_keyboard;
  42
  43 float gametypevote;
  44 string mapvote_chosenmap;
  45 vector gtv_text_size;
  46 vector gtv_text_size_small;
  47
  48 const int NUM_SSDIRS = 4;
  49 string ssdirs[NUM_SSDIRS];
  50 int n_ssdirs;
  51
  52 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  53 {
  54         TC(int, id);
  55         string pre, post;
  56         pre = sprintf("%d. ", id+1);
  57         if(mv_detail)
  58         {
  59                 if(_count == 1)
  60                         post = _(" (1 vote)");
  61                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  62                         post = sprintf(_(" (%d votes)"), _count);
  63                 else
  64                         post = "";
  65         }
  66         else
  67                 post = "";
  68         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  69         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  70         return strcat(pre, map, post);
  71 }
  72
  73 vector MapVote_RGB(int id)
  74 {
  75         TC(int, id);
  76         if(!(mv_flags[id] & GTV_AVAILABLE))
  77                 return '1 1 1';
  78         if(id == mv_ownvote)
  79                 return '0 1 0';
  80         else if (id == mv_selection)
  81                 return '1 1 0';
  82         else
  83                 return '1 1 1';
  84 }
  85
  86 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  87 {
  88         TC(int, id);
  89         // Find the correct alpha
  90         float alpha;
  91         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  92                 alpha = 0.2; // The gametype isn't supported by the map
  93         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  94                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  95         else
  96                 alpha = 1; // Normal, full alpha
  97         alpha *= panel_fg_alpha;
  98
  99         // Bounding box details
 100         float rect_margin = hud_fontsize.y / 2;
 101
 102         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 103         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 104         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 105         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 106
 107         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 108         vector rect_size = '1 1 0';
 109         rect_size.x = tsize + rect_margin;
 110         rect_size.y = maxh + rect_margin;
 111
 112         // Highlight selected item
 113         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 114         {
 115                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 116         }
 117
 118         // Highlight current vote
 119         vector rgb = MapVote_RGB(id);
 120         if(id == mv_ownvote)
 121         {
 122                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 123                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 124         }
 125
 126         vector offset = pos;
 127
 128         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 129         pos.y += title_gap;
 130         maxh -= title_gap;
 131
 132         // Evaluate the image size
 133         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 134         if ( maxh < image_size.y )
 135                 image_size = '1 1 0' * maxh;
 136         image_size *= 0.8;
 137         float desc_padding = gtv_text_size.x * 0.6;
 138         pos.x += image_size.x + desc_padding;
 139         tsize -= image_size.x + desc_padding;
 140
 141         // Split the description into lines
 142         entity title;
 143         title = spawn();
 144         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 145
 146         string thelabel = mv_desc[id], ts;
 147         entity last = title;
 148         entity next = NULL;
 149         float nlines = 0;
 150         if( thelabel != "")
 151         {
 152                 float i,n = tokenizebyseparator(thelabel, "\n");
 153                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 154                 {
 155                         getWrappedLine_remaining = argv(i);
 156                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 157                         {
 158                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 159                                 if (ts != "")
 160                                 {
 161                                         next = spawn();
 162                                         next.message = ts;
 163                                         next.origin = pos-offset;
 164                                         last.chain = next;
 165                                         last = next;
 166                                         pos.y += gtv_text_size_small.y;
 167                                         nlines++;
 168                                 }
 169                         }
 170                 }
 171         }
 172
 173         // Center the contents in the bounding box
 174         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 175         if ( maxh > 0 )
 176                 offset.y += maxh/2;
 177
 178         // Draw the title
 179         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 180
 181         // Draw the icon
 182         if(pic != "")
 183                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 184
 185         // Draw the description
 186         for ( last = title.chain; last ; )
 187         {
 188                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 189                 next = last;
 190                 last = last.chain;
 191                 delete(next);
 192         }
 193
 194         // Cleanup
 195         delete(title);
 196 }
 197
 198 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 199 {
 200         TC(int, id);
 201         vector img_size = '0 0 0';
 202         string label;
 203         float text_size;
 204
 205         float rect_margin = hud_fontsize.y / 2;
 206
 207         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 208         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 209         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 210         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 211
 212         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 213         vector rect_size = '1 1 0';
 214         rect_size.x = tsize + rect_margin;
 215         rect_size.y = isize + rect_margin;
 216
 217         float img_ar = 4/3;
 218         img_size.x = min(tsize, isize * img_ar);
 219         img_size.y = img_size.x / img_ar;
 220         img_size.y -= hud_fontsize.y;
 221         img_size.x = img_size.y * img_ar;
 222
 223         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 224
 225         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 226
 227         text_size = stringwidth(label, false, hud_fontsize);
 228
 229         float save_rect_sizex = rect_size.x;
 230         rect_size.x = max(img_size.x, text_size) + rect_margin;
 231         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 232
 233         vector text_pos = '0 0 0';
 234         text_pos.x = pos.x + (tsize - text_size) / 2;
 235         text_pos.y = pos.y + img_size.y;
 236
 237         pos.x += (tsize - img_size.x) / 2;
 238
 239         float theAlpha;
 240         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 241                 theAlpha = mv_top2_alpha;
 242         else
 243                 theAlpha = 1;
 244         theAlpha *= panel_fg_alpha;
 245
 246         // Highlight selected item
 247         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 248                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 249
 250         // Highlight current vote
 251         vector rgb = MapVote_RGB(id);
 252         if(id == mv_ownvote)
 253         {
 254                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 255                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 256         }
 257
 258         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 259
 260         if(pic == "")
 261         {
 262                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 263         }
 264         else
 265         {
 266                 if(drawgetimagesize(pic) == '0 0 0')
 267                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 268                 else
 269                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 270         }
 271 }
 272
 273 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 274 {
 275         TC(int, id);
 276         vector rgb;
 277         float text_size;
 278         string label;
 279
 280         rgb = MapVote_RGB(id);
 281
 282         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 283
 284         text_size = stringwidth(label, false, hud_fontsize);
 285
 286         pos.x -= text_size*0.5;
 287         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 288 }
 289
 290 vector MapVote_GridVec(vector gridspec, int i, int m)
 291 {
 292         TC(int, i); TC(int, m);
 293         int r = i % m;
 294         return
 295                 '1 0 0' * (gridspec.x * r)
 296                 +
 297                 '0 1 0' * (gridspec.y * (i - r) / m);
 298 }
 299
 300 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 301 {
 302
 303         float c, r;
 304
 305         mv_mouse_selection = -1;
 306
 307         for (r = 0; r < rows; ++r)
 308                 for (c = 0; c < columns; ++c)
 309                 {
 310                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
 311                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 312                                 mousepos.y >= topleft.y + cellsize.y *  r &&
 313                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
 314                         {
 315                                 mv_mouse_selection = r * columns + c;
 316                                 break;
 317                         }
 318                 }
 319
 320         if (mv_mouse_selection >= mv_num_maps)
 321                 mv_mouse_selection = -1;
 322
 323         if (mv_abstain && mv_mouse_selection < 0)
 324                 mv_mouse_selection = mv_num_maps;
 325
 326         if ( mv_selection_keyboard )
 327                 return mv_selection;
 328
 329         return mv_mouse_selection;
 330 }
 331
 332 vector prev_mousepos;
 333 // draws map vote or gametype vote
 334 void MapVote_Draw()
 335 {
 336         string map;
 337         int i;
 338         float tmp;
 339         vector pos;
 340         float center;
 341         float rows;
 342         vector dist = '0 0 0';
 343
 344         //if(intermission != 2) return;
 345         if(!mv_active)
 346                 return;
 347
 348         HUD_Panel_LoadCvars();
 349
 350         if (!autocvar_hud_cursormode)
 351         {
 352                 if (mousepos.x != prev_mousepos.x || mousepos.y != prev_mousepos.y)
 353                 {
 354                         mv_selection_keyboard = 0;
 355                         prev_mousepos = mousepos;
 356                 }
 357         }
 358
 359         center = (vid_conwidth - 1)/2;
 360         xmin = vid_conwidth * 0.08;
 361         xmax = vid_conwidth - xmin;
 362         ymin = 20;
 363         ymax = vid_conheight - ymin;
 364
 365         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 366                 ymin += chat_sizey;
 367         else
 368                 ymax -= chat_sizey;
 369
 370         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 371         if (gametypevote)
 372         {
 373                 gtv_text_size = hud_fontsize * 1.4;
 374                 gtv_text_size_small = hud_fontsize * 1.1;
 375         }
 376
 377         pos.y = ymin;
 378         pos.z = 0;
 379
 380         HUD_Scale_Disable();
 381         draw_beginBoldFont();
 382
 383         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 384         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 385         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 386         pos.y += hud_fontsize.y * 2;
 387
 388         if( mapvote_chosenmap != "" )
 389         {
 390                 pos.y += hud_fontsize.y * 0.25;
 391                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 392                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 393                 pos.y += hud_fontsize.y * 1.5;
 394         }
 395         pos.y += hud_fontsize.y * 0.5;
 396
 397         draw_endBoldFont();
 398
 399         i = ceil(max(0, mv_timeout - time));
 400         map = sprintf(_("%d seconds left"), i);
 401         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 402         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 403         pos.y += hud_fontsize.y * 1.5;
 404         pos.y += hud_fontsize.y * 0.5;
 405
 406         // base for multi-column stuff...
 407         pos.y += hud_fontsize.y;
 408         pos.x = xmin;
 409         ymin = pos.y;
 410         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 411         if(mv_abstain)
 412         {
 413                 mv_num_maps -= 1;
 414                 ymax -= abstain_spacing;
 415         }
 416
 417         // higher than the image itself ratio for mapvote items to reserve space for long map names
 418         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 419         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
 420         mv_columns = table_size.x;
 421         rows = table_size.y;
 422
 423         dist.x = (xmax - xmin) / mv_columns;
 424         dist.y = (ymax - pos.y) / rows;
 425
 426         // reduce size of too wide items
 427         tmp = vid_conwidth / 3; // max width
 428         if(dist.x > tmp)
 429         {
 430                 dist.x = tmp;
 431                 dist.y = min(dist.y, dist.x / item_aspect);
 432         }
 433         tmp = vid_conheight / 3; // max height
 434         if(dist.y > tmp)
 435         {
 436                 dist.y = tmp;
 437                 dist.x = min(dist.x, dist.y * item_aspect);
 438         }
 439
 440         // reduce size to fix aspect ratio
 441         if(dist.x / dist.y > item_aspect)
 442                 dist.x = dist.y * item_aspect;
 443         else
 444                 dist.y = dist.x / item_aspect;
 445
 446         // adjust table pos and size according to the new size
 447         float offset;
 448         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 449         xmin = pos.x += offset;
 450         xmax -= offset;
 451         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 452         ymax -= 2 * offset;
 453
 454         // override panel_pos and panel_size
 455         panel_pos.x = pos.x;
 456         panel_pos.y = pos.y;
 457         panel_size.x = xmax - xmin;
 458         panel_size.y = ymax - ymin;
 459         HUD_Panel_DrawBg();
 460
 461         if(panel_bg_padding)
 462         {
 463                 // FIXME item AR gets slightly changed here...
 464                 // it's rather hard to avoid it at this point
 465                 dist.x -= 2 * panel_bg_padding / mv_columns;
 466                 dist.y -= 2 * panel_bg_padding / rows;
 467                 xmin = pos.x += panel_bg_padding;
 468                 ymin = pos.y += panel_bg_padding;
 469                 xmax -= 2 * panel_bg_padding;
 470                 ymax -= 2 * panel_bg_padding;
 471         }
 472
 473         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 474
 475         if (mv_top2_time)
 476                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time) ** 2);
 477
 478         void (vector, float, float, string, string, float, float) DrawItem;
 479
 480         if(gametypevote)
 481                 DrawItem = GameTypeVote_DrawGameTypeItem;
 482         else
 483                 DrawItem = MapVote_DrawMapItem;
 484
 485         for(i = 0; i < mv_num_maps; ++i)
 486         {
 487                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 488                 map = mv_maps[i];
 489                 if(mv_preview[i])
 490                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 491                 else
 492                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 493         }
 494
 495         if(mv_abstain)
 496                 ++mv_num_maps;
 497
 498         if(mv_abstain && i < mv_num_maps) {
 499                 tmp = mv_votes[i];
 500                 pos.y = ymax + abstain_spacing;
 501                 pos.x = (xmax+xmin)*0.5;
 502                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 503         }
 504 }
 505
 506 void Cmd_MapVote_MapDownload(int argc)
 507 {
 508         TC(int, argc);
 509         entity pak;
 510
 511         if(argc != 2 || !mv_pk3list)
 512         {
 513                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
 514                 return;
 515         }
 516
 517         int id = stof(argv(1));
 518         for(pak = mv_pk3list; pak; pak = pak.chain)
 519                 if(pak.sv_entnum == id)
 520                         break;
 521
 522         if(!pak || pak.sv_entnum != id) {
 523                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
 524                 return;
 525         }
 526
 527         if(PreviewExists(pak.message))
 528         {
 529                 mv_preview[id] = true;
 530                 return;
 531         } else {
 532                 LOG_INFO(_("Requesting preview..."));
 533                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 534         }
 535 }
 536
 537 void MapVote_CheckPK3(string pic, string pk3, int id)
 538 {
 539         TC(int, id);
 540         entity pak;
 541         pak = spawn();
 542         pak.netname = pk3;
 543         pak.message = pic;
 544         pak.sv_entnum = id;
 545
 546         pak.chain = mv_pk3list;
 547         mv_pk3list = pak;
 548
 549         if(pk3 != "")
 550         {
 551                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 552         }
 553         else
 554         {
 555                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 556         }
 557 }
 558
 559 void MapVote_CheckPic(string pic, string pk3, int id)
 560 {
 561         TC(int, id);
 562         // never try to retrieve a pic for the "don't care" 'map'
 563         if(mv_abstain && id == mv_num_maps - 1)
 564                 return;
 565
 566         if(PreviewExists(pic))
 567         {
 568                 mv_preview[id] = true;
 569                 return;
 570         }
 571         MapVote_CheckPK3(pic, pk3, id);
 572 }
 573
 574 void MapVote_ReadMask()
 575 {
 576         int i;
 577         if ( mv_num_maps < 24 )
 578         {
 579                 int mask;
 580                 if(mv_num_maps < 8)
 581                         mask = ReadByte();
 582                 else if(mv_num_maps < 16)
 583                         mask = ReadShort();
 584                 else
 585                         mask = ReadLong();
 586
 587                 for(i = 0; i < mv_num_maps; ++i)
 588                 {
 589                         if (mask & BIT(i))
 590                                 mv_flags[i] |= GTV_AVAILABLE;
 591                         else
 592                                 mv_flags[i] &= ~GTV_AVAILABLE;
 593                 }
 594         }
 595         else
 596         {
 597                 for(i = 0; i < mv_num_maps; ++i )
 598                         mv_flags[i] = ReadByte();
 599         }
 600 }
 601
 602 void MapVote_ReadOption(int i)
 603 {
 604         TC(int, i);
 605         string map = strzone(ReadString());
 606         string pk3 = strzone(ReadString());
 607         int j = bound(0, ReadByte(), n_ssdirs - 1);
 608
 609         mv_maps[i] = map;
 610         mv_pk3[i] = pk3;
 611         mv_flags[i] = GTV_AVAILABLE;
 612
 613         string pic = strzone(strcat(ssdirs[j], "/", map));
 614         mv_pics[i] = pic;
 615         mv_preview[i] = false;
 616         MapVote_CheckPic(pic, pk3, i);
 617 }
 618
 619 void GameTypeVote_ReadOption(int i)
 620 {
 621         TC(int, i);
 622         string gt = strzone(ReadString());
 623
 624         mv_maps[i] = gt;
 625         mv_flags[i] = ReadByte();
 626
 627         string basetype = "";
 628
 629         if ( mv_flags[i] & GTV_CUSTOM )
 630         {
 631                 string name = ReadString();
 632                 if ( strlen(name) < 1 )
 633                         name = gt;
 634                 mv_pk3[i] = strzone(name);
 635                 mv_desc[i] = strzone(ReadString());
 636                 basetype = strzone(ReadString());
 637         }
 638         else
 639         {
 640                 Gametype type = MapInfo_Type_FromString(gt, false);
 641                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 642                 mv_desc[i] = MapInfo_Type_Description(type);
 643         }
 644
 645         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 646         if(precache_pic(mv_picpath) == "")
 647         {
 648                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 649                 if(precache_pic(mv_picpath) == "")
 650                 {
 651                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
 652                         if(precache_pic(mv_picpath) == "")
 653                         {
 654                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
 655                         }
 656                 }
 657         }
 658         string pic = strzone(mv_picpath);
 659         mv_pics[i] = pic;
 660         mv_preview[i] = PreviewExists(pic);
 661 }
 662
 663 void MapVote_Init()
 664 {
 665         mv_active = 1;
 666         if(!autocvar_hud_cursormode) mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 667         mv_selection = -1;
 668         mv_selection_keyboard = 0;
 669
 670         string s;
 671         for(n_ssdirs = 0; ; ++n_ssdirs)
 672         {
 673                 s = ReadString();
 674                 if(s == "")
 675                         break;
 676                 if(n_ssdirs < NUM_SSDIRS)
 677                         ssdirs[n_ssdirs] = s;
 678         }
 679         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 680
 681         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 682         mv_abstain = ReadByte();
 683         if(mv_abstain)
 684                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 685         mv_detail = ReadByte();
 686
 687         mv_ownvote = -1;
 688         mv_timeout = ReadCoord();
 689
 690         gametypevote = ReadByte();
 691
 692         if(gametypevote)
 693         {
 694                 mapvote_chosenmap = strzone(ReadString());
 695                 if ( gametypevote == 2 )
 696                         gametypevote = 0;
 697         }
 698
 699         MapVote_ReadMask();
 700         int i;
 701         for(i = 0; i < mv_num_maps; ++i )
 702                 mv_flags_start[i] = mv_flags[i];
 703
 704         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 705         mv_pk3list = NULL; // I'm still paranoid!
 706
 707         for(i = 0; i < mv_num_maps; ++i)
 708         {
 709                 mv_votes[i] = 0;
 710
 711                 if ( gametypevote )
 712                         GameTypeVote_ReadOption(i);
 713                 else
 714                         MapVote_ReadOption(i);
 715         }
 716
 717         for(i = 0; i < n_ssdirs; ++i)
 718                 ssdirs[n_ssdirs] = string_null;
 719         n_ssdirs = 0;
 720 }
 721
 722 void MapVote_SendChoice(int index)
 723 {
 724         TC(int, index);
 725         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 726 }
 727
 728 int MapVote_MoveLeft(int pos)
 729 {
 730         TC(int, pos);
 731         int imp;
 732         if ( pos < 0 )
 733                 imp = mv_num_maps - 1;
 734         else
 735                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 736         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 737                 imp = MapVote_MoveLeft(imp);
 738         return imp;
 739 }
 740 int MapVote_MoveRight(int pos)
 741 {
 742         TC(int, pos);
 743         int imp;
 744         if ( pos < 0 )
 745                 imp = 0;
 746         else
 747                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 748         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 749                 imp = MapVote_MoveRight(imp);
 750         return imp;
 751 }
 752 int MapVote_MoveUp(int pos)
 753 {
 754         TC(int, pos);
 755         int imp;
 756         if ( pos < 0 )
 757                 imp = mv_num_maps - 1;
 758         else
 759         {
 760                 imp = pos - mv_columns;
 761                 if ( imp < 0 )
 762                 {
 763                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 764                         if ( imp >= mv_num_maps )
 765                                 imp -= mv_columns;
 766                 }
 767         }
 768         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 769                 imp = MapVote_MoveUp(imp);
 770         return imp;
 771 }
 772 int MapVote_MoveDown(int pos)
 773 {
 774         TC(int, pos);
 775         int imp;
 776         if ( pos < 0 )
 777                 imp = 0;
 778         else
 779         {
 780                 imp = pos + mv_columns;
 781                 if ( imp >= mv_num_maps )
 782                         imp = imp % mv_columns;
 783         }
 784         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 785                 imp = MapVote_MoveDown(imp);
 786         return imp;
 787 }
 788
 789 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 790 {
 791         TC(int, bInputType);
 792
 793         static int first_digit = 0;
 794         if (!mv_active)
 795                 return false;
 796
 797         if(bInputType == 3)
 798         {
 799                 mousepos.x = nPrimary;
 800                 mousepos.y = nSecondary;
 801                 mv_selection_keyboard = 0;
 802                 return true;
 803         }
 804
 805         if (bInputType == 0)
 806         {
 807                 if (nPrimary == K_ALT) hudShiftState |= S_ALT;
 808                 if (nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 809                 if (nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 810         }
 811         else if (bInputType == 1)
 812         {
 813                 if (nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 814                 if (nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 815                 if (nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 816
 817                 if (nPrimary == K_CTRL)
 818                         first_digit = 0;
 819         }
 820
 821         if (bInputType != 0)
 822                 return false;
 823
 824         int imp = 0;
 825         switch(nPrimary)
 826         {
 827                 case K_RIGHTARROW:
 828                         mv_selection_keyboard = 1;
 829                         mv_selection = MapVote_MoveRight(mv_selection);
 830                         return true;
 831                 case K_LEFTARROW:
 832                         mv_selection_keyboard = 1;
 833                         mv_selection = MapVote_MoveLeft(mv_selection);
 834                         return true;
 835                 case K_DOWNARROW:
 836                         mv_selection_keyboard = 1;
 837                         mv_selection = MapVote_MoveDown(mv_selection);
 838                         return true;
 839                 case K_UPARROW:
 840                         mv_selection_keyboard = 1;
 841                         mv_selection = MapVote_MoveUp(mv_selection);
 842                         return true;
 843                 case K_KP_ENTER:
 844                 case K_ENTER:
 845                 case K_SPACE:
 846                         if ( mv_selection_keyboard )
 847                                 MapVote_SendChoice(mv_selection);
 848                         return true;
 849                 case '1': case K_KP_1: imp = 1; break;
 850                 case '2': case K_KP_2: imp = 2; break;
 851                 case '3': case K_KP_3: imp = 3; break;
 852                 case '4': case K_KP_4: imp = 4; break;
 853                 case '5': case K_KP_5: imp = 5; break;
 854                 case '6': case K_KP_6: imp = 6; break;
 855                 case '7': case K_KP_7: imp = 7; break;
 856                 case '8': case K_KP_8: imp = 8; break;
 857                 case '9': case K_KP_9: imp = 9; break;
 858                 case '0': case K_KP_0: imp = 10; break;
 859         }
 860
 861         if (imp && hudShiftState & S_CTRL)
 862         {
 863                 if (!first_digit)
 864                 {
 865                         first_digit = imp % 10;
 866                         return true;
 867                 }
 868                 else
 869                         imp = first_digit * 10 + (imp % 10);
 870         }
 871
 872         if (nPrimary == K_MOUSE1)
 873         {
 874                 mv_selection_keyboard = 0;
 875                 mv_selection = mv_mouse_selection;
 876                 if (mv_selection >= 0)
 877                         imp = min(mv_selection + 1, mv_num_maps);
 878         }
 879
 880         if (imp)
 881         {
 882                 if (imp <= mv_num_maps)
 883                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 884                 return true;
 885         }
 886
 887         return false;
 888 }
 889
 890 void MapVote_UpdateMask()
 891 {
 892         MapVote_ReadMask();
 893         mv_top2_time = time;
 894 }
 895
 896 void MapVote_UpdateVotes()
 897 {
 898         int i;
 899         for(i = 0; i < mv_num_maps; ++i)
 900         {
 901                 if(mv_flags[i] & GTV_AVAILABLE)
 902                 {
 903                         if(mv_detail)
 904                                 mv_votes[i] = ReadByte();
 905                         else
 906                                 mv_votes[i] = 0;
 907                 }
 908                 else
 909                         mv_votes[i] = -1;
 910         }
 911
 912         mv_ownvote = ReadByte()-1;
 913 }
 914
 915 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 916 {
 917         make_pure(this);
 918         int sf = ReadByte();
 919         return = true;
 920
 921         if(sf & 1)
 922                 MapVote_Init();
 923
 924         if(sf & 2)
 925                 MapVote_UpdateMask();
 926
 927         if(sf & 4)
 928                 MapVote_UpdateVotes();
 929 }
 930
 931 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 932 {
 933         Net_MapVote_Picture();
 934         return true;
 935 }
 936
 937 void Net_MapVote_Picture()
 938 {
 939         int type = ReadByte();
 940         mv_preview[type] = true;
 941         mv_pics[type] = strzone(ReadPicture());
 942 }