qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 1000;
  44 float autocvar_cl_followmodel_highpass1 = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47
  48 float autocvar_cl_leanmodel;
  49 float autocvar_cl_leanmodel_speed = 0.3;
  50 float autocvar_cl_leanmodel_limit = 1000;
  51 float autocvar_cl_leanmodel_highpass1 = 0.2;
  52 float autocvar_cl_leanmodel_highpass = 0.2;
  53 float autocvar_cl_leanmodel_lowpass = 0.05;
  54
  55 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  56 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  57 { \
  58         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  59 } MACRO_END
  60
  61 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  62 { \
  63         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  64         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  65 } MACRO_END
  66
  67 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __f = 0; lowpass(value, frac, ref_store, __f); \
  70         ret = (value) - __f; \
  71 } MACRO_END
  72
  73 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  80 { \
  81         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  82         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  83 } MACRO_END
  84
  85 #define lowpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  88         lowpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 #define highpass3_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 118 { \
 119         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 120         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 121         highpass_limited(value.z, frac, limit, ref_store.z, ref_out.z); \
 122 } MACRO_END
 123
 124 #define lowpass3_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 125 { \
 126         lowpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 127         lowpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 128         lowpass_limited(value.z, frac, limit, ref_store.z, ref_out.z); \
 129 } MACRO_END
 130
 131 void viewmodel_animate(entity this)
 132 {
 133         static float prevtime;
 134         float frametime = (time - prevtime);
 135         prevtime = time;
 136
 137         if (autocvar_chase_active) return;
 138         if (STAT(HEALTH) <= 0) return;
 139
 140         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 141
 142         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 143         static bool oldonground;
 144         static float hitgroundtime;
 145         static float lastongroundtime;
 146         if (clonground)
 147         {
 148                 float f = time; // cl.movecmd[0].time
 149                 if (!oldonground)
 150                         hitgroundtime = f;
 151                 lastongroundtime = f;
 152         }
 153         oldonground = clonground;
 154
 155
 156         bool teleported = view.csqcmodel_teleported;
 157
 158         float frac;
 159         if(autocvar_cl_followmodel)
 160         {
 161                 vector gunorg = '0 0 0';
 162                 static vector vel_average;
 163                 static vector gunorg_prev = '0 0 0';
 164                 static vector gunorg_adjustment_highpass;
 165                 static vector gunorg_adjustment_lowpass;
 166
 167                 vector vel;
 168                 vector forward, right = '0 0 0', up = '0 0 0';
 169                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 170                 vel.x = view.velocity * forward;
 171                 vel.y = view.velocity * right * -1;
 172                 vel.z = view.velocity * up;
 173                 frac = avg_factor(autocvar_cl_followmodel_highpass1);
 174                 lowpass3_limited(vel, frac, autocvar_cl_followmodel_limit, vel_average, gunorg);
 175
 176                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 177
 178                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 179                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 180                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 181                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 182                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 183                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 184
 185                 this.origin += gunorg;
 186         }
 187
 188         if(autocvar_cl_leanmodel)
 189         {
 190                 vector gunangles = '0 0 0';
 191                 static vector gunangles_prev = '0 0 0';
 192                 static vector gunangles_highpass = '0 0 0';
 193                 static vector gunangles_adjustment_highpass;
 194                 static vector gunangles_adjustment_lowpass;
 195
 196                 if (teleported)
 197                         gunangles_prev = view_angles;
 198
 199                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 200                 gunangles_highpass += gunangles_prev;
 201                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 202                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 203                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 204                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 205                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 206                 gunangles_prev = view_angles;
 207                 gunangles_highpass -= gunangles_prev;
 208
 209                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 210                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 211
 212                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 213                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 214                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 215                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 216                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 217
 218                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 219                 this.angles += gunangles;
 220         }
 221
 222         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 223
 224         // vertical view bobbing code
 225         // TODO: cl_bob
 226
 227         // horizontal view bobbing code
 228         // TODO: cl_bob2
 229
 230         // fall bobbing code
 231         // causes the view to swing down and back up when touching the ground
 232         // TODO: cl_bobfall
 233
 234         // gun model bobbing code
 235         if (autocvar_cl_bobmodel)
 236         {
 237                 // calculate for swinging gun model
 238                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 239                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 240                 // for the most part, but for some reason when you go through a message trigger or
 241                 // pick up an item or anything like that it will momentarily jolt the gun.
 242                 float bspeed;
 243                 float t = 1;
 244                 float s = time * autocvar_cl_bobmodel_speed;
 245                 if (clonground)
 246                 {
 247                         if (time - hitgroundtime < 0.2)
 248                         {
 249                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 250                                 t = time - hitgroundtime;
 251                                 t = bound(0, t, 0.2);
 252                                 t *= 5;
 253                         }
 254                 }
 255                 else
 256                 {
 257                         // recently left the ground, slow the bob down over the next 0.2 seconds
 258                         t = time - lastongroundtime;
 259                         t = 0.2 - bound(0, t, 0.2);
 260                         t *= 5;
 261                 }
 262                 bspeed = xyspeed * 0.01;
 263                 vector gunorg = '0 0 0';
 264                 gunorg.y += bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 265                 gunorg.z += bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 266
 267                 this.origin += gunorg;
 268         }
 269 }
 270
 271 .vector viewmodel_origin, viewmodel_angles;
 272 .float weapon_nextthink;
 273 .float weapon_eta_last;
 274 .float weapon_switchdelay;
 275
 276 void viewmodel_draw(entity this)
 277 {
 278         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 279         float a = this.alpha;
 280         static bool wasinvehicle;
 281         bool invehicle = player_localentnum > maxclients;
 282         if (invehicle) a = -1;
 283         else if (wasinvehicle) a = 1;
 284         wasinvehicle = invehicle;
 285         Weapon wep = activeweapon;
 286         int c = stof(getplayerkeyvalue(current_player, "colors"));
 287         vector g = weaponentity_glowmod(wep, c);
 288         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 289         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 290                 | EF_NODEPTHTEST)
 291                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 292         for (entity e = this; e; e = e.weaponchild)
 293         {
 294                 e.drawmask = mask;
 295                 e.alpha = a;
 296                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 297                 e.glowmod = g;
 298                 e.csqcmodel_effects = fx;
 299                 CSQCModel_Effects_Apply(e);
 300         }
 301         {
 302                 static string name_last;
 303                 string name = wep.mdl;
 304                 if (name != name_last)
 305                 {
 306                         name_last = name;
 307                         CL_WeaponEntity_SetModel(this, name);
 308                         this.viewmodel_origin = this.origin;
 309                         this.viewmodel_angles = this.angles;
 310                 }
 311                 anim_update(this);
 312                 if (!this.animstate_override)
 313                         anim_set(this, this.anim_idle, true, false, false);
 314         }
 315         float f = 0; // 0..1; 0: fully active
 316         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 317         if (eta <= 0) f = this.weapon_eta_last;
 318         else switch (this.state)
 319         {
 320                 case WS_RAISE:
 321                 {
 322                         f = eta / max(eta, this.weapon_switchdelay);
 323                         break;
 324                 }
 325                 case WS_DROP:
 326                 {
 327                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 328                         break;
 329                 }
 330                 case WS_CLEAR:
 331                 {
 332                         f = 1;
 333                         break;
 334                 }
 335         }
 336         this.weapon_eta_last = f;
 337         this.origin = this.viewmodel_origin;
 338         this.angles = this.viewmodel_angles;
 339         this.angles_x = (-90 * f * f);
 340         viewmodel_animate(this);
 341         setorigin(this, this.origin);
 342 }
 343
 344 entity viewmodel;
 345 STATIC_INIT(viewmodel) {
 346     viewmodel = new(viewmodel);
 347     make_pure(viewmodel);
 348         viewmodel.draw = viewmodel_draw;
 349 }
 350
 351 entity porto;
 352 vector polyline[16];
 353 void Porto_Draw(entity this)
 354 {
 355         vector p, dir, ang, q, nextdir;
 356         float portal_number, portal1_idx;
 357
 358         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 359                 return;
 360         if(WEP_CVAR(porto, secondary))
 361                 return;
 362         if(intermission == 1)
 363                 return;
 364         if(intermission == 2)
 365                 return;
 366         if (STAT(HEALTH) <= 0)
 367                 return;
 368
 369         dir = view_forward;
 370
 371         if(angles_held_status)
 372         {
 373                 makevectors(angles_held);
 374                 dir = v_forward;
 375         }
 376
 377         p = view_origin;
 378
 379         polyline[0] = p;
 380         int idx = 1;
 381         portal_number = 0;
 382         nextdir = dir;
 383
 384         for (;;)
 385         {
 386                 dir = nextdir;
 387                 traceline(p, p + 65536 * dir, true, porto);
 388                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 389                         return;
 390                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 391                 p = trace_endpos;
 392                 polyline[idx] = p;
 393                 ++idx;
 394                 if(idx >= 16)
 395                         return;
 396                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 397                         continue;
 398                 ++portal_number;
 399                 ang = vectoangles2(trace_plane_normal, dir);
 400                 ang.x = -ang.x;
 401                 makevectors(ang);
 402                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 403                         return;
 404                 if(portal_number == 1)
 405                 {
 406                         portal1_idx = idx;
 407                         if(portal_number >= 2)
 408                                 break;
 409                 }
 410         }
 411
 412         while(idx >= 2)
 413         {
 414                 p = polyline[idx-2];
 415                 q = polyline[idx-1];
 416                 if(idx == 2)
 417                         p = p - view_up * 16;
 418                 if(idx-1 >= portal1_idx)
 419                 {
 420                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 421                 }
 422                 else
 423                 {
 424                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 425                 }
 426                 --idx;
 427         }
 428 }
 429
 430 void Porto_Init()
 431 {
 432         porto = new(porto);
 433         make_pure(porto);
 434         porto.draw = Porto_Draw;
 435         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 436 }
 437
 438 float drawtime;
 439 float avgspeed;
 440 vector GetCurrentFov(float fov)
 441 {
 442         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 443         float velocityzoom, curspeed;
 444         vector v;
 445
 446         zoomsensitivity = autocvar_cl_zoomsensitivity;
 447         zoomfactor = autocvar_cl_zoomfactor;
 448         if(zoomfactor < 1 || zoomfactor > 30)
 449                 zoomfactor = 2.5;
 450         zoomspeed = autocvar_cl_zoomspeed;
 451         if(zoomspeed >= 0)
 452         if(zoomspeed < 0.5 || zoomspeed > 16)
 453                         zoomspeed = 3.5;
 454
 455         zoomdir = button_zoom;
 456         if(hud == HUD_NORMAL)
 457         if(switchweapon == activeweapon)
 458         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 459                 zoomdir += button_attack2;
 460         if(spectatee_status > 0 || isdemo())
 461         {
 462                 if(spectatorbutton_zoom)
 463                 {
 464                         if(zoomdir)
 465                                 zoomdir = 0;
 466                         else
 467                                 zoomdir = 1;
 468                 }
 469                 // fteqcc failed twice here already, don't optimize this
 470         }
 471
 472         if(zoomdir) { zoomin_effect = 0; }
 473
 474         if(camera_active)
 475         {
 476                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 477         }
 478         else if(autocvar_cl_spawnzoom && zoomin_effect)
 479         {
 480                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 481
 482                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 483                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 484                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 485         }
 486         else
 487         {
 488                 if(zoomspeed < 0) // instant zoom
 489                 {
 490                         if(zoomdir)
 491                                 current_viewzoom = 1 / zoomfactor;
 492                         else
 493                                 current_viewzoom = 1;
 494                 }
 495                 else
 496                 {
 497                         if(zoomdir)
 498                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 499                         else
 500                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 501                 }
 502         }
 503
 504         if(almost_equals(current_viewzoom, 1))
 505                 current_zoomfraction = 0;
 506         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 507                 current_zoomfraction = 1;
 508         else
 509                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 510
 511         if(zoomsensitivity < 1)
 512                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 513         else
 514                 setsensitivityscale(1);
 515
 516         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 517         {
 518                 if(intermission) { curspeed = 0; }
 519                 else
 520                 {
 521
 522                         makevectors(view_angles);
 523                         v = pmove_vel;
 524                         if(csqcplayer)
 525                                 v = csqcplayer.velocity;
 526
 527                         switch(autocvar_cl_velocityzoom_type)
 528                         {
 529                                 case 3: curspeed = max(0, v_forward * v); break;
 530                                 case 2: curspeed = (v_forward * v); break;
 531                                 case 1: default: curspeed = vlen(v); break;
 532                         }
 533                 }
 534
 535                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 536                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 537                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 538
 539                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 540         }
 541         else
 542                 velocityzoom = 1;
 543
 544         float frustumx, frustumy, fovx, fovy;
 545         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 546         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 547         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 548         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 549
 550         return '1 0 0' * fovx + '0 1 0' * fovy;
 551 }
 552
 553 vector GetViewLocationFOV(float fov)
 554 {
 555         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 556         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 557         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 558         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 559         return '1 0 0' * fovx + '0 1 0' * fovy;
 560 }
 561
 562 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 563 {
 564         float fovx, fovy;
 565         float width = (ov_worldmax.x - ov_worldmin.x);
 566         float height = (ov_worldmax.y - ov_worldmin.y);
 567         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 568         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 569         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 570         return '1 0 0' * fovx + '0 1 0' * fovy;
 571 }
 572
 573 // this function must match W_SetupShot!
 574 float zoomscript_caught;
 575
 576 vector wcross_origin;
 577 float wcross_scale_prev, wcross_alpha_prev;
 578 vector wcross_color_prev;
 579 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 580 vector wcross_color_goal_prev;
 581 float wcross_changedonetime;
 582
 583 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 584 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 585 float wcross_name_changestarttime, wcross_name_changedonetime;
 586 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 587
 588 float wcross_ring_prev;
 589
 590 entity trueaim;
 591 entity trueaim_rifle;
 592
 593 const float SHOTTYPE_HITTEAM = 1;
 594 const float SHOTTYPE_HITOBSTRUCTION = 2;
 595 const float SHOTTYPE_HITWORLD = 3;
 596 const float SHOTTYPE_HITENEMY = 4;
 597
 598 void TrueAim_Init()
 599 {
 600         trueaim = new(trueaim);
 601         make_pure(trueaim);
 602         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 603         trueaim_rifle = new(trueaim_rifle);
 604         make_pure(trueaim_rifle);
 605         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 606 }
 607
 608 float EnemyHitCheck()
 609 {
 610         float t, n;
 611         wcross_origin = project_3d_to_2d(trace_endpos);
 612         wcross_origin.z = 0;
 613         if(trace_ent)
 614                 n = trace_ent.entnum;
 615         else
 616                 n = trace_networkentity;
 617         if(n < 1)
 618                 return SHOTTYPE_HITWORLD;
 619         if(n > maxclients)
 620                 return SHOTTYPE_HITWORLD;
 621         t = entcs_GetTeam(n - 1);
 622         if(teamplay)
 623                 if(t == myteam)
 624                         return SHOTTYPE_HITTEAM;
 625         if(t == NUM_SPECTATOR)
 626                 return SHOTTYPE_HITWORLD;
 627         return SHOTTYPE_HITENEMY;
 628 }
 629
 630 float TrueAimCheck()
 631 {
 632         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 633         vector vecs, trueaimpoint, w_shotorg;
 634         vector mi, ma, dv;
 635         float shottype;
 636         entity ta;
 637         float mv;
 638
 639         mi = ma = '0 0 0';
 640         ta = trueaim;
 641         mv = MOVE_NOMONSTERS;
 642
 643         switch(activeweapon) // WEAPONTODO
 644         {
 645                 case WEP_TUBA: // no aim
 646                 case WEP_PORTO: // shoots from eye
 647                 case WEP_NEXBALL: // shoots from eye
 648                 case WEP_HOOK: // no trueaim
 649                 case WEP_MORTAR: // toss curve
 650                         return SHOTTYPE_HITWORLD;
 651                 case WEP_VORTEX:
 652                 case WEP_VAPORIZER:
 653                         mv = MOVE_NORMAL;
 654                         break;
 655                 case WEP_RIFLE:
 656                         ta = trueaim_rifle;
 657                         mv = MOVE_NORMAL;
 658                         if(zoomscript_caught)
 659                         {
 660                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 661                                 return EnemyHitCheck();
 662                         }
 663                         break;
 664                 case WEP_DEVASTATOR: // projectile has a size!
 665                         mi = '-3 -3 -3';
 666                         ma = '3 3 3';
 667                         break;
 668                 case WEP_FIREBALL: // projectile has a size!
 669                         mi = '-16 -16 -16';
 670                         ma = '16 16 16';
 671                         break;
 672                 case WEP_SEEKER: // projectile has a size!
 673                         mi = '-2 -2 -2';
 674                         ma = '2 2 2';
 675                         break;
 676                 case WEP_ELECTRO: // projectile has a size!
 677                         mi = '0 0 -3';
 678                         ma = '0 0 -3';
 679                         break;
 680         }
 681
 682         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 683
 684         vecs = decompressShotOrigin(STAT(SHOTORG));
 685
 686         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 687         trueaimpoint = trace_endpos;
 688
 689         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 690                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 691
 692         if(vecs.x > 0)
 693                 vecs.y = -vecs.y;
 694         else
 695                 vecs = '0 0 0';
 696
 697         dv = view_right * vecs.y + view_up * vecs.z;
 698         w_shotorg = traceorigin + dv;
 699
 700         // now move the vecs forward as much as requested if possible
 701         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 702         w_shotorg = trace_endpos - view_forward * nudge;
 703
 704         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 705         shottype = EnemyHitCheck();
 706         if(shottype != SHOTTYPE_HITWORLD)
 707                 return shottype;
 708
 709 #if 0
 710         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 711         // or rather, I know why, but see no fix
 712         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 713                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 714                 return SHOTTYPE_HITOBSTRUCTION;
 715 #endif
 716
 717         return SHOTTYPE_HITWORLD;
 718 }
 719
 720 void PostInit();
 721 void CSQC_Demo_Camera();
 722 float HUD_WouldDrawScoreboard();
 723 float camera_mode;
 724 const float CAMERA_FREE = 1;
 725 const float CAMERA_CHASE = 2;
 726 float reticle_type;
 727 string reticle_image;
 728 string NextFrameCommand;
 729
 730 vector freeze_org, freeze_ang;
 731 entity nightvision_noise, nightvision_noise2;
 732
 733 const float MAX_TIME_DIFF = 5;
 734 float pickup_crosshair_time, pickup_crosshair_size;
 735 float hitindication_crosshair_size;
 736 float use_vortex_chargepool;
 737
 738 float myhealth, myhealth_prev;
 739 float myhealth_flash;
 740
 741 float old_blurradius, old_bluralpha;
 742 float old_sharpen_intensity;
 743
 744 vector myhealth_gentlergb;
 745
 746 float contentavgalpha, liquidalpha_prev;
 747 vector liquidcolor_prev;
 748
 749 float eventchase_current_distance;
 750 float eventchase_running;
 751 bool WantEventchase(entity this)
 752 {
 753         if(autocvar_cl_orthoview)
 754                 return false;
 755         if(intermission)
 756                 return true;
 757         if(this.viewloc)
 758                 return true;
 759         if(spectatee_status >= 0)
 760         {
 761                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 762                         return true;
 763                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 764                         return true;
 765                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 766                         return true;
 767                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 768                 {
 769                         if(autocvar_cl_eventchase_death == 2)
 770                         {
 771                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 772                                 if(this.velocity == '0 0 0' || eventchase_running)
 773                                         return true;
 774                         }
 775                         else return true;
 776                 }
 777         }
 778         return false;
 779 }
 780
 781 void HUD_Crosshair_Vehicle()
 782 {
 783         if(hud != HUD_BUMBLEBEE_GUN)
 784         {
 785                 Vehicle info = Vehicles_from(hud);
 786                 info.vr_crosshair(info);
 787         }
 788 }
 789
 790 vector damage_blurpostprocess, content_blurpostprocess;
 791
 792 float unaccounted_damage = 0;
 793 void UpdateDamage()
 794 {
 795         // accumulate damage with each stat update
 796         static float damage_total_prev = 0;
 797         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 798         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 799         damage_total_prev = damage_total;
 800
 801         static float damage_dealt_time_prev = 0;
 802         float damage_dealt_time = STAT(HIT_TIME);
 803         if (damage_dealt_time != damage_dealt_time_prev)
 804         {
 805                 unaccounted_damage += unaccounted_damage_new;
 806                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 807         }
 808         damage_dealt_time_prev = damage_dealt_time;
 809
 810         // prevent hitsound when switching spectatee
 811         static float spectatee_status_prev = 0;
 812         if (spectatee_status != spectatee_status_prev)
 813                 unaccounted_damage = 0;
 814         spectatee_status_prev = spectatee_status;
 815 }
 816
 817 void HitSound()
 818 {
 819         // varying sound pitch
 820
 821         static float hitsound_time_prev = 0;
 822         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 823         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 824         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 825         {
 826                 if (autocvar_cl_hitsound && unaccounted_damage)
 827                 {
 828                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 829                         float a = autocvar_cl_hitsound_max_pitch;
 830                         float b = autocvar_cl_hitsound_min_pitch;
 831                         float c = autocvar_cl_hitsound_nom_damage;
 832                         float x = unaccounted_damage;
 833                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 834
 835                         // if sound variation is disabled, set pitch_shift to 1
 836                         if (autocvar_cl_hitsound == 1)
 837                                 pitch_shift = 1;
 838
 839                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 840                         if (autocvar_cl_hitsound == 3)
 841                         {
 842                                 float mirror_value = (a-b)/2 + b;
 843                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 844                         }
 845
 846                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 847
 848                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 849                         // todo: normalize sound pressure levels? seems unnecessary
 850
 851                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 852                 }
 853                 unaccounted_damage = 0;
 854                 hitsound_time_prev = time;
 855         }
 856
 857         static float typehit_time_prev = 0;
 858         float typehit_time = STAT(TYPEHIT_TIME);
 859         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 860         {
 861                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 862                 typehit_time_prev = typehit_time;
 863         }
 864 }
 865
 866 void HUD_Crosshair()
 867 {SELFPARAM();
 868         static float rainbow_last_flicker;
 869         static vector rainbow_prev_color;
 870         entity e = this;
 871         float f, i, j;
 872         vector v;
 873         if(!scoreboard_active && !camera_active && intermission != 2 &&
 874                 spectatee_status != -1 && !csqcplayer.viewloc &&
 875                 !HUD_MinigameMenu_IsOpened() )
 876         {
 877                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 878                         return;
 879
 880                 if (hud != HUD_NORMAL)
 881                 {
 882                         HUD_Crosshair_Vehicle();
 883                         return;
 884                 }
 885
 886                 string wcross_style;
 887                 float wcross_alpha, wcross_resolution;
 888                 wcross_style = autocvar_crosshair;
 889                 if (wcross_style == "0")
 890                         return;
 891                 wcross_resolution = autocvar_crosshair_size;
 892                 if (wcross_resolution == 0)
 893                         return;
 894                 wcross_alpha = autocvar_crosshair_alpha;
 895                 if (wcross_alpha == 0)
 896                         return;
 897
 898                 // TrueAim check
 899                 float shottype;
 900
 901                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 902                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 903                 wcross_origin.z = 0;
 904                 if(autocvar_crosshair_hittest)
 905                 {
 906                         vector wcross_oldorigin;
 907                         wcross_oldorigin = wcross_origin;
 908                         shottype = TrueAimCheck();
 909                         if(shottype == SHOTTYPE_HITWORLD)
 910                         {
 911                                 v = wcross_origin - wcross_oldorigin;
 912                                 v.x /= vid_conwidth;
 913                                 v.y /= vid_conheight;
 914                                 if(vlen(v) > 0.01)
 915                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 916                         }
 917                         if(!autocvar_crosshair_hittest_showimpact)
 918                                 wcross_origin = wcross_oldorigin;
 919                 }
 920                 else
 921                         shottype = SHOTTYPE_HITWORLD;
 922
 923                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 924                 string wcross_name = "";
 925                 float wcross_scale, wcross_blur;
 926
 927                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 928                 {
 929                         e = switchingweapon;
 930                         if(e)
 931                         {
 932                                 if(autocvar_crosshair_per_weapon)
 933                                 {
 934                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 935                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 936                                         //if (wcross_resolution == 0)
 937                                                 //return;
 938
 939                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 940                                         wcross_resolution *= e.w_crosshair_size;
 941                                         wcross_name = e.w_crosshair;
 942                                 }
 943                         }
 944                 }
 945
 946                 if(wcross_name == "")
 947                         wcross_name = strcat("gfx/crosshair", wcross_style);
 948
 949                 // MAIN CROSSHAIR COLOR DECISION
 950                 switch(autocvar_crosshair_color_special)
 951                 {
 952                         case 1: // crosshair_color_per_weapon
 953                         {
 954                                 if(e)
 955                                 {
 956                                         wcross_color = e.wpcolor;
 957                                         break;
 958                                 }
 959                                 else { goto normalcolor; }
 960                         }
 961
 962                         case 2: // crosshair_color_by_health
 963                         {
 964                                 float x = STAT(HEALTH);
 965
 966                                 //x = red
 967                                 //y = green
 968                                 //z = blue
 969
 970                                 wcross_color.z = 0;
 971
 972                                 if(x > 200)
 973                                 {
 974                                         wcross_color.x = 0;
 975                                         wcross_color.y = 1;
 976                                 }
 977                                 else if(x > 150)
 978                                 {
 979                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 980                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 981                                 }
 982                                 else if(x > 100)
 983                                 {
 984                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 985                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 986                                         wcross_color.z = 1 - (x-100)*0.02;
 987                                 }
 988                                 else if(x > 50)
 989                                 {
 990                                         wcross_color.x = 1;
 991                                         wcross_color.y = 1;
 992                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 993                                 }
 994                                 else if(x > 20)
 995                                 {
 996                                         wcross_color.x = 1;
 997                                         wcross_color.y = (x-20)*90/27/100;
 998                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 999                                 }
1000                                 else
1001                                 {
1002                                         wcross_color.x = 1;
1003                                         wcross_color.y = 0;
1004                                 }
1005                                 break;
1006                         }
1007
1008                         case 3: // crosshair_color_rainbow
1009                         {
1010                                 if(time >= rainbow_last_flicker)
1011                                 {
1012                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1013                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1014                                 }
1015                                 wcross_color = rainbow_prev_color;
1016                                 break;
1017                         }
1018                         :normalcolor
1019                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1020                 }
1021
1022                 if(autocvar_crosshair_effect_scalefade)
1023                 {
1024                         wcross_scale = wcross_resolution;
1025                         wcross_resolution = 1;
1026                 }
1027                 else
1028                 {
1029                         wcross_scale = 1;
1030                 }
1031
1032                 if(autocvar_crosshair_pickup)
1033                 {
1034                         float stat_pickup_time = STAT(LAST_PICKUP);
1035
1036                         if(pickup_crosshair_time < stat_pickup_time)
1037                         {
1038                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1039                                         pickup_crosshair_size = 1;
1040
1041                                 pickup_crosshair_time = stat_pickup_time;
1042                         }
1043
1044                         if(pickup_crosshair_size > 0)
1045                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1046                         else
1047                                 pickup_crosshair_size = 0;
1048
1049                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1050                 }
1051
1052                 // todo: make crosshair hit indication dependent on damage dealt
1053                 if(autocvar_crosshair_hitindication)
1054                 {
1055                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1056
1057                         if(unaccounted_damage)
1058                         {
1059                                 hitindication_crosshair_size = 1;
1060                         }
1061
1062                         if(hitindication_crosshair_size > 0)
1063                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1064                         else
1065                                 hitindication_crosshair_size = 0;
1066
1067                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1068                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1069                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1070                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1071                 }
1072
1073                 if(shottype == SHOTTYPE_HITENEMY)
1074                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1075                 if(shottype == SHOTTYPE_HITTEAM)
1076                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1077
1078                 f = fabs(autocvar_crosshair_effect_time);
1079                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1080                 {
1081                         wcross_changedonetime = time + f;
1082                 }
1083                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1084                 {
1085                         wcross_name_changestarttime = time;
1086                         wcross_name_changedonetime = time + f;
1087                         if(wcross_name_goal_prev_prev)
1088                                 strunzone(wcross_name_goal_prev_prev);
1089                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1090                         wcross_name_goal_prev = strzone(wcross_name);
1091                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1092                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1093                         wcross_resolution_goal_prev = wcross_resolution;
1094                 }
1095
1096                 wcross_scale_goal_prev = wcross_scale;
1097                 wcross_alpha_goal_prev = wcross_alpha;
1098                 wcross_color_goal_prev = wcross_color;
1099
1100                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1101                 {
1102                         wcross_blur = 1;
1103                         wcross_alpha *= 0.75;
1104                 }
1105                 else
1106                         wcross_blur = 0;
1107                 // *_prev is at time-frametime
1108                 // * is at wcross_changedonetime+f
1109                 // what do we have at time?
1110                 if(time < wcross_changedonetime)
1111                 {
1112                         f = frametime / (wcross_changedonetime - time + frametime);
1113                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1114                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1115                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1116                 }
1117
1118                 wcross_scale_prev = wcross_scale;
1119                 wcross_alpha_prev = wcross_alpha;
1120                 wcross_color_prev = wcross_color;
1121
1122                 MUTATOR_CALLHOOK(UpdateCrosshair);
1123
1124                 wcross_scale *= 1 - autocvar__menu_alpha;
1125                 wcross_alpha *= 1 - autocvar__menu_alpha;
1126                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1127
1128                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1129                 {
1130                         // crosshair rings for weapon stats
1131                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1132                         {
1133                                 // declarations and stats
1134                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1135                                 string ring_image = string_null, ring_inner_image = string_null;
1136                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1137
1138                                 ring_scale = autocvar_crosshair_ring_size;
1139
1140                                 float weapon_clipload, weapon_clipsize;
1141                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1142                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1143
1144                                 float ok_ammo_charge, ok_ammo_chargepool;
1145                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1146                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1147
1148                                 float vortex_charge, vortex_chargepool;
1149                                 vortex_charge = STAT(VORTEX_CHARGE);
1150                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1151
1152                                 float arc_heat = STAT(ARC_HEAT);
1153
1154                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1155                                         vortex_charge_movingavg = vortex_charge;
1156
1157
1158                                 // handle the values
1159                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1160                                 {
1161                                         if (vortex_chargepool || use_vortex_chargepool) {
1162                                                 use_vortex_chargepool = 1;
1163                                                 ring_inner_value = vortex_chargepool;
1164                                         } else {
1165                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1166                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1167                                         }
1168
1169                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1170                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1171                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1172
1173                                         // draw the outer ring to show the current charge of the weapon
1174                                         ring_value = vortex_charge;
1175                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1176                                         ring_rgb = wcross_color;
1177                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1178                                 }
1179                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1180                                 {
1181                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1182                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1183                                         ring_rgb = wcross_color;
1184                                         ring_image = "gfx/crosshair_ring.tga";
1185                                 }
1186                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1187                                 {
1188                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1189                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1190                                         ring_rgb = wcross_color;
1191                                         ring_image = "gfx/crosshair_ring.tga";
1192                                 }
1193                                 else if (ok_ammo_charge)
1194                                 {
1195                                         ring_value = ok_ammo_chargepool;
1196                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1197                                         ring_rgb = wcross_color;
1198                                         ring_image = "gfx/crosshair_ring.tga";
1199                                 }
1200                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1201                                 {
1202                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1203                                         ring_scale = autocvar_crosshair_ring_reload_size;
1204                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1205                                         ring_rgb = wcross_color;
1206
1207                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1208                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1209                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1210                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1211                                         else
1212                                                 ring_image = "gfx/crosshair_ring.tga";
1213                                 }
1214                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1215                                 {
1216                                         ring_value = arc_heat;
1217                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1218                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1219                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1220                                         ring_image = "gfx/crosshair_ring.tga";
1221                                 }
1222
1223                                 // if in weapon switch animation, fade ring out/in
1224                                 if(autocvar_crosshair_effect_time > 0)
1225                                 {
1226                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1227                                         if (f >= 1)
1228                                         {
1229                                                 wcross_ring_prev = ((ring_image) ? true : false);
1230                                         }
1231
1232                                         if(wcross_ring_prev)
1233                                         {
1234                                                 if(f < 1)
1235                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1236                                         }
1237                                         else
1238                                         {
1239                                                 if(f < 1)
1240                                                         ring_alpha *= bound(0, f, 1);
1241                                         }
1242                                 }
1243
1244                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1245                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1246
1247                                 if (ring_value)
1248                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1249                         }
1250
1251 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1252                         MACRO_BEGIN { \
1253                                 if(wcross_blur > 0) \
1254                                 { \
1255                                         for(i = -2; i <= 2; ++i) \
1256                                         for(j = -2; j <= 2; ++j) \
1257                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1258                                 } \
1259                                 else \
1260                                 { \
1261                                         M(0,0,sz,wcross_name,wcross_alpha); \
1262                                 } \
1263                         } MACRO_END
1264
1265 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1266                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1267
1268 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1269                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1270
1271                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1272                         {
1273                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1274                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1275                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1276                                 f = 1 - f;
1277                         }
1278                         else
1279                         {
1280                                 f = 1;
1281                         }
1282                         wcross_name_alpha_goal_prev = f;
1283
1284                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1285                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1286
1287                         if(autocvar_crosshair_dot)
1288                         {
1289                                 vector wcross_color_old;
1290                                 wcross_color_old = wcross_color;
1291
1292                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1293                                         wcross_color = stov(autocvar_crosshair_dot_color);
1294
1295                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1296                                 // FIXME why don't we use wcross_alpha here?
1297                                 wcross_color = wcross_color_old;
1298                         }
1299                 }
1300         }
1301         else
1302         {
1303                 wcross_scale_prev = 0;
1304                 wcross_alpha_prev = 0;
1305                 wcross_scale_goal_prev = 0;
1306                 wcross_alpha_goal_prev = 0;
1307                 wcross_changedonetime = 0;
1308                 if(wcross_name_goal_prev)
1309                         strunzone(wcross_name_goal_prev);
1310                 wcross_name_goal_prev = string_null;
1311                 if(wcross_name_goal_prev_prev)
1312                         strunzone(wcross_name_goal_prev_prev);
1313                 wcross_name_goal_prev_prev = string_null;
1314                 wcross_name_changestarttime = 0;
1315                 wcross_name_changedonetime = 0;
1316                 wcross_name_alpha_goal_prev = 0;
1317                 wcross_name_alpha_goal_prev_prev = 0;
1318                 wcross_resolution_goal_prev = 0;
1319                 wcross_resolution_goal_prev_prev = 0;
1320         }
1321 }
1322
1323 void HUD_Draw()
1324 {
1325         vector rgb = '0 0 0';
1326         float a = 1;
1327         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1328         {
1329                 rgb = MUTATOR_ARGV(0, vector);
1330                 a = MUTATOR_ARGV(0, float);
1331         }
1332         else if(STAT(FROZEN))
1333         {
1334                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1335         }
1336         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1337         if(!intermission)
1338         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1339         {
1340                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1341                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1342         }
1343         else if(STAT(REVIVE_PROGRESS))
1344         {
1345                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1346                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1347         }
1348
1349         if(autocvar_r_letterbox == 0)
1350                 if(autocvar_viewsize < 120)
1351                 {
1352                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1353                                 Accuracy_LoadLevels();
1354
1355                         HUD_Main();
1356                         HUD_DrawScoreboard();
1357                 }
1358
1359         // crosshair goes VERY LAST
1360         UpdateDamage();
1361         HUD_Crosshair();
1362         HitSound();
1363 }
1364
1365 bool ov_enabled;
1366 float oldr_nearclip;
1367 float oldr_farclip_base;
1368 float oldr_farclip_world;
1369 float oldr_novis;
1370 float oldr_useportalculling;
1371 float oldr_useinfinitefarclip;
1372
1373 void cl_notice_run();
1374 float prev_myteam;
1375 int lasthud;
1376 float vh_notice_time;
1377 void WaypointSprite_Load();
1378 void CSQC_UpdateView(float w, float h)
1379 {SELFPARAM();
1380         entity e;
1381         float fov;
1382         float f;
1383         vector vf_size, vf_min;
1384         float a;
1385
1386         execute_next_frame();
1387
1388         ++framecount;
1389
1390         stats_get();
1391         hud = STAT(HUD);
1392
1393         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1394                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1395
1396         lasthud = hud;
1397
1398         if(autocvar__hud_showbinds_reload) // menu can set this one
1399         {
1400                 db_close(binddb);
1401                 binddb = db_create();
1402                 cvar_set("_hud_showbinds_reload", "0");
1403         }
1404
1405         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1406                 view_quality = getproperty(VF_MINFPS_QUALITY);
1407         else
1408                 view_quality = 1;
1409
1410         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1411         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1412
1413         vf_size = getpropertyvec(VF_SIZE);
1414         vf_min = getpropertyvec(VF_MIN);
1415         vid_width = vf_size.x;
1416         vid_height = vf_size.y;
1417
1418         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1419         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1420
1421         WaypointSprite_Load();
1422
1423         CSQCPlayer_SetCamera();
1424
1425         if(player_localentnum <= maxclients) // is it a client?
1426                 current_player = player_localentnum - 1;
1427         else // then player_localentnum is the vehicle I'm driving
1428                 current_player = player_localnum;
1429         myteam = entcs_GetTeam(current_player);
1430
1431         if(myteam != prev_myteam)
1432         {
1433                 myteamcolors = colormapPaletteColor(myteam, 1);
1434                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1435                 prev_myteam = myteam;
1436         }
1437
1438         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1439
1440         float is_dead = (STAT(HEALTH) <= 0);
1441
1442         // FIXME do we need this hack?
1443         if(isdemo())
1444         {
1445                 // in demos, input_buttons do not work
1446                 button_zoom = (autocvar__togglezoom == "-");
1447         }
1448         else if(button_zoom
1449                 && autocvar_cl_unpress_zoom_on_death
1450                 && (spectatee_status >= 0)
1451                 && (is_dead || intermission))
1452         {
1453                 // no zoom while dead or in intermission please
1454                 localcmd("-zoom\n");
1455                 button_zoom = false;
1456         }
1457
1458         // event chase camera
1459         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1460         {
1461                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1462                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1463                 entity gen = world;
1464
1465                 float vehicle_viewdist = 0;
1466                 vector vehicle_viewofs = '0 0 0';
1467
1468                 if(vehicle_chase)
1469                 {
1470                         if(hud != HUD_BUMBLEBEE_GUN)
1471                         {
1472                                 Vehicle info = Vehicles_from(hud);
1473                                 vehicle_viewdist = info.height;
1474                                 vehicle_viewofs = info.view_ofs;
1475                         }
1476                 }
1477
1478                 if(ons_roundlost)
1479                 {
1480                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1481                                 gen = it;
1482                                 break;
1483                         ));
1484                         if(!gen)
1485                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1486                 }
1487                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1488                 {
1489                         eventchase_running = true;
1490
1491                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1492                         if(!local_player)
1493                                 local_player = self; // fall back!
1494
1495                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1496                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1497                         if(ons_roundlost) { current_view_origin = gen.origin; }
1498
1499                         // detect maximum viewoffset and use it
1500                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1501                         if(vehicle_chase)
1502                         {
1503                                 if(vehicle_viewofs)
1504                                         view_offset = vehicle_viewofs;
1505                                 else
1506                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1507                         }
1508                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1509
1510                         if(view_offset)
1511                         {
1512                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1513                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1514                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1515                         }
1516
1517                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1518                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1519                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1520                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1521
1522                         // make the camera smooth back
1523                         float chase_distance = autocvar_cl_eventchase_distance;
1524                         if(vehicle_chase)
1525                         {
1526                                 if(vehicle_viewofs)
1527                                         chase_distance = vehicle_viewdist;
1528                                 else
1529                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1530                         }
1531                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1532
1533                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1534                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1535                         else if(eventchase_current_distance != chase_distance)
1536                                 eventchase_current_distance = chase_distance;
1537
1538                         makevectors(view_angles);
1539
1540                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1541                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1542
1543                         // If the boxtrace fails, revert back to line tracing.
1544                         if(!local_player.viewloc)
1545                         if(trace_startsolid)
1546                         {
1547                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1548                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1549                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1550                         }
1551                         else { setproperty(VF_ORIGIN, trace_endpos); }
1552
1553                         if(!local_player.viewloc)
1554                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1555                 }
1556                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1557                 {
1558                         eventchase_running = false;
1559                         cvar_set("chase_active", "0");
1560                         eventchase_current_distance = 0; // start from 0 next time
1561                 }
1562         }
1563         // workaround for camera stuck between player's legs when using chase_active 1
1564         // because the engine stops updating the chase_active camera when the game ends
1565         else if(intermission)
1566         {
1567                 cvar_settemp("chase_active", "-1");
1568                 eventchase_current_distance = 0;
1569         }
1570
1571         // do lockview after event chase camera so that it still applies whenever necessary.
1572         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1573         {
1574                 setproperty(VF_ORIGIN, freeze_org);
1575                 setproperty(VF_ANGLES, freeze_ang);
1576         }
1577         else
1578         {
1579                 freeze_org = getpropertyvec(VF_ORIGIN);
1580                 freeze_ang = getpropertyvec(VF_ANGLES);
1581         }
1582
1583         WarpZone_FixView();
1584         //WarpZone_FixPMove();
1585
1586         vector ov_org = '0 0 0';
1587         vector ov_mid = '0 0 0';
1588         vector ov_worldmin = '0 0 0';
1589         vector ov_worldmax = '0 0 0';
1590         if(autocvar_cl_orthoview)
1591         {
1592                 ov_worldmin = mi_picmin;
1593                 ov_worldmax = mi_picmax;
1594
1595                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1596                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1597                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1598
1599                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1600                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1601
1602                 float ov_nearest = vlen(ov_org - vec3(
1603                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1604                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1605                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1606                 ));
1607
1608                 float ov_furthest = 0;
1609                 float dist = 0;
1610
1611                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1612                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1613                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1614                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1615                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1616                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1617                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1618                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1619
1620                 if(!ov_enabled)
1621                 {
1622                         oldr_nearclip = cvar("r_nearclip");
1623                         oldr_farclip_base = cvar("r_farclip_base");
1624                         oldr_farclip_world = cvar("r_farclip_world");
1625                         oldr_novis = cvar("r_novis");
1626                         oldr_useportalculling = cvar("r_useportalculling");
1627                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1628                 }
1629
1630                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1631                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1632                 cvar_settemp("r_farclip_world", "0");
1633                 cvar_settemp("r_novis", "1");
1634                 cvar_settemp("r_useportalculling", "0");
1635                 cvar_settemp("r_useinfinitefarclip", "0");
1636
1637                 setproperty(VF_ORIGIN, ov_org);
1638                 setproperty(VF_ANGLES, '90 0 0');
1639
1640                 ov_enabled = true;
1641
1642                 #if 0
1643                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1644                         vtos(ov_org),
1645                         vtos(getpropertyvec(VF_ANGLES)),
1646                         ov_distance,
1647                         ov_nearest,
1648                         ov_furthest);
1649                 #endif
1650         }
1651         else
1652         {
1653                 if(ov_enabled)
1654                 {
1655                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1656                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1657                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1658                         cvar_set("r_novis", ftos(oldr_novis));
1659                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1660                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1661                 }
1662                 ov_enabled = false;
1663         }
1664
1665         // Render the Scene
1666         view_origin = getpropertyvec(VF_ORIGIN);
1667         view_angles = getpropertyvec(VF_ANGLES);
1668         makevectors(view_angles);
1669         view_forward = v_forward;
1670         view_right = v_right;
1671         view_up = v_up;
1672
1673 #ifdef BLURTEST
1674         if(time > blurtest_time0 && time < blurtest_time1)
1675         {
1676                 float r, t;
1677
1678                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1679                 r = t * blurtest_radius;
1680                 f = 1 / pow(t, blurtest_power) - 1;
1681
1682                 cvar_set("r_glsl_postprocess", "1");
1683                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1684         }
1685         else
1686         {
1687                 cvar_set("r_glsl_postprocess", "0");
1688                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1689         }
1690 #endif
1691
1692         TargetMusic_Advance();
1693         Fog_Force();
1694
1695         if(drawtime == 0)
1696                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1697         else
1698                 drawframetime = bound(0.000001, time - drawtime, 1);
1699         drawtime = time;
1700
1701         // watch for gametype changes here...
1702         // in ParseStuffCMD the cmd isn't executed yet :/
1703         // might even be better to add the gametype to TE_CSQC_INIT...?
1704         if(!postinit)
1705                 PostInit();
1706
1707         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1708         {
1709                 if(calledhooks & HOOK_START)
1710                 {
1711                         localcmd("\ncl_hook_gameend\n");
1712                         calledhooks |= HOOK_END;
1713                 }
1714         }
1715
1716         Announcer();
1717
1718         fov = autocvar_fov;
1719         if(fov <= 59.5)
1720         {
1721                 if(!zoomscript_caught)
1722                 {
1723                         localcmd("+button9\n");
1724                         zoomscript_caught = 1;
1725                 }
1726         }
1727         else
1728         {
1729                 if(zoomscript_caught)
1730                 {
1731                         localcmd("-button9\n");
1732                         zoomscript_caught = 0;
1733                 }
1734         }
1735
1736         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1737
1738         // currently switching-to weapon (for crosshair)
1739         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1740
1741         // actually active weapon (for zoom)
1742         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1743
1744         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1745
1746         f = (serverflags & SERVERFLAG_TEAMPLAY);
1747         if(f != teamplay)
1748         {
1749                 teamplay = f;
1750                 HUD_InitScores();
1751         }
1752
1753         if(last_switchweapon != switchweapon)
1754         {
1755                 weapontime = time;
1756                 last_switchweapon = switchweapon;
1757                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1758                 {
1759                         localcmd("-zoom\n");
1760                         button_zoom = false;
1761                 }
1762                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1763                 {
1764                         localcmd("-fire\n");
1765                         localcmd("-fire2\n");
1766                         button_attack2 = false;
1767                 }
1768         }
1769         if(last_activeweapon != activeweapon)
1770         {
1771                 last_activeweapon = activeweapon;
1772
1773                 e = activeweapon;
1774                 if(e.netname != "")
1775                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1776                 else
1777                         localcmd("\ncl_hook_activeweapon none\n");
1778         }
1779
1780         // ALWAYS Clear Current Scene First
1781         clearscene();
1782
1783         setproperty(VF_ORIGIN, view_origin);
1784         setproperty(VF_ANGLES, view_angles);
1785
1786         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1787         setproperty(VF_SIZE, vf_size);
1788         setproperty(VF_MIN, vf_min);
1789
1790         // Assign Standard Viewflags
1791         // Draw the World (and sky)
1792         setproperty(VF_DRAWWORLD, 1);
1793
1794         // Set the console size vars
1795         vid_conwidth = autocvar_vid_conwidth;
1796         vid_conheight = autocvar_vid_conheight;
1797         vid_pixelheight = autocvar_vid_pixelheight;
1798
1799         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1800         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1801         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1802
1803         // Camera for demo playback
1804         if(camera_active)
1805         {
1806                 if(autocvar_camera_enable)
1807                         CSQC_Demo_Camera();
1808                 else
1809                 {
1810                         cvar_set("chase_active", ftos(chase_active_backup));
1811                         cvar_set("cl_demo_mousegrab", "0");
1812                         camera_active = false;
1813                 }
1814         }
1815         else
1816         {
1817 #ifdef CAMERATEST
1818                 if(autocvar_camera_enable)
1819 #else
1820                 if(autocvar_camera_enable && isdemo())
1821 #endif
1822                 {
1823                         // Enable required Darkplaces cvars
1824                         chase_active_backup = autocvar_chase_active;
1825                         cvar_set("chase_active", "2");
1826                         cvar_set("cl_demo_mousegrab", "1");
1827                         camera_active = true;
1828                         camera_mode = false;
1829                 }
1830         }
1831
1832         // Draw the Crosshair
1833         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1834
1835         // Draw the Engine Status Bar (the default Quake HUD)
1836         setproperty(VF_DRAWENGINESBAR, 0);
1837
1838         // Update the mouse position
1839         /*
1840            mousepos_x = vid_conwidth;
1841            mousepos_y = vid_conheight;
1842            mousepos = mousepos*0.5 + getmousepos();
1843          */
1844
1845         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1846
1847         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1848         renderscene();
1849
1850         // now switch to 2D drawing mode by calling a 2D drawing function
1851         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1852         // next R_RenderScene call
1853         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1854
1855         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1856         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1857         {
1858                 // apply night vision effect
1859                 vector tc_00, tc_01, tc_10, tc_11;
1860                 vector rgb = '0 0 0';
1861
1862                 if(!nightvision_noise)
1863                 {
1864                         nightvision_noise = new(nightvision_noise);
1865                 }
1866                 if(!nightvision_noise2)
1867                 {
1868                         nightvision_noise2 = new(nightvision_noise2);
1869                 }
1870
1871                 // color tint in yellow
1872                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1873
1874                 // draw BG
1875                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1876                 rgb = '1 1 1';
1877                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1878                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1879                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1880                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1881                 tc_11 = tc_01 + tc_10 - tc_00;
1882                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1883                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1884                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1885                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1886                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1887                 R_EndPolygon();
1888
1889                 // draw FG
1890                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1891                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1892                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1893                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1894                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1895                 tc_11 = tc_01 + tc_10 - tc_00;
1896                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1897                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1898                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1899                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1900                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1901                 R_EndPolygon();
1902         }
1903
1904         if(autocvar_cl_reticle)
1905         {
1906                 Weapon wep = activeweapon;
1907                 // Draw the aiming reticle for weapons that use it
1908                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1909                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1910                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1911                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1912                 {
1913                         // no zoom reticle while dead
1914                         reticle_type = 0;
1915                 }
1916                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1917                 {
1918                         if(reticle_image != "") { reticle_type = 2; }
1919                         else { reticle_type = 0; }
1920                 }
1921                 else if(button_zoom || zoomscript_caught)
1922                 {
1923                         // normal zoom
1924                         reticle_type = 1;
1925                 }
1926
1927                 if(reticle_type)
1928                 {
1929                         if(autocvar_cl_reticle_stretch)
1930                         {
1931                                 reticle_size.x = vid_conwidth;
1932                                 reticle_size.y = vid_conheight;
1933                                 reticle_pos.x = 0;
1934                                 reticle_pos.y = 0;
1935                         }
1936                         else
1937                         {
1938                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1939                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1940                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1941                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1942                         }
1943
1944                         if(zoomscript_caught)
1945                                 f = 1;
1946                         else
1947                                 f = current_zoomfraction;
1948
1949                         if(f)
1950                         {
1951                                 switch(reticle_type)
1952                                 {
1953                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1954                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1955                                 }
1956                         }
1957                 }
1958         }
1959         else
1960         {
1961                 if(reticle_type != 0) { reticle_type = 0; }
1962         }
1963
1964
1965         // improved polyblend
1966         if(autocvar_hud_contents)
1967         {
1968                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1969                 vector liquidcolor;
1970
1971                 switch(pointcontents(view_origin))
1972                 {
1973                         case CONTENT_WATER:
1974                                 liquidalpha = autocvar_hud_contents_water_alpha;
1975                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1976                                 incontent = 1;
1977                                 break;
1978
1979                         case CONTENT_LAVA:
1980                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1981                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1982                                 incontent = 1;
1983                                 break;
1984
1985                         case CONTENT_SLIME:
1986                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1987                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1988                                 incontent = 1;
1989                                 break;
1990
1991                         default:
1992                                 liquidalpha = 0;
1993                                 liquidcolor = '0 0 0';
1994                                 incontent = 0;
1995                                 break;
1996                 }
1997
1998                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1999                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2000                         contentfadetime = autocvar_hud_contents_fadeintime;
2001                         liquidalpha_prev = liquidalpha;
2002                         liquidcolor_prev = liquidcolor;
2003                 }
2004                 else
2005                         contentfadetime = autocvar_hud_contents_fadeouttime;
2006
2007                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2008                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2009
2010                 if(contentavgalpha)
2011                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2012
2013                 if(autocvar_hud_postprocessing)
2014                 {
2015                         if(autocvar_hud_contents_blur && contentavgalpha)
2016                         {
2017                                 content_blurpostprocess.x = 1;
2018                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2019                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2020                         }
2021                         else
2022                         {
2023                                 content_blurpostprocess.x = 0;
2024                                 content_blurpostprocess.y = 0;
2025                                 content_blurpostprocess.z = 0;
2026                         }
2027                 }
2028         }
2029
2030         if(autocvar_hud_damage && !STAT(FROZEN))
2031         {
2032                 splash_size.x = max(vid_conwidth, vid_conheight);
2033                 splash_size.y = max(vid_conwidth, vid_conheight);
2034                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2035                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2036
2037                 float myhealth_flash_temp;
2038                 myhealth = STAT(HEALTH);
2039
2040                 // fade out
2041                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2042                 // add new damage
2043                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2044
2045                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2046                 pain_threshold = autocvar_hud_damage_pain_threshold;
2047                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2048                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2049
2050                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2051                 {
2052                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2053                 }
2054
2055                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2056
2057                 if(myhealth_prev < 1)
2058                 {
2059                         if(myhealth >= 1)
2060                         {
2061                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2062                                 myhealth_flash_temp = 0;
2063                         }
2064                         else
2065                         {
2066                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2067                         }
2068                 }
2069
2070                 if(spectatee_status == -1 || intermission)
2071                 {
2072                         myhealth_flash = 0; // observing, or match ended
2073                         myhealth_flash_temp = 0;
2074                 }
2075
2076                 myhealth_prev = myhealth;
2077
2078                 // IDEA: change damage color/picture based on player model for robot/alien species?
2079                 // pro: matches model better
2080                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2081                 // maybe different reddish pics?
2082                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2083                 {
2084                         if(autocvar_cl_gentle_damage == 2)
2085                         {
2086                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2087                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2088                         }
2089                         else
2090                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2091
2092                         if(myhealth_flash_temp > 0)
2093                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2094                 }
2095                 else if(myhealth_flash_temp > 0)
2096                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2097
2098                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2099                 {
2100                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2101                         {
2102                                 damage_blurpostprocess.x = 1;
2103                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2104                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2105                         }
2106                         else
2107                         {
2108                                 damage_blurpostprocess.x = 0;
2109                                 damage_blurpostprocess.y = 0;
2110                                 damage_blurpostprocess.z = 0;
2111                         }
2112                 }
2113         }
2114
2115         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2116         float e2 = (autocvar_hud_powerup != 0);
2117         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2118         {
2119                 // enable or disable rendering types if they are used or not
2120                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2121                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2122
2123                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2124                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2125                 {
2126                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2127                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2128                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2129                         {
2130                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2131                                 old_blurradius = blurradius;
2132                                 old_bluralpha = bluralpha;
2133                         }
2134                 }
2135                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2136                 {
2137                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2138                         old_blurradius = 0;
2139                         old_bluralpha = 0;
2140                 }
2141
2142                 // edge detection postprocess handling done second (used by hud_powerup)
2143                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2144                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2145                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2146
2147                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2148
2149                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2150                 {
2151                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2152                         {
2153                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2154                                 old_sharpen_intensity = sharpen_intensity;
2155                         }
2156                 }
2157                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2158                 {
2159                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2160                         old_sharpen_intensity = 0;
2161                 }
2162
2163                 if(cvar("r_glsl_postprocess") == 0)
2164                         cvar_set("r_glsl_postprocess", "2");
2165         }
2166         else if(cvar("r_glsl_postprocess") == 2)
2167                 cvar_set("r_glsl_postprocess", "0");
2168
2169         /*if(gametype == MAPINFO_TYPE_CTF)
2170           {
2171           ctf_view();
2172           } else */
2173
2174         // draw 2D entities
2175         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2176         Draw_ShowNames_All();
2177         Debug_Draw();
2178
2179         scoreboard_active = HUD_WouldDrawScoreboard();
2180
2181         HUD_Draw();
2182
2183         if(NextFrameCommand)
2184         {
2185                 localcmd("\n", NextFrameCommand, "\n");
2186                 NextFrameCommand = string_null;
2187         }
2188
2189         // we must do this check AFTER a frame was rendered, or it won't work
2190         if(cs_project_is_b0rked == 0)
2191         {
2192                 string w0, h0;
2193                 w0 = ftos(autocvar_vid_conwidth);
2194                 h0 = ftos(autocvar_vid_conheight);
2195                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2196                 //setproperty(VF_FOV, '90 90 0');
2197                 setproperty(VF_ORIGIN, '0 0 0');
2198                 setproperty(VF_ANGLES, '0 0 0');
2199                 setproperty(VF_PERSPECTIVE, 1);
2200                 makevectors('0 0 0');
2201                 vector v1, v2;
2202                 cvar_set("vid_conwidth", "800");
2203                 cvar_set("vid_conheight", "600");
2204                 v1 = cs_project(v_forward);
2205                 cvar_set("vid_conwidth", "640");
2206                 cvar_set("vid_conheight", "480");
2207                 v2 = cs_project(v_forward);
2208                 if(v1 == v2)
2209                         cs_project_is_b0rked = 1;
2210                 else
2211                         cs_project_is_b0rked = -1;
2212                 cvar_set("vid_conwidth", w0);
2213                 cvar_set("vid_conheight", h0);
2214         }
2215
2216         if(autocvar__hud_configure)
2217                 HUD_Panel_Mouse();
2218         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2219                 HUD_Minigame_Mouse();
2220         else if(QuickMenu_IsOpened())
2221                 QuickMenu_Mouse();
2222         else
2223                 HUD_Radar_Mouse();
2224
2225         cl_notice_run();
2226         unpause_update();
2227         Net_Flush();
2228
2229         // let's reset the view back to normal for the end
2230         setproperty(VF_MIN, '0 0 0');
2231         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2232 }
2233
2234
2235 // following vectors must be global to allow seamless switching between camera modes
2236 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2237 void CSQC_Demo_Camera()
2238 {
2239         float speed, attenuation, dimensions;
2240         vector tmp, delta;
2241
2242         if( autocvar_camera_reset || !camera_mode )
2243         {
2244                 camera_offset = '0 0 0';
2245                 current_angles = '0 0 0';
2246                 camera_direction = '0 0 0';
2247                 camera_offset.z += 30;
2248                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2249                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2250                 current_origin = view_origin;
2251                 current_camera_offset  = camera_offset;
2252                 cvar_set("camera_reset", "0");
2253                 camera_mode = CAMERA_CHASE;
2254         }
2255
2256         // Camera angles
2257         if( camera_roll )
2258                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2259
2260         if(autocvar_camera_look_player)
2261         {
2262                 vector dir;
2263                 float n;
2264
2265                 dir = normalize(view_origin - current_position);
2266                 n = mouse_angles.z;
2267                 mouse_angles = vectoangles(dir);
2268                 mouse_angles.x = mouse_angles.x * -1;
2269                 mouse_angles.z = n;
2270         }
2271         else
2272         {
2273                 tmp = getmousepos() * 0.1;
2274                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2275                 {
2276                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2277                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2278                 }
2279         }
2280
2281         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2282         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2283         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2284         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2285
2286         // Fix difference when angles don't have the same sign
2287         delta = '0 0 0';
2288         if(mouse_angles.y < -60 && current_angles.y > 60)
2289                 delta = '0 360 0';
2290         if(mouse_angles.y > 60 && current_angles.y < -60)
2291                 delta = '0 -360 0';
2292
2293         if(autocvar_camera_look_player)
2294                 attenuation = autocvar_camera_look_attenuation;
2295         else
2296                 attenuation = autocvar_camera_speed_attenuation;
2297
2298         attenuation = 1 / max(1, attenuation);
2299         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2300
2301         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2302         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2303         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2304         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2305
2306         // Camera position
2307         tmp = '0 0 0';
2308         dimensions = 0;
2309
2310         if( camera_direction.x )
2311         {
2312                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2313                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2314                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2315                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2316                 ++dimensions;
2317         }
2318
2319         if( camera_direction.y )
2320         {
2321                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2322                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2323                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2324                 ++dimensions;
2325         }
2326
2327         if( camera_direction.z )
2328         {
2329                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2330                 ++dimensions;
2331         }
2332
2333         if(autocvar_camera_free)
2334                 speed = autocvar_camera_speed_free;
2335         else
2336                 speed = autocvar_camera_speed_chase;
2337
2338         if(dimensions)
2339         {
2340                 speed = speed * sqrt(1 / dimensions);
2341                 camera_offset += tmp * speed;
2342         }
2343
2344         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2345
2346         // Camera modes
2347         if( autocvar_camera_free )
2348         {
2349                 if ( camera_mode == CAMERA_CHASE )
2350                 {
2351                         current_camera_offset = current_origin + current_camera_offset;
2352                         camera_offset = current_origin + camera_offset;
2353                 }
2354
2355                 camera_mode = CAMERA_FREE;
2356                 current_position = current_camera_offset;
2357         }
2358         else
2359         {
2360                 if ( camera_mode == CAMERA_FREE )
2361                 {
2362                         current_origin = view_origin;
2363                         camera_offset = camera_offset - current_origin;
2364                         current_camera_offset = current_camera_offset - current_origin;
2365                 }
2366
2367                 camera_mode = CAMERA_CHASE;
2368
2369                 if(autocvar_camera_chase_smoothly)
2370                         current_origin += (view_origin - current_origin) * attenuation;
2371                 else
2372                         current_origin = view_origin;
2373
2374                 current_position = current_origin + current_camera_offset;
2375         }
2376
2377         setproperty(VF_ANGLES, current_angles);
2378         setproperty(VF_ORIGIN, current_position);
2379 }