qcsrc/client/player_skeleton.qc

   1 #include "player_skeleton.qh"
   2
   3 #include "mutators/events.qh"
   4 #include "../lib/csqcmodel/cl_player.qh"
   5 #include "../lib/warpzone/anglestransform.qh"
   6
   7 .vector v_angle;
   8
   9 class(Skeleton) .float skeleton_info_modelindex;
  10 class(Skeleton) .float skeleton_info_skin;
  11 const int BONETYPE_LOWER = 0;
  12 const int BONETYPE_UPPER = 1;
  13 const int MAX_BONES = 128;
  14 class(Skeleton) .float skeleton_bonetype[MAX_BONES];
  15 class(Skeleton) .float skeleton_numbones;
  16
  17 void skeleton_loadinfo(entity e)
  18 {
  19         int i;
  20         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  21                 return;
  22         e.bone_upperbody = 0;
  23         e.bone_weapon = gettagindex(e, "weapon");
  24         if(!e.bone_weapon)
  25                 e.bone_weapon = gettagindex(e, "tag_weapon");
  26         if(!e.bone_weapon)
  27                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  28         MUTATOR_CALLHOOK(Skeleton_CheckBones, e);
  29         for(i = 0; i < MAX_AIM_BONES; ++i)
  30         {
  31                 e.(bone_aim[i]) = 0;
  32                 e.(bone_aimweight[i]) = 0;
  33         }
  34         e.fixbone = 0;
  35         if(get_model_parameters(e.model, e.skin))
  36         {
  37                 if(get_model_parameters_bone_upperbody)
  38                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  39                 if(e.bone_upperbody)
  40                         e.fixbone = get_model_parameters_fixbone;
  41                 if(get_model_parameters_bone_weapon)
  42                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  43                 MUTATOR_CALLHOOK(Skeleton_CheckModel, e);
  44                 for(i = 0; i < MAX_AIM_BONES; ++i)
  45                 {
  46                         if(get_model_parameters_bone_aim[i])
  47                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  48                         if(e.bone_aim[i])
  49                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  50                 }
  51         }
  52         else
  53                 LOG_TRACE("No model parameters for ", e.model, "\n");
  54         //dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  55         get_model_parameters(string_null, 0);
  56         e.skeleton_info_modelindex = e.modelindex;
  57         e.skeleton_info_skin = e.skin;
  58         if(e.skeletonindex)
  59         {
  60                 skel_delete(e.skeletonindex);
  61                 e.skeletonindex = 0;
  62         }
  63 }
  64
  65 void skeleton_markbones(entity e)
  66 {
  67         float s = e.skeletonindex;
  68         float n = (e.skeleton_numbones = skel_get_numbones(s));
  69         int i;
  70         for(i = 1; i <= n; ++i)
  71         {
  72                 float t = BONETYPE_LOWER;
  73                 int p = skel_get_boneparent(s, i);
  74                 if(p > 0)
  75                         t = e.(skeleton_bonetype[p-1]);
  76                 if(i == e.bone_upperbody)
  77                         t = BONETYPE_UPPER;
  78                 e.(skeleton_bonetype[i-1]) = t;
  79         }
  80 }
  81
  82 void skel_set_boneabs(float s, float bone, vector absorg)
  83 {
  84         vector absang = fixedvectoangles2(v_forward, v_up);
  85
  86         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  87         vector parentang = fixedvectoangles2(v_forward, v_up);
  88
  89         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  90         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  91
  92         fixedmakevectors(relang);
  93         skel_set_bone(s, bone, relorg);
  94
  95         /*
  96         vector neworg = skel_get_boneabs(s, bone);
  97         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
  98         printf("ORG: want: %v, got: %v\n", absorg, neworg);
  99         */
 100 }
 101
 102 void free_skeleton_from_frames(entity e)
 103 {
 104         if(e.skeletonindex)
 105         {
 106                 skel_delete(e.skeletonindex);
 107                 e.skeletonindex = 0;
 108         }
 109 }
 110
 111 void skeleton_from_frames(entity e, float is_dead)
 112 {SELFPARAM();
 113         float m = e.modelindex;
 114         if(!e.skeletonindex)
 115         {
 116                 e.skeletonindex = skel_create(m);
 117                 skeleton_markbones(e);
 118         }
 119         float s = e.skeletonindex;
 120         if(!s)
 121                 return;
 122         float n = e.skeleton_numbones;
 123         float savelerpfrac = e.lerpfrac;
 124         float savelerpfrac3 = e.lerpfrac3;
 125         float savelerpfrac4 = e.lerpfrac4;
 126
 127         vector fixbone_oldangles = '0 0 0';
 128         if(e.fixbone)
 129         {
 130                 // make all bones BONETYPE_UPPER
 131                 e.lerpfrac = 0;
 132                 e.lerpfrac3 = savelerpfrac3 * 2;
 133                 e.lerpfrac4 = 0;
 134                 // build skeleton
 135                 skel_build(s, e, m, 0, 1, n);
 136                 // get hip bone
 137                 skel_get_boneabs(s, e.bone_upperbody);
 138                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 139         }
 140         int bone;
 141         for(bone = 0; bone < n; )
 142         {
 143                 float firstbone = bone;
 144                 float bonetype = e.skeleton_bonetype[bone];
 145                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 146                         ;
 147                 if(bonetype == BONETYPE_UPPER)
 148                 {
 149                         // only show frames 1+3 (upper body)
 150                         e.lerpfrac = 0;
 151                         e.lerpfrac3 = savelerpfrac3 * 2;
 152                         e.lerpfrac4 = 0;
 153                 }
 154                 else
 155                 {
 156                         // only show frames 2+4 (lower body)
 157                         e.lerpfrac = savelerpfrac * 2;
 158                         e.lerpfrac3 = 0;
 159                         e.lerpfrac4 = savelerpfrac4 * 2;
 160                 }
 161                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 162                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 163                 skel_build(s, e, m, 0, firstbone + 1, bone);
 164         }
 165         e.lerpfrac = savelerpfrac;
 166         e.lerpfrac3 = savelerpfrac3;
 167         e.lerpfrac4 = savelerpfrac4;
 168
 169         if(e.fixbone)
 170         {
 171                 // FIX IT
 172                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 173                 fixedmakevectors(fixbone_oldangles);
 174                 skel_set_boneabs(s, e.bone_upperbody, org);
 175         }
 176
 177         if(!is_dead)
 178         {
 179                 if(self == csqcplayer)
 180                         self.v_angle_x = input_angles_x;
 181                 int i;
 182                 for(i = 0; i < MAX_AIM_BONES; ++i)
 183                 {
 184                         if(e.(bone_aim[i]))
 185                         {
 186                                 vector aim = '1 0 0' * bound(-90, self.v_angle.x, 90) * e.(bone_aimweight[i]);
 187                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 188                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 189                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 190                                 fixedmakevectors(ang);
 191                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 192                         }
 193                 }
 194         }
 195 }