qcsrc/client/player_skeleton.qc

   1 #include "player_skeleton.qh"
   2
   3 #include "../common/csqcmodel_settings.qh"
   4 #include "../warpzonelib/anglestransform.qh"
   5
   6 class(Skeleton) .float skeleton_info_modelindex;
   7 class(Skeleton) .float skeleton_info_skin;
   8 const int BONETYPE_LOWER = 0;
   9 const int BONETYPE_UPPER = 1;
  10 const int MAX_BONES = 128;
  11 class(Skeleton) .float skeleton_bonetype[MAX_BONES];
  12 class(Skeleton) .float skeleton_numbones;
  13
  14 void skeleton_loadinfo(entity e)
  15 {
  16         int i;
  17         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  18                 return;
  19         e.bone_upperbody = 0;
  20         e.bone_weapon = gettagindex(e, "weapon");
  21         if(!e.bone_weapon)
  22                 e.bone_weapon = gettagindex(e, "tag_weapon");
  23         if(!e.bone_weapon)
  24                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  25         for(i = 0; i < MAX_AIM_BONES; ++i)
  26         {
  27                 e.(bone_aim[i]) = 0;
  28                 e.(bone_aimweight[i]) = 0;
  29         }
  30         e.fixbone = 0;
  31         if(get_model_parameters(e.model, e.skin))
  32         {
  33                 if(get_model_parameters_bone_upperbody)
  34                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  35                 if(e.bone_upperbody)
  36                         e.fixbone = get_model_parameters_fixbone;
  37                 if(get_model_parameters_bone_weapon)
  38                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  39                 for(i = 0; i < MAX_AIM_BONES; ++i)
  40                 {
  41                         if(get_model_parameters_bone_aim[i])
  42                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  43                         if(e.bone_aim[i])
  44                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  45                 }
  46         }
  47         else
  48                 dprint("No model parameters for ", e.model, "\n");
  49         dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  50         get_model_parameters(string_null, 0);
  51         e.skeleton_info_modelindex = e.modelindex;
  52         e.skeleton_info_skin = e.skin;
  53         if(e.skeletonindex)
  54         {
  55                 skel_delete(e.skeletonindex);
  56                 e.skeletonindex = 0;
  57         }
  58 }
  59
  60 void skeleton_markbones(entity e)
  61 {
  62         float s = e.skeletonindex;
  63         float n = (e.skeleton_numbones = skel_get_numbones(s));
  64         int i;
  65         for(i = 1; i <= n; ++i)
  66         {
  67                 float t = BONETYPE_LOWER;
  68                 int p = skel_get_boneparent(s, i);
  69                 if(p > 0)
  70                         t = e.(skeleton_bonetype[p-1]);
  71                 if(i == e.bone_upperbody)
  72                         t = BONETYPE_UPPER;
  73                 e.(skeleton_bonetype[i-1]) = t;
  74         }
  75 }
  76
  77 void skel_set_boneabs(float s, float bone, vector absorg)
  78 {
  79         vector absang = fixedvectoangles2(v_forward, v_up);
  80
  81         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  82         vector parentang = fixedvectoangles2(v_forward, v_up);
  83
  84         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  85         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  86
  87         fixedmakevectors(relang);
  88         skel_set_bone(s, bone, relorg);
  89
  90         /*
  91         vector neworg = skel_get_boneabs(s, bone);
  92         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
  93         printf("ORG: want: %v, got: %v\n", absorg, neworg);
  94         */
  95 }
  96
  97 void free_skeleton_from_frames(entity e)
  98 {
  99         if(e.skeletonindex)
 100         {
 101                 skel_delete(e.skeletonindex);
 102                 e.skeletonindex = 0;
 103         }
 104 }
 105
 106 void skeleton_from_frames(entity e, float is_dead)
 107 {
 108         float m = e.modelindex;
 109         if(!e.skeletonindex)
 110         {
 111                 e.skeletonindex = skel_create(m);
 112                 skeleton_markbones(e);
 113         }
 114         float s = e.skeletonindex;
 115         if(!s)
 116                 return;
 117         float n = e.skeleton_numbones;
 118         float savelerpfrac = e.lerpfrac;
 119         float savelerpfrac3 = e.lerpfrac3;
 120         float savelerpfrac4 = e.lerpfrac4;
 121
 122         vector fixbone_oldangles = '0 0 0';
 123         if(e.fixbone)
 124         {
 125                 // make all bones BONETYPE_UPPER
 126                 e.lerpfrac = 0;
 127                 e.lerpfrac3 = savelerpfrac3 * 2;
 128                 e.lerpfrac4 = 0;
 129                 // build skeleton
 130                 skel_build(s, e, m, 0, 1, n);
 131                 // get hip bone
 132                 skel_get_boneabs(s, e.bone_upperbody);
 133                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 134         }
 135         int bone;
 136         for(bone = 0; bone < n; )
 137         {
 138                 float firstbone = bone;
 139                 float bonetype = e.skeleton_bonetype[bone];
 140                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 141                         ;
 142                 if(bonetype == BONETYPE_UPPER)
 143                 {
 144                         // only show frames 1+3 (upper body)
 145                         e.lerpfrac = 0;
 146                         e.lerpfrac3 = savelerpfrac3 * 2;
 147                         e.lerpfrac4 = 0;
 148                 }
 149                 else
 150                 {
 151                         // only show frames 2+4 (lower body)
 152                         e.lerpfrac = savelerpfrac * 2;
 153                         e.lerpfrac3 = 0;
 154                         e.lerpfrac4 = savelerpfrac4 * 2;
 155                 }
 156                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 157                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 158                 skel_build(s, e, m, 0, firstbone + 1, bone);
 159         }
 160         e.lerpfrac = savelerpfrac;
 161         e.lerpfrac3 = savelerpfrac3;
 162         e.lerpfrac4 = savelerpfrac4;
 163
 164         if(e.fixbone)
 165         {
 166                 // FIX IT
 167                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 168                 fixedmakevectors(fixbone_oldangles);
 169                 skel_set_boneabs(s, e.bone_upperbody, org);
 170         }
 171
 172         if(!is_dead)
 173         {
 174                 int i;
 175                 for(i = 0; i < MAX_AIM_BONES; ++i)
 176                 {
 177                         if(e.(bone_aim[i]))
 178                         {
 179                                 vector aim = '1 0 0' * bound(-90, self.v_angle.x, 90) * e.(bone_aimweight[i]);
 180                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 181                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 182                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 183                                 fixedmakevectors(ang);
 184                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 185                         }
 186                 }
 187         }
 188 }