qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades/all.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../csqcmodellib/cl_player.qh"
  24
  25 #include "../warpzonelib/client.qh"
  26 #include "../warpzonelib/common.qh"
  27
  28 entity porto;
  29 vector polyline[16];
  30 void Porto_Draw(entity this)
  31 {
  32         vector p, dir, ang, q, nextdir;
  33         float portal_number, portal1_idx;
  34
  35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  36                 return;
  37         if(g_balance_porto_secondary)
  38                 return;
  39         if(intermission == 1)
  40                 return;
  41         if(intermission == 2)
  42                 return;
  43         if (getstati(STAT_HEALTH) <= 0)
  44                 return;
  45
  46         dir = view_forward;
  47
  48         if(angles_held_status)
  49         {
  50                 makevectors(angles_held);
  51                 dir = v_forward;
  52         }
  53
  54         p = view_origin;
  55
  56         polyline[0] = p;
  57         int idx = 1;
  58         portal_number = 0;
  59         nextdir = dir;
  60
  61         for (;;)
  62         {
  63                 dir = nextdir;
  64                 traceline(p, p + 65536 * dir, true, porto);
  65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66                         return;
  67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  68                 p = trace_endpos;
  69                 polyline[idx] = p;
  70                 ++idx;
  71                 if(idx >= 16)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         continue;
  75                 ++portal_number;
  76                 ang = vectoangles2(trace_plane_normal, dir);
  77                 ang.x = -ang.x;
  78                 makevectors(ang);
  79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  80                         return;
  81                 if(portal_number == 1)
  82                 {
  83                         portal1_idx = idx;
  84                         if(portal_number >= 2)
  85                                 break;
  86                 }
  87         }
  88
  89         while(idx >= 2)
  90         {
  91                 p = polyline[idx-2];
  92                 q = polyline[idx-1];
  93                 if(idx == 2)
  94                         p = p - view_up * 16;
  95                 if(idx-1 >= portal1_idx)
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 else
 100                 {
 101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 102                 }
 103                 --idx;
 104         }
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 120         float velocityzoom, curspeed;
 121         vector v;
 122
 123         zoomsensitivity = autocvar_cl_zoomsensitivity;
 124         zoomfactor = autocvar_cl_zoomfactor;
 125         if(zoomfactor < 1 || zoomfactor > 30)
 126                 zoomfactor = 2.5;
 127         zoomspeed = autocvar_cl_zoomspeed;
 128         if(zoomspeed >= 0)
 129         if(zoomspeed < 0.5 || zoomspeed > 16)
 130                         zoomspeed = 3.5;
 131
 132         zoomdir = button_zoom;
 133         if(hud == HUD_NORMAL)
 134         if(switchweapon == activeweapon)
 135         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 136                 zoomdir += button_attack2;
 137         if(spectatee_status > 0 || isdemo())
 138         {
 139                 if(spectatorbutton_zoom)
 140                 {
 141                         if(zoomdir)
 142                                 zoomdir = 0;
 143                         else
 144                                 zoomdir = 1;
 145                 }
 146                 // fteqcc failed twice here already, don't optimize this
 147         }
 148
 149         if(zoomdir) { zoomin_effect = 0; }
 150
 151         if(camera_active)
 152         {
 153                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 154         }
 155         else if(autocvar_cl_spawnzoom && zoomin_effect)
 156         {
 157                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 158
 159                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 160                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 161                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 162         }
 163         else
 164         {
 165                 if(zoomspeed < 0) // instant zoom
 166                 {
 167                         if(zoomdir)
 168                                 current_viewzoom = 1 / zoomfactor;
 169                         else
 170                                 current_viewzoom = 1;
 171                 }
 172                 else
 173                 {
 174                         if(zoomdir)
 175                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 176                         else
 177                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 178                 }
 179         }
 180
 181         if(almost_equals(current_viewzoom, 1))
 182                 current_zoomfraction = 0;
 183         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 184                 current_zoomfraction = 1;
 185         else
 186                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 187
 188         if(zoomsensitivity < 1)
 189                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 190         else
 191                 setsensitivityscale(1);
 192
 193         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 194         {
 195                 if(intermission) { curspeed = 0; }
 196                 else
 197                 {
 198
 199                         makevectors(view_angles);
 200                         v = pmove_vel;
 201                         if(csqcplayer)
 202                                 v = csqcplayer.velocity;
 203
 204                         switch(autocvar_cl_velocityzoom_type)
 205                         {
 206                                 case 3: curspeed = max(0, v_forward * v); break;
 207                                 case 2: curspeed = (v_forward * v); break;
 208                                 case 1: default: curspeed = vlen(v); break;
 209                         }
 210                 }
 211
 212                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 213                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 214                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 215
 216                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 217         }
 218         else
 219                 velocityzoom = 1;
 220
 221         float frustumx, frustumy, fovx, fovy;
 222         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 223         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 224         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 225         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 226
 227         return '1 0 0' * fovx + '0 1 0' * fovy;
 228 }
 229
 230 vector GetViewLocationFOV(float fov)
 231 {
 232         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 233         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 234         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 235         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 236         return '1 0 0' * fovx + '0 1 0' * fovy;
 237 }
 238
 239 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 240 {
 241         float fovx, fovy;
 242         float width = (ov_worldmax.x - ov_worldmin.x);
 243         float height = (ov_worldmax.y - ov_worldmin.y);
 244         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 245         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 246         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 247         return '1 0 0' * fovx + '0 1 0' * fovy;
 248 }
 249
 250 // this function must match W_SetupShot!
 251 float zoomscript_caught;
 252
 253 vector wcross_origin;
 254 float wcross_scale_prev, wcross_alpha_prev;
 255 vector wcross_color_prev;
 256 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 257 vector wcross_color_goal_prev;
 258 float wcross_changedonetime;
 259
 260 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 261 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 262 float wcross_name_changestarttime, wcross_name_changedonetime;
 263 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 264
 265 float wcross_ring_prev;
 266
 267 entity trueaim;
 268 entity trueaim_rifle;
 269
 270 const float SHOTTYPE_HITTEAM = 1;
 271 const float SHOTTYPE_HITOBSTRUCTION = 2;
 272 const float SHOTTYPE_HITWORLD = 3;
 273 const float SHOTTYPE_HITENEMY = 4;
 274
 275 void TrueAim_Init()
 276 {
 277         trueaim = spawn();
 278         trueaim.classname = "trueaim";
 279         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 280         trueaim_rifle = spawn();
 281         trueaim_rifle.classname = "trueaim_rifle";
 282         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 283 }
 284
 285 float EnemyHitCheck()
 286 {
 287         float t, n;
 288         wcross_origin = project_3d_to_2d(trace_endpos);
 289         wcross_origin.z = 0;
 290         if(trace_ent)
 291                 n = trace_ent.entnum;
 292         else
 293                 n = trace_networkentity;
 294         if(n < 1)
 295                 return SHOTTYPE_HITWORLD;
 296         if(n > maxclients)
 297                 return SHOTTYPE_HITWORLD;
 298         t = GetPlayerColor(n - 1);
 299         if(teamplay)
 300                 if(t == myteam)
 301                         return SHOTTYPE_HITTEAM;
 302         if(t == NUM_SPECTATOR)
 303                 return SHOTTYPE_HITWORLD;
 304         return SHOTTYPE_HITENEMY;
 305 }
 306
 307 float TrueAimCheck()
 308 {
 309         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 310         vector vecs, trueaimpoint, w_shotorg;
 311         vector mi, ma, dv;
 312         float shottype;
 313         entity ta;
 314         float mv;
 315
 316         mi = ma = '0 0 0';
 317         ta = trueaim;
 318         mv = MOVE_NOMONSTERS;
 319
 320         switch(activeweapon) // WEAPONTODO
 321         {
 322                 case WEP_TUBA.m_id: // no aim
 323                 case WEP_PORTO.m_id: // shoots from eye
 324                 case WEP_NEXBALL.m_id: // shoots from eye
 325                 case WEP_HOOK.m_id: // no trueaim
 326                 case WEP_MORTAR.m_id: // toss curve
 327                         return SHOTTYPE_HITWORLD;
 328                 case WEP_VORTEX.m_id:
 329                 case WEP_VAPORIZER.m_id:
 330                         mv = MOVE_NORMAL;
 331                         break;
 332                 case WEP_RIFLE.m_id:
 333                         ta = trueaim_rifle;
 334                         mv = MOVE_NORMAL;
 335                         if(zoomscript_caught)
 336                         {
 337                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 338                                 return EnemyHitCheck();
 339                         }
 340                         break;
 341                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 342                         mi = '-3 -3 -3';
 343                         ma = '3 3 3';
 344                         break;
 345                 case WEP_FIREBALL.m_id: // projectile has a size!
 346                         mi = '-16 -16 -16';
 347                         ma = '16 16 16';
 348                         break;
 349                 case WEP_SEEKER.m_id: // projectile has a size!
 350                         mi = '-2 -2 -2';
 351                         ma = '2 2 2';
 352                         break;
 353                 case WEP_ELECTRO.m_id: // projectile has a size!
 354                         mi = '0 0 -3';
 355                         ma = '0 0 -3';
 356                         break;
 357         }
 358
 359         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 360
 361         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 362
 363         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 364         trueaimpoint = trace_endpos;
 365
 366         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 367                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 368
 369         if(vecs.x > 0)
 370                 vecs.y = -vecs.y;
 371         else
 372                 vecs = '0 0 0';
 373
 374         dv = view_right * vecs.y + view_up * vecs.z;
 375         w_shotorg = traceorigin + dv;
 376
 377         // now move the vecs forward as much as requested if possible
 378         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 379         w_shotorg = trace_endpos - view_forward * nudge;
 380
 381         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 382         shottype = EnemyHitCheck();
 383         if(shottype != SHOTTYPE_HITWORLD)
 384                 return shottype;
 385
 386 #if 0
 387         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 388         // or rather, I know why, but see no fix
 389         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 390                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 391                 return SHOTTYPE_HITOBSTRUCTION;
 392 #endif
 393
 394         return SHOTTYPE_HITWORLD;
 395 }
 396
 397 void CSQC_common_hud(void);
 398
 399 void PostInit(void);
 400 void CSQC_Demo_Camera();
 401 float HUD_WouldDrawScoreboard();
 402 float camera_mode;
 403 const float CAMERA_FREE = 1;
 404 const float CAMERA_CHASE = 2;
 405 float reticle_type;
 406 string reticle_image;
 407 string NextFrameCommand;
 408
 409 vector freeze_org, freeze_ang;
 410 entity nightvision_noise, nightvision_noise2;
 411
 412 const float MAX_TIME_DIFF = 5;
 413 float pickup_crosshair_time, pickup_crosshair_size;
 414 float hitindication_crosshair_size;
 415 float use_vortex_chargepool;
 416
 417 float myhealth, myhealth_prev;
 418 float myhealth_flash;
 419
 420 float old_blurradius, old_bluralpha;
 421 float old_sharpen_intensity;
 422
 423 vector myhealth_gentlergb;
 424
 425 float contentavgalpha, liquidalpha_prev;
 426 vector liquidcolor_prev;
 427
 428 float eventchase_current_distance;
 429 float eventchase_running;
 430 bool WantEventchase()
 431 {SELFPARAM();
 432         if(autocvar_cl_orthoview)
 433                 return false;
 434         if(intermission)
 435                 return true;
 436         if(self.viewloc)
 437                 return true;
 438         if(spectatee_status >= 0)
 439         {
 440                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 441                         return true;
 442                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 443                         return true;
 444                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 445                         return true;
 446                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 447                 {
 448                         if(autocvar_cl_eventchase_death == 2)
 449                         {
 450                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 451                                 if(self.velocity == '0 0 0' || eventchase_running)
 452                                         return true;
 453                         }
 454                         else return true;
 455                 }
 456         }
 457         return false;
 458 }
 459
 460 vector damage_blurpostprocess, content_blurpostprocess;
 461
 462 float unaccounted_damage = 0;
 463 void UpdateDamage()
 464 {
 465         // accumulate damage with each stat update
 466         static float damage_total_prev = 0;
 467         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 468         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 469         damage_total_prev = damage_total;
 470
 471         static float damage_dealt_time_prev = 0;
 472         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 473         if (damage_dealt_time != damage_dealt_time_prev)
 474         {
 475                 unaccounted_damage += unaccounted_damage_new;
 476                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 477         }
 478         damage_dealt_time_prev = damage_dealt_time;
 479
 480         // prevent hitsound when switching spectatee
 481         static float spectatee_status_prev = 0;
 482         if (spectatee_status != spectatee_status_prev)
 483                 unaccounted_damage = 0;
 484         spectatee_status_prev = spectatee_status;
 485 }
 486
 487 void UpdateHitsound()
 488 {
 489         // varying sound pitch
 490
 491         static float hitsound_time_prev = 0;
 492         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 493         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 494         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 495         {
 496                 if (autocvar_cl_hitsound && unaccounted_damage)
 497                 {
 498                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 499                         float a = autocvar_cl_hitsound_max_pitch;
 500                         float b = autocvar_cl_hitsound_min_pitch;
 501                         float c = autocvar_cl_hitsound_nom_damage;
 502                         float x = unaccounted_damage;
 503                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 504
 505                         // if sound variation is disabled, set pitch_shift to 1
 506                         if (autocvar_cl_hitsound == 1)
 507                                 pitch_shift = 1;
 508
 509                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 510                         if (autocvar_cl_hitsound == 3)
 511                         {
 512                                 float mirror_value = (a-b)/2 + b;
 513                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 514                         }
 515
 516                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 517
 518                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 519                         // todo: normalize sound pressure levels? seems unnecessary
 520
 521                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 522                 }
 523                 unaccounted_damage = 0;
 524                 hitsound_time_prev = time;
 525         }
 526
 527         static float typehit_time_prev = 0;
 528         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 529         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 530         {
 531                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 532                 typehit_time_prev = typehit_time;
 533         }
 534 }
 535
 536 void UpdateCrosshair()
 537 {SELFPARAM();
 538         static float rainbow_last_flicker;
 539     static vector rainbow_prev_color;
 540         entity e = self;
 541         float f, i, j;
 542         vector v;
 543         if(getstati(STAT_FROZEN))
 544                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 545         else if (getstatf(STAT_HEALING_ORB)>time)
 546                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 547         if(!intermission)
 548         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 549         {
 550                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 551                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 552         }
 553         else if(getstatf(STAT_REVIVE_PROGRESS))
 554         {
 555                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 556                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 557         }
 558
 559         if(autocvar_r_letterbox == 0)
 560                 if(autocvar_viewsize < 120)
 561                         CSQC_common_hud();
 562
 563         // crosshair goes VERY LAST
 564         if(!scoreboard_active && !camera_active && intermission != 2 &&
 565                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
 566                 !HUD_MinigameMenu_IsOpened() )
 567         {
 568                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 569                         return;
 570
 571                 string wcross_style;
 572                 float wcross_alpha, wcross_resolution;
 573                 wcross_style = autocvar_crosshair;
 574                 if (wcross_style == "0")
 575                         return;
 576                 wcross_resolution = autocvar_crosshair_size;
 577                 if (wcross_resolution == 0)
 578                         return;
 579                 wcross_alpha = autocvar_crosshair_alpha;
 580                 if (wcross_alpha == 0)
 581                         return;
 582
 583                 // TrueAim check
 584                 float shottype;
 585
 586                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 587                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 588                 wcross_origin.z = 0;
 589                 if(autocvar_crosshair_hittest)
 590                 {
 591                         vector wcross_oldorigin;
 592                         wcross_oldorigin = wcross_origin;
 593                         shottype = TrueAimCheck();
 594                         if(shottype == SHOTTYPE_HITWORLD)
 595                         {
 596                                 v = wcross_origin - wcross_oldorigin;
 597                                 v.x /= vid_conwidth;
 598                                 v.y /= vid_conheight;
 599                                 if(vlen(v) > 0.01)
 600                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 601                         }
 602                         if(!autocvar_crosshair_hittest_showimpact)
 603                                 wcross_origin = wcross_oldorigin;
 604                 }
 605                 else
 606                         shottype = SHOTTYPE_HITWORLD;
 607
 608                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 609                 string wcross_name = "";
 610                 float wcross_scale, wcross_blur;
 611
 612                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 613                 {
 614                         e = get_weaponinfo(switchingweapon);
 615                         if(e)
 616                         {
 617                                 if(autocvar_crosshair_per_weapon)
 618                                 {
 619                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 620                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 621                                         //if (wcross_resolution == 0)
 622                                                 //return;
 623
 624                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 625                                         wcross_resolution *= e.w_crosshair_size;
 626                                         wcross_name = e.w_crosshair;
 627                                 }
 628                         }
 629                 }
 630
 631                 if(wcross_name == "")
 632                         wcross_name = strcat("gfx/crosshair", wcross_style);
 633
 634                 // MAIN CROSSHAIR COLOR DECISION
 635                 switch(autocvar_crosshair_color_special)
 636                 {
 637                         case 1: // crosshair_color_per_weapon
 638                         {
 639                                 if(e)
 640                                 {
 641                                         wcross_color = e.wpcolor;
 642                                         break;
 643                                 }
 644                                 else { goto normalcolor; }
 645                         }
 646
 647                         case 2: // crosshair_color_by_health
 648                         {
 649                                 float x = getstati(STAT_HEALTH);
 650
 651                                 //x = red
 652                                 //y = green
 653                                 //z = blue
 654
 655                                 wcross_color.z = 0;
 656
 657                                 if(x > 200)
 658                                 {
 659                                         wcross_color.x = 0;
 660                                         wcross_color.y = 1;
 661                                 }
 662                                 else if(x > 150)
 663                                 {
 664                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 665                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 666                                 }
 667                                 else if(x > 100)
 668                                 {
 669                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 670                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 671                                         wcross_color.z = 1 - (x-100)*0.02;
 672                                 }
 673                                 else if(x > 50)
 674                                 {
 675                                         wcross_color.x = 1;
 676                                         wcross_color.y = 1;
 677                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 678                                 }
 679                                 else if(x > 20)
 680                                 {
 681                                         wcross_color.x = 1;
 682                                         wcross_color.y = (x-20)*90/27/100;
 683                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 684                                 }
 685                                 else
 686                                 {
 687                                         wcross_color.x = 1;
 688                                         wcross_color.y = 0;
 689                                 }
 690                                 break;
 691                         }
 692
 693                         case 3: // crosshair_color_rainbow
 694                         {
 695                                 if(time >= rainbow_last_flicker)
 696                                 {
 697                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 698                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 699                                 }
 700                                 wcross_color = rainbow_prev_color;
 701                                 break;
 702                         }
 703                         :normalcolor
 704                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 705                 }
 706
 707                 if(autocvar_crosshair_effect_scalefade)
 708                 {
 709                         wcross_scale = wcross_resolution;
 710                         wcross_resolution = 1;
 711                 }
 712                 else
 713                 {
 714                         wcross_scale = 1;
 715                 }
 716
 717                 if(autocvar_crosshair_pickup)
 718                 {
 719                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 720
 721                         if(pickup_crosshair_time < stat_pickup_time)
 722                         {
 723                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 724                                         pickup_crosshair_size = 1;
 725
 726                                 pickup_crosshair_time = stat_pickup_time;
 727                         }
 728
 729                         if(pickup_crosshair_size > 0)
 730                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 731                         else
 732                                 pickup_crosshair_size = 0;
 733
 734                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 735                 }
 736
 737                 // todo: make crosshair hit indication dependent on damage dealt
 738                 if(autocvar_crosshair_hitindication)
 739                 {
 740                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 741
 742                         if(unaccounted_damage)
 743                         {
 744                                 hitindication_crosshair_size = 1;
 745                         }
 746
 747                         if(hitindication_crosshair_size > 0)
 748                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 749                         else
 750                                 hitindication_crosshair_size = 0;
 751
 752                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 753                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 754                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 755                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 756                 }
 757
 758                 if(shottype == SHOTTYPE_HITENEMY)
 759                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 760                 if(shottype == SHOTTYPE_HITTEAM)
 761                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 762
 763                 f = fabs(autocvar_crosshair_effect_time);
 764                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 765                 {
 766                         wcross_changedonetime = time + f;
 767                 }
 768                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 769                 {
 770                         wcross_name_changestarttime = time;
 771                         wcross_name_changedonetime = time + f;
 772                         if(wcross_name_goal_prev_prev)
 773                                 strunzone(wcross_name_goal_prev_prev);
 774                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 775                         wcross_name_goal_prev = strzone(wcross_name);
 776                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 777                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 778                         wcross_resolution_goal_prev = wcross_resolution;
 779                 }
 780
 781                 wcross_scale_goal_prev = wcross_scale;
 782                 wcross_alpha_goal_prev = wcross_alpha;
 783                 wcross_color_goal_prev = wcross_color;
 784
 785                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 786                 {
 787                         wcross_blur = 1;
 788                         wcross_alpha *= 0.75;
 789                 }
 790                 else
 791                         wcross_blur = 0;
 792                 // *_prev is at time-frametime
 793                 // * is at wcross_changedonetime+f
 794                 // what do we have at time?
 795                 if(time < wcross_changedonetime)
 796                 {
 797                         f = frametime / (wcross_changedonetime - time + frametime);
 798                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 799                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 800                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 801                 }
 802
 803                 wcross_scale_prev = wcross_scale;
 804                 wcross_alpha_prev = wcross_alpha;
 805                 wcross_color_prev = wcross_color;
 806
 807                 MUTATOR_CALLHOOK(UpdateCrosshair);
 808
 809                 wcross_scale *= 1 - autocvar__menu_alpha;
 810                 wcross_alpha *= 1 - autocvar__menu_alpha;
 811                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 812
 813                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 814                 {
 815                         // crosshair rings for weapon stats
 816                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 817                         {
 818                                 // declarations and stats
 819                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 820                                 string ring_image = string_null, ring_inner_image = string_null;
 821                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 822
 823                                 ring_scale = autocvar_crosshair_ring_size;
 824
 825                                 float weapon_clipload, weapon_clipsize;
 826                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 827                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 828
 829                                 float ok_ammo_charge, ok_ammo_chargepool;
 830                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 831                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 832
 833                                 float vortex_charge, vortex_chargepool;
 834                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 835                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 836
 837                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 838
 839                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 840                                         vortex_charge_movingavg = vortex_charge;
 841
 842
 843                                 // handle the values
 844                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 845                                 {
 846                                         if (vortex_chargepool || use_vortex_chargepool) {
 847                                                 use_vortex_chargepool = 1;
 848                                                 ring_inner_value = vortex_chargepool;
 849                                         } else {
 850                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 851                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 852                                         }
 853
 854                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 855                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 856                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 857
 858                                         // draw the outer ring to show the current charge of the weapon
 859                                         ring_value = vortex_charge;
 860                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 861                                         ring_rgb = wcross_color;
 862                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 863                                 }
 864                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 865                                 {
 866                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 867                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 868                                         ring_rgb = wcross_color;
 869                                         ring_image = "gfx/crosshair_ring.tga";
 870                                 }
 871                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 872                                 {
 873                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 874                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 875                                         ring_rgb = wcross_color;
 876                                         ring_image = "gfx/crosshair_ring.tga";
 877                                 }
 878                                 else if (ok_ammo_charge)
 879                                 {
 880                                         ring_value = ok_ammo_chargepool;
 881                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 882                                         ring_rgb = wcross_color;
 883                                         ring_image = "gfx/crosshair_ring.tga";
 884                                 }
 885                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 886                                 {
 887                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 888                                         ring_scale = autocvar_crosshair_ring_reload_size;
 889                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 890                                         ring_rgb = wcross_color;
 891
 892                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 893                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 894                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 895                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 896                                         else
 897                                                 ring_image = "gfx/crosshair_ring.tga";
 898                                 }
 899                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 900                                 {
 901                                         ring_value = arc_heat;
 902                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 903                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 904                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 905                                         ring_image = "gfx/crosshair_ring.tga";
 906                                 }
 907
 908                                 // if in weapon switch animation, fade ring out/in
 909                                 if(autocvar_crosshair_effect_time > 0)
 910                                 {
 911                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 912                                         if (f >= 1)
 913                                         {
 914                                                 wcross_ring_prev = ((ring_image) ? true : false);
 915                                         }
 916
 917                                         if(wcross_ring_prev)
 918                                         {
 919                                                 if(f < 1)
 920                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 921                                         }
 922                                         else
 923                                         {
 924                                                 if(f < 1)
 925                                                         ring_alpha *= bound(0, f, 1);
 926                                         }
 927                                 }
 928
 929                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 930                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 931
 932                                 if (ring_value)
 933                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 934                         }
 935
 936 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 937                         do \
 938                         { \
 939                                 if(wcross_blur > 0) \
 940                                 { \
 941                                         for(i = -2; i <= 2; ++i) \
 942                                         for(j = -2; j <= 2; ++j) \
 943                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 944                                 } \
 945                                 else \
 946                                 { \
 947                                         M(0,0,sz,wcross_name,wcross_alpha); \
 948                                 } \
 949                         } \
 950                         while(0)
 951
 952 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 953                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 954
 955 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 956                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 957
 958                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 959                         {
 960                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 961                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 962                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 963                                 f = 1 - f;
 964                         }
 965                         else
 966                         {
 967                                 f = 1;
 968                         }
 969                         wcross_name_alpha_goal_prev = f;
 970
 971                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 972                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 973
 974                         if(autocvar_crosshair_dot)
 975                         {
 976                                 vector wcross_color_old;
 977                                 wcross_color_old = wcross_color;
 978
 979                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 980                                         wcross_color = stov(autocvar_crosshair_dot_color);
 981
 982                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 983                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 984                                 wcross_color = wcross_color_old;
 985                         }
 986                 }
 987         }
 988         else
 989         {
 990                 wcross_scale_prev = 0;
 991                 wcross_alpha_prev = 0;
 992                 wcross_scale_goal_prev = 0;
 993                 wcross_alpha_goal_prev = 0;
 994                 wcross_changedonetime = 0;
 995                 if(wcross_name_goal_prev)
 996                         strunzone(wcross_name_goal_prev);
 997                 wcross_name_goal_prev = string_null;
 998                 if(wcross_name_goal_prev_prev)
 999                         strunzone(wcross_name_goal_prev_prev);
1000                 wcross_name_goal_prev_prev = string_null;
1001                 wcross_name_changestarttime = 0;
1002                 wcross_name_changedonetime = 0;
1003                 wcross_name_alpha_goal_prev = 0;
1004                 wcross_name_alpha_goal_prev_prev = 0;
1005                 wcross_resolution_goal_prev = 0;
1006                 wcross_resolution_goal_prev_prev = 0;
1007         }
1008 }
1009
1010 bool ov_enabled;
1011 float oldr_nearclip;
1012 float oldr_farclip_base;
1013 float oldr_farclip_world;
1014 float oldr_novis;
1015 float oldr_useportalculling;
1016 float oldr_useinfinitefarclip;
1017
1018 const int BUTTON_3 = 4;
1019 const int BUTTON_4 = 8;
1020 float cl_notice_run();
1021 float prev_myteam;
1022 int lasthud;
1023 float vh_notice_time;
1024 void WaypointSprite_Load();
1025 void CSQC_UpdateView(float w, float h)
1026 {SELFPARAM();
1027         entity e;
1028         float fov;
1029         float f;
1030         vector vf_size, vf_min;
1031         float a;
1032
1033         execute_next_frame();
1034
1035         ++framecount;
1036
1037         hud = getstati(STAT_HUD);
1038
1039         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1040                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1041
1042         lasthud = hud;
1043
1044         if(autocvar__hud_showbinds_reload) // menu can set this one
1045         {
1046                 db_close(binddb);
1047                 binddb = db_create();
1048                 cvar_set("_hud_showbinds_reload", "0");
1049         }
1050
1051         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1052                 view_quality = getproperty(VF_MINFPS_QUALITY);
1053         else
1054                 view_quality = 1;
1055
1056         button_attack2 = (input_buttons & BUTTON_3);
1057         button_zoom = (input_buttons & BUTTON_4);
1058
1059         vf_size = getpropertyvec(VF_SIZE);
1060         vf_min = getpropertyvec(VF_MIN);
1061         vid_width = vf_size.x;
1062         vid_height = vf_size.y;
1063
1064         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1065         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1066
1067         WaypointSprite_Load();
1068
1069         CSQCPlayer_SetCamera();
1070
1071         if(player_localentnum <= maxclients) // is it a client?
1072                 current_player = player_localentnum - 1;
1073         else // then player_localentnum is the vehicle I'm driving
1074                 current_player = player_localnum;
1075         myteam = GetPlayerColor(current_player);
1076
1077         if(myteam != prev_myteam)
1078         {
1079                 myteamcolors = colormapPaletteColor(myteam, 1);
1080                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1081                 prev_myteam = myteam;
1082         }
1083
1084         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1085
1086         float is_dead = (getstati(STAT_HEALTH) <= 0);
1087
1088         // FIXME do we need this hack?
1089         if(isdemo())
1090         {
1091                 // in demos, input_buttons do not work
1092                 button_zoom = (autocvar__togglezoom == "-");
1093         }
1094         else if(button_zoom
1095                 && autocvar_cl_unpress_zoom_on_death
1096                 && (spectatee_status >= 0)
1097                 && (is_dead || intermission))
1098         {
1099                 // no zoom while dead or in intermission please
1100                 localcmd("-zoom\n");
1101                 button_zoom = false;
1102         }
1103
1104         // event chase camera
1105         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1106         {
1107                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1108                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1109                 entity gen = world;
1110
1111                 if(ons_roundlost)
1112                 {
1113                         entity e;
1114                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1115                         {
1116                                 if(e.health <= 0)
1117                                 {
1118                                         gen = e;
1119                                         break;
1120                                 }
1121                         }
1122                         if(!gen)
1123                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1124                 }
1125                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1126                 {
1127                         eventchase_running = true;
1128
1129                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1130                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1131                         if(ons_roundlost) { current_view_origin = gen.origin; }
1132
1133                         // detect maximum viewoffset and use it
1134                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1135                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1136                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1137
1138                         if(view_offset)
1139                         {
1140                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1141                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1142                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1143                         }
1144
1145                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1146                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1147                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1148                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1149
1150                         // make the camera smooth back
1151                         float chase_distance = autocvar_cl_eventchase_distance;
1152                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1153                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1154
1155                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1156                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1157                         else if(eventchase_current_distance != chase_distance)
1158                                 eventchase_current_distance = chase_distance;
1159
1160                         makevectors(view_angles);
1161
1162                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1163                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1164
1165                         // If the boxtrace fails, revert back to line tracing.
1166                         if(!self.viewloc)
1167                         if(trace_startsolid)
1168                         {
1169                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1170                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1171                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1172                         }
1173                         else { setproperty(VF_ORIGIN, trace_endpos); }
1174
1175                         if(!self.viewloc)
1176                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1177                 }
1178                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1179                 {
1180                         eventchase_running = false;
1181                         cvar_set("chase_active", "0");
1182                         eventchase_current_distance = 0; // start from 0 next time
1183                 }
1184         }
1185         // workaround for camera stuck between player's legs when using chase_active 1
1186         // because the engine stops updating the chase_active camera when the game ends
1187         else if(intermission)
1188         {
1189                 cvar_settemp("chase_active", "-1");
1190                 eventchase_current_distance = 0;
1191         }
1192
1193         // do lockview after event chase camera so that it still applies whenever necessary.
1194         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1195         {
1196                 setproperty(VF_ORIGIN, freeze_org);
1197                 setproperty(VF_ANGLES, freeze_ang);
1198         }
1199         else
1200         {
1201                 freeze_org = getpropertyvec(VF_ORIGIN);
1202                 freeze_ang = getpropertyvec(VF_ANGLES);
1203         }
1204
1205         WarpZone_FixView();
1206         //WarpZone_FixPMove();
1207
1208         vector ov_org = '0 0 0';
1209         vector ov_mid = '0 0 0';
1210         vector ov_worldmin = '0 0 0';
1211         vector ov_worldmax = '0 0 0';
1212         if(autocvar_cl_orthoview)
1213         {
1214                 ov_worldmin = mi_picmin;
1215                 ov_worldmax = mi_picmax;
1216
1217                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1218                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1219                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1220
1221                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1222                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1223
1224                 float ov_nearest = vlen(ov_org - vec3(
1225                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1226                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1227                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1228                 ));
1229
1230                 float ov_furthest = 0;
1231                 float dist = 0;
1232
1233                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1234                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1235                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1236                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1237                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1238                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1239                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1240                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1241
1242                 if(!ov_enabled)
1243                 {
1244                         oldr_nearclip = cvar("r_nearclip");
1245                         oldr_farclip_base = cvar("r_farclip_base");
1246                         oldr_farclip_world = cvar("r_farclip_world");
1247                         oldr_novis = cvar("r_novis");
1248                         oldr_useportalculling = cvar("r_useportalculling");
1249                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1250                 }
1251
1252                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1253                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1254                 cvar_settemp("r_farclip_world", "0");
1255                 cvar_settemp("r_novis", "1");
1256                 cvar_settemp("r_useportalculling", "0");
1257                 cvar_settemp("r_useinfinitefarclip", "0");
1258
1259                 setproperty(VF_ORIGIN, ov_org);
1260                 setproperty(VF_ANGLES, '90 0 0');
1261
1262                 ov_enabled = true;
1263
1264                 #if 0
1265                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1266                         vtos(ov_org),
1267                         vtos(getpropertyvec(VF_ANGLES)),
1268                         ov_distance,
1269                         ov_nearest,
1270                         ov_furthest);
1271                 #endif
1272         }
1273         else
1274         {
1275                 if(ov_enabled)
1276                 {
1277                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1278                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1279                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1280                         cvar_set("r_novis", ftos(oldr_novis));
1281                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1282                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1283                 }
1284                 ov_enabled = false;
1285         }
1286
1287         // Render the Scene
1288         view_origin = getpropertyvec(VF_ORIGIN);
1289         view_angles = getpropertyvec(VF_ANGLES);
1290         makevectors(view_angles);
1291         view_forward = v_forward;
1292         view_right = v_right;
1293         view_up = v_up;
1294
1295 #ifdef BLURTEST
1296         if(time > blurtest_time0 && time < blurtest_time1)
1297         {
1298                 float r, t;
1299
1300                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1301                 r = t * blurtest_radius;
1302                 f = 1 / pow(t, blurtest_power) - 1;
1303
1304                 cvar_set("r_glsl_postprocess", "1");
1305                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1306         }
1307         else
1308         {
1309                 cvar_set("r_glsl_postprocess", "0");
1310                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1311         }
1312 #endif
1313
1314         TargetMusic_Advance();
1315         Fog_Force();
1316
1317         if(drawtime == 0)
1318                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1319         else
1320                 drawframetime = bound(0.000001, time - drawtime, 1);
1321         drawtime = time;
1322
1323         // watch for gametype changes here...
1324         // in ParseStuffCMD the cmd isn't executed yet :/
1325         // might even be better to add the gametype to TE_CSQC_INIT...?
1326         if(!postinit)
1327                 PostInit();
1328
1329         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1330         {
1331                 if(calledhooks & HOOK_START)
1332                 {
1333                         localcmd("\ncl_hook_gameend\n");
1334                         calledhooks |= HOOK_END;
1335                 }
1336         }
1337
1338         Announcer();
1339
1340         fov = autocvar_fov;
1341         if(fov <= 59.5)
1342         {
1343                 if(!zoomscript_caught)
1344                 {
1345                         localcmd("+button9\n");
1346                         zoomscript_caught = 1;
1347                 }
1348         }
1349         else
1350         {
1351                 if(zoomscript_caught)
1352                 {
1353                         localcmd("-button9\n");
1354                         zoomscript_caught = 0;
1355                 }
1356         }
1357
1358         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1359
1360         // next WANTED weapon (for HUD)
1361         switchweapon = getstati(STAT_SWITCHWEAPON);
1362
1363         // currently switching-to weapon (for crosshair)
1364         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1365
1366         // actually active weapon (for zoom)
1367         activeweapon = getstati(STAT_ACTIVEWEAPON);
1368
1369         f = (serverflags & SERVERFLAG_TEAMPLAY);
1370         if(f != teamplay)
1371         {
1372                 teamplay = f;
1373                 HUD_InitScores();
1374         }
1375
1376         if(last_switchweapon != switchweapon)
1377         {
1378                 weapontime = time;
1379                 last_switchweapon = switchweapon;
1380                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1381                 {
1382                         localcmd("-zoom\n");
1383                         button_zoom = false;
1384                 }
1385                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1386                 {
1387                         localcmd("-fire\n");
1388                         localcmd("-fire2\n");
1389                         button_attack2 = false;
1390                 }
1391         }
1392         if(last_activeweapon != activeweapon)
1393         {
1394                 last_activeweapon = activeweapon;
1395
1396                 e = get_weaponinfo(activeweapon);
1397                 if(e.netname != "")
1398                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1399                 else
1400                         localcmd("\ncl_hook_activeweapon none\n");
1401         }
1402
1403         // ALWAYS Clear Current Scene First
1404         clearscene();
1405
1406         setproperty(VF_ORIGIN, view_origin);
1407         setproperty(VF_ANGLES, view_angles);
1408
1409         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1410         setproperty(VF_SIZE, vf_size);
1411         setproperty(VF_MIN, vf_min);
1412
1413         // Assign Standard Viewflags
1414         // Draw the World (and sky)
1415         setproperty(VF_DRAWWORLD, 1);
1416
1417         // Set the console size vars
1418         vid_conwidth = autocvar_vid_conwidth;
1419         vid_conheight = autocvar_vid_conheight;
1420         vid_pixelheight = autocvar_vid_pixelheight;
1421
1422         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1423         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1424         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1425
1426         // Camera for demo playback
1427         if(camera_active)
1428         {
1429                 if(autocvar_camera_enable)
1430                         CSQC_Demo_Camera();
1431                 else
1432                 {
1433                         cvar_set("chase_active", ftos(chase_active_backup));
1434                         cvar_set("cl_demo_mousegrab", "0");
1435                         camera_active = false;
1436                 }
1437         }
1438         else
1439         {
1440 #ifdef CAMERATEST
1441                 if(autocvar_camera_enable)
1442 #else
1443                 if(autocvar_camera_enable && isdemo())
1444 #endif
1445                 {
1446                         // Enable required Darkplaces cvars
1447                         chase_active_backup = autocvar_chase_active;
1448                         cvar_set("chase_active", "2");
1449                         cvar_set("cl_demo_mousegrab", "1");
1450                         camera_active = true;
1451                         camera_mode = false;
1452                 }
1453         }
1454
1455         // Draw the Crosshair
1456         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1457
1458         // Draw the Engine Status Bar (the default Quake HUD)
1459         setproperty(VF_DRAWENGINESBAR, 0);
1460
1461         // Update the mouse position
1462         /*
1463            mousepos_x = vid_conwidth;
1464            mousepos_y = vid_conheight;
1465            mousepos = mousepos*0.5 + getmousepos();
1466          */
1467
1468         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1469                 WITH(entity, self, e, e.draw(e));
1470         }
1471
1472         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1473         renderscene();
1474
1475         // now switch to 2D drawing mode by calling a 2D drawing function
1476         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1477         // next R_RenderScene call
1478         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1479
1480         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1481         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1482         {
1483                 // apply night vision effect
1484                 vector tc_00, tc_01, tc_10, tc_11;
1485                 vector rgb = '0 0 0';
1486
1487                 if(!nightvision_noise)
1488                 {
1489                         nightvision_noise = spawn();
1490                         nightvision_noise.classname = "nightvision_noise";
1491                 }
1492                 if(!nightvision_noise2)
1493                 {
1494                         nightvision_noise2 = spawn();
1495                         nightvision_noise2.classname = "nightvision_noise2";
1496                 }
1497
1498                 // color tint in yellow
1499                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1500
1501                 // draw BG
1502                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1503                 rgb = '1 1 1';
1504                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1505                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1506                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1507                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1508                 tc_11 = tc_01 + tc_10 - tc_00;
1509                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1510                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1511                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1512                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1513                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1514                 R_EndPolygon();
1515
1516                 // draw FG
1517                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1518                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1519                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1520                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1521                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1522                 tc_11 = tc_01 + tc_10 - tc_00;
1523                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1524                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1525                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1526                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1527                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1528                 R_EndPolygon();
1529         }
1530
1531         if(autocvar_cl_reticle)
1532         {
1533                 Weapon wep = get_weaponinfo(activeweapon);
1534                 // Draw the aiming reticle for weapons that use it
1535                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1536                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1537                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1538                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1539                 {
1540                         // no zoom reticle while dead
1541                         reticle_type = 0;
1542                 }
1543                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1544                 {
1545                         if(reticle_image != "") { reticle_type = 2; }
1546                         else { reticle_type = 0; }
1547                 }
1548                 else if(button_zoom || zoomscript_caught)
1549                 {
1550                         // normal zoom
1551                         reticle_type = 1;
1552                 }
1553
1554                 if(reticle_type)
1555                 {
1556                         if(autocvar_cl_reticle_stretch)
1557                         {
1558                                 reticle_size.x = vid_conwidth;
1559                                 reticle_size.y = vid_conheight;
1560                                 reticle_pos.x = 0;
1561                                 reticle_pos.y = 0;
1562                         }
1563                         else
1564                         {
1565                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1566                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1567                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1568                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1569                         }
1570
1571                         if(zoomscript_caught)
1572                                 f = 1;
1573                         else
1574                                 f = current_zoomfraction;
1575
1576                         if(f)
1577                         {
1578                                 switch(reticle_type)
1579                                 {
1580                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1581                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1582                                 }
1583                         }
1584                 }
1585         }
1586         else
1587         {
1588                 if(reticle_type != 0) { reticle_type = 0; }
1589         }
1590
1591
1592         // improved polyblend
1593         if(autocvar_hud_contents)
1594         {
1595                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1596                 vector liquidcolor;
1597
1598                 switch(pointcontents(view_origin))
1599                 {
1600                         case CONTENT_WATER:
1601                                 liquidalpha = autocvar_hud_contents_water_alpha;
1602                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1603                                 incontent = 1;
1604                                 break;
1605
1606                         case CONTENT_LAVA:
1607                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1608                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1609                                 incontent = 1;
1610                                 break;
1611
1612                         case CONTENT_SLIME:
1613                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1614                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1615                                 incontent = 1;
1616                                 break;
1617
1618                         default:
1619                                 liquidalpha = 0;
1620                                 liquidcolor = '0 0 0';
1621                                 incontent = 0;
1622                                 break;
1623                 }
1624
1625                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1626                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1627                         contentfadetime = autocvar_hud_contents_fadeintime;
1628                         liquidalpha_prev = liquidalpha;
1629                         liquidcolor_prev = liquidcolor;
1630                 }
1631                 else
1632                         contentfadetime = autocvar_hud_contents_fadeouttime;
1633
1634                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1635                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1636
1637                 if(contentavgalpha)
1638                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1639
1640                 if(autocvar_hud_postprocessing)
1641                 {
1642                         if(autocvar_hud_contents_blur && contentavgalpha)
1643                         {
1644                                 content_blurpostprocess.x = 1;
1645                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1646                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1647                         }
1648                         else
1649                         {
1650                                 content_blurpostprocess.x = 0;
1651                                 content_blurpostprocess.y = 0;
1652                                 content_blurpostprocess.z = 0;
1653                         }
1654                 }
1655         }
1656
1657         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1658         {
1659                 splash_size.x = max(vid_conwidth, vid_conheight);
1660                 splash_size.y = max(vid_conwidth, vid_conheight);
1661                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1662                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1663
1664                 float myhealth_flash_temp;
1665                 myhealth = getstati(STAT_HEALTH);
1666
1667                 // fade out
1668                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1669                 // add new damage
1670                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1671
1672                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1673                 pain_threshold = autocvar_hud_damage_pain_threshold;
1674                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1675                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1676
1677                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1678                 {
1679                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1680                 }
1681
1682                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1683
1684                 if(myhealth_prev < 1)
1685                 {
1686                         if(myhealth >= 1)
1687                         {
1688                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1689                                 myhealth_flash_temp = 0;
1690                         }
1691                         else
1692                         {
1693                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1694                         }
1695                 }
1696
1697                 if(spectatee_status == -1 || intermission)
1698                 {
1699                         myhealth_flash = 0; // observing, or match ended
1700                         myhealth_flash_temp = 0;
1701                 }
1702
1703                 myhealth_prev = myhealth;
1704
1705                 // IDEA: change damage color/picture based on player model for robot/alien species?
1706                 // pro: matches model better
1707                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1708                 // maybe different reddish pics?
1709                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1710                 {
1711                         if(autocvar_cl_gentle_damage == 2)
1712                         {
1713                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1714                                 {
1715                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1716                                 }
1717                         }
1718                         else
1719                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1720
1721                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1722                 }
1723                 else
1724                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1725
1726                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1727                 {
1728                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1729                         {
1730                                 damage_blurpostprocess.x = 1;
1731                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1732                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1733                         }
1734                         else
1735                         {
1736                                 damage_blurpostprocess.x = 0;
1737                                 damage_blurpostprocess.y = 0;
1738                                 damage_blurpostprocess.z = 0;
1739                         }
1740                 }
1741         }
1742
1743         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1744         float e2 = (autocvar_hud_powerup != 0);
1745         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1746         {
1747                 // enable or disable rendering types if they are used or not
1748                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1749                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1750
1751                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1752                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1753                 {
1754                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1755                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1756                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1757                         {
1758                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1759                                 old_blurradius = blurradius;
1760                                 old_bluralpha = bluralpha;
1761                         }
1762                 }
1763                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1764                 {
1765                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1766                         old_blurradius = 0;
1767                         old_bluralpha = 0;
1768                 }
1769
1770                 // edge detection postprocess handling done second (used by hud_powerup)
1771                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1772                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1773                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1774
1775                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1776
1777                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1778                 {
1779                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1780                         {
1781                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1782                                 old_sharpen_intensity = sharpen_intensity;
1783                         }
1784                 }
1785                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1786                 {
1787                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1788                         old_sharpen_intensity = 0;
1789                 }
1790
1791                 if(cvar("r_glsl_postprocess") == 0)
1792                         cvar_set("r_glsl_postprocess", "2");
1793         }
1794         else if(cvar("r_glsl_postprocess") == 2)
1795                 cvar_set("r_glsl_postprocess", "0");
1796
1797         if(menu_visible)
1798                 menu_show();
1799
1800         /*if(gametype == MAPINFO_TYPE_CTF)
1801           {
1802           ctf_view();
1803           } else */
1804
1805         // draw 2D entities
1806         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1807                 WITH(entity, self, e, e.draw2d(e));
1808         }
1809         Draw_ShowNames_All();
1810
1811         scoreboard_active = HUD_WouldDrawScoreboard();
1812
1813         UpdateDamage();
1814         UpdateCrosshair();
1815         UpdateHitsound();
1816
1817         if(NextFrameCommand)
1818         {
1819                 localcmd("\n", NextFrameCommand, "\n");
1820                 NextFrameCommand = string_null;
1821         }
1822
1823         // we must do this check AFTER a frame was rendered, or it won't work
1824         if(cs_project_is_b0rked == 0)
1825         {
1826                 string w0, h0;
1827                 w0 = ftos(autocvar_vid_conwidth);
1828                 h0 = ftos(autocvar_vid_conheight);
1829                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1830                 //setproperty(VF_FOV, '90 90 0');
1831                 setproperty(VF_ORIGIN, '0 0 0');
1832                 setproperty(VF_ANGLES, '0 0 0');
1833                 setproperty(VF_PERSPECTIVE, 1);
1834                 makevectors('0 0 0');
1835                 vector v1, v2;
1836                 cvar_set("vid_conwidth", "800");
1837                 cvar_set("vid_conheight", "600");
1838                 v1 = cs_project(v_forward);
1839                 cvar_set("vid_conwidth", "640");
1840                 cvar_set("vid_conheight", "480");
1841                 v2 = cs_project(v_forward);
1842                 if(v1 == v2)
1843                         cs_project_is_b0rked = 1;
1844                 else
1845                         cs_project_is_b0rked = -1;
1846                 cvar_set("vid_conwidth", w0);
1847                 cvar_set("vid_conheight", h0);
1848         }
1849
1850         if(autocvar__hud_configure)
1851                 HUD_Panel_Mouse();
1852         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1853                 HUD_Minigame_Mouse();
1854         else if(QuickMenu_IsOpened())
1855                 QuickMenu_Mouse();
1856         else
1857                 HUD_Radar_Mouse();
1858
1859     if(hud && !intermission)
1860     if(hud == HUD_BUMBLEBEE_GUN)
1861         CSQC_BUMBLE_GUN_HUD();
1862     else {
1863         Vehicle info = get_vehicleinfo(hud);
1864                 info.vr_hud(info);
1865         }
1866
1867         cl_notice_run();
1868
1869         // let's reset the view back to normal for the end
1870         setproperty(VF_MIN, '0 0 0');
1871         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1872 }
1873
1874
1875 void CSQC_common_hud(void)
1876 {
1877         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1878                 Accuracy_LoadLevels();
1879
1880         HUD_Main(); // always run these functions for alpha checks
1881         HUD_DrawScoreboard();
1882
1883         // scoreboard/accuracy, map/gametype voting screen
1884         if (scoreboard_active || intermission == 2)
1885                 HUD_Reset();
1886 }
1887
1888
1889 // following vectors must be global to allow seamless switching between camera modes
1890 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1891 void CSQC_Demo_Camera()
1892 {
1893         float speed, attenuation, dimensions;
1894         vector tmp, delta;
1895
1896         if( autocvar_camera_reset || !camera_mode )
1897         {
1898                 camera_offset = '0 0 0';
1899                 current_angles = '0 0 0';
1900                 camera_direction = '0 0 0';
1901                 camera_offset.z += 30;
1902                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1903                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1904                 current_origin = view_origin;
1905                 current_camera_offset  = camera_offset;
1906                 cvar_set("camera_reset", "0");
1907                 camera_mode = CAMERA_CHASE;
1908         }
1909
1910         // Camera angles
1911         if( camera_roll )
1912                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1913
1914         if(autocvar_camera_look_player)
1915         {
1916                 vector dir;
1917                 float n;
1918
1919                 dir = normalize(view_origin - current_position);
1920                 n = mouse_angles.z;
1921                 mouse_angles = vectoangles(dir);
1922                 mouse_angles.x = mouse_angles.x * -1;
1923                 mouse_angles.z = n;
1924         }
1925         else
1926         {
1927                 tmp = getmousepos() * 0.1;
1928                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1929                 {
1930                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1931                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1932                 }
1933         }
1934
1935         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1936         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1937         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1938         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1939
1940         // Fix difference when angles don't have the same sign
1941         delta = '0 0 0';
1942         if(mouse_angles.y < -60 && current_angles.y > 60)
1943                 delta = '0 360 0';
1944         if(mouse_angles.y > 60 && current_angles.y < -60)
1945                 delta = '0 -360 0';
1946
1947         if(autocvar_camera_look_player)
1948                 attenuation = autocvar_camera_look_attenuation;
1949         else
1950                 attenuation = autocvar_camera_speed_attenuation;
1951
1952         attenuation = 1 / max(1, attenuation);
1953         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1954
1955         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1956         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1957         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1958         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1959
1960         // Camera position
1961         tmp = '0 0 0';
1962         dimensions = 0;
1963
1964         if( camera_direction.x )
1965         {
1966                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1967                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1968                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1969                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1970                 ++dimensions;
1971         }
1972
1973         if( camera_direction.y )
1974         {
1975                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1976                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1977                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1978                 ++dimensions;
1979         }
1980
1981         if( camera_direction.z )
1982         {
1983                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1984                 ++dimensions;
1985         }
1986
1987         if(autocvar_camera_free)
1988                 speed = autocvar_camera_speed_free;
1989         else
1990                 speed = autocvar_camera_speed_chase;
1991
1992         if(dimensions)
1993         {
1994                 speed = speed * sqrt(1 / dimensions);
1995                 camera_offset += tmp * speed;
1996         }
1997
1998         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1999
2000         // Camera modes
2001         if( autocvar_camera_free )
2002         {
2003                 if ( camera_mode == CAMERA_CHASE )
2004                 {
2005                         current_camera_offset = current_origin + current_camera_offset;
2006                         camera_offset = current_origin + camera_offset;
2007                 }
2008
2009                 camera_mode = CAMERA_FREE;
2010                 current_position = current_camera_offset;
2011         }
2012         else
2013         {
2014                 if ( camera_mode == CAMERA_FREE )
2015                 {
2016                         current_origin = view_origin;
2017                         camera_offset = camera_offset - current_origin;
2018                         current_camera_offset = current_camera_offset - current_origin;
2019                 }
2020
2021                 camera_mode = CAMERA_CHASE;
2022
2023                 if(autocvar_camera_chase_smoothly)
2024                         current_origin += (view_origin - current_origin) * attenuation;
2025                 else
2026                         current_origin = view_origin;
2027
2028                 current_position = current_origin + current_camera_offset;
2029         }
2030
2031         setproperty(VF_ANGLES, current_angles);
2032         setproperty(VF_ORIGIN, current_position);
2033 }