Merge branches 'TimePath/weaponsys' and 'Mario/modpack'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "_all.qh"
2
3 #include "announcer.qh"
4 #include "hook.qh"
5 #include "hud.qh"
6 #include "hud_config.qh"
7 #include "mapvoting.qh"
8 #include "noise.qh"
9 #include "scoreboard.qh"
10 #include "shownames.qh"
11 #include "vehicles/all.qh"
12 #include "waypointsprites.qh"
13
14 #include "../common/constants.qh"
15 #include "../common/mapinfo.qh"
16 #include "../common/nades.qh"
17 #include "../common/stats.qh"
18 #include "../common/triggers/target/music.qh"
19 #include "../common/teams.qh"
20 #include "../common/util.qh"
21
22 #include "../common/weapons/all.qh"
23
24 #include "../csqcmodellib/cl_player.qh"
25
26 #include "../warpzonelib/client.qh"
27 #include "../warpzonelib/common.qh"
28 #include "../warpzonelib/mathlib.qh"
29
30 entity porto;
31 vector polyline[16];
32 void Porto_Draw()
33 {
34         vector p, dir, ang, q, nextdir;
35         float portal_number, portal1_idx;
36
37         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
38                 return;
39         if(g_balance_porto_secondary)
40                 return;
41         if(intermission == 1)
42                 return;
43         if(intermission == 2)
44                 return;
45         if (getstati(STAT_HEALTH) <= 0)
46                 return;
47
48         dir = view_forward;
49
50         if(angles_held_status)
51         {
52                 makevectors(angles_held);
53                 dir = v_forward;
54         }
55
56         p = view_origin;
57
58         polyline[0] = p;
59         int idx = 1;
60         portal_number = 0;
61         nextdir = dir;
62
63         for (;;)
64         {
65                 dir = nextdir;
66                 traceline(p, p + 65536 * dir, true, porto);
67                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
68                         return;
69                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
70                 p = trace_endpos;
71                 polyline[idx] = p;
72                 ++idx;
73                 if(idx >= 16)
74                         return;
75                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
76                         continue;
77                 ++portal_number;
78                 ang = vectoangles2(trace_plane_normal, dir);
79                 ang.x = -ang.x;
80                 makevectors(ang);
81                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
82                         return;
83                 if(portal_number == 1)
84                 {
85                         portal1_idx = idx;
86                         if(portal_number >= 2)
87                                 break;
88                 }
89         }
90
91         while(idx >= 2)
92         {
93                 p = polyline[idx-2];
94                 q = polyline[idx-1];
95                 if(idx == 2)
96                         p = p - view_up * 16;
97                 if(idx-1 >= portal1_idx)
98                 {
99                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
100                 }
101                 else
102                 {
103                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
104                 }
105                 --idx;
106         }
107 }
108
109 void Porto_Init()
110 {
111         porto = spawn();
112         porto.classname = "porto";
113         porto.draw = Porto_Draw;
114         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
115 }
116
117 float drawtime;
118 float avgspeed;
119 vector GetCurrentFov(float fov)
120 {
121         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
122         float velocityzoom, curspeed;
123         vector v;
124
125         zoomsensitivity = autocvar_cl_zoomsensitivity;
126         zoomfactor = autocvar_cl_zoomfactor;
127         if(zoomfactor < 1 || zoomfactor > 30)
128                 zoomfactor = 2.5;
129         zoomspeed = autocvar_cl_zoomspeed;
130         if(zoomspeed >= 0)
131         if(zoomspeed < 0.5 || zoomspeed > 16)
132                         zoomspeed = 3.5;
133
134         zoomdir = button_zoom;
135         if(hud == HUD_NORMAL)
136         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
137                 zoomdir += button_attack2;
138         if(spectatee_status > 0 || isdemo())
139         {
140                 if(spectatorbutton_zoom)
141                 {
142                         if(zoomdir)
143                                 zoomdir = 0;
144                         else
145                                 zoomdir = 1;
146                 }
147                 // fteqcc failed twice here already, don't optimize this
148         }
149
150         if(zoomdir) { zoomin_effect = 0; }
151
152         if(camera_active)
153         {
154                 current_viewzoom = min(1, current_viewzoom + drawframetime);
155         }
156         else if(autocvar_cl_spawnzoom && zoomin_effect)
157         {
158                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
159
160                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
161                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
162                 if(current_viewzoom == 1) { zoomin_effect = 0; }
163         }
164         else
165         {
166                 if(zoomspeed < 0) // instant zoom
167                 {
168                         if(zoomdir)
169                                 current_viewzoom = 1 / zoomfactor;
170                         else
171                                 current_viewzoom = 1;
172                 }
173                 else
174                 {
175                         if(zoomdir)
176                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
177                         else
178                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
179                 }
180         }
181
182         if(almost_equals(current_viewzoom, 1))
183                 current_zoomfraction = 0;
184         else if(almost_equals(current_viewzoom, 1/zoomfactor))
185                 current_zoomfraction = 1;
186         else
187                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
188
189         if(zoomsensitivity < 1)
190                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
191         else
192                 setsensitivityscale(1);
193
194         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
195         {
196                 if(intermission) { curspeed = 0; }
197                 else
198                 {
199
200                         makevectors(view_angles);
201                         v = pmove_vel;
202                         if(csqcplayer)
203                                 v = csqcplayer.velocity;
204
205                         switch(autocvar_cl_velocityzoom_type)
206                         {
207                                 case 3: curspeed = max(0, v_forward * v); break;
208                                 case 2: curspeed = (v_forward * v); break;
209                                 case 1: default: curspeed = vlen(v); break;
210                         }
211                 }
212
213                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
214                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
215                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
216
217                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
218         }
219         else
220                 velocityzoom = 1;
221
222         float frustumx, frustumy, fovx, fovy;
223         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
224         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
225         fovx = atan2(frustumx, 1) / M_PI * 360.0;
226         fovy = atan2(frustumy, 1) / M_PI * 360.0;
227
228         return '1 0 0' * fovx + '0 1 0' * fovy;
229 }
230
231 vector GetViewLocationFOV(float fov)
232 {
233         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
234         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
235         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
236         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
237         return '1 0 0' * fovx + '0 1 0' * fovy;
238 }
239
240 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
241 {
242         float fovx, fovy;
243         float width = (ov_worldmax.x - ov_worldmin.x);
244         float height = (ov_worldmax.y - ov_worldmin.y);
245         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
246         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
247         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
248         return '1 0 0' * fovx + '0 1 0' * fovy;
249 }
250
251 // this function must match W_SetupShot!
252 float zoomscript_caught;
253
254 vector wcross_origin;
255 float wcross_scale_prev, wcross_alpha_prev;
256 vector wcross_color_prev;
257 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
258 vector wcross_color_goal_prev;
259 float wcross_changedonetime;
260
261 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
262 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
263 float wcross_name_changestarttime, wcross_name_changedonetime;
264 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
265
266 float wcross_ring_prev;
267
268 entity trueaim;
269 entity trueaim_rifle;
270
271 const float SHOTTYPE_HITTEAM = 1;
272 const float SHOTTYPE_HITOBSTRUCTION = 2;
273 const float SHOTTYPE_HITWORLD = 3;
274 const float SHOTTYPE_HITENEMY = 4;
275
276 void TrueAim_Init()
277 {
278         trueaim = spawn();
279         trueaim.classname = "trueaim";
280         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
281         trueaim_rifle = spawn();
282         trueaim_rifle.classname = "trueaim_rifle";
283         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
284 }
285
286 float EnemyHitCheck()
287 {
288         float t, n;
289         wcross_origin = project_3d_to_2d(trace_endpos);
290         wcross_origin.z = 0;
291         if(trace_ent)
292                 n = trace_ent.entnum;
293         else
294                 n = trace_networkentity;
295         if(n < 1)
296                 return SHOTTYPE_HITWORLD;
297         if(n > maxclients)
298                 return SHOTTYPE_HITWORLD;
299         t = GetPlayerColor(n - 1);
300         if(teamplay)
301                 if(t == myteam)
302                         return SHOTTYPE_HITTEAM;
303         if(t == NUM_SPECTATOR)
304                 return SHOTTYPE_HITWORLD;
305         return SHOTTYPE_HITENEMY;
306 }
307
308 float TrueAimCheck()
309 {
310         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
311         vector vecs, trueaimpoint, w_shotorg;
312         vector mi, ma, dv;
313         float shottype;
314         entity ta;
315         float mv;
316
317         mi = ma = '0 0 0';
318         ta = trueaim;
319         mv = MOVE_NOMONSTERS;
320
321         switch(activeweapon) // WEAPONTODO
322         {
323                 case WEP_TUBA.m_id: // no aim
324                 case WEP_PORTO.m_id: // shoots from eye
325                 case WEP_HOOK.m_id: // no trueaim
326                 case WEP_MORTAR.m_id: // toss curve
327                         return SHOTTYPE_HITWORLD;
328                 case WEP_VORTEX.m_id:
329                 case WEP_VAPORIZER.m_id:
330                         mv = MOVE_NORMAL;
331                         break;
332                 case WEP_RIFLE.m_id:
333                         ta = trueaim_rifle;
334                         mv = MOVE_NORMAL;
335                         if(zoomscript_caught)
336                         {
337                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
338                                 return EnemyHitCheck();
339                         }
340                         break;
341                 case WEP_DEVASTATOR.m_id: // projectile has a size!
342                         mi = '-3 -3 -3';
343                         ma = '3 3 3';
344                         break;
345                 case WEP_FIREBALL.m_id: // projectile has a size!
346                         mi = '-16 -16 -16';
347                         ma = '16 16 16';
348                         break;
349                 case WEP_SEEKER.m_id: // projectile has a size!
350                         mi = '-2 -2 -2';
351                         ma = '2 2 2';
352                         break;
353                 case WEP_ELECTRO.m_id: // projectile has a size!
354                         mi = '0 0 -3';
355                         ma = '0 0 -3';
356                         break;
357         }
358
359         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
360
361         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
362
363         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
364         trueaimpoint = trace_endpos;
365
366         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
367                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
368
369         if(vecs.x > 0)
370                 vecs.y = -vecs.y;
371         else
372                 vecs = '0 0 0';
373
374         dv = view_right * vecs.y + view_up * vecs.z;
375         w_shotorg = traceorigin + dv;
376
377         // now move the vecs forward as much as requested if possible
378         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
379         w_shotorg = trace_endpos - view_forward * nudge;
380
381         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
382         shottype = EnemyHitCheck();
383         if(shottype != SHOTTYPE_HITWORLD)
384                 return shottype;
385
386 #if 0
387         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
388         // or rather, I know why, but see no fix
389         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
390                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
391                 return SHOTTYPE_HITOBSTRUCTION;
392 #endif
393
394         return SHOTTYPE_HITWORLD;
395 }
396
397 void CSQC_common_hud(void);
398
399 void PostInit(void);
400 void CSQC_Demo_Camera();
401 float HUD_WouldDrawScoreboard();
402 float camera_mode;
403 const float CAMERA_FREE = 1;
404 const float CAMERA_CHASE = 2;
405 float reticle_type;
406 string reticle_image;
407 string NextFrameCommand;
408 void CSQC_SPIDER_HUD();
409 void CSQC_RAPTOR_HUD();
410
411 vector freeze_org, freeze_ang;
412 entity nightvision_noise, nightvision_noise2;
413
414 const float MAX_TIME_DIFF = 5;
415 float pickup_crosshair_time, pickup_crosshair_size;
416 float hitindication_crosshair_size;
417 float use_vortex_chargepool;
418
419 float myhealth, myhealth_prev;
420 float myhealth_flash;
421
422 float old_blurradius, old_bluralpha;
423 float old_sharpen_intensity;
424
425 vector myhealth_gentlergb;
426
427 float contentavgalpha, liquidalpha_prev;
428 vector liquidcolor_prev;
429
430 float eventchase_current_distance;
431 float eventchase_running;
432 bool WantEventchase()
433 {
434         if(autocvar_cl_orthoview)
435                 return false;
436         if(intermission)
437                 return true;
438         if(self.viewloc)
439                 return true;
440         if(spectatee_status >= 0)
441         {
442                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO.m_id)))
443                         return true;
444                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
445                 {
446                         if(autocvar_cl_eventchase_death == 2)
447                         {
448                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
449                                 if(self.velocity == '0 0 0' || eventchase_running)
450                                         return true;
451                         }
452                         else return true;
453                 }
454         }
455         return false;
456 }
457
458 vector damage_blurpostprocess, content_blurpostprocess;
459
460 float checkfail[16];
461
462 float unaccounted_damage = 0;
463 void UpdateDamage()
464 {
465         // accumulate damage with each stat update
466         static float damage_total_prev = 0;
467         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
468         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
469         damage_total_prev = damage_total;
470
471         static float damage_dealt_time_prev = 0;
472         float damage_dealt_time = getstatf(STAT_HIT_TIME);
473         if (damage_dealt_time != damage_dealt_time_prev)
474         {
475                 unaccounted_damage += unaccounted_damage_new;
476                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
477         }
478         damage_dealt_time_prev = damage_dealt_time;
479
480         // prevent hitsound when switching spectatee
481         static float spectatee_status_prev = 0;
482         if (spectatee_status != spectatee_status_prev)
483                 unaccounted_damage = 0;
484         spectatee_status_prev = spectatee_status;
485 }
486
487 void UpdateHitsound()
488 {
489         // varying sound pitch
490
491         static float hitsound_time_prev = 0;
492         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
493         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
494         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
495         {
496                 if (autocvar_cl_hitsound && unaccounted_damage)
497                 {
498                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
499                         float a = autocvar_cl_hitsound_max_pitch;
500                         float b = autocvar_cl_hitsound_min_pitch;
501                         float c = autocvar_cl_hitsound_nom_damage;
502                         float x = unaccounted_damage;
503                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
504
505                         // if sound variation is disabled, set pitch_shift to 1
506                         if (autocvar_cl_hitsound == 1)
507                                 pitch_shift = 1;
508
509                         // if pitch shift is reversed, mirror in (max-min)/2 + min
510                         if (autocvar_cl_hitsound == 3)
511                         {
512                                 float mirror_value = (a-b)/2 + b;
513                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
514                         }
515
516                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
517
518                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
519                         // todo: normalize sound pressure levels? seems unnecessary
520
521                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
522                 }
523                 unaccounted_damage = 0;
524                 hitsound_time_prev = time;
525         }
526
527         static float typehit_time_prev = 0;
528         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
529         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
530         {
531                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
532                 typehit_time_prev = typehit_time;
533         }
534 }
535
536 void UpdateCrosshair()
537 {
538         static float rainbow_last_flicker;
539     static vector rainbow_prev_color;
540         entity e = self;
541         float f, i, j;
542         vector v;
543         if(getstati(STAT_FROZEN))
544                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
545         else if (getstatf(STAT_HEALING_ORB)>time)
546                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
547         if(!intermission)
548         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
549         {
550                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
551                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
552         }
553         else if(getstatf(STAT_REVIVE_PROGRESS))
554         {
555                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
556                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
557         }
558
559         if(autocvar_r_letterbox == 0)
560                 if(autocvar_viewsize < 120)
561                         CSQC_common_hud();
562
563         // crosshair goes VERY LAST
564         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc)
565         {
566                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
567                         return;
568
569                 string wcross_style;
570                 float wcross_alpha, wcross_resolution;
571                 wcross_style = autocvar_crosshair;
572                 if (wcross_style == "0")
573                         return;
574                 wcross_resolution = autocvar_crosshair_size;
575                 if (wcross_resolution == 0)
576                         return;
577                 wcross_alpha = autocvar_crosshair_alpha;
578                 if (wcross_alpha == 0)
579                         return;
580
581                 // TrueAim check
582                 float shottype;
583
584                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
585                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
586                 wcross_origin.z = 0;
587                 if(autocvar_crosshair_hittest)
588                 {
589                         vector wcross_oldorigin;
590                         wcross_oldorigin = wcross_origin;
591                         shottype = TrueAimCheck();
592                         if(shottype == SHOTTYPE_HITWORLD)
593                         {
594                                 v = wcross_origin - wcross_oldorigin;
595                                 v.x /= vid_conwidth;
596                                 v.y /= vid_conheight;
597                                 if(vlen(v) > 0.01)
598                                         shottype = SHOTTYPE_HITOBSTRUCTION;
599                         }
600                         if(!autocvar_crosshair_hittest_showimpact)
601                                 wcross_origin = wcross_oldorigin;
602                 }
603                 else
604                         shottype = SHOTTYPE_HITWORLD;
605
606                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
607                 string wcross_name = "";
608                 float wcross_scale, wcross_blur;
609
610                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
611                 {
612                         e = get_weaponinfo(switchingweapon);
613                         if(e)
614                         {
615                                 if(autocvar_crosshair_per_weapon)
616                                 {
617                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
618                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
619                                         //if (wcross_resolution == 0)
620                                                 //return;
621
622                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
623                                         wcross_resolution *= e.w_crosshair_size;
624                                         wcross_name = e.w_crosshair;
625                                 }
626                         }
627                 }
628
629                 if(wcross_name == "")
630                         wcross_name = strcat("gfx/crosshair", wcross_style);
631
632                 // MAIN CROSSHAIR COLOR DECISION
633                 switch(autocvar_crosshair_color_special)
634                 {
635                         case 1: // crosshair_color_per_weapon
636                         {
637                                 if(e)
638                                 {
639                                         wcross_color = e.wpcolor;
640                                         break;
641                                 }
642                                 else { goto normalcolor; }
643                         }
644
645                         case 2: // crosshair_color_by_health
646                         {
647                                 float x = getstati(STAT_HEALTH);
648
649                                 //x = red
650                                 //y = green
651                                 //z = blue
652
653                                 wcross_color.z = 0;
654
655                                 if(x > 200)
656                                 {
657                                         wcross_color.x = 0;
658                                         wcross_color.y = 1;
659                                 }
660                                 else if(x > 150)
661                                 {
662                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
663                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
664                                 }
665                                 else if(x > 100)
666                                 {
667                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
668                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
669                                         wcross_color.z = 1 - (x-100)*0.02;
670                                 }
671                                 else if(x > 50)
672                                 {
673                                         wcross_color.x = 1;
674                                         wcross_color.y = 1;
675                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
676                                 }
677                                 else if(x > 20)
678                                 {
679                                         wcross_color.x = 1;
680                                         wcross_color.y = (x-20)*90/27/100;
681                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
682                                 }
683                                 else
684                                 {
685                                         wcross_color.x = 1;
686                                         wcross_color.y = 0;
687                                 }
688                                 break;
689                         }
690
691                         case 3: // crosshair_color_rainbow
692                         {
693                                 if(time >= rainbow_last_flicker)
694                                 {
695                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
696                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
697                                 }
698                                 wcross_color = rainbow_prev_color;
699                                 break;
700                         }
701                         :normalcolor
702                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
703                 }
704
705                 if(autocvar_crosshair_effect_scalefade)
706                 {
707                         wcross_scale = wcross_resolution;
708                         wcross_resolution = 1;
709                 }
710                 else
711                 {
712                         wcross_scale = 1;
713                 }
714
715                 if(autocvar_crosshair_pickup)
716                 {
717                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
718
719                         if(pickup_crosshair_time < stat_pickup_time)
720                         {
721                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
722                                         pickup_crosshair_size = 1;
723
724                                 pickup_crosshair_time = stat_pickup_time;
725                         }
726
727                         if(pickup_crosshair_size > 0)
728                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
729                         else
730                                 pickup_crosshair_size = 0;
731
732                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
733                 }
734
735                 // todo: make crosshair hit indication dependent on damage dealt
736                 if(autocvar_crosshair_hitindication)
737                 {
738                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
739
740                         if(unaccounted_damage)
741                         {
742                                 hitindication_crosshair_size = 1;
743                         }
744
745                         if(hitindication_crosshair_size > 0)
746                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
747                         else
748                                 hitindication_crosshair_size = 0;
749
750                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
751                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
752                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
753                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
754                 }
755
756                 if(shottype == SHOTTYPE_HITENEMY)
757                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
758                 if(shottype == SHOTTYPE_HITTEAM)
759                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
760
761                 f = fabs(autocvar_crosshair_effect_time);
762                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
763                 {
764                         wcross_changedonetime = time + f;
765                 }
766                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
767                 {
768                         wcross_name_changestarttime = time;
769                         wcross_name_changedonetime = time + f;
770                         if(wcross_name_goal_prev_prev)
771                                 strunzone(wcross_name_goal_prev_prev);
772                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
773                         wcross_name_goal_prev = strzone(wcross_name);
774                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
775                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
776                         wcross_resolution_goal_prev = wcross_resolution;
777                 }
778
779                 wcross_scale_goal_prev = wcross_scale;
780                 wcross_alpha_goal_prev = wcross_alpha;
781                 wcross_color_goal_prev = wcross_color;
782
783                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
784                 {
785                         wcross_blur = 1;
786                         wcross_alpha *= 0.75;
787                 }
788                 else
789                         wcross_blur = 0;
790                 // *_prev is at time-frametime
791                 // * is at wcross_changedonetime+f
792                 // what do we have at time?
793                 if(time < wcross_changedonetime)
794                 {
795                         f = frametime / (wcross_changedonetime - time + frametime);
796                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
797                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
798                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
799                 }
800
801                 wcross_scale_prev = wcross_scale;
802                 wcross_alpha_prev = wcross_alpha;
803                 wcross_color_prev = wcross_color;
804
805                 wcross_scale *= 1 - autocvar__menu_alpha;
806                 wcross_alpha *= 1 - autocvar__menu_alpha;
807                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
808
809                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
810                 {
811                         // crosshair rings for weapon stats
812                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
813                         {
814                                 // declarations and stats
815                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
816                                 string ring_image = string_null, ring_inner_image = string_null;
817                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
818
819                                 ring_scale = autocvar_crosshair_ring_size;
820
821                                 float weapon_clipload, weapon_clipsize;
822                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
823                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
824
825                                 float ok_ammo_charge, ok_ammo_chargepool;
826                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
827                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
828
829                                 float vortex_charge, vortex_chargepool;
830                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
831                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
832
833                                 float arc_heat = getstatf(STAT_ARC_HEAT);
834
835                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
836                                         vortex_charge_movingavg = vortex_charge;
837
838
839                                 // handle the values
840                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
841                                 {
842                                         if (vortex_chargepool || use_vortex_chargepool) {
843                                                 use_vortex_chargepool = 1;
844                                                 ring_inner_value = vortex_chargepool;
845                                         } else {
846                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
847                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
848                                         }
849
850                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
851                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
852                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
853
854                                         // draw the outer ring to show the current charge of the weapon
855                                         ring_value = vortex_charge;
856                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
857                                         ring_rgb = wcross_color;
858                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
859                                 }
860                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
861                                 {
862                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
863                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
864                                         ring_rgb = wcross_color;
865                                         ring_image = "gfx/crosshair_ring.tga";
866                                 }
867                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
868                                 {
869                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
870                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
871                                         ring_rgb = wcross_color;
872                                         ring_image = "gfx/crosshair_ring.tga";
873                                 }
874                                 else if (ok_ammo_charge)
875                                 {
876                                         ring_value = ok_ammo_chargepool;
877                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
878                                         ring_rgb = wcross_color;
879                                         ring_image = "gfx/crosshair_ring.tga";
880                                 }
881                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
882                                 {
883                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
884                                         ring_scale = autocvar_crosshair_ring_reload_size;
885                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
886                                         ring_rgb = wcross_color;
887
888                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
889                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
890                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
891                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
892                                         else
893                                                 ring_image = "gfx/crosshair_ring.tga";
894                                 }
895                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
896                                 {
897                                         ring_value = arc_heat;
898                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
899                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
900                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
901                                         ring_image = "gfx/crosshair_ring.tga";
902                                 }
903
904                                 // if in weapon switch animation, fade ring out/in
905                                 if(autocvar_crosshair_effect_time > 0)
906                                 {
907                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
908                                         if (f >= 1)
909                                         {
910                                                 wcross_ring_prev = ((ring_image) ? true : false);
911                                         }
912
913                                         if(wcross_ring_prev)
914                                         {
915                                                 if(f < 1)
916                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
917                                         }
918                                         else
919                                         {
920                                                 if(f < 1)
921                                                         ring_alpha *= bound(0, f, 1);
922                                         }
923                                 }
924
925                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
926                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
927
928                                 if (ring_value)
929                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
930                         }
931
932 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
933                         do \
934                         { \
935                                 if(wcross_blur > 0) \
936                                 { \
937                                         for(i = -2; i <= 2; ++i) \
938                                         for(j = -2; j <= 2; ++j) \
939                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
940                                 } \
941                                 else \
942                                 { \
943                                         M(0,0,sz,wcross_name,wcross_alpha); \
944                                 } \
945                         } \
946                         while(0)
947
948 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
949                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
950
951 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
952                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
953
954                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
955                         {
956                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
957                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
958                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
959                                 f = 1 - f;
960                         }
961                         else
962                         {
963                                 f = 1;
964                         }
965                         wcross_name_alpha_goal_prev = f;
966
967                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
968                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
969
970                         if(autocvar_crosshair_dot)
971                         {
972                                 vector wcross_color_old;
973                                 wcross_color_old = wcross_color;
974
975                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
976                                         wcross_color = stov(autocvar_crosshair_dot_color);
977
978                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
979                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
980                                 wcross_color = wcross_color_old;
981                         }
982                 }
983         }
984         else
985         {
986                 wcross_scale_prev = 0;
987                 wcross_alpha_prev = 0;
988                 wcross_scale_goal_prev = 0;
989                 wcross_alpha_goal_prev = 0;
990                 wcross_changedonetime = 0;
991                 if(wcross_name_goal_prev)
992                         strunzone(wcross_name_goal_prev);
993                 wcross_name_goal_prev = string_null;
994                 if(wcross_name_goal_prev_prev)
995                         strunzone(wcross_name_goal_prev_prev);
996                 wcross_name_goal_prev_prev = string_null;
997                 wcross_name_changestarttime = 0;
998                 wcross_name_changedonetime = 0;
999                 wcross_name_alpha_goal_prev = 0;
1000                 wcross_name_alpha_goal_prev_prev = 0;
1001                 wcross_resolution_goal_prev = 0;
1002                 wcross_resolution_goal_prev_prev = 0;
1003         }
1004 }
1005
1006 const int BUTTON_3 = 4;
1007 const int BUTTON_4 = 8;
1008 float cl_notice_run();
1009 float prev_myteam;
1010 void CSQC_UpdateView(float w, float h)
1011 {
1012         entity e;
1013         float fov;
1014         float f;
1015         int i;
1016         vector vf_size, vf_min;
1017         float a;
1018
1019         execute_next_frame();
1020
1021         ++framecount;
1022
1023         hud = getstati(STAT_HUD);
1024
1025         if(autocvar__hud_showbinds_reload) // menu can set this one
1026         {
1027                 db_close(binddb);
1028                 binddb = db_create();
1029                 cvar_set("_hud_showbinds_reload", "0");
1030         }
1031
1032         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1033                 view_quality = getproperty(VF_MINFPS_QUALITY);
1034         else
1035                 view_quality = 1;
1036
1037         button_attack2 = (input_buttons & BUTTON_3);
1038         button_zoom = (input_buttons & BUTTON_4);
1039
1040 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1041         float checkfailv = (func)(parm);                                                                                \
1042         if (checkfailv != (val)) {                                                                                      \
1043                 if (!checkfail[(flag)])                                                                                     \
1044                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1045                 checkfail[(flag)] = 1;                                                                                      \
1046         }                                                                                                               \
1047 } while(0)
1048         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1049         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1050         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1051         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1052         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1053         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1054         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1055
1056         vf_size = getpropertyvec(VF_SIZE);
1057         vf_min = getpropertyvec(VF_MIN);
1058         vid_width = vf_size.x;
1059         vid_height = vf_size.y;
1060
1061         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1062         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1063
1064         WaypointSprite_Load();
1065
1066         CSQCPlayer_SetCamera();
1067
1068         if(player_localentnum <= maxclients) // is it a client?
1069                 current_player = player_localentnum - 1;
1070         else // then player_localentnum is the vehicle I'm driving
1071                 current_player = player_localnum;
1072         myteam = GetPlayerColor(current_player);
1073
1074         if(myteam != prev_myteam)
1075         {
1076                 myteamcolors = colormapPaletteColor(myteam, 1);
1077                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1078                         hud_panel[i].update_time = time;
1079                 prev_myteam = myteam;
1080         }
1081
1082         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1083
1084         float is_dead = (getstati(STAT_HEALTH) <= 0);
1085
1086         // FIXME do we need this hack?
1087         if(isdemo())
1088         {
1089                 // in demos, input_buttons do not work
1090                 button_zoom = (autocvar__togglezoom == "-");
1091         }
1092         else if(button_zoom
1093                 && autocvar_cl_unpress_zoom_on_death
1094                 && (spectatee_status >= 0)
1095                 && (is_dead || intermission))
1096         {
1097                 // no zoom while dead or in intermission please
1098                 localcmd("-zoom\n");
1099                 button_zoom = false;
1100         }
1101
1102         // event chase camera
1103         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1104         {
1105                 if(WantEventchase())
1106                 {
1107                         eventchase_running = true;
1108
1109                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1110                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1111
1112                         // detect maximum viewoffset and use it
1113                         if(autocvar_cl_eventchase_viewoffset)
1114                         {
1115                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1116                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1117                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1118                         }
1119
1120                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1121                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1122                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1123                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1124
1125                         // make the camera smooth back
1126                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1127                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1128                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1129                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1130
1131                         makevectors(view_angles);
1132
1133                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1134                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1135
1136                         // If the boxtrace fails, revert back to line tracing.
1137                         if(!self.viewloc)
1138                         if(trace_startsolid)
1139                         {
1140                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1141                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1142                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1143                         }
1144                         else { setproperty(VF_ORIGIN, trace_endpos); }
1145
1146                         if(!self.viewloc)
1147                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1148                 }
1149                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1150                 {
1151                         eventchase_running = false;
1152                         cvar_set("chase_active", "0");
1153                         eventchase_current_distance = 0; // start from 0 next time
1154                 }
1155         }
1156         // workaround for camera stuck between player's legs when using chase_active 1
1157         // because the engine stops updating the chase_active camera when the game ends
1158         else if(intermission)
1159         {
1160                 cvar_settemp("chase_active", "-1");
1161                 eventchase_current_distance = 0;
1162         }
1163
1164         // do lockview after event chase camera so that it still applies whenever necessary.
1165         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1166         {
1167                 setproperty(VF_ORIGIN, freeze_org);
1168                 setproperty(VF_ANGLES, freeze_ang);
1169         }
1170         else
1171         {
1172                 freeze_org = getpropertyvec(VF_ORIGIN);
1173                 freeze_ang = getpropertyvec(VF_ANGLES);
1174         }
1175
1176         WarpZone_FixView();
1177         //WarpZone_FixPMove();
1178
1179         vector ov_org = '0 0 0';
1180         vector ov_mid = '0 0 0';
1181         vector ov_worldmin = '0 0 0';
1182         vector ov_worldmax = '0 0 0';
1183         if(autocvar_cl_orthoview)
1184         {
1185                 ov_worldmin = mi_picmin;
1186                 ov_worldmax = mi_picmax;
1187
1188                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1189                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1190                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1191
1192                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1193                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1194
1195                 float ov_nearest = vlen(ov_org - vec3(
1196                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1197                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1198                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1199                 ));
1200
1201                 float ov_furthest = 0;
1202                 float dist = 0;
1203
1204                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1205                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1206                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1207                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1208                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1209                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1210                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1211                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1212
1213                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1214                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1215                 cvar_settemp("r_farclip_world", "0");
1216                 cvar_settemp("r_novis", "1");
1217                 cvar_settemp("r_useportalculling", "0");
1218                 cvar_settemp("r_useinfinitefarclip", "0");
1219
1220                 setproperty(VF_ORIGIN, ov_org);
1221                 setproperty(VF_ANGLES, '90 0 0');
1222
1223                 #if 0
1224                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1225                         vtos(ov_org),
1226                         vtos(getpropertyvec(VF_ANGLES)),
1227                         ov_distance,
1228                         ov_nearest,
1229                         ov_furthest);
1230                 #endif
1231         }
1232
1233         // Render the Scene
1234         view_origin = getpropertyvec(VF_ORIGIN);
1235         view_angles = getpropertyvec(VF_ANGLES);
1236         makevectors(view_angles);
1237         view_forward = v_forward;
1238         view_right = v_right;
1239         view_up = v_up;
1240
1241 #ifdef BLURTEST
1242         if(time > blurtest_time0 && time < blurtest_time1)
1243         {
1244                 float r, t;
1245
1246                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1247                 r = t * blurtest_radius;
1248                 f = 1 / pow(t, blurtest_power) - 1;
1249
1250                 cvar_set("r_glsl_postprocess", "1");
1251                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1252         }
1253         else
1254         {
1255                 cvar_set("r_glsl_postprocess", "0");
1256                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1257         }
1258 #endif
1259
1260         TargetMusic_Advance();
1261         Fog_Force();
1262
1263         if(drawtime == 0)
1264                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1265         else
1266                 drawframetime = bound(0.000001, time - drawtime, 1);
1267         drawtime = time;
1268
1269         // watch for gametype changes here...
1270         // in ParseStuffCMD the cmd isn't executed yet :/
1271         // might even be better to add the gametype to TE_CSQC_INIT...?
1272         if(!postinit)
1273                 PostInit();
1274
1275         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1276         {
1277                 if(calledhooks & HOOK_START)
1278                 {
1279                         localcmd("\ncl_hook_gameend\n");
1280                         calledhooks |= HOOK_END;
1281                 }
1282         }
1283
1284         Announcer();
1285
1286         fov = autocvar_fov;
1287         if(fov <= 59.5)
1288         {
1289                 if(!zoomscript_caught)
1290                 {
1291                         localcmd("+button9\n");
1292                         zoomscript_caught = 1;
1293                 }
1294         }
1295         else
1296         {
1297                 if(zoomscript_caught)
1298                 {
1299                         localcmd("-button9\n");
1300                         zoomscript_caught = 0;
1301                 }
1302         }
1303
1304         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1305
1306         // next WANTED weapon (for HUD)
1307         switchweapon = getstati(STAT_SWITCHWEAPON);
1308
1309         // currently switching-to weapon (for crosshair)
1310         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1311
1312         // actually active weapon (for zoom)
1313         activeweapon = getstati(STAT_ACTIVEWEAPON);
1314
1315         f = (serverflags & SERVERFLAG_TEAMPLAY);
1316         if(f != teamplay)
1317         {
1318                 teamplay = f;
1319                 HUD_InitScores();
1320         }
1321
1322         if(last_switchweapon != switchweapon)
1323         {
1324                 weapontime = time;
1325                 last_switchweapon = switchweapon;
1326                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1327                 {
1328                         localcmd("-zoom\n");
1329                         button_zoom = false;
1330                 }
1331                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1332                 {
1333                         localcmd("-fire\n");
1334                         localcmd("-fire2\n");
1335                         button_attack2 = false;
1336                 }
1337         }
1338         if(last_activeweapon != activeweapon)
1339         {
1340                 last_activeweapon = activeweapon;
1341
1342                 e = get_weaponinfo(activeweapon);
1343                 if(e.netname != "")
1344                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1345                 else
1346                         localcmd("\ncl_hook_activeweapon none\n");
1347         }
1348
1349         // ALWAYS Clear Current Scene First
1350         clearscene();
1351
1352         setproperty(VF_ORIGIN, view_origin);
1353         setproperty(VF_ANGLES, view_angles);
1354
1355         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1356         setproperty(VF_SIZE, vf_size);
1357         setproperty(VF_MIN, vf_min);
1358
1359         // Assign Standard Viewflags
1360         // Draw the World (and sky)
1361         setproperty(VF_DRAWWORLD, 1);
1362
1363         // Set the console size vars
1364         vid_conwidth = autocvar_vid_conwidth;
1365         vid_conheight = autocvar_vid_conheight;
1366         vid_pixelheight = autocvar_vid_pixelheight;
1367
1368         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1369         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1370         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1371
1372         // Camera for demo playback
1373         if(camera_active)
1374         {
1375                 if(autocvar_camera_enable)
1376                         CSQC_Demo_Camera();
1377                 else
1378                 {
1379                         cvar_set("chase_active", ftos(chase_active_backup));
1380                         cvar_set("cl_demo_mousegrab", "0");
1381                         camera_active = false;
1382                 }
1383         }
1384         else
1385         {
1386 #ifdef CAMERATEST
1387                 if(autocvar_camera_enable)
1388 #else
1389                 if(autocvar_camera_enable && isdemo())
1390 #endif
1391                 {
1392                         // Enable required Darkplaces cvars
1393                         chase_active_backup = autocvar_chase_active;
1394                         cvar_set("chase_active", "2");
1395                         cvar_set("cl_demo_mousegrab", "1");
1396                         camera_active = true;
1397                         camera_mode = false;
1398                 }
1399         }
1400
1401         // Draw the Crosshair
1402         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1403
1404         // Draw the Engine Status Bar (the default Quake HUD)
1405         setproperty(VF_DRAWENGINESBAR, 0);
1406
1407         // Update the mouse position
1408         /*
1409            mousepos_x = vid_conwidth;
1410            mousepos_y = vid_conheight;
1411            mousepos = mousepos*0.5 + getmousepos();
1412          */
1413
1414         e = self;
1415         for(self = world; (self = nextent(self)); )
1416                 if(self.draw)
1417                         self.draw();
1418         self = e;
1419
1420         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1421         renderscene();
1422
1423         // now switch to 2D drawing mode by calling a 2D drawing function
1424         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1425         // next R_RenderScene call
1426         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1427
1428         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1429         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1430         {
1431                 // apply night vision effect
1432                 vector tc_00, tc_01, tc_10, tc_11;
1433                 vector rgb = '0 0 0';
1434
1435                 if(!nightvision_noise)
1436                 {
1437                         nightvision_noise = spawn();
1438                         nightvision_noise.classname = "nightvision_noise";
1439                 }
1440                 if(!nightvision_noise2)
1441                 {
1442                         nightvision_noise2 = spawn();
1443                         nightvision_noise2.classname = "nightvision_noise2";
1444                 }
1445
1446                 // color tint in yellow
1447                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1448
1449                 // draw BG
1450                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1451                 rgb = '1 1 1';
1452                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1453                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1454                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1455                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1456                 tc_11 = tc_01 + tc_10 - tc_00;
1457                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1458                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1459                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1460                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1461                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1462                 R_EndPolygon();
1463
1464                 // draw FG
1465                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1466                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1467                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1468                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1469                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1470                 tc_11 = tc_01 + tc_10 - tc_00;
1471                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1472                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1473                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1474                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1475                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1476                 R_EndPolygon();
1477         }
1478
1479         if(autocvar_cl_reticle)
1480         {
1481                 // Draw the aiming reticle for weapons that use it
1482                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1483                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1484                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1485                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1486                 {
1487                         // no zoom reticle while dead
1488                         reticle_type = 0;
1489                 }
1490                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1491                 {
1492                         if(reticle_image != "") { reticle_type = 2; }
1493                         else { reticle_type = 0; }
1494                 }
1495                 else if(button_zoom || zoomscript_caught)
1496                 {
1497                         // normal zoom
1498                         reticle_type = 1;
1499                 }
1500
1501                 if(reticle_type)
1502                 {
1503                         if(autocvar_cl_reticle_stretch)
1504                         {
1505                                 reticle_size.x = vid_conwidth;
1506                                 reticle_size.y = vid_conheight;
1507                                 reticle_pos.x = 0;
1508                                 reticle_pos.y = 0;
1509                         }
1510                         else
1511                         {
1512                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1513                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1514                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1515                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1516                         }
1517
1518                         if(zoomscript_caught)
1519                                 f = 1;
1520                         else
1521                                 f = current_zoomfraction;
1522
1523                         if(f)
1524                         {
1525                                 switch(reticle_type)
1526                                 {
1527                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1528                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1529                                 }
1530                         }
1531                 }
1532         }
1533         else
1534         {
1535                 if(reticle_type != 0) { reticle_type = 0; }
1536         }
1537
1538
1539         // improved polyblend
1540         if(autocvar_hud_contents)
1541         {
1542                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1543                 vector liquidcolor;
1544
1545                 switch(pointcontents(view_origin))
1546                 {
1547                         case CONTENT_WATER:
1548                                 liquidalpha = autocvar_hud_contents_water_alpha;
1549                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1550                                 incontent = 1;
1551                                 break;
1552
1553                         case CONTENT_LAVA:
1554                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1555                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1556                                 incontent = 1;
1557                                 break;
1558
1559                         case CONTENT_SLIME:
1560                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1561                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1562                                 incontent = 1;
1563                                 break;
1564
1565                         default:
1566                                 liquidalpha = 0;
1567                                 liquidcolor = '0 0 0';
1568                                 incontent = 0;
1569                                 break;
1570                 }
1571
1572                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1573                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1574                         contentfadetime = autocvar_hud_contents_fadeintime;
1575                         liquidalpha_prev = liquidalpha;
1576                         liquidcolor_prev = liquidcolor;
1577                 }
1578                 else
1579                         contentfadetime = autocvar_hud_contents_fadeouttime;
1580
1581                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1582                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1583
1584                 if(contentavgalpha)
1585                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1586
1587                 if(autocvar_hud_postprocessing)
1588                 {
1589                         if(autocvar_hud_contents_blur && contentavgalpha)
1590                         {
1591                                 content_blurpostprocess.x = 1;
1592                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1593                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1594                         }
1595                         else
1596                         {
1597                                 content_blurpostprocess.x = 0;
1598                                 content_blurpostprocess.y = 0;
1599                                 content_blurpostprocess.z = 0;
1600                         }
1601                 }
1602         }
1603
1604         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1605         {
1606                 splash_size.x = max(vid_conwidth, vid_conheight);
1607                 splash_size.y = max(vid_conwidth, vid_conheight);
1608                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1609                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1610
1611                 float myhealth_flash_temp;
1612                 myhealth = getstati(STAT_HEALTH);
1613
1614                 // fade out
1615                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1616                 // add new damage
1617                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1618
1619                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1620                 pain_threshold = autocvar_hud_damage_pain_threshold;
1621                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1622                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1623
1624                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1625                 {
1626                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1627                 }
1628
1629                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1630
1631                 if(myhealth_prev < 1)
1632                 {
1633                         if(myhealth >= 1)
1634                         {
1635                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1636                                 myhealth_flash_temp = 0;
1637                         }
1638                         else
1639                         {
1640                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1641                         }
1642                 }
1643
1644                 if(spectatee_status == -1 || intermission)
1645                 {
1646                         myhealth_flash = 0; // observing, or match ended
1647                         myhealth_flash_temp = 0;
1648                 }
1649
1650                 myhealth_prev = myhealth;
1651
1652                 // IDEA: change damage color/picture based on player model for robot/alien species?
1653                 // pro: matches model better
1654                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1655                 // maybe different reddish pics?
1656                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1657                 {
1658                         if(autocvar_cl_gentle_damage == 2)
1659                         {
1660                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1661                                 {
1662                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1663                                 }
1664                         }
1665                         else
1666                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1667
1668                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1669                 }
1670                 else
1671                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1672
1673                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1674                 {
1675                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1676                         {
1677                                 damage_blurpostprocess.x = 1;
1678                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1679                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1680                         }
1681                         else
1682                         {
1683                                 damage_blurpostprocess.x = 0;
1684                                 damage_blurpostprocess.y = 0;
1685                                 damage_blurpostprocess.z = 0;
1686                         }
1687                 }
1688         }
1689
1690         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1691         float e2 = (autocvar_hud_powerup != 0);
1692         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1693         {
1694                 // enable or disable rendering types if they are used or not
1695                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1696                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1697
1698                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1699                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1700                 {
1701                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1702                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1703                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1704                         {
1705                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1706                                 old_blurradius = blurradius;
1707                                 old_bluralpha = bluralpha;
1708                         }
1709                 }
1710                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1711                 {
1712                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1713                         old_blurradius = 0;
1714                         old_bluralpha = 0;
1715                 }
1716
1717                 // edge detection postprocess handling done second (used by hud_powerup)
1718                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1719                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1720                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1721
1722                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1723
1724                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1725                 {
1726                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1727                         {
1728                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1729                                 old_sharpen_intensity = sharpen_intensity;
1730                         }
1731                 }
1732                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1733                 {
1734                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1735                         old_sharpen_intensity = 0;
1736                 }
1737
1738                 if(cvar("r_glsl_postprocess") == 0)
1739                         cvar_set("r_glsl_postprocess", "2");
1740         }
1741         else if(cvar("r_glsl_postprocess") == 2)
1742                 cvar_set("r_glsl_postprocess", "0");
1743
1744         if(menu_visible)
1745                 menu_show();
1746
1747         /*if(gametype == MAPINFO_TYPE_CTF)
1748           {
1749           ctf_view();
1750           } else */
1751
1752         // draw 2D entities
1753         e = self;
1754         for(self = world; (self = nextent(self)); )
1755                 if(self.draw2d)
1756                         self.draw2d();
1757         self = e;
1758         Draw_ShowNames_All();
1759
1760         scoreboard_active = HUD_WouldDrawScoreboard();
1761
1762         UpdateDamage();
1763         UpdateCrosshair();
1764         UpdateHitsound();
1765
1766         if(NextFrameCommand)
1767         {
1768                 localcmd("\n", NextFrameCommand, "\n");
1769                 NextFrameCommand = string_null;
1770         }
1771
1772         // we must do this check AFTER a frame was rendered, or it won't work
1773         if(cs_project_is_b0rked == 0)
1774         {
1775                 string w0, h0;
1776                 w0 = ftos(autocvar_vid_conwidth);
1777                 h0 = ftos(autocvar_vid_conheight);
1778                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1779                 //setproperty(VF_FOV, '90 90 0');
1780                 setproperty(VF_ORIGIN, '0 0 0');
1781                 setproperty(VF_ANGLES, '0 0 0');
1782                 setproperty(VF_PERSPECTIVE, 1);
1783                 makevectors('0 0 0');
1784                 vector v1, v2;
1785                 cvar_set("vid_conwidth", "800");
1786                 cvar_set("vid_conheight", "600");
1787                 v1 = cs_project(v_forward);
1788                 cvar_set("vid_conwidth", "640");
1789                 cvar_set("vid_conheight", "480");
1790                 v2 = cs_project(v_forward);
1791                 if(v1 == v2)
1792                         cs_project_is_b0rked = 1;
1793                 else
1794                         cs_project_is_b0rked = -1;
1795                 cvar_set("vid_conwidth", w0);
1796                 cvar_set("vid_conheight", h0);
1797         }
1798
1799         if(autocvar__hud_configure)
1800                 HUD_Panel_Mouse();
1801
1802     if(hud && !intermission)
1803     {
1804         if(hud == HUD_SPIDERBOT)
1805             CSQC_SPIDER_HUD();
1806         else if(hud == HUD_WAKIZASHI)
1807             CSQC_WAKIZASHI_HUD();
1808         else if(hud == HUD_RAPTOR)
1809             CSQC_RAPTOR_HUD();
1810         else if(hud == HUD_BUMBLEBEE)
1811             CSQC_BUMBLE_HUD();
1812         else if(hud == HUD_BUMBLEBEE_GUN)
1813             CSQC_BUMBLE_GUN_HUD();
1814     }
1815
1816         cl_notice_run();
1817
1818         // let's reset the view back to normal for the end
1819         setproperty(VF_MIN, '0 0 0');
1820         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1821 }
1822
1823
1824 void CSQC_common_hud(void)
1825 {
1826         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1827                 Accuracy_LoadLevels();
1828
1829         HUD_Main(); // always run these functions for alpha checks
1830         HUD_DrawScoreboard();
1831
1832         // scoreboard/accuracy, map/gametype voting screen
1833         if (scoreboard_active || intermission == 2)
1834                 HUD_Reset();
1835 }
1836
1837
1838 // following vectors must be global to allow seamless switching between camera modes
1839 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1840 void CSQC_Demo_Camera()
1841 {
1842         float speed, attenuation, dimensions;
1843         vector tmp, delta;
1844
1845         if( autocvar_camera_reset || !camera_mode )
1846         {
1847                 camera_offset = '0 0 0';
1848                 current_angles = '0 0 0';
1849                 camera_direction = '0 0 0';
1850                 camera_offset.z += 30;
1851                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1852                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1853                 current_origin = view_origin;
1854                 current_camera_offset  = camera_offset;
1855                 cvar_set("camera_reset", "0");
1856                 camera_mode = CAMERA_CHASE;
1857         }
1858
1859         // Camera angles
1860         if( camera_roll )
1861                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1862
1863         if(autocvar_camera_look_player)
1864         {
1865                 vector dir;
1866                 float n;
1867
1868                 dir = normalize(view_origin - current_position);
1869                 n = mouse_angles.z;
1870                 mouse_angles = vectoangles(dir);
1871                 mouse_angles.x = mouse_angles.x * -1;
1872                 mouse_angles.z = n;
1873         }
1874         else
1875         {
1876                 tmp = getmousepos() * 0.1;
1877                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1878                 {
1879                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1880                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1881                 }
1882         }
1883
1884         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1885         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1886         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1887         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1888
1889         // Fix difference when angles don't have the same sign
1890         delta = '0 0 0';
1891         if(mouse_angles.y < -60 && current_angles.y > 60)
1892                 delta = '0 360 0';
1893         if(mouse_angles.y > 60 && current_angles.y < -60)
1894                 delta = '0 -360 0';
1895
1896         if(autocvar_camera_look_player)
1897                 attenuation = autocvar_camera_look_attenuation;
1898         else
1899                 attenuation = autocvar_camera_speed_attenuation;
1900
1901         attenuation = 1 / max(1, attenuation);
1902         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1903
1904         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1905         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1906         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1907         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1908
1909         // Camera position
1910         tmp = '0 0 0';
1911         dimensions = 0;
1912
1913         if( camera_direction.x )
1914         {
1915                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1916                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1917                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1918                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1919                 ++dimensions;
1920         }
1921
1922         if( camera_direction.y )
1923         {
1924                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1925                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1926                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1927                 ++dimensions;
1928         }
1929
1930         if( camera_direction.z )
1931         {
1932                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1933                 ++dimensions;
1934         }
1935
1936         if(autocvar_camera_free)
1937                 speed = autocvar_camera_speed_free;
1938         else
1939                 speed = autocvar_camera_speed_chase;
1940
1941         if(dimensions)
1942         {
1943                 speed = speed * sqrt(1 / dimensions);
1944                 camera_offset += tmp * speed;
1945         }
1946
1947         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1948
1949         // Camera modes
1950         if( autocvar_camera_free )
1951         {
1952                 if ( camera_mode == CAMERA_CHASE )
1953                 {
1954                         current_camera_offset = current_origin + current_camera_offset;
1955                         camera_offset = current_origin + camera_offset;
1956                 }
1957
1958                 camera_mode = CAMERA_FREE;
1959                 current_position = current_camera_offset;
1960         }
1961         else
1962         {
1963                 if ( camera_mode == CAMERA_FREE )
1964                 {
1965                         current_origin = view_origin;
1966                         camera_offset = camera_offset - current_origin;
1967                         current_camera_offset = current_camera_offset - current_origin;
1968                 }
1969
1970                 camera_mode = CAMERA_CHASE;
1971
1972                 if(autocvar_camera_chase_smoothly)
1973                         current_origin += (view_origin - current_origin) * attenuation;
1974                 else
1975                         current_origin = view_origin;
1976
1977                 current_position = current_origin + current_camera_offset;
1978         }
1979
1980         setproperty(VF_ANGLES, current_angles);
1981         setproperty(VF_ORIGIN, current_position);
1982 }