qcsrc/client/shownames.qc

   1 #include "shownames.qh"
   2
   3 #include "hud/_mod.qh"
   4
   5 #include <common/ent_cs.qh>
   6 #include <common/constants.qh>
   7 #include <common/net_linked.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/teams.qh>
  10
  11 #include <lib/csqcmodel/cl_model.qh>
  12
  13 // this.isactive = player is in range and coordinates/status (health and armor) are up to date
  14 // this.origin = player origin
  15 // this.healthvalue
  16 // this.armorvalue
  17 // this.sameteam = player is on same team as local client
  18 // this.fadedelay = time to wait before name tag starts fading in for enemies
  19 // this.pointtime = last time you pointed at this player
  20 // this.csqcmodel_isdead = value of csqcmodel_isdead to know when the player is dead or not
  21
  22 LinkedList shownames_ent;
  23 STATIC_INIT(shownames_ent)
  24 {
  25         shownames_ent = LL_NEW();
  26         for (int i = 0; i < maxclients; ++i)
  27         {
  28                 entity e = new_pure(shownames_tag);
  29                 e.sv_entnum = i + 1;
  30                 LL_PUSH(shownames_ent, e);
  31         }
  32 }
  33
  34 const float SHOWNAMES_FADESPEED = 4;
  35 const float SHOWNAMES_FADEDELAY = 0.4;
  36 void Draw_ShowNames(entity this)
  37 {
  38         if (this.sv_entnum == (current_player + 1))  // self or spectatee
  39                 if (!(autocvar_hud_shownames_self && autocvar_chase_active)) return;
  40         if (!this.sameteam && !autocvar_hud_shownames_enemies) return;
  41         bool hit;
  42         if (!autocvar_hud_shownames_crosshairdistance && this.sameteam)
  43         {
  44                 hit = true;
  45         }
  46         else
  47         {
  48                 traceline(view_origin, this.origin, MOVE_NORMAL, this);
  49                 hit = !(trace_fraction < 1 && (trace_networkentity != this.sv_entnum && trace_ent.entnum != this.sv_entnum));
  50         }
  51         // handle tag fading
  52         int overlap = -1;
  53         vector o = project_3d_to_2d(this.origin + eZ * autocvar_hud_shownames_offset);
  54         if (autocvar_hud_shownames_crosshairdistance)
  55         {
  56                 float d = autocvar_hud_shownames_crosshairdistance;
  57                 float w = o.x - vid_conwidth / 2;
  58                 float h = o.y - vid_conheight / 2;
  59                 if (d * d > w * w + h * h) this.pointtime = time;
  60                 if (this.pointtime + autocvar_hud_shownames_crosshairdistance_time <= time)
  61                         overlap = 1;
  62                 else if(!autocvar_hud_shownames_crosshairdistance_antioverlap)
  63                         overlap = 0;
  64         }
  65
  66         float dist = vlen(this.origin - view_origin);
  67         if (overlap == -1 && autocvar_hud_shownames_antioverlap)
  68         {
  69                 // fade tag out if another tag that is closer to you overlaps
  70                 entity entcs = NULL;
  71                 LL_EACH(shownames_ent, it != this, {
  72                         entcs = entcs_receiver(i);
  73                         if (!(entcs && entcs.has_sv_origin))
  74                                 continue;
  75                         vector eo = project_3d_to_2d(it.origin);
  76                         if (eo.z < 0 || eo.x < 0 || eo.y < 0 || eo.x > vid_conwidth || eo.y > vid_conheight) continue;
  77                         eo.z = 0;
  78                         if (vdist(((eX * o.x + eY * o.y) - eo), <, autocvar_hud_shownames_antioverlap_distance)
  79                             && vdist((it.origin - view_origin), <, dist))
  80                         {
  81                                 overlap = 1;
  82                                 break;
  83                         }
  84                 });
  85         }
  86         bool onscreen = (o.z >= 0 && o.x >= 0 && o.y >= 0 && o.x <= vid_conwidth && o.y <= vid_conheight);
  87         if (!this.fadedelay) this.fadedelay = time + SHOWNAMES_FADEDELAY;
  88         if (this.csqcmodel_isdead)                                                                   // dead player, fade out slowly
  89         {
  90                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  91         }
  92         else if (!onscreen || (!this.sameteam && !hit)) // out of view, fade out
  93         {
  94                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
  95                 this.fadedelay = 0;                         // reset fade in delay, enemy has left the view
  96         }
  97         else if (overlap > 0) // tag overlap detected, fade out
  98         {
  99                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
 100         }
 101         else if (this.sameteam)  // fade in for team mates
 102         {
 103                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
 104         }
 105         else if (time > this.fadedelay)  // fade in for enemies
 106         {
 107                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
 108         }
 109         float a = autocvar_hud_shownames_alpha * this.alpha;
 110         // multiply by player alpha
 111         if (!this.sameteam || (this.sv_entnum == player_localentnum))
 112         {
 113                 float f = entcs_GetAlpha(this.sv_entnum - 1);
 114                 if (f == 0) f = 1;
 115                 if (f < 0) f = 0;
 116                 // FIXME: alpha is negative when dead, breaking death fade
 117                 if (!this.csqcmodel_isdead) a *= f;
 118         }
 119         if (a < ALPHA_MIN_VISIBLE && gametype != MAPINFO_TYPE_CTS) return;
 120         if (vdist(this.origin - view_origin, >=, max_shot_distance)) return;
 121         if (autocvar_hud_shownames_maxdistance)
 122         {
 123                 if (dist >= autocvar_hud_shownames_maxdistance) return;
 124                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
 125                 a *= (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
 126         }
 127         if (!a) return;
 128         float resize = 1;
 129         if (autocvar_hud_shownames_resize)  // limit resize so its never smaller than 0.5... gets unreadable
 130         {
 131                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
 132                 resize = 0.5 + 0.5 * (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
 133         }
 134         // draw the sprite image
 135         if (o.z >= 0)
 136         {
 137                 o.z = 0;
 138                 vector mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 139                 vector myPos = o - '0.5 0 0' * mySize.x - '0 1 0' * mySize.y;
 140                 // size scaling
 141                 mySize.x *= resize;
 142                 mySize.y *= resize;
 143                 myPos.x += 0.5 * (mySize.x / resize - mySize.x);
 144                 myPos.y += (mySize.y / resize - mySize.y);
 145                 // this is where the origin of the string
 146                 vector namepos = myPos;
 147                 float namewidth = mySize.x;
 148                 if (autocvar_hud_shownames_status && this.sameteam)
 149                 {
 150                         vector v = namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize;
 151                         vector s = eX * 0.5 * mySize.x + eY * resize * autocvar_hud_shownames_statusbar_height;
 152                         if (this.healthvalue > 0)
 153                         {
 154                                 HUD_Panel_DrawProgressBar(v, s, "nametag_statusbar",
 155                                         this.healthvalue / autocvar_hud_panel_healtharmor_maxhealth, false, 1, '1 0 0', a,
 156                                         DRAWFLAG_NORMAL);
 157                         }
 158                         if (this.armorvalue > 0)
 159                         {
 160                                 HUD_Panel_DrawProgressBar(v + eX * 0.5 * mySize.x, s, "nametag_statusbar",
 161                                         this.armorvalue / autocvar_hud_panel_healtharmor_maxarmor, false, 0, '0 1 0', a,
 162                                         DRAWFLAG_NORMAL);
 163                         }
 164                 }
 165                 string s = entcs_GetName(this.sv_entnum - 1);
 166                 if ((autocvar_hud_shownames_decolorize == 1 && teamplay)
 167                     || autocvar_hud_shownames_decolorize == 2) s = playername(s, entcs_GetTeam(this.sv_entnum - 1));
 168                 drawfontscale = '1 1 0' * resize;
 169                 s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 170                 float width = stringwidth(s, true, '1 1 0' * autocvar_hud_shownames_fontsize);
 171                 if (width != namewidth) namepos.x += (namewidth - width) / 2;
 172                 drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 173                 drawfontscale = '1 1 0';
 174         }
 175 }
 176
 177 void Draw_ShowNames_All()
 178 {
 179         if (!autocvar_hud_shownames) return;
 180         LL_EACH(shownames_ent, true, {
 181                 entity entcs = entcs_receiver(i);
 182                 if (!entcs)
 183                 {
 184                         make_pure(it);
 185                         continue;
 186                 }
 187                 make_impure(it);
 188                 assert(getthink(entcs), eprint(entcs));
 189                 getthink(entcs)(entcs);
 190                 if (!entcs.has_origin) continue;
 191                 if (entcs.m_entcs_private)
 192                 {
 193                         it.healthvalue = entcs.healthvalue;
 194                         it.armorvalue = entcs.armorvalue;
 195                         it.sameteam = true;
 196                 }
 197                 else
 198                 {
 199                         it.healthvalue = 0;
 200                         it.armorvalue = 0;
 201                         it.sameteam = false;
 202                 }
 203                 bool dead = entcs_IsDead(i) || entcs_IsSpectating(i);
 204                 if (!it.csqcmodel_isdead) setorigin(it, entcs.origin);
 205                 it.csqcmodel_isdead = dead;
 206                 Draw_ShowNames(it);
 207         });
 208 }