qcsrc/client/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "autocvars.qh"
   4 #include "defs.qh"
   5 #include "hud/_mod.qh"
   6
   7 #include <common/command/_mod.qh>
   8
   9 #include <common/teams.qh>
  10
  11 #include <lib/csqcmodel/cl_model.qh>
  12
  13
  14 void AuditLists()
  15 {
  16         entity e;
  17         entity prev;
  18
  19         prev = players;
  20         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
  21         {
  22                 if(prev != e.sort_prev)
  23                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
  24         }
  25
  26         prev = teams;
  27         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
  28         {
  29                 if(prev != e.sort_prev)
  30                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
  31         }
  32 }
  33
  34
  35 float RegisterPlayer(entity player)
  36 {
  37         entity pl;
  38         AuditLists();
  39         for(pl = players.sort_next; pl; pl = pl.sort_next)
  40                 if(pl == player)
  41                         error("Player already registered!");
  42         player.sort_next = players.sort_next;
  43         player.sort_prev = players;
  44         if(players.sort_next)
  45                 players.sort_next.sort_prev = player;
  46         players.sort_next = player;
  47         AuditLists();
  48         return true;
  49 }
  50
  51 void RemovePlayer(entity player)
  52 {
  53         entity pl, parent;
  54         AuditLists();
  55         parent = players;
  56         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
  57                 parent = pl;
  58
  59         if(!pl)
  60         {
  61                 error("Trying to remove a player which is not in the playerlist!");
  62                 return;
  63         }
  64         parent.sort_next = player.sort_next;
  65         if(player.sort_next)
  66                 player.sort_next.sort_prev = parent;
  67         AuditLists();
  68 }
  69
  70 void MoveToLast(entity e)
  71 {
  72         AuditLists();
  73         entity ent = e.sort_next;
  74         while(ent)
  75         {
  76                 SORT_SWAP(ent, e);
  77                 ent = e.sort_next;
  78         }
  79         AuditLists();
  80 }
  81
  82 float RegisterTeam(entity Team)
  83 {
  84         assert_once(Team.team, eprint(Team));
  85         entity tm;
  86         AuditLists();
  87         for(tm = teams.sort_next; tm; tm = tm.sort_next)
  88                 if(tm == Team)
  89                         error("Team already registered!");
  90         Team.sort_next = teams.sort_next;
  91         Team.sort_prev = teams;
  92         if(teams.sort_next)
  93                 teams.sort_next.sort_prev = Team;
  94         teams.sort_next = Team;
  95         if(Team.team && Team.team != NUM_SPECTATOR)
  96                 ++team_count;
  97         AuditLists();
  98         return true;
  99 }
 100
 101 void RemoveTeam(entity Team)
 102 {
 103         entity tm, parent;
 104         AuditLists();
 105         parent = teams;
 106         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 107                 parent = tm;
 108
 109         if(!tm)
 110         {
 111                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 112                 return;
 113         }
 114         parent.sort_next = Team.sort_next;
 115         if(Team.sort_next)
 116                 Team.sort_next.sort_prev = parent;
 117         if(Team.team && Team.team != NUM_SPECTATOR)
 118                 --team_count;
 119         AuditLists();
 120 }
 121
 122 entity GetTeam(int Team, bool add)
 123 {
 124         TC(int, Team); TC(bool, add);
 125         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 126         if(teamslots[num])
 127                 return teamslots[num];
 128         if (!add)
 129                 return NULL;
 130         entity tm = new_pure(team);
 131         tm.team = Team;
 132         teamslots[num] = tm;
 133         RegisterTeam(tm);
 134         return tm;
 135 }
 136
 137 vector HUD_GetFontsize(string cvarname)
 138 {
 139         vector v;
 140         v = stov(cvar_string(cvarname));
 141         if(v.x == 0)
 142                 v = '8 8 0';
 143         if(v.y == 0)
 144                 v.y = v.x;
 145         v.z = 0;
 146         return v;
 147 }
 148
 149 float PreviewExists(string name)
 150 {
 151         if(autocvar_cl_readpicture_force)
 152                 return false;
 153
 154         if (fexists(strcat(name, ".tga"))) return true;
 155         if (fexists(strcat(name, ".png"))) return true;
 156         if (fexists(strcat(name, ".jpg"))) return true;
 157         if (fexists(strcat(name, ".pcx"))) return true;
 158
 159         return false;
 160 }
 161
 162 // decolorizes and team colors the player name when needed
 163 string playername(string thename, float teamid)
 164 {
 165     TC(int, teamid);
 166     string t;
 167     if (teamplay)
 168     {
 169         t = Team_ColorCode(teamid);
 170         return strcat(t, strdecolorize(thename));
 171     }
 172     else
 173         return strdecolorize(thename);
 174 }
 175
 176 float cvar_or(string cv, float v)
 177 {
 178         string s;
 179         s = cvar_string(cv);
 180         if(s == "")
 181                 return v;
 182         else
 183                 return stof(s);
 184 }
 185
 186 vector project_3d_to_2d(vector vec)
 187 {
 188         vec = cs_project(vec);
 189         if(cs_project_is_b0rked > 0)
 190         {
 191                 vec.x *= vid_conwidth / vid_width;
 192                 vec.y *= vid_conheight / vid_height;
 193         }
 194         return vec;
 195 }
 196
 197 bool projected_on_screen(vector screen_pos)
 198 {
 199         return screen_pos.z >= 0
 200                 && screen_pos.x >= 0
 201                 && screen_pos.y >= 0
 202                 && screen_pos.x < vid_conwidth
 203                 && screen_pos.y < vid_conheight;
 204 }
 205
 206 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
 207 {
 208         return 1.2 / (1.2 - fadelerp);
 209 }
 210
 211 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
 212 {
 213         boxsize.x *= boxxsizefactor; // easier interface for text
 214         return boxsize * (0.5 * (1 - sz));
 215 }
 216
 217 // NOTE base is the central value
 218 // freq: circle frequency, = 2*pi*frequency in hertz
 219 float blink(float base, float range, float freq)
 220 {
 221         // note:
 222         //   RMS = sqrt(base^2 + 0.5 * range^2)
 223         // thus
 224         //   base = sqrt(RMS^2 - 0.5 * range^2)
 225         // ensure RMS == 1
 226
 227         return base + range * cos(time * freq);
 228 }
 229
 230 void drawborderlines(float thickness, vector pos, vector dim, vector color, float theAlpha, float drawflag)
 231 {
 232         vector line_dim = '0 0 0';
 233
 234         // left and right lines
 235         pos.x -= thickness;
 236         line_dim.x = thickness;
 237         line_dim.y = dim.y;
 238         drawfill(pos, line_dim, color, theAlpha, drawflag);
 239         drawfill(pos + (dim.x + thickness) * '1 0 0', line_dim, color, theAlpha, drawflag);
 240
 241         // upper and lower lines
 242         pos.y -= thickness;
 243         line_dim.x = dim.x + thickness * 2; // make upper and lower lines longer
 244         line_dim.y = thickness;
 245         drawfill(pos, line_dim, color, theAlpha, drawflag);
 246         drawfill(pos + (dim.y + thickness) * '0 1 0', line_dim, color, theAlpha, drawflag);
 247 }
 248
 249 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float theAlpha, float drawflag)
 250 {
 251         pos = HUD_Shift(pos);
 252         sz = HUD_Scale(sz);
 253         area = HUD_Scale(area);
 254
 255         vector current_pos = '0 0 0', end_pos, new_size = '0 0 0', ratio = '0 0 0';
 256         end_pos = pos + area;
 257
 258         current_pos.y = pos.y;
 259         while (current_pos.y < end_pos.y)
 260         {
 261                 current_pos.x = pos.x;
 262                 while (current_pos.x < end_pos.x)
 263                 {
 264                         new_size.x = min(sz.x, end_pos.x - current_pos.x);
 265                         new_size.y = min(sz.y, end_pos.y - current_pos.y);
 266                         ratio.x = new_size.x / sz.x;
 267                         ratio.y = new_size.y / sz.y;
 268                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, theAlpha, drawflag);
 269                         current_pos.x += sz.x;
 270                 }
 271                 current_pos.y += sz.y;
 272         }
 273 }
 274
 275 void drawpic_aspect_skin_expanding(vector position, string pic, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 276 {
 277         float sz;
 278         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 279
 280         drawpic_aspect_skin(position + expandingbox_resize_centered_box_offset(sz, theScale, 1), pic, theScale * sz, rgb, theAlpha * (1 - fadelerp), flag);
 281 }
 282
 283 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 284 {
 285         drawpic_aspect_skin_expanding(position, pic, theScale, rgb, theAlpha, flag, fadelerp);
 286         drawpic_skin(position, pic, theScale, rgb, theAlpha * fadelerp, flag);
 287 }
 288
 289 void HUD_Scale_Disable()
 290 {
 291         hud_scale = '1 1 0';
 292         hud_shift = '0 0 0';
 293         drawfontscale = hud_scale;
 294 }
 295
 296 void HUD_Scale_Enable()
 297 {
 298         hud_scale = hud_scale_current;
 299         hud_shift = hud_shift_current;
 300         drawfontscale = hud_scale;
 301 }
 302
 303 vector HUD_Scale(vector v)
 304 {
 305         v.x = HUD_ScaleX(v.x);
 306         v.y = HUD_ScaleY(v.y);
 307         return v;
 308 }
 309
 310 vector HUD_Shift(vector v)
 311 {
 312         v.x = HUD_ShiftX(v.x);
 313         v.y = HUD_ShiftY(v.y);
 314         return v;
 315 }
 316
 317 float stringwidth(string text, float handleColors, vector sz)
 318 {
 319         vector dfs = drawfontscale;
 320         drawfontscale = '1 1 0';
 321         float r = stringwidth_builtin(text, handleColors, sz);
 322         drawfontscale = dfs;
 323         return r;
 324 }
 325
 326 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 327 void drawstring_aspect(vector pos, string text, vector sz, vector color, float theAlpha, float drawflag) {
 328         SET_POS_AND_SZ_Y_ASPECT(false);
 329         drawstring(pos, text, '1 1 0' * sz.y, color, theAlpha, drawflag);
 330 }
 331
 332 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
 333 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float theAlpha, float drawflag) {
 334         SET_POS_AND_SZ_Y_ASPECT(true);
 335         drawcolorcodedstring(pos, text, '1 1 0' * sz.y, theAlpha, drawflag);
 336 }
 337
 338 void drawstring_expanding(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 339 {
 340         float sz;
 341         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 342
 343         drawfontscale = hud_scale * sz;
 344         vector dfs = drawfontscale;
 345         drawfontscale = sz * '1 1 0';
 346         float textaspect = stringwidth_builtin(text, false, theScale * (sz / drawfontscale.x)) / (theScale.x * sz);
 347         drawfontscale = dfs;
 348         drawstring(position + expandingbox_resize_centered_box_offset(sz, theScale, textaspect), text, HUD_Scale(theScale * (sz / drawfontscale.x)), rgb, theAlpha * (1 - fadelerp), flag);
 349         // width parameter:
 350         //    (scale_x * sz / drawfontscale.x) * drawfontscale.x * SIZE1 / (scale_x * sz)
 351         //    SIZE1
 352         drawfontscale = hud_scale;
 353 }
 354
 355 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 356 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float theAlpha, float drawflag, float fadelerp) {
 357         SET_POS_AND_SZ_Y_ASPECT(false);
 358         drawstring_expanding(pos, text, '1 1 0' * sz.y, color, theAlpha, drawflag, fadelerp);
 359 }
 360
 361 void drawcolorcodedstring_expanding(vector position, string text, vector theScale, float theAlpha, float flag, float fadelerp)
 362 {
 363         float sz;
 364         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 365
 366         drawfontscale = hud_scale * sz;
 367         // eventually replace with drawcolorcodedstring
 368         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, theScale, stringwidth_builtin(text, true, theScale * (sz / drawfontscale.x)) / (theScale.x * sz)), text, theScale * (sz / drawfontscale.x), theAlpha * (1 - fadelerp), flag);
 369         drawfontscale = hud_scale;
 370 }
 371
 372 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float theAlpha, float drawflag, float fadelerp) {
 373         SET_POS_AND_SZ_Y_ASPECT(true);
 374         drawcolorcodedstring_expanding(pos, text, '1 1 0' * sz.y, theAlpha, drawflag, fadelerp);
 375 }
 376
 377 void update_mousepos()
 378 {
 379         mousepos += getmousepos() * autocvar_menu_mouse_speed;
 380         mousepos.x = bound(0, mousepos.x, vid_conwidth);
 381         mousepos.y = bound(0, mousepos.y, vid_conheight);
 382 }
 383
 384 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
 385 float PolyDrawModelSurface(entity e, float i_s)
 386 {
 387         float i_t;
 388         float n_t;
 389         vector tri;
 390         string tex;
 391         tex = getsurfacetexture(e, i_s);
 392         if (!tex)
 393                 return 0; // this is beyond the last one
 394         n_t = getsurfacenumtriangles(e, i_s);
 395         for(i_t = 0; i_t < n_t; ++i_t)
 396         {
 397                 tri = getsurfacetriangle(e, i_s, i_t);
 398                 R_BeginPolygon(tex, 0, false);
 399                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.x), getsurfacepointattribute(e, i_s, tri.x, SPA_TEXCOORDS0), '1 1 1', 1);
 400                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.y), getsurfacepointattribute(e, i_s, tri.y, SPA_TEXCOORDS0), '1 1 1', 1);
 401                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.z), getsurfacepointattribute(e, i_s, tri.z, SPA_TEXCOORDS0), '1 1 1', 1);
 402                 R_EndPolygon();
 403         }
 404         return 1;
 405 }
 406 void PolyDrawModel(entity e)
 407 {
 408         float i_s;
 409         for(i_s = 0; ; ++i_s)
 410                 if(!PolyDrawModelSurface(e, i_s))
 411                         break;
 412 }
 413
 414 void DrawCircleClippedPic(vector centre, float radi, string pic, float f, vector rgb, float a, float drawflag)
 415 {
 416         float d;
 417         vector ringsize, v, t;
 418         ringsize = radi * '1 1 0';
 419         centre = HUD_Shift(centre);
 420         ringsize = HUD_Scale(ringsize);
 421
 422         float co = cos(f * 2 * M_PI);
 423         float si = sin(f * 2 * M_PI);
 424         float q = fabs(co) + fabs(si);
 425         co /= q;
 426         si /= q;
 427
 428         if(f >= 1)
 429         {
 430                 // draw full rectangle
 431                 R_BeginPolygon(pic, drawflag, true);
 432                         v = centre;                     t = '0.5 0.5 0';
 433                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 434                         R_PolygonVertex(v, t, rgb, a);
 435
 436                         v = centre;                     t = '0.5 0.5 0';
 437                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 438                         R_PolygonVertex(v, t, rgb, a);
 439
 440                         v = centre;                     t = '0.5 0.5 0';
 441                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 442                         R_PolygonVertex(v, t, rgb, a);
 443
 444                         v = centre;                     t = '0.5 0.5 0';
 445                         v.y -= 0.5 * ringsize.y;        t -= '0.5 -0.5 0';
 446                         R_PolygonVertex(v, t, rgb, a);
 447                 R_EndPolygon();
 448
 449                 d = q - 1;
 450                 if(d > 0)
 451                 {
 452                         R_BeginPolygon(pic, drawflag, true);
 453                                 v = centre;                     t = '0.5 0.5 0';
 454                                 R_PolygonVertex(v, t, rgb, a);
 455
 456                                 v = centre;                     t = '0.5 0.5 0';
 457                                 v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 458                                 R_PolygonVertex(v, t, rgb, a);
 459                 }
 460         }
 461         else if(f > 0.75)
 462         {
 463                 // draw upper and first triangle
 464                 R_BeginPolygon(pic, drawflag, true);
 465                         v = centre;                     t = '0.5 0.5 0';
 466                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 467                         R_PolygonVertex(v, t, rgb, a);
 468
 469                         v = centre;                     t = '0.5 0.5 0';
 470                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 471                         R_PolygonVertex(v, t, rgb, a);
 472
 473                         v = centre;                     t = '0.5 0.5 0';
 474                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 475                         R_PolygonVertex(v, t, rgb, a);
 476                 R_EndPolygon();
 477                 R_BeginPolygon(pic, drawflag, true);
 478                         v = centre;                     t = '0.5 0.5 0';
 479                         R_PolygonVertex(v, t, rgb, a);
 480
 481                         v = centre;                     t = '0.5 0.5 0';
 482                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 483                         R_PolygonVertex(v, t, rgb, a);
 484
 485                         v = centre;                     t = '0.5 0.5 0';
 486                         v.y -= 0.5 * ringsize.y;        t -= '0.5 -0.5 0';
 487                         R_PolygonVertex(v, t, rgb, a);
 488
 489                 d = q - 0.75;
 490                 if(d <= 0)
 491                         R_EndPolygon();
 492         }
 493         else if(f > 0.5)
 494         {
 495                 // draw upper triangle
 496                 R_BeginPolygon(pic, drawflag, true);
 497                         v = centre;                     t = '0.5 0.5 0';
 498                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 499                         R_PolygonVertex(v, t, rgb, a);
 500
 501                         v = centre;                     t = '0.5 0.5 0';
 502                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 503                         R_PolygonVertex(v, t, rgb, a);
 504
 505                         v = centre;                     t = '0.5 0.5 0';
 506                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 507                         R_PolygonVertex(v, t, rgb, a);
 508                 R_EndPolygon();
 509
 510                 d = q - 0.5;
 511                 if(d > 0)
 512                 {
 513                         R_BeginPolygon(pic, drawflag, true);
 514                                 v = centre;                     t = '0.5 0.5 0';
 515                                 R_PolygonVertex(v, t, rgb, a);
 516
 517                                 v = centre;                     t = '0.5 0.5 0';
 518                                 v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 519                                 R_PolygonVertex(v, t, rgb, a);
 520                 }
 521         }
 522         else if(f > 0.25)
 523         {
 524                 // draw first triangle
 525                 R_BeginPolygon(pic, drawflag, true);
 526                         v = centre;                     t = '0.5 0.5 0';
 527                         R_PolygonVertex(v, t, rgb, a);
 528
 529                         v = centre;                     t = '0.5 0.5 0';
 530                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 531                         R_PolygonVertex(v, t, rgb, a);
 532
 533                         v = centre;                     t = '0.5 0.5 0';
 534                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 535                         R_PolygonVertex(v, t, rgb, a);
 536
 537                 d = q - 0.25;
 538                 if(d <= 0)
 539                         R_EndPolygon();
 540         }
 541         else
 542         {
 543                 d = q;
 544                 if(d > 0)
 545                 {
 546                         R_BeginPolygon(pic, drawflag, true);
 547                                 v = centre;                     t = '0.5 0.5 0';
 548                                 R_PolygonVertex(v, t, rgb, a);
 549
 550                                 v = centre;                     t = '0.5 0.5 0';
 551                                 v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 552                                 R_PolygonVertex(v, t, rgb, a);
 553                 }
 554         }
 555
 556         if(d > 0)
 557         {
 558                         v = centre;                     t = '0.5 0.5 0';
 559                         v.x += co * 0.5 * ringsize.x;   t += co * '0.5 0.5 0';
 560                         v.y += si * 0.5 * ringsize.y;   t += si * '0.5 -0.5 0';
 561                         R_PolygonVertex(v, t, rgb, a);
 562                 R_EndPolygon();
 563         }
 564 }
 565
 566 /** engine callback */
 567 void URI_Get_Callback(int id, int status, string data)
 568 {
 569         TC(int, id); TC(int, status);
 570         if(url_URI_Get_Callback(id, status, data))
 571         {
 572                 // handled
 573         }
 574         else if (id == URI_GET_DISCARD)
 575         {
 576                 // discard
 577         }
 578         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 579         {
 580                 // sv_cmd curl
 581                 Curl_URI_Get_Callback(id, status, data);
 582         }
 583         else
 584         {
 585                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 586         }
 587 }
 588
 589 void Accuracy_LoadLevels()
 590 {
 591         if(autocvar_accuracy_color_levels != acc_color_levels)
 592         {
 593                 strcpy(acc_color_levels, autocvar_accuracy_color_levels);
 594                 acc_levels = tokenize_console(acc_color_levels);
 595                 if(acc_levels > MAX_ACCURACY_LEVELS)
 596                         acc_levels = MAX_ACCURACY_LEVELS;
 597                 if(acc_levels < 2)
 598                         LOG_INFO("Warning: accuracy_color_levels must contain at least 2 values");
 599
 600                 int i;
 601                 for(i = 0; i < acc_levels; ++i)
 602                         acc_lev[i] = stof(argv(i)) / 100.0;
 603         }
 604 }
 605
 606 void Accuracy_LoadColors()
 607 {
 608         if(time > acc_col_loadtime)
 609         if(acc_levels >= 2)
 610         {
 611                 int i;
 612                 for(i = 0; i < acc_levels; ++i)
 613                         acc_col[i] = stov(cvar_string(strcat("accuracy_color", ftos(i))));
 614                 acc_col_loadtime = time + 2;
 615         }
 616 }
 617
 618 vector Accuracy_GetColor(float accuracy)
 619 {
 620         float factor;
 621         vector color;
 622         if(acc_levels < 2)
 623                 return '0 0 0'; // return black, can't determine the right color
 624
 625         // find the max level lower than acc
 626         int j = acc_levels-1;
 627         while(j && accuracy < acc_lev[j])
 628                 --j;
 629
 630         // inject color j+1 in color j, how much depending on how much accuracy is higher than level j
 631         factor = (accuracy - acc_lev[j]) / (acc_lev[j+1] - acc_lev[j]);
 632         color = acc_col[j];
 633         color = color + factor * (acc_col[j+1] - color);
 634         return color;
 635 }