1458efe15f13563e9e869cb653c9e5c80791318c
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "announcer.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "hud/panel/quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include <common/animdecide.qh>
13 #include <common/ent_cs.qh>
14 #include <common/anim.qh>
15 #include <common/constants.qh>
16 #include <common/debug.qh>
17 #include <common/mapinfo.qh>
18 #include <common/gamemodes/all.qh>
19 #include <common/physics/player.qh>
20 #include <common/stats.qh>
21 #include <common/triggers/target/music.qh>
22 #include <common/teams.qh>
23
24 #include <common/vehicles/all.qh>
25 #include <common/weapons/all.qh>
26 #include <common/viewloc.qh>
27 #include <common/minigames/cl_minigames.qh>
28 #include <common/minigames/cl_minigames_hud.qh>
29
30 #include <lib/csqcmodel/cl_player.qh>
31 #include <lib/csqcmodel/cl_model.qh>
32 #include "csqcmodel_hooks.qh"
33
34 #include <lib/warpzone/client.qh>
35 #include <lib/warpzone/common.qh>
36
37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
38
39 float autocvar_cl_viewmodel_scale;
40
41 bool autocvar_cl_bobmodel;
42 float autocvar_cl_bobmodel_speed;
43 float autocvar_cl_bobmodel_side;
44 float autocvar_cl_bobmodel_up;
45
46 float autocvar_cl_followmodel;
47 float autocvar_cl_followmodel_speed = 0.3;
48 float autocvar_cl_followmodel_limit = 135;
49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
50 float autocvar_cl_followmodel_highpass = 0.05;
51 float autocvar_cl_followmodel_lowpass = 0.03;
52 bool autocvar_cl_followmodel_velocity_absolute;
53
54 float autocvar_cl_leanmodel;
55 float autocvar_cl_leanmodel_speed = 0.3;
56 float autocvar_cl_leanmodel_limit = 30;
57 float autocvar_cl_leanmodel_highpass1 = 0.2;
58 float autocvar_cl_leanmodel_highpass = 0.2;
59 float autocvar_cl_leanmodel_lowpass = 0.05;
60
61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
63 { \
64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
65 } MACRO_END
66
67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
68 { \
69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
71 } MACRO_END
72
73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
74 { \
75         float __f = 0; lowpass(value, frac, ref_store, __f); \
76         ret = (value) - __f; \
77 } MACRO_END
78
79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
80 { \
81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
82         ret = (value) - __f; \
83 } MACRO_END
84
85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
86 { \
87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
89 } MACRO_END
90
91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
92 { \
93         highpass(value.x, frac, ref_store.x, ref_out.x); \
94         highpass(value.y, frac, ref_store.y, ref_out.y); \
95 } MACRO_END
96
97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
98 { \
99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
101 } MACRO_END
102
103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
104 { \
105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
108 } MACRO_END
109
110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
111 { \
112         highpass(value.x, frac, ref_store.x, ref_out.x); \
113         highpass(value.y, frac, ref_store.y, ref_out.y); \
114         highpass(value.z, frac, ref_store.z, ref_out.z); \
115 } MACRO_END
116
117 void calc_followmodel_ofs(entity view)
118 {
119         if(cl_followmodel_time == time)
120                 return; // cl_followmodel_ofs already calculated for this frame
121
122         float frac;
123         vector gunorg = '0 0 0';
124         static vector vel_average;
125         static vector gunorg_prev = '0 0 0';
126         static vector gunorg_adjustment_highpass;
127         static vector gunorg_adjustment_lowpass;
128
129         vector vel;
130         if (autocvar_cl_followmodel_velocity_absolute)
131                 vel = view.velocity;
132         else
133         {
134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
136                 vel.x = view.velocity * forward;
137                 vel.y = view.velocity * right * -1;
138                 vel.z = view.velocity * up;
139         }
140
141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
144
145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
146         lowpass3(vel, frac, vel_average, gunorg);
147
148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
149
150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
152         frac = avg_factor(autocvar_cl_followmodel_highpass);
153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
156
157         if (autocvar_cl_followmodel_velocity_absolute)
158         {
159                 vector fixed_gunorg;
160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
162                 fixed_gunorg.x = gunorg * forward;
163                 fixed_gunorg.y = gunorg * right * -1;
164                 fixed_gunorg.z = gunorg * up;
165                 gunorg = fixed_gunorg;
166         }
167
168         cl_followmodel_ofs = gunorg;
169         cl_followmodel_time = time;
170 }
171
172 vector leanmodel_ofs(entity view)
173 {
174         float frac;
175         vector gunangles = '0 0 0';
176         static vector gunangles_prev = '0 0 0';
177         static vector gunangles_highpass = '0 0 0';
178         static vector gunangles_adjustment_highpass;
179         static vector gunangles_adjustment_lowpass;
180
181         if (view.csqcmodel_teleported)
182                 gunangles_prev = view_angles;
183
184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
185         gunangles_highpass += gunangles_prev;
186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
191         gunangles_prev = view_angles;
192         gunangles_highpass -= gunangles_prev;
193
194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
196
197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
202
203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
204
205         return gunangles;
206 }
207
208 vector bobmodel_ofs(entity view)
209 {
210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
211         static bool oldonground;
212         static float hitgroundtime;
213         if (clonground)
214         {
215                 float f = time; // cl.movecmd[0].time
216                 if (!oldonground)
217                         hitgroundtime = f;
218         }
219         oldonground = clonground;
220
221         // calculate for swinging gun model
222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
223         vector gunorg = '0 0 0';
224         static float bobmodel_scale = 0;
225         static float time_ofs = 0; // makes the effect always restart in the same way
226         if (clonground)
227         {
228                 if (time - hitgroundtime > 0.05)
229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
230         }
231         else
232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
233
234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
235         if (bobmodel_scale && xyspeed)
236         {
237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
241         }
242         else
243                 time_ofs = time;
244
245         return gunorg;
246 }
247
248 void viewmodel_animate(entity this)
249 {
250         if (autocvar_chase_active) return;
251         if (STAT(HEALTH) <= 0) return;
252
253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
254
255         if (autocvar_cl_followmodel)
256         {
257                 calc_followmodel_ofs(view);
258                 this.origin += cl_followmodel_ofs;
259         }
260
261         if (autocvar_cl_leanmodel)
262                 this.angles += leanmodel_ofs(view);
263
264         // vertical view bobbing code
265         // TODO: cl_bob
266
267         // horizontal view bobbing code
268         // TODO: cl_bob2
269
270         // fall bobbing code
271         // causes the view to swing down and back up when touching the ground
272         // TODO: cl_bobfall
273
274         // gun model bobbing code
275         if (autocvar_cl_bobmodel)
276                 this.origin += bobmodel_ofs(view);
277 }
278
279 .vector viewmodel_origin, viewmodel_angles;
280 .float weapon_nextthink;
281 .float weapon_eta_last;
282 .float weapon_switchdelay;
283
284 void viewmodel_draw(entity this)
285 {
286         if(!activeweapon || !autocvar_r_drawviewmodel)
287                 return;
288         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
289         float a = this.alpha;
290         static bool wasinvehicle;
291         bool invehicle = player_localentnum > maxclients;
292         if (invehicle) a = -1;
293         else if (wasinvehicle) a = 1;
294         wasinvehicle = invehicle;
295         Weapon wep = activeweapon;
296         int c = stof(getplayerkeyvalue(current_player, "colors"));
297         vector g = weaponentity_glowmod(wep, c);
298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
300                 | EF_NODEPTHTEST)
301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
302         for (entity e = this; e; e = e.weaponchild)
303         {
304                 e.drawmask = mask;
305                 e.alpha = a;
306                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
307                 e.glowmod = g;
308                 e.csqcmodel_effects = fx;
309                 CSQCModel_Effects_Apply(e);
310         }
311         {
312                 static string name_last;
313                 string name = wep.mdl;
314                 bool swap = name != name_last;
315                 // if (swap)
316                 {
317                         name_last = name;
318                         CL_WeaponEntity_SetModel(this, name, swap);
319                         this.viewmodel_origin = this.origin;
320                         this.viewmodel_angles = this.angles;
321                 }
322                 anim_update(this);
323                 if (!this.animstate_override && !this.animstate_looping)
324                         anim_set(this, this.anim_idle, true, false, false);
325         }
326         float f = 0; // 0..1; 0: fully active
327         float rate = STAT(WEAPONRATEFACTOR);
328         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
329         if (eta <= 0) f = this.weapon_eta_last;
330         else switch (this.state)
331         {
332                 case WS_RAISE:
333                 {
334                         f = eta / max(eta, this.weapon_switchdelay);
335                         break;
336                 }
337                 case WS_DROP:
338                 {
339                         f = 1 - eta / max(eta, this.weapon_switchdelay);
340                         break;
341                 }
342                 case WS_CLEAR:
343                 {
344                         f = 1;
345                         break;
346                 }
347         }
348         this.weapon_eta_last = f;
349         this.origin = this.viewmodel_origin;
350         this.angles = this.viewmodel_angles;
351         this.angles_x = (-90 * f * f);
352         viewmodel_animate(this);
353         setorigin(this, this.origin);
354 }
355
356 entity viewmodel;
357 STATIC_INIT(viewmodel) {
358     viewmodel = new(viewmodel);
359 }
360
361 void Porto_Draw(entity this);
362 STATIC_INIT(Porto)
363 {
364         entity e = new_pure(porto);
365         e.draw = Porto_Draw;
366         IL_PUSH(g_drawables, e);
367         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
368 }
369
370 const int polyline_length = 16;
371 vector polyline[polyline_length];
372 void Porto_Draw(entity this)
373 {
374         if (activeweapon != WEP_PORTO) return;
375         if (spectatee_status) return;
376         if (WEP_CVAR(porto, secondary)) return;
377         if (intermission == 1) return;
378         if (intermission == 2) return;
379         if (STAT(HEALTH) <= 0) return;
380
381         vector pos = view_origin;
382         vector dir = view_forward;
383         if (angles_held_status)
384         {
385                 makevectors(angles_held);
386                 dir = v_forward;
387         }
388
389         polyline[0] = pos;
390
391         int portal_number = 0, portal1_idx = 1, portal_max = 2;
392         int n = 1 + 2;  // 2 lines == 3 points
393         for (int idx = 0; idx < n && idx < polyline_length - 1; )
394         {
395                 traceline(pos, pos + 65536 * dir, true, this);
396                 dir = reflect(dir, trace_plane_normal);
397                 pos = trace_endpos;
398                 polyline[++idx] = pos;
399                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
400                 {
401                         n += 1;
402                         continue;
403                 }
404                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
405                 {
406                         n = max(2, idx);
407                         break;
408                 }
409                 // check size
410                 {
411                         vector ang = vectoangles2(trace_plane_normal, dir);
412                         ang.x = -ang.x;
413                         makevectors(ang);
414                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
415                         {
416                                 n = max(2, idx);
417                                 break;
418                         }
419                 }
420                 portal_number += 1;
421                 if (portal_number >= portal_max) break;
422                 if (portal_number == 1) portal1_idx = idx;
423         }
424         for (int idx = 0; idx < n - 1; ++idx)
425         {
426                 vector p = polyline[idx], q = polyline[idx + 1];
427                 if (idx == 0) p -= view_up * 16;  // line from player
428                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
429                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
430         }
431 }
432
433 float drawtime;
434 float avgspeed;
435 vector GetCurrentFov(float fov)
436 {
437         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
438         float velocityzoom, curspeed;
439         vector v;
440
441         zoomsensitivity = autocvar_cl_zoomsensitivity;
442         zoomfactor = autocvar_cl_zoomfactor;
443         if(zoomfactor < 1 || zoomfactor > 30)
444                 zoomfactor = 2.5;
445         zoomspeed = autocvar_cl_zoomspeed;
446         if(zoomspeed >= 0)
447         if(zoomspeed < 0.5 || zoomspeed > 16)
448                         zoomspeed = 3.5;
449
450         zoomdir = button_zoom;
451         if(hud == HUD_NORMAL && !spectatee_status)
452         if(switchweapon == activeweapon)
453         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
454                 zoomdir += button_attack2;
455         if(spectatee_status > 0 || isdemo())
456         {
457                 if(spectatorbutton_zoom)
458                 {
459                         if(zoomdir)
460                                 zoomdir = 0;
461                         else
462                                 zoomdir = 1;
463                 }
464                 // fteqcc failed twice here already, don't optimize this
465         }
466
467         if(zoomdir) { zoomin_effect = 0; }
468
469         if(camera_active)
470         {
471                 current_viewzoom = min(1, current_viewzoom + drawframetime);
472         }
473         else if(autocvar_cl_spawnzoom && zoomin_effect)
474         {
475                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
476
477                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
478                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
479                 if(current_viewzoom == 1) { zoomin_effect = 0; }
480         }
481         else
482         {
483                 if(zoomspeed < 0) // instant zoom
484                 {
485                         if(zoomdir)
486                                 current_viewzoom = 1 / zoomfactor;
487                         else
488                                 current_viewzoom = 1;
489                 }
490                 else
491                 {
492                         if(zoomdir)
493                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
494                         else
495                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
496                 }
497         }
498
499         if(almost_equals(current_viewzoom, 1))
500                 current_zoomfraction = 0;
501         else if(almost_equals(current_viewzoom, 1/zoomfactor))
502                 current_zoomfraction = 1;
503         else
504                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
505
506         if(zoomsensitivity < 1)
507                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
508         else
509                 setsensitivityscale(1);
510
511         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
512         {
513                 if(intermission) { curspeed = 0; }
514                 else
515                 {
516
517                         makevectors(view_angles);
518                         v = pmove_vel;
519                         if(csqcplayer)
520                                 v = csqcplayer.velocity;
521
522                         switch(autocvar_cl_velocityzoom_type)
523                         {
524                                 case 3: curspeed = max(0, v_forward * v); break;
525                                 case 2: curspeed = (v_forward * v); break;
526                                 case 1: default: curspeed = vlen(v); break;
527                         }
528                 }
529
530                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
531                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
532                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
533
534                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
535         }
536         else
537                 velocityzoom = 1;
538
539         float frustumx, frustumy, fovx, fovy;
540         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
541         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
542         fovx = atan2(frustumx, 1) / M_PI * 360.0;
543         fovy = atan2(frustumy, 1) / M_PI * 360.0;
544
545         return '1 0 0' * fovx + '0 1 0' * fovy;
546 }
547
548 vector GetViewLocationFOV(float fov)
549 {
550         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
551         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
552         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
553         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
554         return '1 0 0' * fovx + '0 1 0' * fovy;
555 }
556
557 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
558 {
559         float fovx, fovy;
560         float width = (ov_worldmax.x - ov_worldmin.x);
561         float height = (ov_worldmax.y - ov_worldmin.y);
562         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
563         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
564         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
565         return '1 0 0' * fovx + '0 1 0' * fovy;
566 }
567
568 // this function must match W_SetupShot!
569 float zoomscript_caught;
570
571 vector wcross_origin;
572 float wcross_scale_prev, wcross_alpha_prev;
573 vector wcross_color_prev;
574 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
575 vector wcross_color_goal_prev;
576 float wcross_changedonetime;
577
578 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
579 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
580 float wcross_name_changestarttime, wcross_name_changedonetime;
581 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
582
583 float wcross_ring_prev;
584
585 entity trueaim;
586 entity trueaim_rifle;
587
588 const float SHOTTYPE_HITTEAM = 1;
589 const float SHOTTYPE_HITOBSTRUCTION = 2;
590 const float SHOTTYPE_HITWORLD = 3;
591 const float SHOTTYPE_HITENEMY = 4;
592
593 void TrueAim_Init()
594 {
595         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
596         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
597 }
598
599 float EnemyHitCheck()
600 {
601         float t, n;
602         wcross_origin = project_3d_to_2d(trace_endpos);
603         wcross_origin.z = 0;
604         if(trace_ent)
605                 n = trace_ent.entnum;
606         else
607                 n = trace_networkentity;
608         if(n < 1)
609                 return SHOTTYPE_HITWORLD;
610         if(n > maxclients)
611                 return SHOTTYPE_HITWORLD;
612         t = entcs_GetTeam(n - 1);
613         if(teamplay)
614                 if(t == myteam)
615                         return SHOTTYPE_HITTEAM;
616         if(t == NUM_SPECTATOR)
617                 return SHOTTYPE_HITWORLD;
618         return SHOTTYPE_HITENEMY;
619 }
620
621 float TrueAimCheck()
622 {
623         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
624         vector vecs, trueaimpoint, w_shotorg;
625         vector mi, ma, dv;
626         float shottype;
627         entity ta;
628         float mv;
629
630         mi = ma = '0 0 0';
631         ta = trueaim;
632         mv = MOVE_NOMONSTERS;
633
634         switch(activeweapon) // WEAPONTODO
635         {
636                 case WEP_TUBA: // no aim
637                 case WEP_PORTO: // shoots from eye
638                 case WEP_NEXBALL: // shoots from eye
639                 case WEP_HOOK: // no trueaim
640                 case WEP_MORTAR: // toss curve
641                         return SHOTTYPE_HITWORLD;
642                 case WEP_VORTEX:
643                 case WEP_VAPORIZER:
644                         mv = MOVE_NORMAL;
645                         break;
646                 case WEP_RIFLE:
647                         ta = trueaim_rifle;
648                         mv = MOVE_NORMAL;
649                         if(zoomscript_caught)
650                         {
651                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
652                                 return EnemyHitCheck();
653                         }
654                         break;
655                 case WEP_DEVASTATOR: // projectile has a size!
656                         mi = '-3 -3 -3';
657                         ma = '3 3 3';
658                         break;
659                 case WEP_FIREBALL: // projectile has a size!
660                         mi = '-16 -16 -16';
661                         ma = '16 16 16';
662                         break;
663                 case WEP_SEEKER: // projectile has a size!
664                         mi = '-2 -2 -2';
665                         ma = '2 2 2';
666                         break;
667                 case WEP_ELECTRO: // projectile has a size!
668                         mi = '0 0 -3';
669                         ma = '0 0 -3';
670                         break;
671         }
672
673         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
674
675         vecs = decompressShotOrigin(STAT(SHOTORG));
676
677         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
678         trueaimpoint = trace_endpos;
679
680         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
681                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
682
683         if(vecs.x > 0)
684                 vecs.y = -vecs.y;
685         else
686                 vecs = '0 0 0';
687
688         dv = view_right * vecs.y + view_up * vecs.z;
689         w_shotorg = traceorigin + dv;
690
691         // now move the vecs forward as much as requested if possible
692         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
693         w_shotorg = trace_endpos - view_forward * nudge;
694
695         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
696         shottype = EnemyHitCheck();
697         if(shottype != SHOTTYPE_HITWORLD)
698                 return shottype;
699
700 #if 0
701         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
702         // or rather, I know why, but see no fix
703         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
704                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
705                 return SHOTTYPE_HITOBSTRUCTION;
706 #endif
707
708         return SHOTTYPE_HITWORLD;
709 }
710
711 void PostInit();
712 void CSQC_Demo_Camera();
713 float HUD_WouldDrawScoreboard();
714 float camera_mode;
715 const float CAMERA_FREE = 1;
716 const float CAMERA_CHASE = 2;
717 float reticle_type;
718 string reticle_image;
719 string NextFrameCommand;
720
721 vector freeze_org, freeze_ang;
722 entity nightvision_noise, nightvision_noise2;
723
724 const float MAX_TIME_DIFF = 5;
725 float pickup_crosshair_time, pickup_crosshair_size;
726 float hitindication_crosshair_size;
727 float use_vortex_chargepool;
728
729 float myhealth, myhealth_prev;
730 float myhealth_flash;
731
732 float old_blurradius, old_bluralpha;
733 float old_sharpen_intensity;
734
735 vector myhealth_gentlergb;
736
737 float contentavgalpha, liquidalpha_prev;
738 vector liquidcolor_prev;
739
740 float eventchase_current_distance;
741 float eventchase_running;
742 bool WantEventchase(entity this)
743 {
744         if(autocvar_cl_orthoview)
745                 return false;
746         if(intermission)
747                 return true;
748         if(this.viewloc)
749                 return true;
750         if(spectatee_status >= 0)
751         {
752                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
753                         return true;
754                 if(MUTATOR_CALLHOOK(WantEventchase, this))
755                         return true;
756                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
757                 {
758                         if(autocvar_cl_eventchase_death == 2)
759                         {
760                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
761                                 if(this.velocity == '0 0 0' || eventchase_running)
762                                         return true;
763                         }
764                         else return true;
765                 }
766         }
767         return false;
768 }
769
770 void HUD_Crosshair_Vehicle(entity this)
771 {
772         if(hud != HUD_BUMBLEBEE_GUN)
773         {
774                 Vehicle info = Vehicles_from(hud);
775                 info.vr_crosshair(info, this);
776         }
777 }
778
779 vector damage_blurpostprocess, content_blurpostprocess;
780
781 float unaccounted_damage = 0;
782 void UpdateDamage()
783 {
784         // accumulate damage with each stat update
785         static float damage_total_prev = 0;
786         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
787         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
788         damage_total_prev = damage_total;
789
790         static float damage_dealt_time_prev = 0;
791         float damage_dealt_time = STAT(HIT_TIME);
792         if (damage_dealt_time != damage_dealt_time_prev)
793         {
794                 unaccounted_damage += unaccounted_damage_new;
795                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
796         }
797         damage_dealt_time_prev = damage_dealt_time;
798
799         // prevent hitsound when switching spectatee
800         static float spectatee_status_prev = 0;
801         if (spectatee_status != spectatee_status_prev)
802                 unaccounted_damage = 0;
803         spectatee_status_prev = spectatee_status;
804 }
805
806 void HitSound()
807 {
808         // varying sound pitch
809
810         static float hitsound_time_prev = 0;
811         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
812         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
813         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
814         {
815                 if (autocvar_cl_hitsound && unaccounted_damage)
816                 {
817                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
818                         float a = autocvar_cl_hitsound_max_pitch;
819                         float b = autocvar_cl_hitsound_min_pitch;
820                         float c = autocvar_cl_hitsound_nom_damage;
821                         float x = unaccounted_damage;
822                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
823
824                         // if sound variation is disabled, set pitch_shift to 1
825                         if (autocvar_cl_hitsound == 1)
826                                 pitch_shift = 1;
827
828                         // if pitch shift is reversed, mirror in (max-min)/2 + min
829                         if (autocvar_cl_hitsound == 3)
830                         {
831                                 float mirror_value = (a-b)/2 + b;
832                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
833                         }
834
835                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
836
837                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
838                         // todo: normalize sound pressure levels? seems unnecessary
839
840                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
841                 }
842                 unaccounted_damage = 0;
843                 hitsound_time_prev = time;
844         }
845
846         static float typehit_time_prev = 0;
847         float typehit_time = STAT(TYPEHIT_TIME);
848         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
849         {
850                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
851                 typehit_time_prev = typehit_time;
852         }
853 }
854
855 vector crosshair_getcolor(entity this, float health_stat)
856 {
857         static float rainbow_last_flicker;
858         static vector rainbow_prev_color;
859         vector wcross_color = '0 0 0';
860         switch(autocvar_crosshair_color_special)
861         {
862                 case 1: // crosshair_color_per_weapon
863                 {
864                         if(this != WEP_Null && hud == HUD_NORMAL)
865                         {
866                                 wcross_color = this.wpcolor;
867                                 break;
868                         }
869                         else { goto normalcolor; }
870                 }
871
872                 case 2: // crosshair_color_by_health
873                 {
874                         float x = health_stat;
875
876                         //x = red
877                         //y = green
878                         //z = blue
879
880                         wcross_color.z = 0;
881
882                         if(x > 200)
883                         {
884                                 wcross_color.x = 0;
885                                 wcross_color.y = 1;
886                         }
887                         else if(x > 150)
888                         {
889                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
890                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
891                         }
892                         else if(x > 100)
893                         {
894                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
895                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
896                                 wcross_color.z = 1 - (x-100)*0.02;
897                         }
898                         else if(x > 50)
899                         {
900                                 wcross_color.x = 1;
901                                 wcross_color.y = 1;
902                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
903                         }
904                         else if(x > 20)
905                         {
906                                 wcross_color.x = 1;
907                                 wcross_color.y = (x-20)*90/27/100;
908                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
909                         }
910                         else
911                         {
912                                 wcross_color.x = 1;
913                                 wcross_color.y = 0;
914                         }
915                         break;
916                 }
917
918                 case 3: // crosshair_color_rainbow
919                 {
920                         if(time >= rainbow_last_flicker)
921                         {
922                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
923                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
924                         }
925                         wcross_color = rainbow_prev_color;
926                         break;
927                 }
928 LABEL(normalcolor)
929                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
930         }
931
932         return wcross_color;
933 }
934
935 void HUD_Crosshair(entity this)
936 {
937         float f, i, j;
938         vector v;
939         if(!scoreboard_active && !camera_active && intermission != 2 &&
940                 spectatee_status != -1 && !csqcplayer.viewloc &&
941                 !HUD_MinigameMenu_IsOpened() )
942         {
943                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
944                         return;
945
946                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
947                         return;
948
949                 if (hud != HUD_NORMAL)
950                 {
951                         HUD_Crosshair_Vehicle(this);
952                         return;
953                 }
954
955                 string wcross_style;
956                 float wcross_alpha, wcross_resolution;
957                 wcross_style = autocvar_crosshair;
958                 if (wcross_style == "0")
959                         return;
960                 wcross_resolution = autocvar_crosshair_size;
961                 if (wcross_resolution == 0)
962                         return;
963                 wcross_alpha = autocvar_crosshair_alpha;
964                 if (wcross_alpha == 0)
965                         return;
966
967                 // TrueAim check
968                 float shottype;
969
970                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
971                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
972                 wcross_origin.z = 0;
973                 if(autocvar_crosshair_hittest)
974                 {
975                         vector wcross_oldorigin;
976                         wcross_oldorigin = wcross_origin;
977                         shottype = TrueAimCheck();
978                         if(shottype == SHOTTYPE_HITWORLD)
979                         {
980                                 v = wcross_origin - wcross_oldorigin;
981                                 v.x /= vid_conwidth;
982                                 v.y /= vid_conheight;
983                                 if(vlen(v) > 0.01)
984                                         shottype = SHOTTYPE_HITOBSTRUCTION;
985                         }
986                         if(!autocvar_crosshair_hittest_showimpact)
987                                 wcross_origin = wcross_oldorigin;
988                 }
989                 else
990                         shottype = SHOTTYPE_HITWORLD;
991
992                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
993                 string wcross_name = "";
994                 float wcross_scale, wcross_blur;
995
996         entity e = WEP_Null;
997                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
998                 {
999                         e = switchingweapon;
1000                         if(e)
1001                         {
1002                                 if(autocvar_crosshair_per_weapon)
1003                                 {
1004                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1005                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1006                                         //if (wcross_resolution == 0)
1007                                                 //return;
1008
1009                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1010                                         wcross_resolution *= e.w_crosshair_size;
1011                                         wcross_name = e.w_crosshair;
1012                                 }
1013                         }
1014                 }
1015
1016                 if(wcross_name == "")
1017                         wcross_name = strcat("gfx/crosshair", wcross_style);
1018
1019                 // MAIN CROSSHAIR COLOR DECISION
1020                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1021
1022                 if(autocvar_crosshair_effect_scalefade)
1023                 {
1024                         wcross_scale = wcross_resolution;
1025                         wcross_resolution = 1;
1026                 }
1027                 else
1028                 {
1029                         wcross_scale = 1;
1030                 }
1031
1032                 if(autocvar_crosshair_pickup)
1033                 {
1034                         float stat_pickup_time = STAT(LAST_PICKUP);
1035
1036                         if(pickup_crosshair_time < stat_pickup_time)
1037                         {
1038                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1039                                         pickup_crosshair_size = 1;
1040
1041                                 pickup_crosshair_time = stat_pickup_time;
1042                         }
1043
1044                         if(pickup_crosshair_size > 0)
1045                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1046                         else
1047                                 pickup_crosshair_size = 0;
1048
1049                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1050                 }
1051
1052                 // todo: make crosshair hit indication dependent on damage dealt
1053                 if(autocvar_crosshair_hitindication)
1054                 {
1055                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1056
1057                         if(unaccounted_damage)
1058                         {
1059                                 hitindication_crosshair_size = 1;
1060                         }
1061
1062                         if(hitindication_crosshair_size > 0)
1063                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1064                         else
1065                                 hitindication_crosshair_size = 0;
1066
1067                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1068                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1069                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1070                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1071                 }
1072
1073                 if(shottype == SHOTTYPE_HITENEMY)
1074                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1075                 if(shottype == SHOTTYPE_HITTEAM)
1076                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1077
1078                 f = fabs(autocvar_crosshair_effect_time);
1079                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1080                 {
1081                         wcross_changedonetime = time + f;
1082                 }
1083                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1084                 {
1085                         wcross_name_changestarttime = time;
1086                         wcross_name_changedonetime = time + f;
1087                         if(wcross_name_goal_prev_prev)
1088                                 strunzone(wcross_name_goal_prev_prev);
1089                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1090                         wcross_name_goal_prev = strzone(wcross_name);
1091                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1092                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1093                         wcross_resolution_goal_prev = wcross_resolution;
1094                 }
1095
1096                 wcross_scale_goal_prev = wcross_scale;
1097                 wcross_alpha_goal_prev = wcross_alpha;
1098                 wcross_color_goal_prev = wcross_color;
1099
1100                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1101                 {
1102                         wcross_blur = 1;
1103                         wcross_alpha *= 0.75;
1104                 }
1105                 else
1106                         wcross_blur = 0;
1107                 // *_prev is at time-frametime
1108                 // * is at wcross_changedonetime+f
1109                 // what do we have at time?
1110                 if(time < wcross_changedonetime)
1111                 {
1112                         f = frametime / (wcross_changedonetime - time + frametime);
1113                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1114                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1115                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1116                 }
1117
1118                 wcross_scale_prev = wcross_scale;
1119                 wcross_alpha_prev = wcross_alpha;
1120                 wcross_color_prev = wcross_color;
1121
1122                 MUTATOR_CALLHOOK(UpdateCrosshair);
1123
1124                 wcross_scale *= 1 - autocvar__menu_alpha;
1125                 wcross_alpha *= 1 - autocvar__menu_alpha;
1126                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1127
1128                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1129                 {
1130                         // crosshair rings for weapon stats
1131                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1132                         {
1133                                 // declarations and stats
1134                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1135                                 string ring_image = string_null, ring_inner_image = string_null;
1136                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1137
1138                                 ring_scale = autocvar_crosshair_ring_size;
1139
1140                                 float weapon_clipload, weapon_clipsize;
1141                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1142                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1143
1144                                 float ok_ammo_charge, ok_ammo_chargepool;
1145                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1146                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1147
1148                                 float vortex_charge, vortex_chargepool;
1149                                 vortex_charge = STAT(VORTEX_CHARGE);
1150                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1151
1152                                 float arc_heat = STAT(ARC_HEAT);
1153
1154                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1155                                         vortex_charge_movingavg = vortex_charge;
1156
1157
1158                                 // handle the values
1159                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1160                                 {
1161                                         if (vortex_chargepool || use_vortex_chargepool) {
1162                                                 use_vortex_chargepool = 1;
1163                                                 ring_inner_value = vortex_chargepool;
1164                                         } else {
1165                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1166                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1167                                         }
1168
1169                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1170                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1171                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1172
1173                                         // draw the outer ring to show the current charge of the weapon
1174                                         ring_value = vortex_charge;
1175                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1176                                         ring_rgb = wcross_color;
1177                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1178                                 }
1179                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1180                                 {
1181                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1182                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1183                                         ring_rgb = wcross_color;
1184                                         ring_image = "gfx/crosshair_ring.tga";
1185                                 }
1186                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1187                                 {
1188                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1189                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1190                                         ring_rgb = wcross_color;
1191                                         ring_image = "gfx/crosshair_ring.tga";
1192                                 }
1193                                 else if (ok_ammo_charge)
1194                                 {
1195                                         ring_value = ok_ammo_chargepool;
1196                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1197                                         ring_rgb = wcross_color;
1198                                         ring_image = "gfx/crosshair_ring.tga";
1199                                 }
1200                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1201                                 {
1202                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1203                                         ring_scale = autocvar_crosshair_ring_reload_size;
1204                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1205                                         ring_rgb = wcross_color;
1206
1207                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1208                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1209                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1210                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1211                                         else
1212                                                 ring_image = "gfx/crosshair_ring.tga";
1213                                 }
1214                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1215                                 {
1216                                         ring_value = arc_heat;
1217                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1218                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1219                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1220                                         ring_image = "gfx/crosshair_ring.tga";
1221                                 }
1222
1223                                 // if in weapon switch animation, fade ring out/in
1224                                 if(autocvar_crosshair_effect_time > 0)
1225                                 {
1226                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1227                                         if (f >= 1)
1228                                         {
1229                                                 wcross_ring_prev = ((ring_image) ? true : false);
1230                                         }
1231
1232                                         if(wcross_ring_prev)
1233                                         {
1234                                                 if(f < 1)
1235                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1236                                         }
1237                                         else
1238                                         {
1239                                                 if(f < 1)
1240                                                         ring_alpha *= bound(0, f, 1);
1241                                         }
1242                                 }
1243
1244                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1245                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1246
1247                                 if (ring_value)
1248                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1249                         }
1250
1251 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1252                         MACRO_BEGIN { \
1253                                 if(wcross_blur > 0) \
1254                                 { \
1255                                         for(i = -2; i <= 2; ++i) \
1256                                         for(j = -2; j <= 2; ++j) \
1257                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1258                                 } \
1259                                 else \
1260                                 { \
1261                                         M(0,0,sz,wcross_name,wcross_alpha); \
1262                                 } \
1263                         } MACRO_END
1264
1265 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1266                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1267
1268 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1269                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1270
1271                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1272                         {
1273                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1274                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1275                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1276                                 f = 1 - f;
1277                         }
1278                         else
1279                         {
1280                                 f = 1;
1281                         }
1282                         wcross_name_alpha_goal_prev = f;
1283
1284                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1285                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1286
1287                         if(autocvar_crosshair_dot)
1288                         {
1289                                 vector wcross_color_old;
1290                                 wcross_color_old = wcross_color;
1291
1292                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1293                                         wcross_color = stov(autocvar_crosshair_dot_color);
1294
1295                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1296                                 // FIXME why don't we use wcross_alpha here?
1297                                 wcross_color = wcross_color_old;
1298                         }
1299                 }
1300         }
1301         else
1302         {
1303                 wcross_scale_prev = 0;
1304                 wcross_alpha_prev = 0;
1305                 wcross_scale_goal_prev = 0;
1306                 wcross_alpha_goal_prev = 0;
1307                 wcross_changedonetime = 0;
1308                 if(wcross_name_goal_prev)
1309                         strunzone(wcross_name_goal_prev);
1310                 wcross_name_goal_prev = string_null;
1311                 if(wcross_name_goal_prev_prev)
1312                         strunzone(wcross_name_goal_prev_prev);
1313                 wcross_name_goal_prev_prev = string_null;
1314                 wcross_name_changestarttime = 0;
1315                 wcross_name_changedonetime = 0;
1316                 wcross_name_alpha_goal_prev = 0;
1317                 wcross_name_alpha_goal_prev_prev = 0;
1318                 wcross_resolution_goal_prev = 0;
1319                 wcross_resolution_goal_prev_prev = 0;
1320         }
1321 }
1322
1323 void HUD_Draw(entity this)
1324 {
1325         if(!intermission)
1326         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1327         {
1328                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1329         }
1330         else if(STAT(FROZEN))
1331         {
1332                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1333         }
1334         if(!intermission)
1335         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1336         {
1337                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1338                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1339         }
1340         else if(STAT(REVIVE_PROGRESS))
1341         {
1342                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1343                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1344         }
1345
1346         if(autocvar_r_letterbox == 0)
1347                 if(autocvar_viewsize < 120)
1348                 {
1349                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1350                                 Accuracy_LoadLevels();
1351
1352                         HUD_Main();
1353                         HUD_DrawScoreboard();
1354                         HUD_Scale_Disable();
1355                 }
1356
1357         // crosshair goes VERY LAST
1358         UpdateDamage();
1359         HUD_Crosshair(this);
1360         HitSound();
1361 }
1362
1363 bool ov_enabled;
1364 float oldr_nearclip;
1365 float oldr_farclip_base;
1366 float oldr_farclip_world;
1367 float oldr_novis;
1368 float oldr_useportalculling;
1369 float oldr_useinfinitefarclip;
1370
1371 void cl_notice_run();
1372 float prev_myteam;
1373 int lasthud;
1374 float vh_notice_time;
1375 void WaypointSprite_Load();
1376 void CSQC_UpdateView(entity this, float w, float h)
1377 {
1378     TC(int, w); TC(int, h);
1379         entity e;
1380         float fov;
1381         float f;
1382         vector vf_size, vf_min;
1383         float a;
1384
1385         execute_next_frame();
1386
1387         ++framecount;
1388
1389         stats_get();
1390         hud = STAT(HUD);
1391
1392         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1393                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1394
1395         lasthud = hud;
1396
1397         HUD_Scale_Disable();
1398
1399         if(autocvar__hud_showbinds_reload) // menu can set this one
1400         {
1401                 db_close(binddb);
1402                 binddb = db_create();
1403                 cvar_set("_hud_showbinds_reload", "0");
1404         }
1405
1406         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1407                 view_quality = getproperty(VF_MINFPS_QUALITY);
1408         else
1409                 view_quality = 1;
1410
1411         // this needs to be updated manually now due to the destruction of engine physics stats
1412         if(!isdemo() && autocvar_slowmo != STAT(MOVEVARS_TIMESCALE))
1413                 cvar_set("slowmo", ftos(STAT(MOVEVARS_TIMESCALE)));
1414
1415         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1416         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1417
1418         vf_size = getpropertyvec(VF_SIZE);
1419         vf_min = getpropertyvec(VF_MIN);
1420         vid_width = vf_size.x;
1421         vid_height = vf_size.y;
1422
1423         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1424         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1425
1426         WaypointSprite_Load();
1427
1428         CSQCPlayer_SetCamera();
1429
1430         if(player_localentnum <= maxclients) // is it a client?
1431                 current_player = player_localentnum - 1;
1432         else // then player_localentnum is the vehicle I'm driving
1433                 current_player = player_localnum;
1434         myteam = entcs_GetTeam(current_player);
1435
1436         if(myteam != prev_myteam)
1437         {
1438                 myteamcolors = colormapPaletteColor(myteam, 1);
1439                 FOREACH(hud_panels, true, it.update_time = time);
1440                 prev_myteam = myteam;
1441         }
1442
1443         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1444
1445         float is_dead = (STAT(HEALTH) <= 0);
1446
1447         // FIXME do we need this hack?
1448         if(isdemo())
1449         {
1450                 // in demos, input_buttons do not work
1451                 button_zoom = (autocvar__togglezoom == "-");
1452         }
1453         else if(button_zoom
1454                 && autocvar_cl_unpress_zoom_on_death
1455                 && (spectatee_status >= 0)
1456                 && (is_dead || intermission))
1457         {
1458                 // no zoom while dead or in intermission please
1459                 localcmd("-zoom\n");
1460                 button_zoom = false;
1461         }
1462
1463         // event chase camera
1464         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1465         {
1466                 if(STAT(CAMERA_SPECTATOR))
1467                 {
1468                         if(spectatee_status > 0)
1469                         {
1470                                 if(!autocvar_chase_active)
1471                                 {
1472                                         cvar_set("chase_active", "-2");
1473                                         goto skip_eventchase_death;
1474                                 }
1475                         }
1476                         else if(autocvar_chase_active == -2)
1477                                 cvar_set("chase_active", "0");
1478
1479                         if(autocvar_chase_active == -2)
1480                                 goto skip_eventchase_death;
1481                 }
1482                 else if(autocvar_chase_active == -2)
1483                         cvar_set("chase_active", "0");
1484
1485                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1486                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1487                 entity gen = NULL;
1488
1489                 float vehicle_viewdist = 0;
1490                 vector vehicle_viewofs = '0 0 0';
1491
1492                 if(vehicle_chase)
1493                 {
1494                         if(hud != HUD_BUMBLEBEE_GUN)
1495                         {
1496                                 Vehicle info = Vehicles_from(hud);
1497                                 vehicle_viewdist = info.height;
1498                                 vehicle_viewofs = info.view_ofs;
1499                         }
1500                 }
1501
1502                 if(ons_roundlost)
1503                 {
1504                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1505                                 gen = it;
1506                                 break;
1507                         });
1508                         if(!gen)
1509                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1510                 }
1511                 if(WantEventchase(this) || (!autocvar_cl_orthoview && ons_roundlost))
1512                 {
1513                         eventchase_running = true;
1514
1515                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1516                         if(!local_player)
1517                                 local_player = this; // fall back!
1518
1519                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1520                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1521                         if(ons_roundlost) { current_view_origin = gen.origin; }
1522
1523                         // detect maximum viewoffset and use it
1524                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1525                         if(vehicle_chase)
1526                         {
1527                                 if(vehicle_viewofs)
1528                                         view_offset = vehicle_viewofs;
1529                                 else
1530                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1531                         }
1532                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1533
1534                         if(view_offset)
1535                         {
1536                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1537                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1538                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1539                         }
1540
1541                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1542                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1543                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1544                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1545
1546                         // make the camera smooth back
1547                         float chase_distance = autocvar_cl_eventchase_distance;
1548                         if(vehicle_chase)
1549                         {
1550                                 if(vehicle_viewofs)
1551                                         chase_distance = vehicle_viewdist;
1552                                 else
1553                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1554                         }
1555                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1556
1557                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1558                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1559                         else if(eventchase_current_distance != chase_distance)
1560                                 eventchase_current_distance = chase_distance;
1561
1562                         makevectors(view_angles);
1563
1564                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1565                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1566
1567                         // If the boxtrace fails, revert back to line tracing.
1568                         if(!local_player.viewloc)
1569                         if(trace_startsolid)
1570                         {
1571                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1572                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1573                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1574                         }
1575                         else { setproperty(VF_ORIGIN, trace_endpos); }
1576
1577                         if(!local_player.viewloc)
1578                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1579                 }
1580                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1581                 {
1582                         eventchase_running = false;
1583                         cvar_set("chase_active", "0");
1584                         eventchase_current_distance = 0; // start from 0 next time
1585                 }
1586         }
1587         // workaround for camera stuck between player's legs when using chase_active 1
1588         // because the engine stops updating the chase_active camera when the game ends
1589         else if(intermission)
1590         {
1591                 cvar_settemp("chase_active", "-1");
1592                 eventchase_current_distance = 0;
1593         }
1594
1595         LABEL(skip_eventchase_death);
1596
1597         // do lockview after event chase camera so that it still applies whenever necessary.
1598         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1599         {
1600                 setproperty(VF_ORIGIN, freeze_org);
1601                 setproperty(VF_ANGLES, freeze_ang);
1602         }
1603         else
1604         {
1605                 freeze_org = getpropertyvec(VF_ORIGIN);
1606                 freeze_ang = getpropertyvec(VF_ANGLES);
1607         }
1608
1609         WarpZone_FixView();
1610         //WarpZone_FixPMove();
1611
1612         vector ov_org = '0 0 0';
1613         vector ov_mid = '0 0 0';
1614         vector ov_worldmin = '0 0 0';
1615         vector ov_worldmax = '0 0 0';
1616         if(autocvar_cl_orthoview)
1617         {
1618                 ov_worldmin = mi_picmin;
1619                 ov_worldmax = mi_picmax;
1620
1621                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1622                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1623                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1624
1625                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1626                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1627
1628                 float ov_nearest = vlen(ov_org - vec3(
1629                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1630                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1631                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1632                 ));
1633
1634                 float ov_furthest = 0;
1635                 float dist = 0;
1636
1637                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1638                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1639                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1640                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1641                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1642                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1643                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1644                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1645
1646                 if(!ov_enabled)
1647                 {
1648                         oldr_nearclip = cvar("r_nearclip");
1649                         oldr_farclip_base = cvar("r_farclip_base");
1650                         oldr_farclip_world = cvar("r_farclip_world");
1651                         oldr_novis = cvar("r_novis");
1652                         oldr_useportalculling = cvar("r_useportalculling");
1653                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1654                 }
1655
1656                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1657                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1658                 cvar_settemp("r_farclip_world", "0");
1659                 cvar_settemp("r_novis", "1");
1660                 cvar_settemp("r_useportalculling", "0");
1661                 cvar_settemp("r_useinfinitefarclip", "0");
1662
1663                 setproperty(VF_ORIGIN, ov_org);
1664                 setproperty(VF_ANGLES, '90 0 0');
1665
1666                 ov_enabled = true;
1667
1668                 #if 0
1669                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1670                         vtos(ov_org),
1671                         vtos(getpropertyvec(VF_ANGLES)),
1672                         ov_distance,
1673                         ov_nearest,
1674                         ov_furthest);
1675                 #endif
1676         }
1677         else
1678         {
1679                 if(ov_enabled)
1680                 {
1681                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1682                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1683                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1684                         cvar_set("r_novis", ftos(oldr_novis));
1685                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1686                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1687                 }
1688                 ov_enabled = false;
1689         }
1690
1691         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1692         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1693         viewmodel_draw(viewmodel);
1694
1695         // Render the Scene
1696         view_origin = getpropertyvec(VF_ORIGIN);
1697         view_angles = getpropertyvec(VF_ANGLES);
1698         makevectors(view_angles);
1699         view_forward = v_forward;
1700         view_right = v_right;
1701         view_up = v_up;
1702
1703 #ifdef BLURTEST
1704         if(time > blurtest_time0 && time < blurtest_time1)
1705         {
1706                 float r, t;
1707
1708                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1709                 r = t * blurtest_radius;
1710                 f = 1 / pow(t, blurtest_power) - 1;
1711
1712                 cvar_set("r_glsl_postprocess", "1");
1713                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1714         }
1715         else
1716         {
1717                 cvar_set("r_glsl_postprocess", "0");
1718                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1719         }
1720 #endif
1721
1722         TargetMusic_Advance();
1723         Fog_Force();
1724
1725         if(drawtime == 0)
1726                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1727         else
1728                 drawframetime = bound(0.000001, time - drawtime, 1);
1729         drawtime = time;
1730
1731         // watch for gametype changes here...
1732         // in ParseStuffCMD the cmd isn't executed yet :/
1733         // might even be better to add the gametype to TE_CSQC_INIT...?
1734         if(!postinit)
1735                 PostInit();
1736
1737         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1738         {
1739                 if(calledhooks & HOOK_START)
1740                 {
1741                         localcmd("\ncl_hook_gameend\n");
1742                         calledhooks |= HOOK_END;
1743                 }
1744         }
1745
1746         Announcer();
1747
1748         fov = autocvar_fov;
1749         if(fov <= 59.5)
1750         {
1751                 if(!zoomscript_caught)
1752                 {
1753                         localcmd("+button9\n");
1754                         zoomscript_caught = 1;
1755                 }
1756         }
1757         else
1758         {
1759                 if(zoomscript_caught)
1760                 {
1761                         localcmd("-button9\n");
1762                         zoomscript_caught = 0;
1763                 }
1764         }
1765
1766         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1767
1768         // currently switching-to weapon (for crosshair)
1769         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1770
1771         // actually active weapon (for zoom)
1772         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1773
1774         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1775
1776         f = (serverflags & SERVERFLAG_TEAMPLAY);
1777         if(f != teamplay)
1778         {
1779                 teamplay = f;
1780                 HUD_InitScores();
1781         }
1782
1783         if(last_switchweapon != switchweapon)
1784         {
1785                 weapontime = time;
1786                 last_switchweapon = switchweapon;
1787                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1788                 {
1789                         localcmd("-zoom\n");
1790                         button_zoom = false;
1791                 }
1792                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1793                 {
1794                         localcmd("-fire\n");
1795                         localcmd("-fire2\n");
1796                         button_attack2 = false;
1797                 }
1798         }
1799         if(last_activeweapon != activeweapon)
1800         {
1801                 last_activeweapon = activeweapon;
1802
1803                 e = activeweapon;
1804                 if(e.netname != "")
1805                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1806                 else
1807                         localcmd("\ncl_hook_activeweapon none\n");
1808         }
1809
1810         // ALWAYS Clear Current Scene First
1811         clearscene();
1812
1813         setproperty(VF_ORIGIN, view_origin);
1814         setproperty(VF_ANGLES, view_angles);
1815
1816         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1817         setproperty(VF_SIZE, vf_size);
1818         setproperty(VF_MIN, vf_min);
1819
1820         // Assign Standard Viewflags
1821         // Draw the World (and sky)
1822         setproperty(VF_DRAWWORLD, 1);
1823
1824         // Set the console size vars
1825         vid_conwidth = autocvar_vid_conwidth;
1826         vid_conheight = autocvar_vid_conheight;
1827         vid_pixelheight = autocvar_vid_pixelheight;
1828
1829         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1830         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1831         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1832
1833         // Camera for demo playback
1834         if(camera_active)
1835         {
1836                 if(autocvar_camera_enable)
1837                         CSQC_Demo_Camera();
1838                 else
1839                 {
1840                         cvar_set("chase_active", ftos(chase_active_backup));
1841                         cvar_set("cl_demo_mousegrab", "0");
1842                         camera_active = false;
1843                 }
1844         }
1845         else
1846         {
1847 #ifdef CAMERATEST
1848                 if(autocvar_camera_enable)
1849 #else
1850                 if(autocvar_camera_enable && isdemo())
1851 #endif
1852                 {
1853                         // Enable required Darkplaces cvars
1854                         chase_active_backup = autocvar_chase_active;
1855                         cvar_set("chase_active", "2");
1856                         cvar_set("cl_demo_mousegrab", "1");
1857                         camera_active = true;
1858                         camera_mode = false;
1859                 }
1860         }
1861
1862         // Draw the Crosshair
1863         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1864
1865         // Draw the Engine Status Bar (the default Quake HUD)
1866         setproperty(VF_DRAWENGINESBAR, 0);
1867
1868         // Update the mouse position
1869         /*
1870            mousepos_x = vid_conwidth;
1871            mousepos_y = vid_conheight;
1872            mousepos = mousepos*0.5 + getmousepos();
1873          */
1874
1875         IL_EACH(g_drawables, it.draw, it.draw(it));
1876
1877         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1878         renderscene();
1879
1880         // now switch to 2D drawing mode by calling a 2D drawing function
1881         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1882         // next R_RenderScene call
1883         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1884
1885         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1886         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1887         {
1888                 // apply night vision effect
1889                 vector tc_00, tc_01, tc_10, tc_11;
1890                 vector rgb = '0 0 0';
1891
1892                 if(!nightvision_noise)
1893                 {
1894                         nightvision_noise = new(nightvision_noise);
1895                 }
1896                 if(!nightvision_noise2)
1897                 {
1898                         nightvision_noise2 = new(nightvision_noise2);
1899                 }
1900
1901                 // color tint in yellow
1902                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1903
1904                 // draw BG
1905                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1906                 rgb = '1 1 1';
1907                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1908                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1909                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1910                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1911                 tc_11 = tc_01 + tc_10 - tc_00;
1912                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1913                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1914                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1915                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1916                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1917                 R_EndPolygon();
1918
1919                 // draw FG
1920                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1921                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1922                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1923                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1924                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1925                 tc_11 = tc_01 + tc_10 - tc_00;
1926                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1927                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1928                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1929                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1930                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1931                 R_EndPolygon();
1932         }
1933
1934         if(autocvar_cl_reticle)
1935         {
1936                 Weapon wep = activeweapon;
1937                 // Draw the aiming reticle for weapons that use it
1938                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1939                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1940                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1941                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1942                 {
1943                         // no zoom reticle while dead
1944                         reticle_type = 0;
1945                 }
1946                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1947                 {
1948                         if(reticle_image != "") { reticle_type = 2; }
1949                         else { reticle_type = 0; }
1950                 }
1951                 else if(button_zoom || zoomscript_caught)
1952                 {
1953                         // normal zoom
1954                         reticle_type = 1;
1955                 }
1956
1957                 if(reticle_type)
1958                 {
1959                         if(autocvar_cl_reticle_stretch)
1960                         {
1961                                 reticle_size.x = vid_conwidth;
1962                                 reticle_size.y = vid_conheight;
1963                                 reticle_pos.x = 0;
1964                                 reticle_pos.y = 0;
1965                         }
1966                         else
1967                         {
1968                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1969                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1970                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1971                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1972                         }
1973
1974                         if(zoomscript_caught)
1975                                 f = 1;
1976                         else
1977                                 f = current_zoomfraction;
1978
1979                         if(f)
1980                         {
1981                                 switch(reticle_type)
1982                                 {
1983                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1984                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1985                                 }
1986                         }
1987                 }
1988         }
1989         else
1990         {
1991                 if(reticle_type != 0) { reticle_type = 0; }
1992         }
1993
1994
1995         // improved polyblend
1996         if(autocvar_hud_contents)
1997         {
1998                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1999                 vector liquidcolor;
2000
2001                 switch(pointcontents(view_origin))
2002                 {
2003                         case CONTENT_WATER:
2004                                 liquidalpha = autocvar_hud_contents_water_alpha;
2005                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2006                                 incontent = 1;
2007                                 break;
2008
2009                         case CONTENT_LAVA:
2010                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2011                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2012                                 incontent = 1;
2013                                 break;
2014
2015                         case CONTENT_SLIME:
2016                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2017                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2018                                 incontent = 1;
2019                                 break;
2020
2021                         default:
2022                                 liquidalpha = 0;
2023                                 liquidcolor = '0 0 0';
2024                                 incontent = 0;
2025                                 break;
2026                 }
2027
2028                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2029                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2030                         contentfadetime = autocvar_hud_contents_fadeintime;
2031                         liquidalpha_prev = liquidalpha;
2032                         liquidcolor_prev = liquidcolor;
2033                 }
2034                 else
2035                         contentfadetime = autocvar_hud_contents_fadeouttime;
2036
2037                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2038                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2039
2040                 if(contentavgalpha)
2041                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2042
2043                 if(autocvar_hud_postprocessing)
2044                 {
2045                         if(autocvar_hud_contents_blur && contentavgalpha)
2046                         {
2047                                 content_blurpostprocess.x = 1;
2048                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2049                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2050                         }
2051                         else
2052                         {
2053                                 content_blurpostprocess.x = 0;
2054                                 content_blurpostprocess.y = 0;
2055                                 content_blurpostprocess.z = 0;
2056                         }
2057                 }
2058         }
2059
2060         if(autocvar_hud_damage && !STAT(FROZEN))
2061         {
2062                 splash_size.x = max(vid_conwidth, vid_conheight);
2063                 splash_size.y = max(vid_conwidth, vid_conheight);
2064                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2065                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2066
2067                 float myhealth_flash_temp;
2068                 myhealth = STAT(HEALTH);
2069
2070                 // fade out
2071                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2072                 // add new damage
2073                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2074
2075                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2076                 pain_threshold = autocvar_hud_damage_pain_threshold;
2077                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2078                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2079
2080                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2081                 {
2082                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2083                 }
2084
2085                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2086
2087                 if(myhealth_prev < 1)
2088                 {
2089                         if(myhealth >= 1)
2090                         {
2091                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2092                                 myhealth_flash_temp = 0;
2093                         }
2094                         else
2095                         {
2096                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2097                         }
2098                 }
2099
2100                 if(spectatee_status == -1 || intermission)
2101                 {
2102                         myhealth_flash = 0; // observing, or match ended
2103                         myhealth_flash_temp = 0;
2104                 }
2105
2106                 myhealth_prev = myhealth;
2107
2108                 // IDEA: change damage color/picture based on player model for robot/alien species?
2109                 // pro: matches model better
2110                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2111                 // maybe different reddish pics?
2112                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2113                 {
2114                         if(autocvar_cl_gentle_damage == 2)
2115                         {
2116                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2117                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2118                         }
2119                         else
2120                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2121
2122                         if(myhealth_flash_temp > 0)
2123                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2124                 }
2125                 else if(myhealth_flash_temp > 0)
2126                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2127
2128                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2129                 {
2130                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2131                         {
2132                                 damage_blurpostprocess.x = 1;
2133                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2134                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2135                         }
2136                         else
2137                         {
2138                                 damage_blurpostprocess.x = 0;
2139                                 damage_blurpostprocess.y = 0;
2140                                 damage_blurpostprocess.z = 0;
2141                         }
2142                 }
2143         }
2144
2145         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2146         float e2 = (autocvar_hud_powerup != 0);
2147         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2148         {
2149                 // enable or disable rendering types if they are used or not
2150                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2151                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2152
2153                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2154                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2155                 {
2156                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2157                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2158                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2159                         {
2160                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2161                                 old_blurradius = blurradius;
2162                                 old_bluralpha = bluralpha;
2163                         }
2164                 }
2165                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2166                 {
2167                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2168                         old_blurradius = 0;
2169                         old_bluralpha = 0;
2170                 }
2171
2172                 // edge detection postprocess handling done second (used by hud_powerup)
2173                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2174                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2175                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2176
2177                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2178
2179                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2180                 {
2181                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2182                         {
2183                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2184                                 old_sharpen_intensity = sharpen_intensity;
2185                         }
2186                 }
2187                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2188                 {
2189                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2190                         old_sharpen_intensity = 0;
2191                 }
2192
2193                 if(cvar("r_glsl_postprocess") == 0)
2194                         cvar_set("r_glsl_postprocess", "2");
2195         }
2196         else if(cvar("r_glsl_postprocess") == 2)
2197                 cvar_set("r_glsl_postprocess", "0");
2198
2199         /*if(gametype == MAPINFO_TYPE_CTF)
2200           {
2201           ctf_view();
2202           } else */
2203
2204         // draw 2D entities
2205         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2206         Draw_ShowNames_All();
2207         Debug_Draw();
2208
2209         scoreboard_active = HUD_WouldDrawScoreboard();
2210
2211         HUD_Draw(this); // this parameter for deep vehicle function
2212
2213         if(NextFrameCommand)
2214         {
2215                 localcmd("\n", NextFrameCommand, "\n");
2216                 NextFrameCommand = string_null;
2217         }
2218
2219         // we must do this check AFTER a frame was rendered, or it won't work
2220         if(cs_project_is_b0rked == 0)
2221         {
2222                 string w0, h0;
2223                 w0 = ftos(autocvar_vid_conwidth);
2224                 h0 = ftos(autocvar_vid_conheight);
2225                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2226                 //setproperty(VF_FOV, '90 90 0');
2227                 setproperty(VF_ORIGIN, '0 0 0');
2228                 setproperty(VF_ANGLES, '0 0 0');
2229                 setproperty(VF_PERSPECTIVE, 1);
2230                 makevectors('0 0 0');
2231                 vector v1, v2;
2232                 cvar_set("vid_conwidth", "800");
2233                 cvar_set("vid_conheight", "600");
2234                 v1 = cs_project(v_forward);
2235                 cvar_set("vid_conwidth", "640");
2236                 cvar_set("vid_conheight", "480");
2237                 v2 = cs_project(v_forward);
2238                 if(v1 == v2)
2239                         cs_project_is_b0rked = 1;
2240                 else
2241                         cs_project_is_b0rked = -1;
2242                 cvar_set("vid_conwidth", w0);
2243                 cvar_set("vid_conheight", h0);
2244         }
2245
2246         if(autocvar__hud_configure)
2247                 HUD_Panel_Mouse();
2248         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2249                 HUD_Minigame_Mouse();
2250         else if(QuickMenu_IsOpened())
2251                 QuickMenu_Mouse();
2252         else
2253                 HUD_Radar_Mouse();
2254
2255         cl_notice_run();
2256         unpause_update();
2257         Net_Flush();
2258
2259         // let's reset the view back to normal for the end
2260         setproperty(VF_MIN, '0 0 0');
2261         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2262
2263         IL_ENDFRAME();
2264 }
2265
2266
2267 // following vectors must be global to allow seamless switching between camera modes
2268 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2269 void CSQC_Demo_Camera()
2270 {
2271         float speed, attenuation, dimensions;
2272         vector tmp, delta;
2273
2274         if( autocvar_camera_reset || !camera_mode )
2275         {
2276                 camera_offset = '0 0 0';
2277                 current_angles = '0 0 0';
2278                 camera_direction = '0 0 0';
2279                 camera_offset.z += 30;
2280                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2281                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2282                 current_origin = view_origin;
2283                 current_camera_offset  = camera_offset;
2284                 cvar_set("camera_reset", "0");
2285                 camera_mode = CAMERA_CHASE;
2286         }
2287
2288         // Camera angles
2289         if( camera_roll )
2290                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2291
2292         if(autocvar_camera_look_player)
2293         {
2294                 vector dir;
2295                 float n;
2296
2297                 dir = normalize(view_origin - current_position);
2298                 n = mouse_angles.z;
2299                 mouse_angles = vectoangles(dir);
2300                 mouse_angles.x = mouse_angles.x * -1;
2301                 mouse_angles.z = n;
2302         }
2303         else
2304         {
2305                 tmp = getmousepos() * 0.1;
2306                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2307                 {
2308                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2309                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2310                 }
2311         }
2312
2313         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2314         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2315         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2316         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2317
2318         // Fix difference when angles don't have the same sign
2319         delta = '0 0 0';
2320         if(mouse_angles.y < -60 && current_angles.y > 60)
2321                 delta = '0 360 0';
2322         if(mouse_angles.y > 60 && current_angles.y < -60)
2323                 delta = '0 -360 0';
2324
2325         if(autocvar_camera_look_player)
2326                 attenuation = autocvar_camera_look_attenuation;
2327         else
2328                 attenuation = autocvar_camera_speed_attenuation;
2329
2330         attenuation = 1 / max(1, attenuation);
2331         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2332
2333         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2334         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2335         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2336         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2337
2338         // Camera position
2339         tmp = '0 0 0';
2340         dimensions = 0;
2341
2342         if( camera_direction.x )
2343         {
2344                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2345                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2346                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2347                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2348                 ++dimensions;
2349         }
2350
2351         if( camera_direction.y )
2352         {
2353                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2354                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2355                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2356                 ++dimensions;
2357         }
2358
2359         if( camera_direction.z )
2360         {
2361                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2362                 ++dimensions;
2363         }
2364
2365         if(autocvar_camera_free)
2366                 speed = autocvar_camera_speed_free;
2367         else
2368                 speed = autocvar_camera_speed_chase;
2369
2370         if(dimensions)
2371         {
2372                 speed = speed * sqrt(1 / dimensions);
2373                 camera_offset += tmp * speed;
2374         }
2375
2376         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2377
2378         // Camera modes
2379         if( autocvar_camera_free )
2380         {
2381                 if ( camera_mode == CAMERA_CHASE )
2382                 {
2383                         current_camera_offset = current_origin + current_camera_offset;
2384                         camera_offset = current_origin + camera_offset;
2385                 }
2386
2387                 camera_mode = CAMERA_FREE;
2388                 current_position = current_camera_offset;
2389         }
2390         else
2391         {
2392                 if ( camera_mode == CAMERA_FREE )
2393                 {
2394                         current_origin = view_origin;
2395                         camera_offset = camera_offset - current_origin;
2396                         current_camera_offset = current_camera_offset - current_origin;
2397                 }
2398
2399                 camera_mode = CAMERA_CHASE;
2400
2401                 if(autocvar_camera_chase_smoothly)
2402                         current_origin += (view_origin - current_origin) * attenuation;
2403                 else
2404                         current_origin = view_origin;
2405
2406                 current_position = current_origin + current_camera_offset;
2407         }
2408
2409         setproperty(VF_ANGLES, current_angles);
2410         setproperty(VF_ORIGIN, current_position);
2411 }