qcsrc/client/tturrets.qc

   1 #include "tturrets.qh"
   2 #include "waypointsprites.qh"
   3
   4 #include "../server/movelib.qh"
   5
   6 string tid2info_base;
   7 string tid2info_head;
   8 string tid2info_name;
   9 vector  tid2info_min;
  10 vector  tid2info_max;
  11
  12 void turret_tid2info(float _tid);
  13 void turret_precache(float _tid);
  14 float turret_is_precache[TID_LAST];
  15
  16 void turrets_precache()
  17 {
  18     turret_precache(TID_COMMON);
  19 }
  20
  21 void turret_precache(int _tid)
  22 {
  23     if (!turret_is_precache[TID_COMMON])
  24     {
  25         precache_sound ("weapons/rocket_impact.wav");
  26         precache_model ("models/turrets/base-gib1.md3");
  27         precache_model ("models/turrets/base-gib2.md3");
  28         precache_model ("models/turrets/base-gib3.md3");
  29         precache_model ("models/turrets/base-gib4.md3");
  30         precache_model ("models/turrets/head-gib1.md3");
  31         precache_model ("models/turrets/head-gib2.md3");
  32         precache_model ("models/turrets/head-gib3.md3");
  33         precache_model ("models/turrets/head-gib4.md3");
  34         precache_model ("models/turrets/terrainbase.md3");
  35         precache_model ("models/turrets/base.md3");
  36         precache_model ("models/turrets/rocket.md3");
  37     }
  38     turret_tid2info(_tid);
  39     if(turret_is_precache[_tid])
  40         return;
  41
  42     switch(_tid)
  43     {
  44         case TID_EWHEEL:
  45             precache_model ("models/turrets/ewheel-base2.md3");
  46             precache_model ("models/turrets/ewheel-gun1.md3");
  47             break;
  48         case TID_FLAC:
  49             precache_model ("models/turrets/flac.md3");
  50             break;
  51         case TID_FUSION:
  52             precache_model ("models/turrets/reactor.md3");
  53             break;
  54         case TID_HELLION:
  55             precache_model ("models/turrets/hellion.md3");
  56             break;
  57         case TID_HK:
  58             precache_model ("models/turrets/hk.md3");
  59             break;
  60         case TID_MACHINEGUN:
  61             precache_model ("models/turrets/machinegun.md3");
  62             precache_sound ("weapons/uzi_fire.wav");
  63             break;
  64         case TID_MLRS:
  65             precache_model ("models/turrets/mlrs.md3");
  66             break;
  67         case TID_PHASER:
  68             precache_model ("models/turrets/phaser.md3");
  69             precache_model ("models/turrets/phaser_beam.md3");
  70             precache_sound ("turrets/phaser.wav");
  71             break;
  72         case TID_PLASMA:
  73             precache_model ("models/turrets/plasma.md3");
  74             break;
  75         case TID_PLASMA_DUAL:
  76             precache_model ("models/turrets/plasmad.md3");
  77             break;
  78         case TID_TESLA:
  79             precache_model ("models/turrets/tesla_head.md3");
  80             precache_model ("models/turrets/tesla_base.md3");
  81             break;
  82         case TID_WALKER:
  83             precache_model ("models/turrets/walker_head_minigun.md3");
  84             precache_model ("models/turrets/walker_body.md3");
  85             precache_sound ("weapons/uzi_fire.wav");
  86             break;
  87     }
  88     turret_is_precache[_tid] = true;
  89 }
  90
  91 void turret_tid2info(float _tid)
  92 {
  93     tid2info_base = "models/turrets/base.md3";
  94     tid2info_min = '-32 -32 0';
  95     tid2info_max = '32 32 64';
  96
  97     switch(_tid)
  98     {
  99         case TID_EWHEEL:
 100             tid2info_base = "models/turrets/ewheel-base2.md3";
 101             tid2info_head = "models/turrets/ewheel-gun1.md3";
 102             tid2info_name = "eWheel";
 103             break;
 104         case TID_FLAC:
 105             tid2info_head = "models/turrets/flac.md3";
 106             tid2info_name = "Flac Cannon";
 107             break;
 108         case TID_FUSION:
 109             tid2info_head = "models/turrets/reactor.md3";
 110             tid2info_name = "Fusion Reactor";
 111             tid2info_min = '-34 -34 0';
 112             tid2info_max = '34 34 90';
 113             break;
 114         case TID_HELLION:
 115             tid2info_head = "models/turrets/hellion.md3";
 116             tid2info_name = "Hellion";
 117             break;
 118         case TID_HK:
 119             tid2info_head = "models/turrets/hk.md3";
 120             tid2info_name = "Hunter-Killer";
 121             break;
 122         case TID_MACHINEGUN:
 123             tid2info_head = "models/turrets/machinegun.md3";
 124             tid2info_name = "Machinegun";
 125             break;
 126         case TID_MLRS:
 127             tid2info_head = "models/turrets/mlrs.md3";
 128             tid2info_name = "MLRS";
 129             break;
 130         case TID_PHASER:
 131             tid2info_head = "models/turrets/phaser.md3";
 132             tid2info_name = "Phaser";
 133             break;
 134         case TID_PLASMA:
 135             tid2info_head = "models/turrets/plasma.md3";
 136             tid2info_name = "Plasma";
 137             break;
 138         case TID_PLASMA_DUAL:
 139             tid2info_head = "models/turrets/plasmad.md3";
 140             tid2info_name = "Dual Plasma";
 141             break;
 142         case TID_TESLA:
 143             tid2info_base = "models/turrets/tesla_base.md3";
 144             tid2info_head = "models/turrets/tesla_head.md3";
 145             tid2info_name = "Tesla coil";
 146             tid2info_min = '-60 -60 0';
 147             tid2info_max  ='60 60 128';
 148             break;
 149         case TID_WALKER:
 150             tid2info_base = "models/turrets/walker_body.md3";
 151             tid2info_head = "models/turrets/walker_head_minigun.md3";
 152             tid2info_name = "Walker";
 153             tid2info_min = '-70 -70 0';
 154             tid2info_max = '70 70 95';
 155             break;
 156     }
 157 }
 158
 159 void turret_remove()
 160 {
 161     remove(self.tur_head);
 162     //remove(self.enemy);
 163     self.tur_head = world;
 164 }
 165
 166 .vector glowmod;
 167 void turret_changeteam()
 168 {
 169         switch(self.team - 1)
 170         {
 171         case NUM_TEAM_1: // Red
 172             self.glowmod = '2 0 0';
 173             self.teamradar_color = '1 0 0';
 174             break;
 175
 176         case NUM_TEAM_2: // Blue
 177             self.glowmod = '0 0 2';
 178             self.teamradar_color = '0 0 1';
 179             break;
 180
 181         case NUM_TEAM_3: // Yellow
 182             self.glowmod = '1 1 0';
 183             self.teamradar_color = '1 1 0';
 184             break;
 185
 186         case NUM_TEAM_4: // Pink
 187             self.glowmod = '1 0 1';
 188             self.teamradar_color = '1 0 1';
 189             break;
 190         }
 191
 192         if(self.team)
 193         self.colormap = 1024 + (self.team - 1) * 17;
 194
 195         self.tur_head.colormap = self.colormap;
 196         self.tur_head.glowmod = self.glowmod;
 197
 198 }
 199
 200 void turret_head_draw()
 201 {
 202     self.drawmask = MASK_NORMAL;
 203 }
 204
 205 void turret_draw()
 206 {
 207     float dt;
 208
 209     dt = time - self.move_time;
 210     self.move_time = time;
 211     if(dt <= 0)
 212         return;
 213
 214     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 215
 216     if (self.health < 127)
 217     {
 218         dt = random();
 219
 220         if(dt < 0.03)
 221             te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 222     }
 223
 224     if(self.health < 85)
 225     if(dt < 0.01)
 226         pointparticles(particleeffectnum("smoke_large"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 227
 228     if(self.health < 32)
 229     if(dt < 0.015)
 230         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 231
 232 }
 233
 234 void turret_draw2d()
 235 {
 236         if(self.netname == "")
 237             return;
 238
 239         if(!autocvar_g_waypointsprite_turrets)
 240                 return;
 241
 242     if(autocvar_cl_hidewaypoints)
 243         return;
 244
 245         float dist = vlen(self.origin - view_origin);
 246     float t = (GetPlayerColor(player_localnum) + 1);
 247
 248         vector o;
 249         string txt;
 250
 251         if(autocvar_cl_vehicles_hud_tactical)
 252         if(dist < 10240 && t != self.team)
 253         {
 254         // TODO: Vehicle tactical hud
 255         o = project_3d_to_2d(self.origin + '0 0 32');
 256         if(o.z < 0
 257         || o.x < (vid_conwidth * waypointsprite_edgeoffset_left)
 258         || o.y < (vid_conheight * waypointsprite_edgeoffset_top)
 259         || o.x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 260         || o.y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 261             return; // Dont draw wp's for turrets out of view
 262         o.z = 0;
 263         if(hud != HUD_NORMAL)
 264         {
 265                         if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 266                                 txt = "gfx/vehicles/vth-mover.tga";
 267                         else
 268                                 txt = "gfx/vehicles/vth-stationary.tga";
 269
 270                         vector pz = drawgetimagesize(txt) * 0.25;
 271                         drawpic(o - pz * 0.5, txt, pz , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 272         }
 273         }
 274
 275         if(dist > self.maxdistance)
 276         return;
 277
 278         string spriteimage = self.netname;
 279         float a = self.alpha * autocvar_hud_panel_fg_alpha;
 280         vector rgb = spritelookupcolor(spriteimage, self.teamradar_color);
 281
 282
 283         if(self.maxdistance > waypointsprite_normdistance)
 284                 a *= pow(bound(0, (self.maxdistance - dist) / (self.maxdistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent);
 285         else if(self.maxdistance > 0)
 286                 a *= pow(bound(0, (waypointsprite_fadedistance - dist) / (waypointsprite_fadedistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent) * (1 - waypointsprite_minalpha) + waypointsprite_minalpha;
 287
 288         if(rgb == '0 0 0')
 289         {
 290                 self.teamradar_color = '1 0 1';
 291                 printf("WARNING: sprite of name %s has no color, using pink so you notice it\n", spriteimage);
 292         }
 293
 294         txt = self.netname;
 295         if(autocvar_g_waypointsprite_spam && waypointsprite_count >= autocvar_g_waypointsprite_spam)
 296                 txt = _("Spam");
 297         else
 298                 txt = spritelookuptext(spriteimage);
 299
 300         if(time - floor(time) > 0.5 && t == self.team)
 301         {
 302                 if(self.helpme && time < self.helpme)
 303                 {
 304                     a *= SPRITE_HELPME_BLINK;
 305                     txt = sprintf(_("%s under attack!"), txt);
 306                 }
 307                 else
 308                         a *= spritelookupblinkvalue(spriteimage);
 309         }
 310
 311         if(autocvar_g_waypointsprite_uppercase)
 312                 txt = strtoupper(txt);
 313
 314         if(a > 1)
 315         {
 316                 rgb *= a;
 317                 a = 1;
 318         }
 319
 320         if(a <= 0)
 321             return;
 322
 323         rgb = fixrgbexcess(rgb);
 324
 325         o = project_3d_to_2d(self.origin + '0 0 64');
 326         if(o.z < 0
 327         || o.x < (vid_conwidth * waypointsprite_edgeoffset_left)
 328         || o.y < (vid_conheight * waypointsprite_edgeoffset_top)
 329         || o.x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 330         || o.y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 331             return; // Dont draw wp's for turrets out of view
 332
 333         o.z = 0;
 334
 335         float edgedistance_min, crosshairdistance;
 336                 edgedistance_min = min((o.y - (vid_conheight * waypointsprite_edgeoffset_top)),
 337         (o.x - (vid_conwidth * waypointsprite_edgeoffset_left)),
 338         (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right)) - o.x,
 339         (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)) - o.y);
 340
 341         float vidscale = max(vid_conwidth / vid_width, vid_conheight / vid_height);
 342
 343         crosshairdistance = sqrt( pow(o.x - vid_conwidth/2, 2) + pow(o.y - vid_conheight/2, 2) );
 344
 345         t = waypointsprite_scale * vidscale;
 346         a *= waypointsprite_alpha;
 347
 348         {
 349                 a = a * (1 - (1 - waypointsprite_distancefadealpha) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 350                 t = t * (1 - (1 - waypointsprite_distancefadescale) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 351         }
 352         if (edgedistance_min < waypointsprite_edgefadedistance) {
 353                 a = a * (1 - (1 - waypointsprite_edgefadealpha) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 354                 t = t * (1 - (1 - waypointsprite_edgefadescale) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 355         }
 356         if(crosshairdistance < waypointsprite_crosshairfadedistance) {
 357                 a = a * (1 - (1 - waypointsprite_crosshairfadealpha) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 358                 t = t * (1 - (1 - waypointsprite_crosshairfadescale) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 359         }
 360
 361         o = drawspritearrow(o, M_PI, rgb, a, SPRITE_ARROW_SCALE * t);
 362     o = drawspritetext(o, M_PI, (SPRITE_HEALTHBAR_WIDTH + 2 * SPRITE_HEALTHBAR_BORDER) * t, rgb, a, waypointsprite_fontsize * '1 1 0', txt);
 363     drawhealthbar(
 364             o,
 365             0,
 366             self.health / 255,
 367             '0 0 0',
 368             '0 0 0',
 369             0.5 * SPRITE_HEALTHBAR_WIDTH * t,
 370             0.5 * SPRITE_HEALTHBAR_HEIGHT * t,
 371             SPRITE_HEALTHBAR_MARGIN * t + 0.5 * waypointsprite_fontsize,
 372             SPRITE_HEALTHBAR_BORDER * t,
 373             0,
 374             rgb,
 375             a * SPRITE_HEALTHBAR_BORDERALPHA,
 376             rgb,
 377             a * SPRITE_HEALTHBAR_HEALTHALPHA,
 378             DRAWFLAG_NORMAL
 379             );
 380 }
 381
 382 void turret_walker_draw()
 383 {
 384     float dt;
 385
 386     dt = time - self.move_time;
 387     self.move_time = time;
 388     if(dt <= 0)
 389         return;
 390
 391     fixedmakevectors(self.angles);
 392     movelib_groundalign4point(300, 100, 0.25, 45);
 393     setorigin(self, self.origin + self.velocity * dt);
 394     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 395     self.angles_y = self.move_angles.y;
 396
 397     if (self.health < 127)
 398     if(random() < 0.15)
 399         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 400 }
 401
 402 void turret_ewheel_draw()
 403 {
 404     float dt;
 405
 406     dt = time - self.move_time;
 407     self.move_time = time;
 408     if(dt <= 0)
 409         return;
 410
 411     fixedmakevectors(self.angles);
 412     setorigin(self, self.origin + self.velocity * dt);
 413     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 414     self.angles_y = self.move_angles.y;
 415
 416     if (self.health < 127)
 417     if(random() < 0.05)
 418         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 419 }
 420
 421 void turret_construct()
 422 {
 423     if(self.tur_head == world)
 424         self.tur_head = spawn();
 425
 426     turret_tid2info(self.turret_type);
 427     self.netname = tid2info_name;
 428
 429     setorigin(self, self.origin);
 430     setmodel(self, tid2info_base);
 431     setmodel(self.tur_head, tid2info_head);
 432     setsize(self, tid2info_min, tid2info_max);
 433     setsize(self.tur_head, '0 0 0', '0 0 0');
 434
 435     if(self.turret_type == TID_EWHEEL)
 436         setattachment(self.tur_head, self, "");
 437     else
 438         setattachment(self.tur_head, self, "tag_head");
 439
 440     self.tur_head.classname     = "turret_head";
 441     self.tur_head.owner         = self;
 442     self.tur_head.move_movetype = MOVETYPE_NOCLIP;
 443     self.move_movetype          = MOVETYPE_NOCLIP;
 444     self.tur_head.angles        = self.angles;
 445     self.health                 = 255;
 446     self.solid                  = SOLID_BBOX;
 447     self.tur_head.solid         = SOLID_NOT;
 448     self.movetype               = MOVETYPE_NOCLIP;
 449     self.tur_head.movetype      = MOVETYPE_NOCLIP;
 450     self.draw                   = turret_draw;
 451     self.entremove              = turret_remove;
 452     self.drawmask               = MASK_NORMAL;
 453     self.tur_head.drawmask      = MASK_NORMAL;
 454     self.anim_start_time        = 0;
 455     self.draw2d = turret_draw2d;
 456     self.maxdistance = autocvar_g_waypointsprite_turrets_maxdist;
 457     self.teamradar_color = '1 0 0';
 458     self.alpha = 1;
 459
 460     if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 461     {
 462         self.gravity            = 1;
 463         self.movetype           = MOVETYPE_BOUNCE;
 464         self.move_movetype      = MOVETYPE_BOUNCE;
 465         self.move_origin        = self.origin;
 466         self.move_time          = time;
 467         switch(self.turret_type)
 468         {
 469             case TID_EWHEEL:
 470                 self.draw               = turret_ewheel_draw;
 471                 break;
 472             case TID_WALKER:
 473                 self.draw               = turret_walker_draw;
 474                 break;
 475
 476         }
 477     }
 478 }
 479
 480 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode);
 481 void turret_gibboom();
 482 void turret_gib_draw()
 483 {
 484     Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 485
 486     self.drawmask = MASK_NORMAL;
 487
 488         if(self.cnt)
 489         {
 490             if(time >= self.nextthink)
 491             {
 492             turret_gibboom();
 493             remove(self);
 494             }
 495         }
 496         else
 497         {
 498         self.alpha = bound(0, self.nextthink - time, 1);
 499         if(self.alpha < ALPHA_MIN_VISIBLE)
 500             remove(self);
 501         }
 502 }
 503
 504 void turret_gibboom()
 505 {
 506     float i;
 507
 508     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 509     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 510
 511     for (i = 1; i < 5; i = i + 1)
 512         turret_gibtoss(strcat("models/turrets/head-gib", ftos(i), ".md3"), self.origin + '0 0 2', self.velocity + randomvec() * 700, '0 0 0', false);
 513 }
 514
 515 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode)
 516 {
 517     entity gib;
 518
 519     traceline(_from, _to, MOVE_NOMONSTERS, world);
 520     if(trace_startsolid)
 521         return world;
 522
 523     gib = spawn();
 524     setorigin(gib, _from);
 525     setmodel(gib, _model);
 526     gib.colormod    = _cmod;
 527         gib.solid       = SOLID_CORPSE;
 528     gib.draw        = turret_gib_draw;
 529     gib.cnt         = _explode;
 530     setsize(gib, '-1 -1 -1', '1 1 1');
 531     if(_explode)
 532     {
 533         gib.nextthink = time + 0.2 * (autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15));
 534         gib.effects = EF_FLAME;
 535     }
 536     else
 537         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 538
 539     gib.gravity         = 1;
 540         gib.move_movetype   = MOVETYPE_BOUNCE;
 541         gib.move_origin     = _from;
 542         setorigin(gib,        _from);
 543         gib.move_velocity   = _to;
 544         gib.move_avelocity  = prandomvec() * 32;
 545         gib.move_time       = time;
 546         gib.damageforcescale = 1;
 547         gib.classname = "turret_gib";
 548
 549         return gib;
 550 }
 551
 552 void turret_die()
 553 {
 554
 555     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 556     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 557     turret_tid2info(self.turret_type);
 558     if (!autocvar_cl_nogibs)
 559     {
 560         // Base
 561         if(self.turret_type == TID_EWHEEL)
 562             turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 400' + '0.1 0.1 1' * (random() * 400), '-1 -1 -1', true);
 563         else if (self.turret_type == TID_WALKER)
 564             turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 300' + '0.1 0.1 1' * (random() * 200), '-1 -1 -1', true);
 565         else if (self.turret_type == TID_TESLA)
 566             turret_gibtoss(tid2info_base, self.origin + '0 0 18', '0 0 200', '-1 -1 -1', false);
 567         else
 568         {
 569             if (random() > 0.5)
 570             {
 571                 turret_gibtoss("models/turrets/base-gib2.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
 572                 turret_gibtoss("models/turrets/base-gib3.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
 573                 turret_gibtoss("models/turrets/base-gib4.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', false);
 574             }
 575             else
 576                 turret_gibtoss("models/turrets/base-gib1.md3", self.origin + '0 0 8', '0 0 0', '0 0 0', true);
 577
 578             entity headgib = turret_gibtoss(tid2info_head, self.origin + '0 0 32', '0 0 200' + randomvec() * 200, '-1 -1 -1', true);
 579             if(headgib)
 580             {
 581                 headgib.angles = headgib.move_angles = self.tur_head.angles;
 582                 headgib.avelocity = headgib.move_avelocity = self.tur_head.move_avelocity + randomvec() * 45;
 583                 headgib.avelocity_y = headgib.move_avelocity_y = headgib.move_avelocity.y * 5;
 584                 headgib.gravity = 0.5;
 585             }
 586         }
 587     }
 588
 589     setmodel(self, "null");
 590     setmodel(self.tur_head, "null");
 591 }
 592
 593 void ent_turret()
 594 {
 595     int sf = ReadByte();
 596
 597         if(sf & TNSF_SETUP)
 598         {
 599             self.turret_type = ReadByte();
 600
 601             self.origin_x = ReadCoord();
 602             self.origin_y = ReadCoord();
 603             self.origin_z = ReadCoord();
 604             setorigin(self, self.origin);
 605
 606             self.angles_x = ReadAngle();
 607             self.angles_y = ReadAngle();
 608
 609             turret_precache(self.turret_type);
 610             turret_construct();
 611             self.colormap = 1024;
 612             self.glowmod = '0 1 1';
 613             self.tur_head.colormap = self.colormap;
 614             self.tur_head.glowmod = self.glowmod;
 615     }
 616
 617     if(sf & TNSF_ANG)
 618     {
 619         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 620             self.tur_head = spawn();
 621
 622         self.tur_head.move_angles_x = ReadShort();
 623         self.tur_head.move_angles_y = ReadShort();
 624         //self.tur_head.angles = self.angles + self.tur_head.move_angles;
 625         self.tur_head.angles = self.tur_head.move_angles;
 626     }
 627
 628     if(sf & TNSF_AVEL)
 629     {
 630         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 631             self.tur_head = spawn();
 632
 633         self.tur_head.move_avelocity_x = ReadShort();
 634         self.tur_head.move_avelocity_y = ReadShort();
 635     }
 636
 637     if(sf & TNSF_MOVE)
 638     {
 639         self.origin_x = ReadShort();
 640         self.origin_y = ReadShort();
 641         self.origin_z = ReadShort();
 642         setorigin(self, self.origin);
 643
 644         self.velocity_x = ReadShort();
 645         self.velocity_y = ReadShort();
 646         self.velocity_z = ReadShort();
 647
 648         self.move_angles_y = ReadShort();
 649
 650         self.move_time     = time;
 651         self.move_velocity = self.velocity;
 652         self.move_origin   = self.origin;
 653     }
 654
 655     if(sf & TNSF_ANIM)
 656     {
 657         self.frame1time = ReadCoord();
 658         self.frame      = ReadByte();
 659     }
 660
 661     if(sf & TNSF_STATUS)
 662     {
 663         int _tmp = ReadByte();
 664         if(_tmp != self.team)
 665         {
 666             self.team = _tmp;
 667             turret_changeteam();
 668         }
 669
 670         _tmp = ReadByte();
 671         if(_tmp == 0 && self.health != 0)
 672             turret_die();
 673         else if(self.health && self.health != _tmp)
 674             self.helpme = servertime + 10;
 675
 676         self.health = _tmp;
 677     }
 678     //self.enemy.health = self.health / 255;
 679 }