qcsrc/client/quickmenu.qc

   1 #include "_all.qh"
   2
   3 #include "hud_config.qh"
   4
   5 // QUICKMENU_MAXLINES must be <= 10
   6 const int QUICKMENU_MAXLINES = 10;
   7 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
   8 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
   9 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  10 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  11 int QuickMenu_Page_Entries;
  12 int QuickMenu_Page;
  13 int QuickMenu_Page_ActivatedEntry = -1;
  14 bool QuickMenu_Page_ActivatedEntry_Close;
  15 float QuickMenu_Page_ActivatedEntry_Time;
  16 bool QuickMenu_IsLastPage;
  17 // all the entries are loaded into QuickMenu_Buffer
  18 // each entry (submenu or command) is composed of 2 entries
  19 const int QUICKMENU_MAXENTRIES = 256;
  20 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  21 int QuickMenu_Buffer = -1;
  22 int QuickMenu_Buffer_Size;
  23 int QuickMenu_Buffer_Index;
  24 string QuickMenu_CurrentSubMenu;
  25 float QuickMenu_TimeOut;
  26
  27 // QuickMenu_Buffer are labeled with these tags
  28 #define QM_TAG_TITLE "T"
  29 #define QM_TAG_SUBMENU "S"
  30 #define QM_TAG_COMMAND "C"
  31 #define QM_TAG_PLCOMMAND "P"
  32
  33 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  34 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  35
  36 // if s1 is not empty s will be displayed as command otherwise as submenu
  37 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  38 {
  39         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  40         if (QuickMenu_Page_Description[i])
  41                 strunzone(QuickMenu_Page_Description[i]);
  42         QuickMenu_Page_Description[i] = strzone(s);
  43         if (QuickMenu_Page_Command[i])
  44                 strunzone(QuickMenu_Page_Command[i]);
  45         QuickMenu_Page_Command[i] = strzone(s1);
  46 }
  47
  48 void QuickMenu_Page_ClearEntry(int i)
  49 {
  50         if (QuickMenu_Page_Description[i])
  51                 strunzone(QuickMenu_Page_Description[i]);
  52         QuickMenu_Page_Description[i] = string_null;
  53         if (QuickMenu_Page_Command[i])
  54                 strunzone(QuickMenu_Page_Command[i]);
  55         QuickMenu_Page_Command[i] = string_null;
  56 }
  57
  58 float QuickMenu_Page_Load(string target_submenu, float new_page);
  59 void QuickMenu_Default(string submenu);
  60 bool QuickMenu_Open(string mode, string submenu)
  61 {
  62         int fh = -1;
  63         string s;
  64
  65         if(mode == "")
  66         {
  67                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  68                         mode = "default";
  69                 else
  70                         mode = "file";
  71         }
  72
  73         if(mode == "file")
  74         {
  75                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  76                         printf("No file name is set in hud_panel_quickmenu_file, loading default quickmenu\n");
  77                 else
  78                 {
  79                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  80                         if(fh < 0)
  81                                 printf("Couldn't open file \"%s\", loading default quickmenu\n", autocvar_hud_panel_quickmenu_file);
  82                 }
  83                 if(fh < 0)
  84                         mode = "default";
  85         }
  86
  87         if(mode == "default")
  88         {
  89                 QuickMenu_Buffer = buf_create();
  90                 if(QuickMenu_Buffer < 0)
  91                         return false;
  92
  93                 QuickMenu_Default(submenu);
  94         }
  95         else if(mode == "file")
  96         {
  97                 QuickMenu_Buffer = buf_create();
  98                 if(QuickMenu_Buffer < 0)
  99                 {
 100                         fclose(fh);
 101                         return false;
 102                 }
 103
 104                 QuickMenu_Buffer_Size = 0;
 105                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 106                 {
 107                         // first skip invalid entries, so we don't check them anymore
 108                         float argc;
 109                         argc = tokenize_console(s);
 110                         if(argc == 0 || argv(0) == "")
 111                                 continue;
 112                         if(argc == 1)
 113                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 114                         else if(argc == 2)
 115                         {
 116                                 if(argv(1) == "")
 117                                         continue;
 118                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 119                                 ++QuickMenu_Buffer_Size;
 120                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 121                         }
 122                         else if(argc == 3)
 123                         {
 124                                 // check for special keywords
 125                                 float teamplayers = 0, without_me = 0;
 126                                 switch(argv(2))
 127                                 {
 128                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 129                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 130                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 131                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 132                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 133                                         default: continue;
 134                                 }
 135
 136                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 137                                 {
 138                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 139                                         ++QuickMenu_Buffer_Size;
 140                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 141                                         ++QuickMenu_Buffer_Size;
 142                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 143                                         ++QuickMenu_Buffer_Size;
 144                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 145                                 }
 146                         }
 147                         ++QuickMenu_Buffer_Size;
 148                 }
 149                 fclose(fh);
 150         }
 151         else
 152         {
 153                 printf("Unrecognized mode %s\n", mode);
 154                 return false;
 155         }
 156
 157         if (QuickMenu_Buffer_Size <= 0)
 158         {
 159                 buf_del(QuickMenu_Buffer);
 160                 QuickMenu_Buffer = -1;
 161                 return false;
 162         }
 163
 164         if(mode == "file")
 165                 QuickMenu_Page_Load(submenu, 0);
 166         else
 167                 QuickMenu_Page_Load("", 0);
 168
 169         hud_panel_quickmenu = 1;
 170         if(autocvar_hud_cursormode)
 171                 setcursormode(1);
 172         hudShiftState = 0;
 173
 174         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 175         return true;
 176 }
 177
 178 void QuickMenu_Buffer_Close()
 179 {
 180         if (QuickMenu_Buffer >= 0)
 181         {
 182                 buf_del(QuickMenu_Buffer);
 183                 QuickMenu_Buffer = -1;
 184                 QuickMenu_Buffer_Size = 0;
 185         }
 186 }
 187
 188 void QuickMenu_Close()
 189 {
 190         if (QuickMenu_CurrentSubMenu)
 191                 strunzone(QuickMenu_CurrentSubMenu);
 192         QuickMenu_CurrentSubMenu = string_null;
 193         int i;
 194         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 195                 QuickMenu_Page_ClearEntry(i);
 196         QuickMenu_Page_Entries = 0;
 197         hud_panel_quickmenu = 0;
 198         mouseClicked = 0;
 199         prevMouseClicked = 0;
 200         QuickMenu_Buffer_Close();
 201
 202         if(autocvar_hud_cursormode)
 203         if(!mv_active)
 204                 setcursormode(0);
 205 }
 206
 207 // It assumes submenu open tag is already detected
 208 void QuickMenu_skip_submenu(string submenu)
 209 {
 210         string s, z_submenu;
 211         z_submenu = strzone(submenu);
 212         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 213         {
 214                 s = QuickMenu_Buffer_Get();
 215                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 216                         continue;
 217                 if(substring(s, 1, -1) == z_submenu) // submenu end
 218                         break;
 219                 QuickMenu_skip_submenu(substring(s, 1, -1));
 220         }
 221         strunzone(z_submenu);
 222 }
 223
 224 bool QuickMenu_IsOpened()
 225 {
 226         return (QuickMenu_Page_Entries > 0);
 227 }
 228
 229 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, float without_me);
 230 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, float without_me)
 231 {
 232         int i;
 233         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 234                 QuickMenu_Page_ClearEntry(i);
 235         QuickMenu_Buffer_Close();
 236
 237         QuickMenu_Buffer = buf_create();
 238         if(QuickMenu_Buffer < 0)
 239                 return false;
 240
 241         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 242
 243         if(QuickMenu_Buffer_Size <= 0)
 244         {
 245                 buf_del(QuickMenu_Buffer);
 246                 QuickMenu_Buffer = -1;
 247                 return false;
 248         }
 249         return true;
 250 }
 251
 252 // new_page 0 means page 0, new_page != 0 means next page
 253 int QuickMenu_Buffer_Index_Prev;
 254 bool QuickMenu_Page_Load(string target_submenu, int new_page)
 255 {
 256         string s = string_null, cmd = string_null, z_submenu;
 257
 258         if (new_page == 0)
 259                 QuickMenu_Page = 0;
 260         else
 261                 ++QuickMenu_Page;
 262
 263         z_submenu = strzone(target_submenu);
 264         if (QuickMenu_CurrentSubMenu)
 265                 strunzone(QuickMenu_CurrentSubMenu);
 266         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 267
 268         QuickMenu_IsLastPage = true;
 269         QuickMenu_Page_Entries = 0;
 270
 271         QuickMenu_Buffer_Index = 0;
 272         if (z_submenu != "")
 273         {
 274                 // skip everything until the submenu open tag is found
 275                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 276                 {
 277                         s = QuickMenu_Buffer_Get();
 278                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 279                         {
 280                                 // printf("^3 beginning of %s\n", z_submenu);
 281                                 ++QuickMenu_Buffer_Index;
 282                                 break; // target_submenu found!
 283                         }
 284                         // printf("^1 skipping %s\n", s);
 285                 }
 286                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 287                         printf("Couldn't find submenu \"%s\"\n", z_submenu);
 288         }
 289
 290         // only the last page can contain up to QUICKMENU_MAXLINES entries
 291         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 292         // so that the panel can show an empty row and "Continue..."
 293         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 294         int entry_num = 0; // counts entries in target_submenu
 295         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 296         {
 297                 s = QuickMenu_Buffer_Get();
 298
 299                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 300                 {
 301                         // printf("^3 end of %s\n", z_submenu);
 302                         break;
 303                 }
 304
 305                 if(entry_num >= first_entry)
 306                 {
 307                         ++QuickMenu_Page_Entries;
 308                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 309                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 310                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 311                         {
 312                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 313                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 314                                 QuickMenu_IsLastPage = false;
 315                                 break;
 316                         }
 317                 }
 318
 319                 // NOTE: entries are loaded starting from 1, not from 0
 320                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 321                 {
 322                         if(entry_num >= first_entry)
 323                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 324                         QuickMenu_skip_submenu(substring(s, 1, -1));
 325                 }
 326                 else if(entry_num >= first_entry && substring(s, 0, 1) == QM_TAG_TITLE)
 327                 {
 328                         ++QuickMenu_Buffer_Index;
 329                         cmd = QuickMenu_Buffer_Get();
 330                         string command_code = substring(cmd, 0, 1);
 331                         if(command_code == QM_TAG_COMMAND)
 332                                 cmd = substring(cmd, 1, -1);
 333                         else if(command_code == QM_TAG_PLCOMMAND)
 334                         {
 335                                 // throw away the current quickmenu buffer and load a new one
 336                                 cmd = substring(cmd, 1, -1);
 337                                 strunzone(z_submenu);
 338                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 339                                         return QuickMenu_Page_Load("", 0);
 340                                 QuickMenu_Close();
 341                                 return false;
 342                         }
 343
 344                         tokenize_console(cmd);
 345                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 346
 347                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 348                 }
 349
 350                 ++entry_num;
 351         }
 352         strunzone(z_submenu);
 353         if (QuickMenu_Page_Entries == 0)
 354         {
 355                 QuickMenu_Close();
 356                 return false;
 357         }
 358         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 359         return true;
 360 }
 361
 362 bool QuickMenu_ActionForNumber(int num)
 363 {
 364         if (!QuickMenu_IsLastPage)
 365         {
 366                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 367                         return false;
 368                 if (num == QUICKMENU_MAXLINES - 1)
 369                         return false;
 370                 if (num == 0)
 371                 {
 372                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 373                         return false;
 374                 }
 375         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 376                 return false;
 377
 378         if (QuickMenu_Page_Command[num] != "")
 379         {
 380                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 381                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 382                 return true;
 383         }
 384         if (QuickMenu_Page_Description[num] != "")
 385                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 386         return false;
 387 }
 388
 389 void QuickMenu_Page_ActiveEntry(float entry_num)
 390 {
 391         QuickMenu_Page_ActivatedEntry = entry_num;
 392         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 393         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 394         {
 395                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 396                 // toggle commands don't close the quickmenu
 397                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 398                         QuickMenu_Page_ActivatedEntry_Close = false;
 399                 else
 400                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 401         }
 402         else
 403                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 404 }
 405
 406 bool QuickMenu_InputEvent(float bInputType, float nPrimary, float nSecondary)
 407 {
 408         // we only care for keyboard events
 409         if(bInputType == 2)
 410                 return false;
 411
 412         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 413                 return false;
 414
 415         if(bInputType == 3)
 416         {
 417                 mousepos.x = nPrimary;
 418                 mousepos.y = nSecondary;
 419                 return true;
 420         }
 421
 422         // allow console bind to work
 423         string con_keys;
 424         float keys;
 425         con_keys = findkeysforcommand("toggleconsole", 0);
 426         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 427
 428         bool hit_con_bind = false;
 429         int i;
 430         for (i = 0; i < keys; ++i)
 431         {
 432                 if(nPrimary == stof(argv(i)))
 433                         hit_con_bind = true;
 434         }
 435
 436         if(bInputType == 0) {
 437                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 438                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 439                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 440         }
 441         else if(bInputType == 1) {
 442                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 443                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 444                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 445         }
 446
 447         if(nPrimary == K_ESCAPE)
 448         {
 449                 if (bInputType == 1)
 450                         return true;
 451                 QuickMenu_Close();
 452         }
 453         else if(nPrimary >= '0' && nPrimary <= '9')
 454         {
 455                 if (bInputType == 1)
 456                         return true;
 457                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 458         }
 459         if(nPrimary == K_MOUSE1)
 460         {
 461                 if(bInputType == 0) // key pressed
 462                         mouseClicked |= S_MOUSE1;
 463                 else if(bInputType == 1) // key released
 464                         mouseClicked -= (mouseClicked & S_MOUSE1);
 465         }
 466         else if(nPrimary == K_MOUSE2)
 467         {
 468                 if(bInputType == 0) // key pressed
 469                         mouseClicked |= S_MOUSE2;
 470                 else if(bInputType == 1) // key released
 471                         mouseClicked -= (mouseClicked & S_MOUSE2);
 472         }
 473         else if(hit_con_bind)
 474                 return false;
 475
 476         return true;
 477 }
 478
 479 void QuickMenu_Mouse()
 480 {
 481         if(mv_active) return;
 482
 483         if(!mouseClicked)
 484         if(prevMouseClicked & S_MOUSE2)
 485         {
 486                 QuickMenu_Close();
 487                 return;
 488         }
 489
 490         if(!autocvar_hud_cursormode)
 491         {
 492                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 493
 494                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 495                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 496         }
 497
 498         HUD_Panel_UpdateCvars();
 499
 500         if(panel_bg_padding)
 501         {
 502                 panel_pos += '1 1 0' * panel_bg_padding;
 503                 panel_size -= '2 2 0' * panel_bg_padding;
 504         }
 505
 506         float first_entry_pos, entries_height;
 507         vector fontsize;
 508         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 509         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 510         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 511
 512         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 513         {
 514                 float entry_num;
 515                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 516                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 517                 {
 518                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 519                         vector color;
 520                         if(mouseClicked & S_MOUSE1)
 521                                 color = '0.5 1 0.5';
 522                         else if(hudShiftState & S_CTRL)
 523                                 color = '1 1 0.3';
 524                         else
 525                                 color = '1 1 1';
 526                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 527
 528                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 529                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 530                 }
 531         }
 532
 533         vector cursorsize = '32 32 0';
 534         drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 535
 536         prevMouseClicked = mouseClicked;
 537 }
 538
 539 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 540 {
 541         string entry;
 542         float offset;
 543         float desc_width = panel_size.x;
 544         if(option)
 545         {
 546                 string pic = strcat(hud_skin_path, "/", option);
 547                 if(precache_pic(pic) == "")
 548                         pic = strcat("gfx/hud/default/", option);
 549                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 550                 desc_width -= option_size.x;
 551                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 552                 desc_width -= fontsize.x / 4;
 553         }
 554         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 555         if (autocvar_hud_panel_quickmenu_align > 0)
 556         {
 557                 float real_desc_width = stringwidth_colors(entry, fontsize);
 558                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 559
 560                 if(option)
 561                 {
 562                         // when there's enough room align description regardless the checkbox
 563                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 564                         if(offset + real_desc_width + extra_offset < desc_width)
 565                                 offset += extra_offset;
 566                         else
 567                                 offset = max(0, desc_width - real_desc_width);
 568                 }
 569                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 570         }
 571         else
 572                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 573 }
 574
 575 void HUD_QuickMenu(void)
 576 {
 577         if(!autocvar__hud_configure)
 578         {
 579                 if (hud_configure_prev && hud_configure_prev != -1)
 580                         QuickMenu_Close();
 581
 582                 if(!hud_draw_maximized) return;
 583                 if(mv_active) return;
 584                 //if(!autocvar_hud_panel_quickmenu) return;
 585                 if(!hud_panel_quickmenu) return;
 586
 587                 if(QuickMenu_TimeOut)
 588                 if(time > QuickMenu_TimeOut)
 589                 {
 590                         QuickMenu_Close();
 591                         return;
 592                 }
 593         }
 594         else
 595         {
 596                 if(!QuickMenu_IsOpened())
 597                 {
 598                         QuickMenu_Page_Entries = 1;
 599                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 600                         ++QuickMenu_Page_Entries;
 601                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 602                         ++QuickMenu_Page_Entries;
 603                         // although real command doesn't matter here, it must not be empty
 604                         // otherwise the entry is displayed like a submenu
 605                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 606                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 607                         ++QuickMenu_Page_Entries;
 608                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 609                         QuickMenu_IsLastPage = false;
 610                 }
 611         }
 612
 613         HUD_Panel_UpdateCvars();
 614
 615         HUD_Panel_DrawBg(1);
 616
 617         if(panel_bg_padding)
 618         {
 619                 panel_pos += '1 1 0' * panel_bg_padding;
 620                 panel_size -= '2 2 0' * panel_bg_padding;
 621         }
 622
 623         int i;
 624         vector fontsize;
 625         string color;
 626         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 627
 628         if (!QuickMenu_IsLastPage)
 629         {
 630                 color = "^5";
 631                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 632         }
 633         else
 634                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 635
 636         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 637                 if (QuickMenu_Page_Description[i] == "")
 638                         break;
 639                 string option = string_null;
 640                 if (QuickMenu_Page_Command[i] == "")
 641                         color = "^4";
 642                 else
 643                 {
 644                         color = "^3";
 645                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 646                         {
 647                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 648                                 if(end < 0)
 649                                         tokenize_console(QuickMenu_Page_Command[i]);
 650                                 else
 651                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 652
 653                                 //if(argv(1) && argv(0) == "toggle") // already checked
 654                                 {
 655                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 656                                         // "disable feature xxx" "toggle xxx 0 1"
 657                                         float ON_value = 1, OFF_value = 0;
 658                                         if(argv(2))
 659                                                 ON_value = stof(argv(2));
 660
 661                                         if(argv(3))
 662                                                 OFF_value = stof(argv(3));
 663                                         else
 664                                                 OFF_value = !ON_value;
 665
 666                                         float value = cvar(argv(1));
 667                                         if(value == ON_value)
 668                                                 option = "checkbox_checked";
 669                                         else if(value == OFF_value)
 670                                                 option = "checkbox_empty";
 671                                         else
 672                                                 option = "checkbox_undefined";
 673                                 }
 674                         }
 675                 }
 676                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 677
 678                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 679                         && QuickMenu_Page_ActivatedEntry == i)
 680                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 681
 682                 panel_pos.y += fontsize.y;
 683         }
 684
 685         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 686         {
 687                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 688                 {
 689                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 690                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 691                                 QuickMenu_Close();
 692                 }
 693                 else if(QuickMenu_Page_ActivatedEntry_Close)
 694                         QuickMenu_Close();
 695                 QuickMenu_Page_ActivatedEntry = -1;
 696                 QuickMenu_Page_ActivatedEntry_Time = 0;
 697         }
 698 }
 699
 700
 701 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 702         if(target_submenu == eng_submenu && target_submenu_found) \
 703                 return; /* target_submenu entries are now loaded, exit */ \
 704         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 705                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 706         ++QuickMenu_Buffer_Size; \
 707         if(target_submenu == eng_submenu && !target_submenu_found) { \
 708                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 709                 target_submenu_found = true; \
 710         } \
 711 }
 712
 713 #define QUICKMENU_ENTRY(title,command) { \
 714         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 715         { \
 716                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 717                 ++QuickMenu_Buffer_Size; \
 718                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 719         } \
 720         ++QuickMenu_Buffer_Size; \
 721 }
 722
 723 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 724         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 725                 QUICKMENU_SMENU(submenu,eng_submenu) \
 726                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 727                 ++QuickMenu_Buffer_Size; \
 728                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 729                 ++QuickMenu_Buffer_Size; \
 730                 QUICKMENU_SMENU(submenu,eng_submenu) \
 731         } \
 732 }
 733
 734
 735
 736 // useful to Translate a string inside the Command
 737 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 738         if(prvm_language == "en") \
 739                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 740         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 741                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 742         else \
 743                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 744 }
 745
 746 void HUD_Quickmenu_PlayerListEntries(string cmd, float teamplayers, float without_me)
 747 {
 748         entity pl;
 749         if(teamplayers && !team_count)
 750                 return;
 751
 752         for(pl = players.sort_next; pl; pl = pl.sort_next)
 753         {
 754                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 755                         continue;
 756                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 757                         continue;
 758                 if(without_me && pl.sv_entnum == player_localnum)
 759                         continue;
 760                 QUICKMENU_ENTRY(GetPlayerName(pl.sv_entnum), sprintf(cmd, GetPlayerName(pl.sv_entnum)))
 761         }
 762
 763         return;
 764 }
 765
 766
 767 // Specifying target_submenu, this function only loads entries inside target_submenu
 768 // NOTE: alternatively we could have loaded the whole default quickmenu and
 769 // then called QuickMenu_Page_Load(target_submenu, 0);
 770 // but this sytem is more reliable since we can always refer to target_submenu
 771 // with the English title even if a translation is active
 772 void QuickMenu_Default(string target_submenu)
 773 {
 774         bool target_submenu_found = false;
 775         if(target_submenu != "")
 776                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 777
 778         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 779                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 780                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 781                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 782         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 783
 784         if(teamplay)
 785         {
 786         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 787                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 788                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 791                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 792                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 793                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 794                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 795                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 796                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 797                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 802         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 803         }
 804
 805         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 806
 807         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 808                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 809                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 810                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 811                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 812                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 813                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 814                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 815                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 816
 817                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 818                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 819                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 820                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 821
 822                 if(spectatee_status > 0)
 823                 {
 824                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 825                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 826                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 827                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 828                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 829                 }
 830
 831                 if(spectatee_status == -1)
 832                 {
 833                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 834                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 835                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 836                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 838                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 839                 }
 840
 841                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 842                 if(prvm_language != "en")
 843                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 844         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 845
 846         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 847                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 848                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 849                 if(getstatf(STAT_TIMELIMIT) > 0)
 850                 {
 851                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 852                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 853                 }
 854                 if(teamplay)
 855                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 856         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 857
 858         if(target_submenu != "" && !target_submenu_found)
 859         {
 860                 printf("Couldn't find submenu \"%s\"\n", target_submenu);
 861                 if(prvm_language != "en")
 862                         printf("^3Warning: submenu must be in English\n", target_submenu);
 863                 QuickMenu_Buffer_Size = 0;
 864         }
 865 }
 866 #undef QUICKMENU_SMENU
 867 #undef QUICKMENU_ENTRY
 868 #undef QUICKMENU_ENTRY_TC