qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float drawtime;
 398 float avgspeed;
 399 vector GetCurrentFov(float fov)
 400 {
 401         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 402         float velocityzoom, curspeed;
 403         vector v;
 404
 405         zoomsensitivity = autocvar_cl_zoomsensitivity;
 406         zoomfactor = autocvar_cl_zoomfactor;
 407         if(zoomfactor < 1 || zoomfactor > 30)
 408                 zoomfactor = 2.5;
 409         zoomspeed = autocvar_cl_zoomspeed;
 410         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 411                 zoomspeed = 3.5;
 412
 413         zoomdir = button_zoom;
 414
 415         if(hud == HUD_NORMAL && !spectatee_status)
 416         {
 417                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418                 {
 419                         entity wepent = viewmodels[slot];
 420                         if(wepent.switchweapon != wepent.activeweapon)
 421                                 continue;
 422                         Weapon wep = wepent.activeweapon;
 423                         if(wep != WEP_Null && wep.wr_zoomdir)
 424                         {
 425                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 426                                 zoomdir += do_zoom;
 427                         }
 428                 }
 429         }
 430         if(spectatee_status > 0 || isdemo())
 431         {
 432                 if(spectatorbutton_zoom)
 433                 {
 434                         if(zoomdir)
 435                                 zoomdir = 0;
 436                         else
 437                                 zoomdir = 1;
 438                 }
 439                 // fteqcc failed twice here already, don't optimize this
 440         }
 441
 442         if(zoomdir) { zoomin_effect = 0; }
 443
 444         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 445         {
 446                 current_viewzoom = 1;
 447         }
 448         else if (camera_active)
 449         {
 450                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 451         }
 452         else if(autocvar_cl_spawnzoom && zoomin_effect)
 453         {
 454                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 455
 456                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 457                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 458                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 459         }
 460         else
 461         {
 462                 if(zoomspeed < 0) // instant zoom
 463                 {
 464                         if(zoomdir)
 465                                 current_viewzoom = 1 / zoomfactor;
 466                         else
 467                                 current_viewzoom = 1;
 468                 }
 469                 else
 470                 {
 471                         if(zoomdir)
 472                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 473                         else
 474                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 475                 }
 476         }
 477
 478         if(almost_equals(current_viewzoom, 1))
 479                 current_zoomfraction = 0;
 480         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 481                 current_zoomfraction = 1;
 482         else
 483                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 484
 485         if(zoomsensitivity < 1)
 486                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 487         else
 488                 setsensitivityscale(1);
 489
 490         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 491         {
 492                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 493                         curspeed = 0;
 494                 else
 495                 {
 496                         makevectors(view_angles);
 497                         v = pmove_vel;
 498                         if(csqcplayer)
 499                                 v = csqcplayer.velocity;
 500
 501                         switch(autocvar_cl_velocityzoom_type)
 502                         {
 503                                 case 3: curspeed = max(0, v_forward * v); break;
 504                                 case 2: curspeed = (v_forward * v); break;
 505                                 case 1: default: curspeed = vlen(v); break;
 506                         }
 507                 }
 508
 509                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 510                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 511                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 512
 513                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 514         }
 515         else
 516                 velocityzoom = 1;
 517
 518         float frustumx, frustumy, fovx, fovy;
 519         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 520         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 521         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 522         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 523
 524         return '1 0 0' * fovx + '0 1 0' * fovy;
 525 }
 526
 527 vector GetViewLocationFOV(float fov)
 528 {
 529         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 530         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 531         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 532         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 533         return '1 0 0' * fovx + '0 1 0' * fovy;
 534 }
 535
 536 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 537 {
 538         float fovx, fovy;
 539         float width = (ov_worldmax.x - ov_worldmin.x);
 540         float height = (ov_worldmax.y - ov_worldmin.y);
 541         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 542         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         return '1 0 0' * fovx + '0 1 0' * fovy;
 545 }
 546
 547 // this function must match W_SetupShot!
 548 float zoomscript_caught;
 549
 550 bool minigame_wasactive;
 551
 552 vector wcross_origin;
 553 float wcross_scale_prev, wcross_alpha_prev;
 554 vector wcross_color_prev;
 555 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 556 vector wcross_color_goal_prev;
 557 float wcross_changedonetime;
 558
 559 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 560 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 561 float wcross_name_changestarttime, wcross_name_changedonetime;
 562 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 563
 564 float wcross_ring_prev;
 565
 566 entity trueaim;
 567 entity trueaim_rifle;
 568
 569 const float SHOTTYPE_HITTEAM = 1;
 570 const float SHOTTYPE_HITOBSTRUCTION = 2;
 571 const float SHOTTYPE_HITWORLD = 3;
 572 const float SHOTTYPE_HITENEMY = 4;
 573
 574 void TrueAim_Init()
 575 {
 576         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 577         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578 }
 579
 580 float EnemyHitCheck()
 581 {
 582         float t, n;
 583         wcross_origin = project_3d_to_2d(trace_endpos);
 584         wcross_origin.z = 0;
 585         if(trace_ent)
 586                 n = trace_ent.entnum;
 587         else
 588                 n = trace_networkentity;
 589         if(n < 1)
 590                 return SHOTTYPE_HITWORLD;
 591         if(n > maxclients)
 592                 return SHOTTYPE_HITWORLD;
 593         t = entcs_GetTeam(n - 1);
 594         if(teamplay)
 595                 if(t == myteam)
 596                         return SHOTTYPE_HITTEAM;
 597         if(t == NUM_SPECTATOR)
 598                 return SHOTTYPE_HITWORLD;
 599         return SHOTTYPE_HITENEMY;
 600 }
 601
 602 float TrueAimCheck(entity wepent)
 603 {
 604         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 605                 return SHOTTYPE_HITWORLD;
 606
 607         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 608         vector vecs, trueaimpoint, w_shotorg;
 609         vector mi, ma, dv;
 610         float shottype;
 611         entity ta;
 612         float mv;
 613
 614         mi = ma = '0 0 0';
 615         ta = trueaim;
 616         mv = MOVE_NOMONSTERS;
 617
 618         switch(wepent.activeweapon) // WEAPONTODO
 619         {
 620                 case WEP_VORTEX:
 621                 case WEP_OVERKILL_NEX:
 622                 case WEP_VAPORIZER:
 623                         mv = MOVE_NORMAL;
 624                         break;
 625                 case WEP_RIFLE:
 626                         ta = trueaim_rifle;
 627                         mv = MOVE_NORMAL;
 628                         if(zoomscript_caught)
 629                         {
 630                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 631                                 return EnemyHitCheck();
 632                         }
 633                         break;
 634                 case WEP_DEVASTATOR: // projectile has a size!
 635                         mi = '-3 -3 -3';
 636                         ma = '3 3 3';
 637                         break;
 638                 case WEP_FIREBALL: // projectile has a size!
 639                         mi = '-16 -16 -16';
 640                         ma = '16 16 16';
 641                         break;
 642                 case WEP_SEEKER: // projectile has a size!
 643                         mi = '-2 -2 -2';
 644                         ma = '2 2 2';
 645                         break;
 646                 case WEP_ELECTRO: // projectile has a size!
 647                         mi = '0 0 -3';
 648                         ma = '0 0 -3';
 649                         break;
 650         }
 651
 652         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 653
 654         vecs = decompressShotOrigin(STAT(SHOTORG));
 655
 656         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 657         trueaimpoint = trace_endpos;
 658
 659         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 660                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 661
 662         if(vecs.x > 0)
 663                 vecs.y = -vecs.y;
 664         else
 665                 vecs = '0 0 0';
 666
 667         dv = view_right * vecs.y + view_up * vecs.z;
 668         w_shotorg = traceorigin + dv;
 669
 670         // now move the vecs forward as much as requested if possible
 671         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 672         w_shotorg = trace_endpos - view_forward * nudge;
 673
 674         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 675         shottype = EnemyHitCheck();
 676         if(shottype != SHOTTYPE_HITWORLD)
 677                 return shottype;
 678
 679 #if 0
 680         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 681         // or rather, I know why, but see no fix
 682         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 683                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 684                 return SHOTTYPE_HITOBSTRUCTION;
 685 #endif
 686
 687         return SHOTTYPE_HITWORLD;
 688 }
 689
 690 float camera_mode;
 691 const float CAMERA_FREE = 1;
 692 const float CAMERA_CHASE = 2;
 693 float reticle_type;
 694 string NextFrameCommand;
 695
 696 vector freeze_org, freeze_ang;
 697 entity nightvision_noise, nightvision_noise2;
 698
 699 const float MAX_TIME_DIFF = 5;
 700 float pickup_crosshair_time, pickup_crosshair_size;
 701 float hitindication_crosshair_size;
 702 float use_vortex_chargepool;
 703
 704 float myhealth, myhealth_prev;
 705 float myhealth_flash;
 706
 707 float old_blurradius, old_bluralpha;
 708 float old_sharpen_intensity;
 709
 710 vector myhealth_gentlergb;
 711
 712 float contentavgalpha, liquidalpha_prev;
 713 vector liquidcolor_prev;
 714
 715 float eventchase_current_distance;
 716 float eventchase_running;
 717 int WantEventchase(entity this, bool want_vehiclechase)
 718 {
 719         if(autocvar_cl_orthoview)
 720                 return 0;
 721         if(STAT(GAME_STOPPED) || intermission)
 722                 return 1;
 723         if(this.viewloc)
 724                 return 1;
 725         if(spectatee_status >= 0)
 726         {
 727                 if(want_vehiclechase)
 728                         return 1;
 729                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 730                         return 1;
 731                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 732                         return 1;
 733                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 734                 {
 735                         if(autocvar_cl_eventchase_death == 2)
 736                         {
 737                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 738                                 if(this.velocity == '0 0 0' || eventchase_running)
 739                                         return 1;
 740                         }
 741                         else return 1;
 742                 }
 743                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 744                 {
 745                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 746                                 return 1;
 747                         else if (eventchase_running)
 748                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 749                 }
 750         }
 751         return 0;
 752 }
 753
 754 void HUD_Crosshair_Vehicle(entity this)
 755 {
 756         if(hud != HUD_BUMBLEBEE_GUN)
 757         {
 758                 Vehicle info = Vehicles_from(hud);
 759                 info.vr_crosshair(info, this);
 760         }
 761 }
 762
 763 vector damage_blurpostprocess, content_blurpostprocess;
 764
 765 float unaccounted_damage = 0;
 766 void UpdateDamage()
 767 {
 768         // accumulate damage with each stat update
 769         static float damage_total_prev = 0;
 770         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 771         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 772         damage_total_prev = damage_total;
 773
 774         static float damage_dealt_time_prev = 0;
 775         float damage_dealt_time = STAT(HIT_TIME);
 776         if (damage_dealt_time != damage_dealt_time_prev)
 777         {
 778                 unaccounted_damage += unaccounted_damage_new;
 779                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 780         }
 781         damage_dealt_time_prev = damage_dealt_time;
 782
 783         // prevent hitsound when switching spectatee
 784         static float spectatee_status_prev = 0;
 785         if (spectatee_status != spectatee_status_prev)
 786                 unaccounted_damage = 0;
 787         spectatee_status_prev = spectatee_status;
 788 }
 789
 790 void HitSound()
 791 {
 792         // varying sound pitch
 793
 794         bool have_arc = false;
 795         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 796         {
 797                 entity wepent = viewmodels[slot];
 798
 799                 if(wepent.activeweapon == WEP_ARC)
 800                         have_arc = true;
 801         }
 802
 803         static float hitsound_time_prev = 0;
 804         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 805         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 806         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 807         {
 808                 if (autocvar_cl_hitsound && unaccounted_damage)
 809                 {
 810                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 811                         float a = autocvar_cl_hitsound_max_pitch;
 812                         float b = autocvar_cl_hitsound_min_pitch;
 813                         float c = autocvar_cl_hitsound_nom_damage;
 814                         float d = unaccounted_damage;
 815                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 816
 817                         // if sound variation is disabled, set pitch_shift to 1
 818                         if (autocvar_cl_hitsound == 1)
 819                                 pitch_shift = 1;
 820
 821                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 822                         if (autocvar_cl_hitsound == 3)
 823                         {
 824                                 float mirror_value = (a-b)/2 + b;
 825                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 826                         }
 827
 828                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 829
 830                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 831                         // todo: normalize sound pressure levels? seems unnecessary
 832
 833                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 834                 }
 835                 unaccounted_damage = 0;
 836                 hitsound_time_prev = time;
 837         }
 838
 839         static float typehit_time_prev = 0;
 840         float typehit_time = STAT(TYPEHIT_TIME);
 841         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 842         {
 843                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 844                 typehit_time_prev = typehit_time;
 845         }
 846
 847         static float kill_time_prev = 0;
 848         float kill_time = STAT(KILL_TIME);
 849         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 850         {
 851                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 852                 kill_time_prev = kill_time;
 853         }
 854 }
 855
 856 vector crosshair_getcolor(entity this, float health_stat)
 857 {
 858         static float rainbow_last_flicker;
 859         static vector rainbow_prev_color;
 860         vector wcross_color = '0 0 0';
 861         switch(autocvar_crosshair_color_special)
 862         {
 863                 case 1: // crosshair_color_per_weapon
 864                 {
 865                         if(this != WEP_Null && hud == HUD_NORMAL)
 866                         {
 867                                 wcross_color = this.wpcolor;
 868                                 break;
 869                         }
 870                         else { goto normalcolor; }
 871                 }
 872
 873                 case 2: // crosshair_color_by_health
 874                 {
 875                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 876                         float hp = floor(v.x + 1);
 877
 878                         //x = red
 879                         //y = green
 880                         //z = blue
 881
 882                         wcross_color.z = 0;
 883
 884                         if(hp > 200)
 885                         {
 886                                 wcross_color.x = 0;
 887                                 wcross_color.y = 1;
 888                         }
 889                         else if(hp > 150)
 890                         {
 891                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 892                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 893                         }
 894                         else if(hp > 100)
 895                         {
 896                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 897                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 898                                 wcross_color.z = 1 - (hp-100)*0.02;
 899                         }
 900                         else if(hp > 50)
 901                         {
 902                                 wcross_color.x = 1;
 903                                 wcross_color.y = 1;
 904                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 905                         }
 906                         else if(hp > 20)
 907                         {
 908                                 wcross_color.x = 1;
 909                                 wcross_color.y = (hp-20)*90/27/100;
 910                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 911                         }
 912                         else
 913                         {
 914                                 wcross_color.x = 1;
 915                                 wcross_color.y = 0;
 916                         }
 917                         break;
 918                 }
 919
 920                 case 3: // crosshair_color_rainbow
 921                 {
 922                         if(time >= rainbow_last_flicker)
 923                         {
 924                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 925                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 926                         }
 927                         wcross_color = rainbow_prev_color;
 928                         break;
 929                 }
 930 LABEL(normalcolor)
 931                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 932         }
 933
 934         return wcross_color;
 935 }
 936
 937 void HUD_Crosshair(entity this)
 938 {
 939         float f, i, j;
 940         vector v;
 941         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 942                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 943                 !HUD_MinigameMenu_IsOpened() )
 944         {
 945                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 946                         return;
 947
 948                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 949                         return;
 950
 951                 if (hud != HUD_NORMAL)
 952                 {
 953                         HUD_Crosshair_Vehicle(this);
 954                         return;
 955                 }
 956
 957                 string wcross_style;
 958                 float wcross_alpha, wcross_resolution;
 959                 wcross_style = autocvar_crosshair;
 960                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 961                         wcross_style = autocvar_crosshair_2d;
 962                 if (wcross_style == "0")
 963                         return;
 964                 wcross_resolution = autocvar_crosshair_size;
 965                 if (wcross_resolution == 0)
 966                         return;
 967                 wcross_alpha = autocvar_crosshair_alpha;
 968                 if (wcross_alpha == 0)
 969                         return;
 970
 971                 // TrueAim check
 972                 float shottype;
 973
 974                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 975                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 976                         wcross_origin = viewloc_mousepos;
 977                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 978                 {
 979                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 980                         if(csqcplayer && crosshair_chase_playeralpha && crosshair_chase_playeralpha < 1)
 981                         {
 982                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 983                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 984                                 if(trace_ent == csqcplayer && STAT(HEALTH) > 0)
 985                                         csqcplayer.alpha = min(crosshair_chase_playeralpha, myalpha);
 986                                 else
 987                                         csqcplayer.alpha = csqcplayer.m_alpha;
 988                         }
 989                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 990                         wcross_origin = project_3d_to_2d(trace_endpos);
 991                 }
 992                 else
 993                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 994                 wcross_origin.z = 0;
 995                 if(autocvar_crosshair_hittest)
 996                 {
 997                         vector wcross_oldorigin;
 998                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 999                         wcross_oldorigin = wcross_origin;
1000                         shottype = TrueAimCheck(thiswep);
1001                         if(shottype == SHOTTYPE_HITWORLD)
1002                         {
1003                                 v = wcross_origin - wcross_oldorigin;
1004                                 v.x /= vid_conwidth;
1005                                 v.y /= vid_conheight;
1006                                 if(vdist(v, >, 0.01))
1007                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1008                         }
1009                         if(!autocvar_crosshair_hittest_showimpact)
1010                                 wcross_origin = wcross_oldorigin;
1011                 }
1012                 else
1013                         shottype = SHOTTYPE_HITWORLD;
1014
1015                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1016                 string wcross_name = "";
1017                 float wcross_scale, wcross_blur;
1018
1019         entity e = WEP_Null;
1020                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1021                 {
1022                         entity wepent = viewmodels[0]; // TODO: unhardcode
1023                         e = wepent.switchingweapon;
1024                         if(e)
1025                         {
1026                                 if(autocvar_crosshair_per_weapon)
1027                                 {
1028                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1029                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1030                                         //if (wcross_resolution == 0)
1031                                                 //return;
1032
1033                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1034                                         wcross_resolution *= e.w_crosshair_size;
1035                                         wcross_name = e.w_crosshair;
1036                                 }
1037                         }
1038                 }
1039
1040                 if(wcross_name == "")
1041                         wcross_name = strcat("gfx/crosshair", wcross_style);
1042
1043                 // MAIN CROSSHAIR COLOR DECISION
1044                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1045
1046                 if(autocvar_crosshair_effect_scalefade)
1047                 {
1048                         wcross_scale = wcross_resolution;
1049                         wcross_resolution = 1;
1050                 }
1051                 else
1052                 {
1053                         wcross_scale = 1;
1054                 }
1055
1056                 if(autocvar_crosshair_pickup)
1057                 {
1058                         float stat_pickup_time = STAT(LAST_PICKUP);
1059
1060                         if(pickup_crosshair_time < stat_pickup_time)
1061                         {
1062                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1063                                         pickup_crosshair_size = 1;
1064
1065                                 pickup_crosshair_time = stat_pickup_time;
1066                         }
1067
1068                         if(pickup_crosshair_size > 0)
1069                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1070                         else
1071                                 pickup_crosshair_size = 0;
1072
1073                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1074                 }
1075
1076                 // todo: make crosshair hit indication dependent on damage dealt
1077                 if(autocvar_crosshair_hitindication)
1078                 {
1079                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1080
1081                         if(unaccounted_damage)
1082                         {
1083                                 hitindication_crosshair_size = 1;
1084                         }
1085
1086                         if(hitindication_crosshair_size > 0)
1087                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1088                         else
1089                                 hitindication_crosshair_size = 0;
1090
1091                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1092                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1093                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1094                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1095                 }
1096
1097                 if(shottype == SHOTTYPE_HITENEMY)
1098                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1099                 if(shottype == SHOTTYPE_HITTEAM)
1100                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1101
1102                 f = fabs(autocvar_crosshair_effect_time);
1103                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1104                 {
1105                         wcross_changedonetime = time + f;
1106                 }
1107                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1108                 {
1109                         wcross_name_changestarttime = time;
1110                         wcross_name_changedonetime = time + f;
1111                         if(wcross_name_goal_prev_prev)
1112                                 strunzone(wcross_name_goal_prev_prev);
1113                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1114                         wcross_name_goal_prev = strzone(wcross_name);
1115                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1116                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1117                         wcross_resolution_goal_prev = wcross_resolution;
1118                 }
1119
1120                 wcross_scale_goal_prev = wcross_scale;
1121                 wcross_alpha_goal_prev = wcross_alpha;
1122                 wcross_color_goal_prev = wcross_color;
1123
1124                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1125                 {
1126                         wcross_blur = 1;
1127                         wcross_alpha *= 0.75;
1128                 }
1129                 else
1130                         wcross_blur = 0;
1131                 // *_prev is at time-frametime
1132                 // * is at wcross_changedonetime+f
1133                 // what do we have at time?
1134                 if(time < wcross_changedonetime)
1135                 {
1136                         f = frametime / (wcross_changedonetime - time + frametime);
1137                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1138                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1139                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1140                 }
1141
1142                 wcross_scale_prev = wcross_scale;
1143                 wcross_alpha_prev = wcross_alpha;
1144                 wcross_color_prev = wcross_color;
1145
1146                 MUTATOR_CALLHOOK(UpdateCrosshair);
1147
1148                 wcross_scale *= 1 - autocvar__menu_alpha;
1149                 wcross_alpha *= 1 - autocvar__menu_alpha;
1150                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1151
1152                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1153                 {
1154                         // crosshair rings for weapon stats
1155                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1156                         {
1157                                 // declarations and stats
1158                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1159                                 string ring_image = string_null, ring_inner_image = string_null;
1160                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1161
1162                                 ring_scale = autocvar_crosshair_ring_size;
1163
1164                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1165
1166                                 int weapon_clipload = wepent.clip_load;
1167                                 int weapon_clipsize = wepent.clip_size;
1168
1169                                 float arc_heat = wepent.arc_heat_percent;
1170                                 float vcharge = wepent.vortex_charge;
1171                                 float vchargepool = wepent.vortex_chargepool_ammo;
1172                                 float oknex_charge_ = wepent.oknex_charge;
1173                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1174
1175                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1176                                         vortex_charge_movingavg = vcharge;
1177
1178                                 // handle the values
1179                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1180                                 {
1181                                         if (vchargepool || use_vortex_chargepool) {
1182                                                 use_vortex_chargepool = 1;
1183                                                 ring_inner_value = vchargepool;
1184                                         } else {
1185                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1186                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1187                                         }
1188
1189                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1190                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1191                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1192
1193                                         // draw the outer ring to show the current charge of the weapon
1194                                         ring_value = vcharge;
1195                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1196                                         ring_rgb = wcross_color;
1197                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1198                                 }
1199                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1200                                 {
1201                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1202                                                 use_vortex_chargepool = 1;
1203                                                 ring_inner_value = oknex_chargepool_;
1204                                         } else {
1205                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1206                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1207                                         }
1208
1209                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1210                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1211                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1212
1213                                         // draw the outer ring to show the current charge of the weapon
1214                                         ring_value = oknex_charge_;
1215                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1216                                         ring_rgb = wcross_color;
1217                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1218                                 }
1219                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1220                                 {
1221                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1222                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1223                                         ring_rgb = wcross_color;
1224                                         ring_image = "gfx/crosshair_ring.tga";
1225                                 }
1226                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1227                                 {
1228                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1229                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1230                                         ring_rgb = wcross_color;
1231                                         ring_image = "gfx/crosshair_ring.tga";
1232                                 }
1233                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1234                                 {
1235                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1236                                         ring_scale = autocvar_crosshair_ring_reload_size;
1237                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1238                                         ring_rgb = wcross_color;
1239
1240                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1241                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1242                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1243                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1244                                         else
1245                                                 ring_image = "gfx/crosshair_ring.tga";
1246                                 }
1247                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1248                                 {
1249                                         ring_value = arc_heat;
1250                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1251                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1252                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1253                                         ring_image = "gfx/crosshair_ring.tga";
1254                                 }
1255
1256                                 // if in weapon switch animation, fade ring out/in
1257                                 if(autocvar_crosshair_effect_time > 0)
1258                                 {
1259                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1260                                         if (f >= 1)
1261                                         {
1262                                                 wcross_ring_prev = ((ring_image) ? true : false);
1263                                         }
1264
1265                                         if(wcross_ring_prev)
1266                                         {
1267                                                 if(f < 1)
1268                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1269                                         }
1270                                         else
1271                                         {
1272                                                 if(f < 1)
1273                                                         ring_alpha *= bound(0, f, 1);
1274                                         }
1275                                 }
1276
1277                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1278                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1279
1280                                 if (ring_value)
1281                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1282                         }
1283
1284 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1285                         MACRO_BEGIN \
1286                                 vector scaled_sz = sz * wcross_size; \
1287                                 if(wcross_blur > 0) \
1288                                 { \
1289                                         for(i = -2; i <= 2; ++i) \
1290                                         for(j = -2; j <= 2; ++j) \
1291                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1292                                 } \
1293                                 else \
1294                                 { \
1295                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1296                                 } \
1297                         MACRO_END
1298
1299 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1300                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1301
1302 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1303                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1304
1305                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1306                         {
1307                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1308                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1309                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1310                                 f = 1 - f;
1311                         }
1312                         else
1313                         {
1314                                 f = 1;
1315                         }
1316                         wcross_name_alpha_goal_prev = f;
1317
1318                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1319                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1320
1321                         if(autocvar_crosshair_dot)
1322                         {
1323                                 vector wcross_color_old;
1324                                 wcross_color_old = wcross_color;
1325
1326                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1327                                         wcross_color = stov(autocvar_crosshair_dot_color);
1328
1329                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1330                                 // FIXME why don't we use wcross_alpha here?
1331                                 wcross_color = wcross_color_old;
1332                         }
1333                 }
1334         }
1335         else
1336         {
1337                 wcross_scale_prev = 0;
1338                 wcross_alpha_prev = 0;
1339                 wcross_scale_goal_prev = 0;
1340                 wcross_alpha_goal_prev = 0;
1341                 wcross_changedonetime = 0;
1342                 strfree(wcross_name_goal_prev);
1343                 strfree(wcross_name_goal_prev_prev);
1344                 wcross_name_changestarttime = 0;
1345                 wcross_name_changedonetime = 0;
1346                 wcross_name_alpha_goal_prev = 0;
1347                 wcross_name_alpha_goal_prev_prev = 0;
1348                 wcross_resolution_goal_prev = 0;
1349                 wcross_resolution_goal_prev_prev = 0;
1350         }
1351 }
1352
1353 const int MAX_SPECIALCOMMAND = 15;
1354 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1355 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1356 const float SPECIALCOMMAND_SPEED = 150;
1357 const float SPECIALCOMMAND_TURNSPEED = 2;
1358 const float SPECIALCOMMAND_SIZE = 0.025;
1359 const float SPECIALCOMMAND_CHANCE = 0.35;
1360 float sc_spawntime, sc_changetime;
1361 vector sc_color = '1 1 1';
1362 void SpecialCommand()
1363 {
1364         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1365                 return;
1366
1367         if(time >= sc_changetime)
1368         {
1369                 sc_changetime = time + 1;
1370                 sc_color = randomvec() * 1.5;
1371                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1372                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1373                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1374         }
1375         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1376
1377         if(!precache_pic("gfx/smile"))
1378                 return; // damn party poopers
1379
1380         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1381         {
1382                 vector slot = specialcommand_slots[j];
1383                 if(slot.y)
1384                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1385                 //if(slot.z)
1386                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1387                 if(slot.y >= vid_conheight)
1388                         slot = '0 0 0';
1389
1390                 if(slot == '0 0 0')
1391                 {
1392                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1393                         {
1394                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1395                                 slot.y = 1; // start it off 0 so we can use it
1396                                 slot.z = floor(random() * Weapons_MAX);
1397                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1398                                 vector newcolor = randomvec() * 2;
1399                                 newcolor.x = bound(0.4, newcolor.x, 1);
1400                                 newcolor.y = bound(0.4, newcolor.y, 1);
1401                                 newcolor.z = bound(0.4, newcolor.z, 1);
1402                                 specialcommand_colors[j] = newcolor;
1403                         }
1404                 }
1405                 else
1406                 {
1407                         vector splash_size = '0 0 0';
1408                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1409                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1410                         entity wep = Weapons_from(slot.z);
1411                         if(wep == WEP_Null)
1412                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1413                         else
1414                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1415                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1416                 }
1417
1418                 specialcommand_slots[j] = slot;
1419         }
1420 }
1421
1422 void HUD_Draw(entity this)
1423 {
1424         // if we don't know gametype and scores yet avoid drawing the scoreboard
1425         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1426         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1427         // cl_deathscoreboard would show the scoreboard and so on
1428         if(!gametype)
1429                 return;
1430
1431         Hud_Dynamic_Frame();
1432
1433         if(!intermission)
1434         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1435         {
1436                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1437         }
1438         else if(STAT(FROZEN))
1439         {
1440                 vector col = '0.25 0.90 1';
1441                 if(STAT(REVIVE_PROGRESS))
1442                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1443                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1444         }
1445
1446         HUD_Scale_Enable();
1447         if(!intermission)
1448         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1449         {
1450                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1451                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1452                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1453         }
1454         else if(STAT(CAPTURE_PROGRESS))
1455         {
1456                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1457                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1458         }
1459         else if(STAT(REVIVE_PROGRESS))
1460         {
1461                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1462                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1463         }
1464         HUD_Scale_Disable();
1465
1466         if(autocvar_r_letterbox == 0)
1467                 if(autocvar_viewsize < 120)
1468                 {
1469                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1470                                 Accuracy_LoadLevels();
1471
1472                         HUD_Main();
1473                         HUD_Scale_Disable();
1474                 }
1475
1476         // crosshair goes VERY LAST
1477         SpecialCommand();
1478         UpdateDamage();
1479         HUD_Crosshair(this);
1480         HitSound();
1481 }
1482
1483 void ViewLocation_Mouse()
1484 {
1485         if(spectatee_status)
1486                 return; // don't draw it as spectator!
1487
1488         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1489         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1490         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1491
1492         //float cursor_alpha = 1 - autocvar__menu_alpha;
1493         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1494 }
1495
1496 void HUD_Cursor_Show()
1497 {
1498         float cursor_alpha = 1 - autocvar__menu_alpha;
1499         if(cursor_type == CURSOR_NORMAL)
1500                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1501         else if(cursor_type == CURSOR_MOVE)
1502                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1503         else if(cursor_type == CURSOR_RESIZE)
1504                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1505         else if(cursor_type == CURSOR_RESIZE2)
1506                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1507 }
1508
1509 void HUD_Mouse(entity player)
1510 {
1511         if(autocvar__menu_alpha == 1)
1512                 return;
1513
1514         if(!cursor_active)
1515         {
1516                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1517                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1518                 return;
1519         }
1520
1521         if (cursor_active == -1) // starting to display the cursor
1522         {
1523                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1524                 // in the first frame mousepos is the mouse position of the last time
1525                 // the cursor was displayed, thus we ignore it to avoid a glictch
1526                 cursor_active = 1;
1527                 return;
1528         }
1529
1530         if(!autocvar_hud_cursormode)
1531                 update_mousepos();
1532
1533         if(autocvar__hud_configure)
1534                 HUD_Panel_Mouse();
1535         else
1536         {
1537                 if (HUD_MinigameMenu_IsOpened())
1538                         HUD_Minigame_Mouse();
1539                 if (QuickMenu_IsOpened())
1540                         QuickMenu_Mouse();
1541                 if (HUD_Radar_Clickable())
1542                         HUD_Radar_Mouse();
1543         }
1544
1545         prevMouseClicked = mouseClicked;
1546
1547         HUD_Cursor_Show();
1548 }
1549
1550 bool ov_enabled;
1551 float oldr_nearclip;
1552 float oldr_farclip_base;
1553 float oldr_farclip_world;
1554 float oldr_novis;
1555 float oldr_useportalculling;
1556 float oldr_useinfinitefarclip;
1557
1558 float prev_myteam;
1559 int lasthud;
1560 float vh_notice_time;
1561 void CSQC_UpdateView(entity this, float w, float h)
1562 {
1563         TC(int, w); TC(int, h);
1564         entity e;
1565         float fov;
1566         float f;
1567         vector vf_size, vf_min;
1568         float a;
1569
1570         execute_next_frame();
1571
1572         ++framecount;
1573
1574         stats_get();
1575         hud = STAT(HUD);
1576
1577         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1578                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1579
1580         lasthud = hud;
1581
1582         ReplicateVars(false);
1583         if (ReplicateVars_NOT_SENDING())
1584                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1585
1586         HUD_Scale_Disable();
1587
1588         if(autocvar__hud_showbinds_reload) // menu can set this one
1589         {
1590                 db_close(binddb);
1591                 binddb = db_create();
1592                 cvar_set("_hud_showbinds_reload", "0");
1593         }
1594
1595         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1596                 view_quality = getproperty(VF_MINFPS_QUALITY);
1597         else
1598                 view_quality = 1;
1599
1600         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1601         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1602
1603         vf_size = getpropertyvec(VF_SIZE);
1604         vf_min = getpropertyvec(VF_MIN);
1605         vid_width = vf_size.x;
1606         vid_height = vf_size.y;
1607
1608         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1609         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1610
1611         WaypointSprite_Load();
1612
1613         CSQCPlayer_SetCamera();
1614
1615         if(player_localentnum <= maxclients) // is it a client?
1616                 current_player = player_localentnum - 1;
1617         else // then player_localentnum is the vehicle I'm driving
1618                 current_player = player_localnum;
1619         myteam = entcs_GetTeam(current_player);
1620
1621         if(myteam != prev_myteam)
1622         {
1623                 myteamcolors = colormapPaletteColor(myteam, 1);
1624                 FOREACH(hud_panels, true, it.update_time = time);
1625                 prev_myteam = myteam;
1626         }
1627
1628         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1629
1630         float is_dead = (STAT(HEALTH) <= 0);
1631
1632         // FIXME do we need this hack?
1633         if(isdemo())
1634         {
1635                 // in demos, input_buttons do not work
1636                 button_zoom = (autocvar__togglezoom == "-");
1637         }
1638         else if(button_zoom
1639                 && autocvar_cl_unpress_zoom_on_death
1640                 && (spectatee_status >= 0)
1641                 && (is_dead || intermission))
1642         {
1643                 // no zoom while dead or in intermission please
1644                 localcmd("-zoom\n");
1645                 button_zoom = false;
1646         }
1647
1648         // abused multiple places below
1649         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1650         if(!local_player)
1651                 local_player = this; // fall back!
1652
1653         // event chase camera
1654         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1655         {
1656                 if(STAT(CAMERA_SPECTATOR))
1657                 {
1658                         if(spectatee_status > 0)
1659                         {
1660                                 if(!autocvar_chase_active)
1661                                 {
1662                                         cvar_set("chase_active", "-2");
1663                                         goto skip_eventchase_death;
1664                                 }
1665                         }
1666                         else if(autocvar_chase_active == -2)
1667                                 cvar_set("chase_active", "0");
1668
1669                         if(autocvar_chase_active == -2)
1670                                 goto skip_eventchase_death;
1671                 }
1672                 else if(autocvar_chase_active == -2)
1673                         cvar_set("chase_active", "0");
1674
1675                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1676
1677                 float vehicle_viewdist = 0;
1678                 vector vehicle_viewofs = '0 0 0';
1679
1680                 if(vehicle_chase)
1681                 {
1682                         if(hud != HUD_BUMBLEBEE_GUN)
1683                         {
1684                                 Vehicle info = Vehicles_from(hud);
1685                                 vehicle_viewdist = info.height;
1686                                 vehicle_viewofs = info.view_ofs;
1687                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
1688                                         vehicle_chase = false;
1689                         }
1690                         else
1691                                 vehicle_chase = false;
1692                 }
1693
1694                 int eventchase = WantEventchase(this, vehicle_chase);
1695                 if (eventchase)
1696                 {
1697                         vector current_view_origin_override = '0 0 0';
1698                         vector view_offset_override = '0 0 0';
1699                         float chase_distance_override = 0;
1700                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1701                         if(custom_eventchase)
1702                         {
1703                                 current_view_origin_override = M_ARGV(0, vector);
1704                                 view_offset_override = M_ARGV(1, vector);
1705                                 chase_distance_override = M_ARGV(0, float);
1706                         }
1707                         eventchase_running = true;
1708
1709                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1710                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1711                         if (custom_eventchase)
1712                                 current_view_origin = current_view_origin_override;
1713
1714                         // detect maximum viewoffset and use it
1715                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1716                         if(vehicle_chase)
1717                         {
1718                                 if(vehicle_viewofs)
1719                                         view_offset = vehicle_viewofs;
1720                                 else
1721                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1722                         }
1723                         if (custom_eventchase)
1724                                 view_offset = view_offset_override;
1725
1726                         if(view_offset)
1727                         {
1728                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1729                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1730                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1731                         }
1732
1733                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1734                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1735                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1736                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1737
1738                         // make the camera smooth back
1739                         float chase_distance = autocvar_cl_eventchase_distance;
1740                         if(vehicle_chase)
1741                         {
1742                                 if(vehicle_viewofs)
1743                                         chase_distance = vehicle_viewdist;
1744                                 else
1745                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1746                         }
1747                         if (custom_eventchase)
1748                                 chase_distance = chase_distance_override;
1749
1750                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1751                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1752                         else if(eventchase_current_distance != chase_distance)
1753                                 eventchase_current_distance = chase_distance;
1754
1755                         makevectors(view_angles);
1756
1757                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1758                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1759
1760                         // If the boxtrace fails, revert back to line tracing.
1761                         if(!local_player.viewloc)
1762                         if(trace_startsolid)
1763                         {
1764                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1765                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1766                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1767                         }
1768                         else { setproperty(VF_ORIGIN, trace_endpos); }
1769
1770                         if(!local_player.viewloc)
1771                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1772                 }
1773
1774                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1775                 {
1776                         eventchase_running = false;
1777                         cvar_set("chase_active", "0");
1778                         eventchase_current_distance = 0; // start from 0 next time
1779                 }
1780         }
1781         // workaround for camera stuck between player's legs when using chase_active 1
1782         // because the engine stops updating the chase_active camera when the game ends
1783         else if(intermission)
1784         {
1785                 cvar_settemp("chase_active", "-1");
1786                 eventchase_current_distance = 0;
1787         }
1788
1789         LABEL(skip_eventchase_death);
1790
1791         // do lockview after event chase camera so that it still applies whenever necessary.
1792         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1793         {
1794                 setproperty(VF_ORIGIN, freeze_org);
1795                 setproperty(VF_ANGLES, freeze_ang);
1796         }
1797         else
1798         {
1799                 freeze_org = getpropertyvec(VF_ORIGIN);
1800                 freeze_ang = getpropertyvec(VF_ANGLES);
1801         }
1802
1803         WarpZone_FixView();
1804         //WarpZone_FixPMove();
1805
1806         vector ov_org = '0 0 0';
1807         vector ov_mid = '0 0 0';
1808         vector ov_worldmin = '0 0 0';
1809         vector ov_worldmax = '0 0 0';
1810         if(autocvar_cl_orthoview)
1811         {
1812                 ov_worldmin = mi_picmin;
1813                 ov_worldmax = mi_picmax;
1814
1815                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1816                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1817                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1818
1819                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1820                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1821
1822                 float ov_nearest = vlen(ov_org - vec3(
1823                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1824                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1825                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1826                 ));
1827
1828                 float ov_furthest = 0;
1829                 float dist = 0;
1830
1831                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1832                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1833                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839
1840                 if(!ov_enabled)
1841                 {
1842                         oldr_nearclip = cvar("r_nearclip");
1843                         oldr_farclip_base = cvar("r_farclip_base");
1844                         oldr_farclip_world = cvar("r_farclip_world");
1845                         oldr_novis = cvar("r_novis");
1846                         oldr_useportalculling = cvar("r_useportalculling");
1847                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1848                 }
1849
1850                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1851                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1852                 cvar_settemp("r_farclip_world", "0");
1853                 cvar_settemp("r_novis", "1");
1854                 cvar_settemp("r_useportalculling", "0");
1855                 cvar_settemp("r_useinfinitefarclip", "0");
1856
1857                 setproperty(VF_ORIGIN, ov_org);
1858                 setproperty(VF_ANGLES, '90 0 0');
1859
1860                 ov_enabled = true;
1861
1862                 #if 0
1863                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1864                         vtos(ov_org),
1865                         vtos(getpropertyvec(VF_ANGLES)),
1866                         ov_distance,
1867                         ov_nearest,
1868                         ov_furthest);
1869                 #endif
1870         }
1871         else
1872         {
1873                 if(ov_enabled)
1874                 {
1875                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1876                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1877                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1878                         cvar_set("r_novis", ftos(oldr_novis));
1879                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1880                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1881                 }
1882                 ov_enabled = false;
1883         }
1884
1885         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1886         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1887         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888                 viewmodel_draw(viewmodels[slot]);
1889
1890         // Render the Scene
1891         view_origin = getpropertyvec(VF_ORIGIN);
1892         view_angles = getpropertyvec(VF_ANGLES);
1893         MAKEVECTORS(makevectors, view_angles, view_forward, view_right, view_up);
1894
1895 #ifdef BLURTEST
1896         if(time > blurtest_time0 && time < blurtest_time1)
1897         {
1898                 float r, t;
1899
1900                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1901                 r = t * blurtest_radius;
1902                 f = 1 / (t ** blurtest_power) - 1;
1903
1904                 cvar_set("r_glsl_postprocess", "1");
1905                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1906         }
1907         else
1908         {
1909                 cvar_set("r_glsl_postprocess", "0");
1910                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1911         }
1912 #endif
1913
1914         TargetMusic_Advance();
1915         Fog_Force();
1916         fpscounter_update();
1917
1918         if(drawtime == 0)
1919                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1920         else
1921                 drawframetime = bound(0.000001, time - drawtime, 1);
1922         drawtime = time;
1923
1924         // watch for gametype changes here...
1925         // in ParseStuffCMD the cmd isn't executed yet :/
1926         // might even be better to add the gametype to TE_CSQC_INIT...?
1927         if(!postinit)
1928                 PostInit();
1929
1930         if(intermission && !intermission_time)
1931                 intermission_time = time;
1932
1933         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1934         {
1935                 if(calledhooks & HOOK_START)
1936                 {
1937                         localcmd("\ncl_hook_gameend\n");
1938                         calledhooks |= HOOK_END;
1939                 }
1940         }
1941
1942         Announcer();
1943
1944         fov = autocvar_fov;
1945         if(fov <= 59.5)
1946         {
1947                 if(!zoomscript_caught)
1948                 {
1949                         localcmd("+button9\n");
1950                         zoomscript_caught = 1;
1951                 }
1952         }
1953         else
1954         {
1955                 if(zoomscript_caught)
1956                 {
1957                         localcmd("-button9\n");
1958                         zoomscript_caught = 0;
1959                 }
1960         }
1961
1962         if(active_minigame && HUD_MinigameMenu_IsOpened())
1963         {
1964                 if(!minigame_wasactive)
1965                 {
1966                         localcmd("+button12\n");
1967                         minigame_wasactive = true;
1968                 }
1969         }
1970         else if(minigame_wasactive)
1971         {
1972                 localcmd("-button12\n");
1973                 minigame_wasactive = false;
1974         }
1975
1976         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1977
1978         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1979         {
1980                 entity wepent = viewmodels[slot];
1981
1982                 if(wepent.last_switchweapon != wepent.switchweapon)
1983                 {
1984                         weapontime = time;
1985                         wepent.last_switchweapon = wepent.switchweapon;
1986                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1987                         {
1988                                 localcmd("-zoom\n");
1989                                 button_zoom = false;
1990                         }
1991                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1992                         {
1993                                 localcmd("-fire\n");
1994                                 localcmd("-fire2\n");
1995                                 button_attack2 = false;
1996                         }
1997                 }
1998                 if(wepent.last_activeweapon != wepent.activeweapon)
1999                 {
2000                         wepent.last_activeweapon = wepent.activeweapon;
2001
2002                         e = wepent.activeweapon;
2003                         if(e.netname != "")
2004                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2005                         else if(slot == 0)
2006                                 localcmd("\ncl_hook_activeweapon none\n");
2007                 }
2008         }
2009
2010         // ALWAYS Clear Current Scene First
2011         clearscene();
2012
2013         setproperty(VF_ORIGIN, view_origin);
2014         setproperty(VF_ANGLES, view_angles);
2015
2016         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2017         setproperty(VF_SIZE, vf_size);
2018         setproperty(VF_MIN, vf_min);
2019
2020         // Assign Standard Viewflags
2021         // Draw the World (and sky)
2022         setproperty(VF_DRAWWORLD, 1);
2023
2024         // Set the console size vars
2025         vid_conwidth = autocvar_vid_conwidth;
2026         vid_conheight = autocvar_vid_conheight;
2027         vid_pixelheight = autocvar_vid_pixelheight;
2028
2029         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2030         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2031         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2032
2033         if(camera_active) // Camera for demo playback
2034         {
2035                 if(autocvar_camera_enable)
2036                         CSQC_Demo_Camera();
2037                 else
2038                 {
2039                         cvar_set("chase_active", ftos(chase_active_backup));
2040                         cvar_set("cl_demo_mousegrab", "0");
2041                         camera_active = false;
2042                 }
2043         }
2044         else
2045         {
2046 #ifdef CAMERATEST
2047                 if(autocvar_camera_enable)
2048 #else
2049                 if(autocvar_camera_enable && isdemo())
2050 #endif
2051                 {
2052                         // Enable required Darkplaces cvars
2053                         chase_active_backup = autocvar_chase_active;
2054                         cvar_set("chase_active", "2");
2055                         cvar_set("cl_demo_mousegrab", "1");
2056                         camera_active = true;
2057                         camera_mode = false;
2058                 }
2059         }
2060
2061         // Draw the Crosshair
2062         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2063
2064         // Draw the Engine Status Bar (the default Quake HUD)
2065         setproperty(VF_DRAWENGINESBAR, 0);
2066
2067         // Update the mouse position
2068         /*
2069            mousepos_x = vid_conwidth;
2070            mousepos_y = vid_conheight;
2071            mousepos = mousepos*0.5 + getmousepos();
2072          */
2073
2074         IL_EACH(g_drawables, it.draw, it.draw(it));
2075
2076         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2077         renderscene();
2078
2079         // now switch to 2D drawing mode by calling a 2D drawing function
2080         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2081         // next R_RenderScene call
2082         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2083
2084         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2085         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2086         {
2087                 // apply night vision effect
2088                 vector tc_00, tc_01, tc_10, tc_11;
2089                 vector rgb = '0 0 0';
2090
2091                 if(!nightvision_noise)
2092                 {
2093                         nightvision_noise = new(nightvision_noise);
2094                 }
2095                 if(!nightvision_noise2)
2096                 {
2097                         nightvision_noise2 = new(nightvision_noise2);
2098                 }
2099
2100                 // color tint in yellow
2101                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2102
2103                 // draw BG
2104                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2105                 rgb = '1 1 1';
2106                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2107                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2108                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2109                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2110                 tc_11 = tc_01 + tc_10 - tc_00;
2111                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2112                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2113                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2114                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2115                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2116                 R_EndPolygon();
2117
2118                 // draw FG
2119                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2120                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2121                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2122                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2123                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2124                 tc_11 = tc_01 + tc_10 - tc_00;
2125                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2126                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2127                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2128                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2129                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2130                 R_EndPolygon();
2131         }
2132
2133         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2134         {
2135                 string reticle_image = string_null;
2136                 bool wep_zoomed = false;
2137                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2138                 {
2139                         entity wepe = viewmodels[slot];
2140                         Weapon wep = wepe.activeweapon;
2141                         if(wep != WEP_Null && wep.wr_zoom)
2142                         {
2143                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2144                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2145                                         reticle_image = wep.w_reticle;
2146                                 wep_zoomed += do_zoom;
2147                         }
2148                 }
2149                 // Draw the aiming reticle for weapons that use it
2150                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2151                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2152                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2153                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2154                 {
2155                         // no zoom reticle while dead
2156                         reticle_type = 0;
2157                 }
2158                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2159                 {
2160                         if(reticle_image) { reticle_type = 2; }
2161                         else { reticle_type = 0; }
2162                 }
2163                 else if(button_zoom || zoomscript_caught)
2164                 {
2165                         // normal zoom
2166                         reticle_type = 1;
2167                 }
2168
2169                 if(reticle_type)
2170                 {
2171                         if(autocvar_cl_reticle_stretch)
2172                         {
2173                                 reticle_size.x = vid_conwidth;
2174                                 reticle_size.y = vid_conheight;
2175                                 reticle_pos.x = 0;
2176                                 reticle_pos.y = 0;
2177                         }
2178                         else
2179                         {
2180                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2181                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2182                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2183                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2184                         }
2185
2186                         if(zoomscript_caught)
2187                                 f = 1;
2188                         else
2189                                 f = current_zoomfraction;
2190
2191                         if(f)
2192                         {
2193                                 switch(reticle_type)
2194                                 {
2195                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2196                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2197                                 }
2198                         }
2199                 }
2200         }
2201         else
2202         {
2203                 if(reticle_type != 0) { reticle_type = 0; }
2204         }
2205
2206
2207         // improved polyblend
2208         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2209         {
2210                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2211                 vector liquidcolor;
2212
2213                 switch(pointcontents(view_origin))
2214                 {
2215                         case CONTENT_WATER:
2216                                 liquidalpha = autocvar_hud_contents_water_alpha;
2217                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2218                                 incontent = 1;
2219                                 break;
2220
2221                         case CONTENT_LAVA:
2222                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2223                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2224                                 incontent = 1;
2225                                 break;
2226
2227                         case CONTENT_SLIME:
2228                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2229                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2230                                 incontent = 1;
2231                                 break;
2232
2233                         default:
2234                                 liquidalpha = 0;
2235                                 liquidcolor = '0 0 0';
2236                                 incontent = 0;
2237                                 break;
2238                 }
2239
2240                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2241                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2242                         contentfadetime = autocvar_hud_contents_fadeintime;
2243                         liquidalpha_prev = liquidalpha;
2244                         liquidcolor_prev = liquidcolor;
2245                 }
2246                 else
2247                         contentfadetime = autocvar_hud_contents_fadeouttime;
2248
2249                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2250                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2251
2252                 if(contentavgalpha)
2253                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2254
2255                 if(autocvar_hud_postprocessing)
2256                 {
2257                         if(autocvar_hud_contents_blur && contentavgalpha)
2258                         {
2259                                 content_blurpostprocess.x = 1;
2260                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2261                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2262                         }
2263                         else
2264                         {
2265                                 content_blurpostprocess.x = 0;
2266                                 content_blurpostprocess.y = 0;
2267                                 content_blurpostprocess.z = 0;
2268                         }
2269                 }
2270         }
2271
2272         if(autocvar_hud_damage && !STAT(FROZEN))
2273         {
2274                 splash_size.x = max(vid_conwidth, vid_conheight);
2275                 splash_size.y = max(vid_conwidth, vid_conheight);
2276                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2277                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2278
2279                 float myhealth_flash_temp;
2280                 myhealth = STAT(HEALTH);
2281
2282                 // fade out
2283                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2284                 // add new damage
2285                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2286
2287                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2288                 pain_threshold = autocvar_hud_damage_pain_threshold;
2289                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2290                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2291
2292                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2293                 {
2294                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2295                 }
2296
2297                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2298
2299                 if(myhealth_prev < 1)
2300                 {
2301                         if(myhealth >= 1)
2302                         {
2303                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2304                                 myhealth_flash_temp = 0;
2305                         }
2306                         else
2307                         {
2308                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2309                         }
2310                 }
2311
2312                 if(spectatee_status == -1 || intermission)
2313                 {
2314                         myhealth_flash = 0; // observing, or match ended
2315                         myhealth_flash_temp = 0;
2316                 }
2317
2318                 myhealth_prev = myhealth;
2319
2320                 // IDEA: change damage color/picture based on player model for robot/alien species?
2321                 // pro: matches model better
2322                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2323                 // maybe different reddish pics?
2324                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2325                 {
2326                         if(autocvar_cl_gentle_damage == 2)
2327                         {
2328                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2329                                         myhealth_gentlergb = randomvec();
2330                         }
2331                         else
2332                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2333
2334                         if(myhealth_flash_temp > 0)
2335                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2336                 }
2337                 else if(myhealth_flash_temp > 0)
2338                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2339
2340                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2341                 {
2342                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2343                         {
2344                                 damage_blurpostprocess.x = 1;
2345                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2346                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2347                         }
2348                         else
2349                         {
2350                                 damage_blurpostprocess.x = 0;
2351                                 damage_blurpostprocess.y = 0;
2352                                 damage_blurpostprocess.z = 0;
2353                         }
2354                 }
2355         }
2356
2357         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2358         float e2 = (autocvar_hud_powerup != 0);
2359         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2360         {
2361                 // enable or disable rendering types if they are used or not
2362                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2363                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2364
2365                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2366                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2367                 {
2368                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2369                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2370                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2371                         {
2372                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2373                                 old_blurradius = blurradius;
2374                                 old_bluralpha = bluralpha;
2375                         }
2376                 }
2377                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2378                 {
2379                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2380                         old_blurradius = 0;
2381                         old_bluralpha = 0;
2382                 }
2383
2384                 // edge detection postprocess handling done second (used by hud_powerup)
2385                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2386                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2387                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2388
2389                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2390
2391                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2392                 {
2393                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2394                         {
2395                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2396                                 old_sharpen_intensity = sharpen_intensity;
2397                         }
2398                 }
2399                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2400                 {
2401                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2402                         old_sharpen_intensity = 0;
2403                 }
2404
2405                 if(cvar("r_glsl_postprocess") == 0)
2406                         cvar_set("r_glsl_postprocess", "2");
2407         }
2408         else if(cvar("r_glsl_postprocess") == 2)
2409                 cvar_set("r_glsl_postprocess", "0");
2410
2411         /*if(ISGAMETYPE(CTF))
2412           {
2413           ctf_view();
2414           } else */
2415
2416         // draw 2D entities
2417         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2418         Draw_ShowNames_All();
2419 #if ENABLE_DEBUGDRAW
2420         Debug_Draw();
2421 #endif
2422
2423         scoreboard_active = Scoreboard_WouldDraw();
2424
2425         HUD_Draw(this); // this parameter for deep vehicle function
2426
2427         if(NextFrameCommand)
2428         {
2429                 localcmd("\n", NextFrameCommand, "\n");
2430                 NextFrameCommand = string_null;
2431         }
2432
2433         // we must do this check AFTER a frame was rendered, or it won't work
2434         if(cs_project_is_b0rked == 0)
2435         {
2436                 string w0, h0;
2437                 w0 = ftos(autocvar_vid_conwidth);
2438                 h0 = ftos(autocvar_vid_conheight);
2439                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2440                 //setproperty(VF_FOV, '90 90 0');
2441                 setproperty(VF_ORIGIN, '0 0 0');
2442                 setproperty(VF_ANGLES, '0 0 0');
2443                 setproperty(VF_PERSPECTIVE, 1);
2444                 makevectors('0 0 0');
2445                 vector v1, v2;
2446                 cvar_set("vid_conwidth", "800");
2447                 cvar_set("vid_conheight", "600");
2448                 v1 = cs_project(v_forward);
2449                 cvar_set("vid_conwidth", "640");
2450                 cvar_set("vid_conheight", "480");
2451                 v2 = cs_project(v_forward);
2452                 if(v1 == v2)
2453                         cs_project_is_b0rked = 1;
2454                 else
2455                         cs_project_is_b0rked = -1;
2456                 cvar_set("vid_conwidth", w0);
2457                 cvar_set("vid_conheight", h0);
2458         }
2459
2460         HUD_Mouse(local_player);
2461
2462         cl_notice_run();
2463         unpause_update();
2464         Net_Flush();
2465
2466         // let's reset the view back to normal for the end
2467         setproperty(VF_MIN, '0 0 0');
2468         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2469
2470         IL_ENDFRAME();
2471 }
2472
2473
2474 // following vectors must be global to allow seamless switching between camera modes
2475 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2476 void CSQC_Demo_Camera()
2477 {
2478         float speed, attenuation, dimensions;
2479         vector tmp, delta;
2480
2481         if( autocvar_camera_reset || !camera_mode )
2482         {
2483                 camera_offset = '0 0 0';
2484                 current_angles = '0 0 0';
2485                 camera_direction = '0 0 0';
2486                 camera_offset.z += 30;
2487                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2488                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2489                 current_origin = view_origin;
2490                 current_camera_offset  = camera_offset;
2491                 cvar_set("camera_reset", "0");
2492                 camera_mode = CAMERA_CHASE;
2493         }
2494
2495         // Camera angles
2496         if( camera_roll )
2497                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2498
2499         if(autocvar_camera_look_player)
2500         {
2501                 vector dir;
2502                 float n;
2503
2504                 dir = normalize(view_origin - current_position);
2505                 n = mouse_angles.z;
2506                 mouse_angles = vectoangles(dir);
2507                 mouse_angles.x = mouse_angles.x * -1;
2508                 mouse_angles.z = n;
2509         }
2510         else
2511         {
2512                 tmp = getmousepos() * 0.1;
2513                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2514                 {
2515                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2516                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2517                 }
2518         }
2519
2520         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2521         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2522         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2523         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2524
2525         // Fix difference when angles don't have the same sign
2526         delta = '0 0 0';
2527         if(mouse_angles.y < -60 && current_angles.y > 60)
2528                 delta = '0 360 0';
2529         if(mouse_angles.y > 60 && current_angles.y < -60)
2530                 delta = '0 -360 0';
2531
2532         if(autocvar_camera_look_player)
2533                 attenuation = autocvar_camera_look_attenuation;
2534         else
2535                 attenuation = autocvar_camera_speed_attenuation;
2536
2537         attenuation = 1 / max(1, attenuation);
2538         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2539
2540         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2541         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2542         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2543         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2544
2545         // Camera position
2546         tmp = '0 0 0';
2547         dimensions = 0;
2548
2549         if( camera_direction.x )
2550         {
2551                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2552                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2553                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2554                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2555                 ++dimensions;
2556         }
2557
2558         if( camera_direction.y )
2559         {
2560                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2561                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2562                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2563                 ++dimensions;
2564         }
2565
2566         if( camera_direction.z )
2567         {
2568                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2569                 ++dimensions;
2570         }
2571
2572         if(autocvar_camera_free)
2573                 speed = autocvar_camera_speed_free;
2574         else
2575                 speed = autocvar_camera_speed_chase;
2576
2577         if(dimensions)
2578         {
2579                 speed = speed * sqrt(1 / dimensions);
2580                 camera_offset += tmp * speed;
2581         }
2582
2583         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2584
2585         // Camera modes
2586         if( autocvar_camera_free )
2587         {
2588                 if ( camera_mode == CAMERA_CHASE )
2589                 {
2590                         current_camera_offset = current_origin + current_camera_offset;
2591                         camera_offset = current_origin + camera_offset;
2592                 }
2593
2594                 camera_mode = CAMERA_FREE;
2595                 current_position = current_camera_offset;
2596         }
2597         else
2598         {
2599                 if ( camera_mode == CAMERA_FREE )
2600                 {
2601                         current_origin = view_origin;
2602                         camera_offset = camera_offset - current_origin;
2603                         current_camera_offset = current_camera_offset - current_origin;
2604                 }
2605
2606                 camera_mode = CAMERA_CHASE;
2607
2608                 if(autocvar_camera_chase_smoothly)
2609                         current_origin += (view_origin - current_origin) * attenuation;
2610                 else
2611                         current_origin = view_origin;
2612
2613                 current_position = current_origin + current_camera_offset;
2614         }
2615
2616         setproperty(VF_ANGLES, current_angles);
2617         setproperty(VF_ORIGIN, current_position);
2618 }