qcsrc/client/teamradar.qc

   1 #include "teamradar.qh"
   2
   3 #include "autocvars.qh"
   4 #include "hud/_mod.qh"
   5
   6 #include <common/mutators/mutator/waypoints/all.qh>
   7
   8 #include "../lib/csqcmodel/interpolate.qh"
   9
  10 vector teamradar_3dcoord_to_texcoord(vector in)
  11 {
  12         vector out;
  13         out.x = (in.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
  14         out.y = (in.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
  15         out.z = 0;
  16         return out;
  17 }
  18
  19 vector teamradar_texcoord_to_2dcoord(vector in)
  20 {
  21         vector out;
  22         in -= teamradar_origin3d_in_texcoord;
  23
  24         out = Rotate(in, teamradar_angle * DEG2RAD);
  25         out.y = - out.y; // screen space is reversed
  26
  27         out = out * teamradar_size;
  28         if(v_flipped)
  29                 out.x = -out.x;
  30         out += teamradar_origin2d;
  31         return out;
  32 }
  33
  34
  35 vector teamradar_2dcoord_to_texcoord(vector in)
  36 {
  37         vector out;
  38         out = in;
  39
  40         out -= teamradar_origin2d;
  41         if(v_flipped)
  42                 out_x = -out_x;
  43         out = out / teamradar_size;
  44
  45         out_y = - out_y; // screen space is reversed
  46         out = Rotate(out, -teamradar_angle * DEG2RAD);
  47
  48         out += teamradar_origin3d_in_texcoord;
  49
  50         return out;
  51 }
  52
  53 vector teamradar_texcoord_to_3dcoord(vector in,float oz)
  54 {
  55         vector out;
  56         out_x = in_x * (mi_picmax_x - mi_picmin_x) + mi_picmin_x;
  57         out_y = in_y * (mi_picmax_y - mi_picmin_y) + mi_picmin_y;
  58         out_z = oz;
  59         return out;
  60 }
  61
  62 void draw_teamradar_background(float fg)
  63 {
  64         float fga;
  65         vector fgc;
  66
  67         if(fg > 0 && minimapname != "")
  68         {
  69                 fga = 1;
  70                 fgc = '1 1 1' * fg;
  71                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  72                 if(v_flipped)
  73                 {
  74                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  75                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  76                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  77                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  78                 }
  79                 else
  80                 {
  81                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  82                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  83                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  84                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  85                 }
  86                 R_EndPolygon();
  87         }
  88 }
  89
  90 void draw_teamradar_player(vector coord3d, vector pangles, vector rgb)
  91 {
  92         vector coord, rgb2;
  93
  94         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  95
  96         makevectors(pangles - '0 1 0' * teamradar_angle);
  97         if(v_flipped)
  98         {
  99                 v_forward.x = -v_forward.x;
 100                 v_right.x = -v_right.x;
 101                 v_up.x = -v_up.x;
 102         }
 103         v_forward.z = 0;
 104         v_forward = normalize(v_forward);
 105         v_forward.y *= -1.0;
 106         v_right.x = -v_forward.y;
 107         v_right.y = v_forward.x;
 108
 109         if(rgb == '1 1 1')
 110                 rgb2 = '0 0 0';
 111         else
 112                 rgb2 = '1 1 1';
 113
 114         R_BeginPolygon("", 0);
 115         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, panel_fg_alpha);
 116         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, panel_fg_alpha);
 117         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, panel_fg_alpha);
 118         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, panel_fg_alpha);
 119         R_EndPolygon();
 120
 121         R_BeginPolygon("", 0);
 122         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, panel_fg_alpha);
 123         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, panel_fg_alpha);
 124         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, panel_fg_alpha);
 125         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, panel_fg_alpha);
 126         R_EndPolygon();
 127 }
 128
 129 void draw_teamradar_icon(vector coord, entity icon, entity pingdata, vector rgb, float a)
 130 {
 131         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 132         drawpic_builtin(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon.m_radaricon)), '8 8 0', rgb, a, 0);
 133
 134         if(pingdata)
 135         {
 136                 for(int i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
 137                 {
 138                         float dt = pingdata.(teamradar_times[i]);
 139                         if(dt == 0)
 140                                 continue;
 141                         dt = time - dt;
 142                         if(dt >= 1 || dt <= 0)
 143                                 continue;
 144                         vector v = '2 2 0' * teamradar_size * dt;
 145                         drawpic_builtin(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', (1 - dt) * a, DRAWFLAG_ADDITIVE);
 146                 }
 147         }
 148 }
 149
 150 void draw_teamradar_link(vector start, vector end, int colors)
 151 {
 152     TC(int, colors);
 153         vector c0, c1, norm;
 154
 155         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 156         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 157         norm = normalize(start - end);
 158         norm.z = norm.x;
 159         norm.x = -norm.y;
 160         norm.y = norm.z;
 161         norm.z = 0;
 162
 163         c0 = colormapPaletteColor(colors & 0x0F, false);
 164         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, false);
 165
 166         R_BeginPolygon("", 0);
 167         R_PolygonVertex(start - norm, '0 0 0', c0, panel_fg_alpha);
 168         R_PolygonVertex(start + norm, '0 1 0', c0, panel_fg_alpha);
 169         R_PolygonVertex(end + norm, '1 1 0', c1, panel_fg_alpha);
 170         R_PolygonVertex(end - norm, '1 0 0', c1, panel_fg_alpha);
 171         R_EndPolygon();
 172 }
 173
 174 void teamradar_loadcvars()
 175 {
 176         v_flipped = autocvar_v_flipped;
 177         hud_panel_radar_scale = autocvar_hud_panel_radar_scale;
 178         if (hud_panel_radar_maximized && !autocvar__hud_configure)
 179         {
 180                 if (autocvar_hud_panel_radar_maximized_scale > 0)
 181                         hud_panel_radar_scale = autocvar_hud_panel_radar_maximized_scale;
 182         }
 183         hud_panel_radar_foreground_alpha = autocvar_hud_panel_radar_foreground_alpha * panel_fg_alpha;
 184         hud_panel_radar_rotation = autocvar_hud_panel_radar_rotation;
 185         hud_panel_radar_zoommode = autocvar_hud_panel_radar_zoommode;
 186         hud_panel_radar_maximized_rotation = autocvar_hud_panel_radar_maximized_rotation;
 187         hud_panel_radar_maximized_zoommode = autocvar_hud_panel_radar_maximized_zoommode;
 188
 189         // others default to 0
 190         // match this to default hud cfg file!
 191         if(!hud_panel_radar_scale) hud_panel_radar_scale = 4096;
 192         if(!hud_panel_radar_foreground_alpha) hud_panel_radar_foreground_alpha = 0.8 * panel_fg_alpha;
 193         if(!hud_panel_radar_size.x) hud_panel_radar_size.x = 128;
 194         if(!hud_panel_radar_size.y) hud_panel_radar_size.y = hud_panel_radar_size.x;
 195 }
 196
 197 // radar links
 198
 199 NET_HANDLE(ENT_CLIENT_RADARLINK, bool isnew)
 200 {
 201         int sendflags = ReadByte();
 202
 203         InterpolateOrigin_Undo(this);
 204
 205         this.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 206         this.classname = "radarlink";
 207         if (isnew) IL_PUSH(g_radarlinks, this);
 208
 209         if(sendflags & 1)
 210         {
 211                 this.origin = ReadVector();
 212                 setorigin(this, this.origin);
 213         }
 214
 215         if(sendflags & 2)
 216         {
 217                 this.velocity = ReadVector();
 218         }
 219
 220         if(sendflags & 4)
 221         {
 222                 this.team = ReadByte();
 223         }
 224
 225         return = true;
 226
 227         InterpolateOrigin_Note(this);
 228 }