qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "noise.qh"
   9 #include "scoreboard.qh"
  10 #include "shownames.qh"
  11 #include "waypointsprites.qh"
  12
  13 #include "mutators/events.qh"
  14
  15 #include "../common/constants.qh"
  16 #include "../common/mapinfo.qh"
  17 #include "../common/nades.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21 #include "../common/util.qh"
  22
  23 #include "../common/weapons/all.qh"
  24
  25 #include "../csqcmodellib/cl_player.qh"
  26
  27 #include "../warpzonelib/client.qh"
  28 #include "../warpzonelib/common.qh"
  29 #include "../warpzonelib/mathlib.qh"
  30
  31 entity porto;
  32 vector polyline[16];
  33 void Porto_Draw()
  34 {
  35         vector p, dir, ang, q, nextdir;
  36         float portal_number, portal1_idx;
  37
  38         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  39                 return;
  40         if(g_balance_porto_secondary)
  41                 return;
  42         if(intermission == 1)
  43                 return;
  44         if(intermission == 2)
  45                 return;
  46         if (getstati(STAT_HEALTH) <= 0)
  47                 return;
  48
  49         dir = view_forward;
  50
  51         if(angles_held_status)
  52         {
  53                 makevectors(angles_held);
  54                 dir = v_forward;
  55         }
  56
  57         p = view_origin;
  58
  59         polyline[0] = p;
  60         int idx = 1;
  61         portal_number = 0;
  62         nextdir = dir;
  63
  64         for (;;)
  65         {
  66                 dir = nextdir;
  67                 traceline(p, p + 65536 * dir, true, porto);
  68                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  69                         return;
  70                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  71                 p = trace_endpos;
  72                 polyline[idx] = p;
  73                 ++idx;
  74                 if(idx >= 16)
  75                         return;
  76                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  77                         continue;
  78                 ++portal_number;
  79                 ang = vectoangles2(trace_plane_normal, dir);
  80                 ang.x = -ang.x;
  81                 makevectors(ang);
  82                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  83                         return;
  84                 if(portal_number == 1)
  85                 {
  86                         portal1_idx = idx;
  87                         if(portal_number >= 2)
  88                                 break;
  89                 }
  90         }
  91
  92         while(idx >= 2)
  93         {
  94                 p = polyline[idx-2];
  95                 q = polyline[idx-1];
  96                 if(idx == 2)
  97                         p = p - view_up * 16;
  98                 if(idx-1 >= portal1_idx)
  99                 {
 100                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 101                 }
 102                 else
 103                 {
 104                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 105                 }
 106                 --idx;
 107         }
 108 }
 109
 110 void Porto_Init()
 111 {
 112         porto = spawn();
 113         porto.classname = "porto";
 114         porto.draw = Porto_Draw;
 115         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 116 }
 117
 118 float drawtime;
 119 float avgspeed;
 120 vector GetCurrentFov(float fov)
 121 {
 122         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 123         float velocityzoom, curspeed;
 124         vector v;
 125
 126         zoomsensitivity = autocvar_cl_zoomsensitivity;
 127         zoomfactor = autocvar_cl_zoomfactor;
 128         if(zoomfactor < 1 || zoomfactor > 30)
 129                 zoomfactor = 2.5;
 130         zoomspeed = autocvar_cl_zoomspeed;
 131         if(zoomspeed >= 0)
 132         if(zoomspeed < 0.5 || zoomspeed > 16)
 133                         zoomspeed = 3.5;
 134
 135         zoomdir = button_zoom;
 136         if(hud == HUD_NORMAL)
 137         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 138                 zoomdir += button_attack2;
 139         if(spectatee_status > 0 || isdemo())
 140         {
 141                 if(spectatorbutton_zoom)
 142                 {
 143                         if(zoomdir)
 144                                 zoomdir = 0;
 145                         else
 146                                 zoomdir = 1;
 147                 }
 148                 // fteqcc failed twice here already, don't optimize this
 149         }
 150
 151         if(zoomdir) { zoomin_effect = 0; }
 152
 153         if(camera_active)
 154         {
 155                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 156         }
 157         else if(autocvar_cl_spawnzoom && zoomin_effect)
 158         {
 159                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 160
 161                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 162                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 163                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 164         }
 165         else
 166         {
 167                 if(zoomspeed < 0) // instant zoom
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / zoomfactor;
 171                         else
 172                                 current_viewzoom = 1;
 173                 }
 174                 else
 175                 {
 176                         if(zoomdir)
 177                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 178                         else
 179                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 180                 }
 181         }
 182
 183         if(almost_equals(current_viewzoom, 1))
 184                 current_zoomfraction = 0;
 185         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 186                 current_zoomfraction = 1;
 187         else
 188                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 189
 190         if(zoomsensitivity < 1)
 191                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 192         else
 193                 setsensitivityscale(1);
 194
 195         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 196         {
 197                 if(intermission) { curspeed = 0; }
 198                 else
 199                 {
 200
 201                         makevectors(view_angles);
 202                         v = pmove_vel;
 203                         if(csqcplayer)
 204                                 v = csqcplayer.velocity;
 205
 206                         switch(autocvar_cl_velocityzoom_type)
 207                         {
 208                                 case 3: curspeed = max(0, v_forward * v); break;
 209                                 case 2: curspeed = (v_forward * v); break;
 210                                 case 1: default: curspeed = vlen(v); break;
 211                         }
 212                 }
 213
 214                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 215                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 216                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 217
 218                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 219         }
 220         else
 221                 velocityzoom = 1;
 222
 223         float frustumx, frustumy, fovx, fovy;
 224         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 225         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 226         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 227         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 228
 229         return '1 0 0' * fovx + '0 1 0' * fovy;
 230 }
 231
 232 vector GetViewLocationFOV(float fov)
 233 {
 234         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 235         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 236         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 237         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 238         return '1 0 0' * fovx + '0 1 0' * fovy;
 239 }
 240
 241 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 242 {
 243         float fovx, fovy;
 244         float width = (ov_worldmax.x - ov_worldmin.x);
 245         float height = (ov_worldmax.y - ov_worldmin.y);
 246         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 247         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 248         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 249         return '1 0 0' * fovx + '0 1 0' * fovy;
 250 }
 251
 252 // this function must match W_SetupShot!
 253 float zoomscript_caught;
 254
 255 vector wcross_origin;
 256 float wcross_scale_prev, wcross_alpha_prev;
 257 vector wcross_color_prev;
 258 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 259 vector wcross_color_goal_prev;
 260 float wcross_changedonetime;
 261
 262 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 263 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 264 float wcross_name_changestarttime, wcross_name_changedonetime;
 265 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 266
 267 float wcross_ring_prev;
 268
 269 entity trueaim;
 270 entity trueaim_rifle;
 271
 272 const float SHOTTYPE_HITTEAM = 1;
 273 const float SHOTTYPE_HITOBSTRUCTION = 2;
 274 const float SHOTTYPE_HITWORLD = 3;
 275 const float SHOTTYPE_HITENEMY = 4;
 276
 277 void TrueAim_Init()
 278 {
 279         trueaim = spawn();
 280         trueaim.classname = "trueaim";
 281         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 282         trueaim_rifle = spawn();
 283         trueaim_rifle.classname = "trueaim_rifle";
 284         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 285 }
 286
 287 float EnemyHitCheck()
 288 {
 289         float t, n;
 290         wcross_origin = project_3d_to_2d(trace_endpos);
 291         wcross_origin.z = 0;
 292         if(trace_ent)
 293                 n = trace_ent.entnum;
 294         else
 295                 n = trace_networkentity;
 296         if(n < 1)
 297                 return SHOTTYPE_HITWORLD;
 298         if(n > maxclients)
 299                 return SHOTTYPE_HITWORLD;
 300         t = GetPlayerColor(n - 1);
 301         if(teamplay)
 302                 if(t == myteam)
 303                         return SHOTTYPE_HITTEAM;
 304         if(t == NUM_SPECTATOR)
 305                 return SHOTTYPE_HITWORLD;
 306         return SHOTTYPE_HITENEMY;
 307 }
 308
 309 float TrueAimCheck()
 310 {
 311         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 312         vector vecs, trueaimpoint, w_shotorg;
 313         vector mi, ma, dv;
 314         float shottype;
 315         entity ta;
 316         float mv;
 317
 318         mi = ma = '0 0 0';
 319         ta = trueaim;
 320         mv = MOVE_NOMONSTERS;
 321
 322         switch(activeweapon) // WEAPONTODO
 323         {
 324                 case WEP_TUBA.m_id: // no aim
 325                 case WEP_PORTO.m_id: // shoots from eye
 326                 case WEP_HOOK.m_id: // no trueaim
 327                 case WEP_MORTAR.m_id: // toss curve
 328                         return SHOTTYPE_HITWORLD;
 329                 case WEP_VORTEX.m_id:
 330                 case WEP_VAPORIZER.m_id:
 331                         mv = MOVE_NORMAL;
 332                         break;
 333                 case WEP_RIFLE.m_id:
 334                         ta = trueaim_rifle;
 335                         mv = MOVE_NORMAL;
 336                         if(zoomscript_caught)
 337                         {
 338                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 339                                 return EnemyHitCheck();
 340                         }
 341                         break;
 342                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 343                         mi = '-3 -3 -3';
 344                         ma = '3 3 3';
 345                         break;
 346                 case WEP_FIREBALL.m_id: // projectile has a size!
 347                         mi = '-16 -16 -16';
 348                         ma = '16 16 16';
 349                         break;
 350                 case WEP_SEEKER.m_id: // projectile has a size!
 351                         mi = '-2 -2 -2';
 352                         ma = '2 2 2';
 353                         break;
 354                 case WEP_ELECTRO.m_id: // projectile has a size!
 355                         mi = '0 0 -3';
 356                         ma = '0 0 -3';
 357                         break;
 358         }
 359
 360         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 361
 362         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 363
 364         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 365         trueaimpoint = trace_endpos;
 366
 367         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 368                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 369
 370         if(vecs.x > 0)
 371                 vecs.y = -vecs.y;
 372         else
 373                 vecs = '0 0 0';
 374
 375         dv = view_right * vecs.y + view_up * vecs.z;
 376         w_shotorg = traceorigin + dv;
 377
 378         // now move the vecs forward as much as requested if possible
 379         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 380         w_shotorg = trace_endpos - view_forward * nudge;
 381
 382         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 383         shottype = EnemyHitCheck();
 384         if(shottype != SHOTTYPE_HITWORLD)
 385                 return shottype;
 386
 387 #if 0
 388         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 389         // or rather, I know why, but see no fix
 390         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 391                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 392                 return SHOTTYPE_HITOBSTRUCTION;
 393 #endif
 394
 395         return SHOTTYPE_HITWORLD;
 396 }
 397
 398 void CSQC_common_hud(void);
 399
 400 void PostInit(void);
 401 void CSQC_Demo_Camera();
 402 float HUD_WouldDrawScoreboard();
 403 float camera_mode;
 404 const float CAMERA_FREE = 1;
 405 const float CAMERA_CHASE = 2;
 406 float reticle_type;
 407 string reticle_image;
 408 string NextFrameCommand;
 409
 410 vector freeze_org, freeze_ang;
 411 entity nightvision_noise, nightvision_noise2;
 412
 413 const float MAX_TIME_DIFF = 5;
 414 float pickup_crosshair_time, pickup_crosshair_size;
 415 float hitindication_crosshair_size;
 416 float use_vortex_chargepool;
 417
 418 float myhealth, myhealth_prev;
 419 float myhealth_flash;
 420
 421 float old_blurradius, old_bluralpha;
 422 float old_sharpen_intensity;
 423
 424 vector myhealth_gentlergb;
 425
 426 float contentavgalpha, liquidalpha_prev;
 427 vector liquidcolor_prev;
 428
 429 float eventchase_current_distance;
 430 float eventchase_running;
 431 bool WantEventchase()
 432 {
 433         if(autocvar_cl_orthoview)
 434                 return false;
 435         if(intermission)
 436                 return true;
 437         if(self.viewloc)
 438                 return true;
 439         if(spectatee_status >= 0)
 440         {
 441                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 442                         return true;
 443                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO.m_id)))
 444                         return true;
 445                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 446                 {
 447                         if(autocvar_cl_eventchase_death == 2)
 448                         {
 449                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 450                                 if(self.velocity == '0 0 0' || eventchase_running)
 451                                         return true;
 452                         }
 453                         else return true;
 454                 }
 455         }
 456         return false;
 457 }
 458
 459 vector damage_blurpostprocess, content_blurpostprocess;
 460
 461 float checkfail[16];
 462
 463 float unaccounted_damage = 0;
 464 void UpdateDamage()
 465 {
 466         // accumulate damage with each stat update
 467         static float damage_total_prev = 0;
 468         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 469         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 470         damage_total_prev = damage_total;
 471
 472         static float damage_dealt_time_prev = 0;
 473         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 474         if (damage_dealt_time != damage_dealt_time_prev)
 475         {
 476                 unaccounted_damage += unaccounted_damage_new;
 477                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 478         }
 479         damage_dealt_time_prev = damage_dealt_time;
 480
 481         // prevent hitsound when switching spectatee
 482         static float spectatee_status_prev = 0;
 483         if (spectatee_status != spectatee_status_prev)
 484                 unaccounted_damage = 0;
 485         spectatee_status_prev = spectatee_status;
 486 }
 487
 488 void UpdateHitsound()
 489 {
 490         // varying sound pitch
 491
 492         static float hitsound_time_prev = 0;
 493         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 494         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 495         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 496         {
 497                 if (autocvar_cl_hitsound && unaccounted_damage)
 498                 {
 499                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 500                         float a = autocvar_cl_hitsound_max_pitch;
 501                         float b = autocvar_cl_hitsound_min_pitch;
 502                         float c = autocvar_cl_hitsound_nom_damage;
 503                         float x = unaccounted_damage;
 504                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 505
 506                         // if sound variation is disabled, set pitch_shift to 1
 507                         if (autocvar_cl_hitsound == 1)
 508                                 pitch_shift = 1;
 509
 510                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 511                         if (autocvar_cl_hitsound == 3)
 512                         {
 513                                 float mirror_value = (a-b)/2 + b;
 514                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 515                         }
 516
 517                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 518
 519                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 520                         // todo: normalize sound pressure levels? seems unnecessary
 521
 522                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 523                 }
 524                 unaccounted_damage = 0;
 525                 hitsound_time_prev = time;
 526         }
 527
 528         static float typehit_time_prev = 0;
 529         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 530         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 531         {
 532                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 533                 typehit_time_prev = typehit_time;
 534         }
 535 }
 536
 537 void UpdateCrosshair()
 538 {
 539         static float rainbow_last_flicker;
 540     static vector rainbow_prev_color;
 541         entity e = self;
 542         float f, i, j;
 543         vector v;
 544         if(getstati(STAT_FROZEN))
 545                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 546         else if (getstatf(STAT_HEALING_ORB)>time)
 547                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 548         if(!intermission)
 549         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 550         {
 551                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 552                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 553         }
 554         else if(getstatf(STAT_REVIVE_PROGRESS))
 555         {
 556                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 557                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 558         }
 559
 560         if(autocvar_r_letterbox == 0)
 561                 if(autocvar_viewsize < 120)
 562                         CSQC_common_hud();
 563
 564         // crosshair goes VERY LAST
 565         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc)
 566         {
 567                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 568                         return;
 569
 570                 string wcross_style;
 571                 float wcross_alpha, wcross_resolution;
 572                 wcross_style = autocvar_crosshair;
 573                 if (wcross_style == "0")
 574                         return;
 575                 wcross_resolution = autocvar_crosshair_size;
 576                 if (wcross_resolution == 0)
 577                         return;
 578                 wcross_alpha = autocvar_crosshair_alpha;
 579                 if (wcross_alpha == 0)
 580                         return;
 581
 582                 // TrueAim check
 583                 float shottype;
 584
 585                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 586                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 587                 wcross_origin.z = 0;
 588                 if(autocvar_crosshair_hittest)
 589                 {
 590                         vector wcross_oldorigin;
 591                         wcross_oldorigin = wcross_origin;
 592                         shottype = TrueAimCheck();
 593                         if(shottype == SHOTTYPE_HITWORLD)
 594                         {
 595                                 v = wcross_origin - wcross_oldorigin;
 596                                 v.x /= vid_conwidth;
 597                                 v.y /= vid_conheight;
 598                                 if(vlen(v) > 0.01)
 599                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 600                         }
 601                         if(!autocvar_crosshair_hittest_showimpact)
 602                                 wcross_origin = wcross_oldorigin;
 603                 }
 604                 else
 605                         shottype = SHOTTYPE_HITWORLD;
 606
 607                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 608                 string wcross_name = "";
 609                 float wcross_scale, wcross_blur;
 610
 611                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 612                 {
 613                         e = get_weaponinfo(switchingweapon);
 614                         if(e)
 615                         {
 616                                 if(autocvar_crosshair_per_weapon)
 617                                 {
 618                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 619                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 620                                         //if (wcross_resolution == 0)
 621                                                 //return;
 622
 623                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 624                                         wcross_resolution *= e.w_crosshair_size;
 625                                         wcross_name = e.w_crosshair;
 626                                 }
 627                         }
 628                 }
 629
 630                 if(wcross_name == "")
 631                         wcross_name = strcat("gfx/crosshair", wcross_style);
 632
 633                 // MAIN CROSSHAIR COLOR DECISION
 634                 switch(autocvar_crosshair_color_special)
 635                 {
 636                         case 1: // crosshair_color_per_weapon
 637                         {
 638                                 if(e)
 639                                 {
 640                                         wcross_color = e.wpcolor;
 641                                         break;
 642                                 }
 643                                 else { goto normalcolor; }
 644                         }
 645
 646                         case 2: // crosshair_color_by_health
 647                         {
 648                                 float x = getstati(STAT_HEALTH);
 649
 650                                 //x = red
 651                                 //y = green
 652                                 //z = blue
 653
 654                                 wcross_color.z = 0;
 655
 656                                 if(x > 200)
 657                                 {
 658                                         wcross_color.x = 0;
 659                                         wcross_color.y = 1;
 660                                 }
 661                                 else if(x > 150)
 662                                 {
 663                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 664                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 665                                 }
 666                                 else if(x > 100)
 667                                 {
 668                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 669                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 670                                         wcross_color.z = 1 - (x-100)*0.02;
 671                                 }
 672                                 else if(x > 50)
 673                                 {
 674                                         wcross_color.x = 1;
 675                                         wcross_color.y = 1;
 676                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 677                                 }
 678                                 else if(x > 20)
 679                                 {
 680                                         wcross_color.x = 1;
 681                                         wcross_color.y = (x-20)*90/27/100;
 682                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 683                                 }
 684                                 else
 685                                 {
 686                                         wcross_color.x = 1;
 687                                         wcross_color.y = 0;
 688                                 }
 689                                 break;
 690                         }
 691
 692                         case 3: // crosshair_color_rainbow
 693                         {
 694                                 if(time >= rainbow_last_flicker)
 695                                 {
 696                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 697                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 698                                 }
 699                                 wcross_color = rainbow_prev_color;
 700                                 break;
 701                         }
 702                         :normalcolor
 703                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 704                 }
 705
 706                 if(autocvar_crosshair_effect_scalefade)
 707                 {
 708                         wcross_scale = wcross_resolution;
 709                         wcross_resolution = 1;
 710                 }
 711                 else
 712                 {
 713                         wcross_scale = 1;
 714                 }
 715
 716                 if(autocvar_crosshair_pickup)
 717                 {
 718                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 719
 720                         if(pickup_crosshair_time < stat_pickup_time)
 721                         {
 722                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 723                                         pickup_crosshair_size = 1;
 724
 725                                 pickup_crosshair_time = stat_pickup_time;
 726                         }
 727
 728                         if(pickup_crosshair_size > 0)
 729                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 730                         else
 731                                 pickup_crosshair_size = 0;
 732
 733                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 734                 }
 735
 736                 // todo: make crosshair hit indication dependent on damage dealt
 737                 if(autocvar_crosshair_hitindication)
 738                 {
 739                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 740
 741                         if(unaccounted_damage)
 742                         {
 743                                 hitindication_crosshair_size = 1;
 744                         }
 745
 746                         if(hitindication_crosshair_size > 0)
 747                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 748                         else
 749                                 hitindication_crosshair_size = 0;
 750
 751                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 752                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 753                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 754                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 755                 }
 756
 757                 if(shottype == SHOTTYPE_HITENEMY)
 758                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 759                 if(shottype == SHOTTYPE_HITTEAM)
 760                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 761
 762                 f = fabs(autocvar_crosshair_effect_time);
 763                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 764                 {
 765                         wcross_changedonetime = time + f;
 766                 }
 767                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 768                 {
 769                         wcross_name_changestarttime = time;
 770                         wcross_name_changedonetime = time + f;
 771                         if(wcross_name_goal_prev_prev)
 772                                 strunzone(wcross_name_goal_prev_prev);
 773                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 774                         wcross_name_goal_prev = strzone(wcross_name);
 775                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 776                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 777                         wcross_resolution_goal_prev = wcross_resolution;
 778                 }
 779
 780                 wcross_scale_goal_prev = wcross_scale;
 781                 wcross_alpha_goal_prev = wcross_alpha;
 782                 wcross_color_goal_prev = wcross_color;
 783
 784                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 785                 {
 786                         wcross_blur = 1;
 787                         wcross_alpha *= 0.75;
 788                 }
 789                 else
 790                         wcross_blur = 0;
 791                 // *_prev is at time-frametime
 792                 // * is at wcross_changedonetime+f
 793                 // what do we have at time?
 794                 if(time < wcross_changedonetime)
 795                 {
 796                         f = frametime / (wcross_changedonetime - time + frametime);
 797                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 798                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 799                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 800                 }
 801
 802                 wcross_scale_prev = wcross_scale;
 803                 wcross_alpha_prev = wcross_alpha;
 804                 wcross_color_prev = wcross_color;
 805
 806                 MUTATOR_CALLHOOK(UpdateCrosshair);
 807
 808                 wcross_scale *= 1 - autocvar__menu_alpha;
 809                 wcross_alpha *= 1 - autocvar__menu_alpha;
 810                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 811
 812                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 813                 {
 814                         // crosshair rings for weapon stats
 815                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 816                         {
 817                                 // declarations and stats
 818                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 819                                 string ring_image = string_null, ring_inner_image = string_null;
 820                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 821
 822                                 ring_scale = autocvar_crosshair_ring_size;
 823
 824                                 float weapon_clipload, weapon_clipsize;
 825                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 826                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 827
 828                                 float ok_ammo_charge, ok_ammo_chargepool;
 829                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 830                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 831
 832                                 float vortex_charge, vortex_chargepool;
 833                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 834                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 835
 836                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 837
 838                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 839                                         vortex_charge_movingavg = vortex_charge;
 840
 841
 842                                 // handle the values
 843                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 844                                 {
 845                                         if (vortex_chargepool || use_vortex_chargepool) {
 846                                                 use_vortex_chargepool = 1;
 847                                                 ring_inner_value = vortex_chargepool;
 848                                         } else {
 849                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 850                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 851                                         }
 852
 853                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 854                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 855                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 856
 857                                         // draw the outer ring to show the current charge of the weapon
 858                                         ring_value = vortex_charge;
 859                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 860                                         ring_rgb = wcross_color;
 861                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 862                                 }
 863                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 864                                 {
 865                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 866                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 867                                         ring_rgb = wcross_color;
 868                                         ring_image = "gfx/crosshair_ring.tga";
 869                                 }
 870                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 871                                 {
 872                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 873                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 874                                         ring_rgb = wcross_color;
 875                                         ring_image = "gfx/crosshair_ring.tga";
 876                                 }
 877                                 else if (ok_ammo_charge)
 878                                 {
 879                                         ring_value = ok_ammo_chargepool;
 880                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 881                                         ring_rgb = wcross_color;
 882                                         ring_image = "gfx/crosshair_ring.tga";
 883                                 }
 884                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 885                                 {
 886                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 887                                         ring_scale = autocvar_crosshair_ring_reload_size;
 888                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 889                                         ring_rgb = wcross_color;
 890
 891                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 892                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 893                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 894                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 895                                         else
 896                                                 ring_image = "gfx/crosshair_ring.tga";
 897                                 }
 898                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 899                                 {
 900                                         ring_value = arc_heat;
 901                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 902                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 903                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 904                                         ring_image = "gfx/crosshair_ring.tga";
 905                                 }
 906
 907                                 // if in weapon switch animation, fade ring out/in
 908                                 if(autocvar_crosshair_effect_time > 0)
 909                                 {
 910                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 911                                         if (f >= 1)
 912                                         {
 913                                                 wcross_ring_prev = ((ring_image) ? true : false);
 914                                         }
 915
 916                                         if(wcross_ring_prev)
 917                                         {
 918                                                 if(f < 1)
 919                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 920                                         }
 921                                         else
 922                                         {
 923                                                 if(f < 1)
 924                                                         ring_alpha *= bound(0, f, 1);
 925                                         }
 926                                 }
 927
 928                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 929                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 930
 931                                 if (ring_value)
 932                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 933                         }
 934
 935 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 936                         do \
 937                         { \
 938                                 if(wcross_blur > 0) \
 939                                 { \
 940                                         for(i = -2; i <= 2; ++i) \
 941                                         for(j = -2; j <= 2; ++j) \
 942                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 943                                 } \
 944                                 else \
 945                                 { \
 946                                         M(0,0,sz,wcross_name,wcross_alpha); \
 947                                 } \
 948                         } \
 949                         while(0)
 950
 951 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 952                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 953
 954 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 955                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 956
 957                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 958                         {
 959                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 960                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 961                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 962                                 f = 1 - f;
 963                         }
 964                         else
 965                         {
 966                                 f = 1;
 967                         }
 968                         wcross_name_alpha_goal_prev = f;
 969
 970                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 971                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 972
 973                         if(autocvar_crosshair_dot)
 974                         {
 975                                 vector wcross_color_old;
 976                                 wcross_color_old = wcross_color;
 977
 978                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 979                                         wcross_color = stov(autocvar_crosshair_dot_color);
 980
 981                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 982                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 983                                 wcross_color = wcross_color_old;
 984                         }
 985                 }
 986         }
 987         else
 988         {
 989                 wcross_scale_prev = 0;
 990                 wcross_alpha_prev = 0;
 991                 wcross_scale_goal_prev = 0;
 992                 wcross_alpha_goal_prev = 0;
 993                 wcross_changedonetime = 0;
 994                 if(wcross_name_goal_prev)
 995                         strunzone(wcross_name_goal_prev);
 996                 wcross_name_goal_prev = string_null;
 997                 if(wcross_name_goal_prev_prev)
 998                         strunzone(wcross_name_goal_prev_prev);
 999                 wcross_name_goal_prev_prev = string_null;
1000                 wcross_name_changestarttime = 0;
1001                 wcross_name_changedonetime = 0;
1002                 wcross_name_alpha_goal_prev = 0;
1003                 wcross_name_alpha_goal_prev_prev = 0;
1004                 wcross_resolution_goal_prev = 0;
1005                 wcross_resolution_goal_prev_prev = 0;
1006         }
1007 }
1008
1009 const int BUTTON_3 = 4;
1010 const int BUTTON_4 = 8;
1011 float cl_notice_run();
1012 float prev_myteam;
1013 int lasthud;
1014 float vh_notice_time;
1015 void CSQC_UpdateView(float w, float h)
1016 {
1017         entity e;
1018         float fov;
1019         float f;
1020         int i;
1021         vector vf_size, vf_min;
1022         float a;
1023
1024         execute_next_frame();
1025
1026         ++framecount;
1027
1028         hud = getstati(STAT_HUD);
1029
1030         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1031                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1032
1033         lasthud = hud;
1034
1035         if(autocvar__hud_showbinds_reload) // menu can set this one
1036         {
1037                 db_close(binddb);
1038                 binddb = db_create();
1039                 cvar_set("_hud_showbinds_reload", "0");
1040         }
1041
1042         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1043                 view_quality = getproperty(VF_MINFPS_QUALITY);
1044         else
1045                 view_quality = 1;
1046
1047         button_attack2 = (input_buttons & BUTTON_3);
1048         button_zoom = (input_buttons & BUTTON_4);
1049
1050 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1051         float checkfailv = (func)(parm);                                                                                \
1052         if (checkfailv != (val)) {                                                                                      \
1053                 if (!checkfail[(flag)])                                                                                     \
1054                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1055                 checkfail[(flag)] = 1;                                                                                      \
1056         }                                                                                                               \
1057 } while(0)
1058         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1059         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1060         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1061         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1062         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1063         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1064         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1065
1066         vf_size = getpropertyvec(VF_SIZE);
1067         vf_min = getpropertyvec(VF_MIN);
1068         vid_width = vf_size.x;
1069         vid_height = vf_size.y;
1070
1071         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1072         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1073
1074         WaypointSprite_Load();
1075
1076         CSQCPlayer_SetCamera();
1077
1078         if(player_localentnum <= maxclients) // is it a client?
1079                 current_player = player_localentnum - 1;
1080         else // then player_localentnum is the vehicle I'm driving
1081                 current_player = player_localnum;
1082         myteam = GetPlayerColor(current_player);
1083
1084         if(myteam != prev_myteam)
1085         {
1086                 myteamcolors = colormapPaletteColor(myteam, 1);
1087                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1088                         hud_panel[i].update_time = time;
1089                 prev_myteam = myteam;
1090         }
1091
1092         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1093
1094         float is_dead = (getstati(STAT_HEALTH) <= 0);
1095
1096         // FIXME do we need this hack?
1097         if(isdemo())
1098         {
1099                 // in demos, input_buttons do not work
1100                 button_zoom = (autocvar__togglezoom == "-");
1101         }
1102         else if(button_zoom
1103                 && autocvar_cl_unpress_zoom_on_death
1104                 && (spectatee_status >= 0)
1105                 && (is_dead || intermission))
1106         {
1107                 // no zoom while dead or in intermission please
1108                 localcmd("-zoom\n");
1109                 button_zoom = false;
1110         }
1111
1112         // event chase camera
1113         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1114         {
1115                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1116                 if(WantEventchase())
1117                 {
1118                         eventchase_running = true;
1119
1120                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1121                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1122
1123                         // detect maximum viewoffset and use it
1124                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1125                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1126
1127                         if(view_offset)
1128                         {
1129                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1130                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1131                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1132                         }
1133
1134                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1135                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1136                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1137                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1138
1139                         // make the camera smooth back
1140                         float chase_distance = autocvar_cl_eventchase_distance;
1141                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1142
1143                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1144                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1145                         else if(eventchase_current_distance != chase_distance)
1146                                 eventchase_current_distance = chase_distance;
1147
1148                         makevectors(view_angles);
1149
1150                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1151                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1152
1153                         // If the boxtrace fails, revert back to line tracing.
1154                         if(!self.viewloc)
1155                         if(trace_startsolid)
1156                         {
1157                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1158                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1159                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1160                         }
1161                         else { setproperty(VF_ORIGIN, trace_endpos); }
1162
1163                         if(!self.viewloc)
1164                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1165                 }
1166                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1167                 {
1168                         eventchase_running = false;
1169                         cvar_set("chase_active", "0");
1170                         eventchase_current_distance = 0; // start from 0 next time
1171                 }
1172         }
1173         // workaround for camera stuck between player's legs when using chase_active 1
1174         // because the engine stops updating the chase_active camera when the game ends
1175         else if(intermission)
1176         {
1177                 cvar_settemp("chase_active", "-1");
1178                 eventchase_current_distance = 0;
1179         }
1180
1181         // do lockview after event chase camera so that it still applies whenever necessary.
1182         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1183         {
1184                 setproperty(VF_ORIGIN, freeze_org);
1185                 setproperty(VF_ANGLES, freeze_ang);
1186         }
1187         else
1188         {
1189                 freeze_org = getpropertyvec(VF_ORIGIN);
1190                 freeze_ang = getpropertyvec(VF_ANGLES);
1191         }
1192
1193         WarpZone_FixView();
1194         //WarpZone_FixPMove();
1195
1196         vector ov_org = '0 0 0';
1197         vector ov_mid = '0 0 0';
1198         vector ov_worldmin = '0 0 0';
1199         vector ov_worldmax = '0 0 0';
1200         if(autocvar_cl_orthoview)
1201         {
1202                 ov_worldmin = mi_picmin;
1203                 ov_worldmax = mi_picmax;
1204
1205                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1206                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1207                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1208
1209                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1210                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1211
1212                 float ov_nearest = vlen(ov_org - vec3(
1213                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1214                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1215                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1216                 ));
1217
1218                 float ov_furthest = 0;
1219                 float dist = 0;
1220
1221                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1222                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1223                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1224                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1225                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1226                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1227                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1228                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1229
1230                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1231                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1232                 cvar_settemp("r_farclip_world", "0");
1233                 cvar_settemp("r_novis", "1");
1234                 cvar_settemp("r_useportalculling", "0");
1235                 cvar_settemp("r_useinfinitefarclip", "0");
1236
1237                 setproperty(VF_ORIGIN, ov_org);
1238                 setproperty(VF_ANGLES, '90 0 0');
1239
1240                 #if 0
1241                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1242                         vtos(ov_org),
1243                         vtos(getpropertyvec(VF_ANGLES)),
1244                         ov_distance,
1245                         ov_nearest,
1246                         ov_furthest);
1247                 #endif
1248         }
1249
1250         // Render the Scene
1251         view_origin = getpropertyvec(VF_ORIGIN);
1252         view_angles = getpropertyvec(VF_ANGLES);
1253         makevectors(view_angles);
1254         view_forward = v_forward;
1255         view_right = v_right;
1256         view_up = v_up;
1257
1258 #ifdef BLURTEST
1259         if(time > blurtest_time0 && time < blurtest_time1)
1260         {
1261                 float r, t;
1262
1263                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1264                 r = t * blurtest_radius;
1265                 f = 1 / pow(t, blurtest_power) - 1;
1266
1267                 cvar_set("r_glsl_postprocess", "1");
1268                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1269         }
1270         else
1271         {
1272                 cvar_set("r_glsl_postprocess", "0");
1273                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1274         }
1275 #endif
1276
1277         TargetMusic_Advance();
1278         Fog_Force();
1279
1280         if(drawtime == 0)
1281                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1282         else
1283                 drawframetime = bound(0.000001, time - drawtime, 1);
1284         drawtime = time;
1285
1286         // watch for gametype changes here...
1287         // in ParseStuffCMD the cmd isn't executed yet :/
1288         // might even be better to add the gametype to TE_CSQC_INIT...?
1289         if(!postinit)
1290                 PostInit();
1291
1292         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1293         {
1294                 if(calledhooks & HOOK_START)
1295                 {
1296                         localcmd("\ncl_hook_gameend\n");
1297                         calledhooks |= HOOK_END;
1298                 }
1299         }
1300
1301         Announcer();
1302
1303         fov = autocvar_fov;
1304         if(fov <= 59.5)
1305         {
1306                 if(!zoomscript_caught)
1307                 {
1308                         localcmd("+button9\n");
1309                         zoomscript_caught = 1;
1310                 }
1311         }
1312         else
1313         {
1314                 if(zoomscript_caught)
1315                 {
1316                         localcmd("-button9\n");
1317                         zoomscript_caught = 0;
1318                 }
1319         }
1320
1321         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1322
1323         // next WANTED weapon (for HUD)
1324         switchweapon = getstati(STAT_SWITCHWEAPON);
1325
1326         // currently switching-to weapon (for crosshair)
1327         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1328
1329         // actually active weapon (for zoom)
1330         activeweapon = getstati(STAT_ACTIVEWEAPON);
1331
1332         f = (serverflags & SERVERFLAG_TEAMPLAY);
1333         if(f != teamplay)
1334         {
1335                 teamplay = f;
1336                 HUD_InitScores();
1337         }
1338
1339         if(last_switchweapon != switchweapon)
1340         {
1341                 weapontime = time;
1342                 last_switchweapon = switchweapon;
1343                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1344                 {
1345                         localcmd("-zoom\n");
1346                         button_zoom = false;
1347                 }
1348                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1349                 {
1350                         localcmd("-fire\n");
1351                         localcmd("-fire2\n");
1352                         button_attack2 = false;
1353                 }
1354         }
1355         if(last_activeweapon != activeweapon)
1356         {
1357                 last_activeweapon = activeweapon;
1358
1359                 e = get_weaponinfo(activeweapon);
1360                 if(e.netname != "")
1361                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1362                 else
1363                         localcmd("\ncl_hook_activeweapon none\n");
1364         }
1365
1366         // ALWAYS Clear Current Scene First
1367         clearscene();
1368
1369         setproperty(VF_ORIGIN, view_origin);
1370         setproperty(VF_ANGLES, view_angles);
1371
1372         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1373         setproperty(VF_SIZE, vf_size);
1374         setproperty(VF_MIN, vf_min);
1375
1376         // Assign Standard Viewflags
1377         // Draw the World (and sky)
1378         setproperty(VF_DRAWWORLD, 1);
1379
1380         // Set the console size vars
1381         vid_conwidth = autocvar_vid_conwidth;
1382         vid_conheight = autocvar_vid_conheight;
1383         vid_pixelheight = autocvar_vid_pixelheight;
1384
1385         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1386         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1387         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1388
1389         // Camera for demo playback
1390         if(camera_active)
1391         {
1392                 if(autocvar_camera_enable)
1393                         CSQC_Demo_Camera();
1394                 else
1395                 {
1396                         cvar_set("chase_active", ftos(chase_active_backup));
1397                         cvar_set("cl_demo_mousegrab", "0");
1398                         camera_active = false;
1399                 }
1400         }
1401         else
1402         {
1403 #ifdef CAMERATEST
1404                 if(autocvar_camera_enable)
1405 #else
1406                 if(autocvar_camera_enable && isdemo())
1407 #endif
1408                 {
1409                         // Enable required Darkplaces cvars
1410                         chase_active_backup = autocvar_chase_active;
1411                         cvar_set("chase_active", "2");
1412                         cvar_set("cl_demo_mousegrab", "1");
1413                         camera_active = true;
1414                         camera_mode = false;
1415                 }
1416         }
1417
1418         // Draw the Crosshair
1419         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1420
1421         // Draw the Engine Status Bar (the default Quake HUD)
1422         setproperty(VF_DRAWENGINESBAR, 0);
1423
1424         // Update the mouse position
1425         /*
1426            mousepos_x = vid_conwidth;
1427            mousepos_y = vid_conheight;
1428            mousepos = mousepos*0.5 + getmousepos();
1429          */
1430
1431         e = self;
1432         for(self = world; (self = nextent(self)); )
1433                 if(self.draw)
1434                         self.draw();
1435         self = e;
1436
1437         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1438         renderscene();
1439
1440         // now switch to 2D drawing mode by calling a 2D drawing function
1441         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1442         // next R_RenderScene call
1443         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1444
1445         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1446         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1447         {
1448                 // apply night vision effect
1449                 vector tc_00, tc_01, tc_10, tc_11;
1450                 vector rgb = '0 0 0';
1451
1452                 if(!nightvision_noise)
1453                 {
1454                         nightvision_noise = spawn();
1455                         nightvision_noise.classname = "nightvision_noise";
1456                 }
1457                 if(!nightvision_noise2)
1458                 {
1459                         nightvision_noise2 = spawn();
1460                         nightvision_noise2.classname = "nightvision_noise2";
1461                 }
1462
1463                 // color tint in yellow
1464                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1465
1466                 // draw BG
1467                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1468                 rgb = '1 1 1';
1469                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1470                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1471                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1472                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1473                 tc_11 = tc_01 + tc_10 - tc_00;
1474                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1475                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1476                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1477                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1478                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1479                 R_EndPolygon();
1480
1481                 // draw FG
1482                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1483                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1484                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1485                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1486                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1487                 tc_11 = tc_01 + tc_10 - tc_00;
1488                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1489                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1490                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1491                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1492                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1493                 R_EndPolygon();
1494         }
1495
1496         if(autocvar_cl_reticle)
1497         {
1498                 // Draw the aiming reticle for weapons that use it
1499                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1500                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1501                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1502                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1503                 {
1504                         // no zoom reticle while dead
1505                         reticle_type = 0;
1506                 }
1507                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1508                 {
1509                         if(reticle_image != "") { reticle_type = 2; }
1510                         else { reticle_type = 0; }
1511                 }
1512                 else if(button_zoom || zoomscript_caught)
1513                 {
1514                         // normal zoom
1515                         reticle_type = 1;
1516                 }
1517
1518                 if(reticle_type)
1519                 {
1520                         if(autocvar_cl_reticle_stretch)
1521                         {
1522                                 reticle_size.x = vid_conwidth;
1523                                 reticle_size.y = vid_conheight;
1524                                 reticle_pos.x = 0;
1525                                 reticle_pos.y = 0;
1526                         }
1527                         else
1528                         {
1529                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1530                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1531                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1532                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1533                         }
1534
1535                         if(zoomscript_caught)
1536                                 f = 1;
1537                         else
1538                                 f = current_zoomfraction;
1539
1540                         if(f)
1541                         {
1542                                 switch(reticle_type)
1543                                 {
1544                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1545                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1546                                 }
1547                         }
1548                 }
1549         }
1550         else
1551         {
1552                 if(reticle_type != 0) { reticle_type = 0; }
1553         }
1554
1555
1556         // improved polyblend
1557         if(autocvar_hud_contents)
1558         {
1559                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1560                 vector liquidcolor;
1561
1562                 switch(pointcontents(view_origin))
1563                 {
1564                         case CONTENT_WATER:
1565                                 liquidalpha = autocvar_hud_contents_water_alpha;
1566                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1567                                 incontent = 1;
1568                                 break;
1569
1570                         case CONTENT_LAVA:
1571                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1572                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1573                                 incontent = 1;
1574                                 break;
1575
1576                         case CONTENT_SLIME:
1577                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1578                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1579                                 incontent = 1;
1580                                 break;
1581
1582                         default:
1583                                 liquidalpha = 0;
1584                                 liquidcolor = '0 0 0';
1585                                 incontent = 0;
1586                                 break;
1587                 }
1588
1589                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1590                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1591                         contentfadetime = autocvar_hud_contents_fadeintime;
1592                         liquidalpha_prev = liquidalpha;
1593                         liquidcolor_prev = liquidcolor;
1594                 }
1595                 else
1596                         contentfadetime = autocvar_hud_contents_fadeouttime;
1597
1598                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1599                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1600
1601                 if(contentavgalpha)
1602                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1603
1604                 if(autocvar_hud_postprocessing)
1605                 {
1606                         if(autocvar_hud_contents_blur && contentavgalpha)
1607                         {
1608                                 content_blurpostprocess.x = 1;
1609                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1610                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1611                         }
1612                         else
1613                         {
1614                                 content_blurpostprocess.x = 0;
1615                                 content_blurpostprocess.y = 0;
1616                                 content_blurpostprocess.z = 0;
1617                         }
1618                 }
1619         }
1620
1621         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1622         {
1623                 splash_size.x = max(vid_conwidth, vid_conheight);
1624                 splash_size.y = max(vid_conwidth, vid_conheight);
1625                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1626                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1627
1628                 float myhealth_flash_temp;
1629                 myhealth = getstati(STAT_HEALTH);
1630
1631                 // fade out
1632                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1633                 // add new damage
1634                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1635
1636                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1637                 pain_threshold = autocvar_hud_damage_pain_threshold;
1638                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1639                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1640
1641                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1642                 {
1643                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1644                 }
1645
1646                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1647
1648                 if(myhealth_prev < 1)
1649                 {
1650                         if(myhealth >= 1)
1651                         {
1652                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1653                                 myhealth_flash_temp = 0;
1654                         }
1655                         else
1656                         {
1657                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1658                         }
1659                 }
1660
1661                 if(spectatee_status == -1 || intermission)
1662                 {
1663                         myhealth_flash = 0; // observing, or match ended
1664                         myhealth_flash_temp = 0;
1665                 }
1666
1667                 myhealth_prev = myhealth;
1668
1669                 // IDEA: change damage color/picture based on player model for robot/alien species?
1670                 // pro: matches model better
1671                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1672                 // maybe different reddish pics?
1673                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1674                 {
1675                         if(autocvar_cl_gentle_damage == 2)
1676                         {
1677                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1678                                 {
1679                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1680                                 }
1681                         }
1682                         else
1683                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1684
1685                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1686                 }
1687                 else
1688                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1689
1690                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1691                 {
1692                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1693                         {
1694                                 damage_blurpostprocess.x = 1;
1695                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1696                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1697                         }
1698                         else
1699                         {
1700                                 damage_blurpostprocess.x = 0;
1701                                 damage_blurpostprocess.y = 0;
1702                                 damage_blurpostprocess.z = 0;
1703                         }
1704                 }
1705         }
1706
1707         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1708         float e2 = (autocvar_hud_powerup != 0);
1709         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1710         {
1711                 // enable or disable rendering types if they are used or not
1712                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1713                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1714
1715                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1716                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1717                 {
1718                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1719                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1720                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1721                         {
1722                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1723                                 old_blurradius = blurradius;
1724                                 old_bluralpha = bluralpha;
1725                         }
1726                 }
1727                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1728                 {
1729                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1730                         old_blurradius = 0;
1731                         old_bluralpha = 0;
1732                 }
1733
1734                 // edge detection postprocess handling done second (used by hud_powerup)
1735                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1736                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1737                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1738
1739                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1740
1741                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1742                 {
1743                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1744                         {
1745                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1746                                 old_sharpen_intensity = sharpen_intensity;
1747                         }
1748                 }
1749                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1750                 {
1751                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1752                         old_sharpen_intensity = 0;
1753                 }
1754
1755                 if(cvar("r_glsl_postprocess") == 0)
1756                         cvar_set("r_glsl_postprocess", "2");
1757         }
1758         else if(cvar("r_glsl_postprocess") == 2)
1759                 cvar_set("r_glsl_postprocess", "0");
1760
1761         if(menu_visible)
1762                 menu_show();
1763
1764         /*if(gametype == MAPINFO_TYPE_CTF)
1765           {
1766           ctf_view();
1767           } else */
1768
1769         // draw 2D entities
1770         e = self;
1771         for(self = world; (self = nextent(self)); )
1772                 if(self.draw2d)
1773                         self.draw2d();
1774         self = e;
1775         Draw_ShowNames_All();
1776
1777         scoreboard_active = HUD_WouldDrawScoreboard();
1778
1779         UpdateDamage();
1780         UpdateCrosshair();
1781         UpdateHitsound();
1782
1783         if(NextFrameCommand)
1784         {
1785                 localcmd("\n", NextFrameCommand, "\n");
1786                 NextFrameCommand = string_null;
1787         }
1788
1789         // we must do this check AFTER a frame was rendered, or it won't work
1790         if(cs_project_is_b0rked == 0)
1791         {
1792                 string w0, h0;
1793                 w0 = ftos(autocvar_vid_conwidth);
1794                 h0 = ftos(autocvar_vid_conheight);
1795                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1796                 //setproperty(VF_FOV, '90 90 0');
1797                 setproperty(VF_ORIGIN, '0 0 0');
1798                 setproperty(VF_ANGLES, '0 0 0');
1799                 setproperty(VF_PERSPECTIVE, 1);
1800                 makevectors('0 0 0');
1801                 vector v1, v2;
1802                 cvar_set("vid_conwidth", "800");
1803                 cvar_set("vid_conheight", "600");
1804                 v1 = cs_project(v_forward);
1805                 cvar_set("vid_conwidth", "640");
1806                 cvar_set("vid_conheight", "480");
1807                 v2 = cs_project(v_forward);
1808                 if(v1 == v2)
1809                         cs_project_is_b0rked = 1;
1810                 else
1811                         cs_project_is_b0rked = -1;
1812                 cvar_set("vid_conwidth", w0);
1813                 cvar_set("vid_conheight", h0);
1814         }
1815
1816         if(autocvar__hud_configure)
1817                 HUD_Panel_Mouse();
1818
1819     if(hud && !intermission)
1820     if(hud == HUD_BUMBLEBEE_GUN)
1821         CSQC_BUMBLE_GUN_HUD();
1822     else
1823                 VEH_ACTION(hud, VR_HUD);
1824
1825         cl_notice_run();
1826
1827         // let's reset the view back to normal for the end
1828         setproperty(VF_MIN, '0 0 0');
1829         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1830 }
1831
1832
1833 void CSQC_common_hud(void)
1834 {
1835         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1836                 Accuracy_LoadLevels();
1837
1838         HUD_Main(); // always run these functions for alpha checks
1839         HUD_DrawScoreboard();
1840
1841         // scoreboard/accuracy, map/gametype voting screen
1842         if (scoreboard_active || intermission == 2)
1843                 HUD_Reset();
1844 }
1845
1846
1847 // following vectors must be global to allow seamless switching between camera modes
1848 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1849 void CSQC_Demo_Camera()
1850 {
1851         float speed, attenuation, dimensions;
1852         vector tmp, delta;
1853
1854         if( autocvar_camera_reset || !camera_mode )
1855         {
1856                 camera_offset = '0 0 0';
1857                 current_angles = '0 0 0';
1858                 camera_direction = '0 0 0';
1859                 camera_offset.z += 30;
1860                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1861                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1862                 current_origin = view_origin;
1863                 current_camera_offset  = camera_offset;
1864                 cvar_set("camera_reset", "0");
1865                 camera_mode = CAMERA_CHASE;
1866         }
1867
1868         // Camera angles
1869         if( camera_roll )
1870                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1871
1872         if(autocvar_camera_look_player)
1873         {
1874                 vector dir;
1875                 float n;
1876
1877                 dir = normalize(view_origin - current_position);
1878                 n = mouse_angles.z;
1879                 mouse_angles = vectoangles(dir);
1880                 mouse_angles.x = mouse_angles.x * -1;
1881                 mouse_angles.z = n;
1882         }
1883         else
1884         {
1885                 tmp = getmousepos() * 0.1;
1886                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1887                 {
1888                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1889                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1890                 }
1891         }
1892
1893         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1894         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1895         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1896         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1897
1898         // Fix difference when angles don't have the same sign
1899         delta = '0 0 0';
1900         if(mouse_angles.y < -60 && current_angles.y > 60)
1901                 delta = '0 360 0';
1902         if(mouse_angles.y > 60 && current_angles.y < -60)
1903                 delta = '0 -360 0';
1904
1905         if(autocvar_camera_look_player)
1906                 attenuation = autocvar_camera_look_attenuation;
1907         else
1908                 attenuation = autocvar_camera_speed_attenuation;
1909
1910         attenuation = 1 / max(1, attenuation);
1911         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1912
1913         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1914         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1915         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1916         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1917
1918         // Camera position
1919         tmp = '0 0 0';
1920         dimensions = 0;
1921
1922         if( camera_direction.x )
1923         {
1924                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1925                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1926                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1927                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1928                 ++dimensions;
1929         }
1930
1931         if( camera_direction.y )
1932         {
1933                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1934                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1935                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1936                 ++dimensions;
1937         }
1938
1939         if( camera_direction.z )
1940         {
1941                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1942                 ++dimensions;
1943         }
1944
1945         if(autocvar_camera_free)
1946                 speed = autocvar_camera_speed_free;
1947         else
1948                 speed = autocvar_camera_speed_chase;
1949
1950         if(dimensions)
1951         {
1952                 speed = speed * sqrt(1 / dimensions);
1953                 camera_offset += tmp * speed;
1954         }
1955
1956         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1957
1958         // Camera modes
1959         if( autocvar_camera_free )
1960         {
1961                 if ( camera_mode == CAMERA_CHASE )
1962                 {
1963                         current_camera_offset = current_origin + current_camera_offset;
1964                         camera_offset = current_origin + camera_offset;
1965                 }
1966
1967                 camera_mode = CAMERA_FREE;
1968                 current_position = current_camera_offset;
1969         }
1970         else
1971         {
1972                 if ( camera_mode == CAMERA_FREE )
1973                 {
1974                         current_origin = view_origin;
1975                         camera_offset = camera_offset - current_origin;
1976                         current_camera_offset = current_camera_offset - current_origin;
1977                 }
1978
1979                 camera_mode = CAMERA_CHASE;
1980
1981                 if(autocvar_camera_chase_smoothly)
1982                         current_origin += (view_origin - current_origin) * attenuation;
1983                 else
1984                         current_origin = view_origin;
1985
1986                 current_position = current_origin + current_camera_offset;
1987         }
1988
1989         setproperty(VF_ANGLES, current_angles);
1990         setproperty(VF_ORIGIN, current_position);
1991 }