qcsrc/client/projectile.qc

   1 .vector iorigin1, iorigin2;
   2 .float spawntime;
   3 .vector trail_oldorigin;
   4 .float trail_oldtime;
   5 .float fade_time, fade_rate;
   6
   7 void SUB_Null()
   8 {
   9 }
  10
  11 void SUB_Stop()
  12 {
  13         self.move_velocity = self.move_avelocity = '0 0 0';
  14         self.move_movetype = MOVETYPE_NONE;
  15 }
  16
  17 .float alphamod;
  18 .float count; // set if clientside projectile
  19 .float cnt; // sound index
  20 .float gravity;
  21 .float snd_looping;
  22 .float silent;
  23 .float traileffect;
  24
  25 void Projectile_ResetTrail(vector to)
  26 {
  27         self.trail_oldorigin = to;
  28         self.trail_oldtime = time;
  29 }
  30 void Projectile_DrawTrail(vector to)
  31 {
  32         vector from;
  33         float t0;
  34         from = self.trail_oldorigin;
  35         t0 = self.trail_oldtime;
  36         self.trail_oldorigin = to;
  37         self.trail_oldtime = time;
  38
  39         // force the effect even for stationary firemine
  40         if(self.cnt == PROJECTILE_FIREMINE)
  41                 if(from == to)
  42                         from_z += 1;
  43
  44         if (self.traileffect)
  45         {
  46                 particles_alphamin = particles_alphamax = sqrt(self.alpha);
  47                 boxparticles(self.traileffect, self, from, to, self.velocity, self.velocity, sqrt(self.alpha), PARTICLES_USEALPHA);
  48         }
  49 }
  50
  51 void Projectile_Draw()
  52 {
  53         vector rot;
  54         vector trailorigin;
  55         float f;
  56         float drawn;
  57         float t;
  58         float a;
  59
  60         f = self.move_flags;
  61
  62         if(self.count & 0x80)
  63         {
  64                 //self.move_flags &~= FL_ONGROUND;
  65                 if(self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  66                         Movetype_Physics_NoMatchServer();
  67                         // the trivial movetypes do not have to match the
  68                         // server's ticrate as they are ticrate independent
  69                         // NOTE: this assumption is only true if MOVETYPE_FLY
  70                         // projectiles detonate on impact. If they continue
  71                         // moving, we might still be ticrate dependent.
  72                 else
  73                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74                 if(!(self.move_flags & FL_ONGROUND))
  75                         if(self.velocity != '0 0 0')
  76                                 self.angles = vectoangles(self.velocity);
  77         }
  78         else
  79         {
  80                 InterpolateOrigin_Do();
  81         }
  82
  83         if(self.count & 0x80)
  84         {
  85                 drawn = (time >= self.spawntime - 0.02);
  86                 t = max(time, self.spawntime);
  87         }
  88         else
  89         {
  90                 drawn = (self.iflags & IFLAG_VALID);
  91                 t = time;
  92         }
  93
  94         if(!(f & FL_ONGROUND))
  95         {
  96                 rot = '0 0 0';
  97                 switch(self.cnt)
  98                 {
  99                         /*
 100                         case PROJECTILE_GRENADE:
 101                                 rot = '-2000 0 0'; // forward
 102                                 break;
 103                         */
 104                         case PROJECTILE_GRENADE_BOUNCING:
 105                                 rot = '0 -1000 0'; // sideways
 106                                 break;
 107                         case PROJECTILE_HOOKBOMB:
 108                                 rot = '1000 0 0'; // forward
 109                                 break;
 110                         default:
 111                                 break;
 112                 }
 113                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 114         }
 115
 116         vector ang;
 117         ang = self.angles;
 118         ang_x = -ang_x;
 119         makevectors(ang);
 120
 121         a = 1 - (time - self.fade_time) * self.fade_rate;
 122         self.alpha = bound(0, self.alphamod * a, 1);
 123         if(self.alpha <= 0)
 124                 drawn = 0;
 125         self.renderflags = 0;
 126
 127         trailorigin = self.origin;
 128         switch(self.cnt)
 129         {
 130                 case PROJECTILE_GRENADE:
 131                 case PROJECTILE_GRENADE_BOUNCING:
 132                         trailorigin += v_right * 1 + v_forward * -10;
 133                         break;
 134                 default:
 135                         break;
 136         }
 137         if(drawn)
 138                 Projectile_DrawTrail(trailorigin);
 139         else
 140                 Projectile_ResetTrail(trailorigin);
 141
 142         self.drawmask = 0;
 143
 144         if(!drawn)
 145                 return;
 146
 147         switch(self.cnt)
 148         {
 149                 case PROJECTILE_BULLET_GLOWING:
 150                 case PROJECTILE_BULLET_GLOWING_TRACER:
 151                         R_AddDynamicLight(self.origin, 50 * a, '1 1 0');
 152                         break;
 153                 default:
 154                         break;
 155         }
 156
 157         self.drawmask = MASK_NORMAL;
 158 }
 159
 160 void loopsound(entity e, float ch, string samp, float vol, float attn)
 161 {
 162         if(self.silent)
 163                 return;
 164
 165         sound(e, ch, samp, vol, attn);
 166         e.snd_looping = 1;
 167 }
 168
 169 void Ent_RemoveProjectile()
 170 {
 171         if(self.snd_looping)
 172                 sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 173
 174         if(self.count & 0x80)
 175         {
 176                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 177                 Projectile_DrawTrail(trace_endpos);
 178         }
 179 }
 180
 181 void Ent_Projectile()
 182 {
 183         float f;
 184
 185         // projectile properties:
 186         //   kind (interpolated, or clientside)
 187         //
 188         //   modelindex
 189         //   origin
 190         //   scale
 191         //   if clientside:
 192         //     velocity
 193         //     gravity
 194         //   soundindex (hardcoded list)
 195         //   effects
 196         //
 197         // projectiles don't send angles, because they always follow the velocity
 198
 199         f = ReadByte();
 200         self.count = (f & 0x80);
 201         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 202         self.solid = SOLID_TRIGGER;
 203         //self.effects = EF_NOMODELFLAGS;
 204
 205         // this should make collisions with bmodels more exact, but it leads to
 206         // projectiles no longer being able to lie on a bmodel
 207         self.move_nomonsters = MOVE_WORLDONLY;
 208         if(f & 0x40)
 209                 self.move_flags |= FL_ONGROUND;
 210         else
 211                 self.move_flags &~= FL_ONGROUND;
 212
 213         if(!self.move_time)
 214         {
 215                 // for some unknown reason, we don't need to care for
 216                 // sv_gameplayfix_delayprojectiles here.
 217                 self.move_time = time;
 218                 self.spawntime = time;
 219         }
 220         else
 221                 self.move_time = max(self.move_time, time);
 222
 223         if(!(self.count & 0x80))
 224                 InterpolateOrigin_Undo();
 225
 226         if(f & 1)
 227         {
 228                 self.origin_x = ReadCoord();
 229                 self.origin_y = ReadCoord();
 230                 self.origin_z = ReadCoord();
 231                 if(self.count & 0x80)
 232                 {
 233                         self.velocity_x = ReadCoord();
 234                         self.velocity_y = ReadCoord();
 235                         self.velocity_z = ReadCoord();
 236                         if(f & 0x10)
 237                                 self.gravity = ReadCoord();
 238                         else
 239                                 self.gravity = 0; // none
 240                         self.move_origin = self.origin;
 241                         self.move_velocity = self.velocity;
 242                 }
 243
 244                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 245                 {
 246                         self.trail_oldorigin = self.origin;
 247                         if(!(self.count & 0x80))
 248                                 InterpolateOrigin_Reset();
 249                 }
 250
 251                 if(f & 0x20)
 252                 {
 253                         self.fade_time = time + ReadByte() * ticrate;
 254                         self.fade_rate = 1 / (ReadByte() * ticrate);
 255                 }
 256                 else
 257                 {
 258                         self.fade_time = 0;
 259                         self.fade_rate = 0;
 260                 }
 261         }
 262
 263         if(f & 2)
 264         {
 265                 self.cnt = ReadByte();
 266
 267                 self.silent = (self.cnt & 0x80);
 268                 self.cnt = (self.cnt & 0x7F);
 269
 270                 self.scale = 1;
 271                 self.traileffect = 0;
 272                 switch(self.cnt)
 273                 {
 274                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 275                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); self.scale = 2; break;
 276                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl");self.traileffect = particleeffectnum("tr_bullet"); break;
 277                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl");self.traileffect = particleeffectnum("tr_bullet"); break;
 278                         case PROJECTILE_BULLET_GLOWING_TRACER: setmodel(self, "models/tracer.mdl");self.traileffect = particleeffectnum("tr_rifle"); break;
 279                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 280                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 281                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 282                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 283                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 284                         case PROJECTILE_MINE: setmodel(self, "models/mine.md3");self.traileffect = particleeffectnum(""); break;
 285                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl");self.traileffect = particleeffectnum(""); break;
 286                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3");self.traileffect = particleeffectnum(""); break;
 287                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 288                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 289                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_KNIGHTSPIKE"); break;
 290                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("TR_GRENADE"); self.scale = 0.4; break;
 291                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("TR_GRENADE"); self.scale = 0.4; break;
 292                         case PROJECTILE_FIREBALL: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("fireball"); break; // particle effect is good enough
 293                         case PROJECTILE_FIREMINE: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("firemine"); break; // particle effect is good enough
 294                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); self.traileffect = particleeffectnum("TR_ROCKET"); break;
 295                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; self.traileffect = particleeffectnum("TR_ROCKET"); break;
 296                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; self.traileffect = particleeffectnum("TR_ROCKET"); break;
 297                         default:
 298                                 error("Received invalid CSQC projectile, can't work with this!");
 299                                 break;
 300                 }
 301
 302                 self.mins = '0 0 0';
 303                 self.maxs = '0 0 0';
 304                 self.colormod = '0 0 0';
 305                 self.move_touch = SUB_Stop;
 306                 self.move_movetype = MOVETYPE_TOSS;
 307                 self.alphamod = 1;
 308
 309                 switch(self.cnt)
 310                 {
 311                         case PROJECTILE_ELECTRO:
 312                                 // only new engines support sound moving with object
 313                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 314                                 self.mins = '0 0 -4';
 315                                 self.maxs = '0 0 -4';
 316                                 self.move_movetype = MOVETYPE_BOUNCE;
 317                                 self.move_touch = SUB_Null;
 318                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 319                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 320                                 break;
 321                         case PROJECTILE_ROCKET:
 322                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 323                                 self.mins = '-3 -3 -3';
 324                                 self.maxs = '3 3 3';
 325                                 break;
 326                         case PROJECTILE_GRENADE:
 327                                 self.mins = '-3 -3 -3';
 328                                 self.maxs = '3 3 3';
 329                                 break;
 330                         case PROJECTILE_GRENADE_BOUNCING:
 331                                 self.mins = '-3 -3 -3';
 332                                 self.maxs = '3 3 3';
 333                                 self.move_movetype = MOVETYPE_BOUNCE;
 334                                 self.move_touch = SUB_Null;
 335                                 self.move_bounce_factor = g_balance_grenadelauncher_bouncefactor;
 336                                 self.move_bounce_stopspeed = g_balance_grenadelauncher_bouncestop;
 337                                 break;
 338                         case PROJECTILE_MINE:
 339                                 self.mins = '-4 -4 -4';
 340                                 self.maxs = '4 4 4';
 341                                 break;
 342                         case PROJECTILE_PORTO_RED:
 343                                 self.colormod = '2 1 1';
 344                                 self.alphamod = 0.5;
 345                                 self.move_movetype = MOVETYPE_BOUNCE;
 346                                 self.move_touch = SUB_Null;
 347                                 break;
 348                         case PROJECTILE_PORTO_BLUE:
 349                                 self.colormod = '1 1 2';
 350                                 self.alphamod = 0.5;
 351                                 self.move_movetype = MOVETYPE_BOUNCE;
 352                                 self.move_touch = SUB_Null;
 353                                 break;
 354                         case PROJECTILE_HAGAR_BOUNCING:
 355                                 self.move_movetype = MOVETYPE_BOUNCE;
 356                                 self.move_touch = SUB_Null;
 357                                 break;
 358                         case PROJECTILE_CRYLINK_BOUNCING:
 359                                 self.move_movetype = MOVETYPE_BOUNCE;
 360                                 self.move_touch = SUB_Null;
 361                                 break;
 362                         case PROJECTILE_FIREBALL:
 363                                 loopsound(self, CHAN_PROJECTILE, "weapons/fireball_fly2.wav", VOL_BASE, ATTN_NORM);
 364                                 self.mins = '-16 -16 -16';
 365                                 self.maxs = '16 16 16';
 366                                 break;
 367                         case PROJECTILE_FIREMINE:
 368                                 loopsound(self, CHAN_PROJECTILE, "weapons/fireball_fly.wav", VOL_BASE, ATTN_NORM);
 369                                 self.move_movetype = MOVETYPE_BOUNCE;
 370                                 self.move_touch = SUB_Null;
 371                                 self.mins = '-4 -4 -4';
 372                                 self.maxs = '4 4 4';
 373                                 break;
 374                         case PROJECTILE_TAG:
 375                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 376                                 self.mins = '-2 -2 -2';
 377                                 self.maxs = '2 2 2';
 378                                 break;
 379                         case PROJECTILE_FLAC:
 380                                 self.mins = '-2 -2 -2';
 381                                 self.maxs = '2 2 2';
 382                                 break;
 383                         case PROJECTILE_SEEKER:
 384                                 self.mins = '-4 -4 -4';
 385                                 self.maxs = '4 4 4';
 386                                 break;
 387                         default:
 388                                 break;
 389                 }
 390         }
 391
 392         if(self.gravity)
 393         {
 394                 if(self.move_movetype == MOVETYPE_FLY)
 395                         self.move_movetype = MOVETYPE_TOSS;
 396                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 397                         self.move_movetype = MOVETYPE_BOUNCE;
 398         }
 399         else
 400         {
 401                 if(self.move_movetype == MOVETYPE_TOSS)
 402                         self.move_movetype = MOVETYPE_FLY;
 403                 if(self.move_movetype == MOVETYPE_BOUNCE)
 404                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 405         }
 406
 407         if(!(self.count & 0x80))
 408                 InterpolateOrigin_Note();
 409
 410         self.draw = Projectile_Draw;
 411         self.entremove = Ent_RemoveProjectile;
 412 }
 413
 414 void Projectile_Precache()
 415 {
 416         precache_model("models/ebomb.mdl");
 417         precache_model("models/elaser.mdl");
 418         precache_model("models/grenademodel.md3");
 419         precache_model("models/mine.md3");
 420         precache_model("models/hagarmissile.mdl");
 421         precache_model("models/hlac_bullet.md3");
 422         precache_model("models/laser.mdl");
 423         precache_model("models/plasmatrail.mdl");
 424         precache_model("models/rocket.md3");
 425         precache_model("models/tagrocket.md3");
 426         precache_model("models/tracer.mdl");
 427         precache_sound("weapons/electro_fly.wav");
 428         precache_sound("weapons/rocket_fly.wav");
 429         precache_sound("weapons/fireball_fly.wav");
 430         precache_sound("weapons/fireball_fly2.wav");
 431         precache_sound("weapons/tag_rocket_fly.wav");
 432 }