qcsrc/client/quickmenu.qc

   1 #include "_all.qh"
   2
   3 #include "hud_config.qh"
   4
   5 #include "../dpdefs/keycodes.qh"
   6
   7 // QUICKMENU_MAXLINES must be <= 10
   8 const int QUICKMENU_MAXLINES = 10;
   9 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  10 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  11 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  12 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  13 int QuickMenu_Page_Entries;
  14 int QuickMenu_Page;
  15 int QuickMenu_Page_ActivatedEntry = -1;
  16 bool QuickMenu_Page_ActivatedEntry_Close;
  17 float QuickMenu_Page_ActivatedEntry_Time;
  18 bool QuickMenu_IsLastPage;
  19 // all the entries are loaded into QuickMenu_Buffer
  20 // each entry (submenu or command) is composed of 2 entries
  21 const int QUICKMENU_MAXENTRIES = 256;
  22 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  23 int QuickMenu_Buffer = -1;
  24 int QuickMenu_Buffer_Size;
  25 int QuickMenu_Buffer_Index;
  26 string QuickMenu_CurrentSubMenu;
  27 float QuickMenu_TimeOut;
  28 // if s1 is not empty s will be displayed as command otherwise as submenu
  29 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  30 {
  31         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  32         if (QuickMenu_Page_Description[i])
  33                 strunzone(QuickMenu_Page_Description[i]);
  34         QuickMenu_Page_Description[i] = strzone(s);
  35         if (QuickMenu_Page_Command[i])
  36                 strunzone(QuickMenu_Page_Command[i]);
  37         QuickMenu_Page_Command[i] = strzone(s1);
  38 }
  39
  40 void QuickMenu_Page_ClearEntry(int i)
  41 {
  42         if (QuickMenu_Page_Description[i])
  43                 strunzone(QuickMenu_Page_Description[i]);
  44         QuickMenu_Page_Description[i] = string_null;
  45         if (QuickMenu_Page_Command[i])
  46                 strunzone(QuickMenu_Page_Command[i]);
  47         QuickMenu_Page_Command[i] = string_null;
  48 }
  49
  50 float QuickMenu_Page_Load(string target_submenu, float new_page);
  51 void QuickMenu_Default(string submenu);
  52 bool QuickMenu_Open(string mode, string submenu)
  53 {
  54         int fh = -1;
  55         string s;
  56
  57         if(mode == "")
  58         {
  59                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  60                         mode = "default";
  61                 else
  62                         mode = "file";
  63         }
  64
  65         if(mode == "default")
  66         {
  67                 QuickMenu_Buffer = buf_create();
  68                 if(QuickMenu_Buffer < 0)
  69                         return false;
  70
  71                 QuickMenu_Default(submenu);
  72         }
  73         else if(mode == "file")
  74         {
  75                 if(autocvar_hud_panel_quickmenu_file != "")
  76                 if(autocvar_hud_panel_quickmenu_file != "0")
  77                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  78                 if(fh < 0)
  79                 {
  80                         printf("Couldn't open file \"%s\"\n", autocvar_hud_panel_quickmenu_file);
  81                         return false;
  82                 }
  83
  84                 QuickMenu_Buffer = buf_create();
  85                 if(QuickMenu_Buffer < 0)
  86                 {
  87                         fclose(fh);
  88                         return false;
  89                 }
  90
  91                 QuickMenu_Buffer_Size = 0;
  92                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
  93                 {
  94                         // first skip invalid entries, so we don't check them anymore
  95                         float argc;
  96                         argc = tokenize_console(s);
  97                         if(argc == 0 || argv(0) == "" || substring(argv(0), 0, 2) == "////")
  98                                 continue;
  99                         if(argc == 1)
 100                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 101                         else if(argc == 2)
 102                         {
 103                                 if(argv(1) == "")
 104                                         continue;
 105                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", argv(0))); // command Title
 106                                 ++QuickMenu_Buffer_Size;
 107                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", argv(1))); // command
 108                         }
 109                         else if(argc == 3)
 110                         {
 111                                 // check for special keywords
 112                                 float teamplayers = 0, without_me = 0;
 113                                 switch(argv(2))
 114                                 {
 115                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 116                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 117                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 118                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 119                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 120                                         default: continue;
 121                                 }
 122
 123                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 124                                 {
 125                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 126                                         ++QuickMenu_Buffer_Size;
 127                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); // command arguments
 128                                         ++QuickMenu_Buffer_Size;
 129                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", argv(1))); // command for each player
 130                                         ++QuickMenu_Buffer_Size;
 131                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 132                                 }
 133                         }
 134                         ++QuickMenu_Buffer_Size;
 135                 }
 136                 fclose(fh);
 137         }
 138         else
 139         {
 140                 printf("Unrecognized mode %s\n", mode);
 141                 return false;
 142         }
 143
 144         if (QuickMenu_Buffer_Size <= 0)
 145         {
 146                 buf_del(QuickMenu_Buffer);
 147                 QuickMenu_Buffer = -1;
 148                 return false;
 149         }
 150
 151         if(mode == "file")
 152                 QuickMenu_Page_Load(submenu, 0);
 153         else
 154                 QuickMenu_Page_Load("", 0);
 155
 156         hud_panel_quickmenu = 1;
 157         if(autocvar_hud_cursormode)
 158                 setcursormode(1);
 159         hudShiftState = 0;
 160
 161         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 162         return true;
 163 }
 164
 165 void QuickMenu_Buffer_Close()
 166 {
 167         if (QuickMenu_Buffer >= 0)
 168         {
 169                 buf_del(QuickMenu_Buffer);
 170                 QuickMenu_Buffer = -1;
 171                 QuickMenu_Buffer_Size = 0;
 172         }
 173 }
 174
 175 void QuickMenu_Close()
 176 {
 177         if (QuickMenu_CurrentSubMenu)
 178                 strunzone(QuickMenu_CurrentSubMenu);
 179         QuickMenu_CurrentSubMenu = string_null;
 180         int i;
 181         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 182                 QuickMenu_Page_ClearEntry(i);
 183         QuickMenu_Page_Entries = 0;
 184         hud_panel_quickmenu = 0;
 185         mouseClicked = 0;
 186         prevMouseClicked = 0;
 187         QuickMenu_Buffer_Close();
 188
 189         if(autocvar_hud_cursormode)
 190         if(!mv_active)
 191                 setcursormode(0);
 192 }
 193
 194 // It assumes submenu open tag is already detected
 195 void QuickMenu_skip_submenu(string submenu)
 196 {
 197         string s, z_submenu;
 198         z_submenu = strzone(submenu);
 199         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 200         {
 201                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 202                 if(substring(s, 0, 1) != "S")
 203                         continue;
 204                 if(substring(s, 1, -1) == z_submenu) // submenu end
 205                         break;
 206                 QuickMenu_skip_submenu(substring(s, 1, -1));
 207         }
 208         strunzone(z_submenu);
 209 }
 210
 211 bool QuickMenu_IsOpened()
 212 {
 213         return (QuickMenu_Page_Entries > 0);
 214 }
 215
 216 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, float without_me);
 217 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, float without_me)
 218 {
 219         int i;
 220         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 221                 QuickMenu_Page_ClearEntry(i);
 222         QuickMenu_Buffer_Close();
 223
 224         QuickMenu_Buffer = buf_create();
 225         if(QuickMenu_Buffer < 0)
 226                 return false;
 227
 228         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 229
 230         if(QuickMenu_Buffer_Size <= 0)
 231         {
 232                 buf_del(QuickMenu_Buffer);
 233                 QuickMenu_Buffer = -1;
 234                 return false;
 235         }
 236         return true;
 237 }
 238
 239 // new_page 0 means page 0, new_page != 0 means next page
 240 int QuickMenu_Buffer_Index_Prev;
 241 bool QuickMenu_Page_Load(string target_submenu, int new_page)
 242 {
 243         string s = string_null, cmd = string_null, z_submenu;
 244
 245         if (new_page == 0)
 246                 QuickMenu_Page = 0;
 247         else
 248                 ++QuickMenu_Page;
 249
 250         z_submenu = strzone(target_submenu);
 251         if (QuickMenu_CurrentSubMenu)
 252                 strunzone(QuickMenu_CurrentSubMenu);
 253         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 254
 255         QuickMenu_IsLastPage = true;
 256         QuickMenu_Page_Entries = 0;
 257
 258         QuickMenu_Buffer_Index = 0;
 259         if (z_submenu != "")
 260         {
 261                 // skip everything until the submenu open tag is found
 262                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 263                 {
 264                         s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 265                         if(substring(s, 0, 1) == "S" && substring(s, 1, -1) == z_submenu)
 266                         {
 267                                 // printf("^3 beginning of %s\n", z_submenu);
 268                                 ++QuickMenu_Buffer_Index;
 269                                 break; // target_submenu found!
 270                         }
 271                         // printf("^1 skipping %s\n", s);
 272                 }
 273                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 274                         printf("Couldn't find submenu \"%s\"\n", z_submenu);
 275         }
 276
 277         // only the last page can contain up to QUICKMENU_MAXLINES entries
 278         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 279         // so that the panel can show an empty row and "Continue..."
 280         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 281         int entry_num = 0; // counts entries in target_submenu
 282         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 283         {
 284                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 285
 286                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 287                 {
 288                         // printf("^3 end of %s\n", z_submenu);
 289                         break;
 290                 }
 291
 292                 if(entry_num >= first_entry)
 293                 {
 294                         ++QuickMenu_Page_Entries;
 295                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 296                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 297                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 298                         {
 299                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 300                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 301                                 QuickMenu_IsLastPage = false;
 302                                 break;
 303                         }
 304                 }
 305
 306                 // NOTE: entries are loaded starting from 1, not from 0
 307                 if(substring(s, 0, 1) == "S") // submenu
 308                 {
 309                         if(entry_num >= first_entry)
 310                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 311                         QuickMenu_skip_submenu(substring(s, 1, -1));
 312                 }
 313                 else if(entry_num >= first_entry && substring(s, 0, 1) == "T")
 314                 {
 315                         ++QuickMenu_Buffer_Index;
 316                         cmd = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 317                         string command_code = substring(cmd, 0, 1);
 318                         if(command_code == "C")
 319                                 cmd = substring(cmd, 1, -1);
 320                         else if(command_code == "P")
 321                         {
 322                                 // throw away the current quickmenu buffer and load a new one
 323                                 cmd = substring(cmd, 1, -1);
 324                                 strunzone(z_submenu);
 325                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 326                                         return QuickMenu_Page_Load("", 0);
 327                                 QuickMenu_Close();
 328                                 return false;
 329                         }
 330
 331                         tokenize_console(cmd);
 332                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 333
 334                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 335                 }
 336
 337                 ++entry_num;
 338         }
 339         strunzone(z_submenu);
 340         if (QuickMenu_Page_Entries == 0)
 341         {
 342                 QuickMenu_Close();
 343                 return false;
 344         }
 345         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 346         return true;
 347 }
 348
 349 bool QuickMenu_ActionForNumber(int num)
 350 {
 351         if (!QuickMenu_IsLastPage)
 352         {
 353                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 354                         return false;
 355                 if (num == QUICKMENU_MAXLINES - 1)
 356                         return false;
 357                 if (num == 0)
 358                 {
 359                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 360                         return false;
 361                 }
 362         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 363                 return false;
 364
 365         if (QuickMenu_Page_Command[num] != "")
 366         {
 367                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 368                 QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 369                 return true;
 370         }
 371         if (QuickMenu_Page_Description[num] != "")
 372                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 373         return false;
 374 }
 375
 376 void QuickMenu_Page_ActiveEntry(float entry_num)
 377 {
 378         QuickMenu_Page_ActivatedEntry = entry_num;
 379         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 380         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 381         {
 382                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 383                 // toggle commands don't close the quickmenu
 384                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 385                         QuickMenu_Page_ActivatedEntry_Close = false;
 386                 else
 387                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 388         }
 389         else
 390                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 391 }
 392
 393 bool QuickMenu_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         // we only care for keyboard events
 396         if(bInputType == 2)
 397                 return false;
 398
 399         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 400                 return false;
 401
 402         if(bInputType == 3)
 403         {
 404                 mousepos.x = nPrimary;
 405                 mousepos.y = nSecondary;
 406                 return true;
 407         }
 408
 409         // allow console bind to work
 410         string con_keys;
 411         float keys;
 412         con_keys = findkeysforcommand("toggleconsole", 0);
 413         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 414
 415         bool hit_con_bind = false;
 416         int i;
 417         for (i = 0; i < keys; ++i)
 418         {
 419                 if(nPrimary == stof(argv(i)))
 420                         hit_con_bind = true;
 421         }
 422
 423         if(bInputType == 0) {
 424                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 425                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 426                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 427         }
 428         else if(bInputType == 1) {
 429                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 430                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 431                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 432         }
 433
 434         if(nPrimary == K_ESCAPE)
 435         {
 436                 if (bInputType == 1)
 437                         return true;
 438                 QuickMenu_Close();
 439         }
 440         else if(nPrimary >= '0' && nPrimary <= '9')
 441         {
 442                 if (bInputType == 1)
 443                         return true;
 444                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 445         }
 446         if(nPrimary == K_MOUSE1)
 447         {
 448                 if(bInputType == 0) // key pressed
 449                         mouseClicked |= S_MOUSE1;
 450                 else if(bInputType == 1) // key released
 451                         mouseClicked -= (mouseClicked & S_MOUSE1);
 452         }
 453         else if(nPrimary == K_MOUSE2)
 454         {
 455                 if(bInputType == 0) // key pressed
 456                         mouseClicked |= S_MOUSE2;
 457                 else if(bInputType == 1) // key released
 458                         mouseClicked -= (mouseClicked & S_MOUSE2);
 459         }
 460         else if(hit_con_bind)
 461                 return false;
 462
 463         return true;
 464 }
 465
 466 void QuickMenu_Mouse()
 467 {
 468         if(mv_active) return;
 469
 470         if(!mouseClicked)
 471         if(prevMouseClicked & S_MOUSE2)
 472         {
 473                 QuickMenu_Close();
 474                 return;
 475         }
 476
 477         if(!autocvar_hud_cursormode)
 478         {
 479                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 480
 481                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 482                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 483         }
 484
 485         HUD_Panel_UpdateCvars();
 486
 487         if(panel_bg_padding)
 488         {
 489                 panel_pos += '1 1 0' * panel_bg_padding;
 490                 panel_size -= '2 2 0' * panel_bg_padding;
 491         }
 492
 493         float first_entry_pos, entries_height;
 494         vector fontsize;
 495         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 496         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 497         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 498
 499         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 500         {
 501                 float entry_num;
 502                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 503                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 504                 {
 505                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 506                         vector color;
 507                         if(mouseClicked & S_MOUSE1)
 508                                 color = '0.5 1 0.5';
 509                         else if(hudShiftState & S_CTRL)
 510                                 color = '1 1 0.3';
 511                         else
 512                                 color = '1 1 1';
 513                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 514
 515                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 516                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 517                 }
 518         }
 519
 520         vector cursorsize = '32 32 0';
 521         drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 522
 523         prevMouseClicked = mouseClicked;
 524 }
 525
 526 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 527 {
 528         string entry;
 529         float offset;
 530         float desc_width = panel_size.x;
 531         if(option)
 532         {
 533                 string pic = strcat(hud_skin_path, "/", option);
 534                 if(precache_pic(pic) == "")
 535                         pic = strcat("gfx/hud/default/", option);
 536                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 537                 desc_width -= option_size.x;
 538                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 539                 desc_width -= fontsize.x / 4;
 540         }
 541         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 542         if (autocvar_hud_panel_quickmenu_align > 0)
 543         {
 544                 float real_desc_width = stringwidth_colors(entry, fontsize);
 545                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 546
 547                 if(option)
 548                 {
 549                         // when there's enough room align description regardless the checkbox
 550                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 551                         if(offset + real_desc_width + extra_offset < desc_width)
 552                                 offset += extra_offset;
 553                         else
 554                                 offset = max(0, desc_width - real_desc_width);
 555                 }
 556                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 557         }
 558         else
 559                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 560 }
 561
 562 void HUD_QuickMenu(void)
 563 {
 564         if(!autocvar__hud_configure)
 565         {
 566                 if (hud_configure_prev && hud_configure_prev != -1)
 567                         QuickMenu_Close();
 568
 569                 if(!hud_draw_maximized) return;
 570                 if(mv_active) return;
 571                 //if(!autocvar_hud_panel_quickmenu) return;
 572                 if(!hud_panel_quickmenu) return;
 573
 574                 if(time > QuickMenu_TimeOut)
 575                 {
 576                         QuickMenu_Close();
 577                         return;
 578                 }
 579         }
 580         else
 581         {
 582                 if(!QuickMenu_IsOpened())
 583                 {
 584                         QuickMenu_Page_Entries = 1;
 585                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 586                         ++QuickMenu_Page_Entries;
 587                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 588                         ++QuickMenu_Page_Entries;
 589                         // although real command doesn't matter here, it must not be empty
 590                         // otherwise the entry is displayed like a submenu
 591                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 592                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 593                         ++QuickMenu_Page_Entries;
 594                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 595                         QuickMenu_IsLastPage = false;
 596                 }
 597         }
 598
 599         HUD_Panel_UpdateCvars();
 600
 601         HUD_Panel_DrawBg(1);
 602
 603         if(panel_bg_padding)
 604         {
 605                 panel_pos += '1 1 0' * panel_bg_padding;
 606                 panel_size -= '2 2 0' * panel_bg_padding;
 607         }
 608
 609         int i;
 610         vector fontsize;
 611         string color;
 612         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 613
 614         if (!QuickMenu_IsLastPage)
 615         {
 616                 color = "^5";
 617                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 618         }
 619         else
 620                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 621
 622         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 623                 if (QuickMenu_Page_Description[i] == "")
 624                         break;
 625                 string option = string_null;
 626                 if (QuickMenu_Page_Command[i] == "")
 627                         color = "^4";
 628                 else
 629                 {
 630                         color = "^3";
 631                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 632                         {
 633                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 634                                 if(end < 0)
 635                                         tokenize_console(QuickMenu_Page_Command[i]);
 636                                 else
 637                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 638
 639                                 //if(argv(1) && argv(0) == "toggle") // already checked
 640                                 {
 641                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 642                                         // "disable feature xxx" "toggle xxx 0 1"
 643                                         float ON_value = 1, OFF_value = 0;
 644                                         if(argv(2))
 645                                                 ON_value = stof(argv(2));
 646
 647                                         if(argv(3))
 648                                                 OFF_value = stof(argv(3));
 649                                         else
 650                                                 OFF_value = !ON_value;
 651
 652                                         float value = cvar(argv(1));
 653                                         if(value == ON_value)
 654                                                 option = "checkbox_checked";
 655                                         else if(value == OFF_value)
 656                                                 option = "checkbox_empty";
 657                                         else
 658                                                 option = "checkbox_undefined";
 659                                 }
 660                         }
 661                 }
 662                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 663
 664                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 665                         && QuickMenu_Page_ActivatedEntry == i)
 666                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 667
 668                 panel_pos.y += fontsize.y;
 669         }
 670
 671         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 672         {
 673                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 674                 {
 675                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 676                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 677                                 QuickMenu_Close();
 678                 }
 679                 else if(QuickMenu_Page_ActivatedEntry_Close)
 680                         QuickMenu_Close();
 681                 QuickMenu_Page_ActivatedEntry = -1;
 682                 QuickMenu_Page_ActivatedEntry_Time = 0;
 683         }
 684 }
 685
 686
 687 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 688         if(target_submenu == eng_submenu && target_submenu_found) \
 689                 return; /* target_submenu entries are now loaded, exit */ \
 690         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 691                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", submenu)); \
 692         ++QuickMenu_Buffer_Size; \
 693         if(target_submenu == eng_submenu && !target_submenu_found) { \
 694                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 695                 target_submenu_found = true; \
 696         } \
 697 }
 698
 699 #define QUICKMENU_ENTRY(title,command) { \
 700         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 701         { \
 702                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", title)); \
 703                 ++QuickMenu_Buffer_Size; \
 704                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", command)); \
 705         } \
 706         ++QuickMenu_Buffer_Size; \
 707 }
 708
 709 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 710         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 711                 QUICKMENU_SMENU(submenu,eng_submenu) \
 712                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); \
 713                 ++QuickMenu_Buffer_Size; \
 714                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", command)); \
 715                 ++QuickMenu_Buffer_Size; \
 716                 QUICKMENU_SMENU(submenu,eng_submenu) \
 717         } \
 718 }
 719
 720
 721
 722 // useful to Translate a string inside the Command
 723 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 724         if(prvm_language == "en") \
 725                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 726         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 727                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 728         else \
 729                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 730 }
 731
 732 void HUD_Quickmenu_PlayerListEntries(string cmd, float teamplayers, float without_me)
 733 {
 734         entity pl;
 735         if(teamplayers && !team_count)
 736                 return;
 737
 738         for(pl = players.sort_next; pl; pl = pl.sort_next)
 739         {
 740                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 741                         continue;
 742                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 743                         continue;
 744                 if(without_me && pl.sv_entnum == player_localnum)
 745                         continue;
 746                 QUICKMENU_ENTRY(GetPlayerName(pl.sv_entnum), sprintf(cmd, GetPlayerName(pl.sv_entnum)))
 747         }
 748
 749         return;
 750 }
 751
 752
 753 // Specifying target_submenu, this function only loads entries inside target_submenu
 754 // NOTE: alternatively we could have loaded the whole default quickmenu and
 755 // then called QuickMenu_Page_Load(target_submenu, 0);
 756 // but this sytem is more reliable since we can always refer to target_submenu
 757 // with the English title even if a translation is active
 758 void QuickMenu_Default(string target_submenu)
 759 {
 760         bool target_submenu_found = false;
 761         if(target_submenu != "")
 762                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 763
 764         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 765                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 766                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 767                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 768         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 769
 770         if(teamplay)
 771         {
 772         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 773                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 774                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 775                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 776                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 777                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 778                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 779                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 780                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 781                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 782                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 783                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 784                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 785                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 786                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 787                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; +use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 788         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 789         }
 790
 791         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 792
 793         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 794                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 795                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 796                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 797                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 798                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 799                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 800                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 801                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 802
 803                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 804                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 805                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 806                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 807
 808                 if(spectatee_status > 0)
 809                 {
 810                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 811                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 812                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 813                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 814                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 815                 }
 816
 817                 if(spectatee_status == -1)
 818                 {
 819                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 820                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 824                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 825                 }
 826
 827                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 828                 if(prvm_language != "en")
 829                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 830         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 831
 832         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 833                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 834                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 835                 if(getstatf(STAT_TIMELIMIT) > 0)
 836                 {
 837                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 838                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 839                 }
 840                 if(teamplay)
 841                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 842         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 843
 844         if(target_submenu != "" && !target_submenu_found)
 845         {
 846                 printf("Couldn't find submenu \"%s\"\n", target_submenu);
 847                 if(prvm_language != "en")
 848                         printf("^3Warning: submenu must be in English\n", target_submenu);
 849                 QuickMenu_Buffer_Size = 0;
 850         }
 851 }
 852 #undef QUICKMENU_SMENU
 853 #undef QUICKMENU_ENTRY
 854 #undef QUICKMENU_ENTRY_TC