qcsrc/client/scoreboard.qc

   1 float scoreboard_alpha_bg;
   2 float scoreboard_alpha_fg;
   3 float scoreboard_highlight;
   4 float scoreboard_highlight_alpha;
   5 float scoreboard_highlight_alpha_self;
   6 float scoreboard_alpha_name;
   7 float scoreboard_alpha_name_self;
   8
   9 void drawstringright(vector, string, vector, vector, float, float);
  10 void drawstringcenter(vector, string, vector, vector, float, float);
  11
  12 float SCOREBOARD_OFFSET = 50;
  13
  14 void MapVote_Draw();
  15 void HUD_FinaleOverlay()
  16 {
  17         /*vector pos;
  18         pos_x = (vid_conwidth - 1)/2;
  19         pos_y = 16;
  20         pos_z = 0;*/
  21
  22         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
  23
  24         //drawstring(pos, "END", hud_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  25         MapVote_Draw();
  26 }
  27
  28 void Cmd_HUD_SetFields(float argc);
  29 void HUD_InitScores()
  30 {
  31         float i, f;
  32
  33         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
  34         for(i = 0; i < MAX_SCORE; ++i)
  35         {
  36                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
  37                 if(f == SFL_SORT_PRIO_PRIMARY)
  38                         ps_primary = i;
  39                 if(f == SFL_SORT_PRIO_SECONDARY)
  40                         ps_secondary = i;
  41         }
  42         if(ps_secondary == -1)
  43                 ps_secondary = ps_primary;
  44
  45         for(i = 0; i < MAX_TEAMSCORE; ++i)
  46         {
  47                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
  48                 if(f == SFL_SORT_PRIO_PRIMARY)
  49                         ts_primary = i;
  50                 if(f == SFL_SORT_PRIO_SECONDARY)
  51                         ts_secondary = i;
  52         }
  53         if(ts_secondary == -1)
  54                 ts_secondary = ts_primary;
  55
  56         Cmd_HUD_SetFields(0);
  57 }
  58
  59 void HUD_UpdatePlayerPos(entity pl);
  60 float SetTeam(entity pl, float Team);
  61 //float lastpnum;
  62 void HUD_UpdatePlayerTeams()
  63 {
  64         float Team;
  65         entity pl, tmp;
  66         float num;
  67
  68         num = 0;
  69         for(pl = players.sort_next; pl; pl = pl.sort_next)
  70         {
  71                 num += 1;
  72                 Team = GetPlayerColor(pl.sv_entnum);
  73                 if(SetTeam(pl, Team))
  74                 {
  75                         tmp = pl.sort_prev;
  76                         HUD_UpdatePlayerPos(pl);
  77                         if(tmp)
  78                                 pl = tmp;
  79                         else
  80                                 pl = players.sort_next;
  81                 }
  82         }
  83         /*
  84         if(num != lastpnum)
  85                 print(strcat("PNUM: ", ftos(num), "\n"));
  86         lastpnum = num;
  87         */
  88 }
  89
  90 float HUD_ComparePlayerScores(entity left, entity right)
  91 {
  92         float vl, vr;
  93         vl = GetPlayerColor(left.sv_entnum);
  94         vr = GetPlayerColor(right.sv_entnum);
  95
  96         if(!left.gotscores)
  97                 vl = COLOR_SPECTATOR;
  98         if(!right.gotscores)
  99                 vr = COLOR_SPECTATOR;
 100
 101         if(vl > vr)
 102                 return true;
 103         if(vl < vr)
 104                 return false;
 105
 106         if(vl == COLOR_SPECTATOR)
 107         {
 108                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 109                 // no other sorting
 110                 if(!left.gotscores && right.gotscores)
 111                         return true;
 112                 return false;
 113         }
 114
 115         vl = left.scores[ps_primary];
 116         vr = right.scores[ps_primary];
 117         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 118         {
 119                 if(vl == 0 && vr != 0)
 120                         return 1;
 121                 if(vl != 0 && vr == 0)
 122                         return 0;
 123         }
 124         if(vl > vr)
 125                 return IS_INCREASING(scores_flags[ps_primary]);
 126         if(vl < vr)
 127                 return IS_DECREASING(scores_flags[ps_primary]);
 128
 129         vl = left.scores[ps_secondary];
 130         vr = right.scores[ps_secondary];
 131         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 132         {
 133                 if(vl == 0 && vr != 0)
 134                         return 1;
 135                 if(vl != 0 && vr == 0)
 136                         return 0;
 137         }
 138         if(vl > vr)
 139                 return IS_INCREASING(scores_flags[ps_secondary]);
 140         if(vl < vr)
 141                 return IS_DECREASING(scores_flags[ps_secondary]);
 142
 143         return false;
 144 }
 145
 146 void HUD_UpdatePlayerPos(entity player)
 147 {
 148         for(other = player.sort_next; other && HUD_ComparePlayerScores(player, other); other = player.sort_next)
 149         {
 150                 SORT_SWAP(player, other);
 151         }
 152         for(other = player.sort_prev; other != players && HUD_ComparePlayerScores(other, player); other = player.sort_prev)
 153         {
 154                 SORT_SWAP(other, player);
 155         }
 156 }
 157
 158 float HUD_CompareTeamScores(entity left, entity right)
 159 {
 160         float vl, vr;
 161
 162         if(left.team == COLOR_SPECTATOR)
 163                 return 1;
 164         if(right.team == COLOR_SPECTATOR)
 165                 return 0;
 166
 167         vl = left.teamscores[ts_primary];
 168         vr = right.teamscores[ts_primary];
 169         if(vl > vr)
 170                 return IS_INCREASING(teamscores_flags[ts_primary]);
 171         if(vl < vr)
 172                 return IS_DECREASING(teamscores_flags[ts_primary]);
 173
 174         vl = left.teamscores[ts_secondary];
 175         vr = right.teamscores[ts_secondary];
 176         if(vl > vr)
 177                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 178         if(vl < vr)
 179                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 180
 181         return false;
 182 }
 183
 184 void HUD_UpdateTeamPos(entity Team)
 185 {
 186         for(other = Team.sort_next; other && HUD_CompareTeamScores(Team, other); other = Team.sort_next)
 187         {
 188                 SORT_SWAP(Team, other);
 189         }
 190         for(other = Team.sort_prev; other != teams && HUD_CompareTeamScores(other, Team); other = Team.sort_prev)
 191         {
 192                 SORT_SWAP(other, Team);
 193         }
 194 }
 195
 196 void Cmd_HUD_Help(float argc)
 197 {
 198         print("You can modify the scoreboard using the ^2scoreboard_columns_set command.\n");
 199         print("^3|---------------------------------------------------------------|\n");
 200         print("Usage:\n");
 201         print("^2scoreboard_columns_set default\n");
 202         print("^2scoreboard_columns_set ^7filed1 field2 ...\n");
 203         print("The following field names are recognized (case insensitive):\n");
 204         print("You can use a ^3|^7 to start the right-aligned fields.\n\n");
 205
 206         print("^3name^7 or ^3nick^7         Name of a player\n");
 207         print("^3ping^7                     Ping time\n");
 208         print("^3pl^7                       Packet loss\n");
 209         print("^3kills^7                    Number of kills\n");
 210         print("^3deaths^7                   Number of deaths\n");
 211         print("^3suicides^7                 Number of suicides\n");
 212         print("^3frags^7                    kills - suicides\n");
 213         print("^3kd^7                       The kill-death ratio\n");
 214         print("^3caps^7                     How often a flag (CTF) or a key (KeyHunt) was captured\n");
 215         print("^3pickups^7                  How often a flag (CTF) or a key (KeyHunt) was picked up\n");
 216         print("^3fckills^7                  Number of flag carrier kills\n");
 217         print("^3returns^7                  Number of flag returns\n");
 218         print("^3drops^7                    Number of flag drops\n");
 219         print("^3lives^7                    Number of lives (LMS)\n");
 220         print("^3rank^7                     Player rank\n");
 221         print("^3pushes^7                   Number of players pushed into void\n");
 222         print("^3destroyed^7                Number of keys destroyed by pushing them into void\n");
 223         print("^3kckills^7                  Number of keys carrier kills\n");
 224         print("^3losses^7                   Number of times a key was lost\n");
 225         print("^3laps^7                     Number of laps finished (race/cts)\n");
 226         print("^3time^7                     Total time raced (race/cts)\n");
 227         print("^3fastest^7                  Time of fastest lap (race/cts)\n");
 228         print("^3ticks^7                    Number of ticks (DOM)\n");
 229         print("^3takes^7                    Number of domination points taken (DOM)\n");
 230         print("^3score^7                    Total score\n\n");
 231
 232         print("Before a field you can put a + or - sign, then a comma separated list\n");
 233         print("of game types, then a slash, to make the field show up only in these\n");
 234         print("or in all but these game types. You can also specify 'all' as a\n");
 235         print("field to show all fields available for the current game mode.\n\n");
 236
 237         print("The special game type names 'teams' and 'noteams' can be used to\n");
 238         print("include/exclude ALL teams/noteams game modes.\n\n");
 239
 240         print("Example: scoreboard_columns_set name ping pl | +ctf/field3 -dm/field4\n");
 241         print("will display name, ping and pl aligned to the left, and the fields\n");
 242         print("right of the vertical bar aligned to the right.\n");
 243         print("'field3' will only be shown in CTF, and 'field4' will be shown in all\n");
 244         print("other gamemodes except DM.\n");
 245 }
 246
 247 string HUD_DefaultColumnLayout()
 248 {
 249         return strcat( // fteqcc sucks
 250                 "ping pl name | ",
 251                 "-teams,race,lms/kills +freezetag/kills -teams,lms/deaths +freezetag/deaths -teams,lms,race,ka/suicides +freezetag/suicides -race,dm,tdm,ka,freezetag/frags ", // tdm already has this in "score"
 252                 "+ctf/caps +ctf/pickups +ctf/fckills +ctf/returns ",
 253                 "+lms/lives +lms/rank ",
 254                 "+kh/caps +kh/pushes +kh/destroyed ",
 255                 "?+race/laps ?+race/time ?+race/fastest ",
 256                 "+as/objectives +nexball/faults +nexball/goals +ka/drops +ka/pickups +ka/bckills +ka/time +freezetag/revivals ",
 257                 "-lms,race,nexball/score");
 258 }
 259
 260 void Cmd_HUD_SetFields(float argc)
 261 {
 262         float i, j, slash;
 263         string str, pattern;
 264         float have_name, have_primary, have_secondary, have_separator;
 265         float missing;
 266
 267         // TODO: re enable with gametype dependant cvars?
 268         if(argc < 2) // no arguments provided
 269                 argc = tokenizebyseparator(strcat("x ", autocvar_scoreboard_columns), " ");
 270
 271         if(argc < 2)
 272                 argc = tokenizebyseparator(strcat("x ", HUD_DefaultColumnLayout()), " ");
 273
 274         if(argc == 2)
 275         {
 276                 if(argv(1) == "default")
 277                         argc = tokenizebyseparator(strcat("x ", HUD_DefaultColumnLayout()), " ");
 278                 else if(argv(1) == "all")
 279                 {
 280                         string s;
 281                         s = "ping pl color name |";
 282                         for(i = 0; i < MAX_SCORE; ++i)
 283                         {
 284                                 if(i != ps_primary)
 285                                 if(i != ps_secondary)
 286                                 if(scores_label[i] != "")
 287                                         s = strcat(s, " ", scores_label[i]);
 288                         }
 289                         if(ps_secondary != ps_primary)
 290                                 s = strcat(s, " ", scores_label[ps_secondary]);
 291                         s = strcat(s, " ", scores_label[ps_primary]);
 292                         argc = tokenizebyseparator(strcat("x ", s), " ");
 293                 }
 294         }
 295
 296
 297         hud_num_fields = 0;
 298
 299         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 300
 301         for(i = 0; i < argc - 1; ++i)
 302         {
 303                 float nocomplain;
 304                 str = argv(i+1);
 305
 306                 nocomplain = FALSE;
 307                 if(substring(str, 0, 1) == "?")
 308                 {
 309                         nocomplain = TRUE;
 310                         str = substring(str, 1, strlen(str) - 1);
 311                 }
 312
 313                 slash = strstrofs(str, "/", 0);
 314                 if(slash >= 0)
 315                 {
 316                         pattern = substring(str, 0, slash);
 317                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 318
 319                         if not(isGametypeInFilter(gametype, teamplay, pattern))
 320                                 continue;
 321                 }
 322
 323                 strunzone(hud_title[hud_num_fields]);
 324                 hud_title[hud_num_fields] = strzone(str);
 325                 hud_size[hud_num_fields] = stringwidth(str, FALSE, hud_fontsize);
 326                 str = strtolower(str);
 327
 328                 if(str == "ping") {
 329                         hud_field[hud_num_fields] = SP_PING;
 330                 } else if(str == "pl") {
 331                         hud_field[hud_num_fields] = SP_PL;
 332                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 333                         hud_field[hud_num_fields] = SP_KDRATIO;
 334                 } else if(str == "name" || str == "nick") {
 335                         hud_field[hud_num_fields] = SP_NAME;
 336                         have_name = 1;
 337                 } else if(str == "|") {
 338                         hud_field[hud_num_fields] = SP_SEPARATOR;
 339                         have_separator = 1;
 340                 } else {
 341                         for(j = 0; j < MAX_SCORE; ++j)
 342                                 if(str == strtolower(scores_label[j]))
 343                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 344 :notfound
 345                         if(str == "frags")
 346                         {
 347                                 j = SP_FRAGS;
 348                         }
 349                         else
 350                         {
 351                                 if not(nocomplain)
 352                                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 353                                 continue;
 354                         }
 355 :found
 356                         hud_field[hud_num_fields] = j;
 357                         if(j == ps_primary)
 358                                 have_primary = 1;
 359                         if(j == ps_secondary)
 360                                 have_secondary = 1;
 361                 }
 362                 ++hud_num_fields;
 363                 if(hud_num_fields >= MAX_HUD_FIELDS)
 364                         break;
 365         }
 366
 367         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 368                 have_primary = 1;
 369         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 370                 have_secondary = 1;
 371         if(ps_primary == ps_secondary)
 372                 have_secondary = 1;
 373         missing = (!have_primary) + (!have_secondary) + (!have_separator) + (!have_name);
 374
 375         if(hud_num_fields+missing < MAX_HUD_FIELDS)
 376         {
 377                 if(!have_name)
 378                 {
 379                         strunzone(hud_title[hud_num_fields]);
 380                         for(i = hud_num_fields; i > 0; --i)
 381                         {
 382                                 hud_title[i] = hud_title[i-1];
 383                                 hud_size[i] = hud_size[i-1];
 384                                 hud_field[i] = hud_field[i-1];
 385                         }
 386                         hud_title[0] = strzone("name");
 387                         hud_field[0] = SP_NAME;
 388                         ++hud_num_fields;
 389                         print("fixed missing field 'name'\n");
 390
 391                         if(!have_separator)
 392                         {
 393                                 strunzone(hud_title[hud_num_fields]);
 394                                 for(i = hud_num_fields; i > 1; --i)
 395                                 {
 396                                         hud_title[i] = hud_title[i-1];
 397                                         hud_size[i] = hud_size[i-1];
 398                                         hud_field[i] = hud_field[i-1];
 399                                 }
 400                                 hud_title[1] = strzone("|");
 401                                 hud_field[1] = SP_SEPARATOR;
 402                                 hud_size[1] = stringwidth("|", FALSE, hud_fontsize);
 403                                 ++hud_num_fields;
 404                                 print("fixed missing field '|'\n");
 405                         }
 406                 }
 407                 else if(!have_separator)
 408                 {
 409                         strunzone(hud_title[hud_num_fields]);
 410                         hud_title[hud_num_fields] = strzone("|");
 411                         hud_size[hud_num_fields] = stringwidth("|", FALSE, hud_fontsize);
 412                         hud_field[hud_num_fields] = SP_SEPARATOR;
 413                         ++hud_num_fields;
 414                         print("fixed missing field '|'\n");
 415                 }
 416                 if(!have_secondary)
 417                 {
 418                         strunzone(hud_title[hud_num_fields]);
 419                         hud_title[hud_num_fields] = strzone(scores_label[ps_secondary]);
 420                         hud_size[hud_num_fields] = stringwidth(hud_title[hud_num_fields], FALSE, hud_fontsize);
 421                         hud_field[hud_num_fields] = ps_secondary;
 422                         ++hud_num_fields;
 423                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 424                 }
 425                 if(!have_primary)
 426                 {
 427                         strunzone(hud_title[hud_num_fields]);
 428                         hud_title[hud_num_fields] = strzone(scores_label[ps_primary]);
 429                         hud_size[hud_num_fields] = stringwidth(hud_title[hud_num_fields], FALSE, hud_fontsize);
 430                         hud_field[hud_num_fields] = ps_primary;
 431                         ++hud_num_fields;
 432                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 433                 }
 434         }
 435
 436         hud_field[hud_num_fields] = SP_END;
 437 }
 438
 439 // MOVEUP::
 440 vector hud_field_rgb;
 441 string hud_field_icon0;
 442 string hud_field_icon1;
 443 string hud_field_icon2;
 444 vector hud_field_icon0_rgb;
 445 vector hud_field_icon1_rgb;
 446 vector hud_field_icon2_rgb;
 447 float hud_field_icon0_alpha;
 448 float hud_field_icon1_alpha;
 449 float hud_field_icon2_alpha;
 450 string HUD_GetField(entity pl, float field)
 451 {
 452         float tmp, num, denom, f;
 453         string str;
 454         hud_field_rgb = '1 1 1';
 455         hud_field_icon0 = "";
 456         hud_field_icon1 = "";
 457         hud_field_icon2 = "";
 458         hud_field_icon0_rgb = '1 1 1';
 459         hud_field_icon1_rgb = '1 1 1';
 460         hud_field_icon2_rgb = '1 1 1';
 461         hud_field_icon0_alpha = 1;
 462         hud_field_icon1_alpha = 1;
 463         hud_field_icon2_alpha = 1;
 464         switch(field)
 465         {
 466                 case SP_PING:
 467                         if not(pl.gotscores)
 468                                 return "\x8D\x8D\x8D"; // >>> sign
 469                         //str = getplayerkey(pl.sv_entnum, "ping");
 470                         f = pl.ping;
 471                         if(f == 0)
 472                                 return "N/A";
 473                         tmp = max(0, min(220, f-80)) / 220;
 474                         hud_field_rgb = '1 1 1' - '0 1 1'*tmp;
 475                         return ftos(f);
 476
 477                 case SP_PL:
 478                         if not(pl.gotscores)
 479                                 return "N/A";
 480                         f = pl.ping_packetloss;
 481                         tmp = pl.ping_movementloss;
 482                         if(f == 0 && tmp == 0)
 483                                 return "";
 484                         str = ftos(ceil(f * 100));
 485                         if(tmp != 0)
 486                                 str = strcat(str, "~", ftos(ceil(tmp * 100)));
 487                         tmp = bound(0, f / 0.2 + tmp / 0.04, 1); // 20% is REALLY BAD pl
 488                         hud_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 489                         return str;
 490
 491                 case SP_NAME:
 492                         if(ready_waiting && pl.ready)
 493                         {
 494                                 hud_field_icon0 = "gfx/scoreboard/player_ready";
 495                         }
 496                         else if(!teamplay)
 497                         {
 498                                 f = stof(getplayerkey(pl.sv_entnum, "colors"));
 499                                 {
 500                                         hud_field_icon0 = "gfx/scoreboard/playercolor_base";
 501                                         hud_field_icon1 = "gfx/scoreboard/playercolor_shirt";
 502                                         hud_field_icon1_rgb = colormapPaletteColor(floor(f / 16), 0);
 503                                         hud_field_icon2 = "gfx/scoreboard/playercolor_pants";
 504                                         hud_field_icon2_rgb = colormapPaletteColor(mod(f, 16), 1);
 505                                 }
 506                         }
 507                         return GetPlayerName(pl.sv_entnum);
 508
 509                 case SP_FRAGS:
 510                         f = pl.(scores[SP_KILLS]);
 511                         f -= pl.(scores[SP_SUICIDES]);
 512                         return ftos(f);
 513
 514                 case SP_KDRATIO:
 515                         num = pl.(scores[SP_KILLS]);
 516                         denom = pl.(scores[SP_DEATHS]);
 517
 518                         if(denom == 0) {
 519                                 hud_field_rgb = '0 1 0';
 520                                 str = ftos(num);
 521                         } else if(num <= 0) {
 522                                 hud_field_rgb = '1 0 0';
 523                                 str = ftos(num/denom);
 524                         } else
 525                                 str = ftos(num/denom);
 526
 527                         tmp = strstrofs(str, ".", 0);
 528                         if(tmp > 0)
 529                                 str = substring(str, 0, tmp+2);
 530                         return str;
 531
 532                 default:
 533                         tmp = pl.(scores[field]);
 534                         f = scores_flags[field];
 535                         if(field == ps_primary)
 536                                 hud_field_rgb = '1 1 0';
 537                         else if(field == ps_secondary)
 538                                 hud_field_rgb = '0 1 1';
 539                         else
 540                                 hud_field_rgb = '1 1 1';
 541                         return ScoreString(f, tmp);
 542         }
 543         //return "error";
 544 }
 545
 546 float xmin, xmax, ymin, ymax, sbwidth;
 547 float hud_fixscoreboardcolumnwidth_len;
 548 float hud_fixscoreboardcolumnwidth_iconlen;
 549 float hud_fixscoreboardcolumnwidth_marginlen;
 550
 551 string HUD_FixScoreboardColumnWidth(float i, string str)
 552 {
 553         float field, f;
 554         vector sz;
 555         field = hud_field[i];
 556
 557         hud_fixscoreboardcolumnwidth_iconlen = 0;
 558
 559         if(hud_field_icon0 != "")
 560         {
 561                 sz = drawgetimagesize(hud_field_icon0);
 562                 f = sz_x / sz_y;
 563                 if(hud_fixscoreboardcolumnwidth_iconlen < f)
 564                         hud_fixscoreboardcolumnwidth_iconlen = f;
 565         }
 566
 567         if(hud_field_icon1 != "")
 568         {
 569                 sz = drawgetimagesize(hud_field_icon1);
 570                 f = sz_x / sz_y;
 571                 if(hud_fixscoreboardcolumnwidth_iconlen < f)
 572                         hud_fixscoreboardcolumnwidth_iconlen = f;
 573         }
 574
 575         if(hud_field_icon2 != "")
 576         {
 577                 sz = drawgetimagesize(hud_field_icon2);
 578                 f = sz_x / sz_y;
 579                 if(hud_fixscoreboardcolumnwidth_iconlen < f)
 580                         hud_fixscoreboardcolumnwidth_iconlen = f;
 581         }
 582
 583         hud_fixscoreboardcolumnwidth_iconlen *= hud_fontsize_y / hud_fontsize_x; // fix icon aspect
 584
 585         if(hud_fixscoreboardcolumnwidth_iconlen != 0)
 586                 hud_fixscoreboardcolumnwidth_marginlen = stringwidth(" ", FALSE, hud_fontsize);
 587         else
 588                 hud_fixscoreboardcolumnwidth_marginlen = 0;
 589
 590         if(field == SP_NAME) // name gets all remaining space
 591         {
 592                 float namesize, j;
 593                 namesize = sbwidth;// / hud_fontsize_x;
 594                 for(j = 0; j < hud_num_fields; ++j)
 595                         if(j != i)
 596                                 if (hud_field[i] != SP_SEPARATOR)
 597                                         namesize -= hud_size[j] + hud_fontsize_x;
 598                 namesize += hud_fontsize_x;
 599                 hud_size[i] = namesize;
 600
 601                 if (hud_fixscoreboardcolumnwidth_iconlen != 0)
 602                         namesize -= hud_fixscoreboardcolumnwidth_marginlen + hud_fixscoreboardcolumnwidth_iconlen;
 603                 str = textShortenToWidth(str, namesize, hud_fontsize, stringwidth_colors);
 604                 hud_fixscoreboardcolumnwidth_len = stringwidth(str, TRUE, hud_fontsize);
 605         }
 606         else
 607                 hud_fixscoreboardcolumnwidth_len = stringwidth(str, FALSE, hud_fontsize);
 608
 609         f = hud_fixscoreboardcolumnwidth_len + hud_fixscoreboardcolumnwidth_marginlen + hud_fixscoreboardcolumnwidth_iconlen;
 610         if(hud_size[i] < f)
 611                 hud_size[i] = f;
 612
 613         return str;
 614 }
 615
 616 void HUD_PrintScoreboardItem(vector pos, entity pl, float is_self, float pl_number)
 617 {
 618         vector tmp, rgb;
 619         rgb = GetTeamRGB(pl.team);
 620         string str;
 621         float i, field;
 622         float is_spec;
 623         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 624
 625         if((rgb == '1 1 1') && (!is_spec)) {
 626                 rgb_x = autocvar_scoreboard_color_bg_r + 0.5;
 627                 rgb_y = autocvar_scoreboard_color_bg_g + 0.5;
 628                 rgb_z = autocvar_scoreboard_color_bg_b + 0.5; }
 629
 630         // Layout:
 631         tmp_x = sbwidth;
 632         tmp_y = hud_fontsize_y * 1.25;
 633         tmp_z = 0;
 634
 635         // alternated rows highlighting
 636         if(is_self)
 637                 drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, scoreboard_highlight_alpha_self, DRAWFLAG_NORMAL);
 638         else if((scoreboard_highlight) && (!mod(pl_number,2)))
 639                 drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, scoreboard_highlight_alpha, DRAWFLAG_NORMAL);
 640
 641         tmp_y = 0;
 642
 643         for(i = 0; i < hud_num_fields; ++i)
 644         {
 645                 field = hud_field[i];
 646                 if(field == SP_SEPARATOR)
 647                         break;
 648
 649                 if(is_spec && field != SP_NAME && field != SP_PING) {
 650                         pos_x += hud_size[i] + hud_fontsize_x;
 651                         continue;
 652                 }
 653                 str = HUD_GetField(pl, field);
 654                 str = HUD_FixScoreboardColumnWidth(i, str);
 655
 656                 pos_x += hud_size[i] + hud_fontsize_x;
 657
 658                 if(field == SP_NAME) {
 659                         tmp_x = hud_size[i] - hud_fontsize_x*hud_fixscoreboardcolumnwidth_iconlen - hud_fixscoreboardcolumnwidth_marginlen + hud_fontsize_x;
 660                         if (is_self)
 661                                 drawcolorcodedstring(pos - tmp, str, hud_fontsize, scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 662                         else
 663                                 drawcolorcodedstring(pos - tmp, str, hud_fontsize, scoreboard_alpha_name, DRAWFLAG_NORMAL);
 664                 } else {
 665                         tmp_x = hud_fixscoreboardcolumnwidth_len + hud_fontsize_x;
 666                         if (is_self)
 667                                 drawstring(pos - tmp, str, hud_fontsize, hud_field_rgb, scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 668                         else
 669                                 drawstring(pos - tmp, str, hud_fontsize, hud_field_rgb, scoreboard_alpha_name, DRAWFLAG_NORMAL);
 670                 }
 671
 672                 tmp_x = hud_size[i] + hud_fontsize_x;
 673                 if(hud_field_icon0 != "")
 674                         if (is_self)
 675                                 drawpic(pos - tmp, hud_field_icon0, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon0_alpha * scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 676                         else
 677                                 drawpic(pos - tmp, hud_field_icon0, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon0_alpha * scoreboard_alpha_name, DRAWFLAG_NORMAL);
 678                 if(hud_field_icon1 != "")
 679                         if (is_self)
 680                                 drawpic(pos - tmp, hud_field_icon1, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon1_alpha * scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 681                         else
 682                                 drawpic(pos - tmp, hud_field_icon1, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon1_alpha * scoreboard_alpha_name, DRAWFLAG_NORMAL);
 683                 if(hud_field_icon2 != "")
 684                         if (is_self)
 685                                 drawpic(pos - tmp, hud_field_icon2, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon2_rgb, hud_field_icon2_alpha * scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 686                         else
 687                                 drawpic(pos - tmp, hud_field_icon2, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon2_rgb, hud_field_icon2_alpha * scoreboard_alpha_name, DRAWFLAG_NORMAL);
 688         }
 689
 690         if(hud_field[i] == SP_SEPARATOR)
 691         {
 692                 pos_x = xmax;
 693                 for(i = hud_num_fields-1; i > 0; --i)
 694                 {
 695                         field = hud_field[i];
 696                         if(field == SP_SEPARATOR)
 697                                 break;
 698
 699                         if(is_spec && field != SP_NAME && field != SP_PING) {
 700                                 pos_x -= hud_size[i] + hud_fontsize_x;
 701                                 continue;
 702                         }
 703
 704                         str = HUD_GetField(pl, field);
 705                         str = HUD_FixScoreboardColumnWidth(i, str);
 706
 707                         if(field == SP_NAME) {
 708                                 tmp_x = hud_fixscoreboardcolumnwidth_len; // left or right aligned? let's put it right...
 709                                 if(is_self)
 710                                         drawcolorcodedstring(pos - tmp, str, hud_fontsize, scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 711                                 else
 712                                         drawcolorcodedstring(pos - tmp, str, hud_fontsize, scoreboard_alpha_name, DRAWFLAG_NORMAL);
 713                         } else {
 714                                 tmp_x = hud_fixscoreboardcolumnwidth_len;
 715                                 if(is_self)
 716                                         drawstring(pos - tmp, str, hud_fontsize, hud_field_rgb, scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 717                                 else
 718                                         drawstring(pos - tmp, str, hud_fontsize, hud_field_rgb, scoreboard_alpha_name, DRAWFLAG_NORMAL);
 719                         }
 720
 721                         tmp_x = hud_size[i];
 722                         if(hud_field_icon0 != "")
 723                                 if (is_self)
 724                                         drawpic(pos - tmp, hud_field_icon0, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon0_alpha * scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 725                                 else
 726                                         drawpic(pos - tmp, hud_field_icon0, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon0_alpha * scoreboard_alpha_name, DRAWFLAG_NORMAL);
 727                         if(hud_field_icon1 != "")
 728                                 if (is_self)
 729                                         drawpic(pos - tmp, hud_field_icon1, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon1_alpha * scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 730                                 else
 731                                         drawpic(pos - tmp, hud_field_icon1, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon1_rgb, hud_field_icon1_alpha * scoreboard_alpha_name, DRAWFLAG_NORMAL);
 732                         if(hud_field_icon2 != "")
 733                                 if (is_self)
 734                                         drawpic(pos - tmp, hud_field_icon2, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon2_rgb, hud_field_icon2_alpha * scoreboard_alpha_name_self, DRAWFLAG_NORMAL);
 735                                 else
 736                                         drawpic(pos - tmp, hud_field_icon2, '0 1 0' * hud_fontsize_y + '1 0 0' * hud_fontsize_x * hud_fixscoreboardcolumnwidth_iconlen, hud_field_icon2_rgb, hud_field_icon2_alpha * scoreboard_alpha_name, DRAWFLAG_NORMAL);
 737                         pos_x -= hud_size[i] + hud_fontsize_x;
 738                 }
 739         }
 740 }
 741
 742 /*
 743  * HUD_Scoreboard_MakeTable
 744  *
 745  * Makes a table for a team (for all playing players in DM) and fills it
 746  */
 747
 748 vector HUD_Scoreboard_MakeTable(vector pos, entity tm, vector rgb, vector bg_size)
 749 {
 750         float body_table_height, i;
 751         vector tmp, column_dim;
 752         entity pl;
 753
 754         body_table_height = 1.25 * hud_fontsize_y * max(1, tm.team_size); // no player? show 1 empty line
 755
 756         pos -= '1 1 0';
 757
 758         tmp_x = sbwidth + 2;
 759         tmp_y = 1.25 * hud_fontsize_y;
 760
 761         // rounded header
 762         if (teamplay)
 763                 drawpic(pos, "gfx/scoreboard/scoreboard_tableheader", tmp, (rgb * autocvar_scoreboard_color_bg_team) + '0.5 0.5 0.5', scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 764         else
 765                 drawpic(pos, "gfx/scoreboard/scoreboard_tableheader", tmp, rgb + '0.5 0.5 0.5', scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 766
 767         // table border
 768         tmp_y += autocvar_scoreboard_border_thickness;
 769         tmp_y += body_table_height;
 770         drawborderlines(autocvar_scoreboard_border_thickness, pos, tmp, '0 0 0', scoreboard_alpha_bg, DRAWFLAG_NORMAL); // more transparency for the scoreboard
 771
 772         // separator header/table
 773         pos_y += 1.25 * hud_fontsize_y;
 774         tmp_y = autocvar_scoreboard_border_thickness;
 775         drawfill(pos, tmp, '0 0 0', scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 776
 777         pos_y += autocvar_scoreboard_border_thickness;
 778
 779         // table background
 780         tmp_y = body_table_height;
 781         if (teamplay)
 782                 drawpic_tiled(pos, "gfx/scoreboard/scoreboard_bg", bg_size, tmp, rgb * autocvar_scoreboard_color_bg_team, scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 783         else
 784                 drawpic_tiled(pos, "gfx/scoreboard/scoreboard_bg", bg_size, tmp, rgb, scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 785
 786         // anyway, apply some color
 787         //drawfill(pos, tmp + '2 0 0', rgb, 0.1, DRAWFLAG_NORMAL);
 788
 789         // go back to the top to make alternated columns highlighting and to print the strings
 790         pos_y -= 1.25 * hud_fontsize_y;
 791         pos_y -= autocvar_scoreboard_border_thickness;
 792
 793         pos += '1 1 0';
 794
 795         if (scoreboard_highlight)
 796         {
 797                 column_dim_y = 1.25 * hud_fontsize_y; // header
 798                 column_dim_y += autocvar_scoreboard_border_thickness;
 799                 column_dim_y += body_table_height;
 800         }
 801
 802         // print the strings of the columns headers and draw the columns
 803         for(i = 0; i < hud_num_fields; ++i)
 804         {
 805                 if(hud_field[i] == SP_SEPARATOR)
 806                         break;
 807                 column_dim_x = hud_size[i] + hud_fontsize_x;
 808                 if (scoreboard_highlight)
 809                 {
 810                         if (mod(i,2))
 811                                 drawfill(pos - '0 1 0' - hud_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
 812                 }
 813                 drawstring(pos, hud_title[i], hud_fontsize, rgb * 1.5, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
 814                 pos_x += column_dim_x;
 815         }
 816         if(hud_field[i] == SP_SEPARATOR)
 817         {
 818                 pos_x = xmax;
 819                 tmp_y = 0;
 820                 for(i = hud_num_fields-1; i > 0; --i)
 821                 {
 822                         if(hud_field[i] == SP_SEPARATOR)
 823                                 break;
 824
 825                         pos_x -= hud_size[i];
 826
 827                         if (scoreboard_highlight)
 828                         {
 829                                 if (!mod(i,2))
 830                                 {
 831                                         if (i == hud_num_fields-1)
 832                                                 column_dim_x = hud_size[i] + hud_fontsize_x / 2 + 1;
 833                                         else
 834                                                 column_dim_x = hud_size[i] + hud_fontsize_x;
 835                                         drawfill(pos - '0 1 0' - hud_fontsize_x / 2 * '1 0 0', column_dim, '0 0 0', scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
 836                                 }
 837                         }
 838
 839                         tmp_x = stringwidth(hud_title[i], FALSE, hud_fontsize);
 840                         tmp_x = (hud_size[i] - tmp_x);
 841                         drawstring(pos + tmp, hud_title[i], hud_fontsize, rgb * 1.5, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
 842                         pos_x -= hud_fontsize_x;
 843                 }
 844         }
 845
 846         pos_x = xmin;
 847         pos_y += 1.25 * hud_fontsize_y; // skip the header
 848         pos_y += autocvar_scoreboard_border_thickness;
 849
 850         // fill the table and draw the rows
 851         i = 0;
 852         if (teamplay)
 853                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 854                 {
 855                         if(pl.team != tm.team)
 856                                 continue;
 857                         HUD_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
 858                         pos_y += 1.25 * hud_fontsize_y;
 859                         ++i;
 860                 }
 861         else
 862                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 863                 {
 864                         if(pl.team == COLOR_SPECTATOR)
 865                                 continue;
 866                         HUD_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), i);
 867                         pos_y += 1.25 * hud_fontsize_y;
 868                         ++i;
 869                 }
 870
 871         if (i == 0)
 872                 pos_y += 1.25 * hud_fontsize_y; // move to the end of the table
 873         pos_y += 1.25 * hud_fontsize_y; // move empty row (out of the table)
 874
 875         return pos;
 876 }
 877
 878 float HUD_WouldDrawScoreboard() {
 879         if (autocvar__hud_configure)
 880                 return 0;
 881         else if (scoreboard_showscores)
 882                 return 1;
 883         else if (intermission == 1)
 884                 return 1;
 885         else if (intermission == 2)
 886                 return 0;
 887         else if (getstati(STAT_HEALTH) <= 0 && autocvar_cl_deathscoreboard && gametype != GAME_CTS)
 888                 return 1;
 889         else if (spectatee_status == -1)
 890                 return 1;
 891         else if (scoreboard_showscores_force)
 892                 return 1;
 893         return 0;
 894 }
 895
 896 float g_minstagib;
 897 float average_accuracy;
 898 vector HUD_DrawScoreboardAccuracyStats(vector pos, vector rgb, vector bg_size)
 899 {
 900         float i;
 901         float weapon_cnt = WEP_COUNT - 3; // either minstanex/nex are hidden, no port-o-launch, no tuba
 902         float rows;
 903         if(autocvar_scoreboard_accuracy_doublerows)
 904                 rows = 2;
 905         else
 906                 rows = 1;
 907         float height = 40;
 908         float fontsize = height * 1/3;
 909         float weapon_height = height * 2/3;
 910         float weapon_width = sbwidth / weapon_cnt;
 911
 912         drawstring(pos, strcat("Accuracy stats (average ", ftos(average_accuracy), "%)"), hud_fontsize, '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
 913         pos_y += 1.25 * hud_fontsize_y;
 914         vector tmp;
 915         tmp_x = sbwidth;
 916         tmp_y = height * rows;
 917
 918         if (teamplay)
 919                 drawpic_tiled(pos, "gfx/scoreboard/scoreboard_bg", bg_size, tmp, rgb * autocvar_scoreboard_color_bg_team, scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 920         else
 921                 drawpic_tiled(pos, "gfx/scoreboard/scoreboard_bg", bg_size, tmp, rgb, scoreboard_alpha_bg, DRAWFLAG_NORMAL);
 922         drawborderlines(autocvar_scoreboard_border_thickness, pos, tmp, '0 0 0', scoreboard_alpha_bg * 0.75, DRAWFLAG_NORMAL);
 923
 924         // column highlighting
 925         for(i = 0; i < weapon_cnt/rows; ++i)
 926         {
 927                 if(!mod(i, 2))
 928                         drawfill(pos + '1 0 0' * weapon_width * rows * i, '0 1 0' * height * rows + '1 0 0' * weapon_width * rows, '0 0 0', scoreboard_alpha_bg * 0.2, DRAWFLAG_NORMAL);
 929         }
 930
 931         // row highlighting
 932         for(i = 0; i < rows; ++i)
 933         {
 934                 drawfill(pos + '0 1 0' * weapon_height + '0 1 0' * height * i, '1 0 0' * sbwidth + '0 1 0' * fontsize, '1 1 1', scoreboard_highlight_alpha, DRAWFLAG_NORMAL);
 935         }
 936
 937         average_accuracy = 0;
 938         float weapons_with_stats;
 939         weapons_with_stats = 0;
 940         if(rows == 2)
 941                 pos_x += weapon_width / 2;
 942
 943         if(getstati(STAT_SWITCHWEAPON) == WEP_MINSTANEX)
 944                 g_minstagib = 1; // TODO: real detection for minstagib?
 945
 946         float weapon_stats, weapon_number;
 947
 948         if (!acc_levels)
 949                 rgb = '1 1 1';
 950         else if (acc_col_x[0] == -1)
 951                 for (i = 0; i < acc_levels; ++i)
 952                         acc_col[i] = stov(cvar_string(strcat("accuracy_color", ftos(i))));
 953
 954         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 955         {
 956                 self = get_weaponinfo(i);
 957                 if not(self.weapons)
 958                         continue;
 959                 if ((i == WEP_NEX && g_minstagib) || i == WEP_PORTO || (i == WEP_MINSTANEX && !g_minstagib) || i == WEP_TUBA) // skip port-o-launch, nex || minstanex and tuba
 960                         continue;
 961                 weapon_stats = weapon_accuracy[i-WEP_FIRST];
 962
 963                 float weapon_alpha;
 964                 if(weapon_stats >= 0)
 965                         weapon_alpha = scoreboard_alpha_fg;
 966                 else
 967                         weapon_alpha = 0.2 * scoreboard_alpha_fg;
 968
 969                 // weapon icon
 970                 drawpic_aspect_skin(pos, strcat("weapon", self.netname), '1 0 0' * weapon_width + '0 1 0' * weapon_height, '1 1 1', weapon_alpha, DRAWFLAG_NORMAL);
 971                 // the accuracy
 972                 if(weapon_stats >= 0) {
 973                         weapons_with_stats += 1;
 974                         average_accuracy += weapon_stats; // store sum of all accuracies in average_accuracy
 975
 976                         string s;
 977                         s = sprintf("%d%%", weapon_stats*100);
 978
 979                         float padding;
 980                         padding = (weapon_width - stringwidth(s, FALSE, '1 0 0' * fontsize)) / 2; // center the accuracy value
 981
 982                         if (acc_levels)
 983                         {
 984                                 // find the max level lower than weapon_stats
 985                                 float j;
 986                                 j = acc_levels-1;
 987                                 while ( j && weapon_stats < acc_lev[j] )
 988                                         --j;
 989
 990                                 // inject color j+1 in color j, how much depending on how much weapon_stats is higher than level j
 991                                 float factor;
 992                                 factor = (weapon_stats - acc_lev[j]) / (acc_lev[j+1] - acc_lev[j]);
 993                                 rgb = acc_col[j];
 994                                 rgb = rgb + factor * (acc_col[j+1] - rgb);
 995                         }
 996
 997                         drawstring(pos + '1 0 0' * padding + '0 1 0' * weapon_height, s, '1 1 0' * fontsize, rgb, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
 998                 }
 999                 pos_x += weapon_width * rows;
1000                 if(rows == 2 && i == 6) {
1001                         pos_x -= sbwidth;
1002                         pos_y += height;
1003                 }
1004         }
1005
1006         if(weapons_with_stats)
1007                 average_accuracy = floor(average_accuracy / weapons_with_stats);
1008
1009         if(rows == 2)
1010                 pos_x -= weapon_width / 2;
1011         pos_x -= sbwidth;
1012         pos_y += height;
1013
1014         pos_y +=  1.25 * hud_fontsize_y;
1015         return pos;
1016 }
1017
1018 vector HUD_DrawScoreboardRankings(vector pos, entity pl,  vector rgb, vector bg_size)
1019 {
1020         float i;
1021         RANKINGS_RECEIVED_CNT = 0;
1022         for (i=RANKINGS_CNT-1; i>=0; --i)
1023                 if (grecordtime[i])
1024                         ++RANKINGS_RECEIVED_CNT;
1025
1026         if (RANKINGS_RECEIVED_CNT == 0)
1027                 return pos;
1028
1029         float is_spec;
1030         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
1031         vector hl_rgb;
1032         hl_rgb_x = autocvar_scoreboard_color_bg_r + 0.5;
1033         hl_rgb_y = autocvar_scoreboard_color_bg_g + 0.5;
1034         hl_rgb_z = autocvar_scoreboard_color_bg_b + 0.5;
1035
1036         pos_y += hud_fontsize_y;
1037         drawstring(pos, strcat("Rankings"), hud_fontsize, '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1038         pos_y += hud_fontsize_y;
1039         vector tmp;
1040         tmp_x = sbwidth;
1041         tmp_y = 1.25 * hud_fontsize_y * RANKINGS_RECEIVED_CNT;
1042
1043         if (teamplay)
1044                 drawpic_tiled(pos, "gfx/scoreboard/scoreboard_bg", bg_size, tmp, rgb * autocvar_scoreboard_color_bg_team, scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1045         else
1046                 drawpic_tiled(pos, "gfx/scoreboard/scoreboard_bg", bg_size, tmp, rgb, scoreboard_alpha_bg, DRAWFLAG_NORMAL);
1047         drawborderlines(autocvar_scoreboard_border_thickness, pos, tmp, '0 0 0', scoreboard_alpha_bg * 0.75, DRAWFLAG_NORMAL);
1048
1049         // row highlighting
1050         for(i = 0; i<RANKINGS_RECEIVED_CNT; ++i)
1051         {
1052                 string n, p;
1053                 float t;
1054                 t = grecordtime[i];
1055                 if (t == 0)
1056                         continue;
1057                 n = grecordholder[i];
1058                 p = race_PlaceName(i+1);
1059                 if(grecordholder[i] == GetPlayerName(player_localentnum - 1))
1060                         drawfill(pos, '1 0 0' * sbwidth + '0 1.25 0' * hud_fontsize_y, hl_rgb, scoreboard_highlight_alpha_self, DRAWFLAG_NORMAL);
1061                 else if(!mod(i, 2) && scoreboard_highlight)
1062                         drawfill(pos, '1 0 0' * sbwidth + '0 1.25 0' * hud_fontsize_y, hl_rgb, scoreboard_highlight_alpha, DRAWFLAG_NORMAL);
1063                 drawstring(pos, p, '1 1 0' * hud_fontsize_y, '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1064                 drawstring(pos + '3 0 0' * hud_fontsize_y, TIME_ENCODED_TOSTRING(t), '1 1 0' * hud_fontsize_y, '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1065                 drawcolorcodedstring(pos + '8 0 0' * hud_fontsize_y, n, '1 1 0' * hud_fontsize_y, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1066                 pos_y += 1.25 * hud_fontsize_y;
1067         }
1068
1069         return pos;
1070 }
1071
1072 float hud_woulddrawscoreboard_prev;
1073 float hud_woulddrawscoreboard_change; // "time" at which HUD_WouldDrawScoreboard() changed
1074 void HUD_DrawScoreboard()
1075 {
1076         float hud_woulddrawscoreboard;
1077         hud_woulddrawscoreboard = scoreboard_active;
1078         if(hud_woulddrawscoreboard != hud_woulddrawscoreboard_prev) {
1079                 hud_woulddrawscoreboard_change = time;
1080                 hud_woulddrawscoreboard_prev = hud_woulddrawscoreboard;
1081         }
1082
1083         if(hud_woulddrawscoreboard) {
1084                 float scoreboard_fadeinspeed = autocvar_scoreboard_fadeinspeed;
1085                 if (scoreboard_fadeinspeed)
1086                         scoreboard_fade_alpha = bound (0, (time - hud_woulddrawscoreboard_change) * scoreboard_fadeinspeed, 1);
1087                 else
1088                         scoreboard_fade_alpha = 1;
1089         }
1090         else {
1091                 float scoreboard_fadeoutspeed = autocvar_scoreboard_fadeoutspeed;
1092                 if (scoreboard_fadeoutspeed)
1093                         scoreboard_fade_alpha = bound (0, (1/scoreboard_fadeoutspeed - (time - hud_woulddrawscoreboard_change)) * scoreboard_fadeoutspeed, 1);
1094                 else
1095                         scoreboard_fade_alpha = 0;
1096         }
1097
1098         if not(scoreboard_fade_alpha)
1099                 return;
1100
1101         HUD_UpdatePlayerTeams();
1102
1103         scoreboard_alpha_bg = autocvar_scoreboard_alpha_bg * scoreboard_fade_alpha * (1 - autocvar__menu_alpha);
1104         scoreboard_alpha_fg = autocvar_scoreboard_alpha_fg * scoreboard_fade_alpha * (1 - autocvar__menu_alpha);
1105         scoreboard_highlight = autocvar_scoreboard_highlight;
1106         scoreboard_highlight_alpha = autocvar_scoreboard_highlight_alpha * scoreboard_alpha_fg;
1107         scoreboard_highlight_alpha_self = autocvar_scoreboard_highlight_alpha_self * scoreboard_alpha_fg;
1108         scoreboard_alpha_name = autocvar_scoreboard_alpha_name * scoreboard_alpha_fg;
1109         scoreboard_alpha_name_self = autocvar_scoreboard_alpha_name_self * scoreboard_alpha_fg;
1110
1111         vector rgb, pos, tmp;
1112         entity pl, tm;
1113
1114         xmin = autocvar_scoreboard_offset_left * vid_conwidth;
1115         ymin = autocvar_con_notify * autocvar_con_notifysize;
1116
1117         xmax = (1 - autocvar_scoreboard_offset_right) * vid_conwidth;
1118         ymax = vid_conheight - ymin;
1119
1120         sbwidth = xmax - xmin;
1121
1122         // Initializes position
1123         pos_x = xmin;
1124         pos_y = ymin;
1125         pos_z = 0;
1126
1127         // Heading
1128         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1129
1130         centerprint_start_x = vid_conwidth - 0.5 * (pos_x + stringwidth("Scoreboard", FALSE, '24 24 0'));
1131         centerprint_start_y = pos_y;
1132
1133         pos_y += 24;
1134
1135         // Draw the scoreboard
1136         vector bg_size = drawgetimagesize("gfx/scoreboard/scoreboard_bg") * autocvar_scoreboard_bg_scale;
1137
1138         if(teamplay)
1139         {
1140                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1141                 {
1142                         if(tm.team == COLOR_SPECTATOR)
1143                                 continue;
1144
1145                         rgb = GetTeamRGB(tm.team);
1146                         drawstring(pos - '2 0 0' * hud_fontsize_x + '0 1 0' * hud_fontsize_y, ftos(tm.(teamscores[ts_primary])), '1 1 0' * hud_fontsize_y * 1.5, rgb, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1147
1148                         if(ts_primary != ts_secondary)
1149                                 drawstring(pos - '2 0 0' * hud_fontsize_x + '0 2.5 0' * hud_fontsize_y, ftos(tm.(teamscores[ts_secondary])), '1 1 0' * hud_fontsize_y * 1, rgb, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1150
1151                         pos = HUD_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1152                 }
1153         }
1154         else
1155         {
1156                 rgb_x = autocvar_scoreboard_color_bg_r;
1157                 rgb_y = autocvar_scoreboard_color_bg_g;
1158                 rgb_z = autocvar_scoreboard_color_bg_b;
1159
1160                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1161                 {
1162                         if(tm.team == COLOR_SPECTATOR)
1163                                 continue;
1164
1165                         pos = HUD_Scoreboard_MakeTable(pos, tm, rgb, bg_size);
1166                 }
1167         }
1168
1169         if(gametype == GAME_CTS || gametype == GAME_RACE) {
1170                 if(race_speedaward) {
1171                         drawcolorcodedstring(pos, strcat("Speed award: ", ftos(race_speedaward), " ^7(", race_speedaward_holder, "^7)"), hud_fontsize, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1172                         pos_y += 1.25 * hud_fontsize_y;
1173                 }
1174                 if(race_speedaward_alltimebest) {
1175                         drawcolorcodedstring(pos, strcat("All-time fastest: ", ftos(race_speedaward_alltimebest), " ^7(", race_speedaward_alltimebest_holder, "^7)"), hud_fontsize, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1176                         pos_y += 1.25 * hud_fontsize_y;
1177                 }
1178                 pos = HUD_DrawScoreboardRankings(pos, pl, rgb, bg_size);
1179         }
1180         else if(autocvar_scoreboard_accuracy && spectatee_status != -1 && !warmup_stage) {
1181                 if(teamplay)
1182                         pos = HUD_DrawScoreboardAccuracyStats(pos, GetTeamRGB(myteam), bg_size);
1183                 else
1184                         pos = HUD_DrawScoreboardAccuracyStats(pos, rgb, bg_size);
1185         }
1186
1187         // List spectators
1188         float specs;
1189         specs = 0;
1190         tmp = pos;
1191         for(pl = players.sort_next; pl; pl = pl.sort_next)
1192         {
1193                 if(pl.team != COLOR_SPECTATOR)
1194                         continue;
1195                 pos_y += 1.25 * hud_fontsize_y;
1196                 HUD_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1), specs);
1197                 ++specs;
1198         }
1199
1200         if(specs)
1201         {
1202                 drawstring(tmp, "Spectators", hud_fontsize, '1 1 1', scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1203                 pos_y += 1.25 * hud_fontsize_y;
1204         }
1205
1206         // Print info string
1207         string str;
1208         float tl, fl, ll;
1209         str = strcat("playing on ^2", shortmapname, "^7");
1210         tl = getstatf(STAT_TIMELIMIT);
1211         fl = getstatf(STAT_FRAGLIMIT);
1212         ll = getstatf(STAT_LEADLIMIT);
1213         if(gametype == GAME_LMS)
1214         {
1215                 if(tl > 0)
1216                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
1217         }
1218         else
1219         {
1220                 if(tl > 0)
1221                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
1222                 if(fl > 0)
1223                 {
1224                         if(tl > 0)
1225                                 str = strcat(str, " or");
1226                         if(teamplay)
1227                         {
1228                                 str = strcat(str, " until ^3", ScoreString(teamscores_flags[ts_primary], fl));
1229                                 if(teamscores_label[ts_primary] == "score")
1230                                         str = strcat(str, " points^7");
1231                                 else if(teamscores_label[ts_primary] == "fastest")
1232                                         str = strcat(str, " is beaten^7");
1233                                 else
1234                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1235                         }
1236                         else
1237                         {
1238                                 str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
1239                                 if(scores_label[ps_primary] == "score")
1240                                         str = strcat(str, " points^7");
1241                                 else if(scores_label[ps_primary] == "fastest")
1242                                         str = strcat(str, " is beaten^7");
1243                                 else
1244                                         str = strcat(str, " ", scores_label[ps_primary]);
1245                         }
1246                 }
1247                 if(ll > 0)
1248                 {
1249                         if(tl > 0 || fl > 0)
1250                                 str = strcat(str, " or");
1251                         if(teamplay)
1252                         {
1253                                 str = strcat(str, " until a lead of ^3", ScoreString(teamscores_flags[ts_primary], ll));
1254                                 if(teamscores_label[ts_primary] == "score")
1255                                         str = strcat(str, " points^7");
1256                                 else if(teamscores_label[ts_primary] == "fastest")
1257                                         str = strcat(str, " is beaten^7");
1258                                 else
1259                                         str = strcat(str, " ", teamscores_label[ts_primary]);
1260                         }
1261                         else
1262                         {
1263                                 str = strcat(str, " until a lead of ^3", ScoreString(scores_flags[ps_primary], ll));
1264                                 if(scores_label[ps_primary] == "score")
1265                                         str = strcat(str, " points^7");
1266                                 else if(scores_label[ps_primary] == "fastest")
1267                                         str = strcat(str, " is beaten^7");
1268                                 else
1269                                         str = strcat(str, " ", scores_label[ps_primary]);
1270                         }
1271                 }
1272         }
1273
1274
1275         pos_y += 1.2 * hud_fontsize_y;
1276         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - stringwidth(str, TRUE, hud_fontsize)), str, hud_fontsize, scoreboard_alpha_fg, DRAWFLAG_NORMAL);
1277
1278         scoreboard_bottom = pos_y + 2 * hud_fontsize_y;
1279 }