qcsrc/client/quickmenu.qc

   1 #include "_all.qh"
   2
   3 #include "hud_config.qh"
   4
   5 #include "../dpdefs/keycodes.qh"
   6
   7 // QUICKMENU_MAXLINES must be <= 10
   8 const int QUICKMENU_MAXLINES = 10;
   9 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  10 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  11 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  12 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  13 int QuickMenu_Page_Entries;
  14 int QuickMenu_Page;
  15 int QuickMenu_Page_ActivatedEntry = -1;
  16 bool QuickMenu_Page_ActivatedEntry_Close;
  17 float QuickMenu_Page_ActivatedEntry_Time;
  18 bool QuickMenu_IsLastPage;
  19 // all the entries are loaded into QuickMenu_Buffer
  20 // each entry (submenu or command) is composed of 2 entries
  21 const int QUICKMENU_MAXENTRIES = 256;
  22 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  23 int QuickMenu_Buffer = -1;
  24 int QuickMenu_Buffer_Size;
  25 int QuickMenu_Buffer_Index;
  26 string QuickMenu_CurrentSubMenu;
  27 float QuickMenu_TimeOut;
  28 // if s1 is not empty s will be displayed as command otherwise as submenu
  29 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  30 {
  31         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  32         if (QuickMenu_Page_Description[i])
  33                 strunzone(QuickMenu_Page_Description[i]);
  34         QuickMenu_Page_Description[i] = strzone(s);
  35         if (QuickMenu_Page_Command[i])
  36                 strunzone(QuickMenu_Page_Command[i]);
  37         QuickMenu_Page_Command[i] = strzone(s1);
  38 }
  39
  40 void QuickMenu_Page_ClearEntry(int i)
  41 {
  42         if (QuickMenu_Page_Description[i])
  43                 strunzone(QuickMenu_Page_Description[i]);
  44         QuickMenu_Page_Description[i] = string_null;
  45         if (QuickMenu_Page_Command[i])
  46                 strunzone(QuickMenu_Page_Command[i]);
  47         QuickMenu_Page_Command[i] = string_null;
  48 }
  49
  50 float QuickMenu_Page_Load(string target_submenu, float new_page);
  51 void QuickMenu_Default(string submenu);
  52 bool QuickMenu_Open(string mode, string submenu)
  53 {
  54         int fh = -1;
  55         string s;
  56
  57         if(mode == "")
  58         {
  59                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  60                         mode = "default";
  61                 else
  62                         mode = "file";
  63         }
  64
  65         if(mode == "default")
  66         {
  67                 QuickMenu_Buffer = buf_create();
  68                 if(QuickMenu_Buffer < 0)
  69                         return false;
  70
  71                 QuickMenu_Default(submenu);
  72         }
  73         else if(mode == "file")
  74         {
  75                 if(autocvar_hud_panel_quickmenu_file != "")
  76                 if(autocvar_hud_panel_quickmenu_file != "0")
  77                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  78                 if(fh < 0)
  79                 {
  80                         printf("Couldn't open file \"%s\"\n", autocvar_hud_panel_quickmenu_file);
  81                         return false;
  82                 }
  83
  84                 QuickMenu_Buffer = buf_create();
  85                 if(QuickMenu_Buffer < 0)
  86                 {
  87                         fclose(fh);
  88                         return false;
  89                 }
  90
  91                 QuickMenu_Buffer_Size = 0;
  92                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
  93                 {
  94                         // first skip invalid entries, so we don't check them anymore
  95                         float argc;
  96                         argc = tokenize_console(s);
  97                         if(argc == 0 || argv(0) == "" || substring(argv(0), 0, 2) == "////")
  98                                 continue;
  99                         if(argc == 1)
 100                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 101                         else if(argc == 2)
 102                         {
 103                                 if(argv(1) == "")
 104                                         continue;
 105                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", argv(0))); // command Title
 106                                 ++QuickMenu_Buffer_Size;
 107                                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", argv(1))); // command
 108                         }
 109                         else if(argc == 3)
 110                         {
 111                                 // check for special keywords
 112                                 float teamplayers = 0, without_me = 0;
 113                                 switch(argv(2))
 114                                 {
 115                                         case "ALLPLAYERS_BUT_ME":               without_me = 1;
 116                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 117                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1;
 118                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 119                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 120                                         default: continue;
 121                                 }
 122
 123                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 124                                 {
 125                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 126                                         ++QuickMenu_Buffer_Size;
 127                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); // command arguments
 128                                         ++QuickMenu_Buffer_Size;
 129                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", argv(1))); // command for each player
 130                                         ++QuickMenu_Buffer_Size;
 131                                         bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", argv(0))); // Submenu
 132                                 }
 133                         }
 134                         ++QuickMenu_Buffer_Size;
 135                 }
 136                 fclose(fh);
 137         }
 138         else
 139         {
 140                 printf("Unrecognized mode %s\n", mode);
 141                 return false;
 142         }
 143
 144         if (QuickMenu_Buffer_Size <= 0)
 145         {
 146                 buf_del(QuickMenu_Buffer);
 147                 QuickMenu_Buffer = -1;
 148                 return false;
 149         }
 150
 151         if(mode == "file")
 152                 QuickMenu_Page_Load(submenu, 0);
 153         else
 154                 QuickMenu_Page_Load("", 0);
 155
 156         hud_panel_quickmenu = 1;
 157         if(autocvar_hud_cursormode)
 158                 setcursormode(1);
 159         hudShiftState = 0;
 160
 161         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 162         return true;
 163 }
 164
 165 void QuickMenu_Buffer_Close()
 166 {
 167         if (QuickMenu_Buffer >= 0)
 168         {
 169                 buf_del(QuickMenu_Buffer);
 170                 QuickMenu_Buffer = -1;
 171                 QuickMenu_Buffer_Size = 0;
 172         }
 173 }
 174
 175 void QuickMenu_Close()
 176 {
 177         if (QuickMenu_CurrentSubMenu)
 178                 strunzone(QuickMenu_CurrentSubMenu);
 179         QuickMenu_CurrentSubMenu = string_null;
 180         int i;
 181         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 182                 QuickMenu_Page_ClearEntry(i);
 183         QuickMenu_Page_Entries = 0;
 184         hud_panel_quickmenu = 0;
 185         mouseClicked = 0;
 186         prevMouseClicked = 0;
 187         QuickMenu_Buffer_Close();
 188
 189         if(autocvar_hud_cursormode)
 190         if(!mv_active)
 191                 setcursormode(0);
 192 }
 193
 194 // It assumes submenu open tag is already detected
 195 void QuickMenu_skip_submenu(string submenu)
 196 {
 197         string s, z_submenu;
 198         z_submenu = strzone(submenu);
 199         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 200         {
 201                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 202                 if(substring(s, 0, 1) != "S")
 203                         continue;
 204                 if(substring(s, 1, -1) == z_submenu) // submenu end
 205                         break;
 206                 QuickMenu_skip_submenu(substring(s, 1, -1));
 207         }
 208         strunzone(z_submenu);
 209 }
 210
 211 bool QuickMenu_IsOpened()
 212 {
 213         return (QuickMenu_Page_Entries > 0);
 214 }
 215
 216 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, float without_me);
 217 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, float without_me)
 218 {
 219         int i;
 220         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 221                 QuickMenu_Page_ClearEntry(i);
 222         QuickMenu_Buffer_Close();
 223
 224         QuickMenu_Buffer = buf_create();
 225         if(QuickMenu_Buffer < 0)
 226                 return false;
 227
 228         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 229
 230         if(QuickMenu_Buffer_Size <= 0)
 231         {
 232                 buf_del(QuickMenu_Buffer);
 233                 QuickMenu_Buffer = -1;
 234                 return false;
 235         }
 236         return true;
 237 }
 238
 239 // new_page 0 means page 0, new_page != 0 means next page
 240 int QuickMenu_Buffer_Index_Prev;
 241 bool QuickMenu_Page_Load(string target_submenu, int new_page)
 242 {
 243         string s = string_null, cmd = string_null, z_submenu;
 244
 245         if (new_page == 0)
 246                 QuickMenu_Page = 0;
 247         else
 248                 ++QuickMenu_Page;
 249
 250         z_submenu = strzone(target_submenu);
 251         if (QuickMenu_CurrentSubMenu)
 252                 strunzone(QuickMenu_CurrentSubMenu);
 253         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 254
 255         QuickMenu_IsLastPage = true;
 256         QuickMenu_Page_Entries = 0;
 257
 258         QuickMenu_Buffer_Index = 0;
 259         if (z_submenu != "")
 260         {
 261                 // skip everything until the submenu open tag is found
 262                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 263                 {
 264                         s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 265                         if(substring(s, 0, 1) == "S" && substring(s, 1, -1) == z_submenu)
 266                         {
 267                                 // printf("^3 beginning of %s\n", z_submenu);
 268                                 ++QuickMenu_Buffer_Index;
 269                                 break; // target_submenu found!
 270                         }
 271                         // printf("^1 skipping %s\n", s);
 272                 }
 273                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 274                         printf("Couldn't find submenu \"%s\"\n", z_submenu);
 275         }
 276
 277         // only the last page can contain up to QUICKMENU_MAXLINES entries
 278         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 279         // so that the panel can show an empty row and "Continue..."
 280         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 281         int entry_num = 0; // counts entries in target_submenu
 282         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 283         {
 284                 s = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 285
 286                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 287                 {
 288                         // printf("^3 end of %s\n", z_submenu);
 289                         break;
 290                 }
 291
 292                 if(entry_num >= first_entry)
 293                 {
 294                         ++QuickMenu_Page_Entries;
 295                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 296                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 297                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 298                         {
 299                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 300                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 301                                 QuickMenu_IsLastPage = false;
 302                                 break;
 303                         }
 304                 }
 305
 306                 // NOTE: entries are loaded starting from 1, not from 0
 307                 if(substring(s, 0, 1) == "S") // submenu
 308                 {
 309                         if(entry_num >= first_entry)
 310                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 311                         QuickMenu_skip_submenu(substring(s, 1, -1));
 312                 }
 313                 else if(entry_num >= first_entry && substring(s, 0, 1) == "T")
 314                 {
 315                         ++QuickMenu_Buffer_Index;
 316                         cmd = bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index);
 317                         string command_code = substring(cmd, 0, 1);
 318                         if(command_code == "C")
 319                                 cmd = substring(cmd, 1, -1);
 320                         else if(command_code == "P")
 321                         {
 322                                 // throw away the current quickmenu buffer and load a new one
 323                                 cmd = substring(cmd, 1, -1);
 324                                 strunzone(z_submenu);
 325                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 326                                         return QuickMenu_Page_Load("", 0);
 327                                 QuickMenu_Close();
 328                                 return false;
 329                         }
 330
 331                         tokenize_console(cmd);
 332                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 333
 334                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 335                 }
 336
 337                 ++entry_num;
 338         }
 339         strunzone(z_submenu);
 340         if (QuickMenu_Page_Entries == 0)
 341         {
 342                 QuickMenu_Close();
 343                 return false;
 344         }
 345         QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 346         return true;
 347 }
 348
 349 bool QuickMenu_ActionForNumber(int num)
 350 {
 351         if (!QuickMenu_IsLastPage)
 352         {
 353                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 354                         return false;
 355                 if (num == QUICKMENU_MAXLINES - 1)
 356                         return false;
 357                 if (num == 0)
 358                 {
 359                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 360                         return false;
 361                 }
 362         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 363                 return false;
 364
 365         if (QuickMenu_Page_Command[num] != "")
 366         {
 367                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 368                 QuickMenu_TimeOut = time + autocvar_hud_panel_quickmenu_time;
 369                 return true;
 370         }
 371         if (QuickMenu_Page_Description[num] != "")
 372                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 373         return false;
 374 }
 375
 376 void QuickMenu_Page_ActiveEntry(float entry_num)
 377 {
 378         QuickMenu_Page_ActivatedEntry = entry_num;
 379         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 380         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 381         {
 382                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 383                 // toggle commands don't close the quickmenu
 384                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 385                         QuickMenu_Page_ActivatedEntry_Close = false;
 386                 else
 387                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 388         }
 389         else
 390                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 391 }
 392
 393 bool QuickMenu_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         // we only care for keyboard events
 396         if(bInputType == 2)
 397                 return false;
 398
 399         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 400                 return false;
 401
 402         if(bInputType == 3)
 403         {
 404                 mousepos_x = nPrimary;
 405                 mousepos_y = nSecondary;
 406                 return true;
 407         }
 408
 409         // allow console bind to work
 410         string con_keys;
 411         float keys;
 412         con_keys = findkeysforcommand("toggleconsole", 0);
 413         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 414
 415         bool hit_con_bind = false;
 416         int i;
 417         for (i = 0; i < keys; ++i)
 418         {
 419                 if(nPrimary == stof(argv(i)))
 420                         hit_con_bind = true;
 421         }
 422
 423         if(bInputType == 0) {
 424                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 425                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 426                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 427         }
 428         else if(bInputType == 1) {
 429                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 430                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 431                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 432         }
 433
 434         if(nPrimary == K_ESCAPE)
 435         {
 436                 if (bInputType == 1)
 437                         return true;
 438                 QuickMenu_Close();
 439         }
 440         else if(nPrimary >= '0' && nPrimary <= '9')
 441         {
 442                 if (bInputType == 1)
 443                         return true;
 444                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 445         }
 446         if(nPrimary == K_MOUSE1)
 447         {
 448                 if(bInputType == 0) // key pressed
 449                         mouseClicked |= S_MOUSE1;
 450                 else if(bInputType == 1) // key released
 451                         mouseClicked -= (mouseClicked & S_MOUSE1);
 452         }
 453         else if(nPrimary == K_MOUSE2)
 454         {
 455                 if(bInputType == 0) // key pressed
 456                         mouseClicked |= S_MOUSE2;
 457                 else if(bInputType == 1) // key released
 458                         mouseClicked -= (mouseClicked & S_MOUSE2);
 459         }
 460         else if(hit_con_bind)
 461                 return false;
 462
 463         return true;
 464 }
 465
 466 void QuickMenu_Mouse()
 467 {
 468         if(mv_active) return;
 469
 470         if(!mouseClicked)
 471         if(prevMouseClicked & S_MOUSE2)
 472         {
 473                 QuickMenu_Close();
 474                 return;
 475         }
 476
 477         if(!autocvar_hud_cursormode)
 478         {
 479                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 480
 481                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
 482                 mousepos_y = bound(0, mousepos_y, vid_conheight);
 483         }
 484
 485         HUD_Panel_UpdateCvars();
 486
 487         if(panel_bg_padding)
 488         {
 489                 panel_pos += '1 1 0' * panel_bg_padding;
 490                 panel_size -= '2 2 0' * panel_bg_padding;
 491         }
 492
 493         float first_entry_pos, entries_height;
 494         vector fontsize;
 495         fontsize = '1 1 0' * (panel_size_y / QUICKMENU_MAXLINES);
 496         first_entry_pos = panel_pos_y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y) / 2;
 497         entries_height = panel_size_y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y);
 498
 499         if (mousepos_x >= panel_pos_x && mousepos_y >= first_entry_pos && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= first_entry_pos + entries_height)
 500         {
 501                 float entry_num;
 502                 entry_num = floor((mousepos_y - first_entry_pos) / fontsize_y);
 503                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 504                 {
 505                         panel_pos_y = first_entry_pos + entry_num * fontsize_y;
 506                         vector color;
 507                         if(mouseClicked & S_MOUSE1)
 508                                 color = '0.5 1 0.5';
 509                         else if(hudShiftState & S_CTRL)
 510                                 color = '1 1 0.3';
 511                         else
 512                                 color = '1 1 1';
 513                         drawfill(panel_pos, eX * panel_size_x + eY * fontsize_y, color, .2, DRAWFLAG_NORMAL);
 514
 515                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 516                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 517                 }
 518         }
 519
 520         vector cursorsize = '32 32 0';
 521         drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 522
 523         prevMouseClicked = mouseClicked;
 524 }
 525
 526 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 527 {
 528         string entry;
 529         float offset;
 530         float desc_size = panel_size_x;
 531         if(option)
 532         {
 533                 float option_size = stringwidth_nocolors(option, fontsize);
 534                 desc_size -= option_size;
 535                 drawstring(pos + eX * desc_size, option, fontsize, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 536         }
 537         entry = textShortenToWidth(desc, desc_size, fontsize, stringwidth_colors);
 538         if (autocvar_hud_panel_quickmenu_align > 0)
 539         {
 540                 offset = (desc_size - stringwidth_colors(entry, fontsize)) * min(autocvar_hud_panel_quickmenu_align, 1);
 541                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 542         }
 543         else
 544                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 545 }
 546
 547 void HUD_QuickMenu(void)
 548 {
 549         if(!autocvar__hud_configure)
 550         {
 551                 if (hud_configure_prev && hud_configure_prev != -1)
 552                         QuickMenu_Close();
 553
 554                 if(!hud_draw_maximized) return;
 555                 if(mv_active) return;
 556                 //if(!autocvar_hud_panel_quickmenu) return;
 557                 if(!hud_panel_quickmenu) return;
 558
 559                 if(time > QuickMenu_TimeOut)
 560                 {
 561                         QuickMenu_Close();
 562                         return;
 563                 }
 564         }
 565         else
 566         {
 567                 if(!QuickMenu_IsOpened())
 568                 {
 569                         QuickMenu_Page_Entries = 1;
 570                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 571                         ++QuickMenu_Page_Entries;
 572                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 573                         ++QuickMenu_Page_Entries;
 574                         // although real command doesn't matter here, it must not be empty
 575                         // otherwise the entry is displayed like a submenu
 576                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 577                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 578                         ++QuickMenu_Page_Entries;
 579                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 580                         QuickMenu_IsLastPage = false;
 581                 }
 582         }
 583
 584         HUD_Panel_UpdateCvars();
 585
 586         HUD_Panel_DrawBg(1);
 587
 588         if(panel_bg_padding)
 589         {
 590                 panel_pos += '1 1 0' * panel_bg_padding;
 591                 panel_size -= '2 2 0' * panel_bg_padding;
 592         }
 593
 594         int i;
 595         vector fontsize;
 596         string color;
 597         fontsize = '1 1 0' * (panel_size_y / QUICKMENU_MAXLINES);
 598
 599         if (!QuickMenu_IsLastPage)
 600         {
 601                 color = "^5";
 602                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size_y - fontsize_y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 603         }
 604         else
 605                 panel_pos_y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize_y) / 2;
 606
 607         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 608                 if (QuickMenu_Page_Description[i] == "")
 609                         break;
 610                 string option = string_null;
 611                 if (QuickMenu_Page_Command[i] == "")
 612                         color = "^4";
 613                 else
 614                 {
 615                         color = "^3";
 616                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 617                         {
 618                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 619                                 if(end < 0)
 620                                         tokenize_console(QuickMenu_Page_Command[i]);
 621                                 else
 622                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 623
 624                                 //if(argv(1) && argv(0) == "toggle") // already checked
 625                                 {
 626                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 627                                         // "disable feature xxx" "toggle xxx 0 1"
 628                                         float ON_value = 1, OFF_value = 0;
 629                                         if(argv(2))
 630                                                 ON_value = stof(argv(2));
 631
 632                                         if(argv(3))
 633                                                 OFF_value = stof(argv(3));
 634                                         else
 635                                                 OFF_value = !ON_value;
 636
 637                                         float value = cvar(argv(1));
 638                                         if(value == ON_value)
 639                                                 option = "[X]";
 640                                         else if(value == OFF_value)
 641                                                 option = "[_]";
 642                                         else
 643                                                 option = "[?]";
 644                                 }
 645                         }
 646                 }
 647                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 648
 649                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 650                         && QuickMenu_Page_ActivatedEntry == i)
 651                         drawfill(panel_pos, eX * panel_size_x + eY * fontsize_y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 652
 653                 panel_pos_y += fontsize_y;
 654         }
 655
 656         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 657         {
 658                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 659                 {
 660                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 661                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 662                                 QuickMenu_Close();
 663                 }
 664                 else if(QuickMenu_Page_ActivatedEntry_Close)
 665                         QuickMenu_Close();
 666                 QuickMenu_Page_ActivatedEntry = -1;
 667                 QuickMenu_Page_ActivatedEntry_Time = 0;
 668         }
 669 }
 670
 671
 672 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 673         if(target_submenu == eng_submenu && target_submenu_found) \
 674                 return; /* target_submenu entries are now loaded, exit */ \
 675         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 676                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("S", submenu)); \
 677         ++QuickMenu_Buffer_Size; \
 678         if(target_submenu == eng_submenu && !target_submenu_found) { \
 679                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 680                 target_submenu_found = true; \
 681         } \
 682 }
 683
 684 #define QUICKMENU_ENTRY(title,command) { \
 685         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 686         { \
 687                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", title)); \
 688                 ++QuickMenu_Buffer_Size; \
 689                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("C", command)); \
 690         } \
 691         ++QuickMenu_Buffer_Size; \
 692 }
 693
 694 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 695         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 696                 QUICKMENU_SMENU(submenu,eng_submenu) \
 697                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("T", ftos(teamplayers), ftos(without_me))); \
 698                 ++QuickMenu_Buffer_Size; \
 699                 bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat("P", command)); \
 700                 ++QuickMenu_Buffer_Size; \
 701                 QUICKMENU_SMENU(submenu,eng_submenu) \
 702         } \
 703 }
 704
 705
 706
 707 // useful to Translate a string inside the Command
 708 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 709         if(prvm_language == "en") \
 710                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 711         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 712                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 713         else \
 714                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 715 }
 716
 717 void HUD_Quickmenu_PlayerListEntries(string cmd, float teamplayers, float without_me)
 718 {
 719         entity pl;
 720         if(teamplayers && !team_count)
 721                 return;
 722
 723         for(pl = players.sort_next; pl; pl = pl.sort_next)
 724         {
 725                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 726                         continue;
 727                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 728                         continue;
 729                 if(without_me && pl.sv_entnum == player_localnum)
 730                         continue;
 731                 QUICKMENU_ENTRY(GetPlayerName(pl.sv_entnum), sprintf(cmd, GetPlayerName(pl.sv_entnum)))
 732         }
 733
 734         return;
 735 }
 736
 737
 738 // Specifying target_submenu, this function only loads entries inside target_submenu
 739 // NOTE: alternatively we could have loaded the whole default quickmenu and
 740 // then called QuickMenu_Page_Load(target_submenu, 0);
 741 // but this sytem is more reliable since we can always refer to target_submenu
 742 // with the English title even if a translation is active
 743 void QuickMenu_Default(string target_submenu)
 744 {
 745         bool target_submenu_found = false;
 746         if(target_submenu != "")
 747                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 748
 749         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 750                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 751                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 752                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 753         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 754
 755         if(teamplay)
 756         {
 757         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 758                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 759                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 760                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 761                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 762                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 763                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 764                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 765                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 766                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 767                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 768                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 769                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 770                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 771                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 772                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; +use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 773         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 774         }
 775
 776         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s\" ^7", 0, 1)
 777
 778         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 779                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 780                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 781                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 782                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 783                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 784                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 785                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 786                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 787
 788                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 789                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 790                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle cl_chatsound")
 791                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 792
 793                 if(spectatee_status > 0)
 794                 {
 795                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 796                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 797                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 798                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 799                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 800                 }
 801
 802                 if(spectatee_status == -1)
 803                 {
 804                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 805                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 806                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 807                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 808                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 809                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 810                 }
 811
 812                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 813                 if(prvm_language != "en")
 814                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 815         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 816
 817         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 818                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 819                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 820                 if(getstatf(STAT_TIMELIMIT) > 0)
 821                 {
 822                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 823                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 824                 }
 825                 if(teamplay)
 826                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 827         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 828
 829         if(target_submenu != "" && !target_submenu_found)
 830         {
 831                 printf("Couldn't find submenu \"%s\"\n", target_submenu);
 832                 if(prvm_language != "en")
 833                         printf("^3Warning: submenu must be in English\n", target_submenu);
 834                 QuickMenu_Buffer_Size = 0;
 835         }
 836 }
 837 #undef QUICKMENU_SMENU
 838 #undef QUICKMENU_ENTRY
 839 #undef QUICKMENU_ENTRY_TC