qcsrc/client/player_skeleton.qc

   1 #include "player_skeleton.qh"
   2
   3 #include "mutators/events.qh"
   4 #include "../lib/csqcmodel/cl_player.qh"
   5 #include "../lib/warpzone/anglestransform.qh"
   6
   7 .vector v_angle;
   8
   9 class(Skeleton) .float skeleton_info_modelindex;
  10 class(Skeleton) .float skeleton_info_skin;
  11 const int BONETYPE_LOWER = 0;
  12 const int BONETYPE_UPPER = 1;
  13 const int MAX_BONES = 128;
  14 class(Skeleton) .float skeleton_bonetype[MAX_BONES];
  15 class(Skeleton) .float skeleton_numbones;
  16
  17 void skeleton_loadinfo(entity e)
  18 {
  19         int i;
  20         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  21                 return;
  22         e.bone_upperbody = 0;
  23         e.bone_weapon = gettagindex(e, "weapon");
  24         if(!e.bone_weapon)
  25                 e.bone_weapon = gettagindex(e, "tag_weapon");
  26         if(!e.bone_weapon)
  27                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  28         MUTATOR_CALLHOOK(Skeleton_CheckBones, e);
  29         for(i = 0; i < MAX_AIM_BONES; ++i)
  30         {
  31                 e.(bone_aim[i]) = 0;
  32                 e.(bone_aimweight[i]) = 0;
  33         }
  34         e.fixbone = 0;
  35         if(get_model_parameters(e.model, e.skin))
  36         {
  37                 if(get_model_parameters_bone_upperbody)
  38                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  39                 if(e.bone_upperbody)
  40                         e.fixbone = get_model_parameters_fixbone;
  41                 if(get_model_parameters_bone_weapon)
  42                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  43                 MUTATOR_CALLHOOK(Skeleton_CheckModel, e);
  44                 for(i = 0; i < MAX_AIM_BONES; ++i)
  45                 {
  46                         if(get_model_parameters_bone_aim[i])
  47                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  48                         if(e.bone_aim[i])
  49                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  50                 }
  51         }
  52         else
  53                 LOG_TRACE("No model parameters for ", e.model, "\n");
  54         //dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  55         get_model_parameters(string_null, 0);
  56         e.skeleton_info_modelindex = e.modelindex;
  57         e.skeleton_info_skin = e.skin;
  58         if(e.skeletonindex)
  59         {
  60                 skel_delete(e.skeletonindex);
  61                 e.skeletonindex = 0;
  62         }
  63 }
  64
  65 void skeleton_markbones(entity e)
  66 {
  67         float s = e.skeletonindex;
  68         float n = (e.skeleton_numbones = skel_get_numbones(s));
  69         int i;
  70         for(i = 1; i <= n; ++i)
  71         {
  72                 float t = BONETYPE_LOWER;
  73                 int p = skel_get_boneparent(s, i);
  74                 if(p > 0)
  75                         t = e.(skeleton_bonetype[p-1]);
  76                 if(i == e.bone_upperbody)
  77                         t = BONETYPE_UPPER;
  78                 e.(skeleton_bonetype[i-1]) = t;
  79         }
  80 }
  81
  82 void skel_set_boneabs(float s, int bone, vector absorg)
  83 {
  84     TC(int, bone);
  85         vector absang = fixedvectoangles2(v_forward, v_up);
  86
  87         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  88         vector parentang = fixedvectoangles2(v_forward, v_up);
  89
  90         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  91         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  92
  93         fixedmakevectors(relang);
  94         skel_set_bone(s, bone, relorg);
  95
  96         /*
  97         vector neworg = skel_get_boneabs(s, bone);
  98         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
  99         printf("ORG: want: %v, got: %v\n", absorg, neworg);
 100         */
 101 }
 102
 103 void free_skeleton_from_frames(entity e)
 104 {
 105         if(e.skeletonindex)
 106         {
 107                 skel_delete(e.skeletonindex);
 108                 e.skeletonindex = 0;
 109         }
 110 }
 111
 112 void skeleton_from_frames(entity e, bool is_dead)
 113 {
 114     TC(bool, is_dead);
 115         float m = e.modelindex;
 116         if(!e.skeletonindex)
 117         {
 118                 e.skeletonindex = skel_create(m);
 119                 skeleton_markbones(e);
 120         }
 121         float s = e.skeletonindex;
 122         if(!s)
 123                 return;
 124         float n = e.skeleton_numbones;
 125         float savelerpfrac = e.lerpfrac;
 126         float savelerpfrac3 = e.lerpfrac3;
 127         float savelerpfrac4 = e.lerpfrac4;
 128
 129         vector fixbone_oldangles = '0 0 0';
 130         if(e.fixbone)
 131         {
 132                 // make all bones BONETYPE_UPPER
 133                 e.lerpfrac = 0;
 134                 e.lerpfrac3 = savelerpfrac3 * 2;
 135                 e.lerpfrac4 = 0;
 136                 // build skeleton
 137                 skel_build(s, e, m, 0, 1, n);
 138                 // get hip bone
 139                 skel_get_boneabs(s, e.bone_upperbody);
 140                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 141         }
 142         int bone;
 143         for(bone = 0; bone < n; )
 144         {
 145                 float firstbone = bone;
 146                 float bonetype = e.skeleton_bonetype[bone];
 147                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 148                         ;
 149                 if(bonetype == BONETYPE_UPPER)
 150                 {
 151                         // only show frames 1+3 (upper body)
 152                         e.lerpfrac = 0;
 153                         e.lerpfrac3 = savelerpfrac3 * 2;
 154                         e.lerpfrac4 = 0;
 155                 }
 156                 else
 157                 {
 158                         // only show frames 2+4 (lower body)
 159                         e.lerpfrac = savelerpfrac * 2;
 160                         e.lerpfrac3 = 0;
 161                         e.lerpfrac4 = savelerpfrac4 * 2;
 162                 }
 163                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 164                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 165                 skel_build(s, e, m, 0, firstbone + 1, bone);
 166         }
 167         e.lerpfrac = savelerpfrac;
 168         e.lerpfrac3 = savelerpfrac3;
 169         e.lerpfrac4 = savelerpfrac4;
 170
 171         if(e.fixbone)
 172         {
 173                 // FIX IT
 174                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 175                 fixedmakevectors(fixbone_oldangles);
 176                 skel_set_boneabs(s, e.bone_upperbody, org);
 177         }
 178
 179         if(!is_dead)
 180         {
 181                 if(e == csqcplayer && !intermission)
 182                         e.v_angle_x = input_angles_x;
 183                 int i;
 184                 for(i = 0; i < MAX_AIM_BONES; ++i)
 185                 {
 186                         if(e.(bone_aim[i]))
 187                         {
 188                                 vector aim = '1 0 0' * bound(-90, e.v_angle.x, 90) * e.(bone_aimweight[i]);
 189                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 190                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 191                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 192                                 fixedmakevectors(ang);
 193                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 194                         }
 195                 }
 196         }
 197 }