qcsrc/client/tturrets.qc

   1 #if defined(CSQC)
   2     #include "../dpdefs/csprogsdefs.qh"
   3     #include "defs.qh"
   4     #include "../common/constants.qh"
   5     #include "../warpzonelib/mathlib.qh"
   6     #include "../common/teams.qh"
   7     #include "../common/buffs.qh"
   8     #include "autocvars.qh"
   9     #include "teamradar.qh"
  10     #include "movetypes.qh"
  11     #include "tturrets.qh"
  12     #include "../server/tturrets/include/turrets_early.qh"
  13     #include "main.qh"
  14     #include "../csqcmodellib/common.qh"
  15     #include "../csqcmodellib/cl_model.qh"
  16     #include "../server/t_items.qh"
  17 #elif defined(MENUQC)
  18 #elif defined(SVQC)
  19 #endif
  20
  21 string tid2info_base;
  22 string tid2info_head;
  23 string tid2info_name;
  24 vector  tid2info_min;
  25 vector  tid2info_max;
  26
  27 void turret_tid2info(float _tid);
  28 void turret_precache(float _tid);
  29 float turret_is_precache[TID_LAST];
  30
  31 void turrets_precache()
  32 {
  33     turret_precache(TID_COMMON);
  34 }
  35
  36 void turret_precache(int _tid)
  37 {
  38     if (!turret_is_precache[TID_COMMON])
  39     {
  40         precache_sound ("weapons/rocket_impact.wav");
  41         precache_model ("models/turrets/base-gib1.md3");
  42         precache_model ("models/turrets/base-gib2.md3");
  43         precache_model ("models/turrets/base-gib3.md3");
  44         precache_model ("models/turrets/base-gib4.md3");
  45         precache_model ("models/turrets/head-gib1.md3");
  46         precache_model ("models/turrets/head-gib2.md3");
  47         precache_model ("models/turrets/head-gib3.md3");
  48         precache_model ("models/turrets/head-gib4.md3");
  49         precache_model ("models/turrets/terrainbase.md3");
  50         precache_model ("models/turrets/base.md3");
  51         precache_model ("models/turrets/rocket.md3");
  52     }
  53     turret_tid2info(_tid);
  54     if(turret_is_precache[_tid])
  55         return;
  56
  57     switch(_tid)
  58     {
  59         case TID_EWHEEL:
  60             precache_model ("models/turrets/ewheel-base2.md3");
  61             precache_model ("models/turrets/ewheel-gun1.md3");
  62             break;
  63         case TID_FLAC:
  64             precache_model ("models/turrets/flac.md3");
  65             break;
  66         case TID_FUSION:
  67             precache_model ("models/turrets/reactor.md3");
  68             break;
  69         case TID_HELLION:
  70             precache_model ("models/turrets/hellion.md3");
  71             break;
  72         case TID_HK:
  73             precache_model ("models/turrets/hk.md3");
  74             break;
  75         case TID_MACHINEGUN:
  76             precache_model ("models/turrets/machinegun.md3");
  77             precache_sound ("weapons/uzi_fire.wav");
  78             break;
  79         case TID_MLRS:
  80             precache_model ("models/turrets/mlrs.md3");
  81             break;
  82         case TID_PHASER:
  83             precache_model ("models/turrets/phaser.md3");
  84             precache_model ("models/turrets/phaser_beam.md3");
  85             precache_sound ("turrets/phaser.wav");
  86             break;
  87         case TID_PLASMA:
  88             precache_model ("models/turrets/plasma.md3");
  89             break;
  90         case TID_PLASMA_DUAL:
  91             precache_model ("models/turrets/plasmad.md3");
  92             break;
  93         case TID_TESLA:
  94             precache_model ("models/turrets/tesla_head.md3");
  95             precache_model ("models/turrets/tesla_base.md3");
  96             break;
  97         case TID_WALKER:
  98             precache_model ("models/turrets/walker_head_minigun.md3");
  99             precache_model ("models/turrets/walker_body.md3");
 100             precache_sound ("weapons/uzi_fire.wav");
 101             break;
 102     }
 103     turret_is_precache[_tid] = true;
 104 }
 105
 106 void turret_tid2info(float _tid)
 107 {
 108     tid2info_base = "models/turrets/base.md3";
 109     tid2info_min = '-32 -32 0';
 110     tid2info_max = '32 32 64';
 111
 112     switch(_tid)
 113     {
 114         case TID_EWHEEL:
 115             tid2info_base = "models/turrets/ewheel-base2.md3";
 116             tid2info_head = "models/turrets/ewheel-gun1.md3";
 117             tid2info_name = "eWheel";
 118             break;
 119         case TID_FLAC:
 120             tid2info_head = "models/turrets/flac.md3";
 121             tid2info_name = "Flac Cannon";
 122             break;
 123         case TID_FUSION:
 124             tid2info_head = "models/turrets/reactor.md3";
 125             tid2info_name = "Fusion Reactor";
 126             tid2info_min = '-34 -34 0';
 127             tid2info_max = '34 34 90';
 128             break;
 129         case TID_HELLION:
 130             tid2info_head = "models/turrets/hellion.md3";
 131             tid2info_name = "Hellion";
 132             break;
 133         case TID_HK:
 134             tid2info_head = "models/turrets/hk.md3";
 135             tid2info_name = "Hunter-Killer";
 136             break;
 137         case TID_MACHINEGUN:
 138             tid2info_head = "models/turrets/machinegun.md3";
 139             tid2info_name = "Machinegun";
 140             break;
 141         case TID_MLRS:
 142             tid2info_head = "models/turrets/mlrs.md3";
 143             tid2info_name = "MLRS";
 144             break;
 145         case TID_PHASER:
 146             tid2info_head = "models/turrets/phaser.md3";
 147             tid2info_name = "Phaser";
 148             break;
 149         case TID_PLASMA:
 150             tid2info_head = "models/turrets/plasma.md3";
 151             tid2info_name = "Plasma";
 152             break;
 153         case TID_PLASMA_DUAL:
 154             tid2info_head = "models/turrets/plasmad.md3";
 155             tid2info_name = "Dual Plasma";
 156             break;
 157         case TID_TESLA:
 158             tid2info_base = "models/turrets/tesla_base.md3";
 159             tid2info_head = "models/turrets/tesla_head.md3";
 160             tid2info_name = "Tesla coil";
 161             tid2info_min = '-60 -60 0';
 162             tid2info_max  ='60 60 128';
 163             break;
 164         case TID_WALKER:
 165             tid2info_base = "models/turrets/walker_body.md3";
 166             tid2info_head = "models/turrets/walker_head_minigun.md3";
 167             tid2info_name = "Walker";
 168             tid2info_min = '-70 -70 0';
 169             tid2info_max = '70 70 95';
 170             break;
 171     }
 172 }
 173
 174 void turret_remove()
 175 {
 176     remove(self.tur_head);
 177     //remove(self.enemy);
 178     self.tur_head = world;
 179 }
 180
 181 .vector glowmod;
 182 void turret_changeteam()
 183 {
 184         switch(self.team - 1)
 185         {
 186         case NUM_TEAM_1: // Red
 187             self.glowmod = '2 0 0';
 188             self.teamradar_color = '1 0 0';
 189             break;
 190
 191         case NUM_TEAM_2: // Blue
 192             self.glowmod = '0 0 2';
 193             self.teamradar_color = '0 0 1';
 194             break;
 195
 196         case NUM_TEAM_3: // Yellow
 197             self.glowmod = '1 1 0';
 198             self.teamradar_color = '1 1 0';
 199             break;
 200
 201         case NUM_TEAM_4: // Pink
 202             self.glowmod = '1 0 1';
 203             self.teamradar_color = '1 0 1';
 204             break;
 205         }
 206
 207         if(self.team)
 208         self.colormap = 1024 + (self.team - 1) * 17;
 209
 210         self.tur_head.colormap = self.colormap;
 211         self.tur_head.glowmod = self.glowmod;
 212
 213 }
 214
 215 void turret_head_draw()
 216 {
 217     self.drawmask = MASK_NORMAL;
 218 }
 219
 220 void turret_draw()
 221 {
 222     float dt;
 223
 224     dt = time - self.move_time;
 225     self.move_time = time;
 226     if(dt <= 0)
 227         return;
 228
 229     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 230
 231     if (self.health < 127)
 232     {
 233         dt = random();
 234
 235         if(dt < 0.03)
 236             te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 237     }
 238
 239     if(self.health < 85)
 240     if(dt < 0.01)
 241         pointparticles(particleeffectnum("smoke_large"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 242
 243     if(self.health < 32)
 244     if(dt < 0.015)
 245         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 246
 247 }
 248
 249 void turret_draw2d()
 250 {
 251         if(self.netname == "")
 252             return;
 253
 254         if(!autocvar_g_waypointsprite_turrets)
 255                 return;
 256
 257     if(autocvar_cl_hidewaypoints)
 258         return;
 259
 260         float dist = vlen(self.origin - view_origin);
 261     float t = (GetPlayerColor(player_localnum) + 1);
 262
 263         vector o;
 264         string txt;
 265
 266         if(autocvar_cl_vehicles_hud_tactical)
 267         if(dist < 10240 && t != self.team)
 268         {
 269         // TODO: Vehicle tactical hud
 270         o = project_3d_to_2d(self.origin + '0 0 32');
 271         if(o.z < 0
 272         || o.x < (vid_conwidth * waypointsprite_edgeoffset_left)
 273         || o.y < (vid_conheight * waypointsprite_edgeoffset_top)
 274         || o.x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 275         || o.y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 276             return; // Dont draw wp's for turrets out of view
 277         o_z = 0;
 278         if(hud != HUD_NORMAL)
 279         {
 280             switch(hud)
 281             {
 282                 case HUD_SPIDERBOT:
 283                 case HUD_WAKIZASHI:
 284                 case HUD_RAPTOR:
 285                 case HUD_BUMBLEBEE:
 286                     if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 287                         txt = "gfx/vehicles/vth-mover.tga";
 288                     else
 289                         txt = "gfx/vehicles/vth-stationary.tga";
 290
 291                     vector pz = drawgetimagesize(txt) * 0.25;
 292                     drawpic(o - pz * 0.5, txt, pz , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 293                     break;
 294             }
 295         }
 296         }
 297
 298         if(dist > self.maxdistance)
 299         return;
 300
 301         string spriteimage = self.netname;
 302         float a = self.alpha * autocvar_hud_panel_fg_alpha;
 303         vector rgb = spritelookupcolor(spriteimage, self.teamradar_color);
 304
 305
 306         if(self.maxdistance > waypointsprite_normdistance)
 307                 a *= pow(bound(0, (self.maxdistance - dist) / (self.maxdistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent);
 308         else if(self.maxdistance > 0)
 309                 a *= pow(bound(0, (waypointsprite_fadedistance - dist) / (waypointsprite_fadedistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent) * (1 - waypointsprite_minalpha) + waypointsprite_minalpha;
 310
 311         if(rgb == '0 0 0')
 312         {
 313                 self.teamradar_color = '1 0 1';
 314                 printf("WARNING: sprite of name %s has no color, using pink so you notice it\n", spriteimage);
 315         }
 316
 317         txt = self.netname;
 318         if(autocvar_g_waypointsprite_spam && waypointsprite_count >= autocvar_g_waypointsprite_spam)
 319                 txt = _("Spam");
 320         else
 321                 txt = spritelookuptext(spriteimage);
 322
 323         if(time - floor(time) > 0.5 && t == self.team)
 324         {
 325                 if(self.helpme && time < self.helpme)
 326                 {
 327                     a *= SPRITE_HELPME_BLINK;
 328                     txt = sprintf(_("%s under attack!"), txt);
 329                 }
 330                 else
 331                         a *= spritelookupblinkvalue(spriteimage);
 332         }
 333
 334         if(autocvar_g_waypointsprite_uppercase)
 335                 txt = strtoupper(txt);
 336
 337         if(a > 1)
 338         {
 339                 rgb *= a;
 340                 a = 1;
 341         }
 342
 343         if(a <= 0)
 344             return;
 345
 346         rgb = fixrgbexcess(rgb);
 347
 348         o = project_3d_to_2d(self.origin + '0 0 64');
 349         if(o.z < 0
 350         || o.x < (vid_conwidth * waypointsprite_edgeoffset_left)
 351         || o.y < (vid_conheight * waypointsprite_edgeoffset_top)
 352         || o.x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 353         || o.y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 354             return; // Dont draw wp's for turrets out of view
 355
 356         o_z = 0;
 357
 358         float edgedistance_min, crosshairdistance;
 359                 edgedistance_min = min((o.y - (vid_conheight * waypointsprite_edgeoffset_top)),
 360         (o.x - (vid_conwidth * waypointsprite_edgeoffset_left)),
 361         (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right)) - o.x,
 362         (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)) - o.y);
 363
 364         float vidscale = max(vid_conwidth / vid_width, vid_conheight / vid_height);
 365
 366         crosshairdistance = sqrt( pow(o.x - vid_conwidth/2, 2) + pow(o.y - vid_conheight/2, 2) );
 367
 368         t = waypointsprite_scale * vidscale;
 369         a *= waypointsprite_alpha;
 370
 371         {
 372                 a = a * (1 - (1 - waypointsprite_distancefadealpha) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 373                 t = t * (1 - (1 - waypointsprite_distancefadescale) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 374         }
 375         if (edgedistance_min < waypointsprite_edgefadedistance) {
 376                 a = a * (1 - (1 - waypointsprite_edgefadealpha) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 377                 t = t * (1 - (1 - waypointsprite_edgefadescale) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 378         }
 379         if(crosshairdistance < waypointsprite_crosshairfadedistance) {
 380                 a = a * (1 - (1 - waypointsprite_crosshairfadealpha) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 381                 t = t * (1 - (1 - waypointsprite_crosshairfadescale) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 382         }
 383
 384         o = drawspritearrow(o, M_PI, rgb, a, SPRITE_ARROW_SCALE * t);
 385     o = drawspritetext(o, M_PI, (SPRITE_HEALTHBAR_WIDTH + 2 * SPRITE_HEALTHBAR_BORDER) * t, rgb, a, waypointsprite_fontsize * '1 1 0', txt);
 386     drawhealthbar(
 387             o,
 388             0,
 389             self.health / 255,
 390             '0 0 0',
 391             '0 0 0',
 392             0.5 * SPRITE_HEALTHBAR_WIDTH * t,
 393             0.5 * SPRITE_HEALTHBAR_HEIGHT * t,
 394             SPRITE_HEALTHBAR_MARGIN * t + 0.5 * waypointsprite_fontsize,
 395             SPRITE_HEALTHBAR_BORDER * t,
 396             0,
 397             rgb,
 398             a * SPRITE_HEALTHBAR_BORDERALPHA,
 399             rgb,
 400             a * SPRITE_HEALTHBAR_HEALTHALPHA,
 401             DRAWFLAG_NORMAL
 402             );
 403 }
 404
 405 void turret_walker_draw()
 406 {
 407     float dt;
 408
 409     dt = time - self.move_time;
 410     self.move_time = time;
 411     if(dt <= 0)
 412         return;
 413
 414     fixedmakevectors(self.angles);
 415     movelib_groundalign4point(300, 100, 0.25, 45);
 416     setorigin(self, self.origin + self.velocity * dt);
 417     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 418     self.angles_y = self.move_angles.y;
 419
 420     if (self.health < 127)
 421     if(random() < 0.15)
 422         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 423 }
 424
 425 void turret_ewheel_draw()
 426 {
 427     float dt;
 428
 429     dt = time - self.move_time;
 430     self.move_time = time;
 431     if(dt <= 0)
 432         return;
 433
 434     fixedmakevectors(self.angles);
 435     setorigin(self, self.origin + self.velocity * dt);
 436     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 437     self.angles_y = self.move_angles.y;
 438
 439     if (self.health < 127)
 440     if(random() < 0.05)
 441         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 442 }
 443
 444 void turret_construct()
 445 {
 446     if(self.tur_head == world)
 447         self.tur_head = spawn();
 448
 449     turret_tid2info(self.turret_type);
 450     self.netname = tid2info_name;
 451
 452     setorigin(self, self.origin);
 453     setmodel(self, tid2info_base);
 454     setmodel(self.tur_head, tid2info_head);
 455     setsize(self, tid2info_min, tid2info_max);
 456     setsize(self.tur_head, '0 0 0', '0 0 0');
 457
 458     if(self.turret_type == TID_EWHEEL)
 459         setattachment(self.tur_head, self, "");
 460     else
 461         setattachment(self.tur_head, self, "tag_head");
 462
 463     self.tur_head.classname     = "turret_head";
 464     self.tur_head.owner         = self;
 465     self.tur_head.move_movetype = MOVETYPE_NOCLIP;
 466     self.move_movetype          = MOVETYPE_NOCLIP;
 467     self.tur_head.angles        = self.angles;
 468     self.health                 = 255;
 469     self.solid                  = SOLID_BBOX;
 470     self.tur_head.solid         = SOLID_NOT;
 471     self.movetype               = MOVETYPE_NOCLIP;
 472     self.tur_head.movetype      = MOVETYPE_NOCLIP;
 473     self.draw                   = turret_draw;
 474     self.entremove              = turret_remove;
 475     self.drawmask               = MASK_NORMAL;
 476     self.tur_head.drawmask      = MASK_NORMAL;
 477     self.anim_start_time        = 0;
 478     self.draw2d = turret_draw2d;
 479     self.maxdistance = autocvar_g_waypointsprite_turrets_maxdist;
 480     self.teamradar_color = '1 0 0';
 481     self.alpha = 1;
 482
 483     if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 484     {
 485         self.gravity            = 1;
 486         self.movetype           = MOVETYPE_BOUNCE;
 487         self.move_movetype      = MOVETYPE_BOUNCE;
 488         self.move_origin        = self.origin;
 489         self.move_time          = time;
 490         switch(self.turret_type)
 491         {
 492             case TID_EWHEEL:
 493                 self.draw               = turret_ewheel_draw;
 494                 break;
 495             case TID_WALKER:
 496                 self.draw               = turret_walker_draw;
 497                 break;
 498
 499         }
 500     }
 501 }
 502
 503 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode);
 504 void turret_gibboom();
 505 void turret_gib_draw()
 506 {
 507     Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 508
 509     self.drawmask = MASK_NORMAL;
 510
 511         if(self.cnt)
 512         {
 513             if(time >= self.nextthink)
 514             {
 515             turret_gibboom();
 516             remove(self);
 517             }
 518         }
 519         else
 520         {
 521         self.alpha = bound(0, self.nextthink - time, 1);
 522         if(self.alpha < ALPHA_MIN_VISIBLE)
 523             remove(self);
 524         }
 525 }
 526
 527 void turret_gibboom()
 528 {
 529     float i;
 530
 531     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 532     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 533
 534     for (i = 1; i < 5; i = i + 1)
 535         turret_gibtoss(strcat("models/turrets/head-gib", ftos(i), ".md3"), self.origin + '0 0 2', self.velocity + randomvec() * 700, '0 0 0', false);
 536 }
 537
 538 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode)
 539 {
 540     entity gib;
 541
 542     traceline(_from, _to, MOVE_NOMONSTERS, world);
 543     if(trace_startsolid)
 544         return world;
 545
 546     gib = spawn();
 547     setorigin(gib, _from);
 548     setmodel(gib, _model);
 549     gib.colormod    = _cmod;
 550         gib.solid       = SOLID_CORPSE;
 551     gib.draw        = turret_gib_draw;
 552     gib.cnt         = _explode;
 553     setsize(gib, '-1 -1 -1', '1 1 1');
 554     if(_explode)
 555     {
 556         gib.nextthink = time + 0.2 * (autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15));
 557         gib.effects = EF_FLAME;
 558     }
 559     else
 560         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 561
 562     gib.gravity         = 1;
 563         gib.move_movetype   = MOVETYPE_BOUNCE;
 564         gib.move_origin     = _from;
 565         setorigin(gib,        _from);
 566         gib.move_velocity   = _to;
 567         gib.move_avelocity  = prandomvec() * 32;
 568         gib.move_time       = time;
 569         gib.damageforcescale = 1;
 570         gib.classname = "turret_gib";
 571
 572         return gib;
 573 }
 574
 575 void turret_die()
 576 {
 577
 578     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 579     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 580     turret_tid2info(self.turret_type);
 581     if (!autocvar_cl_nogibs)
 582     {
 583         // Base
 584         if(self.turret_type == TID_EWHEEL)
 585             turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 400' + '0.1 0.1 1' * (random() * 400), '-1 -1 -1', true);
 586         else if (self.turret_type == TID_WALKER)
 587             turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 300' + '0.1 0.1 1' * (random() * 200), '-1 -1 -1', true);
 588         else if (self.turret_type == TID_TESLA)
 589             turret_gibtoss(tid2info_base, self.origin + '0 0 18', '0 0 200', '-1 -1 -1', false);
 590         else
 591         {
 592             if (random() > 0.5)
 593             {
 594                 turret_gibtoss("models/turrets/base-gib2.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
 595                 turret_gibtoss("models/turrets/base-gib3.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
 596                 turret_gibtoss("models/turrets/base-gib4.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
 597             }
 598             else
 599                 turret_gibtoss("models/turrets/base-gib1.md3", self.origin + '0 0 8', '0 0 0', '0 0 0', true);
 600
 601             entity headgib = turret_gibtoss(tid2info_head, self.origin + '0 0 32', '0 0 200' + randomvec() * 200, '-1 -1 -1', true);
 602             if(headgib)
 603             {
 604                 headgib.angles = headgib.move_angles = self.tur_head.angles;
 605                 headgib.avelocity = headgib.move_avelocity = self.tur_head.move_avelocity + randomvec() * 45;
 606                 headgib.avelocity_y = headgib.move_avelocity_y = headgib.move_avelocity.y * 5;
 607                 headgib.gravity = 0.5;
 608             }
 609         }
 610     }
 611
 612     setmodel(self, "null");
 613     setmodel(self.tur_head, "null");
 614 }
 615
 616 void ent_turret()
 617 {
 618     int sf = ReadByte();
 619
 620         if(sf & TNSF_SETUP)
 621         {
 622             self.turret_type = ReadByte();
 623
 624             self.origin_x = ReadCoord();
 625             self.origin_y = ReadCoord();
 626             self.origin_z = ReadCoord();
 627             setorigin(self, self.origin);
 628
 629             self.angles_x = ReadAngle();
 630             self.angles_y = ReadAngle();
 631
 632             turret_precache(self.turret_type);
 633             turret_construct();
 634             self.colormap = 1024;
 635             self.glowmod = '0 1 1';
 636             self.tur_head.colormap = self.colormap;
 637             self.tur_head.glowmod = self.glowmod;
 638     }
 639
 640     if(sf & TNSF_ANG)
 641     {
 642         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 643             self.tur_head = spawn();
 644
 645         self.tur_head.move_angles_x = ReadShort();
 646         self.tur_head.move_angles_y = ReadShort();
 647         //self.tur_head.angles = self.angles + self.tur_head.move_angles;
 648         self.tur_head.angles = self.tur_head.move_angles;
 649     }
 650
 651     if(sf & TNSF_AVEL)
 652     {
 653         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 654             self.tur_head = spawn();
 655
 656         self.tur_head.move_avelocity_x = ReadShort();
 657         self.tur_head.move_avelocity_y = ReadShort();
 658     }
 659
 660     if(sf & TNSF_MOVE)
 661     {
 662         self.origin_x = ReadShort();
 663         self.origin_y = ReadShort();
 664         self.origin_z = ReadShort();
 665         setorigin(self, self.origin);
 666
 667         self.velocity_x = ReadShort();
 668         self.velocity_y = ReadShort();
 669         self.velocity_z = ReadShort();
 670
 671         self.move_angles_y = ReadShort();
 672
 673         self.move_time     = time;
 674         self.move_velocity = self.velocity;
 675         self.move_origin   = self.origin;
 676     }
 677
 678     if(sf & TNSF_ANIM)
 679     {
 680         self.frame1time = ReadCoord();
 681         self.frame      = ReadByte();
 682     }
 683
 684     if(sf & TNSF_STATUS)
 685     {
 686         float _tmp;
 687         _tmp = ReadByte();
 688         if(_tmp != self.team)
 689         {
 690             self.team = _tmp;
 691             turret_changeteam();
 692         }
 693
 694         _tmp = ReadByte();
 695         if(_tmp == 0 && self.health != 0)
 696             turret_die();
 697         else if(self.health && self.health != _tmp)
 698             self.helpme = servertime + 10;
 699
 700         self.health = _tmp;
 701     }
 702     //self.enemy.health = self.health / 255;
 703 }