qcsrc/client/player_skeleton.qc

   1 #include "player_skeleton.qh"
   2
   3 #include "../warpzonelib/anglestransform.qh"
   4
   5 .float skeleton_info_modelindex;
   6 .float skeleton_info_skin;
   7 const int BONETYPE_LOWER = 0;
   8 const int BONETYPE_UPPER = 1;
   9 const int MAX_BONES = 128;
  10 .float skeleton_bonetype[MAX_BONES];
  11 .float skeleton_numbones;
  12
  13 void skeleton_loadinfo(entity e)
  14 {
  15         int i;
  16         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  17                 return;
  18         e.bone_upperbody = 0;
  19         e.bone_weapon = gettagindex(e, "weapon");
  20         if(!e.bone_weapon)
  21                 e.bone_weapon = gettagindex(e, "tag_weapon");
  22         if(!e.bone_weapon)
  23                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  24         for(i = 0; i < MAX_AIM_BONES; ++i)
  25         {
  26                 e.(bone_aim[i]) = 0;
  27                 e.(bone_aimweight[i]) = 0;
  28         }
  29         e.fixbone = 0;
  30         if(get_model_parameters(e.model, e.skin))
  31         {
  32                 if(get_model_parameters_bone_upperbody)
  33                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  34                 if(e.bone_upperbody)
  35                         e.fixbone = get_model_parameters_fixbone;
  36                 if(get_model_parameters_bone_weapon)
  37                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  38                 for(i = 0; i < MAX_AIM_BONES; ++i)
  39                 {
  40                         if(get_model_parameters_bone_aim[i])
  41                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  42                         if(e.bone_aim[i])
  43                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  44                 }
  45         }
  46         else
  47                 dprint("No model parameters for ", e.model, "\n");
  48         dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  49         get_model_parameters(string_null, 0);
  50         e.skeleton_info_modelindex = e.modelindex;
  51         e.skeleton_info_skin = e.skin;
  52         if(e.skeletonindex)
  53         {
  54                 skel_delete(e.skeletonindex);
  55                 e.skeletonindex = 0;
  56         }
  57 }
  58
  59 void skeleton_markbones(entity e)
  60 {
  61         float s = e.skeletonindex;
  62         float n = (e.skeleton_numbones = skel_get_numbones(s));
  63         int i;
  64         for(i = 1; i <= n; ++i)
  65         {
  66                 float t = BONETYPE_LOWER;
  67                 int p = skel_get_boneparent(s, i);
  68                 if(p > 0)
  69                         t = e.(skeleton_bonetype[p-1]);
  70                 if(i == e.bone_upperbody)
  71                         t = BONETYPE_UPPER;
  72                 e.(skeleton_bonetype[i-1]) = t;
  73         }
  74 }
  75
  76 void skel_set_boneabs(float s, float bone, vector absorg)
  77 {
  78         vector absang = fixedvectoangles2(v_forward, v_up);
  79
  80         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  81         vector parentang = fixedvectoangles2(v_forward, v_up);
  82
  83         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  84         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  85
  86         fixedmakevectors(relang);
  87         skel_set_bone(s, bone, relorg);
  88
  89         /*
  90         vector neworg = skel_get_boneabs(s, bone);
  91         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
  92         printf("ORG: want: %v, got: %v\n", absorg, neworg);
  93         */
  94 }
  95
  96 void free_skeleton_from_frames(entity e)
  97 {
  98         if(e.skeletonindex)
  99         {
 100                 skel_delete(e.skeletonindex);
 101                 e.skeletonindex = 0;
 102         }
 103 }
 104
 105 void skeleton_from_frames(entity e, float is_dead)
 106 {
 107         float m = e.modelindex;
 108         if(!e.skeletonindex)
 109         {
 110                 e.skeletonindex = skel_create(m);
 111                 skeleton_markbones(e);
 112         }
 113         float s = e.skeletonindex;
 114         if(!s)
 115                 return;
 116         float n = e.skeleton_numbones;
 117         float savelerpfrac = e.lerpfrac;
 118         float savelerpfrac3 = e.lerpfrac3;
 119         float savelerpfrac4 = e.lerpfrac4;
 120
 121         vector fixbone_oldangles = '0 0 0';
 122         if(e.fixbone)
 123         {
 124                 // make all bones BONETYPE_UPPER
 125                 e.lerpfrac = 0;
 126                 e.lerpfrac3 = savelerpfrac3 * 2;
 127                 e.lerpfrac4 = 0;
 128                 // build skeleton
 129                 skel_build(s, e, m, 0, 1, n);
 130                 // get hip bone
 131                 skel_get_boneabs(s, e.bone_upperbody);
 132                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 133         }
 134         int bone;
 135         for(bone = 0; bone < n; )
 136         {
 137                 float firstbone = bone;
 138                 float bonetype = e.skeleton_bonetype[bone];
 139                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 140                         ;
 141                 if(bonetype == BONETYPE_UPPER)
 142                 {
 143                         // only show frames 1+3 (upper body)
 144                         e.lerpfrac = 0;
 145                         e.lerpfrac3 = savelerpfrac3 * 2;
 146                         e.lerpfrac4 = 0;
 147                 }
 148                 else
 149                 {
 150                         // only show frames 2+4 (lower body)
 151                         e.lerpfrac = savelerpfrac * 2;
 152                         e.lerpfrac3 = 0;
 153                         e.lerpfrac4 = savelerpfrac4 * 2;
 154                 }
 155                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 156                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 157                 skel_build(s, e, m, 0, firstbone + 1, bone);
 158         }
 159         e.lerpfrac = savelerpfrac;
 160         e.lerpfrac3 = savelerpfrac3;
 161         e.lerpfrac4 = savelerpfrac4;
 162
 163         if(e.fixbone)
 164         {
 165                 // FIX IT
 166                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 167                 fixedmakevectors(fixbone_oldangles);
 168                 skel_set_boneabs(s, e.bone_upperbody, org);
 169         }
 170
 171         if(!is_dead)
 172         {
 173                 int i;
 174                 for(i = 0; i < MAX_AIM_BONES; ++i)
 175                 {
 176                         if(e.(bone_aim[i]))
 177                         {
 178                                 vector aim = '1 0 0' * bound(-90, self.v_angle.x, 90) * e.(bone_aimweight[i]);
 179                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 180                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 181                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 182                                 fixedmakevectors(ang);
 183                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 184                         }
 185                 }
 186         }
 187 }