Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / teamradar.qc
1 #include "teamradar.qh"
2
3 #include <client/hud/_mod.qh>
4 #include <client/view.qh>
5 #include <common/mutators/mutator/waypoints/all.qh>
6 #include <lib/csqcmodel/interpolate.qh>
7
8 vector teamradar_3dcoord_to_texcoord(vector in)
9 {
10         vector out;
11         out.x = (in.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
12         out.y = (in.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
13         out.z = 0;
14         return out;
15 }
16
17 vector teamradar_texcoord_to_2dcoord(vector in)
18 {
19         vector out;
20         in -= teamradar_origin3d_in_texcoord;
21
22         out = Rotate(in, teamradar_angle * DEG2RAD);
23         out.y = - out.y; // screen space is reversed
24
25         out = out * teamradar_size;
26         if(v_flipped)
27                 out.x = -out.x;
28         out += teamradar_origin2d;
29         return out;
30 }
31
32
33 vector teamradar_2dcoord_to_texcoord(vector in)
34 {
35         vector out;
36         out = in;
37
38         out -= teamradar_origin2d;
39         if(v_flipped)
40                 out_x = -out_x;
41         out = out / teamradar_size;
42
43         out_y = - out_y; // screen space is reversed
44         out = Rotate(out, -teamradar_angle * DEG2RAD);
45
46         out += teamradar_origin3d_in_texcoord;
47
48         return out;
49 }
50
51 vector teamradar_texcoord_to_3dcoord(vector in,float oz)
52 {
53         vector out;
54         out_x = in_x * (mi_picmax_x - mi_picmin_x) + mi_picmin_x;
55         out_y = in_y * (mi_picmax_y - mi_picmin_y) + mi_picmin_y;
56         out_z = oz;
57         return out;
58 }
59
60 void draw_teamradar_background(float fg)
61 {
62         float fga;
63         vector fgc;
64
65         if(fg > 0 && minimapname != "")
66         {
67                 fga = 1;
68                 fgc = '1 1 1' * fg;
69                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP, true);
70                 if(v_flipped)
71                 {
72                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
73                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
74                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
75                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
76                 }
77                 else
78                 {
79                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
80                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
81                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
82                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
83                 }
84                 R_EndPolygon();
85         }
86 }
87
88 void draw_teamradar_player(vector coord3d, vector pangles, vector rgb)
89 {
90         vector coord, rgb2;
91
92         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
93
94         vector forward, right, up;
95         MAKE_VECTORS(pangles - '0 1 0' * teamradar_angle, forward, right, up);
96         if(v_flipped)
97         {
98                 forward.x = -forward.x;
99                 right.x = -right.x;
100                 up.x = -up.x; // TODO: unused!
101         }
102         forward.z = 0;
103         forward = normalize(forward);
104         forward.y *= -1.0;
105         right.x = -forward.y;
106         right.y = forward.x;
107
108         if(rgb == '1 1 1')
109                 rgb2 = '0 0 0';
110         else
111                 rgb2 = '1 1 1';
112
113         R_BeginPolygon("", 0, true);
114         R_PolygonVertex(coord+forward*3, '0 0 0', rgb2, panel_fg_alpha);
115         R_PolygonVertex(coord+right*4-forward*2.5, '0 1 0', rgb2, panel_fg_alpha);
116         R_PolygonVertex(coord-forward*2, '1 0 0', rgb2, panel_fg_alpha);
117         R_PolygonVertex(coord-right*4-forward*2.5, '1 1 0', rgb2, panel_fg_alpha);
118         R_EndPolygon();
119
120         R_BeginPolygon("", 0, true);
121         R_PolygonVertex(coord+forward*2, '0 0 0', rgb, panel_fg_alpha);
122         R_PolygonVertex(coord+right*3-forward*2, '0 1 0', rgb, panel_fg_alpha);
123         R_PolygonVertex(coord-forward, '1 0 0', rgb, panel_fg_alpha);
124         R_PolygonVertex(coord-right*3-forward*2, '1 1 0', rgb, panel_fg_alpha);
125         R_EndPolygon();
126 }
127
128 void draw_teamradar_icon(vector coord, entity icon, entity pingdata, vector rgb, float a)
129 {
130         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
131         drawpic_builtin(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon.m_radaricon)), '8 8 0', rgb, a, 0);
132
133         if(pingdata)
134         {
135                 for(int i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
136                 {
137                         float dt = pingdata.(teamradar_times[i]);
138                         if(dt == 0)
139                                 continue;
140                         dt = time - dt;
141                         if(dt >= 1 || dt <= 0)
142                                 continue;
143                         vector v = '2 2 0' * teamradar_size * dt;
144                         drawpic_builtin(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', (1 - dt) * a, DRAWFLAG_ADDITIVE);
145                 }
146         }
147 }
148
149 void draw_teamradar_link(vector start, vector end, int colors)
150 {
151         TC(int, colors);
152         vector c0, c1, norm;
153
154         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
155         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
156         norm = normalize(start - end);
157         norm.z = norm.x;
158         norm.x = -norm.y;
159         norm.y = norm.z;
160         norm.z = 0;
161
162         c0 = colormapPaletteColor(colors & 0x0F, false);
163         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, false);
164
165         R_BeginPolygon("", 0, true);
166         R_PolygonVertex(start - norm, '0 0 0', c0, panel_fg_alpha);
167         R_PolygonVertex(start + norm, '0 1 0', c0, panel_fg_alpha);
168         R_PolygonVertex(end + norm, '1 1 0', c1, panel_fg_alpha);
169         R_PolygonVertex(end - norm, '1 0 0', c1, panel_fg_alpha);
170         R_EndPolygon();
171 }
172
173 void teamradar_loadcvars()
174 {
175         v_flipped = autocvar_v_flipped;
176         hud_panel_radar_scale = autocvar_hud_panel_radar_scale;
177         if (hud_panel_radar_maximized && !autocvar__hud_configure)
178         {
179                 if (autocvar_hud_panel_radar_maximized_scale > 0)
180                         hud_panel_radar_scale = autocvar_hud_panel_radar_maximized_scale;
181         }
182         hud_panel_radar_foreground_alpha = autocvar_hud_panel_radar_foreground_alpha * panel_fg_alpha;
183         hud_panel_radar_rotation = autocvar_hud_panel_radar_rotation;
184         hud_panel_radar_zoommode = autocvar_hud_panel_radar_zoommode;
185         hud_panel_radar_maximized_rotation = autocvar_hud_panel_radar_maximized_rotation;
186         hud_panel_radar_maximized_zoommode = autocvar_hud_panel_radar_maximized_zoommode;
187
188         // others default to 0
189         // match this to default hud cfg file!
190         if(!hud_panel_radar_scale) hud_panel_radar_scale = 4096;
191         if(!hud_panel_radar_foreground_alpha) hud_panel_radar_foreground_alpha = 0.8 * panel_fg_alpha;
192         if(!hud_panel_radar_size.x) hud_panel_radar_size.x = 128;
193         if(!hud_panel_radar_size.y) hud_panel_radar_size.y = hud_panel_radar_size.x;
194 }
195
196 // radar links
197
198 NET_HANDLE(ENT_CLIENT_RADARLINK, bool isnew)
199 {
200         int sendflags = ReadByte();
201
202         InterpolateOrigin_Undo(this);
203
204         this.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
205         if (isnew) IL_PUSH(g_radarlinks, this);
206
207         if(sendflags & 1)
208         {
209                 this.origin = ReadVector();
210                 setorigin(this, this.origin);
211         }
212
213         if(sendflags & 2)
214         {
215                 this.velocity = ReadVector();
216         }
217
218         if(sendflags & 4)
219         {
220                 this.team = ReadByte();
221         }
222
223         return = true;
224
225         InterpolateOrigin_Note(this);
226 }