qcsrc/client/shownames.qc

   1 #include "shownames.qh"
   2
   3 #include "hud/all.qh"
   4
   5 #include "../common/constants.qh"
   6 #include "../common/mapinfo.qh"
   7 #include "../common/teams.qh"
   8
   9 #include "../lib/csqcmodel/cl_model.qh"
  10
  11 // this.isactive = player is in range and coordinates/status (health and armor) are up to date
  12 // this.origin = player origin
  13 // this.healthvalue
  14 // this.armorvalue
  15 // this.sameteam = player is on same team as local client
  16 // this.fadedelay = time to wait before name tag starts fading in for enemies
  17 // this.pointtime = last time you pointed at this player
  18 // this.csqcmodel_isdead = value of csqcmodel_isdead to know when the player is dead or not
  19
  20 LinkedList shownames_ent;
  21 STATIC_INIT(shownames_ent)
  22 {
  23         shownames_ent = LL_NEW();
  24         for (int i = 0; i < maxclients; ++i)
  25         {
  26                 entity e = new_pure(shownames_tag);
  27                 e.sv_entnum = i + 1;
  28                 LL_PUSH(shownames_ent, e);
  29         }
  30 }
  31
  32 const float SHOWNAMES_FADESPEED = 4;
  33 const float SHOWNAMES_FADEDELAY = 0.4;
  34 void Draw_ShowNames(entity this)
  35 {
  36         if (this.sv_entnum == player_localentnum)  // self or spectatee
  37                 if (!(autocvar_hud_shownames_self && autocvar_chase_active)) return;
  38         if (!this.sameteam && !autocvar_hud_shownames_enemies) return;
  39         bool hit;
  40         if (!autocvar_hud_shownames_crosshairdistance && this.sameteam)
  41         {
  42                 hit = true;
  43         }
  44         else
  45         {
  46                 traceline(view_origin, this.origin, MOVE_NORMAL, this);
  47                 hit = !(trace_fraction < 1 && (trace_networkentity != this.sv_entnum && trace_ent.entnum != this.sv_entnum));
  48         }
  49         // handle tag fading
  50         bool overlap = false;
  51         vector o = project_3d_to_2d(this.origin + eZ * autocvar_hud_shownames_offset);
  52         float dist = vlen(this.origin - view_origin);
  53         if (autocvar_hud_shownames_antioverlap)
  54         {
  55                 // fade tag out if another tag that is closer to you overlaps
  56                 LL_EACH(shownames_ent, it != this && entcs_receiver(i), {
  57                         vector eo = project_3d_to_2d(it.origin);
  58                         if (eo.z < 0 || eo.x < 0 || eo.y < 0 || eo.x > vid_conwidth || eo.y > vid_conheight) continue;
  59                         eo.z = 0;
  60                         if (vdist(((eX * o.x + eY * o.y) - eo), <, autocvar_hud_shownames_antioverlap_distance)
  61                             && vdist((it.origin - view_origin), <, dist))
  62                         {
  63                                 overlap = true;
  64                                 break;
  65                         }
  66                 });
  67         }
  68         bool onscreen = (o.z >= 0 && o.x >= 0 && o.y >= 0 && o.x <= vid_conwidth && o.y <= vid_conheight);
  69         if (autocvar_hud_shownames_crosshairdistance)
  70         {
  71                 float d = autocvar_hud_shownames_crosshairdistance;
  72                 float w = o.x - vid_conwidth / 2;
  73                 float h = o.y - vid_conheight / 2;
  74                 if (d * d > w * w + h * h) this.pointtime = time;
  75                 if (this.pointtime + autocvar_hud_shownames_crosshairdistance_time <= time) overlap = true;
  76                 else overlap = (autocvar_hud_shownames_crosshairdistance_antioverlap ? overlap : false); // override what antioverlap says unless allowed by cvar.
  77         }
  78         if (!this.fadedelay) this.fadedelay = time + SHOWNAMES_FADEDELAY;
  79         if (this.csqcmodel_isdead)                                                                   // dead player, fade out slowly
  80         {
  81                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  82         }
  83         else if (!onscreen || (!this.sameteam && !hit)) // out of view, fade out
  84         {
  85                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
  86                 this.fadedelay = 0;                         // reset fade in delay, enemy has left the view
  87         }
  88         else if (overlap)                               // tag overlap detected, fade out
  89         {
  90                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
  91         }
  92         else if (this.sameteam)  // fade in for team mates
  93         {
  94                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
  95         }
  96         else if (time > this.fadedelay)  // fade in for enemies
  97         {
  98                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
  99         }
 100         float a = autocvar_hud_shownames_alpha * this.alpha;
 101         // multiply by player alpha
 102         if (!this.sameteam || (this.sv_entnum == player_localentnum))
 103         {
 104                 float f = entcs_GetAlpha(this.sv_entnum - 1);
 105                 if (f == 0) f = 1;
 106                 if (f < 0) f = 0;
 107                 // FIXME: alpha is negative when dead, breaking death fade
 108                 if (!this.csqcmodel_isdead) a *= f;
 109         }
 110         if (a < ALPHA_MIN_VISIBLE && gametype != MAPINFO_TYPE_CTS) return;
 111         if (autocvar_hud_shownames_maxdistance)
 112         {
 113                 if (dist >= autocvar_hud_shownames_maxdistance) return;
 114                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
 115                 a *= (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
 116         }
 117         if (!a) return;
 118         float resize = 1;
 119         if (autocvar_hud_shownames_resize)  // limit resize so its never smaller than 0.5... gets unreadable
 120         {
 121                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
 122                 resize = 0.5 + 0.5 * (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
 123         }
 124         // draw the sprite image
 125         if (o.z >= 0)
 126         {
 127                 o.z = 0;
 128                 vector mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 129                 vector myPos = o - '0.5 0 0' * mySize.x - '0 1 0' * mySize.y;
 130                 // size scaling
 131                 mySize.x *= resize;
 132                 mySize.y *= resize;
 133                 myPos.x += 0.5 * (mySize.x / resize - mySize.x);
 134                 myPos.y += (mySize.y / resize - mySize.y);
 135                 // this is where the origin of the string
 136                 vector namepos = myPos;
 137                 float namewidth = mySize.x;
 138                 if (autocvar_hud_shownames_status && this.sameteam)
 139                 {
 140                         vector v = namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize;
 141                         vector s = eX * 0.5 * mySize.x + eY * resize * autocvar_hud_shownames_statusbar_height;
 142                         if (this.healthvalue > 0)
 143                         {
 144                                 HUD_Panel_DrawProgressBar(v, s, "nametag_statusbar",
 145                                         this.healthvalue / autocvar_hud_panel_healtharmor_maxhealth, false, 1, '1 0 0', a,
 146                                         DRAWFLAG_NORMAL);
 147                         }
 148                         if (this.armorvalue > 0)
 149                         {
 150                                 HUD_Panel_DrawProgressBar(v + eX * 0.5 * mySize.x, s, "nametag_statusbar",
 151                                         this.armorvalue / autocvar_hud_panel_healtharmor_maxarmor, false, 0, '0 1 0', a,
 152                                         DRAWFLAG_NORMAL);
 153                         }
 154                 }
 155                 string s = entcs_GetName(this.sv_entnum - 1);
 156                 if ((autocvar_hud_shownames_decolorize == 1 && teamplay)
 157                     || autocvar_hud_shownames_decolorize == 2) s = playername(s, entcs_GetTeam(this.sv_entnum - 1));
 158                 drawfontscale = '1 1 0' * resize;
 159                 s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 160                 float width = stringwidth(s, true, '1 1 0' * autocvar_hud_shownames_fontsize);
 161                 if (width != namewidth) namepos.x += (namewidth - width) / 2;
 162                 drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 163                 drawfontscale = '1 1 0';
 164         }
 165 }
 166
 167 void Draw_ShowNames_All()
 168 {
 169         if (!autocvar_hud_shownames) return;
 170         LL_EACH(shownames_ent, true, {
 171                 entity entcs = entcs_receiver(i);
 172                 if (!entcs)
 173                 {
 174                         make_pure(it);
 175                         continue;
 176                 }
 177                 make_impure(it);
 178                 assert(entcs.think, eprint(entcs));
 179                 WITH(entity, self, entcs, entcs.think());
 180                 if (!entcs.has_origin) continue;
 181                 if (entcs.m_entcs_private)
 182                 {
 183                         it.healthvalue = entcs.healthvalue;
 184                         it.armorvalue = entcs.armorvalue;
 185                         it.sameteam = true;
 186                 }
 187                 else
 188                 {
 189                         it.healthvalue = 0;
 190                         it.armorvalue = 0;
 191                         it.sameteam = false;
 192                 }
 193                 bool dead = entcs_IsDead(i) || entcs_IsSpectating(i);
 194                 if (!it.csqcmodel_isdead) setorigin(it, entcs.origin);
 195                 it.csqcmodel_isdead = dead;
 196                 Draw_ShowNames(it);
 197         });
 198 }