]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/client/miscfunctions.qc
Move fexists from server/miscfunctions.qc to common/util.qc so that it's available...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / miscfunctions.qc
1 var float(string text, float handleColors, vector fontSize) stringwidth;
2
3 entity players;
4 entity teams;
5
6 void serverAnnouncer()
7 {
8         // check for pending announcement, play it and remove it
9         if(announce_snd != "")
10         {
11                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/", announce_snd, ".wav"), VOL_BASEVOICE, ATTN_NONE);
12                 strunzone(announce_snd);
13                 announce_snd = "";
14         }
15 }
16
17 void restartAnnouncer_Think() {
18         float countdown_rounded, countdown;
19         countdown = getstatf(STAT_GAMESTARTTIME) - time;
20         countdown_rounded = floor(0.5 + countdown);
21         if(countdown <= 0) {
22                 if (!spectatee_status) //do cprint only for players
23                         centerprint(_("^1Begin!"));
24
25                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/begin.wav"), VOL_BASEVOICE, ATTN_NONE);
26                 //reset maptime announcers now as well
27                 announcer_5min = announcer_1min = FALSE;
28
29                 remove(self);
30                 return;
31         }
32         else {
33                 if (!spectatee_status) //do cprint only for players
34                         centerprint(sprintf(_("^1Game starts in %d seconds"), countdown_rounded));
35
36                 if(countdown_rounded <= 3 && countdown_rounded >= 1) {
37                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/", ftos(countdown_rounded), ".wav"), VOL_BASEVOICE, ATTN_NONE);
38                 }
39
40                 self.nextthink = getstatf(STAT_GAMESTARTTIME) - (countdown - 1);
41         }
42 }
43
44 /**
45  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
46  */
47 void maptimeAnnouncer() {
48         float timelimit;
49         timelimit = getstatf(STAT_TIMELIMIT);
50         float timeleft;
51         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
52
53         float warmuplimit;
54         float warmuptimeleft;
55         if(warmup_stage) {
56                 warmuplimit = autocvar_g_warmup_limit;
57                 if(warmuplimit > 0) {
58                         warmuptimeleft = max(0, warmuplimit + getstatf(STAT_GAMESTARTTIME) - time); 
59                 }
60         }
61
62         //5 minute check
63         if (autocvar_cl_sound_maptime_warning >= 2) {
64                 //make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
65                 if(announcer_5min)
66                 {
67                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 300) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 300))
68                                 announcer_5min = FALSE;
69                 }
70                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 300 && warmuptimeleft > 299))
71                         //if we're in warmup mode, check whether there's a warmup timelimit
72                         if not (warmuplimit == -1 && warmup_stage) {
73                                 announcer_5min = TRUE;
74                                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"), VOL_BASEVOICE, ATTN_NONE);
75                         }
76         }
77
78         //1 minute check
79         if (autocvar_cl_sound_maptime_warning == 1 || autocvar_cl_sound_maptime_warning == 3) {
80                 if (announcer_1min)
81                 {
82                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 60))
83                                 announcer_1min = FALSE;
84                 }
85                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 60))
86                         //if we're in warmup mode, check whether there's a warmup timelimit
87                         if not (warmuplimit == -1 && warmup_stage) {
88                                 announcer_1min = TRUE;
89                                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"), VOL_BASEVOICE, ATTN_NONE);
90                         }
91         }
92 }
93
94 /**
95  * Announce carried items (e.g. flags in CTF).
96  */
97 float redflag_prev;
98 float blueflag_prev;
99 void carrierAnnouncer() {
100         float stat_items, redflag, blueflag;
101         float pickup;
102         string item;
103
104         if not(autocvar_cl_notify_carried_items)
105                 return;
106
107         stat_items = getstati(STAT_ITEMS);
108
109         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
110         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
111
112         if (redflag == 3 && redflag != redflag_prev) {
113                 item = _("^1RED^7 flag");
114                 pickup = (redflag_prev == 2);
115         }
116
117         if (blueflag == 3 && blueflag != blueflag_prev) {
118                 item = _("^4BLUE^7 flag");
119                 pickup = (blueflag_prev == 2);
120         }
121
122         if (item)
123         {
124                 if (pickup) {
125                         if (autocvar_cl_notify_carried_items & 2)
126                                 centerprint(sprintf(_("You picked up the %s!"), item));
127                 }
128                 else {
129                         if (autocvar_cl_notify_carried_items & 1)
130                                 centerprint(sprintf(_("You got the %s!"), item));
131                 }
132         }
133
134         blueflag_prev = blueflag;
135         redflag_prev = redflag;
136 }
137
138 /**
139  * Add all future announcer sounds precaches here.
140  * TODO: announcer queues
141  */
142 void Announcer_Precache () {
143         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
144         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
145
146         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
147         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
148         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
149         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
150         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
151         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
152         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
153         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
154         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
155         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
156         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
157         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
158         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
159         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
160         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
161
162         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
163         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
164         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
165         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
166         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
167         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
168         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
169
170         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
172         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
176         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
180
181         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
183
184         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
187 }
188
189 void AuditLists()
190 {
191         entity e;
192         entity prev;
193
194         prev = players;
195         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
196         {
197                 if(prev != e.sort_prev)
198                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
199         }
200
201         prev = teams;
202         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
203         {
204                 if(prev != e.sort_prev)
205                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
206         }
207 }
208
209
210 float RegisterPlayer(entity player)
211 {
212         entity pl;
213         AuditLists();
214         for(pl = players.sort_next; pl; pl = pl.sort_next)
215                 if(pl == player)
216                         error("Player already registered!");
217         player.sort_next = players.sort_next;
218         player.sort_prev = players;
219         if(players.sort_next)
220                 players.sort_next.sort_prev = player;
221         players.sort_next = player;
222         AuditLists();
223         return true;
224 }
225
226 void RemovePlayer(entity player)
227 {
228         entity pl, parent;
229         AuditLists();
230         parent = players;
231         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
232                 parent = pl;
233
234         if(!pl)
235         {
236                 error("Trying to remove a player which is not in the playerlist!");
237                 return;
238         }
239         parent.sort_next = player.sort_next;
240         if(player.sort_next)
241                 player.sort_next.sort_prev = parent;
242         AuditLists();
243 }
244
245 void MoveToLast(entity e)
246 {
247         AuditLists();
248         other = e.sort_next;
249         while(other)
250         {
251                 SORT_SWAP(other, e);
252                 other = e.sort_next;
253         }
254         AuditLists();
255 }
256
257 float RegisterTeam(entity Team)
258 {
259         entity tm;
260         AuditLists();
261         for(tm = teams.sort_next; tm; tm = tm.sort_next)
262                 if(tm == Team)
263                         error("Team already registered!");
264         Team.sort_next = teams.sort_next;
265         Team.sort_prev = teams;
266         if(teams.sort_next)
267                 teams.sort_next.sort_prev = Team;
268         teams.sort_next = Team;
269         AuditLists();
270         return true;
271 }
272
273 void RemoveTeam(entity Team)
274 {
275         entity tm, parent;
276         AuditLists();
277         parent = teams;
278         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
279                 parent = tm;
280
281         if(!tm)
282         {
283                 print(_("Trying to remove a team which is not in the teamlist!"));
284                 return;
285         }
286         parent.sort_next = Team.sort_next;
287         if(Team.sort_next)
288                 Team.sort_next.sort_prev = parent;
289         AuditLists();
290 }
291
292 entity GetTeam(float Team, float add)
293 {
294         float num;
295         entity tm;
296         num = (Team == COLOR_SPECTATOR) ? 16 : Team;
297         if(teamslots[num])
298                 return teamslots[num];
299         if not(add)
300                 return NULL;
301         tm = spawn();
302         tm.team = Team;
303         teamslots[num] = tm;
304         RegisterTeam(tm);
305         return tm;
306 }
307
308 vector HUD_GetFontsize(string cvarname)
309 {
310         vector v;
311         v = stov(cvar_string(cvarname));
312         if(v_x == 0)
313                 v = '8 8 0';
314         if(v_y == 0)
315                 v_y = v_x;
316         v_z = 0;
317         return v;
318 }
319
320 float PreviewExists(string name)
321 {
322         float f;
323         string file;
324
325         if(autocvar_cl_readpicture_force)
326                 return false;
327
328         if (fexists(strcat(name, ".tga"))) return true;
329         if (fexists(strcat(name, ".png"))) return true;
330         if (fexists(strcat(name, ".jpg"))) return true;
331         if (fexists(strcat(name, ".pcx"))) return true;
332
333         return false;
334 }
335
336 vector rotate(vector v, float a)
337 {
338         vector w;
339         // FTEQCC SUCKS AGAIN
340         w_x =      v_x * cos(a) + v_y * sin(a);
341         w_y = -1 * v_x * sin(a) + v_y * cos(a);
342         return w;
343 }
344
345 float ColorTranslateMode;
346
347 string ColorTranslateRGB(string s)
348 {
349         if(ColorTranslateMode & 1)
350                 return strdecolorize(s);
351         else
352                 return s;
353 }
354
355 float cvar_or(string cv, float v)
356 {
357         string s;
358         s = cvar_string(cv);
359         if(s == "")
360                 return v;
361         else
362                 return stof(s);
363 }
364
365 vector project_3d_to_2d(vector vec)
366 {
367         vec = cs_project(vec);
368         if(cs_project_is_b0rked > 0)
369         {
370                 vec_x *= vid_conwidth / vid_width;
371                 vec_y *= vid_conheight / vid_height;
372         }
373         return vec;
374 }
375
376 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
377 {
378 }
379
380 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
381 {
382         return 1.2 / (1.2 - fadelerp);
383 }
384
385 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
386 {
387         boxsize_x *= boxxsizefactor; // easier interface for text
388         return boxsize * (0.5 * (1 - sz));
389 }
390
391 void drawborderlines(float thickness, vector pos, vector dim, vector color, float alpha, float drawflag)
392 {
393         vector line_dim;
394
395         // left and right lines
396         pos_x -= thickness;
397         line_dim_x = thickness;
398         line_dim_y = dim_y;
399         drawfill(pos, line_dim, color, alpha, drawflag);
400         drawfill(pos + (dim_x + thickness) * '1 0 0', line_dim, color, alpha, drawflag);
401
402         // upper and lower lines
403         pos_y -= thickness;
404         line_dim_x = dim_x + thickness * 2; // make upper and lower lines longer
405         line_dim_y = thickness;
406         drawfill(pos, line_dim, color, alpha, drawflag);
407         drawfill(pos + (dim_y + thickness) * '0 1 0', line_dim, color, alpha, drawflag);
408 }
409
410 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float alpha, float drawflag)
411 {
412         vector current_pos, end_pos, new_size, ratio;
413         end_pos = pos + area;
414
415         current_pos_y = pos_y;
416         while (current_pos_y < end_pos_y)
417         {
418                 current_pos_x = pos_x;
419                 while (current_pos_x < end_pos_x)
420                 {
421                         new_size_x = min(sz_x, end_pos_x - current_pos_x);
422                         new_size_y = min(sz_y, end_pos_y - current_pos_y);
423                         ratio_x = new_size_x / sz_x;
424                         ratio_y = new_size_y / sz_y;
425                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, alpha, drawflag);
426                         current_pos_x += sz_x;
427                 }
428                 current_pos_y += sz_y;
429         }
430 }
431
432 // drawpic wrapper to draw an image as large as possible with preserved aspect ratio into a box
433 var float _drawpic_imgaspect;
434 var float _drawpic_aspect;
435 var vector _drawpic_imgsize;
436 var vector _drawpic_sz;
437 var vector _drawpic_oldsz;
438 var string _drawpic_picpath;
439 #define drawpic_aspect(pos,pic,mySize,color,alpha,drawflag)\
440         do {\
441                 _drawpic_imgsize = drawgetimagesize(pic);\
442                 _drawpic_imgaspect = _drawpic_imgsize_x/_drawpic_imgsize_y;\
443                 _drawpic_oldsz = _drawpic_sz = mySize;\
444                 _drawpic_aspect = _drawpic_sz_x/_drawpic_sz_y;\
445                 if(_drawpic_aspect > _drawpic_imgaspect) {\
446                         _drawpic_sz_x = _drawpic_sz_y * _drawpic_imgaspect;\
447                         drawpic(pos + eX * (_drawpic_oldsz_x - _drawpic_sz_x) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
448                 } else {\
449                         _drawpic_sz_y = _drawpic_sz_x / _drawpic_imgaspect;\
450                         drawpic(pos + eY * (_drawpic_oldsz_y - _drawpic_sz_y) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
451                 }\
452         } while(0)
453
454 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
455 #define drawpic_aspect_skin(pos,pic,sz,color,alpha,drawflag)\
456         do{\
457                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
458                 if(precache_pic(_drawpic_picpath) == "") {\
459                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
460                 }\
461                 drawpic_aspect(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
462                 _drawpic_picpath = string_null;\
463         } while(0)
464
465 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
466 #define drawpic_skin(pos,pic,sz,color,alpha,drawflag)\
467         do{\
468                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
469                 if(precache_pic(_drawpic_picpath) == "") {\
470                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
471                 }\
472                 drawpic(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
473                 _drawpic_picpath = string_null;\
474         } while(0)
475
476 void drawpic_aspect_skin_expanding(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
477 {
478         float sz;
479         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
480
481         drawpic_skin(position + expandingbox_resize_centered_box_offset(sz, scale, 1), pic, scale * sz, rgb, alpha * (1 - fadelerp), flag);
482 }
483
484 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
485 {
486         drawpic_aspect_skin_expanding(position, pic, scale, rgb, alpha, flag, fadelerp);
487         drawpic_skin(position, pic, scale, rgb, alpha * fadelerp, flag);
488 }
489
490 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
491 void drawstring_aspect(vector pos, string text, vector sz, vector color, float alpha, float drawflag) {
492         vector textsize;
493         textsize = eX * stringwidth(text, FALSE, '1 1 1' * sz_y) + eY * sz_y;
494
495         float textaspect;
496         textaspect = textsize_x/textsize_y;
497
498         vector oldsz;
499         oldsz = sz;
500         float aspect;
501         aspect = sz_x/sz_y;
502
503         if(aspect > textaspect) {
504                 sz_x = sz_y * textaspect;
505                 drawstring(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag);
506         } else {
507                 sz_y = sz_x / textaspect; 
508                 drawstring(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag);
509         }
510 }
511
512 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
513 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float alpha, float drawflag) {
514         vector textsize;
515         textsize = eX * stringwidth(text, TRUE, '1 1 1' * sz_y) + eY * sz_y;
516
517         float textaspect;
518         textaspect = textsize_x/textsize_y;
519
520         vector oldsz;
521         oldsz = sz;
522         float aspect;
523         aspect = sz_x/sz_y;
524
525         if(aspect > textaspect) {
526                 sz_x = sz_y * textaspect;
527                 drawcolorcodedstring(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag);
528         } else {
529                 sz_y = sz_x / textaspect; 
530                 drawcolorcodedstring(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag);
531         }
532 }
533
534 vector drawfontscale;
535 void drawstring_expanding(vector position, string text, vector scale, vector rgb, float alpha, float flag, float fadelerp)
536 {
537         float sz;
538         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
539
540         drawfontscale = sz * '1 1 0';
541         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
542         drawstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, FALSE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), rgb, alpha * (1 - fadelerp), flag);
543         // width parameter:
544         //    (scale_x * sz / drawfontscale_x) * drawfontscale_x * SIZE1 / (scale_x * sz)
545         //    SIZE1
546         drawfontscale = '1 1 0';
547 }
548
549 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
550 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float alpha, float drawflag, float fadelerp) {
551         vector textsize;
552         textsize = eX * stringwidth(text, FALSE, '1 1 1' * sz_y) + eY * sz_y;
553
554         float textaspect;
555         textaspect = textsize_x/textsize_y;
556
557         vector oldsz;
558         oldsz = sz;
559         float aspect;
560         aspect = sz_x/sz_y;
561
562         if(aspect > textaspect) {
563                 sz_x = sz_y * textaspect;
564                 drawstring_expanding(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
565         } else {
566                 sz_y = sz_x / textaspect; 
567                 drawstring_expanding(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
568         }
569 }
570
571 void drawcolorcodedstring_expanding(vector position, string text, vector scale, float alpha, float flag, float fadelerp)
572 {
573         float sz;
574         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
575
576         drawfontscale = sz * '1 1 0';
577         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
578         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, TRUE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), alpha * (1 - fadelerp), flag);
579         drawfontscale = '1 1 0';
580 }
581
582 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float alpha, float drawflag, float fadelerp) {
583         vector textsize;
584         textsize = eX * stringwidth(text, TRUE, '1 1 1' * sz_y) + eY * sz_y;
585         
586         float textaspect;
587         textaspect = textsize_x/textsize_y;
588
589         vector oldsz;
590         oldsz = sz;
591         float aspect;
592         aspect = sz_x/sz_y;
593
594         if(aspect > textaspect) {
595                 sz_x = sz_y * textaspect;
596                 drawcolorcodedstring_expanding(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
597         } else {
598                 sz_y = sz_x / textaspect; 
599                 drawcolorcodedstring_expanding(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
600         }
601 }
602
603 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
604 float PolyDrawModelSurface(entity e, float i_s)
605 {
606         float i_t;
607         float n_t;
608         vector tri;
609         string tex;
610         tex = getsurfacetexture(e, i_s);
611         if not(tex)
612                 return 0; // this is beyond the last one
613         n_t = getsurfacenumtriangles(e, i_s);
614         for(i_t = 0; i_t < n_t; ++i_t)
615         {
616                 tri = getsurfacetriangle(e, i_s, i_t);
617                 R_BeginPolygon(tex, 0);
618                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_x), getsurfacepointattribute(e, i_s, tri_x, SPA_TEXCOORDS0), '1 1 1', 1);
619                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_y), getsurfacepointattribute(e, i_s, tri_y, SPA_TEXCOORDS0), '1 1 1', 1);
620                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_z), getsurfacepointattribute(e, i_s, tri_z, SPA_TEXCOORDS0), '1 1 1', 1);
621                 R_EndPolygon();
622         }
623         return 1;
624 }
625 void PolyDrawModel(entity e)
626 {
627         float i_s;
628         for(i_s = 0; ; ++i_s)
629                 if(!PolyDrawModelSurface(e, i_s))
630                         break;
631 }
632
633 void DrawCircleClippedPic(vector centre, float radius, string pic, float f, vector rgb, float a, float drawflag)
634 {
635         float x, y, q, d;
636         vector ringsize, v, t;
637         ringsize = radius * '1 1 0';
638
639         x = cos(f * 2 * M_PI);
640         y = sin(f * 2 * M_PI);
641         q = fabs(x) + fabs(y);
642         x /= q;
643         y /= q;
644
645         if(f >= 1)
646         {
647                 // draw full rectangle
648                 R_BeginPolygon(pic, drawflag);
649                         v = centre;                     t = '0.5 0.5 0';
650                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
651                         R_PolygonVertex(v, t, rgb, a);
652
653                         v = centre;                     t = '0.5 0.5 0';
654                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
655                         R_PolygonVertex(v, t, rgb, a);
656
657                         v = centre;                     t = '0.5 0.5 0';
658                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
659                         R_PolygonVertex(v, t, rgb, a);
660
661                         v = centre;                     t = '0.5 0.5 0';
662                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
663                         R_PolygonVertex(v, t, rgb, a);
664                 R_EndPolygon();
665
666                 d = q - 1;
667                 if(d > 0)
668                 {
669                         R_BeginPolygon(pic, drawflag);
670                                 v = centre;                     t = '0.5 0.5 0';
671                                 R_PolygonVertex(v, t, rgb, a);
672
673                                 v = centre;                     t = '0.5 0.5 0';
674                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
675                                 R_PolygonVertex(v, t, rgb, a);
676                 }
677         }
678         else if(f > 0.75)
679         {
680                 // draw upper and first triangle
681                 R_BeginPolygon(pic, drawflag);
682                         v = centre;                     t = '0.5 0.5 0';
683                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
684                         R_PolygonVertex(v, t, rgb, a);
685
686                         v = centre;                     t = '0.5 0.5 0';
687                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
688                         R_PolygonVertex(v, t, rgb, a);
689
690                         v = centre;                     t = '0.5 0.5 0';
691                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
692                         R_PolygonVertex(v, t, rgb, a);
693                 R_EndPolygon();
694                 R_BeginPolygon(pic, drawflag);
695                         v = centre;                     t = '0.5 0.5 0';
696                         R_PolygonVertex(v, t, rgb, a);
697
698                         v = centre;                     t = '0.5 0.5 0';
699                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
700                         R_PolygonVertex(v, t, rgb, a);
701
702                         v = centre;                     t = '0.5 0.5 0';
703                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
704                         R_PolygonVertex(v, t, rgb, a);
705
706                 d = q - 0.75;
707                 if(d <= 0)
708                         R_EndPolygon();
709         }
710         else if(f > 0.5)
711         {
712                 // draw upper triangle
713                 R_BeginPolygon(pic, drawflag);
714                         v = centre;                     t = '0.5 0.5 0';
715                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
716                         R_PolygonVertex(v, t, rgb, a);
717
718                         v = centre;                     t = '0.5 0.5 0';
719                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
720                         R_PolygonVertex(v, t, rgb, a);
721
722                         v = centre;                     t = '0.5 0.5 0';
723                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
724                         R_PolygonVertex(v, t, rgb, a);
725                 R_EndPolygon();
726
727                 d = q - 0.5;
728                 if(d > 0)
729                 {
730                         R_BeginPolygon(pic, drawflag);
731                                 v = centre;                     t = '0.5 0.5 0';
732                                 R_PolygonVertex(v, t, rgb, a);
733
734                                 v = centre;                     t = '0.5 0.5 0';
735                                 v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
736                                 R_PolygonVertex(v, t, rgb, a);
737                 }
738         }
739         else if(f > 0.25)
740         {
741                 // draw first triangle
742                 R_BeginPolygon(pic, drawflag);
743                         v = centre;                     t = '0.5 0.5 0';
744                         R_PolygonVertex(v, t, rgb, a);
745
746                         v = centre;                     t = '0.5 0.5 0';
747                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
748                         R_PolygonVertex(v, t, rgb, a);
749
750                         v = centre;                     t = '0.5 0.5 0';
751                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
752                         R_PolygonVertex(v, t, rgb, a);
753
754                 d = q - 0.25;
755                 if(d <= 0)
756                         R_EndPolygon();
757         }
758         else
759         {
760                 d = q;
761                 if(d > 0)
762                 {
763                         R_BeginPolygon(pic, drawflag);
764                                 v = centre;                     t = '0.5 0.5 0';
765                                 R_PolygonVertex(v, t, rgb, a);
766
767                                 v = centre;                     t = '0.5 0.5 0';
768                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
769                                 R_PolygonVertex(v, t, rgb, a);
770                 }
771         }
772
773         if(d > 0)
774         {
775                         v = centre;                     t = '0.5 0.5 0';
776                         v_x += x * 0.5 * ringsize_x;    t += x * '0.5 0.5 0';
777                         v_y += y * 0.5 * ringsize_y;    t += y * '0.5 -0.5 0';
778                         R_PolygonVertex(v, t, rgb, a);
779                 R_EndPolygon();
780         }
781 }