qcsrc/client/player_skeleton.qc

   1 #include "player_skeleton.qh"
   2
   3 #include "../common/csqcmodel_settings.qh"
   4
   5 #include "../warpzonelib/anglestransform.qh"
   6
   7 class(Skeleton) .float skeleton_info_modelindex;
   8 class(Skeleton) .float skeleton_info_skin;
   9 const int BONETYPE_LOWER = 0;
  10 const int BONETYPE_UPPER = 1;
  11 const int MAX_BONES = 128;
  12 class(Skeleton) .float skeleton_bonetype[MAX_BONES];
  13 class(Skeleton) .float skeleton_numbones;
  14
  15 void skeleton_loadinfo(entity e)
  16 {
  17         int i;
  18         if(e.skeleton_info_modelindex == e.modelindex && e.skeleton_info_skin == e.skin)
  19                 return;
  20         e.bone_upperbody = 0;
  21         e.bone_weapon = gettagindex(e, "weapon");
  22         if(!e.bone_weapon)
  23                 e.bone_weapon = gettagindex(e, "tag_weapon");
  24         if(!e.bone_weapon)
  25                 e.bone_weapon = gettagindex(e, "bip01 r hand");
  26         MUTATOR_CALLHOOK(Skeleton_CheckBones, e);
  27         for(i = 0; i < MAX_AIM_BONES; ++i)
  28         {
  29                 e.(bone_aim[i]) = 0;
  30                 e.(bone_aimweight[i]) = 0;
  31         }
  32         e.fixbone = 0;
  33         if(get_model_parameters(e.model, e.skin))
  34         {
  35                 if(get_model_parameters_bone_upperbody)
  36                         e.bone_upperbody = gettagindex(e, get_model_parameters_bone_upperbody);
  37                 if(e.bone_upperbody)
  38                         e.fixbone = get_model_parameters_fixbone;
  39                 if(get_model_parameters_bone_weapon)
  40                         e.bone_weapon = gettagindex(e, get_model_parameters_bone_weapon);
  41                 MUTATOR_CALLHOOK(Skeleton_CheckModel, e);
  42                 for(i = 0; i < MAX_AIM_BONES; ++i)
  43                 {
  44                         if(get_model_parameters_bone_aim[i])
  45                                 e.(bone_aim[i]) = gettagindex(e, get_model_parameters_bone_aim[i]);
  46                         if(e.bone_aim[i])
  47                                 e.(bone_aimweight[i]) = get_model_parameters_bone_aimweight[i];
  48                 }
  49         }
  50         else
  51                 LOG_TRACE("No model parameters for ", e.model, "\n");
  52         //dprint(e.model, " uses ", ftos(e.bone_upperbody), " ", ftos(e.fixbone), "\n");
  53         get_model_parameters(string_null, 0);
  54         e.skeleton_info_modelindex = e.modelindex;
  55         e.skeleton_info_skin = e.skin;
  56         if(e.skeletonindex)
  57         {
  58                 skel_delete(e.skeletonindex);
  59                 e.skeletonindex = 0;
  60         }
  61 }
  62
  63 void skeleton_markbones(entity e)
  64 {
  65         float s = e.skeletonindex;
  66         float n = (e.skeleton_numbones = skel_get_numbones(s));
  67         int i;
  68         for(i = 1; i <= n; ++i)
  69         {
  70                 float t = BONETYPE_LOWER;
  71                 int p = skel_get_boneparent(s, i);
  72                 if(p > 0)
  73                         t = e.(skeleton_bonetype[p-1]);
  74                 if(i == e.bone_upperbody)
  75                         t = BONETYPE_UPPER;
  76                 e.(skeleton_bonetype[i-1]) = t;
  77         }
  78 }
  79
  80 void skel_set_boneabs(float s, float bone, vector absorg)
  81 {
  82         vector absang = fixedvectoangles2(v_forward, v_up);
  83
  84         vector parentorg = skel_get_boneabs(s, skel_get_boneparent(s, bone));
  85         vector parentang = fixedvectoangles2(v_forward, v_up);
  86
  87         vector relang = AnglesTransform_LeftDivide(parentang, absang);
  88         vector relorg = AnglesTransform_Apply(AnglesTransform_Invert(parentang), absorg - parentorg);
  89
  90         fixedmakevectors(relang);
  91         skel_set_bone(s, bone, relorg);
  92
  93         /*
  94         vector neworg = skel_get_boneabs(s, bone);
  95         printf("ANG: want: %v, got: %v\n", absang, fixedvectoangles2(v_forward, v_up));
  96         printf("ORG: want: %v, got: %v\n", absorg, neworg);
  97         */
  98 }
  99
 100 void free_skeleton_from_frames(entity e)
 101 {
 102         if(e.skeletonindex)
 103         {
 104                 skel_delete(e.skeletonindex);
 105                 e.skeletonindex = 0;
 106         }
 107 }
 108
 109 void skeleton_from_frames(entity e, float is_dead)
 110 {SELFPARAM();
 111         float m = e.modelindex;
 112         if(!e.skeletonindex)
 113         {
 114                 e.skeletonindex = skel_create(m);
 115                 skeleton_markbones(e);
 116         }
 117         float s = e.skeletonindex;
 118         if(!s)
 119                 return;
 120         float n = e.skeleton_numbones;
 121         float savelerpfrac = e.lerpfrac;
 122         float savelerpfrac3 = e.lerpfrac3;
 123         float savelerpfrac4 = e.lerpfrac4;
 124
 125         vector fixbone_oldangles = '0 0 0';
 126         if(e.fixbone)
 127         {
 128                 // make all bones BONETYPE_UPPER
 129                 e.lerpfrac = 0;
 130                 e.lerpfrac3 = savelerpfrac3 * 2;
 131                 e.lerpfrac4 = 0;
 132                 // build skeleton
 133                 skel_build(s, e, m, 0, 1, n);
 134                 // get hip bone
 135                 skel_get_boneabs(s, e.bone_upperbody);
 136                 fixbone_oldangles = fixedvectoangles2(v_forward, v_up);
 137         }
 138         int bone;
 139         for(bone = 0; bone < n; )
 140         {
 141                 float firstbone = bone;
 142                 float bonetype = e.skeleton_bonetype[bone];
 143                 for(++bone; (bone < n) && (e.skeleton_bonetype[bone] == bonetype); ++bone)
 144                         ;
 145                 if(bonetype == BONETYPE_UPPER)
 146                 {
 147                         // only show frames 1+3 (upper body)
 148                         e.lerpfrac = 0;
 149                         e.lerpfrac3 = savelerpfrac3 * 2;
 150                         e.lerpfrac4 = 0;
 151                 }
 152                 else
 153                 {
 154                         // only show frames 2+4 (lower body)
 155                         e.lerpfrac = savelerpfrac * 2;
 156                         e.lerpfrac3 = 0;
 157                         e.lerpfrac4 = savelerpfrac4 * 2;
 158                 }
 159                 //printf("Run: bone %d to %d, type %d\n", firstbone + 1, bone, bonetype);
 160                 //printf("frame %d %d %d %d lerpfrac * %d %d %d\n", e.frame, e.frame2, e.frame3, e.frame4, e.lerpfrac, e.lerpfrac3, e.lerpfrac4);
 161                 skel_build(s, e, m, 0, firstbone + 1, bone);
 162         }
 163         e.lerpfrac = savelerpfrac;
 164         e.lerpfrac3 = savelerpfrac3;
 165         e.lerpfrac4 = savelerpfrac4;
 166
 167         if(e.fixbone)
 168         {
 169                 // FIX IT
 170                 vector org = skel_get_boneabs(s, e.bone_upperbody);
 171                 fixedmakevectors(fixbone_oldangles);
 172                 skel_set_boneabs(s, e.bone_upperbody, org);
 173         }
 174
 175         if(!is_dead)
 176         {
 177                 if(self == csqcplayer)
 178                         self.v_angle_x = input_angles_x;
 179                 int i;
 180                 for(i = 0; i < MAX_AIM_BONES; ++i)
 181                 {
 182                         if(e.(bone_aim[i]))
 183                         {
 184                                 vector aim = '1 0 0' * bound(-90, self.v_angle.x, 90) * e.(bone_aimweight[i]);
 185                                 vector org = skel_get_boneabs(s, e.(bone_aim[i]));
 186                                 vector ang_cur = fixedvectoangles2(v_forward, v_up);
 187                                 vector ang = AnglesTransform_Multiply(aim, ang_cur);
 188                                 fixedmakevectors(ang);
 189                                 skel_set_boneabs(s, e.(bone_aim[i]), org);
 190                         }
 191                 }
 192         }
 193 }