qcsrc/client/miscfunctions.qc

   1 var float(string text, float handleColors, vector fontSize) stringwidth;
   2
   3 entity players;
   4 entity teams;
   5
   6 void serverAnnouncer()
   7 {
   8         // check for pending announcement, play it and remove it
   9         if(announce_snd != "")
  10         {
  11                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/", announce_snd, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  12                 strunzone(announce_snd);
  13                 announce_snd = "";
  14         }
  15 }
  16
  17 void restartAnnouncer_Think() {
  18         float countdown_rounded, countdown;
  19         countdown = getstatf(STAT_GAMESTARTTIME) - time;
  20         countdown_rounded = floor(0.5 + countdown);
  21         if(countdown <= 0) {
  22                 if (!spectatee_status) //do cprint only for players
  23                         centerprint("^1Begin!");
  24
  25                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/begin.wav"), VOL_BASEVOICE, ATTN_NONE);
  26                 //reset maptime announcers now as well
  27                 announcer_5min = announcer_1min = FALSE;
  28
  29                 remove(self);
  30                 return;
  31         }
  32         else {
  33                 if (!spectatee_status) //do cprint only for players
  34                         centerprint(strcat("^1Game starts in ", ftos(countdown_rounded), " seconds"));
  35
  36                 if(countdown_rounded <= 3 && countdown_rounded >= 1) {
  37                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/", ftos(countdown_rounded), ".wav"), VOL_BASEVOICE, ATTN_NONE);
  38                 }
  39
  40                 self.nextthink = getstatf(STAT_GAMESTARTTIME) - (countdown - 1);
  41         }
  42 }
  43
  44 /**
  45  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
  46  */
  47 void maptimeAnnouncer() {
  48         float timelimit;
  49         timelimit = getstatf(STAT_TIMELIMIT);
  50         float timeleft;
  51         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  52
  53         float warmuplimit;
  54         float warmuptimeleft;
  55         if(warmup_stage) {
  56                 warmuplimit = autocvar_g_warmup_limit;
  57                 if(warmuplimit > 0) {
  58                         warmuptimeleft = max(0, warmuplimit + getstatf(STAT_GAMESTARTTIME) - time);
  59                 }
  60         }
  61
  62         //5 minute check
  63         if (autocvar_cl_sound_maptime_warning >= 2) {
  64                 //make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  65                 if(announcer_5min)
  66                 {
  67                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 300) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 300))
  68                                 announcer_5min = FALSE;
  69                 }
  70                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 300 && warmuptimeleft > 299))
  71                         //if we're in warmup mode, check whether there's a warmup timelimit
  72                         if not (warmuplimit == -1 && warmup_stage) {
  73                                 announcer_5min = TRUE;
  74                                 //dprint("i will play the sound, I promise!\n");
  75                                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"), VOL_BASEVOICE, ATTN_NONE);
  76                         }
  77         }
  78
  79         //1 minute check
  80         if (autocvar_cl_sound_maptime_warning == 1 || autocvar_cl_sound_maptime_warning == 3) {
  81                 if (announcer_1min)
  82                 {
  83                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 60))
  84                                 announcer_1min = FALSE;
  85                 }
  86                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 60))
  87                         //if we're in warmup mode, check whether there's a warmup timelimit
  88                         if not (warmuplimit == -1 && warmup_stage) {
  89                                 announcer_1min = TRUE;
  90                                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"), VOL_BASEVOICE, ATTN_NONE);
  91                         }
  92         }
  93 }
  94
  95 /**
  96  * Announce carried items (e.g. flags in CTF).
  97  */
  98 float redflag_prev;
  99 float blueflag_prev;
 100 void carrierAnnouncer() {
 101         float stat_items, redflag, blueflag;
 102         float pickup;
 103         string item;
 104
 105         if not(autocvar_cl_notify_carried_items)
 106                 return;
 107
 108         stat_items = getstati(STAT_ITEMS);
 109
 110         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 111         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 112
 113         if (redflag == 3 && redflag != redflag_prev) {
 114                 item = "^1RED^7 flag";
 115                 pickup = (redflag_prev == 2);
 116         }
 117
 118         if (blueflag == 3 && blueflag != blueflag_prev) {
 119                 item = "^4BLUE^7 flag";
 120                 pickup = (blueflag_prev == 2);
 121         }
 122
 123         if (item)
 124         {
 125                 if (pickup) {
 126                         if (autocvar_cl_notify_carried_items & 2)
 127                                 centerprint(strcat("You picked up the ", item, "!"));
 128                 }
 129                 else {
 130                         if (autocvar_cl_notify_carried_items & 1)
 131                                 centerprint(strcat("You got the ", item, "!"));
 132                 }
 133         }
 134
 135         blueflag_prev = blueflag;
 136         redflag_prev = redflag;
 137 }
 138
 139 /**
 140  * Add all future announcer sounds precaches here.
 141  * TODO: announcer queues
 142  */
 143 void Announcer_Precache () {
 144         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 145         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 146
 147         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 148         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 149         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 150         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 151         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 152         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 153         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 154         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 155         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 156         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 157         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 158         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 159         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 160         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 161         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 162
 163         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 164         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 165         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 166         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 167         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 168         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 169         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 170
 171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 172         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 176         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 180         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 181
 182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 183         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 184
 185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 187         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 188 }
 189
 190 void AuditLists()
 191 {
 192         entity e;
 193         entity prev;
 194
 195         prev = players;
 196         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 197         {
 198                 if(prev != e.sort_prev)
 199                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 200         }
 201
 202         prev = teams;
 203         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 204         {
 205                 if(prev != e.sort_prev)
 206                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 207         }
 208 }
 209
 210
 211 float RegisterPlayer(entity player)
 212 {
 213         entity pl;
 214         AuditLists();
 215         for(pl = players.sort_next; pl; pl = pl.sort_next)
 216                 if(pl == player)
 217                         error("Player already registered!");
 218         player.sort_next = players.sort_next;
 219         player.sort_prev = players;
 220         if(players.sort_next)
 221                 players.sort_next.sort_prev = player;
 222         players.sort_next = player;
 223         AuditLists();
 224         return true;
 225 }
 226
 227 void RemovePlayer(entity player)
 228 {
 229         entity pl, parent;
 230         AuditLists();
 231         parent = players;
 232         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 233                 parent = pl;
 234
 235         if(!pl)
 236         {
 237                 error("Trying to remove a player which is not in the playerlist!");
 238                 return;
 239         }
 240         parent.sort_next = player.sort_next;
 241         if(player.sort_next)
 242                 player.sort_next.sort_prev = parent;
 243         AuditLists();
 244 }
 245
 246 void MoveToLast(entity e)
 247 {
 248         AuditLists();
 249         other = e.sort_next;
 250         while(other)
 251         {
 252                 SORT_SWAP(other, e);
 253                 other = e.sort_next;
 254         }
 255         AuditLists();
 256 }
 257
 258 float RegisterTeam(entity Team)
 259 {
 260         entity tm;
 261         AuditLists();
 262         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 263                 if(tm == Team)
 264                         error("Team already registered!");
 265         Team.sort_next = teams.sort_next;
 266         Team.sort_prev = teams;
 267         if(teams.sort_next)
 268                 teams.sort_next.sort_prev = Team;
 269         teams.sort_next = Team;
 270         AuditLists();
 271         return true;
 272 }
 273
 274 void RemoveTeam(entity Team)
 275 {
 276         entity tm, parent;
 277         AuditLists();
 278         parent = teams;
 279         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 280                 parent = tm;
 281
 282         if(!tm)
 283         {
 284                 print("Trying to remove a team which is not in the teamlist!");
 285                 return;
 286         }
 287         parent.sort_next = Team.sort_next;
 288         if(Team.sort_next)
 289                 Team.sort_next.sort_prev = parent;
 290         AuditLists();
 291 }
 292
 293 entity GetTeam(float Team, float add)
 294 {
 295         float num;
 296         entity tm;
 297         num = (Team == COLOR_SPECTATOR) ? 16 : Team;
 298         if(teamslots[num])
 299                 return teamslots[num];
 300         if not(add)
 301                 return NULL;
 302         tm = spawn();
 303         tm.team = Team;
 304         teamslots[num] = tm;
 305         RegisterTeam(tm);
 306         return tm;
 307 }
 308
 309 vector HUD_GetFontsize(string cvarname)
 310 {
 311         vector v;
 312         v = stov(cvar_string(cvarname));
 313         if(v_x == 0)
 314                 v = '8 8 0';
 315         if(v_y == 0)
 316                 v_y = v_x;
 317         v_z = 0;
 318         return v;
 319 }
 320
 321 float PreviewExists(string name)
 322 {
 323         float f;
 324         string file;
 325
 326         if(autocvar_cl_readpicture_force)
 327                 return false;
 328
 329         file = strcat(name, ".tga");
 330         f = fopen(file, FILE_READ);
 331         if(f >= 0)
 332         {
 333                 fclose(f);
 334                 return true;
 335         }
 336         file = strcat(name, ".png");
 337         f = fopen(file, FILE_READ);
 338         if(f >= 0)
 339         {
 340                 fclose(f);
 341                 return true;
 342         }
 343         file = strcat(name, ".jpg");
 344         f = fopen(file, FILE_READ);
 345         if(f >= 0)
 346         {
 347                 fclose(f);
 348                 return true;
 349         }
 350         file = strcat(name, ".pcx");
 351         f = fopen(file, FILE_READ);
 352         if(f >= 0)
 353         {
 354                 fclose(f);
 355                 return true;
 356         }
 357         return false;
 358 }
 359
 360 vector rotate(vector v, float a)
 361 {
 362         vector w;
 363         // FTEQCC SUCKS AGAIN
 364         w_x =      v_x * cos(a) + v_y * sin(a);
 365         w_y = -1 * v_x * sin(a) + v_y * cos(a);
 366         return w;
 367 }
 368
 369 float ColorTranslateMode;
 370
 371 string ColorTranslateRGB(string s)
 372 {
 373         if(ColorTranslateMode & 1)
 374                 return strdecolorize(s);
 375         else
 376                 return s;
 377 }
 378
 379 float cvar_or(string cv, float v)
 380 {
 381         string s;
 382         s = cvar_string(cv);
 383         if(s == "")
 384                 return v;
 385         else
 386                 return stof(s);
 387 }
 388
 389 vector project_3d_to_2d(vector vec)
 390 {
 391         vec = cs_project(vec);
 392         if(cs_project_is_b0rked > 0)
 393         {
 394                 vec_x *= vid_conwidth / vid_width;
 395                 vec_y *= vid_conheight / vid_height;
 396         }
 397         return vec;
 398 }
 399
 400 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
 401 {
 402 }
 403
 404 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
 405 {
 406         return 1.2 / (1.2 - fadelerp);
 407 }
 408
 409 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
 410 {
 411         boxsize_x *= boxxsizefactor; // easier interface for text
 412         return boxsize * (0.5 * (1 - sz));
 413 }
 414
 415 void drawborderlines(float thickness, vector pos, vector dim, vector color, float alpha, float drawflag)
 416 {
 417         vector line_dim;
 418
 419         // left and right lines
 420         pos_x -= thickness;
 421         line_dim_x = thickness;
 422         line_dim_y = dim_y;
 423         drawfill(pos, line_dim, color, alpha, drawflag);
 424         drawfill(pos + (dim_x + thickness) * '1 0 0', line_dim, color, alpha, drawflag);
 425
 426         // upper and lower lines
 427         pos_y -= thickness;
 428         line_dim_x = dim_x + thickness * 2; // make upper and lower lines longer
 429         line_dim_y = thickness;
 430         drawfill(pos, line_dim, color, alpha, drawflag);
 431         drawfill(pos + (dim_y + thickness) * '0 1 0', line_dim, color, alpha, drawflag);
 432 }
 433
 434 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float alpha, float drawflag)
 435 {
 436         vector current_pos, end_pos, new_size, ratio;
 437         end_pos = pos + area;
 438
 439         current_pos_y = pos_y;
 440         while (current_pos_y < end_pos_y)
 441         {
 442                 current_pos_x = pos_x;
 443                 while (current_pos_x < end_pos_x)
 444                 {
 445                         new_size_x = min(sz_x, end_pos_x - current_pos_x);
 446                         new_size_y = min(sz_y, end_pos_y - current_pos_y);
 447                         ratio_x = new_size_x / sz_x;
 448                         ratio_y = new_size_y / sz_y;
 449                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, alpha, drawflag);
 450                         current_pos_x += sz_x;
 451                 }
 452                 current_pos_y += sz_y;
 453         }
 454 }
 455
 456 // drawpic wrapper to draw an image as large as possible with preserved aspect ratio into a box
 457 var float _drawpic_imgaspect;
 458 var float _drawpic_aspect;
 459 var vector _drawpic_imgsize;
 460 var vector _drawpic_sz;
 461 var vector _drawpic_oldsz;
 462 var string _drawpic_picpath;
 463 #define drawpic_aspect(pos,pic,mySize,color,alpha,drawflag)\
 464         do {\
 465                 _drawpic_imgsize = drawgetimagesize(pic);\
 466                 _drawpic_imgaspect = _drawpic_imgsize_x/_drawpic_imgsize_y;\
 467                 _drawpic_oldsz = _drawpic_sz = mySize;\
 468                 _drawpic_aspect = _drawpic_sz_x/_drawpic_sz_y;\
 469                 if(_drawpic_aspect > _drawpic_imgaspect) {\
 470                         _drawpic_sz_x = _drawpic_sz_y * _drawpic_imgaspect;\
 471                         drawpic(pos + eX * (_drawpic_oldsz_x - _drawpic_sz_x) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
 472                 } else {\
 473                         _drawpic_sz_y = _drawpic_sz_x / _drawpic_imgaspect;\
 474                         drawpic(pos + eY * (_drawpic_oldsz_y - _drawpic_sz_y) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
 475                 }\
 476         } while(0)
 477
 478 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
 479 #define drawpic_aspect_skin(pos,pic,sz,color,alpha,drawflag)\
 480         do{\
 481                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
 482                 if(precache_pic(_drawpic_picpath) == "") {\
 483                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
 484                 }\
 485                 drawpic_aspect(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
 486                 _drawpic_picpath = string_null;\
 487         } while(0)
 488
 489 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
 490 #define drawpic_skin(pos,pic,sz,color,alpha,drawflag)\
 491         do{\
 492                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
 493                 if(precache_pic(_drawpic_picpath) == "") {\
 494                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
 495                 }\
 496                 drawpic(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
 497                 _drawpic_picpath = string_null;\
 498         } while(0)
 499
 500 void drawpic_aspect_skin_expanding(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 501 {
 502         float sz;
 503         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 504
 505         drawpic_skin(position + expandingbox_resize_centered_box_offset(sz, scale, 1), pic, scale * sz, rgb, alpha * (1 - fadelerp), flag);
 506 }
 507
 508 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 509 {
 510         drawpic_aspect_skin_expanding(position, pic, scale, rgb, alpha, flag, fadelerp);
 511         drawpic_skin(position, pic, scale, rgb, alpha * fadelerp, flag);
 512 }
 513
 514 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 515 void drawstring_aspect(vector pos, string text, vector sz, vector color, float alpha, float drawflag) {
 516         vector textsize;
 517         textsize = eX * stringwidth(text, FALSE, '1 1 1' * sz_y) + eY * sz_y;
 518
 519         float textaspect;
 520         textaspect = textsize_x/textsize_y;
 521
 522         vector oldsz;
 523         oldsz = sz;
 524         float aspect;
 525         aspect = sz_x/sz_y;
 526
 527         if(aspect > textaspect) {
 528                 sz_x = sz_y * textaspect;
 529                 drawstring(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag);
 530         } else {
 531                 sz_y = sz_x / textaspect;
 532                 drawstring(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag);
 533         }
 534 }
 535
 536 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
 537 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float alpha, float drawflag) {
 538         vector textsize;
 539         textsize = eX * stringwidth(text, TRUE, '1 1 1' * sz_y) + eY * sz_y;
 540
 541         float textaspect;
 542         textaspect = textsize_x/textsize_y;
 543
 544         vector oldsz;
 545         oldsz = sz;
 546         float aspect;
 547         aspect = sz_x/sz_y;
 548
 549         if(aspect > textaspect) {
 550                 sz_x = sz_y * textaspect;
 551                 drawcolorcodedstring(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag);
 552         } else {
 553                 sz_y = sz_x / textaspect;
 554                 drawcolorcodedstring(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag);
 555         }
 556 }
 557
 558 vector drawfontscale;
 559 void drawstring_expanding(vector position, string text, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 560 {
 561         float sz;
 562         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 563
 564         drawfontscale = sz * '1 1 0';
 565         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
 566         drawstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, FALSE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), rgb, alpha * (1 - fadelerp), flag);
 567         // width parameter:
 568         //    (scale_x * sz / drawfontscale_x) * drawfontscale_x * SIZE1 / (scale_x * sz)
 569         //    SIZE1
 570         drawfontscale = '1 1 0';
 571 }
 572
 573 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 574 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float alpha, float drawflag, float fadelerp) {
 575         vector textsize;
 576         textsize = eX * stringwidth(text, FALSE, '1 1 1' * sz_y) + eY * sz_y;
 577
 578         float textaspect;
 579         textaspect = textsize_x/textsize_y;
 580
 581         vector oldsz;
 582         oldsz = sz;
 583         float aspect;
 584         aspect = sz_x/sz_y;
 585
 586         if(aspect > textaspect) {
 587                 sz_x = sz_y * textaspect;
 588                 drawstring_expanding(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
 589         } else {
 590                 sz_y = sz_x / textaspect;
 591                 drawstring_expanding(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
 592         }
 593 }
 594
 595 void drawcolorcodedstring_expanding(vector position, string text, vector scale, float alpha, float flag, float fadelerp)
 596 {
 597         float sz;
 598         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 599
 600         drawfontscale = sz * '1 1 0';
 601         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
 602         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, TRUE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), alpha * (1 - fadelerp), flag);
 603         drawfontscale = '1 1 0';
 604 }
 605
 606 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float alpha, float drawflag, float fadelerp) {
 607         vector textsize;
 608         textsize = eX * stringwidth(text, TRUE, '1 1 1' * sz_y) + eY * sz_y;
 609
 610         float textaspect;
 611         textaspect = textsize_x/textsize_y;
 612
 613         vector oldsz;
 614         oldsz = sz;
 615         float aspect;
 616         aspect = sz_x/sz_y;
 617
 618         if(aspect > textaspect) {
 619                 sz_x = sz_y * textaspect;
 620                 drawcolorcodedstring_expanding(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
 621         } else {
 622                 sz_y = sz_x / textaspect;
 623                 drawcolorcodedstring_expanding(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
 624         }
 625 }
 626
 627 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
 628 float PolyDrawModelSurface(entity e, float i_s)
 629 {
 630         float i_t;
 631         float n_t;
 632         vector tri;
 633         string tex;
 634         tex = getsurfacetexture(e, i_s);
 635         if not(tex)
 636                 return 0; // this is beyond the last one
 637         n_t = getsurfacenumtriangles(e, i_s);
 638         for(i_t = 0; i_t < n_t; ++i_t)
 639         {
 640                 tri = getsurfacetriangle(e, i_s, i_t);
 641                 R_BeginPolygon(tex, 0);
 642                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_x), getsurfacepointattribute(e, i_s, tri_x, SPA_TEXCOORDS0), '1 1 1', 1);
 643                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_y), getsurfacepointattribute(e, i_s, tri_y, SPA_TEXCOORDS0), '1 1 1', 1);
 644                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_z), getsurfacepointattribute(e, i_s, tri_z, SPA_TEXCOORDS0), '1 1 1', 1);
 645                 R_EndPolygon();
 646         }
 647         return 1;
 648 }
 649 void PolyDrawModel(entity e)
 650 {
 651         float i_s;
 652         for(i_s = 0; ; ++i_s)
 653                 if(!PolyDrawModelSurface(e, i_s))
 654                         break;
 655 }
 656
 657 void DrawCircleClippedPic(vector centre, float radius, string pic, float f, vector rgb, float a, float drawflag)
 658 {
 659         float x, y, q, d;
 660         vector ringsize, v, t;
 661         ringsize = radius * '1 1 0';
 662
 663         x = cos(f * 2 * M_PI);
 664         y = sin(f * 2 * M_PI);
 665         q = fabs(x) + fabs(y);
 666         x /= q;
 667         y /= q;
 668
 669         if(f >= 1)
 670         {
 671                 // draw full rectangle
 672                 R_BeginPolygon(pic, drawflag);
 673                         v = centre;                     t = '0.5 0.5 0';
 674                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 675                         R_PolygonVertex(v, t, rgb, a);
 676
 677                         v = centre;                     t = '0.5 0.5 0';
 678                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 679                         R_PolygonVertex(v, t, rgb, a);
 680
 681                         v = centre;                     t = '0.5 0.5 0';
 682                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 683                         R_PolygonVertex(v, t, rgb, a);
 684
 685                         v = centre;                     t = '0.5 0.5 0';
 686                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
 687                         R_PolygonVertex(v, t, rgb, a);
 688                 R_EndPolygon();
 689
 690                 d = q - 1;
 691                 if(d > 0)
 692                 {
 693                         R_BeginPolygon(pic, drawflag);
 694                                 v = centre;                     t = '0.5 0.5 0';
 695                                 R_PolygonVertex(v, t, rgb, a);
 696
 697                                 v = centre;                     t = '0.5 0.5 0';
 698                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 699                                 R_PolygonVertex(v, t, rgb, a);
 700                 }
 701         }
 702         else if(f > 0.75)
 703         {
 704                 // draw upper and first triangle
 705                 R_BeginPolygon(pic, drawflag);
 706                         v = centre;                     t = '0.5 0.5 0';
 707                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 708                         R_PolygonVertex(v, t, rgb, a);
 709
 710                         v = centre;                     t = '0.5 0.5 0';
 711                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 712                         R_PolygonVertex(v, t, rgb, a);
 713
 714                         v = centre;                     t = '0.5 0.5 0';
 715                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 716                         R_PolygonVertex(v, t, rgb, a);
 717                 R_EndPolygon();
 718                 R_BeginPolygon(pic, drawflag);
 719                         v = centre;                     t = '0.5 0.5 0';
 720                         R_PolygonVertex(v, t, rgb, a);
 721
 722                         v = centre;                     t = '0.5 0.5 0';
 723                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 724                         R_PolygonVertex(v, t, rgb, a);
 725
 726                         v = centre;                     t = '0.5 0.5 0';
 727                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
 728                         R_PolygonVertex(v, t, rgb, a);
 729
 730                 d = q - 0.75;
 731                 if(d <= 0)
 732                         R_EndPolygon();
 733         }
 734         else if(f > 0.5)
 735         {
 736                 // draw upper triangle
 737                 R_BeginPolygon(pic, drawflag);
 738                         v = centre;                     t = '0.5 0.5 0';
 739                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 740                         R_PolygonVertex(v, t, rgb, a);
 741
 742                         v = centre;                     t = '0.5 0.5 0';
 743                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 744                         R_PolygonVertex(v, t, rgb, a);
 745
 746                         v = centre;                     t = '0.5 0.5 0';
 747                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 748                         R_PolygonVertex(v, t, rgb, a);
 749                 R_EndPolygon();
 750
 751                 d = q - 0.5;
 752                 if(d > 0)
 753                 {
 754                         R_BeginPolygon(pic, drawflag);
 755                                 v = centre;                     t = '0.5 0.5 0';
 756                                 R_PolygonVertex(v, t, rgb, a);
 757
 758                                 v = centre;                     t = '0.5 0.5 0';
 759                                 v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 760                                 R_PolygonVertex(v, t, rgb, a);
 761                 }
 762         }
 763         else if(f > 0.25)
 764         {
 765                 // draw first triangle
 766                 R_BeginPolygon(pic, drawflag);
 767                         v = centre;                     t = '0.5 0.5 0';
 768                         R_PolygonVertex(v, t, rgb, a);
 769
 770                         v = centre;                     t = '0.5 0.5 0';
 771                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 772                         R_PolygonVertex(v, t, rgb, a);
 773
 774                         v = centre;                     t = '0.5 0.5 0';
 775                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 776                         R_PolygonVertex(v, t, rgb, a);
 777
 778                 d = q - 0.25;
 779                 if(d <= 0)
 780                         R_EndPolygon();
 781         }
 782         else
 783         {
 784                 d = q;
 785                 if(d > 0)
 786                 {
 787                         R_BeginPolygon(pic, drawflag);
 788                                 v = centre;                     t = '0.5 0.5 0';
 789                                 R_PolygonVertex(v, t, rgb, a);
 790
 791                                 v = centre;                     t = '0.5 0.5 0';
 792                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 793                                 R_PolygonVertex(v, t, rgb, a);
 794                 }
 795         }
 796
 797         if(d > 0)
 798         {
 799                         v = centre;                     t = '0.5 0.5 0';
 800                         v_x += x * 0.5 * ringsize_x;    t += x * '0.5 0.5 0';
 801                         v_y += y * 0.5 * ringsize_y;    t += y * '0.5 -0.5 0';
 802                         R_PolygonVertex(v, t, rgb, a);
 803                 R_EndPolygon();
 804         }
 805 }