qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79 { \
  80         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  81         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  82 } MACRO_END
  83
  84 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  85 { \
  86         float __f = 0; lowpass(value, frac, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } MACRO_END
  89
  90 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  91 { \
  92         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  93         ret = (value) - __f; \
  94 } MACRO_END
  95
  96 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97 { \
  98         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  99         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 100 } MACRO_END
 101
 102 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 103 { \
 104         highpass(value.x, frac, ref_store.x, ref_out.x); \
 105         highpass(value.y, frac, ref_store.y, ref_out.y); \
 106 } MACRO_END
 107
 108 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 109 { \
 110         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 111         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 112 } MACRO_END
 113
 114 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 117         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 118         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 122 { \
 123         highpass(value.x, frac, ref_store.x, ref_out.x); \
 124         highpass(value.y, frac, ref_store.y, ref_out.y); \
 125         highpass(value.z, frac, ref_store.z, ref_out.z); \
 126 } MACRO_END
 127
 128 void calc_followmodel_ofs(entity view)
 129 {
 130         if(cl_followmodel_time == time)
 131                 return; // cl_followmodel_ofs already calculated for this frame
 132
 133         float frac;
 134         vector gunorg = '0 0 0';
 135         static vector vel_average;
 136         static vector gunorg_adjustment_highpass;
 137         static vector gunorg_adjustment_lowpass;
 138
 139         vector vel;
 140         if (autocvar_cl_followmodel_velocity_absolute)
 141                 vel = view.velocity;
 142         else
 143         {
 144                 MAKE_VECTORS_NEW(view_angles, forward, right, up);
 145                 vel.x = view.velocity * forward;
 146                 vel.y = view.velocity * right * -1;
 147                 vel.z = view.velocity * up;
 148         }
 149
 150         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 151         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 152         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 153
 154         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 155         lowpass3(vel, frac, vel_average, gunorg);
 156
 157         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 158
 159         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 160         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 161         frac = avg_factor(autocvar_cl_followmodel_highpass);
 162         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 163         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 164         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 165
 166         if (autocvar_cl_followmodel_velocity_absolute)
 167         {
 168                 vector fixed_gunorg;
 169                 MAKE_VECTORS_NEW(view_angles, forward, right, up);
 170                 fixed_gunorg.x = gunorg * forward;
 171                 fixed_gunorg.y = gunorg * right * -1;
 172                 fixed_gunorg.z = gunorg * up;
 173                 gunorg = fixed_gunorg;
 174         }
 175
 176         cl_followmodel_ofs = gunorg;
 177         cl_followmodel_time = time;
 178 }
 179
 180 vector leanmodel_ofs(entity view)
 181 {
 182         float frac;
 183         vector gunangles = '0 0 0';
 184         static vector gunangles_prev = '0 0 0';
 185         static vector gunangles_highpass = '0 0 0';
 186         static vector gunangles_adjustment_highpass;
 187         static vector gunangles_adjustment_lowpass;
 188
 189         if (view.csqcmodel_teleported)
 190                 gunangles_prev = view_angles;
 191
 192         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 193         gunangles_highpass += gunangles_prev;
 194         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 195         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 196         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 197         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 198         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 199         gunangles_prev = view_angles;
 200         gunangles_highpass -= gunangles_prev;
 201
 202         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 203         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 204
 205         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 206         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 207         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 208         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 209         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 210
 211         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 212
 213         return gunangles;
 214 }
 215
 216 vector bobmodel_ofs(entity view)
 217 {
 218         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 219         static bool oldonground;
 220         static float hitgroundtime;
 221         if (clonground)
 222         {
 223                 float f = time; // cl.movecmd[0].time
 224                 if (!oldonground)
 225                         hitgroundtime = f;
 226         }
 227         oldonground = clonground;
 228
 229         // calculate for swinging gun model
 230         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 231         vector gunorg = '0 0 0';
 232         static float bobmodel_scale = 0;
 233         static float time_ofs = 0; // makes the effect always restart in the same way
 234         if (clonground)
 235         {
 236                 if (time - hitgroundtime > 0.05)
 237                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 238         }
 239         else
 240                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 241
 242         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 243         if (bobmodel_scale && xyspeed)
 244         {
 245                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 246                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 247                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 248                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 249         }
 250         else
 251                 time_ofs = time;
 252
 253         return gunorg;
 254 }
 255
 256 void viewmodel_animate(entity this)
 257 {
 258         if (autocvar_chase_active) return;
 259         if (STAT(HEALTH) <= 0) return;
 260
 261         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 262
 263         if (autocvar_cl_followmodel)
 264         {
 265                 calc_followmodel_ofs(view);
 266                 this.origin += cl_followmodel_ofs;
 267         }
 268
 269         if (autocvar_cl_leanmodel)
 270                 this.angles += leanmodel_ofs(view);
 271
 272         // vertical view bobbing code
 273         // TODO: cl_bob
 274
 275         // horizontal view bobbing code
 276         // TODO: cl_bob2
 277
 278         // fall bobbing code
 279         // causes the view to swing down and back up when touching the ground
 280         // TODO: cl_bobfall
 281
 282         // gun model bobbing code
 283         if (autocvar_cl_bobmodel)
 284                 this.origin += bobmodel_ofs(view);
 285 }
 286
 287 .vector viewmodel_origin, viewmodel_angles;
 288 .float weapon_nextthink;
 289 .float weapon_eta_last;
 290 .float weapon_switchdelay;
 291
 292 .string name_last;
 293
 294 void viewmodel_draw(entity this)
 295 {
 296         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 297                 return;
 298         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 299         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 300         bool invehicle = player_localentnum > maxclients;
 301         if (invehicle) a = -1;
 302         Weapon wep = this.activeweapon;
 303         int c = entcs_GetClientColors(current_player);
 304         vector g = weaponentity_glowmod(wep, NULL, c, this);
 305         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 306         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 307                 | EF_NODEPTHTEST)
 308                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 309         for (entity e = this; e; e = e.weaponchild)
 310         {
 311                 e.drawmask = mask;
 312                 e.alpha = a;
 313                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 314                 e.glowmod = g;
 315                 e.csqcmodel_effects = fx;
 316                 CSQCModel_Effects_Apply(e);
 317         }
 318         if(a >= 0)
 319         {
 320                 string name = wep.mdl;
 321                 string newname = wep.wr_viewmodel(wep, this);
 322                 if(newname)
 323                         name = newname;
 324                 bool swap = name != this.name_last;
 325                 // if (swap)
 326                 {
 327                         this.name_last = name;
 328                         CL_WeaponEntity_SetModel(this, name, swap);
 329                         this.viewmodel_origin = this.origin;
 330                         this.viewmodel_angles = this.angles;
 331                 }
 332                 anim_update(this);
 333                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 334                         anim_set(this, this.anim_idle, true, false, false);
 335         }
 336         float f = 0; // 0..1; 0: fully active
 337         float rate = STAT(WEAPONRATEFACTOR);
 338         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 339         if (eta <= 0) f = this.weapon_eta_last;
 340         else switch (this.state)
 341         {
 342                 case WS_RAISE:
 343                 {
 344                         f = eta / max(eta, this.weapon_switchdelay);
 345                         break;
 346                 }
 347                 case WS_DROP:
 348                 {
 349                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 350                         break;
 351                 }
 352                 case WS_CLEAR:
 353                 {
 354                         f = 1;
 355                         break;
 356                 }
 357         }
 358         this.weapon_eta_last = f;
 359         this.origin = this.viewmodel_origin;
 360         this.angles = this.viewmodel_angles;
 361         this.angles_x = (-90 * f * f);
 362         viewmodel_animate(this);
 363         MUTATOR_CALLHOOK(DrawViewModel, this);
 364         setorigin(this, this.origin);
 365 }
 366
 367 STATIC_INIT(viewmodel) {
 368     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 369         viewmodels[slot] = new(viewmodel);
 370 }
 371
 372 float showfps_prevfps;
 373 float showfps_prevfps_time;
 374 int showfps_framecounter;
 375
 376 void fpscounter_update()
 377 {
 378         if(!STAT(SHOWFPS))
 379                 return;
 380
 381         float currentTime = gettime(GETTIME_REALTIME);
 382         showfps_framecounter += 1;
 383         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 384         {
 385                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 386                 showfps_framecounter = 0;
 387                 showfps_prevfps_time = currentTime;
 388
 389                 int channel = MSG_C2S;
 390                 WriteHeader(channel, fpsreport);
 391                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 392         }
 393 }
 394
 395 STATIC_INIT(fpscounter_init)
 396 {
 397         float currentTime = gettime(GETTIME_REALTIME);
 398         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 399 }
 400
 401 STATIC_INIT(Porto)
 402 {
 403         entity e = new_pure(porto);
 404         e.draw = Porto_Draw;
 405         IL_PUSH(g_drawables, e);
 406         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 407 }
 408
 409 const int polyline_length = 16;
 410 .vector polyline[polyline_length];
 411 void Porto_Draw(entity this)
 412 {
 413         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 414         {
 415                 entity wepent = viewmodels[slot];
 416
 417                 if (wepent.activeweapon != WEP_PORTO) continue;
 418                 if (spectatee_status) continue;
 419                 if (WEP_CVAR(porto, secondary)) continue;
 420                 if (intermission == 1) continue;
 421                 if (intermission == 2) continue;
 422                 if (STAT(HEALTH) <= 0) continue;
 423
 424                 vector pos = view_origin;
 425                 vector dir = view_forward;
 426                 MAKE_VECTORS_NEW(autocvar_chase_active ? warpzone_save_view_angles : view_angles, forward, right, up);
 427                 pos += right * -wepent.movedir.y
 428                         +  up * wepent.movedir.z;
 429
 430                 if (wepent.angles_held_status)
 431                 {
 432                         MAKE_VECTORS(wepent.angles_held, forward, right, up);
 433                         dir = forward;
 434                 }
 435
 436                 wepent.polyline[0] = pos;
 437
 438                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 439                 int n = 1 + 2;  // 2 lines == 3 points
 440                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 441                 {
 442                         traceline(pos, pos + 65536 * dir, true, this);
 443                         dir = reflect(dir, trace_plane_normal);
 444                         pos = trace_endpos;
 445                         wepent.polyline[++idx] = pos;
 446                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 447                         {
 448                                 n += 1;
 449                                 continue;
 450                         }
 451                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 452                         {
 453                                 n = max(2, idx);
 454                                 break;
 455                         }
 456                         // check size
 457                         {
 458                                 vector ang = vectoangles2(trace_plane_normal, dir);
 459                                 ang.x = -ang.x;
 460                                 MAKE_VECTORS(ang, forward, right, up);
 461                                 if (!CheckWireframeBox(this, pos - 48 * right - 48 * up + 16 * forward, 96 * right, 96 * up, 96 * forward))
 462                                 {
 463                                         n = max(2, idx);
 464                                         break;
 465                                 }
 466                         }
 467                         portal_number += 1;
 468                         if (portal_number >= portal_max) break;
 469                         if (portal_number == 1) portal1_idx = idx;
 470                 }
 471                 for (int idx = 0; idx < n - 1; ++idx)
 472                 {
 473                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 474                         if (idx == 0) p -= view_up * 16;  // line from player
 475                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 476                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 477                 }
 478         }
 479 }
 480
 481 float drawtime;
 482 float avgspeed;
 483 vector GetCurrentFov(float fov)
 484 {
 485         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 486         float velocityzoom, curspeed;
 487         vector v;
 488
 489         zoomsensitivity = autocvar_cl_zoomsensitivity;
 490         zoomfactor = autocvar_cl_zoomfactor;
 491         if(zoomfactor < 1 || zoomfactor > 30)
 492                 zoomfactor = 2.5;
 493         zoomspeed = autocvar_cl_zoomspeed;
 494         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 495                 zoomspeed = 3.5;
 496
 497         zoomdir = button_zoom;
 498
 499         if(hud == HUD_NORMAL && !spectatee_status)
 500         {
 501                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 502                 {
 503                         entity wepent = viewmodels[slot];
 504                         if(wepent.switchweapon != wepent.activeweapon)
 505                                 continue;
 506                         Weapon wep = wepent.activeweapon;
 507                         if(wep != WEP_Null && wep.wr_zoomdir)
 508                         {
 509                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 510                                 zoomdir += do_zoom;
 511                         }
 512                 }
 513         }
 514         if(spectatee_status > 0 || isdemo())
 515         {
 516                 if(spectatorbutton_zoom)
 517                 {
 518                         if(zoomdir)
 519                                 zoomdir = 0;
 520                         else
 521                                 zoomdir = 1;
 522                 }
 523                 // fteqcc failed twice here already, don't optimize this
 524         }
 525
 526         if(zoomdir) { zoomin_effect = 0; }
 527
 528         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 529         {
 530                 current_viewzoom = 1;
 531         }
 532         else if (camera_active)
 533         {
 534                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 535         }
 536         else if(autocvar_cl_spawnzoom && zoomin_effect)
 537         {
 538                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 539
 540                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 541                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 542                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 543         }
 544         else
 545         {
 546                 if(zoomspeed < 0) // instant zoom
 547                 {
 548                         if(zoomdir)
 549                                 current_viewzoom = 1 / zoomfactor;
 550                         else
 551                                 current_viewzoom = 1;
 552                 }
 553                 else
 554                 {
 555                         if(zoomdir)
 556                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 557                         else
 558                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 559                 }
 560         }
 561
 562         if(almost_equals(current_viewzoom, 1))
 563                 current_zoomfraction = 0;
 564         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 565                 current_zoomfraction = 1;
 566         else
 567                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 568
 569         if(zoomsensitivity < 1)
 570                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 571         else
 572                 setsensitivityscale(1);
 573
 574         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 575         {
 576                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 577                         curspeed = 0;
 578                 else
 579                 {
 580                         MAKE_VECTORS_NEW(view_angles, forward, right, up);
 581                         v = pmove_vel;
 582                         if(csqcplayer)
 583                                 v = csqcplayer.velocity;
 584
 585                         switch(autocvar_cl_velocityzoom_type)
 586                         {
 587                                 case 3: curspeed = max(0, forward * v); break;
 588                                 case 2: curspeed = (forward * v); break;
 589                                 case 1: default: curspeed = vlen(v); break;
 590                         }
 591                 }
 592
 593                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 594                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 595                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 596
 597                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 598         }
 599         else
 600                 velocityzoom = 1;
 601
 602         float frustumx, frustumy, fovx, fovy;
 603         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 604         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 605         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 606         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 607
 608         return '1 0 0' * fovx + '0 1 0' * fovy;
 609 }
 610
 611 vector GetViewLocationFOV(float fov)
 612 {
 613         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 614         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 615         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 616         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 617         return '1 0 0' * fovx + '0 1 0' * fovy;
 618 }
 619
 620 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 621 {
 622         float fovx, fovy;
 623         float width = (ov_worldmax.x - ov_worldmin.x);
 624         float height = (ov_worldmax.y - ov_worldmin.y);
 625         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 626         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 627         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 628         return '1 0 0' * fovx + '0 1 0' * fovy;
 629 }
 630
 631 // this function must match W_SetupShot!
 632 float zoomscript_caught;
 633
 634 bool minigame_wasactive;
 635
 636 vector wcross_origin;
 637 float wcross_scale_prev, wcross_alpha_prev;
 638 vector wcross_color_prev;
 639 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 640 vector wcross_color_goal_prev;
 641 float wcross_changedonetime;
 642
 643 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 644 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 645 float wcross_name_changestarttime, wcross_name_changedonetime;
 646 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 647
 648 float wcross_ring_prev;
 649
 650 entity trueaim;
 651 entity trueaim_rifle;
 652
 653 const float SHOTTYPE_HITTEAM = 1;
 654 const float SHOTTYPE_HITOBSTRUCTION = 2;
 655 const float SHOTTYPE_HITWORLD = 3;
 656 const float SHOTTYPE_HITENEMY = 4;
 657
 658 void TrueAim_Init()
 659 {
 660         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 661         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 662 }
 663
 664 float EnemyHitCheck()
 665 {
 666         float t, n;
 667         wcross_origin = project_3d_to_2d(trace_endpos);
 668         wcross_origin.z = 0;
 669         if(trace_ent)
 670                 n = trace_ent.entnum;
 671         else
 672                 n = trace_networkentity;
 673         if(n < 1)
 674                 return SHOTTYPE_HITWORLD;
 675         if(n > maxclients)
 676                 return SHOTTYPE_HITWORLD;
 677         t = entcs_GetTeam(n - 1);
 678         if(teamplay)
 679                 if(t == myteam)
 680                         return SHOTTYPE_HITTEAM;
 681         if(t == NUM_SPECTATOR)
 682                 return SHOTTYPE_HITWORLD;
 683         return SHOTTYPE_HITENEMY;
 684 }
 685
 686 float TrueAimCheck(entity wepent)
 687 {
 688         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 689         vector vecs, trueaimpoint, w_shotorg;
 690         vector mi, ma, dv;
 691         float shottype;
 692         entity ta;
 693         float mv;
 694
 695         mi = ma = '0 0 0';
 696         ta = trueaim;
 697         mv = MOVE_NOMONSTERS;
 698
 699         switch(wepent.activeweapon) // WEAPONTODO
 700         {
 701                 case WEP_TUBA: // no aim
 702                 case WEP_PORTO: // shoots from eye
 703                 case WEP_NEXBALL: // shoots from eye
 704                 case WEP_HOOK: // no trueaim
 705                 case WEP_MORTAR: // toss curve
 706                         return SHOTTYPE_HITWORLD;
 707                 case WEP_VORTEX:
 708                 case WEP_OVERKILL_NEX:
 709                 case WEP_VAPORIZER:
 710                         mv = MOVE_NORMAL;
 711                         break;
 712                 case WEP_RIFLE:
 713                         ta = trueaim_rifle;
 714                         mv = MOVE_NORMAL;
 715                         if(zoomscript_caught)
 716                         {
 717                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 718                                 return EnemyHitCheck();
 719                         }
 720                         break;
 721                 case WEP_DEVASTATOR: // projectile has a size!
 722                         mi = '-3 -3 -3';
 723                         ma = '3 3 3';
 724                         break;
 725                 case WEP_FIREBALL: // projectile has a size!
 726                         mi = '-16 -16 -16';
 727                         ma = '16 16 16';
 728                         break;
 729                 case WEP_SEEKER: // projectile has a size!
 730                         mi = '-2 -2 -2';
 731                         ma = '2 2 2';
 732                         break;
 733                 case WEP_ELECTRO: // projectile has a size!
 734                         mi = '0 0 -3';
 735                         ma = '0 0 -3';
 736                         break;
 737         }
 738
 739         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 740
 741         vecs = decompressShotOrigin(STAT(SHOTORG));
 742
 743         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 744         trueaimpoint = trace_endpos;
 745
 746         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 747                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 748
 749         if(vecs.x > 0)
 750                 vecs.y = -vecs.y;
 751         else
 752                 vecs = '0 0 0';
 753
 754         dv = view_right * vecs.y + view_up * vecs.z;
 755         w_shotorg = traceorigin + dv;
 756
 757         // now move the vecs forward as much as requested if possible
 758         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 759         w_shotorg = trace_endpos - view_forward * nudge;
 760
 761         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 762         shottype = EnemyHitCheck();
 763         if(shottype != SHOTTYPE_HITWORLD)
 764                 return shottype;
 765
 766 #if 0
 767         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 768         // or rather, I know why, but see no fix
 769         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 770                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 771                 return SHOTTYPE_HITOBSTRUCTION;
 772 #endif
 773
 774         return SHOTTYPE_HITWORLD;
 775 }
 776
 777 float camera_mode;
 778 const float CAMERA_FREE = 1;
 779 const float CAMERA_CHASE = 2;
 780 float reticle_type;
 781 string NextFrameCommand;
 782
 783 vector freeze_org, freeze_ang;
 784 entity nightvision_noise, nightvision_noise2;
 785
 786 const float MAX_TIME_DIFF = 5;
 787 float pickup_crosshair_time, pickup_crosshair_size;
 788 float hitindication_crosshair_size;
 789 float use_vortex_chargepool;
 790
 791 float myhealth, myhealth_prev;
 792 float myhealth_flash;
 793
 794 float old_blurradius, old_bluralpha;
 795 float old_sharpen_intensity;
 796
 797 vector myhealth_gentlergb;
 798
 799 float contentavgalpha, liquidalpha_prev;
 800 vector liquidcolor_prev;
 801
 802 float eventchase_current_distance;
 803 float eventchase_running;
 804 int WantEventchase(entity this)
 805 {
 806         if(autocvar_cl_orthoview)
 807                 return 0;
 808         if(STAT(GAME_STOPPED) || intermission)
 809                 return 1;
 810         if(this.viewloc)
 811                 return 1;
 812         if(spectatee_status >= 0)
 813         {
 814                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 815                         return 1;
 816                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 817                         return 1;
 818                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 819                         return 1;
 820                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 821                 {
 822                         if(autocvar_cl_eventchase_death == 2)
 823                         {
 824                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 825                                 if(this.velocity == '0 0 0' || eventchase_running)
 826                                         return 1;
 827                         }
 828                         else return 1;
 829                 }
 830                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 831                 {
 832                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 833                                 return 1;
 834                         else if (eventchase_running)
 835                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 836                 }
 837         }
 838         return 0;
 839 }
 840
 841 void HUD_Crosshair_Vehicle(entity this)
 842 {
 843         if(hud != HUD_BUMBLEBEE_GUN)
 844         {
 845                 Vehicle info = Vehicles_from(hud);
 846                 info.vr_crosshair(info, this);
 847         }
 848 }
 849
 850 vector damage_blurpostprocess, content_blurpostprocess;
 851
 852 float unaccounted_damage = 0;
 853 void UpdateDamage()
 854 {
 855         // accumulate damage with each stat update
 856         static float damage_total_prev = 0;
 857         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 858         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 859         damage_total_prev = damage_total;
 860
 861         static float damage_dealt_time_prev = 0;
 862         float damage_dealt_time = STAT(HIT_TIME);
 863         if (damage_dealt_time != damage_dealt_time_prev)
 864         {
 865                 unaccounted_damage += unaccounted_damage_new;
 866                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 867         }
 868         damage_dealt_time_prev = damage_dealt_time;
 869
 870         // prevent hitsound when switching spectatee
 871         static float spectatee_status_prev = 0;
 872         if (spectatee_status != spectatee_status_prev)
 873                 unaccounted_damage = 0;
 874         spectatee_status_prev = spectatee_status;
 875 }
 876
 877 void HitSound()
 878 {
 879         // varying sound pitch
 880
 881         bool have_arc = false;
 882         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 883         {
 884                 entity wepent = viewmodels[slot];
 885
 886                 if(wepent.activeweapon == WEP_ARC)
 887                         have_arc = true;
 888         }
 889
 890         static float hitsound_time_prev = 0;
 891         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 892         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 893         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 894         {
 895                 if (autocvar_cl_hitsound && unaccounted_damage)
 896                 {
 897                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 898                         float a = autocvar_cl_hitsound_max_pitch;
 899                         float b = autocvar_cl_hitsound_min_pitch;
 900                         float c = autocvar_cl_hitsound_nom_damage;
 901                         float d = unaccounted_damage;
 902                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 903
 904                         // if sound variation is disabled, set pitch_shift to 1
 905                         if (autocvar_cl_hitsound == 1)
 906                                 pitch_shift = 1;
 907
 908                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 909                         if (autocvar_cl_hitsound == 3)
 910                         {
 911                                 float mirror_value = (a-b)/2 + b;
 912                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 913                         }
 914
 915                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 916
 917                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 918                         // todo: normalize sound pressure levels? seems unnecessary
 919
 920                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 921                 }
 922                 unaccounted_damage = 0;
 923                 hitsound_time_prev = time;
 924         }
 925
 926         static float typehit_time_prev = 0;
 927         float typehit_time = STAT(TYPEHIT_TIME);
 928         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 929         {
 930                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 931                 typehit_time_prev = typehit_time;
 932         }
 933
 934         static float kill_time_prev = 0;
 935         float kill_time = STAT(KILL_TIME);
 936         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 937         {
 938                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 939                 kill_time_prev = kill_time;
 940         }
 941 }
 942
 943 vector crosshair_getcolor(entity this, float health_stat)
 944 {
 945         static float rainbow_last_flicker;
 946         static vector rainbow_prev_color;
 947         vector wcross_color = '0 0 0';
 948         switch(autocvar_crosshair_color_special)
 949         {
 950                 case 1: // crosshair_color_per_weapon
 951                 {
 952                         if(this != WEP_Null && hud == HUD_NORMAL)
 953                         {
 954                                 wcross_color = this.wpcolor;
 955                                 break;
 956                         }
 957                         else { goto normalcolor; }
 958                 }
 959
 960                 case 2: // crosshair_color_by_health
 961                 {
 962                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 963                         float hp = floor(v.x + 1);
 964
 965                         //x = red
 966                         //y = green
 967                         //z = blue
 968
 969                         wcross_color.z = 0;
 970
 971                         if(hp > 200)
 972                         {
 973                                 wcross_color.x = 0;
 974                                 wcross_color.y = 1;
 975                         }
 976                         else if(hp > 150)
 977                         {
 978                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 979                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 980                         }
 981                         else if(hp > 100)
 982                         {
 983                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 984                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 985                                 wcross_color.z = 1 - (hp-100)*0.02;
 986                         }
 987                         else if(hp > 50)
 988                         {
 989                                 wcross_color.x = 1;
 990                                 wcross_color.y = 1;
 991                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 992                         }
 993                         else if(hp > 20)
 994                         {
 995                                 wcross_color.x = 1;
 996                                 wcross_color.y = (hp-20)*90/27/100;
 997                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 998                         }
 999                         else
1000                         {
1001                                 wcross_color.x = 1;
1002                                 wcross_color.y = 0;
1003                         }
1004                         break;
1005                 }
1006
1007                 case 3: // crosshair_color_rainbow
1008                 {
1009                         if(time >= rainbow_last_flicker)
1010                         {
1011                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1012                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1013                         }
1014                         wcross_color = rainbow_prev_color;
1015                         break;
1016                 }
1017 LABEL(normalcolor)
1018                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1019         }
1020
1021         return wcross_color;
1022 }
1023
1024 void HUD_Crosshair(entity this)
1025 {
1026         float f, i, j;
1027         vector v;
1028         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1029                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1030                 !HUD_MinigameMenu_IsOpened() )
1031         {
1032                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1033                         return;
1034
1035                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1036                         return;
1037
1038                 if (hud != HUD_NORMAL)
1039                 {
1040                         HUD_Crosshair_Vehicle(this);
1041                         return;
1042                 }
1043
1044                 string wcross_style;
1045                 float wcross_alpha, wcross_resolution;
1046                 wcross_style = autocvar_crosshair;
1047                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1048                         wcross_style = autocvar_crosshair_2d;
1049                 if (wcross_style == "0")
1050                         return;
1051                 wcross_resolution = autocvar_crosshair_size;
1052                 if (wcross_resolution == 0)
1053                         return;
1054                 wcross_alpha = autocvar_crosshair_alpha;
1055                 if (wcross_alpha == 0)
1056                         return;
1057
1058                 // TrueAim check
1059                 float shottype;
1060
1061                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1062                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1063                         wcross_origin = viewloc_mousepos;
1064                 else
1065                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1066                 wcross_origin.z = 0;
1067                 if(autocvar_crosshair_hittest)
1068                 {
1069                         vector wcross_oldorigin;
1070                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1071                         wcross_oldorigin = wcross_origin;
1072                         shottype = TrueAimCheck(thiswep);
1073                         if(shottype == SHOTTYPE_HITWORLD)
1074                         {
1075                                 v = wcross_origin - wcross_oldorigin;
1076                                 v.x /= vid_conwidth;
1077                                 v.y /= vid_conheight;
1078                                 if(vdist(v, >, 0.01))
1079                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1080                         }
1081                         if(!autocvar_crosshair_hittest_showimpact)
1082                                 wcross_origin = wcross_oldorigin;
1083                 }
1084                 else
1085                         shottype = SHOTTYPE_HITWORLD;
1086
1087                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1088                 string wcross_name = "";
1089                 float wcross_scale, wcross_blur;
1090
1091         entity e = WEP_Null;
1092                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1093                 {
1094                         entity wepent = viewmodels[0]; // TODO: unhardcode
1095                         e = wepent.switchingweapon;
1096                         if(e)
1097                         {
1098                                 if(autocvar_crosshair_per_weapon)
1099                                 {
1100                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1101                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1102                                         //if (wcross_resolution == 0)
1103                                                 //return;
1104
1105                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1106                                         wcross_resolution *= e.w_crosshair_size;
1107                                         wcross_name = e.w_crosshair;
1108                                 }
1109                         }
1110                 }
1111
1112                 if(wcross_name == "")
1113                         wcross_name = strcat("gfx/crosshair", wcross_style);
1114
1115                 // MAIN CROSSHAIR COLOR DECISION
1116                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1117
1118                 if(autocvar_crosshair_effect_scalefade)
1119                 {
1120                         wcross_scale = wcross_resolution;
1121                         wcross_resolution = 1;
1122                 }
1123                 else
1124                 {
1125                         wcross_scale = 1;
1126                 }
1127
1128                 if(autocvar_crosshair_pickup)
1129                 {
1130                         float stat_pickup_time = STAT(LAST_PICKUP);
1131
1132                         if(pickup_crosshair_time < stat_pickup_time)
1133                         {
1134                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1135                                         pickup_crosshair_size = 1;
1136
1137                                 pickup_crosshair_time = stat_pickup_time;
1138                         }
1139
1140                         if(pickup_crosshair_size > 0)
1141                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1142                         else
1143                                 pickup_crosshair_size = 0;
1144
1145                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1146                 }
1147
1148                 // todo: make crosshair hit indication dependent on damage dealt
1149                 if(autocvar_crosshair_hitindication)
1150                 {
1151                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1152
1153                         if(unaccounted_damage)
1154                         {
1155                                 hitindication_crosshair_size = 1;
1156                         }
1157
1158                         if(hitindication_crosshair_size > 0)
1159                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1160                         else
1161                                 hitindication_crosshair_size = 0;
1162
1163                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1164                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1165                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1166                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1167                 }
1168
1169                 if(shottype == SHOTTYPE_HITENEMY)
1170                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1171                 if(shottype == SHOTTYPE_HITTEAM)
1172                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1173
1174                 f = fabs(autocvar_crosshair_effect_time);
1175                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1176                 {
1177                         wcross_changedonetime = time + f;
1178                 }
1179                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1180                 {
1181                         wcross_name_changestarttime = time;
1182                         wcross_name_changedonetime = time + f;
1183                         if(wcross_name_goal_prev_prev)
1184                                 strunzone(wcross_name_goal_prev_prev);
1185                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1186                         wcross_name_goal_prev = strzone(wcross_name);
1187                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1188                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1189                         wcross_resolution_goal_prev = wcross_resolution;
1190                 }
1191
1192                 wcross_scale_goal_prev = wcross_scale;
1193                 wcross_alpha_goal_prev = wcross_alpha;
1194                 wcross_color_goal_prev = wcross_color;
1195
1196                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1197                 {
1198                         wcross_blur = 1;
1199                         wcross_alpha *= 0.75;
1200                 }
1201                 else
1202                         wcross_blur = 0;
1203                 // *_prev is at time-frametime
1204                 // * is at wcross_changedonetime+f
1205                 // what do we have at time?
1206                 if(time < wcross_changedonetime)
1207                 {
1208                         f = frametime / (wcross_changedonetime - time + frametime);
1209                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1210                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1211                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1212                 }
1213
1214                 wcross_scale_prev = wcross_scale;
1215                 wcross_alpha_prev = wcross_alpha;
1216                 wcross_color_prev = wcross_color;
1217
1218                 MUTATOR_CALLHOOK(UpdateCrosshair);
1219
1220                 wcross_scale *= 1 - autocvar__menu_alpha;
1221                 wcross_alpha *= 1 - autocvar__menu_alpha;
1222                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1223
1224                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1225                 {
1226                         // crosshair rings for weapon stats
1227                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1228                         {
1229                                 // declarations and stats
1230                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1231                                 string ring_image = string_null, ring_inner_image = string_null;
1232                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1233
1234                                 ring_scale = autocvar_crosshair_ring_size;
1235
1236                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1237
1238                                 int weapon_clipload = wepent.clip_load;
1239                                 int weapon_clipsize = wepent.clip_size;
1240
1241                                 float arc_heat = wepent.arc_heat_percent;
1242                                 float vcharge = wepent.vortex_charge;
1243                                 float vchargepool = wepent.vortex_chargepool_ammo;
1244                                 float oknex_charge_ = wepent.oknex_charge;
1245                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1246
1247                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1248                                         vortex_charge_movingavg = vcharge;
1249
1250                                 // handle the values
1251                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1252                                 {
1253                                         if (vchargepool || use_vortex_chargepool) {
1254                                                 use_vortex_chargepool = 1;
1255                                                 ring_inner_value = vchargepool;
1256                                         } else {
1257                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1258                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1259                                         }
1260
1261                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1262                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1263                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1264
1265                                         // draw the outer ring to show the current charge of the weapon
1266                                         ring_value = vcharge;
1267                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1268                                         ring_rgb = wcross_color;
1269                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1270                                 }
1271                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1272                                 {
1273                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1274                                                 use_vortex_chargepool = 1;
1275                                                 ring_inner_value = oknex_chargepool_;
1276                                         } else {
1277                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1278                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1279                                         }
1280
1281                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1282                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1283                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1284
1285                                         // draw the outer ring to show the current charge of the weapon
1286                                         ring_value = oknex_charge_;
1287                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1288                                         ring_rgb = wcross_color;
1289                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1290                                 }
1291                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1292                                 {
1293                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1294                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1295                                         ring_rgb = wcross_color;
1296                                         ring_image = "gfx/crosshair_ring.tga";
1297                                 }
1298                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1299                                 {
1300                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1301                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1302                                         ring_rgb = wcross_color;
1303                                         ring_image = "gfx/crosshair_ring.tga";
1304                                 }
1305                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1306                                 {
1307                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1308                                         ring_scale = autocvar_crosshair_ring_reload_size;
1309                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1310                                         ring_rgb = wcross_color;
1311
1312                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1313                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1314                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1315                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1316                                         else
1317                                                 ring_image = "gfx/crosshair_ring.tga";
1318                                 }
1319                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1320                                 {
1321                                         ring_value = arc_heat;
1322                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1323                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1324                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1325                                         ring_image = "gfx/crosshair_ring.tga";
1326                                 }
1327
1328                                 // if in weapon switch animation, fade ring out/in
1329                                 if(autocvar_crosshair_effect_time > 0)
1330                                 {
1331                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1332                                         if (f >= 1)
1333                                         {
1334                                                 wcross_ring_prev = ((ring_image) ? true : false);
1335                                         }
1336
1337                                         if(wcross_ring_prev)
1338                                         {
1339                                                 if(f < 1)
1340                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1341                                         }
1342                                         else
1343                                         {
1344                                                 if(f < 1)
1345                                                         ring_alpha *= bound(0, f, 1);
1346                                         }
1347                                 }
1348
1349                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1350                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1351
1352                                 if (ring_value)
1353                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1354                         }
1355
1356 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1357                         MACRO_BEGIN { \
1358                                 if(wcross_blur > 0) \
1359                                 { \
1360                                         for(i = -2; i <= 2; ++i) \
1361                                         for(j = -2; j <= 2; ++j) \
1362                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1363                                 } \
1364                                 else \
1365                                 { \
1366                                         M(0,0,sz,wcross_name,wcross_alpha); \
1367                                 } \
1368                         } MACRO_END
1369
1370 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1371                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1372
1373 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1374                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1375
1376                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1377                         {
1378                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1379                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1380                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1381                                 f = 1 - f;
1382                         }
1383                         else
1384                         {
1385                                 f = 1;
1386                         }
1387                         wcross_name_alpha_goal_prev = f;
1388
1389                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1390                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1391
1392                         if(autocvar_crosshair_dot)
1393                         {
1394                                 vector wcross_color_old;
1395                                 wcross_color_old = wcross_color;
1396
1397                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1398                                         wcross_color = stov(autocvar_crosshair_dot_color);
1399
1400                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1401                                 // FIXME why don't we use wcross_alpha here?
1402                                 wcross_color = wcross_color_old;
1403                         }
1404                 }
1405         }
1406         else
1407         {
1408                 wcross_scale_prev = 0;
1409                 wcross_alpha_prev = 0;
1410                 wcross_scale_goal_prev = 0;
1411                 wcross_alpha_goal_prev = 0;
1412                 wcross_changedonetime = 0;
1413                 strfree(wcross_name_goal_prev);
1414                 strfree(wcross_name_goal_prev_prev);
1415                 wcross_name_changestarttime = 0;
1416                 wcross_name_changedonetime = 0;
1417                 wcross_name_alpha_goal_prev = 0;
1418                 wcross_name_alpha_goal_prev_prev = 0;
1419                 wcross_resolution_goal_prev = 0;
1420                 wcross_resolution_goal_prev_prev = 0;
1421         }
1422 }
1423
1424 const int MAX_SPECIALCOMMAND = 15;
1425 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1426 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1427 const float SPECIALCOMMAND_SPEED = 150;
1428 const float SPECIALCOMMAND_TURNSPEED = 2;
1429 const float SPECIALCOMMAND_SIZE = 0.025;
1430 const float SPECIALCOMMAND_CHANCE = 0.35;
1431 float sc_spawntime, sc_changetime;
1432 vector sc_color = '1 1 1';
1433 void SpecialCommand()
1434 {
1435         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1436                 return;
1437
1438         if(time >= sc_changetime)
1439         {
1440                 sc_changetime = time + 1;
1441                 sc_color = randomvec() * 1.5;
1442                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1443                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1444                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1445         }
1446         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1447
1448         if(!precache_pic("gfx/smile"))
1449                 return; // damn party poopers
1450
1451         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1452         {
1453                 vector slot = specialcommand_slots[j];
1454                 if(slot.y)
1455                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1456                 //if(slot.z)
1457                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1458                 if(slot.y >= vid_conheight)
1459                         slot = '0 0 0';
1460
1461                 if(slot == '0 0 0')
1462                 {
1463                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1464                         {
1465                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1466                                 slot.y = 1; // start it off 0 so we can use it
1467                                 slot.z = floor(random() * Weapons_MAX);
1468                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1469                                 vector newcolor = randomvec() * 2;
1470                                 newcolor.x = bound(0.4, newcolor.x, 1);
1471                                 newcolor.y = bound(0.4, newcolor.y, 1);
1472                                 newcolor.z = bound(0.4, newcolor.z, 1);
1473                                 specialcommand_colors[j] = newcolor;
1474                         }
1475                 }
1476                 else
1477                 {
1478                         vector splash_size = '0 0 0';
1479                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1480                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1481                         entity wep = Weapons_from(slot.z);
1482                         if(wep == WEP_Null)
1483                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1484                         else
1485                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1486                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1487                 }
1488
1489                 specialcommand_slots[j] = slot;
1490         }
1491 }
1492
1493 void HUD_Draw(entity this)
1494 {
1495         // if we don't know gametype and scores yet avoid drawing the scoreboard
1496         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1497         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1498         // cl_deathscoreboard would show the scoreboard and so on
1499         if(!gametype)
1500                 return;
1501
1502         Hud_Dynamic_Frame();
1503
1504         if(!intermission)
1505         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1506         {
1507                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1508         }
1509         else if(STAT(FROZEN))
1510         {
1511                 vector col = '0.25 0.90 1';
1512                 if(STAT(REVIVE_PROGRESS))
1513                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1514                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1515         }
1516
1517         HUD_Scale_Enable();
1518         if(!intermission)
1519         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1520         {
1521                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1522                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1523                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1524         }
1525         else if(STAT(CAPTURE_PROGRESS))
1526         {
1527                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1528                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1529         }
1530         else if(STAT(REVIVE_PROGRESS))
1531         {
1532                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1533                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1534         }
1535         HUD_Scale_Disable();
1536
1537         if(autocvar_r_letterbox == 0)
1538                 if(autocvar_viewsize < 120)
1539                 {
1540                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1541                                 Accuracy_LoadLevels();
1542
1543                         HUD_Main();
1544                         HUD_Scale_Disable();
1545                 }
1546
1547         // crosshair goes VERY LAST
1548         SpecialCommand();
1549         UpdateDamage();
1550         HUD_Crosshair(this);
1551         HitSound();
1552 }
1553
1554 void ViewLocation_Mouse()
1555 {
1556         if(spectatee_status)
1557                 return; // don't draw it as spectator!
1558
1559         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1560         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1561         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1562
1563         //float cursor_alpha = 1 - autocvar__menu_alpha;
1564         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1565 }
1566
1567 void HUD_Cursor_Show()
1568 {
1569         float cursor_alpha = 1 - autocvar__menu_alpha;
1570         if(cursor_type == CURSOR_NORMAL)
1571                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1572         else if(cursor_type == CURSOR_MOVE)
1573                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1574         else if(cursor_type == CURSOR_RESIZE)
1575                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1576         else if(cursor_type == CURSOR_RESIZE2)
1577                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1578 }
1579
1580 void HUD_Mouse(entity player)
1581 {
1582         if(autocvar__menu_alpha == 1)
1583                 return;
1584
1585         if(!cursor_active)
1586         {
1587                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1588                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1589                 return;
1590         }
1591
1592         if(!autocvar_hud_cursormode)
1593                 update_mousepos();
1594
1595         if(autocvar__hud_configure)
1596                 HUD_Panel_Mouse();
1597         else
1598         {
1599                 if (HUD_MinigameMenu_IsOpened())
1600                         HUD_Minigame_Mouse();
1601                 if (QuickMenu_IsOpened())
1602                         QuickMenu_Mouse();
1603                 if (HUD_Radar_Clickable())
1604                         HUD_Radar_Mouse();
1605         }
1606
1607         prevMouseClicked = mouseClicked;
1608
1609         HUD_Cursor_Show();
1610 }
1611
1612 bool ov_enabled;
1613 float oldr_nearclip;
1614 float oldr_farclip_base;
1615 float oldr_farclip_world;
1616 float oldr_novis;
1617 float oldr_useportalculling;
1618 float oldr_useinfinitefarclip;
1619
1620 float prev_myteam;
1621 int lasthud;
1622 float vh_notice_time;
1623 void CSQC_UpdateView(entity this, float w, float h)
1624 {
1625         TC(int, w); TC(int, h);
1626         entity e;
1627         float fov;
1628         float f;
1629         vector vf_size, vf_min;
1630         float a;
1631
1632         execute_next_frame();
1633
1634         ++framecount;
1635
1636         stats_get();
1637         hud = STAT(HUD);
1638
1639         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1640                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1641
1642         lasthud = hud;
1643
1644         HUD_Scale_Disable();
1645
1646         if(autocvar__hud_showbinds_reload) // menu can set this one
1647         {
1648                 db_close(binddb);
1649                 binddb = db_create();
1650                 cvar_set("_hud_showbinds_reload", "0");
1651         }
1652
1653         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1654                 view_quality = getproperty(VF_MINFPS_QUALITY);
1655         else
1656                 view_quality = 1;
1657
1658         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1659         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1660
1661         vf_size = getpropertyvec(VF_SIZE);
1662         vf_min = getpropertyvec(VF_MIN);
1663         vid_width = vf_size.x;
1664         vid_height = vf_size.y;
1665
1666         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1667         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1668
1669         WaypointSprite_Load();
1670
1671         CSQCPlayer_SetCamera();
1672
1673         if(player_localentnum <= maxclients) // is it a client?
1674                 current_player = player_localentnum - 1;
1675         else // then player_localentnum is the vehicle I'm driving
1676                 current_player = player_localnum;
1677         myteam = entcs_GetTeam(current_player);
1678
1679         if(myteam != prev_myteam)
1680         {
1681                 myteamcolors = colormapPaletteColor(myteam, 1);
1682                 FOREACH(hud_panels, true, it.update_time = time);
1683                 prev_myteam = myteam;
1684         }
1685
1686         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1687
1688         float is_dead = (STAT(HEALTH) <= 0);
1689
1690         // FIXME do we need this hack?
1691         if(isdemo())
1692         {
1693                 // in demos, input_buttons do not work
1694                 button_zoom = (autocvar__togglezoom == "-");
1695         }
1696         else if(button_zoom
1697                 && autocvar_cl_unpress_zoom_on_death
1698                 && (spectatee_status >= 0)
1699                 && (is_dead || intermission))
1700         {
1701                 // no zoom while dead or in intermission please
1702                 localcmd("-zoom\n");
1703                 button_zoom = false;
1704         }
1705
1706         // abused multiple places below
1707         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1708         if(!local_player)
1709                 local_player = this; // fall back!
1710
1711         // event chase camera
1712         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1713         {
1714                 if(STAT(CAMERA_SPECTATOR))
1715                 {
1716                         if(spectatee_status > 0)
1717                         {
1718                                 if(!autocvar_chase_active)
1719                                 {
1720                                         cvar_set("chase_active", "-2");
1721                                         goto skip_eventchase_death;
1722                                 }
1723                         }
1724                         else if(autocvar_chase_active == -2)
1725                                 cvar_set("chase_active", "0");
1726
1727                         if(autocvar_chase_active == -2)
1728                                 goto skip_eventchase_death;
1729                 }
1730                 else if(autocvar_chase_active == -2)
1731                         cvar_set("chase_active", "0");
1732
1733                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1734
1735                 float vehicle_viewdist = 0;
1736                 vector vehicle_viewofs = '0 0 0';
1737
1738                 if(vehicle_chase)
1739                 {
1740                         if(hud != HUD_BUMBLEBEE_GUN)
1741                         {
1742                                 Vehicle info = Vehicles_from(hud);
1743                                 vehicle_viewdist = info.height;
1744                                 vehicle_viewofs = info.view_ofs;
1745                         }
1746                 }
1747
1748                 int eventchase = WantEventchase(this);
1749                 if (eventchase)
1750                 {
1751                         vector current_view_origin_override = '0 0 0';
1752                         vector view_offset_override = '0 0 0';
1753                         float chase_distance_override = 0;
1754                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1755                         if(custom_eventchase)
1756                         {
1757                                 current_view_origin_override = M_ARGV(0, vector);
1758                                 view_offset_override = M_ARGV(1, vector);
1759                                 chase_distance_override = M_ARGV(0, float);
1760                         }
1761                         eventchase_running = true;
1762
1763                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1764                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1765                         if (custom_eventchase)
1766                                 current_view_origin = current_view_origin_override;
1767
1768                         // detect maximum viewoffset and use it
1769                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1770                         if(vehicle_chase)
1771                         {
1772                                 if(vehicle_viewofs)
1773                                         view_offset = vehicle_viewofs;
1774                                 else
1775                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1776                         }
1777                         if (custom_eventchase)
1778                                 view_offset = view_offset_override;
1779
1780                         if(view_offset)
1781                         {
1782                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1783                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1784                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1785                         }
1786
1787                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1788                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1789                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1790                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1791
1792                         // make the camera smooth back
1793                         float chase_distance = autocvar_cl_eventchase_distance;
1794                         if(vehicle_chase)
1795                         {
1796                                 if(vehicle_viewofs)
1797                                         chase_distance = vehicle_viewdist;
1798                                 else
1799                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1800                         }
1801                         if (custom_eventchase)
1802                                 chase_distance = chase_distance_override;
1803
1804                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1805                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1806                         else if(eventchase_current_distance != chase_distance)
1807                                 eventchase_current_distance = chase_distance;
1808
1809                         MAKE_VECTORS_NEW(view_angles, forward, right, up);
1810
1811                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1812                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1813
1814                         // If the boxtrace fails, revert back to line tracing.
1815                         if(!local_player.viewloc)
1816                         if(trace_startsolid)
1817                         {
1818                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1819                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1820                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
1821                         }
1822                         else { setproperty(VF_ORIGIN, trace_endpos); }
1823
1824                         if(!local_player.viewloc)
1825                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1826                 }
1827
1828                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1829                 {
1830                         eventchase_running = false;
1831                         cvar_set("chase_active", "0");
1832                         eventchase_current_distance = 0; // start from 0 next time
1833                 }
1834         }
1835         // workaround for camera stuck between player's legs when using chase_active 1
1836         // because the engine stops updating the chase_active camera when the game ends
1837         else if(intermission)
1838         {
1839                 cvar_settemp("chase_active", "-1");
1840                 eventchase_current_distance = 0;
1841         }
1842
1843         LABEL(skip_eventchase_death);
1844
1845         // do lockview after event chase camera so that it still applies whenever necessary.
1846         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1847         {
1848                 setproperty(VF_ORIGIN, freeze_org);
1849                 setproperty(VF_ANGLES, freeze_ang);
1850         }
1851         else
1852         {
1853                 freeze_org = getpropertyvec(VF_ORIGIN);
1854                 freeze_ang = getpropertyvec(VF_ANGLES);
1855         }
1856
1857         WarpZone_FixView();
1858         //WarpZone_FixPMove();
1859
1860         vector ov_org = '0 0 0';
1861         vector ov_mid = '0 0 0';
1862         vector ov_worldmin = '0 0 0';
1863         vector ov_worldmax = '0 0 0';
1864         if(autocvar_cl_orthoview)
1865         {
1866                 ov_worldmin = mi_picmin;
1867                 ov_worldmax = mi_picmax;
1868
1869                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1870                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1871                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1872
1873                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1874                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1875
1876                 float ov_nearest = vlen(ov_org - vec3(
1877                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1878                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1879                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1880                 ));
1881
1882                 float ov_furthest = 0;
1883                 float dist = 0;
1884
1885                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1886                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1887                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1888                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1889                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1890                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1891                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1892                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1893
1894                 if(!ov_enabled)
1895                 {
1896                         oldr_nearclip = cvar("r_nearclip");
1897                         oldr_farclip_base = cvar("r_farclip_base");
1898                         oldr_farclip_world = cvar("r_farclip_world");
1899                         oldr_novis = cvar("r_novis");
1900                         oldr_useportalculling = cvar("r_useportalculling");
1901                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1902                 }
1903
1904                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1905                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1906                 cvar_settemp("r_farclip_world", "0");
1907                 cvar_settemp("r_novis", "1");
1908                 cvar_settemp("r_useportalculling", "0");
1909                 cvar_settemp("r_useinfinitefarclip", "0");
1910
1911                 setproperty(VF_ORIGIN, ov_org);
1912                 setproperty(VF_ANGLES, '90 0 0');
1913
1914                 ov_enabled = true;
1915
1916                 #if 0
1917                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1918                         vtos(ov_org),
1919                         vtos(getpropertyvec(VF_ANGLES)),
1920                         ov_distance,
1921                         ov_nearest,
1922                         ov_furthest);
1923                 #endif
1924         }
1925         else
1926         {
1927                 if(ov_enabled)
1928                 {
1929                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1930                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1931                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1932                         cvar_set("r_novis", ftos(oldr_novis));
1933                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1934                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1935                 }
1936                 ov_enabled = false;
1937         }
1938
1939         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1940         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1941         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1942                 viewmodel_draw(viewmodels[slot]);
1943
1944         // Render the Scene
1945         view_origin = getpropertyvec(VF_ORIGIN);
1946         view_angles = getpropertyvec(VF_ANGLES);
1947         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1948
1949 #ifdef BLURTEST
1950         if(time > blurtest_time0 && time < blurtest_time1)
1951         {
1952                 float r, t;
1953
1954                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1955                 r = t * blurtest_radius;
1956                 f = 1 / (t ** blurtest_power) - 1;
1957
1958                 cvar_set("r_glsl_postprocess", "1");
1959                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1960         }
1961         else
1962         {
1963                 cvar_set("r_glsl_postprocess", "0");
1964                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1965         }
1966 #endif
1967
1968         TargetMusic_Advance();
1969         Fog_Force();
1970         fpscounter_update();
1971
1972         if(drawtime == 0)
1973                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1974         else
1975                 drawframetime = bound(0.000001, time - drawtime, 1);
1976         drawtime = time;
1977
1978         // watch for gametype changes here...
1979         // in ParseStuffCMD the cmd isn't executed yet :/
1980         // might even be better to add the gametype to TE_CSQC_INIT...?
1981         if(!postinit)
1982                 PostInit();
1983
1984         if(intermission && !intermission_time)
1985                 intermission_time = time;
1986
1987         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1988         {
1989                 if(calledhooks & HOOK_START)
1990                 {
1991                         localcmd("\ncl_hook_gameend\n");
1992                         calledhooks |= HOOK_END;
1993                 }
1994         }
1995
1996         Announcer();
1997
1998         fov = autocvar_fov;
1999         if(fov <= 59.5)
2000         {
2001                 if(!zoomscript_caught)
2002                 {
2003                         localcmd("+button9\n");
2004                         zoomscript_caught = 1;
2005                 }
2006         }
2007         else
2008         {
2009                 if(zoomscript_caught)
2010                 {
2011                         localcmd("-button9\n");
2012                         zoomscript_caught = 0;
2013                 }
2014         }
2015
2016         if(active_minigame && HUD_MinigameMenu_IsOpened())
2017         {
2018                 if(!minigame_wasactive)
2019                 {
2020                         localcmd("+button14\n");
2021                         minigame_wasactive = true;
2022                 }
2023         }
2024         else if(minigame_wasactive)
2025         {
2026                 localcmd("-button14\n");
2027                 minigame_wasactive = false;
2028         }
2029
2030         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2031
2032         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2033         {
2034                 entity wepent = viewmodels[slot];
2035
2036                 if(wepent.last_switchweapon != wepent.switchweapon)
2037                 {
2038                         weapontime = time;
2039                         wepent.last_switchweapon = wepent.switchweapon;
2040                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2041                         {
2042                                 localcmd("-zoom\n");
2043                                 button_zoom = false;
2044                         }
2045                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2046                         {
2047                                 localcmd("-fire\n");
2048                                 localcmd("-fire2\n");
2049                                 button_attack2 = false;
2050                         }
2051                 }
2052                 if(wepent.last_activeweapon != wepent.activeweapon)
2053                 {
2054                         wepent.last_activeweapon = wepent.activeweapon;
2055
2056                         e = wepent.activeweapon;
2057                         if(e.netname != "")
2058                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2059                         else if(slot == 0)
2060                                 localcmd("\ncl_hook_activeweapon none\n");
2061                 }
2062         }
2063
2064         // ALWAYS Clear Current Scene First
2065         clearscene();
2066
2067         setproperty(VF_ORIGIN, view_origin);
2068         setproperty(VF_ANGLES, view_angles);
2069
2070         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2071         setproperty(VF_SIZE, vf_size);
2072         setproperty(VF_MIN, vf_min);
2073
2074         // Assign Standard Viewflags
2075         // Draw the World (and sky)
2076         setproperty(VF_DRAWWORLD, 1);
2077
2078         // Set the console size vars
2079         vid_conwidth = autocvar_vid_conwidth;
2080         vid_conheight = autocvar_vid_conheight;
2081         vid_pixelheight = autocvar_vid_pixelheight;
2082
2083         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2084         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2085         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2086
2087         if(camera_active) // Camera for demo playback
2088         {
2089                 if(autocvar_camera_enable)
2090                         CSQC_Demo_Camera();
2091                 else
2092                 {
2093                         cvar_set("chase_active", ftos(chase_active_backup));
2094                         cvar_set("cl_demo_mousegrab", "0");
2095                         camera_active = false;
2096                 }
2097         }
2098         else
2099         {
2100 #ifdef CAMERATEST
2101                 if(autocvar_camera_enable)
2102 #else
2103                 if(autocvar_camera_enable && isdemo())
2104 #endif
2105                 {
2106                         // Enable required Darkplaces cvars
2107                         chase_active_backup = autocvar_chase_active;
2108                         cvar_set("chase_active", "2");
2109                         cvar_set("cl_demo_mousegrab", "1");
2110                         camera_active = true;
2111                         camera_mode = false;
2112                 }
2113         }
2114
2115         // Draw the Crosshair
2116         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2117
2118         // Draw the Engine Status Bar (the default Quake HUD)
2119         setproperty(VF_DRAWENGINESBAR, 0);
2120
2121         // Update the mouse position
2122         /*
2123            mousepos_x = vid_conwidth;
2124            mousepos_y = vid_conheight;
2125            mousepos = mousepos*0.5 + getmousepos();
2126          */
2127
2128         IL_EACH(g_drawables, it.draw, it.draw(it));
2129
2130         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2131         renderscene();
2132
2133         // now switch to 2D drawing mode by calling a 2D drawing function
2134         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2135         // next R_RenderScene call
2136         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2137
2138         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2139         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2140         {
2141                 // apply night vision effect
2142                 vector tc_00, tc_01, tc_10, tc_11;
2143                 vector rgb = '0 0 0';
2144
2145                 if(!nightvision_noise)
2146                 {
2147                         nightvision_noise = new(nightvision_noise);
2148                 }
2149                 if(!nightvision_noise2)
2150                 {
2151                         nightvision_noise2 = new(nightvision_noise2);
2152                 }
2153
2154                 // color tint in yellow
2155                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2156
2157                 // draw BG
2158                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2159                 rgb = '1 1 1';
2160                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2161                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2162                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2163                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2164                 tc_11 = tc_01 + tc_10 - tc_00;
2165                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2166                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2167                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2168                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2169                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2170                 R_EndPolygon();
2171
2172                 // draw FG
2173                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2174                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2175                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2176                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2177                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2178                 tc_11 = tc_01 + tc_10 - tc_00;
2179                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2180                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2181                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2182                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2183                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2184                 R_EndPolygon();
2185         }
2186
2187         if(autocvar_cl_reticle)
2188         {
2189                 string reticle_image = string_null;
2190                 bool wep_zoomed = false;
2191                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2192                 {
2193                         entity wepe = viewmodels[slot];
2194                         Weapon wep = wepe.activeweapon;
2195                         if(wep != WEP_Null && wep.wr_zoom)
2196                         {
2197                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2198                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2199                                         reticle_image = wep.w_reticle;
2200                                 wep_zoomed += do_zoom;
2201                         }
2202                 }
2203                 // Draw the aiming reticle for weapons that use it
2204                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2205                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2206                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2207                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2208                 {
2209                         // no zoom reticle while dead
2210                         reticle_type = 0;
2211                 }
2212                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2213                 {
2214                         if(reticle_image) { reticle_type = 2; }
2215                         else { reticle_type = 0; }
2216                 }
2217                 else if(button_zoom || zoomscript_caught)
2218                 {
2219                         // normal zoom
2220                         reticle_type = 1;
2221                 }
2222
2223                 if(reticle_type)
2224                 {
2225                         if(autocvar_cl_reticle_stretch)
2226                         {
2227                                 reticle_size.x = vid_conwidth;
2228                                 reticle_size.y = vid_conheight;
2229                                 reticle_pos.x = 0;
2230                                 reticle_pos.y = 0;
2231                         }
2232                         else
2233                         {
2234                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2235                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2236                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2237                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2238                         }
2239
2240                         if(zoomscript_caught)
2241                                 f = 1;
2242                         else
2243                                 f = current_zoomfraction;
2244
2245                         if(f)
2246                         {
2247                                 switch(reticle_type)
2248                                 {
2249                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2250                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2251                                 }
2252                         }
2253                 }
2254         }
2255         else
2256         {
2257                 if(reticle_type != 0) { reticle_type = 0; }
2258         }
2259
2260
2261         // improved polyblend
2262         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2263         {
2264                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2265                 vector liquidcolor;
2266
2267                 switch(pointcontents(view_origin))
2268                 {
2269                         case CONTENT_WATER:
2270                                 liquidalpha = autocvar_hud_contents_water_alpha;
2271                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2272                                 incontent = 1;
2273                                 break;
2274
2275                         case CONTENT_LAVA:
2276                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2277                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2278                                 incontent = 1;
2279                                 break;
2280
2281                         case CONTENT_SLIME:
2282                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2283                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2284                                 incontent = 1;
2285                                 break;
2286
2287                         default:
2288                                 liquidalpha = 0;
2289                                 liquidcolor = '0 0 0';
2290                                 incontent = 0;
2291                                 break;
2292                 }
2293
2294                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2295                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2296                         contentfadetime = autocvar_hud_contents_fadeintime;
2297                         liquidalpha_prev = liquidalpha;
2298                         liquidcolor_prev = liquidcolor;
2299                 }
2300                 else
2301                         contentfadetime = autocvar_hud_contents_fadeouttime;
2302
2303                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2304                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2305
2306                 if(contentavgalpha)
2307                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2308
2309                 if(autocvar_hud_postprocessing)
2310                 {
2311                         if(autocvar_hud_contents_blur && contentavgalpha)
2312                         {
2313                                 content_blurpostprocess.x = 1;
2314                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2315                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2316                         }
2317                         else
2318                         {
2319                                 content_blurpostprocess.x = 0;
2320                                 content_blurpostprocess.y = 0;
2321                                 content_blurpostprocess.z = 0;
2322                         }
2323                 }
2324         }
2325
2326         if(autocvar_hud_damage && !STAT(FROZEN))
2327         {
2328                 splash_size.x = max(vid_conwidth, vid_conheight);
2329                 splash_size.y = max(vid_conwidth, vid_conheight);
2330                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2331                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2332
2333                 float myhealth_flash_temp;
2334                 myhealth = STAT(HEALTH);
2335
2336                 // fade out
2337                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2338                 // add new damage
2339                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2340
2341                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2342                 pain_threshold = autocvar_hud_damage_pain_threshold;
2343                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2344                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2345
2346                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2347                 {
2348                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2349                 }
2350
2351                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2352
2353                 if(myhealth_prev < 1)
2354                 {
2355                         if(myhealth >= 1)
2356                         {
2357                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2358                                 myhealth_flash_temp = 0;
2359                         }
2360                         else
2361                         {
2362                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2363                         }
2364                 }
2365
2366                 if(spectatee_status == -1 || intermission)
2367                 {
2368                         myhealth_flash = 0; // observing, or match ended
2369                         myhealth_flash_temp = 0;
2370                 }
2371
2372                 myhealth_prev = myhealth;
2373
2374                 // IDEA: change damage color/picture based on player model for robot/alien species?
2375                 // pro: matches model better
2376                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2377                 // maybe different reddish pics?
2378                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2379                 {
2380                         if(autocvar_cl_gentle_damage == 2)
2381                         {
2382                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2383                                         myhealth_gentlergb = randomvec();
2384                         }
2385                         else
2386                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2387
2388                         if(myhealth_flash_temp > 0)
2389                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2390                 }
2391                 else if(myhealth_flash_temp > 0)
2392                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2393
2394                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2395                 {
2396                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2397                         {
2398                                 damage_blurpostprocess.x = 1;
2399                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2400                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2401                         }
2402                         else
2403                         {
2404                                 damage_blurpostprocess.x = 0;
2405                                 damage_blurpostprocess.y = 0;
2406                                 damage_blurpostprocess.z = 0;
2407                         }
2408                 }
2409         }
2410
2411         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2412         float e2 = (autocvar_hud_powerup != 0);
2413         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2414         {
2415                 // enable or disable rendering types if they are used or not
2416                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2417                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2418
2419                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2420                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2421                 {
2422                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2423                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2424                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2425                         {
2426                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2427                                 old_blurradius = blurradius;
2428                                 old_bluralpha = bluralpha;
2429                         }
2430                 }
2431                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2432                 {
2433                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2434                         old_blurradius = 0;
2435                         old_bluralpha = 0;
2436                 }
2437
2438                 // edge detection postprocess handling done second (used by hud_powerup)
2439                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2440                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2441                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2442
2443                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2444
2445                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2446                 {
2447                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2448                         {
2449                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2450                                 old_sharpen_intensity = sharpen_intensity;
2451                         }
2452                 }
2453                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2454                 {
2455                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2456                         old_sharpen_intensity = 0;
2457                 }
2458
2459                 if(cvar("r_glsl_postprocess") == 0)
2460                         cvar_set("r_glsl_postprocess", "2");
2461         }
2462         else if(cvar("r_glsl_postprocess") == 2)
2463                 cvar_set("r_glsl_postprocess", "0");
2464
2465         /*if(ISGAMETYPE(CTF))
2466           {
2467           ctf_view();
2468           } else */
2469
2470         // draw 2D entities
2471         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2472         Draw_ShowNames_All();
2473 #if ENABLE_DEBUGDRAW
2474         Debug_Draw();
2475 #endif
2476
2477         scoreboard_active = Scoreboard_WouldDraw();
2478
2479         HUD_Draw(this); // this parameter for deep vehicle function
2480
2481         if(NextFrameCommand)
2482         {
2483                 localcmd("\n", NextFrameCommand, "\n");
2484                 NextFrameCommand = string_null;
2485         }
2486
2487         // we must do this check AFTER a frame was rendered, or it won't work
2488         if(cs_project_is_b0rked == 0)
2489         {
2490                 string w0, h0;
2491                 w0 = ftos(autocvar_vid_conwidth);
2492                 h0 = ftos(autocvar_vid_conheight);
2493                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2494                 //setproperty(VF_FOV, '90 90 0');
2495                 setproperty(VF_ORIGIN, '0 0 0');
2496                 setproperty(VF_ANGLES, '0 0 0');
2497                 setproperty(VF_PERSPECTIVE, 1);
2498                 MAKE_VECTORS_NEW('0 0 0', forward, right, up);
2499                 vector v1, v2;
2500                 cvar_set("vid_conwidth", "800");
2501                 cvar_set("vid_conheight", "600");
2502                 v1 = cs_project(forward);
2503                 cvar_set("vid_conwidth", "640");
2504                 cvar_set("vid_conheight", "480");
2505                 v2 = cs_project(forward);
2506                 if(v1 == v2)
2507                         cs_project_is_b0rked = 1;
2508                 else
2509                         cs_project_is_b0rked = -1;
2510                 cvar_set("vid_conwidth", w0);
2511                 cvar_set("vid_conheight", h0);
2512         }
2513
2514         HUD_Mouse(local_player);
2515
2516         cl_notice_run();
2517         unpause_update();
2518         Net_Flush();
2519
2520         // let's reset the view back to normal for the end
2521         setproperty(VF_MIN, '0 0 0');
2522         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2523
2524         IL_ENDFRAME();
2525 }
2526
2527
2528 // following vectors must be global to allow seamless switching between camera modes
2529 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2530 void CSQC_Demo_Camera()
2531 {
2532         float speed, attenuation, dimensions;
2533         vector tmp, delta;
2534
2535         if( autocvar_camera_reset || !camera_mode )
2536         {
2537                 camera_offset = '0 0 0';
2538                 current_angles = '0 0 0';
2539                 camera_direction = '0 0 0';
2540                 camera_offset.z += 30;
2541                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2542                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2543                 current_origin = view_origin;
2544                 current_camera_offset  = camera_offset;
2545                 cvar_set("camera_reset", "0");
2546                 camera_mode = CAMERA_CHASE;
2547         }
2548
2549         // Camera angles
2550         if( camera_roll )
2551                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2552
2553         if(autocvar_camera_look_player)
2554         {
2555                 vector dir;
2556                 float n;
2557
2558                 dir = normalize(view_origin - current_position);
2559                 n = mouse_angles.z;
2560                 mouse_angles = vectoangles(dir);
2561                 mouse_angles.x = mouse_angles.x * -1;
2562                 mouse_angles.z = n;
2563         }
2564         else
2565         {
2566                 tmp = getmousepos() * 0.1;
2567                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2568                 {
2569                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2570                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2571                 }
2572         }
2573
2574         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2575         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2576         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2577         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2578
2579         // Fix difference when angles don't have the same sign
2580         delta = '0 0 0';
2581         if(mouse_angles.y < -60 && current_angles.y > 60)
2582                 delta = '0 360 0';
2583         if(mouse_angles.y > 60 && current_angles.y < -60)
2584                 delta = '0 -360 0';
2585
2586         if(autocvar_camera_look_player)
2587                 attenuation = autocvar_camera_look_attenuation;
2588         else
2589                 attenuation = autocvar_camera_speed_attenuation;
2590
2591         attenuation = 1 / max(1, attenuation);
2592         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2593
2594         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2595         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2596         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2597         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2598
2599         // Camera position
2600         tmp = '0 0 0';
2601         dimensions = 0;
2602
2603         if( camera_direction.x )
2604         {
2605                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2606                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2607                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2608                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2609                 ++dimensions;
2610         }
2611
2612         if( camera_direction.y )
2613         {
2614                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2615                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2616                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2617                 ++dimensions;
2618         }
2619
2620         if( camera_direction.z )
2621         {
2622                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2623                 ++dimensions;
2624         }
2625
2626         if(autocvar_camera_free)
2627                 speed = autocvar_camera_speed_free;
2628         else
2629                 speed = autocvar_camera_speed_chase;
2630
2631         if(dimensions)
2632         {
2633                 speed = speed * sqrt(1 / dimensions);
2634                 camera_offset += tmp * speed;
2635         }
2636
2637         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2638
2639         // Camera modes
2640         if( autocvar_camera_free )
2641         {
2642                 if ( camera_mode == CAMERA_CHASE )
2643                 {
2644                         current_camera_offset = current_origin + current_camera_offset;
2645                         camera_offset = current_origin + camera_offset;
2646                 }
2647
2648                 camera_mode = CAMERA_FREE;
2649                 current_position = current_camera_offset;
2650         }
2651         else
2652         {
2653                 if ( camera_mode == CAMERA_FREE )
2654                 {
2655                         current_origin = view_origin;
2656                         camera_offset = camera_offset - current_origin;
2657                         current_camera_offset = current_camera_offset - current_origin;
2658                 }
2659
2660                 camera_mode = CAMERA_CHASE;
2661
2662                 if(autocvar_camera_chase_smoothly)
2663                         current_origin += (view_origin - current_origin) * attenuation;
2664                 else
2665                         current_origin = view_origin;
2666
2667                 current_position = current_origin + current_camera_offset;
2668         }
2669
2670         setproperty(VF_ANGLES, current_angles);
2671         setproperty(VF_ORIGIN, current_position);
2672 }