qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15
  16 vector mv_mousepos;
  17 float mv_selection;
  18
  19 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)
  20 {
  21         string pre, post;
  22         pre = strcat(ftos(id+1), ". ");
  23         if(mv_detail)
  24         {
  25                 if(count == 1)
  26                         post = strcat(" (1 vote)");
  27                 else
  28                         post = strcat(" (", ftos(count), " votes)");
  29         }
  30         else
  31                 post = "";
  32         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);
  33         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  34         return strcat(pre, map, post);
  35 }
  36
  37 vector MapVote_RGB(float id)
  38 {
  39         if(id == mv_ownvote)
  40                 return '0 1 0';
  41         else if (id == mv_selection)
  42                 return '1 1 0';
  43         else
  44                 return '1 1 1';
  45 }
  46
  47 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  48 {
  49         vector img_size;
  50         vector rgb;
  51         string label;
  52         float text_size;
  53
  54         isize -= hud_fontsize_y; // respect the text when calculating the image size
  55
  56         rgb = MapVote_RGB(id);
  57
  58         img_size_y = isize;
  59         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  60
  61         pos_y = pos_y + img_size_y;
  62
  63         label = MapVote_FormatMapItem(id, map, count, tsize, hud_fontsize);
  64
  65         text_size = stringwidth(label, false, hud_fontsize);
  66
  67         pos_x -= text_size*0.5;
  68         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  69
  70         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  71         pos_y = pos_y - img_size_y;
  72
  73         pos += autocvar_scoreboard_border_thickness * '1 1 0';
  74         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
  75         if(pic == "")
  76         {
  77                 drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  78         }
  79         else
  80         {
  81                 drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  82         }
  83
  84         if(id == mv_ownvote)
  85                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, 1, DRAWFLAG_NORMAL);
  86         else
  87                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', 1, DRAWFLAG_NORMAL);
  88
  89         if(id == mv_selection)
  90                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
  91 }
  92
  93 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
  94 {
  95         vector rgb;
  96         float text_size;
  97         string label;
  98
  99         rgb = MapVote_RGB(id);
 100
 101         pos_y = pos_y + hud_fontsize_y;
 102
 103         label = MapVote_FormatMapItem(id, "Don't care", count, tsize, hud_fontsize);
 104
 105         text_size = stringwidth(label, false, hud_fontsize);
 106
 107         pos_x -= text_size*0.5;
 108         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 109 }
 110
 111 vector MapVote_GridVec(vector gridspec, float i, float m)
 112 {
 113         float r;
 114         r = mod(i, m);
 115         return
 116                 '1 0 0' * (gridspec_x * r)
 117                 +
 118                 '0 1 0' * (gridspec_y * (i - r) / m);
 119 }
 120
 121 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 122 {
 123         float cell;
 124         float c, r;
 125
 126         cell = -1;
 127
 128         for (r = 0; r < rows; ++r)
 129                 for (c = 0; c < columns; ++c)
 130                 {
 131                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&
 132                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&
 133                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&
 134                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))
 135                         {
 136                                 cell = r * columns + c;
 137                                 break;
 138                         }
 139                 }
 140
 141         if (cell >= mv_num_maps)
 142                 cell = -1;
 143
 144         if (mv_abstain && cell < 0)
 145                 return mv_num_maps;
 146
 147         return cell;
 148 }
 149
 150 void MapVote_Draw()
 151 {
 152         string map;
 153         float i, tmp;
 154         vector pos;
 155         float isize;
 156         float center;
 157         float columns, rows;
 158         float tsize;
 159         vector dist;
 160
 161         if(!mv_active)
 162                 return;
 163
 164         mv_mousepos = mv_mousepos + getmousepos();
 165
 166         mv_mousepos_x = bound(0, mv_mousepos_x, vid_conwidth);
 167         mv_mousepos_y = bound(0, mv_mousepos_y, vid_conheight);
 168
 169         center = (vid_conwidth - 1)/2;
 170         xmin = vid_conwidth*0.05; // 5% border must suffice
 171         xmax = vid_conwidth - xmin;
 172         ymin = 20;
 173         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 174         if(i < 0)
 175                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 176         if(i >= 0 || ymax < (vid_conheight*0.5))
 177                 ymax = vid_conheight - ymin;
 178
 179         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 180
 181         pos_y = ymin;
 182         pos_z = 0;
 183         //pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 184         pos_x = center - stringwidth("Vote for a map", false, '12 0 0');
 185         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 186         pos_y += 26;
 187
 188         i = ceil(max(0, mv_timeout - time));
 189         map = strcat(ftos(i), " seconds left");
 190         //pos_x = center - stringwidth(map, false) * 0.5 * 16;
 191         pos_x = center - stringwidth(map, false, '8 0 0');
 192         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 193         pos_y += 22;
 194         pos_x = xmin;
 195
 196         // base for multi-column stuff...
 197         ymin = pos_y;
 198         if(mv_abstain)
 199                 mv_num_maps -= 1;
 200
 201         if(mv_num_maps > 3)
 202         {
 203                 columns = 3;
 204         } else {
 205                 columns = mv_num_maps;
 206         }
 207         rows = ceil(mv_num_maps / columns);
 208
 209         dist_x = (xmax - xmin) / columns;
 210         dist_y = (ymax - pos_y) / rows;
 211         tsize = dist_x - 10;
 212         isize = min(dist_y - 10, 0.75 * tsize);
 213
 214         mv_selection = MapVote_Selection(pos, dist, rows, columns);
 215
 216         pos_x += (xmax - xmin) / (2 * columns);
 217         pos_y += (dist_y - isize) / 2;
 218         ymax -= isize;
 219
 220         for(i = 0; i < mv_num_maps; ++i)
 221         {
 222                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 223                 if(tmp < 0)
 224                         continue;
 225                 map = mv_maps[i];
 226                 if(mv_preview[i])
 227                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 228                 else
 229                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 230         }
 231
 232         if(mv_abstain)
 233                 ++mv_num_maps;
 234
 235         if(mv_abstain && i < mv_num_maps) {
 236                 tmp = mv_votes[i];
 237                 pos_y = ymax + isize - hud_fontsize_y;
 238                 pos_x = (xmax+xmin)*0.5;
 239                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 240         }
 241
 242         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', autocvar_hud_panel_fg_alpha, DRAWFLAG_NORMAL);
 243 }
 244
 245 void Cmd_MapVote_MapDownload(float argc)
 246 {
 247         float id;
 248         entity pak;
 249
 250         if(argc != 2 || !mv_pk3list)
 251         {
 252                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 253                 return;
 254         }
 255
 256         id = stof(argv(1));
 257         for(pak = mv_pk3list; pak; pak = pak.chain)
 258                 if(pak.sv_entnum == id)
 259                         break;
 260
 261         if(!pak || pak.sv_entnum != id) {
 262                 print("^1Error:^7 Couldn't find pak index.\n");
 263                 return;
 264         }
 265
 266         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 267
 268         if(PreviewExists(pak.message))
 269         {
 270                 mv_preview[id] = true;
 271                 //print("^2Found...\n");
 272                 return;
 273         } else {
 274                 print("Requesting preview...\n");
 275                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 276         }
 277 }
 278
 279 void MapVote_CheckPK3(string pic, string pk3, float id)
 280 {
 281         entity pak;
 282         pak = spawn();
 283         pak.netname = pk3;
 284         pak.message = pic;
 285         pak.sv_entnum = id;
 286
 287         pak.chain = mv_pk3list;
 288         mv_pk3list = pak;
 289
 290         if(pk3 != "")
 291         {
 292                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 293         }
 294         else
 295         {
 296                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 297         }
 298 }
 299
 300 void MapVote_CheckPic(string pic, string pk3, float id)
 301 {
 302         // never try to retrieve a pic for the "don't care" 'map'
 303         if(mv_abstain && id == mv_num_maps - 1)
 304                 return;
 305
 306         if(PreviewExists(pic))
 307         {
 308                 mv_preview[id] = true;
 309                 return;
 310         }
 311         MapVote_CheckPK3(pic, pk3, id);
 312 }
 313
 314 #define NUM_SSDIRS 4
 315 string ssdirs[NUM_SSDIRS];
 316 float n_ssdirs;
 317 void MapVote_Init()
 318 {
 319         float i, j, power;
 320         string map, pk3, s;
 321
 322         precache_sound ("misc/invshot.wav");
 323
 324         mv_active = 1;
 325
 326         mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 327         mv_selection = -1;
 328
 329         for(n_ssdirs = 0; ; ++n_ssdirs)
 330         {
 331                 s = ReadString();
 332                 if(s == "")
 333                         break;
 334                 if(n_ssdirs < NUM_SSDIRS)
 335                         ssdirs[n_ssdirs] = s;
 336         }
 337         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 338
 339         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 340         mv_abstain = ReadByte();
 341         if(mv_abstain)
 342                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 343         mv_detail = ReadByte();
 344
 345         mv_ownvote = -1;
 346         mv_timeout = ReadCoord();
 347
 348         if(mv_num_maps <= 8)
 349                 mv_maps_mask = ReadByte();
 350         else
 351                 mv_maps_mask = ReadShort();
 352
 353         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 354         mv_pk3list = NULL; // I'm still paranoid!
 355
 356         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 357         {
 358                 mv_votes[i] = 0;
 359
 360                 if(mv_maps_mask & power)
 361                 {
 362                         map = strzone(ReadString());
 363                         pk3 = strzone(ReadString());
 364                         j = bound(0, ReadByte(), n_ssdirs - 1);
 365
 366                         mv_maps[i] = map;
 367                         mv_pk3[i] = pk3;
 368                         map = strzone(strcat(ssdirs[j], "/", map));
 369                         mv_pics[i] = map;
 370
 371                         mv_preview[i] = false;
 372
 373                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 374                         MapVote_CheckPic(map, pk3, i);
 375                 }
 376                 else
 377                 {
 378                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 379                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 380                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 381                         mv_preview[i] = false;
 382                 }
 383         }
 384
 385         for(i = 0; i < n_ssdirs; ++i)
 386                 ssdirs[n_ssdirs] = string_null;
 387         n_ssdirs = 0;
 388 }
 389
 390 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 391 {
 392         float imp;
 393
 394         if (!mv_active)
 395                 return false;
 396
 397         if (bInputType != 0)
 398                 return false;
 399
 400         if ('0' <= nPrimary && nPrimary <= '9')
 401         {
 402                 imp = nPrimary - '0';
 403                 if (imp == 0) imp = 10;
 404                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 405                 return true;
 406         }
 407
 408         if (nPrimary == K_MOUSE1)
 409                 if (mv_selection >= 0)
 410                 {
 411                         imp = min(mv_selection + 1, mv_num_maps);
 412                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 413                         return true;
 414                 }
 415
 416         return false;
 417 }
 418
 419 void MapVote_UpdateMask()
 420 {
 421         float i, power;
 422         float oldmask;
 423
 424         oldmask = mv_maps_mask;
 425         if(mv_num_maps <= 8)
 426                 mv_maps_mask = ReadByte();
 427         else
 428                 mv_maps_mask = ReadShort();
 429
 430         if(oldmask & mv_maps_mask != oldmask)
 431                 if(oldmask & mv_maps_mask == mv_maps_mask)
 432                          sound(world, CHAN_AUTO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 433
 434         // remove votes that no longer apply
 435         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 436                 if not(mv_maps_mask & power)
 437                         mv_votes[i] = -1;
 438 }
 439
 440 void MapVote_UpdateVotes()
 441 {
 442         float i, power;
 443         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 444         {
 445                 if(mv_maps_mask & power)
 446                 {
 447                         if(mv_detail)
 448                                 mv_votes[i] = ReadByte();
 449                         else
 450                                 mv_votes[i] = 0;
 451                 }
 452                 else
 453                         mv_votes[i] = -1;
 454         }
 455
 456         mv_ownvote = ReadByte()-1;
 457 }
 458
 459 void Ent_MapVote()
 460 {
 461         float sf;
 462
 463         sf = ReadByte();
 464
 465         if(sf & 1)
 466                 MapVote_Init();
 467
 468         if(sf & 2)
 469                 MapVote_UpdateMask();
 470
 471         if(sf & 4)
 472                 MapVote_UpdateVotes();
 473 }
 474
 475 void Net_MapVote_Picture()
 476 {
 477         float type;
 478         type = ReadByte();
 479         mv_preview[type] = true;
 480         mv_pics[type] = strzone(ReadPicture());
 481 }