Remove some leftovers from merge
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "_all.qh"
2
3 #include "announcer.qh"
4 #include "hook.qh"
5 #include "hud.qh"
6 #include "hud_config.qh"
7 #include "mapvoting.qh"
8 #include "noise.qh"
9 #include "scoreboard.qh"
10 #include "shownames.qh"
11 #include "waypointsprites.qh"
12
13 #include "../common/constants.qh"
14 #include "../common/mapinfo.qh"
15 #include "../common/nades.qh"
16 #include "../common/stats.qh"
17 #include "../common/triggers/target/music.qh"
18 #include "../common/teams.qh"
19 #include "../common/util.qh"
20
21 #include "../common/weapons/all.qh"
22
23 #include "../common/vehicles/vehicles.qh"
24 #include "../common/vehicles/cl_vehicles.qh"
25
26 #include "../csqcmodellib/cl_player.qh"
27
28 #include "../warpzonelib/client.qh"
29 #include "../warpzonelib/common.qh"
30 #include "../warpzonelib/mathlib.qh"
31
32 entity porto;
33 vector polyline[16];
34 void Porto_Draw()
35 {
36         vector p, dir, ang, q, nextdir;
37         float portal_number, portal1_idx;
38
39         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
40                 return;
41         if(g_balance_porto_secondary)
42                 return;
43         if(intermission == 1)
44                 return;
45         if(intermission == 2)
46                 return;
47         if (getstati(STAT_HEALTH) <= 0)
48                 return;
49
50         dir = view_forward;
51
52         if(angles_held_status)
53         {
54                 makevectors(angles_held);
55                 dir = v_forward;
56         }
57
58         p = view_origin;
59
60         polyline[0] = p;
61         int idx = 1;
62         portal_number = 0;
63         nextdir = dir;
64
65         for (;;)
66         {
67                 dir = nextdir;
68                 traceline(p, p + 65536 * dir, true, porto);
69                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
70                         return;
71                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
72                 p = trace_endpos;
73                 polyline[idx] = p;
74                 ++idx;
75                 if(idx >= 16)
76                         return;
77                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
78                         continue;
79                 ++portal_number;
80                 ang = vectoangles2(trace_plane_normal, dir);
81                 ang.x = -ang.x;
82                 makevectors(ang);
83                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
84                         return;
85                 if(portal_number == 1)
86                 {
87                         portal1_idx = idx;
88                         if(portal_number >= 2)
89                                 break;
90                 }
91         }
92
93         while(idx >= 2)
94         {
95                 p = polyline[idx-2];
96                 q = polyline[idx-1];
97                 if(idx == 2)
98                         p = p - view_up * 16;
99                 if(idx-1 >= portal1_idx)
100                 {
101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
102                 }
103                 else
104                 {
105                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
106                 }
107                 --idx;
108         }
109 }
110
111 void Porto_Init()
112 {
113         porto = spawn();
114         porto.classname = "porto";
115         porto.draw = Porto_Draw;
116         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
117 }
118
119 float drawtime;
120 float avgspeed;
121 vector GetCurrentFov(float fov)
122 {
123         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
124         float velocityzoom, curspeed;
125         vector v;
126
127         zoomsensitivity = autocvar_cl_zoomsensitivity;
128         zoomfactor = autocvar_cl_zoomfactor;
129         if(zoomfactor < 1 || zoomfactor > 16)
130                 zoomfactor = 2.5;
131         zoomspeed = autocvar_cl_zoomspeed;
132         if(zoomspeed >= 0)
133         if(zoomspeed < 0.5 || zoomspeed > 16)
134                         zoomspeed = 3.5;
135
136         zoomdir = button_zoom;
137         if(hud == HUD_NORMAL)
138         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
139                 zoomdir += button_attack2;
140         if(spectatee_status > 0 || isdemo())
141         {
142                 if(spectatorbutton_zoom)
143                 {
144                         if(zoomdir)
145                                 zoomdir = 0;
146                         else
147                                 zoomdir = 1;
148                 }
149                 // fteqcc failed twice here already, don't optimize this
150         }
151
152         if(zoomdir) { zoomin_effect = 0; }
153
154         if(camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else if(autocvar_cl_spawnzoom && zoomin_effect)
159         {
160                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
161
162                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
163                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
164                 if(current_viewzoom == 1) { zoomin_effect = 0; }
165         }
166         else
167         {
168                 if(zoomspeed < 0) // instant zoom
169                 {
170                         if(zoomdir)
171                                 current_viewzoom = 1 / zoomfactor;
172                         else
173                                 current_viewzoom = 1;
174                 }
175                 else
176                 {
177                         if(zoomdir)
178                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
179                         else
180                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
181                 }
182         }
183
184         if(almost_equals(current_viewzoom, 1))
185                 current_zoomfraction = 0;
186         else if(almost_equals(current_viewzoom, 1/zoomfactor))
187                 current_zoomfraction = 1;
188         else
189                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
190
191         if(zoomsensitivity < 1)
192                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
193         else
194                 setsensitivityscale(1);
195
196         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
197         {
198                 if(intermission) { curspeed = 0; }
199                 else
200                 {
201
202                         makevectors(view_angles);
203                         v = pmove_vel;
204                         if(csqcplayer)
205                                 v = csqcplayer.velocity;
206
207                         switch(autocvar_cl_velocityzoom_type)
208                         {
209                                 case 3: curspeed = max(0, v_forward * v); break;
210                                 case 2: curspeed = (v_forward * v); break;
211                                 case 1: default: curspeed = vlen(v); break;
212                         }
213                 }
214
215                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
216                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
217                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
218
219                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
220         }
221         else
222                 velocityzoom = 1;
223
224         float frustumx, frustumy, fovx, fovy;
225         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
226         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
227         fovx = atan2(frustumx, 1) / M_PI * 360.0;
228         fovy = atan2(frustumy, 1) / M_PI * 360.0;
229
230         return '1 0 0' * fovx + '0 1 0' * fovy;
231 }
232
233 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
234 {
235         float fovx, fovy;
236         float width = (ov_worldmax.x - ov_worldmin.x);
237         float height = (ov_worldmax.y - ov_worldmin.y);
238         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
239         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
240         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
241         return '1 0 0' * fovx + '0 1 0' * fovy;
242 }
243
244 // this function must match W_SetupShot!
245 float zoomscript_caught;
246
247 vector wcross_origin;
248 float wcross_scale_prev, wcross_alpha_prev;
249 vector wcross_color_prev;
250 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
251 vector wcross_color_goal_prev;
252 float wcross_changedonetime;
253
254 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
255 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
256 float wcross_name_changestarttime, wcross_name_changedonetime;
257 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
258
259 float wcross_ring_prev;
260
261 entity trueaim;
262 entity trueaim_rifle;
263
264 const float SHOTTYPE_HITTEAM = 1;
265 const float SHOTTYPE_HITOBSTRUCTION = 2;
266 const float SHOTTYPE_HITWORLD = 3;
267 const float SHOTTYPE_HITENEMY = 4;
268
269 void TrueAim_Init()
270 {
271         trueaim = spawn();
272         trueaim.classname = "trueaim";
273         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
274         trueaim_rifle = spawn();
275         trueaim_rifle.classname = "trueaim_rifle";
276         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
277 }
278
279 float EnemyHitCheck()
280 {
281         float t, n;
282         wcross_origin = project_3d_to_2d(trace_endpos);
283         wcross_origin.z = 0;
284         if(trace_ent)
285                 n = trace_ent.entnum;
286         else
287                 n = trace_networkentity;
288         if(n < 1)
289                 return SHOTTYPE_HITWORLD;
290         if(n > maxclients)
291                 return SHOTTYPE_HITWORLD;
292         t = GetPlayerColor(n - 1);
293         if(teamplay)
294                 if(t == myteam)
295                         return SHOTTYPE_HITTEAM;
296         if(t == NUM_SPECTATOR)
297                 return SHOTTYPE_HITWORLD;
298         return SHOTTYPE_HITENEMY;
299 }
300
301 float TrueAimCheck()
302 {
303         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
304         vector vecs, trueaimpoint, w_shotorg;
305         vector mi, ma, dv;
306         float shottype;
307         entity ta;
308         float mv;
309
310         mi = ma = '0 0 0';
311         ta = trueaim;
312         mv = MOVE_NOMONSTERS;
313
314         switch(activeweapon) // WEAPONTODO
315         {
316                 case WEP_TUBA: // no aim
317                 case WEP_PORTO: // shoots from eye
318                 case WEP_HOOK: // no trueaim
319                 case WEP_MORTAR: // toss curve
320                         return SHOTTYPE_HITWORLD;
321                 case WEP_VORTEX:
322                 case WEP_VAPORIZER:
323                         mv = MOVE_NORMAL;
324                         break;
325                 case WEP_RIFLE:
326                         ta = trueaim_rifle;
327                         mv = MOVE_NORMAL;
328                         if(zoomscript_caught)
329                         {
330                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
331                                 return EnemyHitCheck();
332                         }
333                         break;
334                 case WEP_DEVASTATOR: // projectile has a size!
335                         mi = '-3 -3 -3';
336                         ma = '3 3 3';
337                         break;
338                 case WEP_FIREBALL: // projectile has a size!
339                         mi = '-16 -16 -16';
340                         ma = '16 16 16';
341                         break;
342                 case WEP_SEEKER: // projectile has a size!
343                         mi = '-2 -2 -2';
344                         ma = '2 2 2';
345                         break;
346                 case WEP_ELECTRO: // projectile has a size!
347                         mi = '0 0 -3';
348                         ma = '0 0 -3';
349                         break;
350         }
351
352         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
353
354         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
355
356         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
357         trueaimpoint = trace_endpos;
358
359         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
360                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
361
362         if(vecs.x > 0)
363                 vecs.y = -vecs.y;
364         else
365                 vecs = '0 0 0';
366
367         dv = view_right * vecs.y + view_up * vecs.z;
368         w_shotorg = traceorigin + dv;
369
370         // now move the vecs forward as much as requested if possible
371         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
372         w_shotorg = trace_endpos - view_forward * nudge;
373
374         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
375         shottype = EnemyHitCheck();
376         if(shottype != SHOTTYPE_HITWORLD)
377                 return shottype;
378
379 #if 0
380         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
381         // or rather, I know why, but see no fix
382         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
383                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
384                 return SHOTTYPE_HITOBSTRUCTION;
385 #endif
386
387         return SHOTTYPE_HITWORLD;
388 }
389
390 void CSQC_common_hud(void);
391
392 void PostInit(void);
393 void CSQC_Demo_Camera();
394 float HUD_WouldDrawScoreboard();
395 float camera_mode;
396 const float CAMERA_FREE = 1;
397 const float CAMERA_CHASE = 2;
398 float reticle_type;
399 string reticle_image;
400 string NextFrameCommand;
401
402 vector freeze_org, freeze_ang;
403 entity nightvision_noise, nightvision_noise2;
404
405 const float MAX_TIME_DIFF = 5;
406 float pickup_crosshair_time, pickup_crosshair_size;
407 float hitindication_crosshair_size;
408 float use_vortex_chargepool;
409
410 float myhealth, myhealth_prev;
411 float myhealth_flash;
412
413 float old_blurradius, old_bluralpha;
414 float old_sharpen_intensity;
415
416 vector myhealth_gentlergb;
417
418 float contentavgalpha, liquidalpha_prev;
419 vector liquidcolor_prev;
420
421 float eventchase_current_distance;
422 float eventchase_running;
423 float WantEventchase()
424 {
425         if(autocvar_cl_orthoview)
426                 return false;
427         if(intermission)
428                 return true;
429         if(spectatee_status >= 0)
430         {
431                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
432                         return true;
433                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
434                 {
435                         if(autocvar_cl_eventchase_death == 2)
436                         {
437                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
438                                 if(self.velocity == '0 0 0' || eventchase_running)
439                                         return true;
440                         }
441                         else return true;
442                 }
443         }
444         return false;
445 }
446
447 vector damage_blurpostprocess, content_blurpostprocess;
448
449 float checkfail[16];
450
451 float unaccounted_damage = 0;
452 void UpdateDamage()
453 {
454         // accumulate damage with each stat update
455         static float damage_total_prev = 0;
456         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
457         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
458         damage_total_prev = damage_total;
459
460         static float damage_dealt_time_prev = 0;
461         float damage_dealt_time = getstatf(STAT_HIT_TIME);
462         if (damage_dealt_time != damage_dealt_time_prev)
463         {
464                 unaccounted_damage += unaccounted_damage_new;
465                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
466         }
467         damage_dealt_time_prev = damage_dealt_time;
468
469         // prevent hitsound when switching spectatee
470         static float spectatee_status_prev = 0;
471         if (spectatee_status != spectatee_status_prev)
472                 unaccounted_damage = 0;
473         spectatee_status_prev = spectatee_status;
474 }
475
476 void UpdateHitsound()
477 {
478         // varying sound pitch
479
480         static float hitsound_time_prev = 0;
481         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
482         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
483         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
484         {
485                 if (autocvar_cl_hitsound && unaccounted_damage)
486                 {
487                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
488                         float a = autocvar_cl_hitsound_max_pitch;
489                         float b = autocvar_cl_hitsound_min_pitch;
490                         float c = autocvar_cl_hitsound_nom_damage;
491                         float x = unaccounted_damage;
492                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
493
494                         // if sound variation is disabled, set pitch_shift to 1
495                         if (autocvar_cl_hitsound == 1)
496                                 pitch_shift = 1;
497
498                         // if pitch shift is reversed, mirror in (max-min)/2 + min
499                         if (autocvar_cl_hitsound == 3)
500                         {
501                                 float mirror_value = (a-b)/2 + b;
502                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
503                         }
504
505                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
506
507                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
508                         // todo: normalize sound pressure levels? seems unnecessary
509
510                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
511                 }
512                 unaccounted_damage = 0;
513                 hitsound_time_prev = time;
514         }
515
516         static float typehit_time_prev = 0;
517         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
518         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
519         {
520                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
521                 typehit_time_prev = typehit_time;
522         }
523 }
524
525 void UpdateCrosshair()
526 {
527         static float rainbow_last_flicker;
528     static vector rainbow_prev_color;
529         entity e = self;
530         float f, i, j;
531         vector v;
532         if(getstati(STAT_FROZEN))
533                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
534         else if (getstatf(STAT_HEALING_ORB)>time)
535                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
536         if(!intermission)
537         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
538         {
539                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
540                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
541         }
542         else if(getstatf(STAT_REVIVE_PROGRESS))
543         {
544                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
545                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
546         }
547
548         if(autocvar_r_letterbox == 0)
549                 if(autocvar_viewsize < 120)
550                         CSQC_common_hud();
551
552         // crosshair goes VERY LAST
553         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
554         {
555                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
556                         return;
557
558                 string wcross_style;
559                 float wcross_alpha, wcross_resolution;
560                 wcross_style = autocvar_crosshair;
561                 if (wcross_style == "0")
562                         return;
563                 wcross_resolution = autocvar_crosshair_size;
564                 if (wcross_resolution == 0)
565                         return;
566                 wcross_alpha = autocvar_crosshair_alpha;
567                 if (wcross_alpha == 0)
568                         return;
569
570                 // TrueAim check
571                 float shottype;
572
573                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
574                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
575                 wcross_origin.z = 0;
576                 if(autocvar_crosshair_hittest)
577                 {
578                         vector wcross_oldorigin;
579                         wcross_oldorigin = wcross_origin;
580                         shottype = TrueAimCheck();
581                         if(shottype == SHOTTYPE_HITWORLD)
582                         {
583                                 v = wcross_origin - wcross_oldorigin;
584                                 v.x /= vid_conwidth;
585                                 v.y /= vid_conheight;
586                                 if(vlen(v) > 0.01)
587                                         shottype = SHOTTYPE_HITOBSTRUCTION;
588                         }
589                         if(!autocvar_crosshair_hittest_showimpact)
590                                 wcross_origin = wcross_oldorigin;
591                 }
592                 else
593                         shottype = SHOTTYPE_HITWORLD;
594
595                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
596                 string wcross_name = "";
597                 float wcross_scale, wcross_blur;
598
599                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
600                 {
601                         e = get_weaponinfo(switchingweapon);
602                         if(e)
603                         {
604                                 if(autocvar_crosshair_per_weapon)
605                                 {
606                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
607                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
608                                         //if (wcross_resolution == 0)
609                                                 //return;
610
611                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
612                                         wcross_resolution *= e.w_crosshair_size;
613                                         wcross_name = e.w_crosshair;
614                                 }
615                         }
616                 }
617
618                 if(wcross_name == "")
619                         wcross_name = strcat("gfx/crosshair", wcross_style);
620
621                 // MAIN CROSSHAIR COLOR DECISION
622                 switch(autocvar_crosshair_color_special)
623                 {
624                         case 1: // crosshair_color_per_weapon
625                         {
626                                 if(e)
627                                 {
628                                         wcross_color = e.wpcolor;
629                                         break;
630                                 }
631                                 else { goto normalcolor; }
632                         }
633
634                         case 2: // crosshair_color_by_health
635                         {
636                                 float x = getstati(STAT_HEALTH);
637
638                                 //x = red
639                                 //y = green
640                                 //z = blue
641
642                                 wcross_color.z = 0;
643
644                                 if(x > 200)
645                                 {
646                                         wcross_color.x = 0;
647                                         wcross_color.y = 1;
648                                 }
649                                 else if(x > 150)
650                                 {
651                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
652                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
653                                 }
654                                 else if(x > 100)
655                                 {
656                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
657                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
658                                         wcross_color.z = 1 - (x-100)*0.02;
659                                 }
660                                 else if(x > 50)
661                                 {
662                                         wcross_color.x = 1;
663                                         wcross_color.y = 1;
664                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
665                                 }
666                                 else if(x > 20)
667                                 {
668                                         wcross_color.x = 1;
669                                         wcross_color.y = (x-20)*90/27/100;
670                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
671                                 }
672                                 else
673                                 {
674                                         wcross_color.x = 1;
675                                         wcross_color.y = 0;
676                                 }
677                                 break;
678                         }
679
680                         case 3: // crosshair_color_rainbow
681                         {
682                                 if(time >= rainbow_last_flicker)
683                                 {
684                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
685                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
686                                 }
687                                 wcross_color = rainbow_prev_color;
688                                 break;
689                         }
690                         :normalcolor
691                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
692                 }
693
694                 if(autocvar_crosshair_effect_scalefade)
695                 {
696                         wcross_scale = wcross_resolution;
697                         wcross_resolution = 1;
698                 }
699                 else
700                 {
701                         wcross_scale = 1;
702                 }
703
704                 if(autocvar_crosshair_pickup)
705                 {
706                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
707
708                         if(pickup_crosshair_time < stat_pickup_time)
709                         {
710                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
711                                         pickup_crosshair_size = 1;
712
713                                 pickup_crosshair_time = stat_pickup_time;
714                         }
715
716                         if(pickup_crosshair_size > 0)
717                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
718                         else
719                                 pickup_crosshair_size = 0;
720
721                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
722                 }
723
724                 // todo: make crosshair hit indication dependent on damage dealt
725                 if(autocvar_crosshair_hitindication)
726                 {
727                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
728
729                         if(unaccounted_damage)
730                         {
731                                 hitindication_crosshair_size = 1;
732                         }
733
734                         if(hitindication_crosshair_size > 0)
735                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
736                         else
737                                 hitindication_crosshair_size = 0;
738
739                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
740                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
741                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
742                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
743                 }
744
745                 if(shottype == SHOTTYPE_HITENEMY)
746                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
747                 if(shottype == SHOTTYPE_HITTEAM)
748                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
749
750                 f = fabs(autocvar_crosshair_effect_time);
751                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
752                 {
753                         wcross_changedonetime = time + f;
754                 }
755                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
756                 {
757                         wcross_name_changestarttime = time;
758                         wcross_name_changedonetime = time + f;
759                         if(wcross_name_goal_prev_prev)
760                                 strunzone(wcross_name_goal_prev_prev);
761                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
762                         wcross_name_goal_prev = strzone(wcross_name);
763                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
764                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
765                         wcross_resolution_goal_prev = wcross_resolution;
766                 }
767
768                 wcross_scale_goal_prev = wcross_scale;
769                 wcross_alpha_goal_prev = wcross_alpha;
770                 wcross_color_goal_prev = wcross_color;
771
772                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
773                 {
774                         wcross_blur = 1;
775                         wcross_alpha *= 0.75;
776                 }
777                 else
778                         wcross_blur = 0;
779                 // *_prev is at time-frametime
780                 // * is at wcross_changedonetime+f
781                 // what do we have at time?
782                 if(time < wcross_changedonetime)
783                 {
784                         f = frametime / (wcross_changedonetime - time + frametime);
785                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
786                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
787                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
788                 }
789
790                 wcross_scale_prev = wcross_scale;
791                 wcross_alpha_prev = wcross_alpha;
792                 wcross_color_prev = wcross_color;
793
794                 wcross_scale *= 1 - autocvar__menu_alpha;
795                 wcross_alpha *= 1 - autocvar__menu_alpha;
796                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
797
798                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
799                 {
800                         // crosshair rings for weapon stats
801                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
802                         {
803                                 // declarations and stats
804                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
805                                 string ring_image = string_null, ring_inner_image = string_null;
806                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
807
808                                 ring_scale = autocvar_crosshair_ring_size;
809
810                                 float weapon_clipload, weapon_clipsize;
811                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
812                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
813
814                                 float ok_ammo_charge, ok_ammo_chargepool;
815                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
816                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
817
818                                 float vortex_charge, vortex_chargepool;
819                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
820                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
821
822                                 float arc_heat = getstatf(STAT_ARC_HEAT);
823
824                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
825                                         vortex_charge_movingavg = vortex_charge;
826
827
828                                 // handle the values
829                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
830                                 {
831                                         if (vortex_chargepool || use_vortex_chargepool) {
832                                                 use_vortex_chargepool = 1;
833                                                 ring_inner_value = vortex_chargepool;
834                                         } else {
835                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
836                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
837                                         }
838
839                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
840                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
841                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
842
843                                         // draw the outer ring to show the current charge of the weapon
844                                         ring_value = vortex_charge;
845                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
846                                         ring_rgb = wcross_color;
847                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
848                                 }
849                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
850                                 {
851                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
852                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
853                                         ring_rgb = wcross_color;
854                                         ring_image = "gfx/crosshair_ring.tga";
855                                 }
856                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
857                                 {
858                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
859                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
860                                         ring_rgb = wcross_color;
861                                         ring_image = "gfx/crosshair_ring.tga";
862                                 }
863                                 else if (ok_ammo_charge)
864                                 {
865                                         ring_value = ok_ammo_chargepool;
866                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
867                                         ring_rgb = wcross_color;
868                                         ring_image = "gfx/crosshair_ring.tga";
869                                 }
870                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
871                                 {
872                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
873                                         ring_scale = autocvar_crosshair_ring_reload_size;
874                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
875                                         ring_rgb = wcross_color;
876
877                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
878                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
879                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
880                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
881                                         else
882                                                 ring_image = "gfx/crosshair_ring.tga";
883                                 }
884                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
885                                 {
886                                         ring_value = arc_heat;
887                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
888                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
889                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
890                                         ring_image = "gfx/crosshair_ring.tga";
891                                 }
892
893                                 // if in weapon switch animation, fade ring out/in
894                                 if(autocvar_crosshair_effect_time > 0)
895                                 {
896                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
897                                         if (f >= 1)
898                                         {
899                                                 wcross_ring_prev = ((ring_image) ? true : false);
900                                         }
901
902                                         if(wcross_ring_prev)
903                                         {
904                                                 if(f < 1)
905                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
906                                         }
907                                         else
908                                         {
909                                                 if(f < 1)
910                                                         ring_alpha *= bound(0, f, 1);
911                                         }
912                                 }
913
914                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
915                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
916
917                                 if (ring_value)
918                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
919                         }
920
921 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
922                         do \
923                         { \
924                                 if(wcross_blur > 0) \
925                                 { \
926                                         for(i = -2; i <= 2; ++i) \
927                                         for(j = -2; j <= 2; ++j) \
928                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
929                                 } \
930                                 else \
931                                 { \
932                                         M(0,0,sz,wcross_name,wcross_alpha); \
933                                 } \
934                         } \
935                         while(0)
936
937 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
938                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
939
940 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
941                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
942
943                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
944                         {
945                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
946                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
947                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
948                                 f = 1 - f;
949                         }
950                         else
951                         {
952                                 f = 1;
953                         }
954                         wcross_name_alpha_goal_prev = f;
955
956                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
957                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
958
959                         if(autocvar_crosshair_dot)
960                         {
961                                 vector wcross_color_old;
962                                 wcross_color_old = wcross_color;
963
964                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
965                                         wcross_color = stov(autocvar_crosshair_dot_color);
966
967                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
968                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
969                                 wcross_color = wcross_color_old;
970                         }
971                 }
972         }
973         else
974         {
975                 wcross_scale_prev = 0;
976                 wcross_alpha_prev = 0;
977                 wcross_scale_goal_prev = 0;
978                 wcross_alpha_goal_prev = 0;
979                 wcross_changedonetime = 0;
980                 if(wcross_name_goal_prev)
981                         strunzone(wcross_name_goal_prev);
982                 wcross_name_goal_prev = string_null;
983                 if(wcross_name_goal_prev_prev)
984                         strunzone(wcross_name_goal_prev_prev);
985                 wcross_name_goal_prev_prev = string_null;
986                 wcross_name_changestarttime = 0;
987                 wcross_name_changedonetime = 0;
988                 wcross_name_alpha_goal_prev = 0;
989                 wcross_name_alpha_goal_prev_prev = 0;
990                 wcross_resolution_goal_prev = 0;
991                 wcross_resolution_goal_prev_prev = 0;
992         }
993 }
994
995 const int BUTTON_3 = 4;
996 const int BUTTON_4 = 8;
997 float cl_notice_run();
998 float prev_myteam;
999 void CSQC_UpdateView(float w, float h)
1000 {
1001         entity e;
1002         float fov;
1003         float f;
1004         int i;
1005         vector vf_size, vf_min;
1006         float a;
1007
1008         execute_next_frame();
1009
1010         ++framecount;
1011
1012         hud = getstati(STAT_HUD);
1013
1014         if(autocvar__hud_showbinds_reload) // menu can set this one
1015         {
1016                 db_close(binddb);
1017                 binddb = db_create();
1018                 cvar_set("_hud_showbinds_reload", "0");
1019         }
1020
1021         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1022                 view_quality = getproperty(VF_MINFPS_QUALITY);
1023         else
1024                 view_quality = 1;
1025
1026         button_attack2 = (input_buttons & BUTTON_3);
1027         button_zoom = (input_buttons & BUTTON_4);
1028
1029 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1030         float checkfailv = (func)(parm);                                                                                \
1031         if (checkfailv != (val)) {                                                                                      \
1032                 if (!checkfail[(flag)])                                                                                     \
1033                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1034                 checkfail[(flag)] = 1;                                                                                      \
1035         }                                                                                                               \
1036 } while(0)
1037         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1038         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1039         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1040         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1041         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1042         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1043         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1044
1045         vf_size = getpropertyvec(VF_SIZE);
1046         vf_min = getpropertyvec(VF_MIN);
1047         vid_width = vf_size.x;
1048         vid_height = vf_size.y;
1049
1050         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1051         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1052
1053         WaypointSprite_Load();
1054
1055         CSQCPlayer_SetCamera();
1056
1057         myteam = GetPlayerColor(player_localentnum - 1);
1058
1059         if(myteam != prev_myteam)
1060         {
1061                 myteamcolors = colormapPaletteColor(myteam, 1);
1062                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1063                         hud_panel[i].update_time = time;
1064                 prev_myteam = myteam;
1065         }
1066
1067         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1068
1069         float is_dead = (getstati(STAT_HEALTH) <= 0);
1070
1071         // FIXME do we need this hack?
1072         if(isdemo())
1073         {
1074                 // in demos, input_buttons do not work
1075                 button_zoom = (autocvar__togglezoom == "-");
1076         }
1077         else if(button_zoom
1078                 && autocvar_cl_unpress_zoom_on_death
1079                 && (spectatee_status >= 0)
1080                 && (is_dead || intermission))
1081         {
1082                 // no zoom while dead or in intermission please
1083                 localcmd("-zoom\n");
1084                 button_zoom = false;
1085         }
1086
1087         // event chase camera
1088         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1089         {
1090                 if(WantEventchase())
1091                 {
1092                         eventchase_running = true;
1093
1094                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1095                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1096
1097                         // detect maximum viewoffset and use it
1098                         if(autocvar_cl_eventchase_viewoffset)
1099                         {
1100                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1101                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1102                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1103                         }
1104
1105                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1106                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1107                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1108                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1109
1110                         // make the camera smooth back
1111                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1112                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1113                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1114                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1115
1116                         makevectors(view_angles);
1117
1118                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1119                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1120
1121                         // If the boxtrace fails, revert back to line tracing.
1122                         if(trace_startsolid)
1123                         {
1124                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1125                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1126                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1127                         }
1128                         else { setproperty(VF_ORIGIN, trace_endpos); }
1129
1130                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1131                 }
1132                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1133                 {
1134                         eventchase_running = false;
1135                         cvar_set("chase_active", "0");
1136                         eventchase_current_distance = 0; // start from 0 next time
1137                 }
1138         }
1139         // workaround for camera stuck between player's legs when using chase_active 1
1140         // because the engine stops updating the chase_active camera when the game ends
1141         else if(intermission)
1142         {
1143                 cvar_settemp("chase_active", "-1");
1144                 eventchase_current_distance = 0;
1145         }
1146
1147         // do lockview after event chase camera so that it still applies whenever necessary.
1148         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1149         {
1150                 setproperty(VF_ORIGIN, freeze_org);
1151                 setproperty(VF_ANGLES, freeze_ang);
1152         }
1153         else
1154         {
1155                 freeze_org = getpropertyvec(VF_ORIGIN);
1156                 freeze_ang = getpropertyvec(VF_ANGLES);
1157         }
1158
1159         WarpZone_FixView();
1160         //WarpZone_FixPMove();
1161
1162         vector ov_org = '0 0 0';
1163         vector ov_mid = '0 0 0';
1164         vector ov_worldmin = '0 0 0';
1165         vector ov_worldmax = '0 0 0';
1166         if(autocvar_cl_orthoview)
1167         {
1168                 ov_worldmin = mi_picmin;
1169                 ov_worldmax = mi_picmax;
1170
1171                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1172                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1173                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1174
1175                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1176                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1177
1178                 float ov_nearest = vlen(ov_org - vec3(
1179                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1180                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1181                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1182                 ));
1183
1184                 float ov_furthest = 0;
1185                 float dist = 0;
1186
1187                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1188                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1189                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1190                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1191                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1192                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1193                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1194                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1195
1196                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1197                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1198                 cvar_settemp("r_farclip_world", "0");
1199                 cvar_settemp("r_novis", "1");
1200                 cvar_settemp("r_useportalculling", "0");
1201                 cvar_settemp("r_useinfinitefarclip", "0");
1202
1203                 setproperty(VF_ORIGIN, ov_org);
1204                 setproperty(VF_ANGLES, '90 0 0');
1205
1206                 #if 0
1207                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1208                         vtos(ov_org),
1209                         vtos(getpropertyvec(VF_ANGLES)),
1210                         ov_distance,
1211                         ov_nearest,
1212                         ov_furthest);
1213                 #endif
1214         }
1215
1216         // Render the Scene
1217         view_origin = getpropertyvec(VF_ORIGIN);
1218         view_angles = getpropertyvec(VF_ANGLES);
1219         makevectors(view_angles);
1220         view_forward = v_forward;
1221         view_right = v_right;
1222         view_up = v_up;
1223
1224 #ifdef BLURTEST
1225         if(time > blurtest_time0 && time < blurtest_time1)
1226         {
1227                 float r, t;
1228
1229                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1230                 r = t * blurtest_radius;
1231                 f = 1 / pow(t, blurtest_power) - 1;
1232
1233                 cvar_set("r_glsl_postprocess", "1");
1234                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1235         }
1236         else
1237         {
1238                 cvar_set("r_glsl_postprocess", "0");
1239                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1240         }
1241 #endif
1242
1243         TargetMusic_Advance();
1244         Fog_Force();
1245
1246         if(drawtime == 0)
1247                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1248         else
1249                 drawframetime = bound(0.000001, time - drawtime, 1);
1250         drawtime = time;
1251
1252         // watch for gametype changes here...
1253         // in ParseStuffCMD the cmd isn't executed yet :/
1254         // might even be better to add the gametype to TE_CSQC_INIT...?
1255         if(!postinit)
1256                 PostInit();
1257
1258         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1259         {
1260                 if(calledhooks & HOOK_START)
1261                 {
1262                         localcmd("\ncl_hook_gameend\n");
1263                         calledhooks |= HOOK_END;
1264                 }
1265         }
1266
1267         Announcer();
1268
1269         fov = autocvar_fov;
1270         if(fov <= 59.5)
1271         {
1272                 if(!zoomscript_caught)
1273                 {
1274                         localcmd("+button9\n");
1275                         zoomscript_caught = 1;
1276                 }
1277         }
1278         else
1279         {
1280                 if(zoomscript_caught)
1281                 {
1282                         localcmd("-button9\n");
1283                         zoomscript_caught = 0;
1284                 }
1285         }
1286
1287         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1288
1289         // next WANTED weapon (for HUD)
1290         switchweapon = getstati(STAT_SWITCHWEAPON);
1291
1292         // currently switching-to weapon (for crosshair)
1293         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1294
1295         // actually active weapon (for zoom)
1296         activeweapon = getstati(STAT_ACTIVEWEAPON);
1297
1298         f = (serverflags & SERVERFLAG_TEAMPLAY);
1299         if(f != teamplay)
1300         {
1301                 teamplay = f;
1302                 HUD_InitScores();
1303         }
1304
1305         if(last_switchweapon != switchweapon)
1306         {
1307                 weapontime = time;
1308                 last_switchweapon = switchweapon;
1309                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1310                 {
1311                         localcmd("-zoom\n");
1312                         button_zoom = false;
1313                 }
1314                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1315                 {
1316                         localcmd("-fire\n");
1317                         localcmd("-fire2\n");
1318                         button_attack2 = false;
1319                 }
1320         }
1321         if(last_activeweapon != activeweapon)
1322         {
1323                 last_activeweapon = activeweapon;
1324
1325                 e = get_weaponinfo(activeweapon);
1326                 if(e.netname != "")
1327                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1328                 else
1329                         localcmd("\ncl_hook_activeweapon none\n");
1330         }
1331
1332         // ALWAYS Clear Current Scene First
1333         clearscene();
1334
1335         setproperty(VF_ORIGIN, view_origin);
1336         setproperty(VF_ANGLES, view_angles);
1337
1338         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1339         setproperty(VF_SIZE, vf_size);
1340         setproperty(VF_MIN, vf_min);
1341
1342         // Assign Standard Viewflags
1343         // Draw the World (and sky)
1344         setproperty(VF_DRAWWORLD, 1);
1345
1346         // Set the console size vars
1347         vid_conwidth = autocvar_vid_conwidth;
1348         vid_conheight = autocvar_vid_conheight;
1349         vid_pixelheight = autocvar_vid_pixelheight;
1350
1351         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1352         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1353
1354         // Camera for demo playback
1355         if(camera_active)
1356         {
1357                 if(autocvar_camera_enable)
1358                         CSQC_Demo_Camera();
1359                 else
1360                 {
1361                         cvar_set("chase_active", ftos(chase_active_backup));
1362                         cvar_set("cl_demo_mousegrab", "0");
1363                         camera_active = false;
1364                 }
1365         }
1366         else
1367         {
1368 #ifdef CAMERATEST
1369                 if(autocvar_camera_enable)
1370 #else
1371                 if(autocvar_camera_enable && isdemo())
1372 #endif
1373                 {
1374                         // Enable required Darkplaces cvars
1375                         chase_active_backup = autocvar_chase_active;
1376                         cvar_set("chase_active", "2");
1377                         cvar_set("cl_demo_mousegrab", "1");
1378                         camera_active = true;
1379                         camera_mode = false;
1380                 }
1381         }
1382
1383         // Draw the Crosshair
1384         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1385
1386         // Draw the Engine Status Bar (the default Quake HUD)
1387         setproperty(VF_DRAWENGINESBAR, 0);
1388
1389         // Update the mouse position
1390         /*
1391            mousepos_x = vid_conwidth;
1392            mousepos_y = vid_conheight;
1393            mousepos = mousepos*0.5 + getmousepos();
1394          */
1395
1396         e = self;
1397         for(self = world; (self = nextent(self)); )
1398                 if(self.draw)
1399                         self.draw();
1400         self = e;
1401
1402         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1403         renderscene();
1404
1405         // now switch to 2D drawing mode by calling a 2D drawing function
1406         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1407         // next R_RenderScene call
1408         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1409
1410         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1411         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1412         {
1413                 // apply night vision effect
1414                 vector tc_00, tc_01, tc_10, tc_11;
1415                 vector rgb = '0 0 0';
1416
1417                 if(!nightvision_noise)
1418                 {
1419                         nightvision_noise = spawn();
1420                         nightvision_noise.classname = "nightvision_noise";
1421                 }
1422                 if(!nightvision_noise2)
1423                 {
1424                         nightvision_noise2 = spawn();
1425                         nightvision_noise2.classname = "nightvision_noise2";
1426                 }
1427
1428                 // color tint in yellow
1429                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1430
1431                 // draw BG
1432                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1433                 rgb = '1 1 1';
1434                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1435                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1436                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1437                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1438                 tc_11 = tc_01 + tc_10 - tc_00;
1439                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1440                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1441                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1442                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1443                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1444                 R_EndPolygon();
1445
1446                 // draw FG
1447                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1448                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1449                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1450                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1451                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1452                 tc_11 = tc_01 + tc_10 - tc_00;
1453                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1454                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1455                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1456                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1457                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1458                 R_EndPolygon();
1459         }
1460
1461         if(autocvar_cl_reticle)
1462         {
1463                 // Draw the aiming reticle for weapons that use it
1464                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1465                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1466                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1467                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1468                 {
1469                         // no zoom reticle while dead
1470                         reticle_type = 0;
1471                 }
1472                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1473                 {
1474                         if(reticle_image != "") { reticle_type = 2; }
1475                         else { reticle_type = 0; }
1476                 }
1477                 else if(button_zoom || zoomscript_caught)
1478                 {
1479                         // normal zoom
1480                         reticle_type = 1;
1481                 }
1482
1483                 if(reticle_type)
1484                 {
1485                         if(autocvar_cl_reticle_stretch)
1486                         {
1487                                 reticle_size.x = vid_conwidth;
1488                                 reticle_size.y = vid_conheight;
1489                                 reticle_pos.x = 0;
1490                                 reticle_pos.y = 0;
1491                         }
1492                         else
1493                         {
1494                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1495                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1496                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1497                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1498                         }
1499
1500                         if(zoomscript_caught)
1501                                 f = 1;
1502                         else
1503                                 f = current_zoomfraction;
1504
1505                         if(f)
1506                         {
1507                                 switch(reticle_type)
1508                                 {
1509                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1510                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1511                                 }
1512                         }
1513                 }
1514         }
1515         else
1516         {
1517                 if(reticle_type != 0) { reticle_type = 0; }
1518         }
1519
1520
1521         // improved polyblend
1522         if(autocvar_hud_contents)
1523         {
1524                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1525                 vector liquidcolor;
1526
1527                 switch(pointcontents(view_origin))
1528                 {
1529                         case CONTENT_WATER:
1530                                 liquidalpha = autocvar_hud_contents_water_alpha;
1531                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1532                                 incontent = 1;
1533                                 break;
1534
1535                         case CONTENT_LAVA:
1536                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1537                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1538                                 incontent = 1;
1539                                 break;
1540
1541                         case CONTENT_SLIME:
1542                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1543                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1544                                 incontent = 1;
1545                                 break;
1546
1547                         default:
1548                                 liquidalpha = 0;
1549                                 liquidcolor = '0 0 0';
1550                                 incontent = 0;
1551                                 break;
1552                 }
1553
1554                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1555                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1556                         contentfadetime = autocvar_hud_contents_fadeintime;
1557                         liquidalpha_prev = liquidalpha;
1558                         liquidcolor_prev = liquidcolor;
1559                 }
1560                 else
1561                         contentfadetime = autocvar_hud_contents_fadeouttime;
1562
1563                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1564                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1565
1566                 if(contentavgalpha)
1567                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1568
1569                 if(autocvar_hud_postprocessing)
1570                 {
1571                         if(autocvar_hud_contents_blur && contentavgalpha)
1572                         {
1573                                 content_blurpostprocess.x = 1;
1574                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1575                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1576                         }
1577                         else
1578                         {
1579                                 content_blurpostprocess.x = 0;
1580                                 content_blurpostprocess.y = 0;
1581                                 content_blurpostprocess.z = 0;
1582                         }
1583                 }
1584         }
1585
1586         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1587         {
1588                 splash_size.x = max(vid_conwidth, vid_conheight);
1589                 splash_size.y = max(vid_conwidth, vid_conheight);
1590                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1591                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1592
1593                 float myhealth_flash_temp;
1594                 myhealth = getstati(STAT_HEALTH);
1595
1596                 // fade out
1597                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1598                 // add new damage
1599                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1600
1601                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1602                 pain_threshold = autocvar_hud_damage_pain_threshold;
1603                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1604                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1605
1606                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1607                 {
1608                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1609                 }
1610
1611                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1612
1613                 if(myhealth_prev < 1)
1614                 {
1615                         if(myhealth >= 1)
1616                         {
1617                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1618                                 myhealth_flash_temp = 0;
1619                         }
1620                         else
1621                         {
1622                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1623                         }
1624                 }
1625
1626                 if(spectatee_status == -1 || intermission)
1627                 {
1628                         myhealth_flash = 0; // observing, or match ended
1629                         myhealth_flash_temp = 0;
1630                 }
1631
1632                 myhealth_prev = myhealth;
1633
1634                 // IDEA: change damage color/picture based on player model for robot/alien species?
1635                 // pro: matches model better
1636                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1637                 // maybe different reddish pics?
1638                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1639                 {
1640                         if(autocvar_cl_gentle_damage == 2)
1641                         {
1642                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1643                                 {
1644                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1645                                 }
1646                         }
1647                         else
1648                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1649
1650                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1651                 }
1652                 else
1653                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1654
1655                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1656                 {
1657                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1658                         {
1659                                 damage_blurpostprocess.x = 1;
1660                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1661                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1662                         }
1663                         else
1664                         {
1665                                 damage_blurpostprocess.x = 0;
1666                                 damage_blurpostprocess.y = 0;
1667                                 damage_blurpostprocess.z = 0;
1668                         }
1669                 }
1670         }
1671
1672         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1673         float e2 = (autocvar_hud_powerup != 0);
1674         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1675         {
1676                 // enable or disable rendering types if they are used or not
1677                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1678                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1679
1680                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1681                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1682                 {
1683                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1684                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1685                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1686                         {
1687                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1688                                 old_blurradius = blurradius;
1689                                 old_bluralpha = bluralpha;
1690                         }
1691                 }
1692                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1693                 {
1694                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1695                         old_blurradius = 0;
1696                         old_bluralpha = 0;
1697                 }
1698
1699                 // edge detection postprocess handling done second (used by hud_powerup)
1700                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1701                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1702                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1703
1704                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1705
1706                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1707                 {
1708                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1709                         {
1710                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1711                                 old_sharpen_intensity = sharpen_intensity;
1712                         }
1713                 }
1714                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1715                 {
1716                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1717                         old_sharpen_intensity = 0;
1718                 }
1719
1720                 if(cvar("r_glsl_postprocess") == 0)
1721                         cvar_set("r_glsl_postprocess", "2");
1722         }
1723         else if(cvar("r_glsl_postprocess") == 2)
1724                 cvar_set("r_glsl_postprocess", "0");
1725
1726         if(menu_visible)
1727                 menu_show();
1728
1729         /*if(gametype == MAPINFO_TYPE_CTF)
1730           {
1731           ctf_view();
1732           } else */
1733
1734         // draw 2D entities
1735         e = self;
1736         for(self = world; (self = nextent(self)); )
1737                 if(self.draw2d)
1738                         self.draw2d();
1739         self = e;
1740         Draw_ShowNames_All();
1741
1742         scoreboard_active = HUD_WouldDrawScoreboard();
1743
1744         UpdateDamage();
1745         UpdateCrosshair();
1746         UpdateHitsound();
1747
1748         if(NextFrameCommand)
1749         {
1750                 localcmd("\n", NextFrameCommand, "\n");
1751                 NextFrameCommand = string_null;
1752         }
1753
1754         // we must do this check AFTER a frame was rendered, or it won't work
1755         if(cs_project_is_b0rked == 0)
1756         {
1757                 string w0, h0;
1758                 w0 = ftos(autocvar_vid_conwidth);
1759                 h0 = ftos(autocvar_vid_conheight);
1760                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1761                 //setproperty(VF_FOV, '90 90 0');
1762                 setproperty(VF_ORIGIN, '0 0 0');
1763                 setproperty(VF_ANGLES, '0 0 0');
1764                 setproperty(VF_PERSPECTIVE, 1);
1765                 makevectors('0 0 0');
1766                 vector v1, v2;
1767                 cvar_set("vid_conwidth", "800");
1768                 cvar_set("vid_conheight", "600");
1769                 v1 = cs_project(v_forward);
1770                 cvar_set("vid_conwidth", "640");
1771                 cvar_set("vid_conheight", "480");
1772                 v2 = cs_project(v_forward);
1773                 if(v1 == v2)
1774                         cs_project_is_b0rked = 1;
1775                 else
1776                         cs_project_is_b0rked = -1;
1777                 cvar_set("vid_conwidth", w0);
1778                 cvar_set("vid_conheight", h0);
1779         }
1780
1781         if(autocvar__hud_configure)
1782                 HUD_Panel_Mouse();
1783
1784     if(hud && !intermission)
1785     if(hud == HUD_BUMBLEBEE_GUN)
1786         CSQC_BUMBLE_GUN_HUD();
1787     else
1788                 VEH_ACTION(hud, VR_HUD);
1789
1790         cl_notice_run();
1791
1792         // let's reset the view back to normal for the end
1793         setproperty(VF_MIN, '0 0 0');
1794         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1795 }
1796
1797
1798 void CSQC_common_hud(void)
1799 {
1800         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1801                 Accuracy_LoadLevels();
1802
1803         HUD_Main(); // always run these functions for alpha checks
1804         HUD_DrawScoreboard();
1805
1806         if (scoreboard_active) // scoreboard/accuracy
1807                 HUD_Reset();
1808         else if (intermission == 2) // map voting screen
1809         {
1810                 MapVote_Draw();
1811                 HUD_Reset();
1812         }
1813 }
1814
1815
1816 // following vectors must be global to allow seamless switching between camera modes
1817 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1818 void CSQC_Demo_Camera()
1819 {
1820         float speed, attenuation, dimensions;
1821         vector tmp, delta;
1822
1823         if( autocvar_camera_reset || !camera_mode )
1824         {
1825                 camera_offset = '0 0 0';
1826                 current_angles = '0 0 0';
1827                 camera_direction = '0 0 0';
1828                 camera_offset.z += 30;
1829                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1830                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1831                 current_origin = view_origin;
1832                 current_camera_offset  = camera_offset;
1833                 cvar_set("camera_reset", "0");
1834                 camera_mode = CAMERA_CHASE;
1835         }
1836
1837         // Camera angles
1838         if( camera_roll )
1839                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1840
1841         if(autocvar_camera_look_player)
1842         {
1843                 vector dir;
1844                 float n;
1845
1846                 dir = normalize(view_origin - current_position);
1847                 n = mouse_angles.z;
1848                 mouse_angles = vectoangles(dir);
1849                 mouse_angles.x = mouse_angles.x * -1;
1850                 mouse_angles.z = n;
1851         }
1852         else
1853         {
1854                 tmp = getmousepos() * 0.1;
1855                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1856                 {
1857                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1858                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1859                 }
1860         }
1861
1862         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1863         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1864         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1865         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1866
1867         // Fix difference when angles don't have the same sign
1868         delta = '0 0 0';
1869         if(mouse_angles.y < -60 && current_angles.y > 60)
1870                 delta = '0 360 0';
1871         if(mouse_angles.y > 60 && current_angles.y < -60)
1872                 delta = '0 -360 0';
1873
1874         if(autocvar_camera_look_player)
1875                 attenuation = autocvar_camera_look_attenuation;
1876         else
1877                 attenuation = autocvar_camera_speed_attenuation;
1878
1879         attenuation = 1 / max(1, attenuation);
1880         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1881
1882         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1883         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1884         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1885         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1886
1887         // Camera position
1888         tmp = '0 0 0';
1889         dimensions = 0;
1890
1891         if( camera_direction.x )
1892         {
1893                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1894                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1895                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1896                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1897                 ++dimensions;
1898         }
1899
1900         if( camera_direction.y )
1901         {
1902                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1903                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1904                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1905                 ++dimensions;
1906         }
1907
1908         if( camera_direction.z )
1909         {
1910                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1911                 ++dimensions;
1912         }
1913
1914         if(autocvar_camera_free)
1915                 speed = autocvar_camera_speed_free;
1916         else
1917                 speed = autocvar_camera_speed_chase;
1918
1919         if(dimensions)
1920         {
1921                 speed = speed * sqrt(1 / dimensions);
1922                 camera_offset += tmp * speed;
1923         }
1924
1925         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1926
1927         // Camera modes
1928         if( autocvar_camera_free )
1929         {
1930                 if ( camera_mode == CAMERA_CHASE )
1931                 {
1932                         current_camera_offset = current_origin + current_camera_offset;
1933                         camera_offset = current_origin + camera_offset;
1934                 }
1935
1936                 camera_mode = CAMERA_FREE;
1937                 current_position = current_camera_offset;
1938         }
1939         else
1940         {
1941                 if ( camera_mode == CAMERA_FREE )
1942                 {
1943                         current_origin = view_origin;
1944                         camera_offset = camera_offset - current_origin;
1945                         current_camera_offset = current_camera_offset - current_origin;
1946                 }
1947
1948                 camera_mode = CAMERA_CHASE;
1949
1950                 if(autocvar_camera_chase_smoothly)
1951                         current_origin += (view_origin - current_origin) * attenuation;
1952                 else
1953                         current_origin = view_origin;
1954
1955                 current_position = current_origin + current_camera_offset;
1956         }
1957
1958         setproperty(VF_ANGLES, current_angles);
1959         setproperty(VF_ORIGIN, current_position);
1960 }