qcsrc/client/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "hud/all.qh"
   4
   5 #include <common/command/generic.qh>
   6
   7 #include <common/teams.qh>
   8
   9 #include <lib/csqcmodel/cl_model.qh>
  10
  11
  12 void AuditLists()
  13 {
  14         entity e;
  15         entity prev;
  16
  17         prev = players;
  18         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
  19         {
  20                 if(prev != e.sort_prev)
  21                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
  22         }
  23
  24         prev = teams;
  25         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
  26         {
  27                 if(prev != e.sort_prev)
  28                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
  29         }
  30 }
  31
  32
  33 float RegisterPlayer(entity player)
  34 {
  35         entity pl;
  36         AuditLists();
  37         for(pl = players.sort_next; pl; pl = pl.sort_next)
  38                 if(pl == player)
  39                         error("Player already registered!");
  40         player.sort_next = players.sort_next;
  41         player.sort_prev = players;
  42         if(players.sort_next)
  43                 players.sort_next.sort_prev = player;
  44         players.sort_next = player;
  45         AuditLists();
  46         return true;
  47 }
  48
  49 void RemovePlayer(entity player)
  50 {
  51         entity pl, parent;
  52         AuditLists();
  53         parent = players;
  54         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
  55                 parent = pl;
  56
  57         if(!pl)
  58         {
  59                 error("Trying to remove a player which is not in the playerlist!");
  60                 return;
  61         }
  62         parent.sort_next = player.sort_next;
  63         if(player.sort_next)
  64                 player.sort_next.sort_prev = parent;
  65         AuditLists();
  66 }
  67
  68 void MoveToLast(entity e)
  69 {
  70         AuditLists();
  71         other = e.sort_next;
  72         while(other)
  73         {
  74                 SORT_SWAP(other, e);
  75                 other = e.sort_next;
  76         }
  77         AuditLists();
  78 }
  79
  80 float RegisterTeam(entity Team)
  81 {
  82         assert_once(Team.team, eprint(Team));
  83         entity tm;
  84         AuditLists();
  85         for(tm = teams.sort_next; tm; tm = tm.sort_next)
  86                 if(tm == Team)
  87                         error("Team already registered!");
  88         Team.sort_next = teams.sort_next;
  89         Team.sort_prev = teams;
  90         if(teams.sort_next)
  91                 teams.sort_next.sort_prev = Team;
  92         teams.sort_next = Team;
  93         if(Team.team && Team.team != NUM_SPECTATOR)
  94                 ++team_count;
  95         AuditLists();
  96         return true;
  97 }
  98
  99 void RemoveTeam(entity Team)
 100 {
 101         entity tm, parent;
 102         AuditLists();
 103         parent = teams;
 104         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 105                 parent = tm;
 106
 107         if(!tm)
 108         {
 109                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 110                 return;
 111         }
 112         parent.sort_next = Team.sort_next;
 113         if(Team.sort_next)
 114                 Team.sort_next.sort_prev = parent;
 115         if(Team.team && Team.team != NUM_SPECTATOR)
 116                 --team_count;
 117         AuditLists();
 118 }
 119
 120 entity GetTeam(int Team, bool add)
 121 {
 122     TC(int, Team); TC(bool, add);
 123         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 124         if(teamslots[num])
 125                 return teamslots[num];
 126         if (!add)
 127                 return world;
 128         entity tm = new_pure(team);
 129         tm.team = Team;
 130         teamslots[num] = tm;
 131         RegisterTeam(tm);
 132         return tm;
 133 }
 134
 135 vector HUD_GetFontsize(string cvarname)
 136 {
 137         vector v;
 138         v = stov(cvar_string(cvarname));
 139         if(v.x == 0)
 140                 v = '8 8 0';
 141         if(v.y == 0)
 142                 v.y = v.x;
 143         v.z = 0;
 144         return v;
 145 }
 146
 147 float PreviewExists(string name)
 148 {
 149         if(autocvar_cl_readpicture_force)
 150                 return false;
 151
 152         if (fexists(strcat(name, ".tga"))) return true;
 153         if (fexists(strcat(name, ".png"))) return true;
 154         if (fexists(strcat(name, ".jpg"))) return true;
 155         if (fexists(strcat(name, ".pcx"))) return true;
 156
 157         return false;
 158 }
 159
 160 // decolorizes and team colors the player name when needed
 161 string playername(string thename, float teamid)
 162 {
 163     TC(int, teamid);
 164     string t;
 165     if (teamplay)
 166     {
 167         t = Team_ColorCode(teamid);
 168         return strcat(t, strdecolorize(thename));
 169     }
 170     else
 171         return strdecolorize(thename);
 172 }
 173
 174 float cvar_or(string cv, float v)
 175 {
 176         string s;
 177         s = cvar_string(cv);
 178         if(s == "")
 179                 return v;
 180         else
 181                 return stof(s);
 182 }
 183
 184 vector project_3d_to_2d(vector vec)
 185 {
 186         vec = cs_project(vec);
 187         if(cs_project_is_b0rked > 0)
 188         {
 189                 vec.x *= vid_conwidth / vid_width;
 190                 vec.y *= vid_conheight / vid_height;
 191         }
 192         return vec;
 193 }
 194
 195 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
 196 {
 197         return 1.2 / (1.2 - fadelerp);
 198 }
 199
 200 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
 201 {
 202         boxsize.x *= boxxsizefactor; // easier interface for text
 203         return boxsize * (0.5 * (1 - sz));
 204 }
 205
 206 void drawborderlines(float thickness, vector pos, vector dim, vector color, float theAlpha, float drawflag)
 207 {
 208         vector line_dim = '0 0 0';
 209
 210         // left and right lines
 211         pos.x -= thickness;
 212         line_dim.x = thickness;
 213         line_dim.y = dim.y;
 214         drawfill(pos, line_dim, color, theAlpha, drawflag);
 215         drawfill(pos + (dim.x + thickness) * '1 0 0', line_dim, color, theAlpha, drawflag);
 216
 217         // upper and lower lines
 218         pos.y -= thickness;
 219         line_dim.x = dim.x + thickness * 2; // make upper and lower lines longer
 220         line_dim.y = thickness;
 221         drawfill(pos, line_dim, color, theAlpha, drawflag);
 222         drawfill(pos + (dim.y + thickness) * '0 1 0', line_dim, color, theAlpha, drawflag);
 223 }
 224
 225 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float theAlpha, float drawflag)
 226 {
 227         vector current_pos = '0 0 0', end_pos, new_size = '0 0 0', ratio = '0 0 0';
 228         end_pos = pos + area;
 229
 230         current_pos.y = pos.y;
 231         while (current_pos.y < end_pos.y)
 232         {
 233                 current_pos.x = pos.x;
 234                 while (current_pos.x < end_pos.x)
 235                 {
 236                         new_size.x = min(sz.x, end_pos.x - current_pos.x);
 237                         new_size.y = min(sz.y, end_pos.y - current_pos.y);
 238                         ratio.x = new_size.x / sz.x;
 239                         ratio.y = new_size.y / sz.y;
 240                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, theAlpha, drawflag);
 241                         current_pos.x += sz.x;
 242                 }
 243                 current_pos.y += sz.y;
 244         }
 245 }
 246
 247 void drawpic_aspect_skin_expanding(vector position, string pic, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 248 {
 249         float sz;
 250         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 251
 252         drawpic_aspect_skin(position + expandingbox_resize_centered_box_offset(sz, theScale, 1), pic, theScale * sz, rgb, theAlpha * (1 - fadelerp), flag);
 253 }
 254
 255 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 256 {
 257         drawpic_aspect_skin_expanding(position, pic, theScale, rgb, theAlpha, flag, fadelerp);
 258         drawpic_skin(position, pic, theScale, rgb, theAlpha * fadelerp, flag);
 259 }
 260
 261 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 262 void drawstring_aspect(vector pos, string text, vector sz, vector color, float theAlpha, float drawflag) {
 263         SET_POS_AND_SZ_Y_ASPECT(false);
 264         drawstring(pos, text, '1 1 0' * sz.y, color, theAlpha, drawflag);
 265 }
 266
 267 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
 268 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float theAlpha, float drawflag) {
 269         SET_POS_AND_SZ_Y_ASPECT(true);
 270         drawcolorcodedstring(pos, text, '1 1 0' * sz.y, theAlpha, drawflag);
 271 }
 272
 273 void drawstring_expanding(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag, float fadelerp)
 274 {
 275         float sz;
 276         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 277
 278         drawfontscale = sz * '1 1 0';
 279         drawstring(position + expandingbox_resize_centered_box_offset(sz, theScale, stringwidth(text, false, theScale * (sz / drawfontscale.x)) / (theScale.x * sz)), text, theScale * (sz / drawfontscale.x), rgb, theAlpha * (1 - fadelerp), flag);
 280         // width parameter:
 281         //    (scale_x * sz / drawfontscale_x) * drawfontscale_x * SIZE1 / (scale_x * sz)
 282         //    SIZE1
 283         drawfontscale = '1 1 0';
 284 }
 285
 286 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 287 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float theAlpha, float drawflag, float fadelerp) {
 288         SET_POS_AND_SZ_Y_ASPECT(false);
 289         drawstring_expanding(pos, text, '1 1 0' * sz.y, color, theAlpha, drawflag, fadelerp);
 290 }
 291
 292 void drawcolorcodedstring_expanding(vector position, string text, vector theScale, float theAlpha, float flag, float fadelerp)
 293 {
 294         float sz;
 295         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 296
 297         drawfontscale = sz * '1 1 0';
 298         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, theScale, stringwidth(text, true, theScale * (sz / drawfontscale.x)) / (theScale.x * sz)), text, theScale * (sz / drawfontscale.x), theAlpha * (1 - fadelerp), flag);
 299         drawfontscale = '1 1 0';
 300 }
 301
 302 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float theAlpha, float drawflag, float fadelerp) {
 303         SET_POS_AND_SZ_Y_ASPECT(true);
 304         drawcolorcodedstring_expanding(pos, text, '1 1 0' * sz.y, theAlpha, drawflag, fadelerp);
 305 }
 306
 307 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
 308 float PolyDrawModelSurface(entity e, float i_s)
 309 {
 310         float i_t;
 311         float n_t;
 312         vector tri;
 313         string tex;
 314         tex = getsurfacetexture(e, i_s);
 315         if (!tex)
 316                 return 0; // this is beyond the last one
 317         n_t = getsurfacenumtriangles(e, i_s);
 318         for(i_t = 0; i_t < n_t; ++i_t)
 319         {
 320                 tri = getsurfacetriangle(e, i_s, i_t);
 321                 R_BeginPolygon(tex, 0);
 322                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.x), getsurfacepointattribute(e, i_s, tri.x, SPA_TEXCOORDS0), '1 1 1', 1);
 323                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.y), getsurfacepointattribute(e, i_s, tri.y, SPA_TEXCOORDS0), '1 1 1', 1);
 324                 R_PolygonVertex(getsurfacepoint(e, i_s, tri.z), getsurfacepointattribute(e, i_s, tri.z, SPA_TEXCOORDS0), '1 1 1', 1);
 325                 R_EndPolygon();
 326         }
 327         return 1;
 328 }
 329 void PolyDrawModel(entity e)
 330 {
 331         float i_s;
 332         for(i_s = 0; ; ++i_s)
 333                 if(!PolyDrawModelSurface(e, i_s))
 334                         break;
 335 }
 336
 337 void DrawCircleClippedPic(vector centre, float radi, string pic, float f, vector rgb, float a, float drawflag)
 338 {
 339         float x, y, q, d;
 340         vector ringsize, v, t;
 341         ringsize = radi * '1 1 0';
 342
 343         x = cos(f * 2 * M_PI);
 344         y = sin(f * 2 * M_PI);
 345         q = fabs(x) + fabs(y);
 346         x /= q;
 347         y /= q;
 348
 349         if(f >= 1)
 350         {
 351                 // draw full rectangle
 352                 R_BeginPolygon(pic, drawflag);
 353                         v = centre;                     t = '0.5 0.5 0';
 354                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 355                         R_PolygonVertex(v, t, rgb, a);
 356
 357                         v = centre;                     t = '0.5 0.5 0';
 358                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 359                         R_PolygonVertex(v, t, rgb, a);
 360
 361                         v = centre;                     t = '0.5 0.5 0';
 362                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 363                         R_PolygonVertex(v, t, rgb, a);
 364
 365                         v = centre;                     t = '0.5 0.5 0';
 366                         v.y -= 0.5 * ringsize.y;        t -= '0.5 -0.5 0';
 367                         R_PolygonVertex(v, t, rgb, a);
 368                 R_EndPolygon();
 369
 370                 d = q - 1;
 371                 if(d > 0)
 372                 {
 373                         R_BeginPolygon(pic, drawflag);
 374                                 v = centre;                     t = '0.5 0.5 0';
 375                                 R_PolygonVertex(v, t, rgb, a);
 376
 377                                 v = centre;                     t = '0.5 0.5 0';
 378                                 v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 379                                 R_PolygonVertex(v, t, rgb, a);
 380                 }
 381         }
 382         else if(f > 0.75)
 383         {
 384                 // draw upper and first triangle
 385                 R_BeginPolygon(pic, drawflag);
 386                         v = centre;                     t = '0.5 0.5 0';
 387                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 388                         R_PolygonVertex(v, t, rgb, a);
 389
 390                         v = centre;                     t = '0.5 0.5 0';
 391                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 392                         R_PolygonVertex(v, t, rgb, a);
 393
 394                         v = centre;                     t = '0.5 0.5 0';
 395                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 396                         R_PolygonVertex(v, t, rgb, a);
 397                 R_EndPolygon();
 398                 R_BeginPolygon(pic, drawflag);
 399                         v = centre;                     t = '0.5 0.5 0';
 400                         R_PolygonVertex(v, t, rgb, a);
 401
 402                         v = centre;                     t = '0.5 0.5 0';
 403                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 404                         R_PolygonVertex(v, t, rgb, a);
 405
 406                         v = centre;                     t = '0.5 0.5 0';
 407                         v.y -= 0.5 * ringsize.y;        t -= '0.5 -0.5 0';
 408                         R_PolygonVertex(v, t, rgb, a);
 409
 410                 d = q - 0.75;
 411                 if(d <= 0)
 412                         R_EndPolygon();
 413         }
 414         else if(f > 0.5)
 415         {
 416                 // draw upper triangle
 417                 R_BeginPolygon(pic, drawflag);
 418                         v = centre;                     t = '0.5 0.5 0';
 419                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 420                         R_PolygonVertex(v, t, rgb, a);
 421
 422                         v = centre;                     t = '0.5 0.5 0';
 423                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 424                         R_PolygonVertex(v, t, rgb, a);
 425
 426                         v = centre;                     t = '0.5 0.5 0';
 427                         v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 428                         R_PolygonVertex(v, t, rgb, a);
 429                 R_EndPolygon();
 430
 431                 d = q - 0.5;
 432                 if(d > 0)
 433                 {
 434                         R_BeginPolygon(pic, drawflag);
 435                                 v = centre;                     t = '0.5 0.5 0';
 436                                 R_PolygonVertex(v, t, rgb, a);
 437
 438                                 v = centre;                     t = '0.5 0.5 0';
 439                                 v.x -= 0.5 * ringsize.x;        t -= '0.5 0.5 0';
 440                                 R_PolygonVertex(v, t, rgb, a);
 441                 }
 442         }
 443         else if(f > 0.25)
 444         {
 445                 // draw first triangle
 446                 R_BeginPolygon(pic, drawflag);
 447                         v = centre;                     t = '0.5 0.5 0';
 448                         R_PolygonVertex(v, t, rgb, a);
 449
 450                         v = centre;                     t = '0.5 0.5 0';
 451                         v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 452                         R_PolygonVertex(v, t, rgb, a);
 453
 454                         v = centre;                     t = '0.5 0.5 0';
 455                         v.y += 0.5 * ringsize.y;        t += '0.5 -0.5 0';
 456                         R_PolygonVertex(v, t, rgb, a);
 457
 458                 d = q - 0.25;
 459                 if(d <= 0)
 460                         R_EndPolygon();
 461         }
 462         else
 463         {
 464                 d = q;
 465                 if(d > 0)
 466                 {
 467                         R_BeginPolygon(pic, drawflag);
 468                                 v = centre;                     t = '0.5 0.5 0';
 469                                 R_PolygonVertex(v, t, rgb, a);
 470
 471                                 v = centre;                     t = '0.5 0.5 0';
 472                                 v.x += 0.5 * ringsize.x;        t += '0.5 0.5 0';
 473                                 R_PolygonVertex(v, t, rgb, a);
 474                 }
 475         }
 476
 477         if(d > 0)
 478         {
 479                         v = centre;                     t = '0.5 0.5 0';
 480                         v.x += x * 0.5 * ringsize.x;    t += x * '0.5 0.5 0';
 481                         v.y += y * 0.5 * ringsize.y;    t += y * '0.5 -0.5 0';
 482                         R_PolygonVertex(v, t, rgb, a);
 483                 R_EndPolygon();
 484         }
 485 }
 486
 487 /** engine callback */
 488 void URI_Get_Callback(int id, int status, string data)
 489 {
 490     TC(int, id); TC(int, status);
 491         if(url_URI_Get_Callback(id, status, data))
 492         {
 493                 // handled
 494         }
 495         else if (id == URI_GET_DISCARD)
 496         {
 497                 // discard
 498         }
 499         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 500         {
 501                 // sv_cmd curl
 502                 Curl_URI_Get_Callback(id, status, data);
 503         }
 504         else
 505         {
 506                 LOG_INFOF("Received HTTP request data for an invalid id %d.\n", id);
 507         }
 508 }
 509
 510 void Accuracy_LoadLevels()
 511 {
 512         if(autocvar_accuracy_color_levels != acc_color_levels)
 513         {
 514                 if(acc_color_levels)
 515                         strunzone(acc_color_levels);
 516                 acc_color_levels = strzone(autocvar_accuracy_color_levels);
 517                 acc_levels = tokenize_console(acc_color_levels);
 518                 if(acc_levels > MAX_ACCURACY_LEVELS)
 519                         acc_levels = MAX_ACCURACY_LEVELS;
 520                 if(acc_levels < 2)
 521                         LOG_INFO("Warning: accuracy_color_levels must contain at least 2 values\n");
 522
 523                 int i;
 524                 for(i = 0; i < acc_levels; ++i)
 525                         acc_lev[i] = stof(argv(i)) / 100.0;
 526         }
 527 }
 528
 529 void Accuracy_LoadColors()
 530 {
 531         if(time > acc_col_loadtime)
 532         if(acc_levels >= 2)
 533         {
 534                 int i;
 535                 for(i = 0; i < acc_levels; ++i)
 536                         acc_col[i] = stov(cvar_string(strcat("accuracy_color", ftos(i))));
 537                 acc_col_loadtime = time + 2;
 538         }
 539 }
 540
 541 vector Accuracy_GetColor(float accuracy)
 542 {
 543         float factor;
 544         vector color;
 545         if(acc_levels < 2)
 546                 return '0 0 0'; // return black, can't determine the right color
 547
 548         // find the max level lower than acc
 549         int j = acc_levels-1;
 550         while(j && accuracy < acc_lev[j])
 551                 --j;
 552
 553         // inject color j+1 in color j, how much depending on how much accuracy is higher than level j
 554         factor = (accuracy - acc_lev[j]) / (acc_lev[j+1] - acc_lev[j]);
 555         color = acc_col[j];
 556         color = color + factor * (acc_col[j+1] - color);
 557         return color;
 558 }
 559