qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         Weapon wep = this.activeweapon;
 297         int c = entcs_GetClientColors(current_player);
 298         vector g = weaponentity_glowmod(wep, NULL, c, this);
 299         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 300         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 301                 | EF_NODEPTHTEST)
 302                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 303         for (entity e = this; e; e = e.weaponchild)
 304         {
 305                 e.drawmask = mask;
 306                 e.alpha = a;
 307                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 308                 e.glowmod = g;
 309                 e.csqcmodel_effects = fx;
 310                 CSQCModel_Effects_Apply(e);
 311         }
 312         if(a >= 0)
 313         {
 314                 string name = wep.mdl;
 315                 string newname = wep.wr_viewmodel(wep, this);
 316                 if(newname)
 317                         name = newname;
 318                 bool swap = name != this.name_last;
 319                 // if (swap)
 320                 {
 321                         this.name_last = name;
 322                         CL_WeaponEntity_SetModel(this, name, swap);
 323                         this.viewmodel_origin = this.origin;
 324                         this.viewmodel_angles = this.angles;
 325                 }
 326                 anim_update(this);
 327                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 328                         anim_set(this, this.anim_idle, true, false, false);
 329         }
 330         float f = 0; // 0..1; 0: fully active
 331         float rate = STAT(WEAPONRATEFACTOR);
 332         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 333         if (eta <= 0) f = this.weapon_eta_last;
 334         else switch (this.state)
 335         {
 336                 case WS_RAISE:
 337                 {
 338                         f = eta / max(eta, this.weapon_switchdelay);
 339                         break;
 340                 }
 341                 case WS_DROP:
 342                 {
 343                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_CLEAR:
 347                 {
 348                         f = 1;
 349                         break;
 350                 }
 351         }
 352         this.weapon_eta_last = f;
 353         this.origin = this.viewmodel_origin;
 354         this.angles = this.viewmodel_angles;
 355         this.angles_x = (-90 * f * f);
 356         viewmodel_animate(this);
 357         MUTATOR_CALLHOOK(DrawViewModel, this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 STATIC_INIT(viewmodel) {
 362     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         viewmodels[slot] = new(viewmodel);
 364 }
 365
 366 float showfps_prevfps;
 367 float showfps_prevfps_time;
 368 int showfps_framecounter;
 369
 370 void fpscounter_update()
 371 {
 372         if(!STAT(SHOWFPS))
 373                 return;
 374
 375         float currentTime = gettime(GETTIME_REALTIME);
 376         showfps_framecounter += 1;
 377         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 378         {
 379                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 380                 showfps_framecounter = 0;
 381                 showfps_prevfps_time = currentTime;
 382
 383                 int channel = MSG_C2S;
 384                 WriteHeader(channel, fpsreport);
 385                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 386         }
 387 }
 388
 389 STATIC_INIT(fpscounter_init)
 390 {
 391         float currentTime = gettime(GETTIME_REALTIME);
 392         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 393 }
 394
 395 float drawtime;
 396 float avgspeed;
 397 vector GetCurrentFov(float fov)
 398 {
 399         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 400         float velocityzoom, curspeed;
 401         vector v;
 402
 403         zoomsensitivity = autocvar_cl_zoomsensitivity;
 404         zoomfactor = autocvar_cl_zoomfactor;
 405         if(zoomfactor < 1 || zoomfactor > 30)
 406                 zoomfactor = 2.5;
 407         zoomspeed = autocvar_cl_zoomspeed;
 408         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 409                 zoomspeed = 3.5;
 410
 411         zoomdir = button_zoom;
 412
 413         if(hud == HUD_NORMAL && !spectatee_status)
 414         {
 415                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 416                 {
 417                         entity wepent = viewmodels[slot];
 418                         if(wepent.switchweapon != wepent.activeweapon)
 419                                 continue;
 420                         Weapon wep = wepent.activeweapon;
 421                         if(wep != WEP_Null && wep.wr_zoomdir)
 422                         {
 423                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 424                                 zoomdir += do_zoom;
 425                         }
 426                 }
 427         }
 428         if(spectatee_status > 0 || isdemo())
 429         {
 430                 if(spectatorbutton_zoom)
 431                 {
 432                         if(zoomdir)
 433                                 zoomdir = 0;
 434                         else
 435                                 zoomdir = 1;
 436                 }
 437                 // fteqcc failed twice here already, don't optimize this
 438         }
 439
 440         if(zoomdir) { zoomin_effect = 0; }
 441
 442         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 443         {
 444                 current_viewzoom = 1;
 445         }
 446         else if (camera_active)
 447         {
 448                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 449         }
 450         else if(autocvar_cl_spawnzoom && zoomin_effect)
 451         {
 452                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 453
 454                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 455                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 456                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 457         }
 458         else
 459         {
 460                 if(zoomspeed < 0) // instant zoom
 461                 {
 462                         if(zoomdir)
 463                                 current_viewzoom = 1 / zoomfactor;
 464                         else
 465                                 current_viewzoom = 1;
 466                 }
 467                 else
 468                 {
 469                         if(zoomdir)
 470                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 471                         else
 472                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 473                 }
 474         }
 475
 476         if(almost_equals(current_viewzoom, 1))
 477                 current_zoomfraction = 0;
 478         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 479                 current_zoomfraction = 1;
 480         else
 481                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 482
 483         if(zoomsensitivity < 1)
 484                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 485         else
 486                 setsensitivityscale(1);
 487
 488         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 489         {
 490                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 491                         curspeed = 0;
 492                 else
 493                 {
 494                         makevectors(view_angles);
 495                         v = pmove_vel;
 496                         if(csqcplayer)
 497                                 v = csqcplayer.velocity;
 498
 499                         switch(autocvar_cl_velocityzoom_type)
 500                         {
 501                                 case 3: curspeed = max(0, v_forward * v); break;
 502                                 case 2: curspeed = (v_forward * v); break;
 503                                 case 1: default: curspeed = vlen(v); break;
 504                         }
 505                 }
 506
 507                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 508                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 509                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 510
 511                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 512         }
 513         else
 514                 velocityzoom = 1;
 515
 516         float frustumx, frustumy, fovx, fovy;
 517         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 518         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 519         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 520         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 521
 522         return '1 0 0' * fovx + '0 1 0' * fovy;
 523 }
 524
 525 vector GetViewLocationFOV(float fov)
 526 {
 527         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 528         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 529         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 530         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 531         return '1 0 0' * fovx + '0 1 0' * fovy;
 532 }
 533
 534 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 535 {
 536         float fovx, fovy;
 537         float width = (ov_worldmax.x - ov_worldmin.x);
 538         float height = (ov_worldmax.y - ov_worldmin.y);
 539         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 540         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 541         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 542         return '1 0 0' * fovx + '0 1 0' * fovy;
 543 }
 544
 545 // this function must match W_SetupShot!
 546 float zoomscript_caught;
 547
 548 bool minigame_wasactive;
 549
 550 vector wcross_origin;
 551 float wcross_scale_prev, wcross_alpha_prev;
 552 vector wcross_color_prev;
 553 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 554 vector wcross_color_goal_prev;
 555 float wcross_changedonetime;
 556
 557 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 558 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 559 float wcross_name_changestarttime, wcross_name_changedonetime;
 560 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 561
 562 float wcross_ring_prev;
 563
 564 entity trueaim;
 565 entity trueaim_rifle;
 566
 567 const float SHOTTYPE_HITTEAM = 1;
 568 const float SHOTTYPE_HITOBSTRUCTION = 2;
 569 const float SHOTTYPE_HITWORLD = 3;
 570 const float SHOTTYPE_HITENEMY = 4;
 571
 572 void TrueAim_Init()
 573 {
 574         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 575         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 576 }
 577
 578 float EnemyHitCheck()
 579 {
 580         float t, n;
 581         wcross_origin = project_3d_to_2d(trace_endpos);
 582         wcross_origin.z = 0;
 583         if(trace_ent)
 584                 n = trace_ent.entnum;
 585         else
 586                 n = trace_networkentity;
 587         if(n < 1)
 588                 return SHOTTYPE_HITWORLD;
 589         if(n > maxclients)
 590                 return SHOTTYPE_HITWORLD;
 591         t = entcs_GetTeam(n - 1);
 592         if(teamplay)
 593                 if(t == myteam)
 594                         return SHOTTYPE_HITTEAM;
 595         if(t == NUM_SPECTATOR)
 596                 return SHOTTYPE_HITWORLD;
 597         return SHOTTYPE_HITENEMY;
 598 }
 599
 600 float TrueAimCheck(entity wepent)
 601 {
 602         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 603                 return SHOTTYPE_HITWORLD;
 604
 605         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 606         vector vecs, trueaimpoint, w_shotorg;
 607         vector mi, ma, dv;
 608         float shottype;
 609         entity ta;
 610         float mv;
 611
 612         mi = ma = '0 0 0';
 613         ta = trueaim;
 614         mv = MOVE_NOMONSTERS;
 615
 616         switch(wepent.activeweapon) // WEAPONTODO
 617         {
 618                 case WEP_VORTEX:
 619                 case WEP_OVERKILL_NEX:
 620                 case WEP_VAPORIZER:
 621                         mv = MOVE_NORMAL;
 622                         break;
 623                 case WEP_RIFLE:
 624                         ta = trueaim_rifle;
 625                         mv = MOVE_NORMAL;
 626                         if(zoomscript_caught)
 627                         {
 628                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 629                                 return EnemyHitCheck();
 630                         }
 631                         break;
 632                 case WEP_DEVASTATOR: // projectile has a size!
 633                         mi = '-3 -3 -3';
 634                         ma = '3 3 3';
 635                         break;
 636                 case WEP_FIREBALL: // projectile has a size!
 637                         mi = '-16 -16 -16';
 638                         ma = '16 16 16';
 639                         break;
 640                 case WEP_SEEKER: // projectile has a size!
 641                         mi = '-2 -2 -2';
 642                         ma = '2 2 2';
 643                         break;
 644                 case WEP_ELECTRO: // projectile has a size!
 645                         mi = '0 0 -3';
 646                         ma = '0 0 -3';
 647                         break;
 648         }
 649
 650         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 651
 652         vecs = decompressShotOrigin(STAT(SHOTORG));
 653
 654         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 655         trueaimpoint = trace_endpos;
 656
 657         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 658                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 659
 660         if(vecs.x > 0)
 661                 vecs.y = -vecs.y;
 662         else
 663                 vecs = '0 0 0';
 664
 665         dv = view_right * vecs.y + view_up * vecs.z;
 666         w_shotorg = traceorigin + dv;
 667
 668         // now move the vecs forward as much as requested if possible
 669         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 670         w_shotorg = trace_endpos - view_forward * nudge;
 671
 672         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 673         shottype = EnemyHitCheck();
 674         if(shottype != SHOTTYPE_HITWORLD)
 675                 return shottype;
 676
 677 #if 0
 678         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 679         // or rather, I know why, but see no fix
 680         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 681                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 682                 return SHOTTYPE_HITOBSTRUCTION;
 683 #endif
 684
 685         return SHOTTYPE_HITWORLD;
 686 }
 687
 688 float camera_mode;
 689 const float CAMERA_FREE = 1;
 690 const float CAMERA_CHASE = 2;
 691 float reticle_type;
 692 string NextFrameCommand;
 693
 694 vector freeze_org, freeze_ang;
 695 entity nightvision_noise, nightvision_noise2;
 696
 697 const float MAX_TIME_DIFF = 5;
 698 float pickup_crosshair_time, pickup_crosshair_size;
 699 float hitindication_crosshair_size;
 700 float use_vortex_chargepool;
 701
 702 float myhealth, myhealth_prev;
 703 float myhealth_flash;
 704
 705 float old_blurradius, old_bluralpha;
 706 float old_sharpen_intensity;
 707
 708 vector myhealth_gentlergb;
 709
 710 float contentavgalpha, liquidalpha_prev;
 711 vector liquidcolor_prev;
 712
 713 float eventchase_current_distance;
 714 float eventchase_running;
 715 int WantEventchase(entity this)
 716 {
 717         if(autocvar_cl_orthoview)
 718                 return 0;
 719         if(STAT(GAME_STOPPED) || intermission)
 720                 return 1;
 721         if(this.viewloc)
 722                 return 1;
 723         if(spectatee_status >= 0)
 724         {
 725                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 726                         return 1;
 727                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 728                         return 1;
 729                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 730                         return 1;
 731                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 732                 {
 733                         if(autocvar_cl_eventchase_death == 2)
 734                         {
 735                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 736                                 if(this.velocity == '0 0 0' || eventchase_running)
 737                                         return 1;
 738                         }
 739                         else return 1;
 740                 }
 741                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 742                 {
 743                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 744                                 return 1;
 745                         else if (eventchase_running)
 746                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 747                 }
 748         }
 749         return 0;
 750 }
 751
 752 void HUD_Crosshair_Vehicle(entity this)
 753 {
 754         if(hud != HUD_BUMBLEBEE_GUN)
 755         {
 756                 Vehicle info = Vehicles_from(hud);
 757                 info.vr_crosshair(info, this);
 758         }
 759 }
 760
 761 vector damage_blurpostprocess, content_blurpostprocess;
 762
 763 float unaccounted_damage = 0;
 764 void UpdateDamage()
 765 {
 766         // accumulate damage with each stat update
 767         static float damage_total_prev = 0;
 768         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 769         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 770         damage_total_prev = damage_total;
 771
 772         static float damage_dealt_time_prev = 0;
 773         float damage_dealt_time = STAT(HIT_TIME);
 774         if (damage_dealt_time != damage_dealt_time_prev)
 775         {
 776                 unaccounted_damage += unaccounted_damage_new;
 777                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 778         }
 779         damage_dealt_time_prev = damage_dealt_time;
 780
 781         // prevent hitsound when switching spectatee
 782         static float spectatee_status_prev = 0;
 783         if (spectatee_status != spectatee_status_prev)
 784                 unaccounted_damage = 0;
 785         spectatee_status_prev = spectatee_status;
 786 }
 787
 788 void HitSound()
 789 {
 790         // varying sound pitch
 791
 792         bool have_arc = false;
 793         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 794         {
 795                 entity wepent = viewmodels[slot];
 796
 797                 if(wepent.activeweapon == WEP_ARC)
 798                         have_arc = true;
 799         }
 800
 801         static float hitsound_time_prev = 0;
 802         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 803         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 804         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 805         {
 806                 if (autocvar_cl_hitsound && unaccounted_damage)
 807                 {
 808                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 809                         float a = autocvar_cl_hitsound_max_pitch;
 810                         float b = autocvar_cl_hitsound_min_pitch;
 811                         float c = autocvar_cl_hitsound_nom_damage;
 812                         float d = unaccounted_damage;
 813                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 814
 815                         // if sound variation is disabled, set pitch_shift to 1
 816                         if (autocvar_cl_hitsound == 1)
 817                                 pitch_shift = 1;
 818
 819                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 820                         if (autocvar_cl_hitsound == 3)
 821                         {
 822                                 float mirror_value = (a-b)/2 + b;
 823                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 824                         }
 825
 826                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 827
 828                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 829                         // todo: normalize sound pressure levels? seems unnecessary
 830
 831                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 832                 }
 833                 unaccounted_damage = 0;
 834                 hitsound_time_prev = time;
 835         }
 836
 837         static float typehit_time_prev = 0;
 838         float typehit_time = STAT(TYPEHIT_TIME);
 839         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 840         {
 841                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 842                 typehit_time_prev = typehit_time;
 843         }
 844
 845         static float kill_time_prev = 0;
 846         float kill_time = STAT(KILL_TIME);
 847         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 848         {
 849                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 850                 kill_time_prev = kill_time;
 851         }
 852 }
 853
 854 vector crosshair_getcolor(entity this, float health_stat)
 855 {
 856         static float rainbow_last_flicker;
 857         static vector rainbow_prev_color;
 858         vector wcross_color = '0 0 0';
 859         switch(autocvar_crosshair_color_special)
 860         {
 861                 case 1: // crosshair_color_per_weapon
 862                 {
 863                         if(this != WEP_Null && hud == HUD_NORMAL)
 864                         {
 865                                 wcross_color = this.wpcolor;
 866                                 break;
 867                         }
 868                         else { goto normalcolor; }
 869                 }
 870
 871                 case 2: // crosshair_color_by_health
 872                 {
 873                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 874                         float hp = floor(v.x + 1);
 875
 876                         //x = red
 877                         //y = green
 878                         //z = blue
 879
 880                         wcross_color.z = 0;
 881
 882                         if(hp > 200)
 883                         {
 884                                 wcross_color.x = 0;
 885                                 wcross_color.y = 1;
 886                         }
 887                         else if(hp > 150)
 888                         {
 889                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 890                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 891                         }
 892                         else if(hp > 100)
 893                         {
 894                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 895                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 896                                 wcross_color.z = 1 - (hp-100)*0.02;
 897                         }
 898                         else if(hp > 50)
 899                         {
 900                                 wcross_color.x = 1;
 901                                 wcross_color.y = 1;
 902                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 903                         }
 904                         else if(hp > 20)
 905                         {
 906                                 wcross_color.x = 1;
 907                                 wcross_color.y = (hp-20)*90/27/100;
 908                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 909                         }
 910                         else
 911                         {
 912                                 wcross_color.x = 1;
 913                                 wcross_color.y = 0;
 914                         }
 915                         break;
 916                 }
 917
 918                 case 3: // crosshair_color_rainbow
 919                 {
 920                         if(time >= rainbow_last_flicker)
 921                         {
 922                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 923                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 924                         }
 925                         wcross_color = rainbow_prev_color;
 926                         break;
 927                 }
 928 LABEL(normalcolor)
 929                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 930         }
 931
 932         return wcross_color;
 933 }
 934
 935 void HUD_Crosshair(entity this)
 936 {
 937         float f, i, j;
 938         vector v;
 939         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 940                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 941                 !HUD_MinigameMenu_IsOpened() )
 942         {
 943                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 944                         return;
 945
 946                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 947                         return;
 948
 949                 if (hud != HUD_NORMAL)
 950                 {
 951                         HUD_Crosshair_Vehicle(this);
 952                         return;
 953                 }
 954
 955                 string wcross_style;
 956                 float wcross_alpha, wcross_resolution;
 957                 wcross_style = autocvar_crosshair;
 958                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 959                         wcross_style = autocvar_crosshair_2d;
 960                 if (wcross_style == "0")
 961                         return;
 962                 wcross_resolution = autocvar_crosshair_size;
 963                 if (wcross_resolution == 0)
 964                         return;
 965                 wcross_alpha = autocvar_crosshair_alpha;
 966                 if (wcross_alpha == 0)
 967                         return;
 968
 969                 // TrueAim check
 970                 float shottype;
 971
 972                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 973                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 974                         wcross_origin = viewloc_mousepos;
 975                 else
 976                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 977                 wcross_origin.z = 0;
 978                 if(autocvar_crosshair_hittest)
 979                 {
 980                         vector wcross_oldorigin;
 981                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 982                         wcross_oldorigin = wcross_origin;
 983                         shottype = TrueAimCheck(thiswep);
 984                         if(shottype == SHOTTYPE_HITWORLD)
 985                         {
 986                                 v = wcross_origin - wcross_oldorigin;
 987                                 v.x /= vid_conwidth;
 988                                 v.y /= vid_conheight;
 989                                 if(vdist(v, >, 0.01))
 990                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 991                         }
 992                         if(!autocvar_crosshair_hittest_showimpact)
 993                                 wcross_origin = wcross_oldorigin;
 994                 }
 995                 else
 996                         shottype = SHOTTYPE_HITWORLD;
 997
 998                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 999                 string wcross_name = "";
1000                 float wcross_scale, wcross_blur;
1001
1002         entity e = WEP_Null;
1003                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1004                 {
1005                         entity wepent = viewmodels[0]; // TODO: unhardcode
1006                         e = wepent.switchingweapon;
1007                         if(e)
1008                         {
1009                                 if(autocvar_crosshair_per_weapon)
1010                                 {
1011                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1012                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1013                                         //if (wcross_resolution == 0)
1014                                                 //return;
1015
1016                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1017                                         wcross_resolution *= e.w_crosshair_size;
1018                                         wcross_name = e.w_crosshair;
1019                                 }
1020                         }
1021                 }
1022
1023                 if(wcross_name == "")
1024                         wcross_name = strcat("gfx/crosshair", wcross_style);
1025
1026                 // MAIN CROSSHAIR COLOR DECISION
1027                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1028
1029                 if(autocvar_crosshair_effect_scalefade)
1030                 {
1031                         wcross_scale = wcross_resolution;
1032                         wcross_resolution = 1;
1033                 }
1034                 else
1035                 {
1036                         wcross_scale = 1;
1037                 }
1038
1039                 if(autocvar_crosshair_pickup)
1040                 {
1041                         float stat_pickup_time = STAT(LAST_PICKUP);
1042
1043                         if(pickup_crosshair_time < stat_pickup_time)
1044                         {
1045                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1046                                         pickup_crosshair_size = 1;
1047
1048                                 pickup_crosshair_time = stat_pickup_time;
1049                         }
1050
1051                         if(pickup_crosshair_size > 0)
1052                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1053                         else
1054                                 pickup_crosshair_size = 0;
1055
1056                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1057                 }
1058
1059                 // todo: make crosshair hit indication dependent on damage dealt
1060                 if(autocvar_crosshair_hitindication)
1061                 {
1062                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1063
1064                         if(unaccounted_damage)
1065                         {
1066                                 hitindication_crosshair_size = 1;
1067                         }
1068
1069                         if(hitindication_crosshair_size > 0)
1070                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1071                         else
1072                                 hitindication_crosshair_size = 0;
1073
1074                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1075                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1076                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1077                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1078                 }
1079
1080                 if(shottype == SHOTTYPE_HITENEMY)
1081                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1082                 if(shottype == SHOTTYPE_HITTEAM)
1083                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1084
1085                 f = fabs(autocvar_crosshair_effect_time);
1086                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1087                 {
1088                         wcross_changedonetime = time + f;
1089                 }
1090                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1091                 {
1092                         wcross_name_changestarttime = time;
1093                         wcross_name_changedonetime = time + f;
1094                         if(wcross_name_goal_prev_prev)
1095                                 strunzone(wcross_name_goal_prev_prev);
1096                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1097                         wcross_name_goal_prev = strzone(wcross_name);
1098                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1099                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1100                         wcross_resolution_goal_prev = wcross_resolution;
1101                 }
1102
1103                 wcross_scale_goal_prev = wcross_scale;
1104                 wcross_alpha_goal_prev = wcross_alpha;
1105                 wcross_color_goal_prev = wcross_color;
1106
1107                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1108                 {
1109                         wcross_blur = 1;
1110                         wcross_alpha *= 0.75;
1111                 }
1112                 else
1113                         wcross_blur = 0;
1114                 // *_prev is at time-frametime
1115                 // * is at wcross_changedonetime+f
1116                 // what do we have at time?
1117                 if(time < wcross_changedonetime)
1118                 {
1119                         f = frametime / (wcross_changedonetime - time + frametime);
1120                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1121                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1122                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1123                 }
1124
1125                 wcross_scale_prev = wcross_scale;
1126                 wcross_alpha_prev = wcross_alpha;
1127                 wcross_color_prev = wcross_color;
1128
1129                 MUTATOR_CALLHOOK(UpdateCrosshair);
1130
1131                 wcross_scale *= 1 - autocvar__menu_alpha;
1132                 wcross_alpha *= 1 - autocvar__menu_alpha;
1133                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1134
1135                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1136                 {
1137                         // crosshair rings for weapon stats
1138                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1139                         {
1140                                 // declarations and stats
1141                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1142                                 string ring_image = string_null, ring_inner_image = string_null;
1143                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1144
1145                                 ring_scale = autocvar_crosshair_ring_size;
1146
1147                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1148
1149                                 int weapon_clipload = wepent.clip_load;
1150                                 int weapon_clipsize = wepent.clip_size;
1151
1152                                 float arc_heat = wepent.arc_heat_percent;
1153                                 float vcharge = wepent.vortex_charge;
1154                                 float vchargepool = wepent.vortex_chargepool_ammo;
1155                                 float oknex_charge_ = wepent.oknex_charge;
1156                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1157
1158                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1159                                         vortex_charge_movingavg = vcharge;
1160
1161                                 // handle the values
1162                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1163                                 {
1164                                         if (vchargepool || use_vortex_chargepool) {
1165                                                 use_vortex_chargepool = 1;
1166                                                 ring_inner_value = vchargepool;
1167                                         } else {
1168                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1169                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1170                                         }
1171
1172                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1173                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1174                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1175
1176                                         // draw the outer ring to show the current charge of the weapon
1177                                         ring_value = vcharge;
1178                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1179                                         ring_rgb = wcross_color;
1180                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1181                                 }
1182                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1183                                 {
1184                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1185                                                 use_vortex_chargepool = 1;
1186                                                 ring_inner_value = oknex_chargepool_;
1187                                         } else {
1188                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1189                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1190                                         }
1191
1192                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1193                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1194                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1195
1196                                         // draw the outer ring to show the current charge of the weapon
1197                                         ring_value = oknex_charge_;
1198                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1199                                         ring_rgb = wcross_color;
1200                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1201                                 }
1202                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1203                                 {
1204                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1205                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1206                                         ring_rgb = wcross_color;
1207                                         ring_image = "gfx/crosshair_ring.tga";
1208                                 }
1209                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1210                                 {
1211                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1212                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1213                                         ring_rgb = wcross_color;
1214                                         ring_image = "gfx/crosshair_ring.tga";
1215                                 }
1216                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1217                                 {
1218                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1219                                         ring_scale = autocvar_crosshair_ring_reload_size;
1220                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1221                                         ring_rgb = wcross_color;
1222
1223                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1224                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1225                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1226                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1227                                         else
1228                                                 ring_image = "gfx/crosshair_ring.tga";
1229                                 }
1230                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1231                                 {
1232                                         ring_value = arc_heat;
1233                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1234                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1235                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1236                                         ring_image = "gfx/crosshair_ring.tga";
1237                                 }
1238
1239                                 // if in weapon switch animation, fade ring out/in
1240                                 if(autocvar_crosshair_effect_time > 0)
1241                                 {
1242                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1243                                         if (f >= 1)
1244                                         {
1245                                                 wcross_ring_prev = ((ring_image) ? true : false);
1246                                         }
1247
1248                                         if(wcross_ring_prev)
1249                                         {
1250                                                 if(f < 1)
1251                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1252                                         }
1253                                         else
1254                                         {
1255                                                 if(f < 1)
1256                                                         ring_alpha *= bound(0, f, 1);
1257                                         }
1258                                 }
1259
1260                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1261                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1262
1263                                 if (ring_value)
1264                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1265                         }
1266
1267 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1268                         MACRO_BEGIN \
1269                                 vector scaled_sz = sz * wcross_size; \
1270                                 if(wcross_blur > 0) \
1271                                 { \
1272                                         for(i = -2; i <= 2; ++i) \
1273                                         for(j = -2; j <= 2; ++j) \
1274                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1275                                 } \
1276                                 else \
1277                                 { \
1278                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1279                                 } \
1280                         MACRO_END
1281
1282 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1283                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1284
1285 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1286                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1287
1288                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1289                         {
1290                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1291                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1292                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1293                                 f = 1 - f;
1294                         }
1295                         else
1296                         {
1297                                 f = 1;
1298                         }
1299                         wcross_name_alpha_goal_prev = f;
1300
1301                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1302                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1303
1304                         if(autocvar_crosshair_dot)
1305                         {
1306                                 vector wcross_color_old;
1307                                 wcross_color_old = wcross_color;
1308
1309                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1310                                         wcross_color = stov(autocvar_crosshair_dot_color);
1311
1312                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1313                                 // FIXME why don't we use wcross_alpha here?
1314                                 wcross_color = wcross_color_old;
1315                         }
1316                 }
1317         }
1318         else
1319         {
1320                 wcross_scale_prev = 0;
1321                 wcross_alpha_prev = 0;
1322                 wcross_scale_goal_prev = 0;
1323                 wcross_alpha_goal_prev = 0;
1324                 wcross_changedonetime = 0;
1325                 strfree(wcross_name_goal_prev);
1326                 strfree(wcross_name_goal_prev_prev);
1327                 wcross_name_changestarttime = 0;
1328                 wcross_name_changedonetime = 0;
1329                 wcross_name_alpha_goal_prev = 0;
1330                 wcross_name_alpha_goal_prev_prev = 0;
1331                 wcross_resolution_goal_prev = 0;
1332                 wcross_resolution_goal_prev_prev = 0;
1333         }
1334 }
1335
1336 const int MAX_SPECIALCOMMAND = 15;
1337 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1338 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1339 const float SPECIALCOMMAND_SPEED = 150;
1340 const float SPECIALCOMMAND_TURNSPEED = 2;
1341 const float SPECIALCOMMAND_SIZE = 0.025;
1342 const float SPECIALCOMMAND_CHANCE = 0.35;
1343 float sc_spawntime, sc_changetime;
1344 vector sc_color = '1 1 1';
1345 void SpecialCommand()
1346 {
1347         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1348                 return;
1349
1350         if(time >= sc_changetime)
1351         {
1352                 sc_changetime = time + 1;
1353                 sc_color = randomvec() * 1.5;
1354                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1355                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1356                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1357         }
1358         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1359
1360         if(!precache_pic("gfx/smile"))
1361                 return; // damn party poopers
1362
1363         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1364         {
1365                 vector slot = specialcommand_slots[j];
1366                 if(slot.y)
1367                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1368                 //if(slot.z)
1369                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1370                 if(slot.y >= vid_conheight)
1371                         slot = '0 0 0';
1372
1373                 if(slot == '0 0 0')
1374                 {
1375                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1376                         {
1377                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1378                                 slot.y = 1; // start it off 0 so we can use it
1379                                 slot.z = floor(random() * Weapons_MAX);
1380                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1381                                 vector newcolor = randomvec() * 2;
1382                                 newcolor.x = bound(0.4, newcolor.x, 1);
1383                                 newcolor.y = bound(0.4, newcolor.y, 1);
1384                                 newcolor.z = bound(0.4, newcolor.z, 1);
1385                                 specialcommand_colors[j] = newcolor;
1386                         }
1387                 }
1388                 else
1389                 {
1390                         vector splash_size = '0 0 0';
1391                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1392                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1393                         entity wep = Weapons_from(slot.z);
1394                         if(wep == WEP_Null)
1395                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1396                         else
1397                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1398                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1399                 }
1400
1401                 specialcommand_slots[j] = slot;
1402         }
1403 }
1404
1405 void HUD_Draw(entity this)
1406 {
1407         // if we don't know gametype and scores yet avoid drawing the scoreboard
1408         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1409         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1410         // cl_deathscoreboard would show the scoreboard and so on
1411         if(!gametype)
1412                 return;
1413
1414         Hud_Dynamic_Frame();
1415
1416         if(!intermission)
1417         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1418         {
1419                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1420         }
1421         else if(STAT(FROZEN))
1422         {
1423                 vector col = '0.25 0.90 1';
1424                 if(STAT(REVIVE_PROGRESS))
1425                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1426                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1427         }
1428
1429         HUD_Scale_Enable();
1430         if(!intermission)
1431         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1432         {
1433                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1434                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1435                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1436         }
1437         else if(STAT(CAPTURE_PROGRESS))
1438         {
1439                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1440                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1441         }
1442         else if(STAT(REVIVE_PROGRESS))
1443         {
1444                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1445                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1446         }
1447         HUD_Scale_Disable();
1448
1449         if(autocvar_r_letterbox == 0)
1450                 if(autocvar_viewsize < 120)
1451                 {
1452                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1453                                 Accuracy_LoadLevels();
1454
1455                         HUD_Main();
1456                         HUD_Scale_Disable();
1457                 }
1458
1459         // crosshair goes VERY LAST
1460         SpecialCommand();
1461         UpdateDamage();
1462         HUD_Crosshair(this);
1463         HitSound();
1464 }
1465
1466 void ViewLocation_Mouse()
1467 {
1468         if(spectatee_status)
1469                 return; // don't draw it as spectator!
1470
1471         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1472         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1473         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1474
1475         //float cursor_alpha = 1 - autocvar__menu_alpha;
1476         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1477 }
1478
1479 void HUD_Cursor_Show()
1480 {
1481         float cursor_alpha = 1 - autocvar__menu_alpha;
1482         if(cursor_type == CURSOR_NORMAL)
1483                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1484         else if(cursor_type == CURSOR_MOVE)
1485                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1486         else if(cursor_type == CURSOR_RESIZE)
1487                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1488         else if(cursor_type == CURSOR_RESIZE2)
1489                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1490 }
1491
1492 void HUD_Mouse(entity player)
1493 {
1494         if(autocvar__menu_alpha == 1)
1495                 return;
1496
1497         if(!cursor_active)
1498         {
1499                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1500                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1501                 return;
1502         }
1503
1504         if (cursor_active == -1) // starting to display the cursor
1505         {
1506                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1507                 // in the first frame mousepos is the mouse position of the last time
1508                 // the cursor was displayed, thus we ignore it to avoid a glictch
1509                 cursor_active = 1;
1510                 return;
1511         }
1512
1513         if(!autocvar_hud_cursormode)
1514                 update_mousepos();
1515
1516         if(autocvar__hud_configure)
1517                 HUD_Panel_Mouse();
1518         else
1519         {
1520                 if (HUD_MinigameMenu_IsOpened())
1521                         HUD_Minigame_Mouse();
1522                 if (QuickMenu_IsOpened())
1523                         QuickMenu_Mouse();
1524                 if (HUD_Radar_Clickable())
1525                         HUD_Radar_Mouse();
1526         }
1527
1528         prevMouseClicked = mouseClicked;
1529
1530         HUD_Cursor_Show();
1531 }
1532
1533 bool ov_enabled;
1534 float oldr_nearclip;
1535 float oldr_farclip_base;
1536 float oldr_farclip_world;
1537 float oldr_novis;
1538 float oldr_useportalculling;
1539 float oldr_useinfinitefarclip;
1540
1541 float prev_myteam;
1542 int lasthud;
1543 float vh_notice_time;
1544 void CSQC_UpdateView(entity this, float w, float h)
1545 {
1546         TC(int, w); TC(int, h);
1547         entity e;
1548         float fov;
1549         float f;
1550         vector vf_size, vf_min;
1551         float a;
1552
1553         execute_next_frame();
1554
1555         ++framecount;
1556
1557         stats_get();
1558         hud = STAT(HUD);
1559
1560         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1561                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1562
1563         lasthud = hud;
1564
1565         // TODO maybe don't send cvar values until the menu is open
1566         // TODO remove CheckSendCvars from menu code (it seems broken anyway)
1567         // TODO remove references to sendcvar from cvar descriptions
1568
1569         ReplicateVars(false);
1570         if (ReplicateVars_NOT_SENDING())
1571                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1572
1573         HUD_Scale_Disable();
1574
1575         if(autocvar__hud_showbinds_reload) // menu can set this one
1576         {
1577                 db_close(binddb);
1578                 binddb = db_create();
1579                 cvar_set("_hud_showbinds_reload", "0");
1580         }
1581
1582         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1583                 view_quality = getproperty(VF_MINFPS_QUALITY);
1584         else
1585                 view_quality = 1;
1586
1587         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1588         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1589
1590         vf_size = getpropertyvec(VF_SIZE);
1591         vf_min = getpropertyvec(VF_MIN);
1592         vid_width = vf_size.x;
1593         vid_height = vf_size.y;
1594
1595         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1596         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1597
1598         WaypointSprite_Load();
1599
1600         CSQCPlayer_SetCamera();
1601
1602         if(player_localentnum <= maxclients) // is it a client?
1603                 current_player = player_localentnum - 1;
1604         else // then player_localentnum is the vehicle I'm driving
1605                 current_player = player_localnum;
1606         myteam = entcs_GetTeam(current_player);
1607
1608         if(myteam != prev_myteam)
1609         {
1610                 myteamcolors = colormapPaletteColor(myteam, 1);
1611                 FOREACH(hud_panels, true, it.update_time = time);
1612                 prev_myteam = myteam;
1613         }
1614
1615         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1616
1617         float is_dead = (STAT(HEALTH) <= 0);
1618
1619         // FIXME do we need this hack?
1620         if(isdemo())
1621         {
1622                 // in demos, input_buttons do not work
1623                 button_zoom = (autocvar__togglezoom == "-");
1624         }
1625         else if(button_zoom
1626                 && autocvar_cl_unpress_zoom_on_death
1627                 && (spectatee_status >= 0)
1628                 && (is_dead || intermission))
1629         {
1630                 // no zoom while dead or in intermission please
1631                 localcmd("-zoom\n");
1632                 button_zoom = false;
1633         }
1634
1635         // abused multiple places below
1636         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1637         if(!local_player)
1638                 local_player = this; // fall back!
1639
1640         // event chase camera
1641         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1642         {
1643                 if(STAT(CAMERA_SPECTATOR))
1644                 {
1645                         if(spectatee_status > 0)
1646                         {
1647                                 if(!autocvar_chase_active)
1648                                 {
1649                                         cvar_set("chase_active", "-2");
1650                                         goto skip_eventchase_death;
1651                                 }
1652                         }
1653                         else if(autocvar_chase_active == -2)
1654                                 cvar_set("chase_active", "0");
1655
1656                         if(autocvar_chase_active == -2)
1657                                 goto skip_eventchase_death;
1658                 }
1659                 else if(autocvar_chase_active == -2)
1660                         cvar_set("chase_active", "0");
1661
1662                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1663
1664                 float vehicle_viewdist = 0;
1665                 vector vehicle_viewofs = '0 0 0';
1666
1667                 if(vehicle_chase)
1668                 {
1669                         if(hud != HUD_BUMBLEBEE_GUN)
1670                         {
1671                                 Vehicle info = Vehicles_from(hud);
1672                                 vehicle_viewdist = info.height;
1673                                 vehicle_viewofs = info.view_ofs;
1674                         }
1675                 }
1676
1677                 int eventchase = WantEventchase(this);
1678                 if (eventchase)
1679                 {
1680                         vector current_view_origin_override = '0 0 0';
1681                         vector view_offset_override = '0 0 0';
1682                         float chase_distance_override = 0;
1683                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1684                         if(custom_eventchase)
1685                         {
1686                                 current_view_origin_override = M_ARGV(0, vector);
1687                                 view_offset_override = M_ARGV(1, vector);
1688                                 chase_distance_override = M_ARGV(0, float);
1689                         }
1690                         eventchase_running = true;
1691
1692                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1693                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1694                         if (custom_eventchase)
1695                                 current_view_origin = current_view_origin_override;
1696
1697                         // detect maximum viewoffset and use it
1698                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1699                         if(vehicle_chase)
1700                         {
1701                                 if(vehicle_viewofs)
1702                                         view_offset = vehicle_viewofs;
1703                                 else
1704                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1705                         }
1706                         if (custom_eventchase)
1707                                 view_offset = view_offset_override;
1708
1709                         if(view_offset)
1710                         {
1711                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1712                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1713                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1714                         }
1715
1716                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1717                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1718                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1719                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1720
1721                         // make the camera smooth back
1722                         float chase_distance = autocvar_cl_eventchase_distance;
1723                         if(vehicle_chase)
1724                         {
1725                                 if(vehicle_viewofs)
1726                                         chase_distance = vehicle_viewdist;
1727                                 else
1728                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1729                         }
1730                         if (custom_eventchase)
1731                                 chase_distance = chase_distance_override;
1732
1733                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1734                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1735                         else if(eventchase_current_distance != chase_distance)
1736                                 eventchase_current_distance = chase_distance;
1737
1738                         makevectors(view_angles);
1739
1740                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1741                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1742
1743                         // If the boxtrace fails, revert back to line tracing.
1744                         if(!local_player.viewloc)
1745                         if(trace_startsolid)
1746                         {
1747                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1748                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1749                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1750                         }
1751                         else { setproperty(VF_ORIGIN, trace_endpos); }
1752
1753                         if(!local_player.viewloc)
1754                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1755                 }
1756
1757                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1758                 {
1759                         eventchase_running = false;
1760                         cvar_set("chase_active", "0");
1761                         eventchase_current_distance = 0; // start from 0 next time
1762                 }
1763         }
1764         // workaround for camera stuck between player's legs when using chase_active 1
1765         // because the engine stops updating the chase_active camera when the game ends
1766         else if(intermission)
1767         {
1768                 cvar_settemp("chase_active", "-1");
1769                 eventchase_current_distance = 0;
1770         }
1771
1772         LABEL(skip_eventchase_death);
1773
1774         // do lockview after event chase camera so that it still applies whenever necessary.
1775         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1776         {
1777                 setproperty(VF_ORIGIN, freeze_org);
1778                 setproperty(VF_ANGLES, freeze_ang);
1779         }
1780         else
1781         {
1782                 freeze_org = getpropertyvec(VF_ORIGIN);
1783                 freeze_ang = getpropertyvec(VF_ANGLES);
1784         }
1785
1786         WarpZone_FixView();
1787         //WarpZone_FixPMove();
1788
1789         vector ov_org = '0 0 0';
1790         vector ov_mid = '0 0 0';
1791         vector ov_worldmin = '0 0 0';
1792         vector ov_worldmax = '0 0 0';
1793         if(autocvar_cl_orthoview)
1794         {
1795                 ov_worldmin = mi_picmin;
1796                 ov_worldmax = mi_picmax;
1797
1798                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1799                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1800                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1801
1802                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1803                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1804
1805                 float ov_nearest = vlen(ov_org - vec3(
1806                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1807                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1808                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1809                 ));
1810
1811                 float ov_furthest = 0;
1812                 float dist = 0;
1813
1814                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1815                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1816                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1817                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1818                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1819                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1820                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1821                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1822
1823                 if(!ov_enabled)
1824                 {
1825                         oldr_nearclip = cvar("r_nearclip");
1826                         oldr_farclip_base = cvar("r_farclip_base");
1827                         oldr_farclip_world = cvar("r_farclip_world");
1828                         oldr_novis = cvar("r_novis");
1829                         oldr_useportalculling = cvar("r_useportalculling");
1830                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1831                 }
1832
1833                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1834                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1835                 cvar_settemp("r_farclip_world", "0");
1836                 cvar_settemp("r_novis", "1");
1837                 cvar_settemp("r_useportalculling", "0");
1838                 cvar_settemp("r_useinfinitefarclip", "0");
1839
1840                 setproperty(VF_ORIGIN, ov_org);
1841                 setproperty(VF_ANGLES, '90 0 0');
1842
1843                 ov_enabled = true;
1844
1845                 #if 0
1846                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1847                         vtos(ov_org),
1848                         vtos(getpropertyvec(VF_ANGLES)),
1849                         ov_distance,
1850                         ov_nearest,
1851                         ov_furthest);
1852                 #endif
1853         }
1854         else
1855         {
1856                 if(ov_enabled)
1857                 {
1858                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1859                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1860                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1861                         cvar_set("r_novis", ftos(oldr_novis));
1862                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1863                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1864                 }
1865                 ov_enabled = false;
1866         }
1867
1868         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1869         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1870         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1871                 viewmodel_draw(viewmodels[slot]);
1872
1873         // Render the Scene
1874         view_origin = getpropertyvec(VF_ORIGIN);
1875         view_angles = getpropertyvec(VF_ANGLES);
1876         MAKEVECTORS(makevectors, view_angles, view_forward, view_right, view_up);
1877
1878 #ifdef BLURTEST
1879         if(time > blurtest_time0 && time < blurtest_time1)
1880         {
1881                 float r, t;
1882
1883                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1884                 r = t * blurtest_radius;
1885                 f = 1 / (t ** blurtest_power) - 1;
1886
1887                 cvar_set("r_glsl_postprocess", "1");
1888                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1889         }
1890         else
1891         {
1892                 cvar_set("r_glsl_postprocess", "0");
1893                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1894         }
1895 #endif
1896
1897         TargetMusic_Advance();
1898         Fog_Force();
1899         fpscounter_update();
1900
1901         if(drawtime == 0)
1902                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1903         else
1904                 drawframetime = bound(0.000001, time - drawtime, 1);
1905         drawtime = time;
1906
1907         // watch for gametype changes here...
1908         // in ParseStuffCMD the cmd isn't executed yet :/
1909         // might even be better to add the gametype to TE_CSQC_INIT...?
1910         if(!postinit)
1911                 PostInit();
1912
1913         if(intermission && !intermission_time)
1914                 intermission_time = time;
1915
1916         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1917         {
1918                 if(calledhooks & HOOK_START)
1919                 {
1920                         localcmd("\ncl_hook_gameend\n");
1921                         calledhooks |= HOOK_END;
1922                 }
1923         }
1924
1925         Announcer();
1926
1927         fov = autocvar_fov;
1928         if(fov <= 59.5)
1929         {
1930                 if(!zoomscript_caught)
1931                 {
1932                         localcmd("+button9\n");
1933                         zoomscript_caught = 1;
1934                 }
1935         }
1936         else
1937         {
1938                 if(zoomscript_caught)
1939                 {
1940                         localcmd("-button9\n");
1941                         zoomscript_caught = 0;
1942                 }
1943         }
1944
1945         if(active_minigame && HUD_MinigameMenu_IsOpened())
1946         {
1947                 if(!minigame_wasactive)
1948                 {
1949                         localcmd("+button12\n");
1950                         minigame_wasactive = true;
1951                 }
1952         }
1953         else if(minigame_wasactive)
1954         {
1955                 localcmd("-button12\n");
1956                 minigame_wasactive = false;
1957         }
1958
1959         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1960
1961         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1962         {
1963                 entity wepent = viewmodels[slot];
1964
1965                 if(wepent.last_switchweapon != wepent.switchweapon)
1966                 {
1967                         weapontime = time;
1968                         wepent.last_switchweapon = wepent.switchweapon;
1969                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1970                         {
1971                                 localcmd("-zoom\n");
1972                                 button_zoom = false;
1973                         }
1974                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1975                         {
1976                                 localcmd("-fire\n");
1977                                 localcmd("-fire2\n");
1978                                 button_attack2 = false;
1979                         }
1980                 }
1981                 if(wepent.last_activeweapon != wepent.activeweapon)
1982                 {
1983                         wepent.last_activeweapon = wepent.activeweapon;
1984
1985                         e = wepent.activeweapon;
1986                         if(e.netname != "")
1987                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1988                         else if(slot == 0)
1989                                 localcmd("\ncl_hook_activeweapon none\n");
1990                 }
1991         }
1992
1993         // ALWAYS Clear Current Scene First
1994         clearscene();
1995
1996         setproperty(VF_ORIGIN, view_origin);
1997         setproperty(VF_ANGLES, view_angles);
1998
1999         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2000         setproperty(VF_SIZE, vf_size);
2001         setproperty(VF_MIN, vf_min);
2002
2003         // Assign Standard Viewflags
2004         // Draw the World (and sky)
2005         setproperty(VF_DRAWWORLD, 1);
2006
2007         // Set the console size vars
2008         vid_conwidth = autocvar_vid_conwidth;
2009         vid_conheight = autocvar_vid_conheight;
2010         vid_pixelheight = autocvar_vid_pixelheight;
2011
2012         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2013         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2014         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2015
2016         if(camera_active) // Camera for demo playback
2017         {
2018                 if(autocvar_camera_enable)
2019                         CSQC_Demo_Camera();
2020                 else
2021                 {
2022                         cvar_set("chase_active", ftos(chase_active_backup));
2023                         cvar_set("cl_demo_mousegrab", "0");
2024                         camera_active = false;
2025                 }
2026         }
2027         else
2028         {
2029 #ifdef CAMERATEST
2030                 if(autocvar_camera_enable)
2031 #else
2032                 if(autocvar_camera_enable && isdemo())
2033 #endif
2034                 {
2035                         // Enable required Darkplaces cvars
2036                         chase_active_backup = autocvar_chase_active;
2037                         cvar_set("chase_active", "2");
2038                         cvar_set("cl_demo_mousegrab", "1");
2039                         camera_active = true;
2040                         camera_mode = false;
2041                 }
2042         }
2043
2044         // Draw the Crosshair
2045         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2046
2047         // Draw the Engine Status Bar (the default Quake HUD)
2048         setproperty(VF_DRAWENGINESBAR, 0);
2049
2050         // Update the mouse position
2051         /*
2052            mousepos_x = vid_conwidth;
2053            mousepos_y = vid_conheight;
2054            mousepos = mousepos*0.5 + getmousepos();
2055          */
2056
2057         IL_EACH(g_drawables, it.draw, it.draw(it));
2058
2059         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2060         renderscene();
2061
2062         // now switch to 2D drawing mode by calling a 2D drawing function
2063         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2064         // next R_RenderScene call
2065         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2066
2067         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2068         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2069         {
2070                 // apply night vision effect
2071                 vector tc_00, tc_01, tc_10, tc_11;
2072                 vector rgb = '0 0 0';
2073
2074                 if(!nightvision_noise)
2075                 {
2076                         nightvision_noise = new(nightvision_noise);
2077                 }
2078                 if(!nightvision_noise2)
2079                 {
2080                         nightvision_noise2 = new(nightvision_noise2);
2081                 }
2082
2083                 // color tint in yellow
2084                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2085
2086                 // draw BG
2087                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2088                 rgb = '1 1 1';
2089                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2090                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2091                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2092                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2093                 tc_11 = tc_01 + tc_10 - tc_00;
2094                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2095                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2096                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2097                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2098                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2099                 R_EndPolygon();
2100
2101                 // draw FG
2102                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2103                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2104                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2105                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2106                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2107                 tc_11 = tc_01 + tc_10 - tc_00;
2108                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2109                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2110                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2111                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2112                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2113                 R_EndPolygon();
2114         }
2115
2116         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2117         {
2118                 string reticle_image = string_null;
2119                 bool wep_zoomed = false;
2120                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2121                 {
2122                         entity wepe = viewmodels[slot];
2123                         Weapon wep = wepe.activeweapon;
2124                         if(wep != WEP_Null && wep.wr_zoom)
2125                         {
2126                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2127                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2128                                         reticle_image = wep.w_reticle;
2129                                 wep_zoomed += do_zoom;
2130                         }
2131                 }
2132                 // Draw the aiming reticle for weapons that use it
2133                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2134                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2135                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2136                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2137                 {
2138                         // no zoom reticle while dead
2139                         reticle_type = 0;
2140                 }
2141                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2142                 {
2143                         if(reticle_image) { reticle_type = 2; }
2144                         else { reticle_type = 0; }
2145                 }
2146                 else if(button_zoom || zoomscript_caught)
2147                 {
2148                         // normal zoom
2149                         reticle_type = 1;
2150                 }
2151
2152                 if(reticle_type)
2153                 {
2154                         if(autocvar_cl_reticle_stretch)
2155                         {
2156                                 reticle_size.x = vid_conwidth;
2157                                 reticle_size.y = vid_conheight;
2158                                 reticle_pos.x = 0;
2159                                 reticle_pos.y = 0;
2160                         }
2161                         else
2162                         {
2163                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2164                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2165                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2166                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2167                         }
2168
2169                         if(zoomscript_caught)
2170                                 f = 1;
2171                         else
2172                                 f = current_zoomfraction;
2173
2174                         if(f)
2175                         {
2176                                 switch(reticle_type)
2177                                 {
2178                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2179                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2180                                 }
2181                         }
2182                 }
2183         }
2184         else
2185         {
2186                 if(reticle_type != 0) { reticle_type = 0; }
2187         }
2188
2189
2190         // improved polyblend
2191         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2192         {
2193                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2194                 vector liquidcolor;
2195
2196                 switch(pointcontents(view_origin))
2197                 {
2198                         case CONTENT_WATER:
2199                                 liquidalpha = autocvar_hud_contents_water_alpha;
2200                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2201                                 incontent = 1;
2202                                 break;
2203
2204                         case CONTENT_LAVA:
2205                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2206                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2207                                 incontent = 1;
2208                                 break;
2209
2210                         case CONTENT_SLIME:
2211                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2212                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2213                                 incontent = 1;
2214                                 break;
2215
2216                         default:
2217                                 liquidalpha = 0;
2218                                 liquidcolor = '0 0 0';
2219                                 incontent = 0;
2220                                 break;
2221                 }
2222
2223                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2224                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2225                         contentfadetime = autocvar_hud_contents_fadeintime;
2226                         liquidalpha_prev = liquidalpha;
2227                         liquidcolor_prev = liquidcolor;
2228                 }
2229                 else
2230                         contentfadetime = autocvar_hud_contents_fadeouttime;
2231
2232                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2233                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2234
2235                 if(contentavgalpha)
2236                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2237
2238                 if(autocvar_hud_postprocessing)
2239                 {
2240                         if(autocvar_hud_contents_blur && contentavgalpha)
2241                         {
2242                                 content_blurpostprocess.x = 1;
2243                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2244                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2245                         }
2246                         else
2247                         {
2248                                 content_blurpostprocess.x = 0;
2249                                 content_blurpostprocess.y = 0;
2250                                 content_blurpostprocess.z = 0;
2251                         }
2252                 }
2253         }
2254
2255         if(autocvar_hud_damage && !STAT(FROZEN))
2256         {
2257                 splash_size.x = max(vid_conwidth, vid_conheight);
2258                 splash_size.y = max(vid_conwidth, vid_conheight);
2259                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2260                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2261
2262                 float myhealth_flash_temp;
2263                 myhealth = STAT(HEALTH);
2264
2265                 // fade out
2266                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2267                 // add new damage
2268                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2269
2270                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2271                 pain_threshold = autocvar_hud_damage_pain_threshold;
2272                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2273                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2274
2275                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2276                 {
2277                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2278                 }
2279
2280                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2281
2282                 if(myhealth_prev < 1)
2283                 {
2284                         if(myhealth >= 1)
2285                         {
2286                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2287                                 myhealth_flash_temp = 0;
2288                         }
2289                         else
2290                         {
2291                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2292                         }
2293                 }
2294
2295                 if(spectatee_status == -1 || intermission)
2296                 {
2297                         myhealth_flash = 0; // observing, or match ended
2298                         myhealth_flash_temp = 0;
2299                 }
2300
2301                 myhealth_prev = myhealth;
2302
2303                 // IDEA: change damage color/picture based on player model for robot/alien species?
2304                 // pro: matches model better
2305                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2306                 // maybe different reddish pics?
2307                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2308                 {
2309                         if(autocvar_cl_gentle_damage == 2)
2310                         {
2311                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2312                                         myhealth_gentlergb = randomvec();
2313                         }
2314                         else
2315                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2316
2317                         if(myhealth_flash_temp > 0)
2318                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2319                 }
2320                 else if(myhealth_flash_temp > 0)
2321                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2322
2323                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2324                 {
2325                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2326                         {
2327                                 damage_blurpostprocess.x = 1;
2328                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2329                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2330                         }
2331                         else
2332                         {
2333                                 damage_blurpostprocess.x = 0;
2334                                 damage_blurpostprocess.y = 0;
2335                                 damage_blurpostprocess.z = 0;
2336                         }
2337                 }
2338         }
2339
2340         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2341         float e2 = (autocvar_hud_powerup != 0);
2342         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2343         {
2344                 // enable or disable rendering types if they are used or not
2345                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2346                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2347
2348                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2349                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2350                 {
2351                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2352                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2353                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2354                         {
2355                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2356                                 old_blurradius = blurradius;
2357                                 old_bluralpha = bluralpha;
2358                         }
2359                 }
2360                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2361                 {
2362                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2363                         old_blurradius = 0;
2364                         old_bluralpha = 0;
2365                 }
2366
2367                 // edge detection postprocess handling done second (used by hud_powerup)
2368                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2369                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2370                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2371
2372                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2373
2374                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2375                 {
2376                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2377                         {
2378                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2379                                 old_sharpen_intensity = sharpen_intensity;
2380                         }
2381                 }
2382                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2383                 {
2384                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2385                         old_sharpen_intensity = 0;
2386                 }
2387
2388                 if(cvar("r_glsl_postprocess") == 0)
2389                         cvar_set("r_glsl_postprocess", "2");
2390         }
2391         else if(cvar("r_glsl_postprocess") == 2)
2392                 cvar_set("r_glsl_postprocess", "0");
2393
2394         /*if(ISGAMETYPE(CTF))
2395           {
2396           ctf_view();
2397           } else */
2398
2399         // draw 2D entities
2400         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2401         Draw_ShowNames_All();
2402 #if ENABLE_DEBUGDRAW
2403         Debug_Draw();
2404 #endif
2405
2406         scoreboard_active = Scoreboard_WouldDraw();
2407
2408         HUD_Draw(this); // this parameter for deep vehicle function
2409
2410         if(NextFrameCommand)
2411         {
2412                 localcmd("\n", NextFrameCommand, "\n");
2413                 NextFrameCommand = string_null;
2414         }
2415
2416         // we must do this check AFTER a frame was rendered, or it won't work
2417         if(cs_project_is_b0rked == 0)
2418         {
2419                 string w0, h0;
2420                 w0 = ftos(autocvar_vid_conwidth);
2421                 h0 = ftos(autocvar_vid_conheight);
2422                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2423                 //setproperty(VF_FOV, '90 90 0');
2424                 setproperty(VF_ORIGIN, '0 0 0');
2425                 setproperty(VF_ANGLES, '0 0 0');
2426                 setproperty(VF_PERSPECTIVE, 1);
2427                 makevectors('0 0 0');
2428                 vector v1, v2;
2429                 cvar_set("vid_conwidth", "800");
2430                 cvar_set("vid_conheight", "600");
2431                 v1 = cs_project(v_forward);
2432                 cvar_set("vid_conwidth", "640");
2433                 cvar_set("vid_conheight", "480");
2434                 v2 = cs_project(v_forward);
2435                 if(v1 == v2)
2436                         cs_project_is_b0rked = 1;
2437                 else
2438                         cs_project_is_b0rked = -1;
2439                 cvar_set("vid_conwidth", w0);
2440                 cvar_set("vid_conheight", h0);
2441         }
2442
2443         HUD_Mouse(local_player);
2444
2445         cl_notice_run();
2446         unpause_update();
2447         Net_Flush();
2448
2449         // let's reset the view back to normal for the end
2450         setproperty(VF_MIN, '0 0 0');
2451         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2452
2453         IL_ENDFRAME();
2454 }
2455
2456
2457 // following vectors must be global to allow seamless switching between camera modes
2458 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2459 void CSQC_Demo_Camera()
2460 {
2461         float speed, attenuation, dimensions;
2462         vector tmp, delta;
2463
2464         if( autocvar_camera_reset || !camera_mode )
2465         {
2466                 camera_offset = '0 0 0';
2467                 current_angles = '0 0 0';
2468                 camera_direction = '0 0 0';
2469                 camera_offset.z += 30;
2470                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2471                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2472                 current_origin = view_origin;
2473                 current_camera_offset  = camera_offset;
2474                 cvar_set("camera_reset", "0");
2475                 camera_mode = CAMERA_CHASE;
2476         }
2477
2478         // Camera angles
2479         if( camera_roll )
2480                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2481
2482         if(autocvar_camera_look_player)
2483         {
2484                 vector dir;
2485                 float n;
2486
2487                 dir = normalize(view_origin - current_position);
2488                 n = mouse_angles.z;
2489                 mouse_angles = vectoangles(dir);
2490                 mouse_angles.x = mouse_angles.x * -1;
2491                 mouse_angles.z = n;
2492         }
2493         else
2494         {
2495                 tmp = getmousepos() * 0.1;
2496                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2497                 {
2498                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2499                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2500                 }
2501         }
2502
2503         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2504         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2505         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2506         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2507
2508         // Fix difference when angles don't have the same sign
2509         delta = '0 0 0';
2510         if(mouse_angles.y < -60 && current_angles.y > 60)
2511                 delta = '0 360 0';
2512         if(mouse_angles.y > 60 && current_angles.y < -60)
2513                 delta = '0 -360 0';
2514
2515         if(autocvar_camera_look_player)
2516                 attenuation = autocvar_camera_look_attenuation;
2517         else
2518                 attenuation = autocvar_camera_speed_attenuation;
2519
2520         attenuation = 1 / max(1, attenuation);
2521         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2522
2523         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2524         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2525         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2526         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2527
2528         // Camera position
2529         tmp = '0 0 0';
2530         dimensions = 0;
2531
2532         if( camera_direction.x )
2533         {
2534                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2535                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2536                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2537                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2538                 ++dimensions;
2539         }
2540
2541         if( camera_direction.y )
2542         {
2543                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2544                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2545                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2546                 ++dimensions;
2547         }
2548
2549         if( camera_direction.z )
2550         {
2551                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2552                 ++dimensions;
2553         }
2554
2555         if(autocvar_camera_free)
2556                 speed = autocvar_camera_speed_free;
2557         else
2558                 speed = autocvar_camera_speed_chase;
2559
2560         if(dimensions)
2561         {
2562                 speed = speed * sqrt(1 / dimensions);
2563                 camera_offset += tmp * speed;
2564         }
2565
2566         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2567
2568         // Camera modes
2569         if( autocvar_camera_free )
2570         {
2571                 if ( camera_mode == CAMERA_CHASE )
2572                 {
2573                         current_camera_offset = current_origin + current_camera_offset;
2574                         camera_offset = current_origin + camera_offset;
2575                 }
2576
2577                 camera_mode = CAMERA_FREE;
2578                 current_position = current_camera_offset;
2579         }
2580         else
2581         {
2582                 if ( camera_mode == CAMERA_FREE )
2583                 {
2584                         current_origin = view_origin;
2585                         camera_offset = camera_offset - current_origin;
2586                         current_camera_offset = current_camera_offset - current_origin;
2587                 }
2588
2589                 camera_mode = CAMERA_CHASE;
2590
2591                 if(autocvar_camera_chase_smoothly)
2592                         current_origin += (view_origin - current_origin) * attenuation;
2593                 else
2594                         current_origin = view_origin;
2595
2596                 current_position = current_origin + current_camera_offset;
2597         }
2598
2599         setproperty(VF_ANGLES, current_angles);
2600         setproperty(VF_ORIGIN, current_position);
2601 }