qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 void viewmodel_draw(entity this)
 285 {
 286         if(!activeweapon || !autocvar_r_drawviewmodel)
 287                 return;
 288         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 289         float a = this.alpha;
 290         static bool wasinvehicle;
 291         bool invehicle = player_localentnum > maxclients;
 292         if (invehicle) a = -1;
 293         else if (wasinvehicle) a = 1;
 294         wasinvehicle = invehicle;
 295         Weapon wep = activeweapon;
 296         int c = entcs_GetClientColors(current_player);
 297         vector g = weaponentity_glowmod(wep, NULL, c);
 298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 300                 | EF_NODEPTHTEST)
 301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 302         for (entity e = this; e; e = e.weaponchild)
 303         {
 304                 e.drawmask = mask;
 305                 e.alpha = a;
 306                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 307                 e.glowmod = g;
 308                 e.csqcmodel_effects = fx;
 309                 CSQCModel_Effects_Apply(e);
 310         }
 311         {
 312                 static string name_last;
 313                 string name = wep.mdl;
 314                 bool swap = name != name_last;
 315                 // if (swap)
 316                 {
 317                         name_last = name;
 318                         CL_WeaponEntity_SetModel(this, name, swap);
 319                         this.viewmodel_origin = this.origin;
 320                         this.viewmodel_angles = this.angles;
 321                 }
 322                 anim_update(this);
 323                 if (!this.animstate_override && !this.animstate_looping)
 324                         anim_set(this, this.anim_idle, true, false, false);
 325         }
 326         float f = 0; // 0..1; 0: fully active
 327         float rate = STAT(WEAPONRATEFACTOR);
 328         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 329         if (eta <= 0) f = this.weapon_eta_last;
 330         else switch (this.state)
 331         {
 332                 case WS_RAISE:
 333                 {
 334                         f = eta / max(eta, this.weapon_switchdelay);
 335                         break;
 336                 }
 337                 case WS_DROP:
 338                 {
 339                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 340                         break;
 341                 }
 342                 case WS_CLEAR:
 343                 {
 344                         f = 1;
 345                         break;
 346                 }
 347         }
 348         this.weapon_eta_last = f;
 349         this.origin = this.viewmodel_origin;
 350         this.angles = this.viewmodel_angles;
 351         this.angles_x = (-90 * f * f);
 352         viewmodel_animate(this);
 353         setorigin(this, this.origin);
 354 }
 355
 356 entity viewmodel;
 357 STATIC_INIT(viewmodel) {
 358     viewmodel = new(viewmodel);
 359 }
 360
 361 void Porto_Draw(entity this);
 362 STATIC_INIT(Porto)
 363 {
 364         entity e = new_pure(porto);
 365         e.draw = Porto_Draw;
 366         IL_PUSH(g_drawables, e);
 367         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 368 }
 369
 370 const int polyline_length = 16;
 371 vector polyline[polyline_length];
 372 void Porto_Draw(entity this)
 373 {
 374         if (activeweapon != WEP_PORTO) return;
 375         if (spectatee_status) return;
 376         if (WEP_CVAR(porto, secondary)) return;
 377         if (intermission == 1) return;
 378         if (intermission == 2) return;
 379         if (STAT(HEALTH) <= 0) return;
 380
 381         vector pos = view_origin;
 382         vector dir = view_forward;
 383         if (angles_held_status)
 384         {
 385                 makevectors(angles_held);
 386                 dir = v_forward;
 387         }
 388
 389         polyline[0] = pos;
 390
 391         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 392         int n = 1 + 2;  // 2 lines == 3 points
 393         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 394         {
 395                 traceline(pos, pos + 65536 * dir, true, this);
 396                 dir = reflect(dir, trace_plane_normal);
 397                 pos = trace_endpos;
 398                 polyline[++idx] = pos;
 399                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 400                 {
 401                         n += 1;
 402                         continue;
 403                 }
 404                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 405                 {
 406                         n = max(2, idx);
 407                         break;
 408                 }
 409                 // check size
 410                 {
 411                         vector ang = vectoangles2(trace_plane_normal, dir);
 412                         ang.x = -ang.x;
 413                         makevectors(ang);
 414                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 415                         {
 416                                 n = max(2, idx);
 417                                 break;
 418                         }
 419                 }
 420                 portal_number += 1;
 421                 if (portal_number >= portal_max) break;
 422                 if (portal_number == 1) portal1_idx = idx;
 423         }
 424         for (int idx = 0; idx < n - 1; ++idx)
 425         {
 426                 vector p = polyline[idx], q = polyline[idx + 1];
 427                 if (idx == 0) p -= view_up * 16;  // line from player
 428                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 429                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 430         }
 431 }
 432
 433 float drawtime;
 434 float avgspeed;
 435 vector GetCurrentFov(float fov)
 436 {
 437         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 438         float velocityzoom, curspeed;
 439         vector v;
 440
 441         zoomsensitivity = autocvar_cl_zoomsensitivity;
 442         zoomfactor = autocvar_cl_zoomfactor;
 443         if(zoomfactor < 1 || zoomfactor > 30)
 444                 zoomfactor = 2.5;
 445         zoomspeed = autocvar_cl_zoomspeed;
 446         if(zoomspeed >= 0)
 447         if(zoomspeed < 0.5 || zoomspeed > 16)
 448                         zoomspeed = 3.5;
 449
 450         zoomdir = button_zoom;
 451         if(hud == HUD_NORMAL && !spectatee_status)
 452         if(switchweapon == activeweapon)
 453         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 454                 zoomdir += button_attack2;
 455         if(spectatee_status > 0 || isdemo())
 456         {
 457                 if(spectatorbutton_zoom)
 458                 {
 459                         if(zoomdir)
 460                                 zoomdir = 0;
 461                         else
 462                                 zoomdir = 1;
 463                 }
 464                 // fteqcc failed twice here already, don't optimize this
 465         }
 466
 467         if(zoomdir) { zoomin_effect = 0; }
 468
 469         if(camera_active)
 470         {
 471                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 472         }
 473         else if(autocvar_cl_spawnzoom && zoomin_effect)
 474         {
 475                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 476
 477                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 478                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 479                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 480         }
 481         else
 482         {
 483                 if(zoomspeed < 0) // instant zoom
 484                 {
 485                         if(zoomdir)
 486                                 current_viewzoom = 1 / zoomfactor;
 487                         else
 488                                 current_viewzoom = 1;
 489                 }
 490                 else
 491                 {
 492                         if(zoomdir)
 493                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 494                         else
 495                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 496                 }
 497         }
 498
 499         if(almost_equals(current_viewzoom, 1))
 500                 current_zoomfraction = 0;
 501         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 502                 current_zoomfraction = 1;
 503         else
 504                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 505
 506         if(zoomsensitivity < 1)
 507                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 508         else
 509                 setsensitivityscale(1);
 510
 511         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 512         {
 513                 if(intermission) { curspeed = 0; }
 514                 else
 515                 {
 516
 517                         makevectors(view_angles);
 518                         v = pmove_vel;
 519                         if(csqcplayer)
 520                                 v = csqcplayer.velocity;
 521
 522                         switch(autocvar_cl_velocityzoom_type)
 523                         {
 524                                 case 3: curspeed = max(0, v_forward * v); break;
 525                                 case 2: curspeed = (v_forward * v); break;
 526                                 case 1: default: curspeed = vlen(v); break;
 527                         }
 528                 }
 529
 530                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 531                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 532                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 533
 534                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 535         }
 536         else
 537                 velocityzoom = 1;
 538
 539         float frustumx, frustumy, fovx, fovy;
 540         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 541         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 542         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 543         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 544
 545         return '1 0 0' * fovx + '0 1 0' * fovy;
 546 }
 547
 548 vector GetViewLocationFOV(float fov)
 549 {
 550         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 551         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 552         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 553         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 554         return '1 0 0' * fovx + '0 1 0' * fovy;
 555 }
 556
 557 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 558 {
 559         float fovx, fovy;
 560         float width = (ov_worldmax.x - ov_worldmin.x);
 561         float height = (ov_worldmax.y - ov_worldmin.y);
 562         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 563         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 564         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 565         return '1 0 0' * fovx + '0 1 0' * fovy;
 566 }
 567
 568 // this function must match W_SetupShot!
 569 float zoomscript_caught;
 570
 571 vector wcross_origin;
 572 float wcross_scale_prev, wcross_alpha_prev;
 573 vector wcross_color_prev;
 574 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 575 vector wcross_color_goal_prev;
 576 float wcross_changedonetime;
 577
 578 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 579 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 580 float wcross_name_changestarttime, wcross_name_changedonetime;
 581 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 582
 583 float wcross_ring_prev;
 584
 585 entity trueaim;
 586 entity trueaim_rifle;
 587
 588 const float SHOTTYPE_HITTEAM = 1;
 589 const float SHOTTYPE_HITOBSTRUCTION = 2;
 590 const float SHOTTYPE_HITWORLD = 3;
 591 const float SHOTTYPE_HITENEMY = 4;
 592
 593 void TrueAim_Init()
 594 {
 595         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 596         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 597 }
 598
 599 float EnemyHitCheck()
 600 {
 601         float t, n;
 602         wcross_origin = project_3d_to_2d(trace_endpos);
 603         wcross_origin.z = 0;
 604         if(trace_ent)
 605                 n = trace_ent.entnum;
 606         else
 607                 n = trace_networkentity;
 608         if(n < 1)
 609                 return SHOTTYPE_HITWORLD;
 610         if(n > maxclients)
 611                 return SHOTTYPE_HITWORLD;
 612         t = entcs_GetTeam(n - 1);
 613         if(teamplay)
 614                 if(t == myteam)
 615                         return SHOTTYPE_HITTEAM;
 616         if(t == NUM_SPECTATOR)
 617                 return SHOTTYPE_HITWORLD;
 618         return SHOTTYPE_HITENEMY;
 619 }
 620
 621 float TrueAimCheck()
 622 {
 623         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 624         vector vecs, trueaimpoint, w_shotorg;
 625         vector mi, ma, dv;
 626         float shottype;
 627         entity ta;
 628         float mv;
 629
 630         mi = ma = '0 0 0';
 631         ta = trueaim;
 632         mv = MOVE_NOMONSTERS;
 633
 634         switch(activeweapon) // WEAPONTODO
 635         {
 636                 case WEP_TUBA: // no aim
 637                 case WEP_PORTO: // shoots from eye
 638                 case WEP_NEXBALL: // shoots from eye
 639                 case WEP_HOOK: // no trueaim
 640                 case WEP_MORTAR: // toss curve
 641                         return SHOTTYPE_HITWORLD;
 642                 case WEP_VORTEX:
 643                 case WEP_VAPORIZER:
 644                         mv = MOVE_NORMAL;
 645                         break;
 646                 case WEP_RIFLE:
 647                         ta = trueaim_rifle;
 648                         mv = MOVE_NORMAL;
 649                         if(zoomscript_caught)
 650                         {
 651                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 652                                 return EnemyHitCheck();
 653                         }
 654                         break;
 655                 case WEP_DEVASTATOR: // projectile has a size!
 656                         mi = '-3 -3 -3';
 657                         ma = '3 3 3';
 658                         break;
 659                 case WEP_FIREBALL: // projectile has a size!
 660                         mi = '-16 -16 -16';
 661                         ma = '16 16 16';
 662                         break;
 663                 case WEP_SEEKER: // projectile has a size!
 664                         mi = '-2 -2 -2';
 665                         ma = '2 2 2';
 666                         break;
 667                 case WEP_ELECTRO: // projectile has a size!
 668                         mi = '0 0 -3';
 669                         ma = '0 0 -3';
 670                         break;
 671         }
 672
 673         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 674
 675         vecs = decompressShotOrigin(STAT(SHOTORG));
 676
 677         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 678         trueaimpoint = trace_endpos;
 679
 680         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 681                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 682
 683         if(vecs.x > 0)
 684                 vecs.y = -vecs.y;
 685         else
 686                 vecs = '0 0 0';
 687
 688         dv = view_right * vecs.y + view_up * vecs.z;
 689         w_shotorg = traceorigin + dv;
 690
 691         // now move the vecs forward as much as requested if possible
 692         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 693         w_shotorg = trace_endpos - view_forward * nudge;
 694
 695         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 696         shottype = EnemyHitCheck();
 697         if(shottype != SHOTTYPE_HITWORLD)
 698                 return shottype;
 699
 700 #if 0
 701         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 702         // or rather, I know why, but see no fix
 703         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 704                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 705                 return SHOTTYPE_HITOBSTRUCTION;
 706 #endif
 707
 708         return SHOTTYPE_HITWORLD;
 709 }
 710
 711 void PostInit();
 712 void CSQC_Demo_Camera();
 713 float camera_mode;
 714 const float CAMERA_FREE = 1;
 715 const float CAMERA_CHASE = 2;
 716 float reticle_type;
 717 string reticle_image;
 718 string NextFrameCommand;
 719
 720 vector freeze_org, freeze_ang;
 721 entity nightvision_noise, nightvision_noise2;
 722
 723 const float MAX_TIME_DIFF = 5;
 724 float pickup_crosshair_time, pickup_crosshair_size;
 725 float hitindication_crosshair_size;
 726 float use_vortex_chargepool;
 727
 728 float myhealth, myhealth_prev;
 729 float myhealth_flash;
 730
 731 float old_blurradius, old_bluralpha;
 732 float old_sharpen_intensity;
 733
 734 vector myhealth_gentlergb;
 735
 736 float contentavgalpha, liquidalpha_prev;
 737 vector liquidcolor_prev;
 738
 739 float eventchase_current_distance;
 740 float eventchase_running;
 741 bool WantEventchase(entity this)
 742 {
 743         if(autocvar_cl_orthoview)
 744                 return false;
 745         if(intermission)
 746                 return true;
 747         if(this.viewloc)
 748                 return true;
 749         if(spectatee_status >= 0)
 750         {
 751                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 752                         return true;
 753                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 754                         return true;
 755                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 756                 {
 757                         if(autocvar_cl_eventchase_death == 2)
 758                         {
 759                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 760                                 if(this.velocity == '0 0 0' || eventchase_running)
 761                                         return true;
 762                         }
 763                         else return true;
 764                 }
 765         }
 766         return false;
 767 }
 768
 769 void HUD_Crosshair_Vehicle(entity this)
 770 {
 771         if(hud != HUD_BUMBLEBEE_GUN)
 772         {
 773                 Vehicle info = Vehicles_from(hud);
 774                 info.vr_crosshair(info, this);
 775         }
 776 }
 777
 778 vector damage_blurpostprocess, content_blurpostprocess;
 779
 780 float unaccounted_damage = 0;
 781 void UpdateDamage()
 782 {
 783         // accumulate damage with each stat update
 784         static float damage_total_prev = 0;
 785         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 786         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 787         damage_total_prev = damage_total;
 788
 789         static float damage_dealt_time_prev = 0;
 790         float damage_dealt_time = STAT(HIT_TIME);
 791         if (damage_dealt_time != damage_dealt_time_prev)
 792         {
 793                 unaccounted_damage += unaccounted_damage_new;
 794                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 795         }
 796         damage_dealt_time_prev = damage_dealt_time;
 797
 798         // prevent hitsound when switching spectatee
 799         static float spectatee_status_prev = 0;
 800         if (spectatee_status != spectatee_status_prev)
 801                 unaccounted_damage = 0;
 802         spectatee_status_prev = spectatee_status;
 803 }
 804
 805 void HitSound()
 806 {
 807         // varying sound pitch
 808
 809         static float hitsound_time_prev = 0;
 810         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 811         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 812         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 813         {
 814                 if (autocvar_cl_hitsound && unaccounted_damage)
 815                 {
 816                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 817                         float a = autocvar_cl_hitsound_max_pitch;
 818                         float b = autocvar_cl_hitsound_min_pitch;
 819                         float c = autocvar_cl_hitsound_nom_damage;
 820                         float x = unaccounted_damage;
 821                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 822
 823                         // if sound variation is disabled, set pitch_shift to 1
 824                         if (autocvar_cl_hitsound == 1)
 825                                 pitch_shift = 1;
 826
 827                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 828                         if (autocvar_cl_hitsound == 3)
 829                         {
 830                                 float mirror_value = (a-b)/2 + b;
 831                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 832                         }
 833
 834                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 835
 836                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 837                         // todo: normalize sound pressure levels? seems unnecessary
 838
 839                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 840                 }
 841                 unaccounted_damage = 0;
 842                 hitsound_time_prev = time;
 843         }
 844
 845         static float typehit_time_prev = 0;
 846         float typehit_time = STAT(TYPEHIT_TIME);
 847         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 848         {
 849                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 850                 typehit_time_prev = typehit_time;
 851         }
 852 }
 853
 854 vector crosshair_getcolor(entity this, float health_stat)
 855 {
 856         static float rainbow_last_flicker;
 857         static vector rainbow_prev_color;
 858         vector wcross_color = '0 0 0';
 859         switch(autocvar_crosshair_color_special)
 860         {
 861                 case 1: // crosshair_color_per_weapon
 862                 {
 863                         if(this != WEP_Null && hud == HUD_NORMAL)
 864                         {
 865                                 wcross_color = this.wpcolor;
 866                                 break;
 867                         }
 868                         else { goto normalcolor; }
 869                 }
 870
 871                 case 2: // crosshair_color_by_health
 872                 {
 873                         float x = health_stat;
 874
 875                         //x = red
 876                         //y = green
 877                         //z = blue
 878
 879                         wcross_color.z = 0;
 880
 881                         if(x > 200)
 882                         {
 883                                 wcross_color.x = 0;
 884                                 wcross_color.y = 1;
 885                         }
 886                         else if(x > 150)
 887                         {
 888                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 889                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 890                         }
 891                         else if(x > 100)
 892                         {
 893                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 894                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 895                                 wcross_color.z = 1 - (x-100)*0.02;
 896                         }
 897                         else if(x > 50)
 898                         {
 899                                 wcross_color.x = 1;
 900                                 wcross_color.y = 1;
 901                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 902                         }
 903                         else if(x > 20)
 904                         {
 905                                 wcross_color.x = 1;
 906                                 wcross_color.y = (x-20)*90/27/100;
 907                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 908                         }
 909                         else
 910                         {
 911                                 wcross_color.x = 1;
 912                                 wcross_color.y = 0;
 913                         }
 914                         break;
 915                 }
 916
 917                 case 3: // crosshair_color_rainbow
 918                 {
 919                         if(time >= rainbow_last_flicker)
 920                         {
 921                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 922                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 923                         }
 924                         wcross_color = rainbow_prev_color;
 925                         break;
 926                 }
 927 LABEL(normalcolor)
 928                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 929         }
 930
 931         return wcross_color;
 932 }
 933
 934 void HUD_Crosshair(entity this)
 935 {
 936         float f, i, j;
 937         vector v;
 938         if(!scoreboard_active && !camera_active && intermission != 2 &&
 939                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 940                 !HUD_MinigameMenu_IsOpened() )
 941         {
 942                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 943                         return;
 944
 945                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 946                         return;
 947
 948                 if (hud != HUD_NORMAL)
 949                 {
 950                         HUD_Crosshair_Vehicle(this);
 951                         return;
 952                 }
 953
 954                 string wcross_style;
 955                 float wcross_alpha, wcross_resolution;
 956                 wcross_style = autocvar_crosshair;
 957                 if (wcross_style == "0")
 958                         return;
 959                 wcross_resolution = autocvar_crosshair_size;
 960                 if (wcross_resolution == 0)
 961                         return;
 962                 wcross_alpha = autocvar_crosshair_alpha;
 963                 if (wcross_alpha == 0)
 964                         return;
 965
 966                 // TrueAim check
 967                 float shottype;
 968
 969                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 970                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 971                 wcross_origin.z = 0;
 972                 if(autocvar_crosshair_hittest)
 973                 {
 974                         vector wcross_oldorigin;
 975                         wcross_oldorigin = wcross_origin;
 976                         shottype = TrueAimCheck();
 977                         if(shottype == SHOTTYPE_HITWORLD)
 978                         {
 979                                 v = wcross_origin - wcross_oldorigin;
 980                                 v.x /= vid_conwidth;
 981                                 v.y /= vid_conheight;
 982                                 if(vdist(v, >, 0.01))
 983                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 984                         }
 985                         if(!autocvar_crosshair_hittest_showimpact)
 986                                 wcross_origin = wcross_oldorigin;
 987                 }
 988                 else
 989                         shottype = SHOTTYPE_HITWORLD;
 990
 991                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 992                 string wcross_name = "";
 993                 float wcross_scale, wcross_blur;
 994
 995         entity e = WEP_Null;
 996                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 997                 {
 998                         e = switchingweapon;
 999                         if(e)
1000                         {
1001                                 if(autocvar_crosshair_per_weapon)
1002                                 {
1003                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1004                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1005                                         //if (wcross_resolution == 0)
1006                                                 //return;
1007
1008                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1009                                         wcross_resolution *= e.w_crosshair_size;
1010                                         wcross_name = e.w_crosshair;
1011                                 }
1012                         }
1013                 }
1014
1015                 if(wcross_name == "")
1016                         wcross_name = strcat("gfx/crosshair", wcross_style);
1017
1018                 // MAIN CROSSHAIR COLOR DECISION
1019                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1020
1021                 if(autocvar_crosshair_effect_scalefade)
1022                 {
1023                         wcross_scale = wcross_resolution;
1024                         wcross_resolution = 1;
1025                 }
1026                 else
1027                 {
1028                         wcross_scale = 1;
1029                 }
1030
1031                 if(autocvar_crosshair_pickup)
1032                 {
1033                         float stat_pickup_time = STAT(LAST_PICKUP);
1034
1035                         if(pickup_crosshair_time < stat_pickup_time)
1036                         {
1037                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1038                                         pickup_crosshair_size = 1;
1039
1040                                 pickup_crosshair_time = stat_pickup_time;
1041                         }
1042
1043                         if(pickup_crosshair_size > 0)
1044                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1045                         else
1046                                 pickup_crosshair_size = 0;
1047
1048                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1049                 }
1050
1051                 // todo: make crosshair hit indication dependent on damage dealt
1052                 if(autocvar_crosshair_hitindication)
1053                 {
1054                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1055
1056                         if(unaccounted_damage)
1057                         {
1058                                 hitindication_crosshair_size = 1;
1059                         }
1060
1061                         if(hitindication_crosshair_size > 0)
1062                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1063                         else
1064                                 hitindication_crosshair_size = 0;
1065
1066                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1067                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1068                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1069                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1070                 }
1071
1072                 if(shottype == SHOTTYPE_HITENEMY)
1073                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1074                 if(shottype == SHOTTYPE_HITTEAM)
1075                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1076
1077                 f = fabs(autocvar_crosshair_effect_time);
1078                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1079                 {
1080                         wcross_changedonetime = time + f;
1081                 }
1082                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1083                 {
1084                         wcross_name_changestarttime = time;
1085                         wcross_name_changedonetime = time + f;
1086                         if(wcross_name_goal_prev_prev)
1087                                 strunzone(wcross_name_goal_prev_prev);
1088                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1089                         wcross_name_goal_prev = strzone(wcross_name);
1090                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1091                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1092                         wcross_resolution_goal_prev = wcross_resolution;
1093                 }
1094
1095                 wcross_scale_goal_prev = wcross_scale;
1096                 wcross_alpha_goal_prev = wcross_alpha;
1097                 wcross_color_goal_prev = wcross_color;
1098
1099                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1100                 {
1101                         wcross_blur = 1;
1102                         wcross_alpha *= 0.75;
1103                 }
1104                 else
1105                         wcross_blur = 0;
1106                 // *_prev is at time-frametime
1107                 // * is at wcross_changedonetime+f
1108                 // what do we have at time?
1109                 if(time < wcross_changedonetime)
1110                 {
1111                         f = frametime / (wcross_changedonetime - time + frametime);
1112                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1113                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1114                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1115                 }
1116
1117                 wcross_scale_prev = wcross_scale;
1118                 wcross_alpha_prev = wcross_alpha;
1119                 wcross_color_prev = wcross_color;
1120
1121                 MUTATOR_CALLHOOK(UpdateCrosshair);
1122
1123                 wcross_scale *= 1 - autocvar__menu_alpha;
1124                 wcross_alpha *= 1 - autocvar__menu_alpha;
1125                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1126
1127                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1128                 {
1129                         // crosshair rings for weapon stats
1130                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1131                         {
1132                                 // declarations and stats
1133                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1134                                 string ring_image = string_null, ring_inner_image = string_null;
1135                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1136
1137                                 ring_scale = autocvar_crosshair_ring_size;
1138
1139                                 float weapon_clipload, weapon_clipsize;
1140                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1141                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1142
1143                                 float ok_ammo_charge, ok_ammo_chargepool;
1144                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1145                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1146
1147                                 float vortex_charge, vortex_chargepool;
1148                                 vortex_charge = STAT(VORTEX_CHARGE);
1149                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1150
1151                                 float arc_heat = STAT(ARC_HEAT);
1152
1153                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1154                                         vortex_charge_movingavg = vortex_charge;
1155
1156
1157                                 // handle the values
1158                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1159                                 {
1160                                         if (vortex_chargepool || use_vortex_chargepool) {
1161                                                 use_vortex_chargepool = 1;
1162                                                 ring_inner_value = vortex_chargepool;
1163                                         } else {
1164                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1165                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1166                                         }
1167
1168                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1169                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1170                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1171
1172                                         // draw the outer ring to show the current charge of the weapon
1173                                         ring_value = vortex_charge;
1174                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1175                                         ring_rgb = wcross_color;
1176                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1177                                 }
1178                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1179                                 {
1180                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1181                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1182                                         ring_rgb = wcross_color;
1183                                         ring_image = "gfx/crosshair_ring.tga";
1184                                 }
1185                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1186                                 {
1187                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1188                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1189                                         ring_rgb = wcross_color;
1190                                         ring_image = "gfx/crosshair_ring.tga";
1191                                 }
1192                                 else if (ok_ammo_charge)
1193                                 {
1194                                         ring_value = ok_ammo_chargepool;
1195                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1196                                         ring_rgb = wcross_color;
1197                                         ring_image = "gfx/crosshair_ring.tga";
1198                                 }
1199                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1200                                 {
1201                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1202                                         ring_scale = autocvar_crosshair_ring_reload_size;
1203                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1204                                         ring_rgb = wcross_color;
1205
1206                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1207                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1208                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1209                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1210                                         else
1211                                                 ring_image = "gfx/crosshair_ring.tga";
1212                                 }
1213                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1214                                 {
1215                                         ring_value = arc_heat;
1216                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1217                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1218                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1219                                         ring_image = "gfx/crosshair_ring.tga";
1220                                 }
1221
1222                                 // if in weapon switch animation, fade ring out/in
1223                                 if(autocvar_crosshair_effect_time > 0)
1224                                 {
1225                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1226                                         if (f >= 1)
1227                                         {
1228                                                 wcross_ring_prev = ((ring_image) ? true : false);
1229                                         }
1230
1231                                         if(wcross_ring_prev)
1232                                         {
1233                                                 if(f < 1)
1234                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1235                                         }
1236                                         else
1237                                         {
1238                                                 if(f < 1)
1239                                                         ring_alpha *= bound(0, f, 1);
1240                                         }
1241                                 }
1242
1243                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1244                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1245
1246                                 if (ring_value)
1247                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1248                         }
1249
1250 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1251                         MACRO_BEGIN { \
1252                                 if(wcross_blur > 0) \
1253                                 { \
1254                                         for(i = -2; i <= 2; ++i) \
1255                                         for(j = -2; j <= 2; ++j) \
1256                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1257                                 } \
1258                                 else \
1259                                 { \
1260                                         M(0,0,sz,wcross_name,wcross_alpha); \
1261                                 } \
1262                         } MACRO_END
1263
1264 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1265                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1266
1267 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1268                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1269
1270                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1271                         {
1272                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1273                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1274                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1275                                 f = 1 - f;
1276                         }
1277                         else
1278                         {
1279                                 f = 1;
1280                         }
1281                         wcross_name_alpha_goal_prev = f;
1282
1283                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1284                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1285
1286                         if(autocvar_crosshair_dot)
1287                         {
1288                                 vector wcross_color_old;
1289                                 wcross_color_old = wcross_color;
1290
1291                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1292                                         wcross_color = stov(autocvar_crosshair_dot_color);
1293
1294                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1295                                 // FIXME why don't we use wcross_alpha here?
1296                                 wcross_color = wcross_color_old;
1297                         }
1298                 }
1299         }
1300         else
1301         {
1302                 wcross_scale_prev = 0;
1303                 wcross_alpha_prev = 0;
1304                 wcross_scale_goal_prev = 0;
1305                 wcross_alpha_goal_prev = 0;
1306                 wcross_changedonetime = 0;
1307                 if(wcross_name_goal_prev)
1308                         strunzone(wcross_name_goal_prev);
1309                 wcross_name_goal_prev = string_null;
1310                 if(wcross_name_goal_prev_prev)
1311                         strunzone(wcross_name_goal_prev_prev);
1312                 wcross_name_goal_prev_prev = string_null;
1313                 wcross_name_changestarttime = 0;
1314                 wcross_name_changedonetime = 0;
1315                 wcross_name_alpha_goal_prev = 0;
1316                 wcross_name_alpha_goal_prev_prev = 0;
1317                 wcross_resolution_goal_prev = 0;
1318                 wcross_resolution_goal_prev_prev = 0;
1319         }
1320 }
1321
1322 void HUD_Draw(entity this)
1323 {
1324         // if we don't know gametype and scores yet avoid drawing the scoreboard
1325         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1326         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1327         // cl_deathscoreboard would show the scoreboard and so on
1328         if(!gametype)
1329                 return;
1330
1331         if(!intermission)
1332         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1333         {
1334                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1335         }
1336         else if(STAT(FROZEN))
1337         {
1338                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1339         }
1340         if(!intermission)
1341         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1342         {
1343                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1344                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1345         }
1346         else if(STAT(CAPTURE_PROGRESS))
1347         {
1348                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1349                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1350         }
1351         else if(STAT(REVIVE_PROGRESS))
1352         {
1353                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1354                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1355         }
1356
1357         if(autocvar_r_letterbox == 0)
1358                 if(autocvar_viewsize < 120)
1359                 {
1360                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1361                                 Accuracy_LoadLevels();
1362
1363                         HUD_Main();
1364                         HUD_Scale_Disable();
1365                 }
1366
1367         // crosshair goes VERY LAST
1368         UpdateDamage();
1369         HUD_Crosshair(this);
1370         HitSound();
1371 }
1372
1373 bool ov_enabled;
1374 float oldr_nearclip;
1375 float oldr_farclip_base;
1376 float oldr_farclip_world;
1377 float oldr_novis;
1378 float oldr_useportalculling;
1379 float oldr_useinfinitefarclip;
1380
1381 void cl_notice_run();
1382
1383 float prev_myteam;
1384 int lasthud;
1385 float vh_notice_time;
1386 void WaypointSprite_Load();
1387 void CSQC_UpdateView(entity this, float w, float h)
1388 {
1389     TC(int, w); TC(int, h);
1390         entity e;
1391         float fov;
1392         float f;
1393         vector vf_size, vf_min;
1394         float a;
1395
1396         execute_next_frame();
1397
1398         ++framecount;
1399
1400         stats_get();
1401         hud = STAT(HUD);
1402
1403         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1404                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1405
1406         lasthud = hud;
1407
1408         HUD_Scale_Disable();
1409
1410         if(autocvar__hud_showbinds_reload) // menu can set this one
1411         {
1412                 db_close(binddb);
1413                 binddb = db_create();
1414                 cvar_set("_hud_showbinds_reload", "0");
1415         }
1416
1417         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1418                 view_quality = getproperty(VF_MINFPS_QUALITY);
1419         else
1420                 view_quality = 1;
1421
1422         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1423         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1424
1425         vf_size = getpropertyvec(VF_SIZE);
1426         vf_min = getpropertyvec(VF_MIN);
1427         vid_width = vf_size.x;
1428         vid_height = vf_size.y;
1429
1430         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1431         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1432
1433         WaypointSprite_Load();
1434
1435         CSQCPlayer_SetCamera();
1436
1437         if(player_localentnum <= maxclients) // is it a client?
1438                 current_player = player_localentnum - 1;
1439         else // then player_localentnum is the vehicle I'm driving
1440                 current_player = player_localnum;
1441         myteam = entcs_GetTeam(current_player);
1442
1443         if(myteam != prev_myteam)
1444         {
1445                 myteamcolors = colormapPaletteColor(myteam, 1);
1446                 FOREACH(hud_panels, true, it.update_time = time);
1447                 prev_myteam = myteam;
1448         }
1449
1450         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1451
1452         float is_dead = (STAT(HEALTH) <= 0);
1453
1454         // FIXME do we need this hack?
1455         if(isdemo())
1456         {
1457                 // in demos, input_buttons do not work
1458                 button_zoom = (autocvar__togglezoom == "-");
1459         }
1460         else if(button_zoom
1461                 && autocvar_cl_unpress_zoom_on_death
1462                 && (spectatee_status >= 0)
1463                 && (is_dead || intermission))
1464         {
1465                 // no zoom while dead or in intermission please
1466                 localcmd("-zoom\n");
1467                 button_zoom = false;
1468         }
1469
1470         // event chase camera
1471         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1472         {
1473                 if(STAT(CAMERA_SPECTATOR))
1474                 {
1475                         if(spectatee_status > 0)
1476                         {
1477                                 if(!autocvar_chase_active)
1478                                 {
1479                                         cvar_set("chase_active", "-2");
1480                                         goto skip_eventchase_death;
1481                                 }
1482                         }
1483                         else if(autocvar_chase_active == -2)
1484                                 cvar_set("chase_active", "0");
1485
1486                         if(autocvar_chase_active == -2)
1487                                 goto skip_eventchase_death;
1488                 }
1489                 else if(autocvar_chase_active == -2)
1490                         cvar_set("chase_active", "0");
1491
1492                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1493
1494                 float vehicle_viewdist = 0;
1495                 vector vehicle_viewofs = '0 0 0';
1496
1497                 if(vehicle_chase)
1498                 {
1499                         if(hud != HUD_BUMBLEBEE_GUN)
1500                         {
1501                                 Vehicle info = Vehicles_from(hud);
1502                                 vehicle_viewdist = info.height;
1503                                 vehicle_viewofs = info.view_ofs;
1504                         }
1505                 }
1506
1507                 if(WantEventchase(this))
1508                 {
1509                         vector current_view_origin_override = '0 0 0';
1510                         vector view_offset_override = '0 0 0';
1511                         float chase_distance_override = 0;
1512                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1513                         if(custom_eventchase)
1514                         {
1515                                 current_view_origin_override = M_ARGV(0, vector);
1516                                 view_offset_override = M_ARGV(1, vector);
1517                                 chase_distance_override = M_ARGV(0, float);
1518                         }
1519                         eventchase_running = true;
1520
1521                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1522                         if(!local_player)
1523                                 local_player = this; // fall back!
1524
1525                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1526                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1527                         if (custom_eventchase)
1528                                 current_view_origin = current_view_origin_override;
1529
1530                         // detect maximum viewoffset and use it
1531                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1532                         if(vehicle_chase)
1533                         {
1534                                 if(vehicle_viewofs)
1535                                         view_offset = vehicle_viewofs;
1536                                 else
1537                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1538                         }
1539                         if (custom_eventchase)
1540                                 view_offset = view_offset_override;
1541
1542                         if(view_offset)
1543                         {
1544                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1545                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1546                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1547                         }
1548
1549                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1550                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1551                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1552                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1553
1554                         // make the camera smooth back
1555                         float chase_distance = autocvar_cl_eventchase_distance;
1556                         if(vehicle_chase)
1557                         {
1558                                 if(vehicle_viewofs)
1559                                         chase_distance = vehicle_viewdist;
1560                                 else
1561                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1562                         }
1563                         if (custom_eventchase)
1564                                 chase_distance = chase_distance_override;
1565
1566                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1567                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1568                         else if(eventchase_current_distance != chase_distance)
1569                                 eventchase_current_distance = chase_distance;
1570
1571                         makevectors(view_angles);
1572
1573                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1574                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1575
1576                         // If the boxtrace fails, revert back to line tracing.
1577                         if(!local_player.viewloc)
1578                         if(trace_startsolid)
1579                         {
1580                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1581                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1582                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1583                         }
1584                         else { setproperty(VF_ORIGIN, trace_endpos); }
1585
1586                         if(!local_player.viewloc)
1587                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1588                 }
1589                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1590                 {
1591                         eventchase_running = false;
1592                         cvar_set("chase_active", "0");
1593                         eventchase_current_distance = 0; // start from 0 next time
1594                 }
1595         }
1596         // workaround for camera stuck between player's legs when using chase_active 1
1597         // because the engine stops updating the chase_active camera when the game ends
1598         else if(intermission)
1599         {
1600                 cvar_settemp("chase_active", "-1");
1601                 eventchase_current_distance = 0;
1602         }
1603
1604         LABEL(skip_eventchase_death);
1605
1606         // do lockview after event chase camera so that it still applies whenever necessary.
1607         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1608         {
1609                 setproperty(VF_ORIGIN, freeze_org);
1610                 setproperty(VF_ANGLES, freeze_ang);
1611         }
1612         else
1613         {
1614                 freeze_org = getpropertyvec(VF_ORIGIN);
1615                 freeze_ang = getpropertyvec(VF_ANGLES);
1616         }
1617
1618         WarpZone_FixView();
1619         //WarpZone_FixPMove();
1620
1621         vector ov_org = '0 0 0';
1622         vector ov_mid = '0 0 0';
1623         vector ov_worldmin = '0 0 0';
1624         vector ov_worldmax = '0 0 0';
1625         if(autocvar_cl_orthoview)
1626         {
1627                 ov_worldmin = mi_picmin;
1628                 ov_worldmax = mi_picmax;
1629
1630                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1631                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1632                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1633
1634                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1635                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1636
1637                 float ov_nearest = vlen(ov_org - vec3(
1638                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1639                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1640                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1641                 ));
1642
1643                 float ov_furthest = 0;
1644                 float dist = 0;
1645
1646                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1647                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1648                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1649                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1650                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1651                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1652                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1653                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1654
1655                 if(!ov_enabled)
1656                 {
1657                         oldr_nearclip = cvar("r_nearclip");
1658                         oldr_farclip_base = cvar("r_farclip_base");
1659                         oldr_farclip_world = cvar("r_farclip_world");
1660                         oldr_novis = cvar("r_novis");
1661                         oldr_useportalculling = cvar("r_useportalculling");
1662                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1663                 }
1664
1665                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1666                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1667                 cvar_settemp("r_farclip_world", "0");
1668                 cvar_settemp("r_novis", "1");
1669                 cvar_settemp("r_useportalculling", "0");
1670                 cvar_settemp("r_useinfinitefarclip", "0");
1671
1672                 setproperty(VF_ORIGIN, ov_org);
1673                 setproperty(VF_ANGLES, '90 0 0');
1674
1675                 ov_enabled = true;
1676
1677                 #if 0
1678                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1679                         vtos(ov_org),
1680                         vtos(getpropertyvec(VF_ANGLES)),
1681                         ov_distance,
1682                         ov_nearest,
1683                         ov_furthest);
1684                 #endif
1685         }
1686         else
1687         {
1688                 if(ov_enabled)
1689                 {
1690                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1691                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1692                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1693                         cvar_set("r_novis", ftos(oldr_novis));
1694                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1695                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1696                 }
1697                 ov_enabled = false;
1698         }
1699
1700         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1701         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1702         viewmodel_draw(viewmodel);
1703
1704         // Render the Scene
1705         view_origin = getpropertyvec(VF_ORIGIN);
1706         view_angles = getpropertyvec(VF_ANGLES);
1707         makevectors(view_angles);
1708         view_forward = v_forward;
1709         view_right = v_right;
1710         view_up = v_up;
1711
1712 #ifdef BLURTEST
1713         if(time > blurtest_time0 && time < blurtest_time1)
1714         {
1715                 float r, t;
1716
1717                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1718                 r = t * blurtest_radius;
1719                 f = 1 / pow(t, blurtest_power) - 1;
1720
1721                 cvar_set("r_glsl_postprocess", "1");
1722                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1723         }
1724         else
1725         {
1726                 cvar_set("r_glsl_postprocess", "0");
1727                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1728         }
1729 #endif
1730
1731         TargetMusic_Advance();
1732         Fog_Force();
1733
1734         if(drawtime == 0)
1735                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1736         else
1737                 drawframetime = bound(0.000001, time - drawtime, 1);
1738         drawtime = time;
1739
1740         // watch for gametype changes here...
1741         // in ParseStuffCMD the cmd isn't executed yet :/
1742         // might even be better to add the gametype to TE_CSQC_INIT...?
1743         if(!postinit)
1744                 PostInit();
1745
1746         if(intermission && !gameover_time)
1747                 gameover_time = time;
1748
1749         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1750         {
1751                 if(calledhooks & HOOK_START)
1752                 {
1753                         localcmd("\ncl_hook_gameend\n");
1754                         calledhooks |= HOOK_END;
1755                 }
1756         }
1757
1758         Announcer();
1759
1760         fov = autocvar_fov;
1761         if(fov <= 59.5)
1762         {
1763                 if(!zoomscript_caught)
1764                 {
1765                         localcmd("+button9\n");
1766                         zoomscript_caught = 1;
1767                 }
1768         }
1769         else
1770         {
1771                 if(zoomscript_caught)
1772                 {
1773                         localcmd("-button9\n");
1774                         zoomscript_caught = 0;
1775                 }
1776         }
1777
1778         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1779
1780         // currently switching-to weapon (for crosshair)
1781         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1782
1783         // actually active weapon (for zoom)
1784         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1785
1786         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1787
1788         if(last_switchweapon != switchweapon)
1789         {
1790                 weapontime = time;
1791                 last_switchweapon = switchweapon;
1792                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1793                 {
1794                         localcmd("-zoom\n");
1795                         button_zoom = false;
1796                 }
1797                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1798                 {
1799                         localcmd("-fire\n");
1800                         localcmd("-fire2\n");
1801                         button_attack2 = false;
1802                 }
1803         }
1804         if(last_activeweapon != activeweapon)
1805         {
1806                 last_activeweapon = activeweapon;
1807
1808                 e = activeweapon;
1809                 if(e.netname != "")
1810                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1811                 else
1812                         localcmd("\ncl_hook_activeweapon none\n");
1813         }
1814
1815         // ALWAYS Clear Current Scene First
1816         clearscene();
1817
1818         setproperty(VF_ORIGIN, view_origin);
1819         setproperty(VF_ANGLES, view_angles);
1820
1821         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1822         setproperty(VF_SIZE, vf_size);
1823         setproperty(VF_MIN, vf_min);
1824
1825         // Assign Standard Viewflags
1826         // Draw the World (and sky)
1827         setproperty(VF_DRAWWORLD, 1);
1828
1829         // Set the console size vars
1830         vid_conwidth = autocvar_vid_conwidth;
1831         vid_conheight = autocvar_vid_conheight;
1832         vid_pixelheight = autocvar_vid_pixelheight;
1833
1834         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1835         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1836         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1837
1838         if(camera_active) // Camera for demo playback
1839         {
1840                 if(autocvar_camera_enable)
1841                         CSQC_Demo_Camera();
1842                 else
1843                 {
1844                         cvar_set("chase_active", ftos(chase_active_backup));
1845                         cvar_set("cl_demo_mousegrab", "0");
1846                         camera_active = false;
1847                 }
1848         }
1849         else
1850         {
1851 #ifdef CAMERATEST
1852                 if(autocvar_camera_enable)
1853 #else
1854                 if(autocvar_camera_enable && isdemo())
1855 #endif
1856                 {
1857                         // Enable required Darkplaces cvars
1858                         chase_active_backup = autocvar_chase_active;
1859                         cvar_set("chase_active", "2");
1860                         cvar_set("cl_demo_mousegrab", "1");
1861                         camera_active = true;
1862                         camera_mode = false;
1863                 }
1864         }
1865
1866         // Draw the Crosshair
1867         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1868
1869         // Draw the Engine Status Bar (the default Quake HUD)
1870         setproperty(VF_DRAWENGINESBAR, 0);
1871
1872         // Update the mouse position
1873         /*
1874            mousepos_x = vid_conwidth;
1875            mousepos_y = vid_conheight;
1876            mousepos = mousepos*0.5 + getmousepos();
1877          */
1878
1879         IL_EACH(g_drawables, it.draw, it.draw(it));
1880
1881         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1882         renderscene();
1883
1884         // now switch to 2D drawing mode by calling a 2D drawing function
1885         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1886         // next R_RenderScene call
1887         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1888
1889         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1890         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1891         {
1892                 // apply night vision effect
1893                 vector tc_00, tc_01, tc_10, tc_11;
1894                 vector rgb = '0 0 0';
1895
1896                 if(!nightvision_noise)
1897                 {
1898                         nightvision_noise = new(nightvision_noise);
1899                 }
1900                 if(!nightvision_noise2)
1901                 {
1902                         nightvision_noise2 = new(nightvision_noise2);
1903                 }
1904
1905                 // color tint in yellow
1906                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1907
1908                 // draw BG
1909                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1910                 rgb = '1 1 1';
1911                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1912                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1913                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1914                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1915                 tc_11 = tc_01 + tc_10 - tc_00;
1916                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1917                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1918                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1919                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1920                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1921                 R_EndPolygon();
1922
1923                 // draw FG
1924                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1925                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1926                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1927                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1928                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1929                 tc_11 = tc_01 + tc_10 - tc_00;
1930                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1931                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1932                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1933                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1934                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1935                 R_EndPolygon();
1936         }
1937
1938         if(autocvar_cl_reticle)
1939         {
1940                 Weapon wep = activeweapon;
1941                 // Draw the aiming reticle for weapons that use it
1942                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1943                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1944                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1945                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1946                 {
1947                         // no zoom reticle while dead
1948                         reticle_type = 0;
1949                 }
1950                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1951                 {
1952                         if(reticle_image != "") { reticle_type = 2; }
1953                         else { reticle_type = 0; }
1954                 }
1955                 else if(button_zoom || zoomscript_caught)
1956                 {
1957                         // normal zoom
1958                         reticle_type = 1;
1959                 }
1960
1961                 if(reticle_type)
1962                 {
1963                         if(autocvar_cl_reticle_stretch)
1964                         {
1965                                 reticle_size.x = vid_conwidth;
1966                                 reticle_size.y = vid_conheight;
1967                                 reticle_pos.x = 0;
1968                                 reticle_pos.y = 0;
1969                         }
1970                         else
1971                         {
1972                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1973                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1974                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1975                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1976                         }
1977
1978                         if(zoomscript_caught)
1979                                 f = 1;
1980                         else
1981                                 f = current_zoomfraction;
1982
1983                         if(f)
1984                         {
1985                                 switch(reticle_type)
1986                                 {
1987                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1988                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1989                                 }
1990                         }
1991                 }
1992         }
1993         else
1994         {
1995                 if(reticle_type != 0) { reticle_type = 0; }
1996         }
1997
1998
1999         // improved polyblend
2000         if(autocvar_hud_contents)
2001         {
2002                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2003                 vector liquidcolor;
2004
2005                 switch(pointcontents(view_origin))
2006                 {
2007                         case CONTENT_WATER:
2008                                 liquidalpha = autocvar_hud_contents_water_alpha;
2009                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2010                                 incontent = 1;
2011                                 break;
2012
2013                         case CONTENT_LAVA:
2014                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2015                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2016                                 incontent = 1;
2017                                 break;
2018
2019                         case CONTENT_SLIME:
2020                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2021                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2022                                 incontent = 1;
2023                                 break;
2024
2025                         default:
2026                                 liquidalpha = 0;
2027                                 liquidcolor = '0 0 0';
2028                                 incontent = 0;
2029                                 break;
2030                 }
2031
2032                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2033                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2034                         contentfadetime = autocvar_hud_contents_fadeintime;
2035                         liquidalpha_prev = liquidalpha;
2036                         liquidcolor_prev = liquidcolor;
2037                 }
2038                 else
2039                         contentfadetime = autocvar_hud_contents_fadeouttime;
2040
2041                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2042                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2043
2044                 if(contentavgalpha)
2045                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2046
2047                 if(autocvar_hud_postprocessing)
2048                 {
2049                         if(autocvar_hud_contents_blur && contentavgalpha)
2050                         {
2051                                 content_blurpostprocess.x = 1;
2052                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2053                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2054                         }
2055                         else
2056                         {
2057                                 content_blurpostprocess.x = 0;
2058                                 content_blurpostprocess.y = 0;
2059                                 content_blurpostprocess.z = 0;
2060                         }
2061                 }
2062         }
2063
2064         if(autocvar_hud_damage && !STAT(FROZEN))
2065         {
2066                 splash_size.x = max(vid_conwidth, vid_conheight);
2067                 splash_size.y = max(vid_conwidth, vid_conheight);
2068                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2069                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2070
2071                 float myhealth_flash_temp;
2072                 myhealth = STAT(HEALTH);
2073
2074                 // fade out
2075                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2076                 // add new damage
2077                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2078
2079                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2080                 pain_threshold = autocvar_hud_damage_pain_threshold;
2081                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2082                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2083
2084                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2085                 {
2086                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2087                 }
2088
2089                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2090
2091                 if(myhealth_prev < 1)
2092                 {
2093                         if(myhealth >= 1)
2094                         {
2095                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2096                                 myhealth_flash_temp = 0;
2097                         }
2098                         else
2099                         {
2100                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2101                         }
2102                 }
2103
2104                 if(spectatee_status == -1 || intermission)
2105                 {
2106                         myhealth_flash = 0; // observing, or match ended
2107                         myhealth_flash_temp = 0;
2108                 }
2109
2110                 myhealth_prev = myhealth;
2111
2112                 // IDEA: change damage color/picture based on player model for robot/alien species?
2113                 // pro: matches model better
2114                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2115                 // maybe different reddish pics?
2116                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2117                 {
2118                         if(autocvar_cl_gentle_damage == 2)
2119                         {
2120                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2121                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2122                         }
2123                         else
2124                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2125
2126                         if(myhealth_flash_temp > 0)
2127                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2128                 }
2129                 else if(myhealth_flash_temp > 0)
2130                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2131
2132                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2133                 {
2134                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2135                         {
2136                                 damage_blurpostprocess.x = 1;
2137                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2138                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2139                         }
2140                         else
2141                         {
2142                                 damage_blurpostprocess.x = 0;
2143                                 damage_blurpostprocess.y = 0;
2144                                 damage_blurpostprocess.z = 0;
2145                         }
2146                 }
2147         }
2148
2149         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2150         float e2 = (autocvar_hud_powerup != 0);
2151         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2152         {
2153                 // enable or disable rendering types if they are used or not
2154                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2155                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2156
2157                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2158                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2159                 {
2160                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2161                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2162                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2163                         {
2164                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2165                                 old_blurradius = blurradius;
2166                                 old_bluralpha = bluralpha;
2167                         }
2168                 }
2169                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2170                 {
2171                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2172                         old_blurradius = 0;
2173                         old_bluralpha = 0;
2174                 }
2175
2176                 // edge detection postprocess handling done second (used by hud_powerup)
2177                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2178                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2179                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2180
2181                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2182
2183                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2184                 {
2185                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2186                         {
2187                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2188                                 old_sharpen_intensity = sharpen_intensity;
2189                         }
2190                 }
2191                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2192                 {
2193                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2194                         old_sharpen_intensity = 0;
2195                 }
2196
2197                 if(cvar("r_glsl_postprocess") == 0)
2198                         cvar_set("r_glsl_postprocess", "2");
2199         }
2200         else if(cvar("r_glsl_postprocess") == 2)
2201                 cvar_set("r_glsl_postprocess", "0");
2202
2203         /*if(gametype == MAPINFO_TYPE_CTF)
2204           {
2205           ctf_view();
2206           } else */
2207
2208         // draw 2D entities
2209         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2210         Draw_ShowNames_All();
2211         Debug_Draw();
2212
2213         scoreboard_active = Scoreboard_WouldDraw();
2214
2215         HUD_Draw(this); // this parameter for deep vehicle function
2216
2217         if(NextFrameCommand)
2218         {
2219                 localcmd("\n", NextFrameCommand, "\n");
2220                 NextFrameCommand = string_null;
2221         }
2222
2223         // we must do this check AFTER a frame was rendered, or it won't work
2224         if(cs_project_is_b0rked == 0)
2225         {
2226                 string w0, h0;
2227                 w0 = ftos(autocvar_vid_conwidth);
2228                 h0 = ftos(autocvar_vid_conheight);
2229                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2230                 //setproperty(VF_FOV, '90 90 0');
2231                 setproperty(VF_ORIGIN, '0 0 0');
2232                 setproperty(VF_ANGLES, '0 0 0');
2233                 setproperty(VF_PERSPECTIVE, 1);
2234                 makevectors('0 0 0');
2235                 vector v1, v2;
2236                 cvar_set("vid_conwidth", "800");
2237                 cvar_set("vid_conheight", "600");
2238                 v1 = cs_project(v_forward);
2239                 cvar_set("vid_conwidth", "640");
2240                 cvar_set("vid_conheight", "480");
2241                 v2 = cs_project(v_forward);
2242                 if(v1 == v2)
2243                         cs_project_is_b0rked = 1;
2244                 else
2245                         cs_project_is_b0rked = -1;
2246                 cvar_set("vid_conwidth", w0);
2247                 cvar_set("vid_conheight", h0);
2248         }
2249
2250         if(autocvar__hud_configure)
2251                 HUD_Panel_Mouse();
2252         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2253                 HUD_Minigame_Mouse();
2254         else if(QuickMenu_IsOpened())
2255                 QuickMenu_Mouse();
2256         else
2257                 HUD_Radar_Mouse();
2258
2259         cl_notice_run();
2260         unpause_update();
2261         Net_Flush();
2262
2263         // let's reset the view back to normal for the end
2264         setproperty(VF_MIN, '0 0 0');
2265         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2266
2267         IL_ENDFRAME();
2268 }
2269
2270
2271 // following vectors must be global to allow seamless switching between camera modes
2272 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2273 void CSQC_Demo_Camera()
2274 {
2275         float speed, attenuation, dimensions;
2276         vector tmp, delta;
2277
2278         if( autocvar_camera_reset || !camera_mode )
2279         {
2280                 camera_offset = '0 0 0';
2281                 current_angles = '0 0 0';
2282                 camera_direction = '0 0 0';
2283                 camera_offset.z += 30;
2284                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2285                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2286                 current_origin = view_origin;
2287                 current_camera_offset  = camera_offset;
2288                 cvar_set("camera_reset", "0");
2289                 camera_mode = CAMERA_CHASE;
2290         }
2291
2292         // Camera angles
2293         if( camera_roll )
2294                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2295
2296         if(autocvar_camera_look_player)
2297         {
2298                 vector dir;
2299                 float n;
2300
2301                 dir = normalize(view_origin - current_position);
2302                 n = mouse_angles.z;
2303                 mouse_angles = vectoangles(dir);
2304                 mouse_angles.x = mouse_angles.x * -1;
2305                 mouse_angles.z = n;
2306         }
2307         else
2308         {
2309                 tmp = getmousepos() * 0.1;
2310                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2311                 {
2312                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2313                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2314                 }
2315         }
2316
2317         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2318         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2319         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2320         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2321
2322         // Fix difference when angles don't have the same sign
2323         delta = '0 0 0';
2324         if(mouse_angles.y < -60 && current_angles.y > 60)
2325                 delta = '0 360 0';
2326         if(mouse_angles.y > 60 && current_angles.y < -60)
2327                 delta = '0 -360 0';
2328
2329         if(autocvar_camera_look_player)
2330                 attenuation = autocvar_camera_look_attenuation;
2331         else
2332                 attenuation = autocvar_camera_speed_attenuation;
2333
2334         attenuation = 1 / max(1, attenuation);
2335         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2336
2337         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2338         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2339         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2340         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2341
2342         // Camera position
2343         tmp = '0 0 0';
2344         dimensions = 0;
2345
2346         if( camera_direction.x )
2347         {
2348                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2349                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2350                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2351                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2352                 ++dimensions;
2353         }
2354
2355         if( camera_direction.y )
2356         {
2357                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2358                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2359                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2360                 ++dimensions;
2361         }
2362
2363         if( camera_direction.z )
2364         {
2365                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2366                 ++dimensions;
2367         }
2368
2369         if(autocvar_camera_free)
2370                 speed = autocvar_camera_speed_free;
2371         else
2372                 speed = autocvar_camera_speed_chase;
2373
2374         if(dimensions)
2375         {
2376                 speed = speed * sqrt(1 / dimensions);
2377                 camera_offset += tmp * speed;
2378         }
2379
2380         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2381
2382         // Camera modes
2383         if( autocvar_camera_free )
2384         {
2385                 if ( camera_mode == CAMERA_CHASE )
2386                 {
2387                         current_camera_offset = current_origin + current_camera_offset;
2388                         camera_offset = current_origin + camera_offset;
2389                 }
2390
2391                 camera_mode = CAMERA_FREE;
2392                 current_position = current_camera_offset;
2393         }
2394         else
2395         {
2396                 if ( camera_mode == CAMERA_FREE )
2397                 {
2398                         current_origin = view_origin;
2399                         camera_offset = camera_offset - current_origin;
2400                         current_camera_offset = current_camera_offset - current_origin;
2401                 }
2402
2403                 camera_mode = CAMERA_CHASE;
2404
2405                 if(autocvar_camera_chase_smoothly)
2406                         current_origin += (view_origin - current_origin) * attenuation;
2407                 else
2408                         current_origin = view_origin;
2409
2410                 current_position = current_origin + current_camera_offset;
2411         }
2412
2413         setproperty(VF_ANGLES, current_angles);
2414         setproperty(VF_ORIGIN, current_position);
2415 }