qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 1000;
  44 float autocvar_cl_followmodel_highpass1 = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47
  48 float autocvar_cl_leanmodel;
  49 float autocvar_cl_leanmodel_speed = 0.3;
  50 float autocvar_cl_leanmodel_limit = 1000;
  51 float autocvar_cl_leanmodel_highpass1 = 0.2;
  52 float autocvar_cl_leanmodel_highpass = 0.2;
  53 float autocvar_cl_leanmodel_lowpass = 0.05;
  54
  55 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  56 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  57 { \
  58         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  59 } MACRO_END
  60
  61 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  62 { \
  63         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  64         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  65 } MACRO_END
  66
  67 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __f = 0; lowpass(value, frac, ref_store, __f); \
  70         ret = (value) - __f; \
  71 } MACRO_END
  72
  73 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  80 { \
  81         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  82         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  83 } MACRO_END
  84
  85 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         highpass(value.x, frac, ref_store.x, ref_out.x); \
  88         highpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  94         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 100         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 101         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 102 } MACRO_END
 103
 104 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass(value.x, frac, ref_store.x, ref_out.x); \
 107         highpass(value.y, frac, ref_store.y, ref_out.y); \
 108         highpass(value.z, frac, ref_store.z, ref_out.z); \
 109 } MACRO_END
 110
 111 #define highpass3_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 112 { \
 113         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 114         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 115         highpass_limited(value.z, frac, limit, ref_store.z, ref_out.z); \
 116 } MACRO_END
 117
 118 void viewmodel_animate(entity this)
 119 {
 120         static float prevtime;
 121         float frametime = (time - prevtime);
 122         prevtime = time;
 123
 124         if (autocvar_chase_active) return;
 125         if (STAT(HEALTH) <= 0) return;
 126
 127         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 128
 129         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 130         static bool oldonground;
 131         static float hitgroundtime;
 132         static float lastongroundtime;
 133         if (clonground)
 134         {
 135                 float f = time; // cl.movecmd[0].time
 136                 if (!oldonground)
 137                         hitgroundtime = f;
 138                 lastongroundtime = f;
 139         }
 140         oldonground = clonground;
 141
 142         vector gunorg = '0 0 0', gunangles = '0 0 0';
 143         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 144
 145         bool teleported = view.csqcmodel_teleported;
 146
 147         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 148         if (teleported)
 149         {
 150                 // try to fix the first highpass; result is NOT
 151                 // perfect! TODO find a better fix
 152                 gunangles_prev = view_angles;
 153                 gunorg_prev = view_origin;
 154         }
 155
 156         float frac;
 157         static vector gunorg_highpass = '0 0 0';
 158
 159         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 160         gunorg_highpass += gunorg_prev;
 161         frac = avg_factor(autocvar_cl_followmodel_highpass1);
 162         highpass3_limited(view_origin, frac, autocvar_cl_followmodel_limit, gunorg_highpass, gunorg);
 163         gunorg_prev = view_origin;
 164         gunorg_highpass -= gunorg_prev;
 165
 166         static vector gunangles_highpass = '0 0 0';
 167
 168         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 169         gunangles_highpass += gunangles_prev;
 170         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 171         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 172         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 173         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 174         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 175         gunangles_prev = view_angles;
 176         gunangles_highpass -= gunangles_prev;
 177
 178         // 3. calculate the RAW adjustment vectors
 179         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_speed : 0);
 180         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_speed : 0);
 181         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_speed : 0);
 182
 183         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_speed : 0);
 184         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_speed : 0);
 185         ROLL(gunangles) = 0;
 186
 187         static vector gunorg_adjustment_highpass;
 188         static vector gunorg_adjustment_lowpass;
 189         static vector gunangles_adjustment_highpass;
 190         static vector gunangles_adjustment_lowpass;
 191
 192         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 193         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 194         frac = avg_factor(autocvar_cl_followmodel_highpass);
 195         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 196         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 197         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 206
 207         // vertical view bobbing code
 208         // TODO: cl_bob
 209
 210         // horizontal view bobbing code
 211         // TODO: cl_bob2
 212
 213         // fall bobbing code
 214         // causes the view to swing down and back up when touching the ground
 215         // TODO: cl_bobfall
 216
 217         // gun model bobbing code
 218         if (autocvar_cl_bobmodel)
 219         {
 220                 // calculate for swinging gun model
 221                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 222                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 223                 // for the most part, but for some reason when you go through a message trigger or
 224                 // pick up an item or anything like that it will momentarily jolt the gun.
 225                 vector forward, right = '0 0 0', up = '0 0 0';
 226                 float bspeed;
 227                 float t = 1;
 228                 float s = time * autocvar_cl_bobmodel_speed;
 229                 if (clonground)
 230                 {
 231                         if (time - hitgroundtime < 0.2)
 232                         {
 233                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 234                                 t = time - hitgroundtime;
 235                                 t = bound(0, t, 0.2);
 236                                 t *= 5;
 237                         }
 238                 }
 239                 else
 240                 {
 241                         // recently left the ground, slow the bob down over the next 0.2 seconds
 242                         t = time - lastongroundtime;
 243                         t = 0.2 - bound(0, t, 0.2);
 244                         t *= 5;
 245                 }
 246                 bspeed = xyspeed * 0.01;
 247                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 248                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 249                 gunorg += bobr * right;
 250                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 251                 gunorg += bobu * up;
 252         }
 253         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 254         v.z = gunorg.z;
 255         this.origin += v;
 256         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 257         this.angles += gunangles;
 258 }
 259
 260 .vector viewmodel_origin, viewmodel_angles;
 261 .float weapon_nextthink;
 262 .float weapon_eta_last;
 263 .float weapon_switchdelay;
 264
 265 void viewmodel_draw(entity this)
 266 {
 267         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 268         float a = this.alpha;
 269         static bool wasinvehicle;
 270         bool invehicle = player_localentnum > maxclients;
 271         if (invehicle) a = -1;
 272         else if (wasinvehicle) a = 1;
 273         wasinvehicle = invehicle;
 274         Weapon wep = activeweapon;
 275         int c = stof(getplayerkeyvalue(current_player, "colors"));
 276         vector g = weaponentity_glowmod(wep, c);
 277         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 278         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 279                 | EF_NODEPTHTEST)
 280                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 281         for (entity e = this; e; e = e.weaponchild)
 282         {
 283                 e.drawmask = mask;
 284                 e.alpha = a;
 285                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 286                 e.glowmod = g;
 287                 e.csqcmodel_effects = fx;
 288                 CSQCModel_Effects_Apply(e);
 289         }
 290         {
 291                 static string name_last;
 292                 string name = wep.mdl;
 293                 if (name != name_last)
 294                 {
 295                         name_last = name;
 296                         CL_WeaponEntity_SetModel(this, name);
 297                         this.viewmodel_origin = this.origin;
 298                         this.viewmodel_angles = this.angles;
 299                 }
 300                 anim_update(this);
 301                 if (!this.animstate_override)
 302                         anim_set(this, this.anim_idle, true, false, false);
 303         }
 304         float f = 0; // 0..1; 0: fully active
 305         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 306         if (eta <= 0) f = this.weapon_eta_last;
 307         else switch (this.state)
 308         {
 309                 case WS_RAISE:
 310                 {
 311                         f = eta / max(eta, this.weapon_switchdelay);
 312                         break;
 313                 }
 314                 case WS_DROP:
 315                 {
 316                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 317                         break;
 318                 }
 319                 case WS_CLEAR:
 320                 {
 321                         f = 1;
 322                         break;
 323                 }
 324         }
 325         this.weapon_eta_last = f;
 326         this.origin = this.viewmodel_origin;
 327         this.angles = this.viewmodel_angles;
 328         this.angles_x = (-90 * f * f);
 329         viewmodel_animate(this);
 330         setorigin(this, this.origin);
 331 }
 332
 333 entity viewmodel;
 334 STATIC_INIT(viewmodel) {
 335     viewmodel = new(viewmodel);
 336     make_pure(viewmodel);
 337         viewmodel.draw = viewmodel_draw;
 338 }
 339
 340 entity porto;
 341 vector polyline[16];
 342 void Porto_Draw(entity this)
 343 {
 344         vector p, dir, ang, q, nextdir;
 345         float portal_number, portal1_idx;
 346
 347         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 348                 return;
 349         if(WEP_CVAR(porto, secondary))
 350                 return;
 351         if(intermission == 1)
 352                 return;
 353         if(intermission == 2)
 354                 return;
 355         if (STAT(HEALTH) <= 0)
 356                 return;
 357
 358         dir = view_forward;
 359
 360         if(angles_held_status)
 361         {
 362                 makevectors(angles_held);
 363                 dir = v_forward;
 364         }
 365
 366         p = view_origin;
 367
 368         polyline[0] = p;
 369         int idx = 1;
 370         portal_number = 0;
 371         nextdir = dir;
 372
 373         for (;;)
 374         {
 375                 dir = nextdir;
 376                 traceline(p, p + 65536 * dir, true, porto);
 377                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 378                         return;
 379                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 380                 p = trace_endpos;
 381                 polyline[idx] = p;
 382                 ++idx;
 383                 if(idx >= 16)
 384                         return;
 385                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 386                         continue;
 387                 ++portal_number;
 388                 ang = vectoangles2(trace_plane_normal, dir);
 389                 ang.x = -ang.x;
 390                 makevectors(ang);
 391                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 392                         return;
 393                 if(portal_number == 1)
 394                 {
 395                         portal1_idx = idx;
 396                         if(portal_number >= 2)
 397                                 break;
 398                 }
 399         }
 400
 401         while(idx >= 2)
 402         {
 403                 p = polyline[idx-2];
 404                 q = polyline[idx-1];
 405                 if(idx == 2)
 406                         p = p - view_up * 16;
 407                 if(idx-1 >= portal1_idx)
 408                 {
 409                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 410                 }
 411                 else
 412                 {
 413                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 414                 }
 415                 --idx;
 416         }
 417 }
 418
 419 void Porto_Init()
 420 {
 421         porto = new(porto);
 422         make_pure(porto);
 423         porto.draw = Porto_Draw;
 424         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 425 }
 426
 427 float drawtime;
 428 float avgspeed;
 429 vector GetCurrentFov(float fov)
 430 {
 431         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 432         float velocityzoom, curspeed;
 433         vector v;
 434
 435         zoomsensitivity = autocvar_cl_zoomsensitivity;
 436         zoomfactor = autocvar_cl_zoomfactor;
 437         if(zoomfactor < 1 || zoomfactor > 30)
 438                 zoomfactor = 2.5;
 439         zoomspeed = autocvar_cl_zoomspeed;
 440         if(zoomspeed >= 0)
 441         if(zoomspeed < 0.5 || zoomspeed > 16)
 442                         zoomspeed = 3.5;
 443
 444         zoomdir = button_zoom;
 445         if(hud == HUD_NORMAL)
 446         if(switchweapon == activeweapon)
 447         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 448                 zoomdir += button_attack2;
 449         if(spectatee_status > 0 || isdemo())
 450         {
 451                 if(spectatorbutton_zoom)
 452                 {
 453                         if(zoomdir)
 454                                 zoomdir = 0;
 455                         else
 456                                 zoomdir = 1;
 457                 }
 458                 // fteqcc failed twice here already, don't optimize this
 459         }
 460
 461         if(zoomdir) { zoomin_effect = 0; }
 462
 463         if(camera_active)
 464         {
 465                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 466         }
 467         else if(autocvar_cl_spawnzoom && zoomin_effect)
 468         {
 469                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 470
 471                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 472                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 473                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 474         }
 475         else
 476         {
 477                 if(zoomspeed < 0) // instant zoom
 478                 {
 479                         if(zoomdir)
 480                                 current_viewzoom = 1 / zoomfactor;
 481                         else
 482                                 current_viewzoom = 1;
 483                 }
 484                 else
 485                 {
 486                         if(zoomdir)
 487                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 488                         else
 489                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 490                 }
 491         }
 492
 493         if(almost_equals(current_viewzoom, 1))
 494                 current_zoomfraction = 0;
 495         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 496                 current_zoomfraction = 1;
 497         else
 498                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 499
 500         if(zoomsensitivity < 1)
 501                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 502         else
 503                 setsensitivityscale(1);
 504
 505         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 506         {
 507                 if(intermission) { curspeed = 0; }
 508                 else
 509                 {
 510
 511                         makevectors(view_angles);
 512                         v = pmove_vel;
 513                         if(csqcplayer)
 514                                 v = csqcplayer.velocity;
 515
 516                         switch(autocvar_cl_velocityzoom_type)
 517                         {
 518                                 case 3: curspeed = max(0, v_forward * v); break;
 519                                 case 2: curspeed = (v_forward * v); break;
 520                                 case 1: default: curspeed = vlen(v); break;
 521                         }
 522                 }
 523
 524                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 525                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 526                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 527
 528                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 529         }
 530         else
 531                 velocityzoom = 1;
 532
 533         float frustumx, frustumy, fovx, fovy;
 534         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 535         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 536         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 537         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 538
 539         return '1 0 0' * fovx + '0 1 0' * fovy;
 540 }
 541
 542 vector GetViewLocationFOV(float fov)
 543 {
 544         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 545         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 546         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 547         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 548         return '1 0 0' * fovx + '0 1 0' * fovy;
 549 }
 550
 551 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 552 {
 553         float fovx, fovy;
 554         float width = (ov_worldmax.x - ov_worldmin.x);
 555         float height = (ov_worldmax.y - ov_worldmin.y);
 556         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 557         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 558         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 559         return '1 0 0' * fovx + '0 1 0' * fovy;
 560 }
 561
 562 // this function must match W_SetupShot!
 563 float zoomscript_caught;
 564
 565 vector wcross_origin;
 566 float wcross_scale_prev, wcross_alpha_prev;
 567 vector wcross_color_prev;
 568 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 569 vector wcross_color_goal_prev;
 570 float wcross_changedonetime;
 571
 572 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 573 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 574 float wcross_name_changestarttime, wcross_name_changedonetime;
 575 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 576
 577 float wcross_ring_prev;
 578
 579 entity trueaim;
 580 entity trueaim_rifle;
 581
 582 const float SHOTTYPE_HITTEAM = 1;
 583 const float SHOTTYPE_HITOBSTRUCTION = 2;
 584 const float SHOTTYPE_HITWORLD = 3;
 585 const float SHOTTYPE_HITENEMY = 4;
 586
 587 void TrueAim_Init()
 588 {
 589         trueaim = new(trueaim);
 590         make_pure(trueaim);
 591         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 592         trueaim_rifle = new(trueaim_rifle);
 593         make_pure(trueaim_rifle);
 594         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 595 }
 596
 597 float EnemyHitCheck()
 598 {
 599         float t, n;
 600         wcross_origin = project_3d_to_2d(trace_endpos);
 601         wcross_origin.z = 0;
 602         if(trace_ent)
 603                 n = trace_ent.entnum;
 604         else
 605                 n = trace_networkentity;
 606         if(n < 1)
 607                 return SHOTTYPE_HITWORLD;
 608         if(n > maxclients)
 609                 return SHOTTYPE_HITWORLD;
 610         t = entcs_GetTeam(n - 1);
 611         if(teamplay)
 612                 if(t == myteam)
 613                         return SHOTTYPE_HITTEAM;
 614         if(t == NUM_SPECTATOR)
 615                 return SHOTTYPE_HITWORLD;
 616         return SHOTTYPE_HITENEMY;
 617 }
 618
 619 float TrueAimCheck()
 620 {
 621         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 622         vector vecs, trueaimpoint, w_shotorg;
 623         vector mi, ma, dv;
 624         float shottype;
 625         entity ta;
 626         float mv;
 627
 628         mi = ma = '0 0 0';
 629         ta = trueaim;
 630         mv = MOVE_NOMONSTERS;
 631
 632         switch(activeweapon) // WEAPONTODO
 633         {
 634                 case WEP_TUBA: // no aim
 635                 case WEP_PORTO: // shoots from eye
 636                 case WEP_NEXBALL: // shoots from eye
 637                 case WEP_HOOK: // no trueaim
 638                 case WEP_MORTAR: // toss curve
 639                         return SHOTTYPE_HITWORLD;
 640                 case WEP_VORTEX:
 641                 case WEP_VAPORIZER:
 642                         mv = MOVE_NORMAL;
 643                         break;
 644                 case WEP_RIFLE:
 645                         ta = trueaim_rifle;
 646                         mv = MOVE_NORMAL;
 647                         if(zoomscript_caught)
 648                         {
 649                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 650                                 return EnemyHitCheck();
 651                         }
 652                         break;
 653                 case WEP_DEVASTATOR: // projectile has a size!
 654                         mi = '-3 -3 -3';
 655                         ma = '3 3 3';
 656                         break;
 657                 case WEP_FIREBALL: // projectile has a size!
 658                         mi = '-16 -16 -16';
 659                         ma = '16 16 16';
 660                         break;
 661                 case WEP_SEEKER: // projectile has a size!
 662                         mi = '-2 -2 -2';
 663                         ma = '2 2 2';
 664                         break;
 665                 case WEP_ELECTRO: // projectile has a size!
 666                         mi = '0 0 -3';
 667                         ma = '0 0 -3';
 668                         break;
 669         }
 670
 671         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 672
 673         vecs = decompressShotOrigin(STAT(SHOTORG));
 674
 675         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 676         trueaimpoint = trace_endpos;
 677
 678         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 679                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 680
 681         if(vecs.x > 0)
 682                 vecs.y = -vecs.y;
 683         else
 684                 vecs = '0 0 0';
 685
 686         dv = view_right * vecs.y + view_up * vecs.z;
 687         w_shotorg = traceorigin + dv;
 688
 689         // now move the vecs forward as much as requested if possible
 690         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 691         w_shotorg = trace_endpos - view_forward * nudge;
 692
 693         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 694         shottype = EnemyHitCheck();
 695         if(shottype != SHOTTYPE_HITWORLD)
 696                 return shottype;
 697
 698 #if 0
 699         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 700         // or rather, I know why, but see no fix
 701         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 702                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 703                 return SHOTTYPE_HITOBSTRUCTION;
 704 #endif
 705
 706         return SHOTTYPE_HITWORLD;
 707 }
 708
 709 void PostInit();
 710 void CSQC_Demo_Camera();
 711 float HUD_WouldDrawScoreboard();
 712 float camera_mode;
 713 const float CAMERA_FREE = 1;
 714 const float CAMERA_CHASE = 2;
 715 float reticle_type;
 716 string reticle_image;
 717 string NextFrameCommand;
 718
 719 vector freeze_org, freeze_ang;
 720 entity nightvision_noise, nightvision_noise2;
 721
 722 const float MAX_TIME_DIFF = 5;
 723 float pickup_crosshair_time, pickup_crosshair_size;
 724 float hitindication_crosshair_size;
 725 float use_vortex_chargepool;
 726
 727 float myhealth, myhealth_prev;
 728 float myhealth_flash;
 729
 730 float old_blurradius, old_bluralpha;
 731 float old_sharpen_intensity;
 732
 733 vector myhealth_gentlergb;
 734
 735 float contentavgalpha, liquidalpha_prev;
 736 vector liquidcolor_prev;
 737
 738 float eventchase_current_distance;
 739 float eventchase_running;
 740 bool WantEventchase(entity this)
 741 {
 742         if(autocvar_cl_orthoview)
 743                 return false;
 744         if(intermission)
 745                 return true;
 746         if(this.viewloc)
 747                 return true;
 748         if(spectatee_status >= 0)
 749         {
 750                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 751                         return true;
 752                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 753                         return true;
 754                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 755                         return true;
 756                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 757                 {
 758                         if(autocvar_cl_eventchase_death == 2)
 759                         {
 760                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 761                                 if(this.velocity == '0 0 0' || eventchase_running)
 762                                         return true;
 763                         }
 764                         else return true;
 765                 }
 766         }
 767         return false;
 768 }
 769
 770 void HUD_Crosshair_Vehicle()
 771 {
 772         if(hud != HUD_BUMBLEBEE_GUN)
 773         {
 774                 Vehicle info = Vehicles_from(hud);
 775                 info.vr_crosshair(info);
 776         }
 777 }
 778
 779 vector damage_blurpostprocess, content_blurpostprocess;
 780
 781 float unaccounted_damage = 0;
 782 void UpdateDamage()
 783 {
 784         // accumulate damage with each stat update
 785         static float damage_total_prev = 0;
 786         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 787         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 788         damage_total_prev = damage_total;
 789
 790         static float damage_dealt_time_prev = 0;
 791         float damage_dealt_time = STAT(HIT_TIME);
 792         if (damage_dealt_time != damage_dealt_time_prev)
 793         {
 794                 unaccounted_damage += unaccounted_damage_new;
 795                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 796         }
 797         damage_dealt_time_prev = damage_dealt_time;
 798
 799         // prevent hitsound when switching spectatee
 800         static float spectatee_status_prev = 0;
 801         if (spectatee_status != spectatee_status_prev)
 802                 unaccounted_damage = 0;
 803         spectatee_status_prev = spectatee_status;
 804 }
 805
 806 void HitSound()
 807 {
 808         // varying sound pitch
 809
 810         static float hitsound_time_prev = 0;
 811         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 812         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 813         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 814         {
 815                 if (autocvar_cl_hitsound && unaccounted_damage)
 816                 {
 817                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 818                         float a = autocvar_cl_hitsound_max_pitch;
 819                         float b = autocvar_cl_hitsound_min_pitch;
 820                         float c = autocvar_cl_hitsound_nom_damage;
 821                         float x = unaccounted_damage;
 822                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 823
 824                         // if sound variation is disabled, set pitch_shift to 1
 825                         if (autocvar_cl_hitsound == 1)
 826                                 pitch_shift = 1;
 827
 828                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 829                         if (autocvar_cl_hitsound == 3)
 830                         {
 831                                 float mirror_value = (a-b)/2 + b;
 832                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 833                         }
 834
 835                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 836
 837                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 838                         // todo: normalize sound pressure levels? seems unnecessary
 839
 840                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 841                 }
 842                 unaccounted_damage = 0;
 843                 hitsound_time_prev = time;
 844         }
 845
 846         static float typehit_time_prev = 0;
 847         float typehit_time = STAT(TYPEHIT_TIME);
 848         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 849         {
 850                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 851                 typehit_time_prev = typehit_time;
 852         }
 853 }
 854
 855 void HUD_Crosshair()
 856 {SELFPARAM();
 857         static float rainbow_last_flicker;
 858         static vector rainbow_prev_color;
 859         entity e = this;
 860         float f, i, j;
 861         vector v;
 862         if(!scoreboard_active && !camera_active && intermission != 2 &&
 863                 spectatee_status != -1 && !csqcplayer.viewloc &&
 864                 !HUD_MinigameMenu_IsOpened() )
 865         {
 866                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 867                         return;
 868
 869                 if (hud != HUD_NORMAL)
 870                 {
 871                         HUD_Crosshair_Vehicle();
 872                         return;
 873                 }
 874
 875                 string wcross_style;
 876                 float wcross_alpha, wcross_resolution;
 877                 wcross_style = autocvar_crosshair;
 878                 if (wcross_style == "0")
 879                         return;
 880                 wcross_resolution = autocvar_crosshair_size;
 881                 if (wcross_resolution == 0)
 882                         return;
 883                 wcross_alpha = autocvar_crosshair_alpha;
 884                 if (wcross_alpha == 0)
 885                         return;
 886
 887                 // TrueAim check
 888                 float shottype;
 889
 890                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 891                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 892                 wcross_origin.z = 0;
 893                 if(autocvar_crosshair_hittest)
 894                 {
 895                         vector wcross_oldorigin;
 896                         wcross_oldorigin = wcross_origin;
 897                         shottype = TrueAimCheck();
 898                         if(shottype == SHOTTYPE_HITWORLD)
 899                         {
 900                                 v = wcross_origin - wcross_oldorigin;
 901                                 v.x /= vid_conwidth;
 902                                 v.y /= vid_conheight;
 903                                 if(vlen(v) > 0.01)
 904                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 905                         }
 906                         if(!autocvar_crosshair_hittest_showimpact)
 907                                 wcross_origin = wcross_oldorigin;
 908                 }
 909                 else
 910                         shottype = SHOTTYPE_HITWORLD;
 911
 912                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 913                 string wcross_name = "";
 914                 float wcross_scale, wcross_blur;
 915
 916                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 917                 {
 918                         e = switchingweapon;
 919                         if(e)
 920                         {
 921                                 if(autocvar_crosshair_per_weapon)
 922                                 {
 923                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 924                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 925                                         //if (wcross_resolution == 0)
 926                                                 //return;
 927
 928                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 929                                         wcross_resolution *= e.w_crosshair_size;
 930                                         wcross_name = e.w_crosshair;
 931                                 }
 932                         }
 933                 }
 934
 935                 if(wcross_name == "")
 936                         wcross_name = strcat("gfx/crosshair", wcross_style);
 937
 938                 // MAIN CROSSHAIR COLOR DECISION
 939                 switch(autocvar_crosshair_color_special)
 940                 {
 941                         case 1: // crosshair_color_per_weapon
 942                         {
 943                                 if(e)
 944                                 {
 945                                         wcross_color = e.wpcolor;
 946                                         break;
 947                                 }
 948                                 else { goto normalcolor; }
 949                         }
 950
 951                         case 2: // crosshair_color_by_health
 952                         {
 953                                 float x = STAT(HEALTH);
 954
 955                                 //x = red
 956                                 //y = green
 957                                 //z = blue
 958
 959                                 wcross_color.z = 0;
 960
 961                                 if(x > 200)
 962                                 {
 963                                         wcross_color.x = 0;
 964                                         wcross_color.y = 1;
 965                                 }
 966                                 else if(x > 150)
 967                                 {
 968                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 969                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 970                                 }
 971                                 else if(x > 100)
 972                                 {
 973                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 974                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 975                                         wcross_color.z = 1 - (x-100)*0.02;
 976                                 }
 977                                 else if(x > 50)
 978                                 {
 979                                         wcross_color.x = 1;
 980                                         wcross_color.y = 1;
 981                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 982                                 }
 983                                 else if(x > 20)
 984                                 {
 985                                         wcross_color.x = 1;
 986                                         wcross_color.y = (x-20)*90/27/100;
 987                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 988                                 }
 989                                 else
 990                                 {
 991                                         wcross_color.x = 1;
 992                                         wcross_color.y = 0;
 993                                 }
 994                                 break;
 995                         }
 996
 997                         case 3: // crosshair_color_rainbow
 998                         {
 999                                 if(time >= rainbow_last_flicker)
1000                                 {
1001                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1002                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1003                                 }
1004                                 wcross_color = rainbow_prev_color;
1005                                 break;
1006                         }
1007                         :normalcolor
1008                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1009                 }
1010
1011                 if(autocvar_crosshair_effect_scalefade)
1012                 {
1013                         wcross_scale = wcross_resolution;
1014                         wcross_resolution = 1;
1015                 }
1016                 else
1017                 {
1018                         wcross_scale = 1;
1019                 }
1020
1021                 if(autocvar_crosshair_pickup)
1022                 {
1023                         float stat_pickup_time = STAT(LAST_PICKUP);
1024
1025                         if(pickup_crosshair_time < stat_pickup_time)
1026                         {
1027                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1028                                         pickup_crosshair_size = 1;
1029
1030                                 pickup_crosshair_time = stat_pickup_time;
1031                         }
1032
1033                         if(pickup_crosshair_size > 0)
1034                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1035                         else
1036                                 pickup_crosshair_size = 0;
1037
1038                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1039                 }
1040
1041                 // todo: make crosshair hit indication dependent on damage dealt
1042                 if(autocvar_crosshair_hitindication)
1043                 {
1044                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1045
1046                         if(unaccounted_damage)
1047                         {
1048                                 hitindication_crosshair_size = 1;
1049                         }
1050
1051                         if(hitindication_crosshair_size > 0)
1052                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1053                         else
1054                                 hitindication_crosshair_size = 0;
1055
1056                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1057                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1058                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1059                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1060                 }
1061
1062                 if(shottype == SHOTTYPE_HITENEMY)
1063                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1064                 if(shottype == SHOTTYPE_HITTEAM)
1065                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1066
1067                 f = fabs(autocvar_crosshair_effect_time);
1068                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1069                 {
1070                         wcross_changedonetime = time + f;
1071                 }
1072                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1073                 {
1074                         wcross_name_changestarttime = time;
1075                         wcross_name_changedonetime = time + f;
1076                         if(wcross_name_goal_prev_prev)
1077                                 strunzone(wcross_name_goal_prev_prev);
1078                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1079                         wcross_name_goal_prev = strzone(wcross_name);
1080                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1081                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1082                         wcross_resolution_goal_prev = wcross_resolution;
1083                 }
1084
1085                 wcross_scale_goal_prev = wcross_scale;
1086                 wcross_alpha_goal_prev = wcross_alpha;
1087                 wcross_color_goal_prev = wcross_color;
1088
1089                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1090                 {
1091                         wcross_blur = 1;
1092                         wcross_alpha *= 0.75;
1093                 }
1094                 else
1095                         wcross_blur = 0;
1096                 // *_prev is at time-frametime
1097                 // * is at wcross_changedonetime+f
1098                 // what do we have at time?
1099                 if(time < wcross_changedonetime)
1100                 {
1101                         f = frametime / (wcross_changedonetime - time + frametime);
1102                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1103                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1104                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1105                 }
1106
1107                 wcross_scale_prev = wcross_scale;
1108                 wcross_alpha_prev = wcross_alpha;
1109                 wcross_color_prev = wcross_color;
1110
1111                 MUTATOR_CALLHOOK(UpdateCrosshair);
1112
1113                 wcross_scale *= 1 - autocvar__menu_alpha;
1114                 wcross_alpha *= 1 - autocvar__menu_alpha;
1115                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1116
1117                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1118                 {
1119                         // crosshair rings for weapon stats
1120                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1121                         {
1122                                 // declarations and stats
1123                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1124                                 string ring_image = string_null, ring_inner_image = string_null;
1125                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1126
1127                                 ring_scale = autocvar_crosshair_ring_size;
1128
1129                                 float weapon_clipload, weapon_clipsize;
1130                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1131                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1132
1133                                 float ok_ammo_charge, ok_ammo_chargepool;
1134                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1135                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1136
1137                                 float vortex_charge, vortex_chargepool;
1138                                 vortex_charge = STAT(VORTEX_CHARGE);
1139                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1140
1141                                 float arc_heat = STAT(ARC_HEAT);
1142
1143                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1144                                         vortex_charge_movingavg = vortex_charge;
1145
1146
1147                                 // handle the values
1148                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1149                                 {
1150                                         if (vortex_chargepool || use_vortex_chargepool) {
1151                                                 use_vortex_chargepool = 1;
1152                                                 ring_inner_value = vortex_chargepool;
1153                                         } else {
1154                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1155                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1156                                         }
1157
1158                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1159                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1160                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1161
1162                                         // draw the outer ring to show the current charge of the weapon
1163                                         ring_value = vortex_charge;
1164                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1165                                         ring_rgb = wcross_color;
1166                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1167                                 }
1168                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1169                                 {
1170                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1171                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1172                                         ring_rgb = wcross_color;
1173                                         ring_image = "gfx/crosshair_ring.tga";
1174                                 }
1175                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1176                                 {
1177                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1178                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1179                                         ring_rgb = wcross_color;
1180                                         ring_image = "gfx/crosshair_ring.tga";
1181                                 }
1182                                 else if (ok_ammo_charge)
1183                                 {
1184                                         ring_value = ok_ammo_chargepool;
1185                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1186                                         ring_rgb = wcross_color;
1187                                         ring_image = "gfx/crosshair_ring.tga";
1188                                 }
1189                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1190                                 {
1191                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1192                                         ring_scale = autocvar_crosshair_ring_reload_size;
1193                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1194                                         ring_rgb = wcross_color;
1195
1196                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1197                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1198                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1199                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1200                                         else
1201                                                 ring_image = "gfx/crosshair_ring.tga";
1202                                 }
1203                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1204                                 {
1205                                         ring_value = arc_heat;
1206                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1207                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1208                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1209                                         ring_image = "gfx/crosshair_ring.tga";
1210                                 }
1211
1212                                 // if in weapon switch animation, fade ring out/in
1213                                 if(autocvar_crosshair_effect_time > 0)
1214                                 {
1215                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1216                                         if (f >= 1)
1217                                         {
1218                                                 wcross_ring_prev = ((ring_image) ? true : false);
1219                                         }
1220
1221                                         if(wcross_ring_prev)
1222                                         {
1223                                                 if(f < 1)
1224                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1225                                         }
1226                                         else
1227                                         {
1228                                                 if(f < 1)
1229                                                         ring_alpha *= bound(0, f, 1);
1230                                         }
1231                                 }
1232
1233                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1234                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1235
1236                                 if (ring_value)
1237                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1238                         }
1239
1240 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1241                         MACRO_BEGIN { \
1242                                 if(wcross_blur > 0) \
1243                                 { \
1244                                         for(i = -2; i <= 2; ++i) \
1245                                         for(j = -2; j <= 2; ++j) \
1246                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1247                                 } \
1248                                 else \
1249                                 { \
1250                                         M(0,0,sz,wcross_name,wcross_alpha); \
1251                                 } \
1252                         } MACRO_END
1253
1254 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1255                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1256
1257 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1258                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1259
1260                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1261                         {
1262                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1263                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1264                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1265                                 f = 1 - f;
1266                         }
1267                         else
1268                         {
1269                                 f = 1;
1270                         }
1271                         wcross_name_alpha_goal_prev = f;
1272
1273                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1274                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1275
1276                         if(autocvar_crosshair_dot)
1277                         {
1278                                 vector wcross_color_old;
1279                                 wcross_color_old = wcross_color;
1280
1281                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1282                                         wcross_color = stov(autocvar_crosshair_dot_color);
1283
1284                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1285                                 // FIXME why don't we use wcross_alpha here?
1286                                 wcross_color = wcross_color_old;
1287                         }
1288                 }
1289         }
1290         else
1291         {
1292                 wcross_scale_prev = 0;
1293                 wcross_alpha_prev = 0;
1294                 wcross_scale_goal_prev = 0;
1295                 wcross_alpha_goal_prev = 0;
1296                 wcross_changedonetime = 0;
1297                 if(wcross_name_goal_prev)
1298                         strunzone(wcross_name_goal_prev);
1299                 wcross_name_goal_prev = string_null;
1300                 if(wcross_name_goal_prev_prev)
1301                         strunzone(wcross_name_goal_prev_prev);
1302                 wcross_name_goal_prev_prev = string_null;
1303                 wcross_name_changestarttime = 0;
1304                 wcross_name_changedonetime = 0;
1305                 wcross_name_alpha_goal_prev = 0;
1306                 wcross_name_alpha_goal_prev_prev = 0;
1307                 wcross_resolution_goal_prev = 0;
1308                 wcross_resolution_goal_prev_prev = 0;
1309         }
1310 }
1311
1312 void HUD_Draw()
1313 {
1314         vector rgb = '0 0 0';
1315         float a = 1;
1316         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1317         {
1318                 rgb = MUTATOR_ARGV(0, vector);
1319                 a = MUTATOR_ARGV(0, float);
1320         }
1321         else if(STAT(FROZEN))
1322         {
1323                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1324         }
1325         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1326         if(!intermission)
1327         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1328         {
1329                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1330                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1331         }
1332         else if(STAT(REVIVE_PROGRESS))
1333         {
1334                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1335                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1336         }
1337
1338         if(autocvar_r_letterbox == 0)
1339                 if(autocvar_viewsize < 120)
1340                 {
1341                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1342                                 Accuracy_LoadLevels();
1343
1344                         HUD_Main();
1345                         HUD_DrawScoreboard();
1346                 }
1347
1348         // crosshair goes VERY LAST
1349         UpdateDamage();
1350         HUD_Crosshair();
1351         HitSound();
1352 }
1353
1354 bool ov_enabled;
1355 float oldr_nearclip;
1356 float oldr_farclip_base;
1357 float oldr_farclip_world;
1358 float oldr_novis;
1359 float oldr_useportalculling;
1360 float oldr_useinfinitefarclip;
1361
1362 void cl_notice_run();
1363 float prev_myteam;
1364 int lasthud;
1365 float vh_notice_time;
1366 void WaypointSprite_Load();
1367 void CSQC_UpdateView(float w, float h)
1368 {SELFPARAM();
1369         entity e;
1370         float fov;
1371         float f;
1372         vector vf_size, vf_min;
1373         float a;
1374
1375         execute_next_frame();
1376
1377         ++framecount;
1378
1379         stats_get();
1380         hud = STAT(HUD);
1381
1382         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1383                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1384
1385         lasthud = hud;
1386
1387         if(autocvar__hud_showbinds_reload) // menu can set this one
1388         {
1389                 db_close(binddb);
1390                 binddb = db_create();
1391                 cvar_set("_hud_showbinds_reload", "0");
1392         }
1393
1394         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1395                 view_quality = getproperty(VF_MINFPS_QUALITY);
1396         else
1397                 view_quality = 1;
1398
1399         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1400         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1401
1402         vf_size = getpropertyvec(VF_SIZE);
1403         vf_min = getpropertyvec(VF_MIN);
1404         vid_width = vf_size.x;
1405         vid_height = vf_size.y;
1406
1407         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1408         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1409
1410         WaypointSprite_Load();
1411
1412         CSQCPlayer_SetCamera();
1413
1414         if(player_localentnum <= maxclients) // is it a client?
1415                 current_player = player_localentnum - 1;
1416         else // then player_localentnum is the vehicle I'm driving
1417                 current_player = player_localnum;
1418         myteam = entcs_GetTeam(current_player);
1419
1420         if(myteam != prev_myteam)
1421         {
1422                 myteamcolors = colormapPaletteColor(myteam, 1);
1423                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1424                 prev_myteam = myteam;
1425         }
1426
1427         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1428
1429         float is_dead = (STAT(HEALTH) <= 0);
1430
1431         // FIXME do we need this hack?
1432         if(isdemo())
1433         {
1434                 // in demos, input_buttons do not work
1435                 button_zoom = (autocvar__togglezoom == "-");
1436         }
1437         else if(button_zoom
1438                 && autocvar_cl_unpress_zoom_on_death
1439                 && (spectatee_status >= 0)
1440                 && (is_dead || intermission))
1441         {
1442                 // no zoom while dead or in intermission please
1443                 localcmd("-zoom\n");
1444                 button_zoom = false;
1445         }
1446
1447         // event chase camera
1448         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1449         {
1450                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1451                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1452                 entity gen = world;
1453
1454                 float vehicle_viewdist = 0;
1455                 vector vehicle_viewofs = '0 0 0';
1456
1457                 if(vehicle_chase)
1458                 {
1459                         if(hud != HUD_BUMBLEBEE_GUN)
1460                         {
1461                                 Vehicle info = Vehicles_from(hud);
1462                                 vehicle_viewdist = info.height;
1463                                 vehicle_viewofs = info.view_ofs;
1464                         }
1465                 }
1466
1467                 if(ons_roundlost)
1468                 {
1469                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1470                                 gen = it;
1471                                 break;
1472                         ));
1473                         if(!gen)
1474                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1475                 }
1476                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1477                 {
1478                         eventchase_running = true;
1479
1480                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1481                         if(!local_player)
1482                                 local_player = self; // fall back!
1483
1484                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1485                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1486                         if(ons_roundlost) { current_view_origin = gen.origin; }
1487
1488                         // detect maximum viewoffset and use it
1489                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1490                         if(vehicle_chase)
1491                         {
1492                                 if(vehicle_viewofs)
1493                                         view_offset = vehicle_viewofs;
1494                                 else
1495                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1496                         }
1497                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1498
1499                         if(view_offset)
1500                         {
1501                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1502                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1503                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1504                         }
1505
1506                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1507                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1508                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1509                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1510
1511                         // make the camera smooth back
1512                         float chase_distance = autocvar_cl_eventchase_distance;
1513                         if(vehicle_chase)
1514                         {
1515                                 if(vehicle_viewofs)
1516                                         chase_distance = vehicle_viewdist;
1517                                 else
1518                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1519                         }
1520                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1521
1522                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1523                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1524                         else if(eventchase_current_distance != chase_distance)
1525                                 eventchase_current_distance = chase_distance;
1526
1527                         makevectors(view_angles);
1528
1529                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1530                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1531
1532                         // If the boxtrace fails, revert back to line tracing.
1533                         if(!local_player.viewloc)
1534                         if(trace_startsolid)
1535                         {
1536                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1537                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1538                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1539                         }
1540                         else { setproperty(VF_ORIGIN, trace_endpos); }
1541
1542                         if(!local_player.viewloc)
1543                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1544                 }
1545                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1546                 {
1547                         eventchase_running = false;
1548                         cvar_set("chase_active", "0");
1549                         eventchase_current_distance = 0; // start from 0 next time
1550                 }
1551         }
1552         // workaround for camera stuck between player's legs when using chase_active 1
1553         // because the engine stops updating the chase_active camera when the game ends
1554         else if(intermission)
1555         {
1556                 cvar_settemp("chase_active", "-1");
1557                 eventchase_current_distance = 0;
1558         }
1559
1560         // do lockview after event chase camera so that it still applies whenever necessary.
1561         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1562         {
1563                 setproperty(VF_ORIGIN, freeze_org);
1564                 setproperty(VF_ANGLES, freeze_ang);
1565         }
1566         else
1567         {
1568                 freeze_org = getpropertyvec(VF_ORIGIN);
1569                 freeze_ang = getpropertyvec(VF_ANGLES);
1570         }
1571
1572         WarpZone_FixView();
1573         //WarpZone_FixPMove();
1574
1575         vector ov_org = '0 0 0';
1576         vector ov_mid = '0 0 0';
1577         vector ov_worldmin = '0 0 0';
1578         vector ov_worldmax = '0 0 0';
1579         if(autocvar_cl_orthoview)
1580         {
1581                 ov_worldmin = mi_picmin;
1582                 ov_worldmax = mi_picmax;
1583
1584                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1585                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1586                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1587
1588                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1589                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1590
1591                 float ov_nearest = vlen(ov_org - vec3(
1592                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1593                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1594                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1595                 ));
1596
1597                 float ov_furthest = 0;
1598                 float dist = 0;
1599
1600                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1601                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1602                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1603                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1604                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1605                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1606                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1607                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1608
1609                 if(!ov_enabled)
1610                 {
1611                         oldr_nearclip = cvar("r_nearclip");
1612                         oldr_farclip_base = cvar("r_farclip_base");
1613                         oldr_farclip_world = cvar("r_farclip_world");
1614                         oldr_novis = cvar("r_novis");
1615                         oldr_useportalculling = cvar("r_useportalculling");
1616                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1617                 }
1618
1619                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1620                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1621                 cvar_settemp("r_farclip_world", "0");
1622                 cvar_settemp("r_novis", "1");
1623                 cvar_settemp("r_useportalculling", "0");
1624                 cvar_settemp("r_useinfinitefarclip", "0");
1625
1626                 setproperty(VF_ORIGIN, ov_org);
1627                 setproperty(VF_ANGLES, '90 0 0');
1628
1629                 ov_enabled = true;
1630
1631                 #if 0
1632                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1633                         vtos(ov_org),
1634                         vtos(getpropertyvec(VF_ANGLES)),
1635                         ov_distance,
1636                         ov_nearest,
1637                         ov_furthest);
1638                 #endif
1639         }
1640         else
1641         {
1642                 if(ov_enabled)
1643                 {
1644                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1645                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1646                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1647                         cvar_set("r_novis", ftos(oldr_novis));
1648                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1649                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1650                 }
1651                 ov_enabled = false;
1652         }
1653
1654         // Render the Scene
1655         view_origin = getpropertyvec(VF_ORIGIN);
1656         view_angles = getpropertyvec(VF_ANGLES);
1657         makevectors(view_angles);
1658         view_forward = v_forward;
1659         view_right = v_right;
1660         view_up = v_up;
1661
1662 #ifdef BLURTEST
1663         if(time > blurtest_time0 && time < blurtest_time1)
1664         {
1665                 float r, t;
1666
1667                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1668                 r = t * blurtest_radius;
1669                 f = 1 / pow(t, blurtest_power) - 1;
1670
1671                 cvar_set("r_glsl_postprocess", "1");
1672                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1673         }
1674         else
1675         {
1676                 cvar_set("r_glsl_postprocess", "0");
1677                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1678         }
1679 #endif
1680
1681         TargetMusic_Advance();
1682         Fog_Force();
1683
1684         if(drawtime == 0)
1685                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1686         else
1687                 drawframetime = bound(0.000001, time - drawtime, 1);
1688         drawtime = time;
1689
1690         // watch for gametype changes here...
1691         // in ParseStuffCMD the cmd isn't executed yet :/
1692         // might even be better to add the gametype to TE_CSQC_INIT...?
1693         if(!postinit)
1694                 PostInit();
1695
1696         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1697         {
1698                 if(calledhooks & HOOK_START)
1699                 {
1700                         localcmd("\ncl_hook_gameend\n");
1701                         calledhooks |= HOOK_END;
1702                 }
1703         }
1704
1705         Announcer();
1706
1707         fov = autocvar_fov;
1708         if(fov <= 59.5)
1709         {
1710                 if(!zoomscript_caught)
1711                 {
1712                         localcmd("+button9\n");
1713                         zoomscript_caught = 1;
1714                 }
1715         }
1716         else
1717         {
1718                 if(zoomscript_caught)
1719                 {
1720                         localcmd("-button9\n");
1721                         zoomscript_caught = 0;
1722                 }
1723         }
1724
1725         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1726
1727         // currently switching-to weapon (for crosshair)
1728         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1729
1730         // actually active weapon (for zoom)
1731         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1732
1733         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1734
1735         f = (serverflags & SERVERFLAG_TEAMPLAY);
1736         if(f != teamplay)
1737         {
1738                 teamplay = f;
1739                 HUD_InitScores();
1740         }
1741
1742         if(last_switchweapon != switchweapon)
1743         {
1744                 weapontime = time;
1745                 last_switchweapon = switchweapon;
1746                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1747                 {
1748                         localcmd("-zoom\n");
1749                         button_zoom = false;
1750                 }
1751                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1752                 {
1753                         localcmd("-fire\n");
1754                         localcmd("-fire2\n");
1755                         button_attack2 = false;
1756                 }
1757         }
1758         if(last_activeweapon != activeweapon)
1759         {
1760                 last_activeweapon = activeweapon;
1761
1762                 e = activeweapon;
1763                 if(e.netname != "")
1764                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1765                 else
1766                         localcmd("\ncl_hook_activeweapon none\n");
1767         }
1768
1769         // ALWAYS Clear Current Scene First
1770         clearscene();
1771
1772         setproperty(VF_ORIGIN, view_origin);
1773         setproperty(VF_ANGLES, view_angles);
1774
1775         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1776         setproperty(VF_SIZE, vf_size);
1777         setproperty(VF_MIN, vf_min);
1778
1779         // Assign Standard Viewflags
1780         // Draw the World (and sky)
1781         setproperty(VF_DRAWWORLD, 1);
1782
1783         // Set the console size vars
1784         vid_conwidth = autocvar_vid_conwidth;
1785         vid_conheight = autocvar_vid_conheight;
1786         vid_pixelheight = autocvar_vid_pixelheight;
1787
1788         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1789         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1790         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1791
1792         // Camera for demo playback
1793         if(camera_active)
1794         {
1795                 if(autocvar_camera_enable)
1796                         CSQC_Demo_Camera();
1797                 else
1798                 {
1799                         cvar_set("chase_active", ftos(chase_active_backup));
1800                         cvar_set("cl_demo_mousegrab", "0");
1801                         camera_active = false;
1802                 }
1803         }
1804         else
1805         {
1806 #ifdef CAMERATEST
1807                 if(autocvar_camera_enable)
1808 #else
1809                 if(autocvar_camera_enable && isdemo())
1810 #endif
1811                 {
1812                         // Enable required Darkplaces cvars
1813                         chase_active_backup = autocvar_chase_active;
1814                         cvar_set("chase_active", "2");
1815                         cvar_set("cl_demo_mousegrab", "1");
1816                         camera_active = true;
1817                         camera_mode = false;
1818                 }
1819         }
1820
1821         // Draw the Crosshair
1822         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1823
1824         // Draw the Engine Status Bar (the default Quake HUD)
1825         setproperty(VF_DRAWENGINESBAR, 0);
1826
1827         // Update the mouse position
1828         /*
1829            mousepos_x = vid_conwidth;
1830            mousepos_y = vid_conheight;
1831            mousepos = mousepos*0.5 + getmousepos();
1832          */
1833
1834         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1835
1836         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1837         renderscene();
1838
1839         // now switch to 2D drawing mode by calling a 2D drawing function
1840         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1841         // next R_RenderScene call
1842         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1843
1844         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1845         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1846         {
1847                 // apply night vision effect
1848                 vector tc_00, tc_01, tc_10, tc_11;
1849                 vector rgb = '0 0 0';
1850
1851                 if(!nightvision_noise)
1852                 {
1853                         nightvision_noise = new(nightvision_noise);
1854                 }
1855                 if(!nightvision_noise2)
1856                 {
1857                         nightvision_noise2 = new(nightvision_noise2);
1858                 }
1859
1860                 // color tint in yellow
1861                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1862
1863                 // draw BG
1864                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1865                 rgb = '1 1 1';
1866                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1867                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1868                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1869                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1870                 tc_11 = tc_01 + tc_10 - tc_00;
1871                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1872                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1873                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1874                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1875                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1876                 R_EndPolygon();
1877
1878                 // draw FG
1879                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1880                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1881                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1882                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1883                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1884                 tc_11 = tc_01 + tc_10 - tc_00;
1885                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1886                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1887                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1888                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1889                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1890                 R_EndPolygon();
1891         }
1892
1893         if(autocvar_cl_reticle)
1894         {
1895                 Weapon wep = activeweapon;
1896                 // Draw the aiming reticle for weapons that use it
1897                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1898                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1899                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1900                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1901                 {
1902                         // no zoom reticle while dead
1903                         reticle_type = 0;
1904                 }
1905                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1906                 {
1907                         if(reticle_image != "") { reticle_type = 2; }
1908                         else { reticle_type = 0; }
1909                 }
1910                 else if(button_zoom || zoomscript_caught)
1911                 {
1912                         // normal zoom
1913                         reticle_type = 1;
1914                 }
1915
1916                 if(reticle_type)
1917                 {
1918                         if(autocvar_cl_reticle_stretch)
1919                         {
1920                                 reticle_size.x = vid_conwidth;
1921                                 reticle_size.y = vid_conheight;
1922                                 reticle_pos.x = 0;
1923                                 reticle_pos.y = 0;
1924                         }
1925                         else
1926                         {
1927                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1928                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1929                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1930                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1931                         }
1932
1933                         if(zoomscript_caught)
1934                                 f = 1;
1935                         else
1936                                 f = current_zoomfraction;
1937
1938                         if(f)
1939                         {
1940                                 switch(reticle_type)
1941                                 {
1942                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1943                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1944                                 }
1945                         }
1946                 }
1947         }
1948         else
1949         {
1950                 if(reticle_type != 0) { reticle_type = 0; }
1951         }
1952
1953
1954         // improved polyblend
1955         if(autocvar_hud_contents)
1956         {
1957                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1958                 vector liquidcolor;
1959
1960                 switch(pointcontents(view_origin))
1961                 {
1962                         case CONTENT_WATER:
1963                                 liquidalpha = autocvar_hud_contents_water_alpha;
1964                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1965                                 incontent = 1;
1966                                 break;
1967
1968                         case CONTENT_LAVA:
1969                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1970                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1971                                 incontent = 1;
1972                                 break;
1973
1974                         case CONTENT_SLIME:
1975                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1976                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1977                                 incontent = 1;
1978                                 break;
1979
1980                         default:
1981                                 liquidalpha = 0;
1982                                 liquidcolor = '0 0 0';
1983                                 incontent = 0;
1984                                 break;
1985                 }
1986
1987                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1988                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1989                         contentfadetime = autocvar_hud_contents_fadeintime;
1990                         liquidalpha_prev = liquidalpha;
1991                         liquidcolor_prev = liquidcolor;
1992                 }
1993                 else
1994                         contentfadetime = autocvar_hud_contents_fadeouttime;
1995
1996                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1997                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1998
1999                 if(contentavgalpha)
2000                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2001
2002                 if(autocvar_hud_postprocessing)
2003                 {
2004                         if(autocvar_hud_contents_blur && contentavgalpha)
2005                         {
2006                                 content_blurpostprocess.x = 1;
2007                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2008                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2009                         }
2010                         else
2011                         {
2012                                 content_blurpostprocess.x = 0;
2013                                 content_blurpostprocess.y = 0;
2014                                 content_blurpostprocess.z = 0;
2015                         }
2016                 }
2017         }
2018
2019         if(autocvar_hud_damage && !STAT(FROZEN))
2020         {
2021                 splash_size.x = max(vid_conwidth, vid_conheight);
2022                 splash_size.y = max(vid_conwidth, vid_conheight);
2023                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2024                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2025
2026                 float myhealth_flash_temp;
2027                 myhealth = STAT(HEALTH);
2028
2029                 // fade out
2030                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2031                 // add new damage
2032                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2033
2034                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2035                 pain_threshold = autocvar_hud_damage_pain_threshold;
2036                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2037                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2038
2039                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2040                 {
2041                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2042                 }
2043
2044                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2045
2046                 if(myhealth_prev < 1)
2047                 {
2048                         if(myhealth >= 1)
2049                         {
2050                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2051                                 myhealth_flash_temp = 0;
2052                         }
2053                         else
2054                         {
2055                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2056                         }
2057                 }
2058
2059                 if(spectatee_status == -1 || intermission)
2060                 {
2061                         myhealth_flash = 0; // observing, or match ended
2062                         myhealth_flash_temp = 0;
2063                 }
2064
2065                 myhealth_prev = myhealth;
2066
2067                 // IDEA: change damage color/picture based on player model for robot/alien species?
2068                 // pro: matches model better
2069                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2070                 // maybe different reddish pics?
2071                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2072                 {
2073                         if(autocvar_cl_gentle_damage == 2)
2074                         {
2075                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2076                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2077                         }
2078                         else
2079                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2080
2081                         if(myhealth_flash_temp > 0)
2082                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2083                 }
2084                 else if(myhealth_flash_temp > 0)
2085                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2086
2087                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2088                 {
2089                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2090                         {
2091                                 damage_blurpostprocess.x = 1;
2092                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2093                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2094                         }
2095                         else
2096                         {
2097                                 damage_blurpostprocess.x = 0;
2098                                 damage_blurpostprocess.y = 0;
2099                                 damage_blurpostprocess.z = 0;
2100                         }
2101                 }
2102         }
2103
2104         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2105         float e2 = (autocvar_hud_powerup != 0);
2106         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2107         {
2108                 // enable or disable rendering types if they are used or not
2109                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2110                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2111
2112                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2113                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2114                 {
2115                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2116                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2117                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2118                         {
2119                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2120                                 old_blurradius = blurradius;
2121                                 old_bluralpha = bluralpha;
2122                         }
2123                 }
2124                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2125                 {
2126                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2127                         old_blurradius = 0;
2128                         old_bluralpha = 0;
2129                 }
2130
2131                 // edge detection postprocess handling done second (used by hud_powerup)
2132                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2133                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2134                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2135
2136                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2137
2138                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2139                 {
2140                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2141                         {
2142                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2143                                 old_sharpen_intensity = sharpen_intensity;
2144                         }
2145                 }
2146                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2147                 {
2148                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2149                         old_sharpen_intensity = 0;
2150                 }
2151
2152                 if(cvar("r_glsl_postprocess") == 0)
2153                         cvar_set("r_glsl_postprocess", "2");
2154         }
2155         else if(cvar("r_glsl_postprocess") == 2)
2156                 cvar_set("r_glsl_postprocess", "0");
2157
2158         /*if(gametype == MAPINFO_TYPE_CTF)
2159           {
2160           ctf_view();
2161           } else */
2162
2163         // draw 2D entities
2164         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2165         Draw_ShowNames_All();
2166         Debug_Draw();
2167
2168         scoreboard_active = HUD_WouldDrawScoreboard();
2169
2170         HUD_Draw();
2171
2172         if(NextFrameCommand)
2173         {
2174                 localcmd("\n", NextFrameCommand, "\n");
2175                 NextFrameCommand = string_null;
2176         }
2177
2178         // we must do this check AFTER a frame was rendered, or it won't work
2179         if(cs_project_is_b0rked == 0)
2180         {
2181                 string w0, h0;
2182                 w0 = ftos(autocvar_vid_conwidth);
2183                 h0 = ftos(autocvar_vid_conheight);
2184                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2185                 //setproperty(VF_FOV, '90 90 0');
2186                 setproperty(VF_ORIGIN, '0 0 0');
2187                 setproperty(VF_ANGLES, '0 0 0');
2188                 setproperty(VF_PERSPECTIVE, 1);
2189                 makevectors('0 0 0');
2190                 vector v1, v2;
2191                 cvar_set("vid_conwidth", "800");
2192                 cvar_set("vid_conheight", "600");
2193                 v1 = cs_project(v_forward);
2194                 cvar_set("vid_conwidth", "640");
2195                 cvar_set("vid_conheight", "480");
2196                 v2 = cs_project(v_forward);
2197                 if(v1 == v2)
2198                         cs_project_is_b0rked = 1;
2199                 else
2200                         cs_project_is_b0rked = -1;
2201                 cvar_set("vid_conwidth", w0);
2202                 cvar_set("vid_conheight", h0);
2203         }
2204
2205         if(autocvar__hud_configure)
2206                 HUD_Panel_Mouse();
2207         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2208                 HUD_Minigame_Mouse();
2209         else if(QuickMenu_IsOpened())
2210                 QuickMenu_Mouse();
2211         else
2212                 HUD_Radar_Mouse();
2213
2214         cl_notice_run();
2215         unpause_update();
2216         Net_Flush();
2217
2218         // let's reset the view back to normal for the end
2219         setproperty(VF_MIN, '0 0 0');
2220         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2221 }
2222
2223
2224 // following vectors must be global to allow seamless switching between camera modes
2225 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2226 void CSQC_Demo_Camera()
2227 {
2228         float speed, attenuation, dimensions;
2229         vector tmp, delta;
2230
2231         if( autocvar_camera_reset || !camera_mode )
2232         {
2233                 camera_offset = '0 0 0';
2234                 current_angles = '0 0 0';
2235                 camera_direction = '0 0 0';
2236                 camera_offset.z += 30;
2237                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2238                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2239                 current_origin = view_origin;
2240                 current_camera_offset  = camera_offset;
2241                 cvar_set("camera_reset", "0");
2242                 camera_mode = CAMERA_CHASE;
2243         }
2244
2245         // Camera angles
2246         if( camera_roll )
2247                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2248
2249         if(autocvar_camera_look_player)
2250         {
2251                 vector dir;
2252                 float n;
2253
2254                 dir = normalize(view_origin - current_position);
2255                 n = mouse_angles.z;
2256                 mouse_angles = vectoangles(dir);
2257                 mouse_angles.x = mouse_angles.x * -1;
2258                 mouse_angles.z = n;
2259         }
2260         else
2261         {
2262                 tmp = getmousepos() * 0.1;
2263                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2264                 {
2265                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2266                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2267                 }
2268         }
2269
2270         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2271         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2272         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2273         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2274
2275         // Fix difference when angles don't have the same sign
2276         delta = '0 0 0';
2277         if(mouse_angles.y < -60 && current_angles.y > 60)
2278                 delta = '0 360 0';
2279         if(mouse_angles.y > 60 && current_angles.y < -60)
2280                 delta = '0 -360 0';
2281
2282         if(autocvar_camera_look_player)
2283                 attenuation = autocvar_camera_look_attenuation;
2284         else
2285                 attenuation = autocvar_camera_speed_attenuation;
2286
2287         attenuation = 1 / max(1, attenuation);
2288         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2289
2290         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2291         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2292         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2293         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2294
2295         // Camera position
2296         tmp = '0 0 0';
2297         dimensions = 0;
2298
2299         if( camera_direction.x )
2300         {
2301                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2302                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2303                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2304                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2305                 ++dimensions;
2306         }
2307
2308         if( camera_direction.y )
2309         {
2310                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2311                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2312                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2313                 ++dimensions;
2314         }
2315
2316         if( camera_direction.z )
2317         {
2318                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2319                 ++dimensions;
2320         }
2321
2322         if(autocvar_camera_free)
2323                 speed = autocvar_camera_speed_free;
2324         else
2325                 speed = autocvar_camera_speed_chase;
2326
2327         if(dimensions)
2328         {
2329                 speed = speed * sqrt(1 / dimensions);
2330                 camera_offset += tmp * speed;
2331         }
2332
2333         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2334
2335         // Camera modes
2336         if( autocvar_camera_free )
2337         {
2338                 if ( camera_mode == CAMERA_CHASE )
2339                 {
2340                         current_camera_offset = current_origin + current_camera_offset;
2341                         camera_offset = current_origin + camera_offset;
2342                 }
2343
2344                 camera_mode = CAMERA_FREE;
2345                 current_position = current_camera_offset;
2346         }
2347         else
2348         {
2349                 if ( camera_mode == CAMERA_FREE )
2350                 {
2351                         current_origin = view_origin;
2352                         camera_offset = camera_offset - current_origin;
2353                         current_camera_offset = current_camera_offset - current_origin;
2354                 }
2355
2356                 camera_mode = CAMERA_CHASE;
2357
2358                 if(autocvar_camera_chase_smoothly)
2359                         current_origin += (view_origin - current_origin) * attenuation;
2360                 else
2361                         current_origin = view_origin;
2362
2363                 current_position = current_origin + current_camera_offset;
2364         }
2365
2366         setproperty(VF_ANGLES, current_angles);
2367         setproperty(VF_ORIGIN, current_position);
2368 }