qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 vector teamradar_extraclip_mins, teamradar_extraclip_maxs; // for non-centered radar display
   6 float teamradar_size; // 2D scale factor
   7 float hud_radar_scale; // window size = ...qu
   8 float hud_radar_nohudhack;
   9 float v_flipped;
  10
  11 float vlen2d(vector v)
  12 {
  13         return sqrt(v_x * v_x + v_y * v_y);
  14 }
  15
  16 float vlen_maxnorm2d(vector v)
  17 {
  18         return max4(v_x, v_y, -v_x, -v_y);
  19 }
  20
  21 float vlen_minnorm2d(vector v)
  22 {
  23         return min(max(v_x, -v_x), max(v_y, -v_y));
  24 }
  25
  26 vector teamradar_3dcoord_to_texcoord(vector in)
  27 {
  28         vector out;
  29         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  30         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  31         out_z = 0;
  32         return out;
  33 }
  34
  35 vector teamradar_texcoord_to_2dcoord(vector in)
  36 {
  37         vector out;
  38         in -= teamradar_origin3d_in_texcoord;
  39
  40         out = rotate(in, teamradar_angle * DEG2RAD);
  41         out_y = - out_y; // screen space is reversed
  42
  43         out = out * teamradar_size;
  44         if(v_flipped)
  45                 out_x = -out_x;
  46         out += teamradar_origin2d;
  47         return out;
  48 }
  49
  50 vector yinvert(vector v)
  51 {
  52         v_y = 1 - v_y;
  53         return v;
  54 }
  55
  56 void draw_teamradar_background(float bg, float fg)
  57 {
  58         float fga;
  59         vector fgc;
  60         if(bg > 0)
  61         {
  62                 R_BeginPolygon("", 0);
  63                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5 + teamradar_extraclip_mins_x) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5 + teamradar_extraclip_mins_y), '0 0 0', '0 0 0', bg);
  64                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5 + teamradar_extraclip_maxs_x) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5 + teamradar_extraclip_mins_y), '0 0 0', '0 0 0', bg);
  65                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5 + teamradar_extraclip_maxs_x) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5 + teamradar_extraclip_maxs_y), '0 0 0', '0 0 0', bg);
  66                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5 + teamradar_extraclip_mins_x) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5 + teamradar_extraclip_maxs_y), '0 0 0', '0 0 0', bg);
  67                 R_EndPolygon();
  68         }
  69
  70         if(fg > 0 && minimapname != "")
  71         {
  72                 fga = 1;
  73                 fgc = '1 1 1' * fg;
  74                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  75                 if(v_flipped)
  76                 {
  77                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  78                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  79                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  80                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  81                 }
  82                 else
  83                 {
  84                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  85                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  86                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  87                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  88                 }
  89                 R_EndPolygon();
  90         }
  91 }
  92
  93 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  94 {
  95         vector coord, rgb2;
  96
  97         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  98
  99         makevectors(pangles - '0 1 0' * teamradar_angle);
 100         if(v_flipped)
 101         {
 102                 v_forward_x = -v_forward_x;
 103                 v_right_x = -v_right_x;
 104                 v_up_x = -v_up_x;
 105         }
 106         v_forward_z = 0;
 107         v_forward = normalize(v_forward);
 108         v_forward_y *= -1.0;
 109         v_right_x = -v_forward_y;
 110         v_right_y = v_forward_x;
 111
 112         if(rgb == '1 1 1')
 113                 rgb2 = '0 0 0';
 114         else
 115                 rgb2 = '1 1 1';
 116
 117         R_BeginPolygon("", 0);
 118         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, hud_alpha_fg);
 119         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, hud_alpha_fg);
 120         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, hud_alpha_fg);
 121         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, hud_alpha_fg);
 122         R_EndPolygon();
 123
 124         R_BeginPolygon("", 0);
 125         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, hud_alpha_fg);
 126         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, hud_alpha_fg);
 127         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, hud_alpha_fg);
 128         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, hud_alpha_fg);
 129         R_EndPolygon();
 130 };
 131
 132 void draw_teamradar_icon(vector coord, float icon, entity pingdata, vector rgb, float a)
 133 {
 134         float dt;
 135         vector v;
 136         float i;
 137
 138         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 139         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 140
 141         if(pingdata)
 142         {
 143                 for(i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
 144                 {
 145                         dt = pingdata.(teamradar_times[i]);
 146                         if(dt == 0)
 147                                 continue;
 148                         dt = time - dt;
 149                         if(dt >= 1 || dt <= 0)
 150                                 continue;
 151                         v = '2 2 0' * teamradar_size * dt;
 152                         drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', (1 - dt) * a, DRAWFLAG_ADDITIVE);
 153                 }
 154         }
 155 }
 156
 157 void draw_teamradar_link(vector start, vector end, float colors)
 158 {
 159         vector c0, c1, norm;
 160
 161         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 162         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 163         norm = normalize(start - end);
 164         norm_z = norm_x;
 165         norm_x = -norm_y;
 166         norm_y = norm_z;
 167         norm_z = 0;
 168
 169         c0 = colormapPaletteColor(colors & 0x0F, FALSE);
 170         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, FALSE);
 171
 172         R_BeginPolygon("", 0);
 173         R_PolygonVertex(start - norm, '0 0 0', c0, hud_alpha_fg);
 174         R_PolygonVertex(start + norm, '0 1 0', c0, hud_alpha_fg);
 175         R_PolygonVertex(end + norm, '1 1 0', c1, hud_alpha_fg);
 176         R_PolygonVertex(end - norm, '1 0 0', c1, hud_alpha_fg);
 177         R_EndPolygon();
 178 }
 179
 180 float hud_radar_scale;
 181 float hud_radar_background_alpha;
 182 float hud_radar_foreground_alpha;
 183 float hud_radar_rotation;
 184 vector hud_radar_size;
 185 vector hud_radar_position;
 186 float hud_radar_zoommode;
 187
 188 void teamradar_loadcvars()
 189 {
 190         v_flipped = cvar("v_flipped");
 191         if(ons_showmap)
 192         {
 193                 hud_radar_scale = 42; // dummy, not used (see zoommode)
 194                 hud_radar_background_alpha = 1 * (1 - cvar("_menu_alpha"));
 195                 hud_radar_foreground_alpha = 1 * (1 - cvar("_menu_alpha"));
 196                 hud_radar_rotation = cvar("hud_radar_rotation");
 197                 if(!hud_radar_rotation)
 198                         hud_radar_rotation = 4;
 199                 hud_radar_zoommode = 3;
 200                 hud_radar_nohudhack = 0;
 201         }
 202         else
 203         {
 204                 hud_radar_scale = cvar("hud_radar_scale");
 205                 hud_radar_background_alpha = cvar("hud_radar_background_alpha") * hud_alpha_fg;
 206                 hud_radar_foreground_alpha = cvar("hud_radar_foreground_alpha") * hud_alpha_fg;
 207                 hud_radar_rotation = cvar("hud_radar_rotation");
 208                 hud_radar_zoommode = cvar("hud_radar_zoommode");
 209
 210                 // others default to 0
 211                 // match this to defaultXonotic.cfg!
 212                 if(!hud_radar_scale) hud_radar_scale = 4096;
 213                 if(!hud_radar_background_alpha) hud_radar_background_alpha = 0.4 * hud_alpha_fg;
 214                 if(!hud_radar_foreground_alpha) hud_radar_foreground_alpha = 0.8 * hud_alpha_fg;
 215                 if(!hud_radar_size_x) hud_radar_size_x = 128;
 216                 if(!hud_radar_size_y) hud_radar_size_y = hud_radar_size_x;
 217
 218                 hud_radar_size_z = 0;
 219                 hud_radar_nohudhack = hud_radar_position_z;
 220                 hud_radar_position_z = 0;
 221         }
 222 }
 223
 224 // radar links
 225
 226 void Ent_RadarLink()
 227 {
 228         float sendflags;
 229         sendflags = ReadByte();
 230
 231         InterpolateOrigin_Undo();
 232
 233         self.iflags = IFLAG_VELOCITY;
 234         self.classname = "radarlink";
 235
 236         if(sendflags & 1)
 237         {
 238                 self.origin_x = ReadCoord();
 239                 self.origin_y = ReadCoord();
 240                 self.origin_z = ReadCoord();
 241         }
 242
 243         if(sendflags & 2)
 244         {
 245                 self.velocity_x = ReadCoord();
 246                 self.velocity_y = ReadCoord();
 247                 self.velocity_z = ReadCoord();
 248         }
 249
 250         if(sendflags & 4)
 251         {
 252                 self.team = ReadByte();
 253         }
 254
 255         InterpolateOrigin_Note();
 256 }