41822f54bca29bc7b2c3ed35e30818d9196d95d4
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1
2 #include "announcer.qh"
3 #include "hook.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include "../common/constants.qh"
13 #include "../common/debug.qh"
14 #include "../common/mapinfo.qh"
15 #include "../common/gamemodes/all.qh"
16 #include "../common/stats.qh"
17 #include "../common/triggers/target/music.qh"
18 #include "../common/teams.qh"
19
20 #include "../common/vehicles/all.qh"
21 #include "../common/weapons/all.qh"
22 #include "../common/viewloc.qh"
23 #include "../common/minigames/cl_minigames.qh"
24 #include "../common/minigames/cl_minigames_hud.qh"
25
26 #include "../lib/csqcmodel/cl_player.qh"
27
28 #include "../lib/warpzone/client.qh"
29 #include "../lib/warpzone/common.qh"
30
31 entity porto;
32 vector polyline[16];
33 void Porto_Draw(entity this)
34 {
35         vector p, dir, ang, q, nextdir;
36         float portal_number, portal1_idx;
37
38         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
39                 return;
40         if(g_balance_porto_secondary)
41                 return;
42         if(intermission == 1)
43                 return;
44         if(intermission == 2)
45                 return;
46         if (getstati(STAT_HEALTH) <= 0)
47                 return;
48
49         dir = view_forward;
50
51         if(angles_held_status)
52         {
53                 makevectors(angles_held);
54                 dir = v_forward;
55         }
56
57         p = view_origin;
58
59         polyline[0] = p;
60         int idx = 1;
61         portal_number = 0;
62         nextdir = dir;
63
64         for (;;)
65         {
66                 dir = nextdir;
67                 traceline(p, p + 65536 * dir, true, porto);
68                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
69                         return;
70                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
71                 p = trace_endpos;
72                 polyline[idx] = p;
73                 ++idx;
74                 if(idx >= 16)
75                         return;
76                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
77                         continue;
78                 ++portal_number;
79                 ang = vectoangles2(trace_plane_normal, dir);
80                 ang.x = -ang.x;
81                 makevectors(ang);
82                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
83                         return;
84                 if(portal_number == 1)
85                 {
86                         portal1_idx = idx;
87                         if(portal_number >= 2)
88                                 break;
89                 }
90         }
91
92         while(idx >= 2)
93         {
94                 p = polyline[idx-2];
95                 q = polyline[idx-1];
96                 if(idx == 2)
97                         p = p - view_up * 16;
98                 if(idx-1 >= portal1_idx)
99                 {
100                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
101                 }
102                 else
103                 {
104                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
105                 }
106                 --idx;
107         }
108 }
109
110 void Porto_Init()
111 {
112         porto = new(porto);
113         make_pure(porto);
114         porto.draw = Porto_Draw;
115         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
116 }
117
118 float drawtime;
119 float avgspeed;
120 vector GetCurrentFov(float fov)
121 {
122         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
123         float velocityzoom, curspeed;
124         vector v;
125
126         zoomsensitivity = autocvar_cl_zoomsensitivity;
127         zoomfactor = autocvar_cl_zoomfactor;
128         if(zoomfactor < 1 || zoomfactor > 30)
129                 zoomfactor = 2.5;
130         zoomspeed = autocvar_cl_zoomspeed;
131         if(zoomspeed >= 0)
132         if(zoomspeed < 0.5 || zoomspeed > 16)
133                         zoomspeed = 3.5;
134
135         zoomdir = button_zoom;
136         if(hud == HUD_NORMAL)
137         if(switchweapon == activeweapon)
138         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
139                 zoomdir += button_attack2;
140         if(spectatee_status > 0 || isdemo())
141         {
142                 if(spectatorbutton_zoom)
143                 {
144                         if(zoomdir)
145                                 zoomdir = 0;
146                         else
147                                 zoomdir = 1;
148                 }
149                 // fteqcc failed twice here already, don't optimize this
150         }
151
152         if(zoomdir) { zoomin_effect = 0; }
153
154         if(camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else if(autocvar_cl_spawnzoom && zoomin_effect)
159         {
160                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
161
162                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
163                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
164                 if(current_viewzoom == 1) { zoomin_effect = 0; }
165         }
166         else
167         {
168                 if(zoomspeed < 0) // instant zoom
169                 {
170                         if(zoomdir)
171                                 current_viewzoom = 1 / zoomfactor;
172                         else
173                                 current_viewzoom = 1;
174                 }
175                 else
176                 {
177                         if(zoomdir)
178                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
179                         else
180                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
181                 }
182         }
183
184         if(almost_equals(current_viewzoom, 1))
185                 current_zoomfraction = 0;
186         else if(almost_equals(current_viewzoom, 1/zoomfactor))
187                 current_zoomfraction = 1;
188         else
189                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
190
191         if(zoomsensitivity < 1)
192                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
193         else
194                 setsensitivityscale(1);
195
196         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
197         {
198                 if(intermission) { curspeed = 0; }
199                 else
200                 {
201
202                         makevectors(view_angles);
203                         v = pmove_vel;
204                         if(csqcplayer)
205                                 v = csqcplayer.velocity;
206
207                         switch(autocvar_cl_velocityzoom_type)
208                         {
209                                 case 3: curspeed = max(0, v_forward * v); break;
210                                 case 2: curspeed = (v_forward * v); break;
211                                 case 1: default: curspeed = vlen(v); break;
212                         }
213                 }
214
215                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
216                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
217                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
218
219                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
220         }
221         else
222                 velocityzoom = 1;
223
224         float frustumx, frustumy, fovx, fovy;
225         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
226         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
227         fovx = atan2(frustumx, 1) / M_PI * 360.0;
228         fovy = atan2(frustumy, 1) / M_PI * 360.0;
229
230         return '1 0 0' * fovx + '0 1 0' * fovy;
231 }
232
233 vector GetViewLocationFOV(float fov)
234 {
235         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
236         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
237         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
238         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
239         return '1 0 0' * fovx + '0 1 0' * fovy;
240 }
241
242 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
243 {
244         float fovx, fovy;
245         float width = (ov_worldmax.x - ov_worldmin.x);
246         float height = (ov_worldmax.y - ov_worldmin.y);
247         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
248         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
249         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
250         return '1 0 0' * fovx + '0 1 0' * fovy;
251 }
252
253 // this function must match W_SetupShot!
254 float zoomscript_caught;
255
256 vector wcross_origin;
257 float wcross_scale_prev, wcross_alpha_prev;
258 vector wcross_color_prev;
259 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
260 vector wcross_color_goal_prev;
261 float wcross_changedonetime;
262
263 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
264 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
265 float wcross_name_changestarttime, wcross_name_changedonetime;
266 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
267
268 float wcross_ring_prev;
269
270 entity trueaim;
271 entity trueaim_rifle;
272
273 const float SHOTTYPE_HITTEAM = 1;
274 const float SHOTTYPE_HITOBSTRUCTION = 2;
275 const float SHOTTYPE_HITWORLD = 3;
276 const float SHOTTYPE_HITENEMY = 4;
277
278 void TrueAim_Init()
279 {
280         trueaim = new(trueaim);
281         make_pure(trueaim);
282         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
283         trueaim_rifle = new(trueaim_rifle);
284         make_pure(trueaim_rifle);
285         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
286 }
287
288 float EnemyHitCheck()
289 {
290         float t, n;
291         wcross_origin = project_3d_to_2d(trace_endpos);
292         wcross_origin.z = 0;
293         if(trace_ent)
294                 n = trace_ent.entnum;
295         else
296                 n = trace_networkentity;
297         if(n < 1)
298                 return SHOTTYPE_HITWORLD;
299         if(n > maxclients)
300                 return SHOTTYPE_HITWORLD;
301         t = GetPlayerColor(n - 1);
302         if(teamplay)
303                 if(t == myteam)
304                         return SHOTTYPE_HITTEAM;
305         if(t == NUM_SPECTATOR)
306                 return SHOTTYPE_HITWORLD;
307         return SHOTTYPE_HITENEMY;
308 }
309
310 float TrueAimCheck()
311 {
312         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
313         vector vecs, trueaimpoint, w_shotorg;
314         vector mi, ma, dv;
315         float shottype;
316         entity ta;
317         float mv;
318
319         mi = ma = '0 0 0';
320         ta = trueaim;
321         mv = MOVE_NOMONSTERS;
322
323         switch(activeweapon) // WEAPONTODO
324         {
325                 case WEP_TUBA.m_id: // no aim
326                 case WEP_PORTO.m_id: // shoots from eye
327                 case WEP_NEXBALL.m_id: // shoots from eye
328                 case WEP_HOOK.m_id: // no trueaim
329                 case WEP_MORTAR.m_id: // toss curve
330                         return SHOTTYPE_HITWORLD;
331                 case WEP_VORTEX.m_id:
332                 case WEP_VAPORIZER.m_id:
333                         mv = MOVE_NORMAL;
334                         break;
335                 case WEP_RIFLE.m_id:
336                         ta = trueaim_rifle;
337                         mv = MOVE_NORMAL;
338                         if(zoomscript_caught)
339                         {
340                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
341                                 return EnemyHitCheck();
342                         }
343                         break;
344                 case WEP_DEVASTATOR.m_id: // projectile has a size!
345                         mi = '-3 -3 -3';
346                         ma = '3 3 3';
347                         break;
348                 case WEP_FIREBALL.m_id: // projectile has a size!
349                         mi = '-16 -16 -16';
350                         ma = '16 16 16';
351                         break;
352                 case WEP_SEEKER.m_id: // projectile has a size!
353                         mi = '-2 -2 -2';
354                         ma = '2 2 2';
355                         break;
356                 case WEP_ELECTRO.m_id: // projectile has a size!
357                         mi = '0 0 -3';
358                         ma = '0 0 -3';
359                         break;
360         }
361
362         vector traceorigin = entcs_receiver[player_localentnum - 1].origin + (eZ * getstati(STAT_VIEWHEIGHT));
363
364         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
365
366         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
367         trueaimpoint = trace_endpos;
368
369         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
370                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
371
372         if(vecs.x > 0)
373                 vecs.y = -vecs.y;
374         else
375                 vecs = '0 0 0';
376
377         dv = view_right * vecs.y + view_up * vecs.z;
378         w_shotorg = traceorigin + dv;
379
380         // now move the vecs forward as much as requested if possible
381         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
382         w_shotorg = trace_endpos - view_forward * nudge;
383
384         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
385         shottype = EnemyHitCheck();
386         if(shottype != SHOTTYPE_HITWORLD)
387                 return shottype;
388
389 #if 0
390         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
391         // or rather, I know why, but see no fix
392         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
393                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
394                 return SHOTTYPE_HITOBSTRUCTION;
395 #endif
396
397         return SHOTTYPE_HITWORLD;
398 }
399
400 void PostInit();
401 void CSQC_Demo_Camera();
402 float HUD_WouldDrawScoreboard();
403 float camera_mode;
404 const float CAMERA_FREE = 1;
405 const float CAMERA_CHASE = 2;
406 float reticle_type;
407 string reticle_image;
408 string NextFrameCommand;
409
410 vector freeze_org, freeze_ang;
411 entity nightvision_noise, nightvision_noise2;
412
413 const float MAX_TIME_DIFF = 5;
414 float pickup_crosshair_time, pickup_crosshair_size;
415 float hitindication_crosshair_size;
416 float use_vortex_chargepool;
417
418 float myhealth, myhealth_prev;
419 float myhealth_flash;
420
421 float old_blurradius, old_bluralpha;
422 float old_sharpen_intensity;
423
424 vector myhealth_gentlergb;
425
426 float contentavgalpha, liquidalpha_prev;
427 vector liquidcolor_prev;
428
429 float eventchase_current_distance;
430 float eventchase_running;
431 bool WantEventchase()
432 {SELFPARAM();
433         if(autocvar_cl_orthoview)
434                 return false;
435         if(intermission)
436                 return true;
437         if(self.viewloc)
438                 return true;
439         if(spectatee_status >= 0)
440         {
441                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
442                         return true;
443                 if(MUTATOR_CALLHOOK(WantEventchase, self))
444                         return true;
445                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
446                         return true;
447                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
448                 {
449                         if(autocvar_cl_eventchase_death == 2)
450                         {
451                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
452                                 if(self.velocity == '0 0 0' || eventchase_running)
453                                         return true;
454                         }
455                         else return true;
456                 }
457         }
458         return false;
459 }
460
461 void HUD_Crosshair_Vehicle()
462 {
463         if(hud != HUD_BUMBLEBEE_GUN)
464         {
465                 Vehicle info = get_vehicleinfo(hud);
466                 info.vr_crosshair(info);
467         }
468 }
469
470 vector damage_blurpostprocess, content_blurpostprocess;
471
472 float unaccounted_damage = 0;
473 void UpdateDamage()
474 {
475         // accumulate damage with each stat update
476         static float damage_total_prev = 0;
477         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
478         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
479         damage_total_prev = damage_total;
480
481         static float damage_dealt_time_prev = 0;
482         float damage_dealt_time = getstatf(STAT_HIT_TIME);
483         if (damage_dealt_time != damage_dealt_time_prev)
484         {
485                 unaccounted_damage += unaccounted_damage_new;
486                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
487         }
488         damage_dealt_time_prev = damage_dealt_time;
489
490         // prevent hitsound when switching spectatee
491         static float spectatee_status_prev = 0;
492         if (spectatee_status != spectatee_status_prev)
493                 unaccounted_damage = 0;
494         spectatee_status_prev = spectatee_status;
495 }
496
497 void HitSound()
498 {
499         // varying sound pitch
500
501         static float hitsound_time_prev = 0;
502         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
503         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
504         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
505         {
506                 if (autocvar_cl_hitsound && unaccounted_damage)
507                 {
508                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
509                         float a = autocvar_cl_hitsound_max_pitch;
510                         float b = autocvar_cl_hitsound_min_pitch;
511                         float c = autocvar_cl_hitsound_nom_damage;
512                         float x = unaccounted_damage;
513                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
514
515                         // if sound variation is disabled, set pitch_shift to 1
516                         if (autocvar_cl_hitsound == 1)
517                                 pitch_shift = 1;
518
519                         // if pitch shift is reversed, mirror in (max-min)/2 + min
520                         if (autocvar_cl_hitsound == 3)
521                         {
522                                 float mirror_value = (a-b)/2 + b;
523                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
524                         }
525
526                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
527
528                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
529                         // todo: normalize sound pressure levels? seems unnecessary
530
531                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
532                 }
533                 unaccounted_damage = 0;
534                 hitsound_time_prev = time;
535         }
536
537         static float typehit_time_prev = 0;
538         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
539         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
540         {
541                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
542                 typehit_time_prev = typehit_time;
543         }
544 }
545
546 void HUD_Crosshair()
547 {SELFPARAM();
548         static float rainbow_last_flicker;
549         static vector rainbow_prev_color;
550         entity e = self;
551         float f, i, j;
552         vector v;
553         if(!scoreboard_active && !camera_active && intermission != 2 &&
554                 spectatee_status != -1 && !csqcplayer.viewloc &&
555                 !HUD_MinigameMenu_IsOpened() )
556         {
557                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
558                         return;
559
560                 if (hud != HUD_NORMAL)
561                 {
562                         HUD_Crosshair_Vehicle();
563                         return;
564                 }
565
566                 string wcross_style;
567                 float wcross_alpha, wcross_resolution;
568                 wcross_style = autocvar_crosshair;
569                 if (wcross_style == "0")
570                         return;
571                 wcross_resolution = autocvar_crosshair_size;
572                 if (wcross_resolution == 0)
573                         return;
574                 wcross_alpha = autocvar_crosshair_alpha;
575                 if (wcross_alpha == 0)
576                         return;
577
578                 // TrueAim check
579                 float shottype;
580
581                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
582                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
583                 wcross_origin.z = 0;
584                 if(autocvar_crosshair_hittest)
585                 {
586                         vector wcross_oldorigin;
587                         wcross_oldorigin = wcross_origin;
588                         shottype = TrueAimCheck();
589                         if(shottype == SHOTTYPE_HITWORLD)
590                         {
591                                 v = wcross_origin - wcross_oldorigin;
592                                 v.x /= vid_conwidth;
593                                 v.y /= vid_conheight;
594                                 if(vlen(v) > 0.01)
595                                         shottype = SHOTTYPE_HITOBSTRUCTION;
596                         }
597                         if(!autocvar_crosshair_hittest_showimpact)
598                                 wcross_origin = wcross_oldorigin;
599                 }
600                 else
601                         shottype = SHOTTYPE_HITWORLD;
602
603                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
604                 string wcross_name = "";
605                 float wcross_scale, wcross_blur;
606
607                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
608                 {
609                         e = get_weaponinfo(switchingweapon);
610                         if(e)
611                         {
612                                 if(autocvar_crosshair_per_weapon)
613                                 {
614                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
615                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
616                                         //if (wcross_resolution == 0)
617                                                 //return;
618
619                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
620                                         wcross_resolution *= e.w_crosshair_size;
621                                         wcross_name = e.w_crosshair;
622                                 }
623                         }
624                 }
625
626                 if(wcross_name == "")
627                         wcross_name = strcat("gfx/crosshair", wcross_style);
628
629                 // MAIN CROSSHAIR COLOR DECISION
630                 switch(autocvar_crosshair_color_special)
631                 {
632                         case 1: // crosshair_color_per_weapon
633                         {
634                                 if(e)
635                                 {
636                                         wcross_color = e.wpcolor;
637                                         break;
638                                 }
639                                 else { goto normalcolor; }
640                         }
641
642                         case 2: // crosshair_color_by_health
643                         {
644                                 float x = getstati(STAT_HEALTH);
645
646                                 //x = red
647                                 //y = green
648                                 //z = blue
649
650                                 wcross_color.z = 0;
651
652                                 if(x > 200)
653                                 {
654                                         wcross_color.x = 0;
655                                         wcross_color.y = 1;
656                                 }
657                                 else if(x > 150)
658                                 {
659                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
660                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
661                                 }
662                                 else if(x > 100)
663                                 {
664                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
665                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
666                                         wcross_color.z = 1 - (x-100)*0.02;
667                                 }
668                                 else if(x > 50)
669                                 {
670                                         wcross_color.x = 1;
671                                         wcross_color.y = 1;
672                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
673                                 }
674                                 else if(x > 20)
675                                 {
676                                         wcross_color.x = 1;
677                                         wcross_color.y = (x-20)*90/27/100;
678                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
679                                 }
680                                 else
681                                 {
682                                         wcross_color.x = 1;
683                                         wcross_color.y = 0;
684                                 }
685                                 break;
686                         }
687
688                         case 3: // crosshair_color_rainbow
689                         {
690                                 if(time >= rainbow_last_flicker)
691                                 {
692                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
693                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
694                                 }
695                                 wcross_color = rainbow_prev_color;
696                                 break;
697                         }
698                         :normalcolor
699                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
700                 }
701
702                 if(autocvar_crosshair_effect_scalefade)
703                 {
704                         wcross_scale = wcross_resolution;
705                         wcross_resolution = 1;
706                 }
707                 else
708                 {
709                         wcross_scale = 1;
710                 }
711
712                 if(autocvar_crosshair_pickup)
713                 {
714                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
715
716                         if(pickup_crosshair_time < stat_pickup_time)
717                         {
718                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
719                                         pickup_crosshair_size = 1;
720
721                                 pickup_crosshair_time = stat_pickup_time;
722                         }
723
724                         if(pickup_crosshair_size > 0)
725                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
726                         else
727                                 pickup_crosshair_size = 0;
728
729                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
730                 }
731
732                 // todo: make crosshair hit indication dependent on damage dealt
733                 if(autocvar_crosshair_hitindication)
734                 {
735                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
736
737                         if(unaccounted_damage)
738                         {
739                                 hitindication_crosshair_size = 1;
740                         }
741
742                         if(hitindication_crosshair_size > 0)
743                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
744                         else
745                                 hitindication_crosshair_size = 0;
746
747                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
748                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
749                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
750                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
751                 }
752
753                 if(shottype == SHOTTYPE_HITENEMY)
754                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
755                 if(shottype == SHOTTYPE_HITTEAM)
756                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
757
758                 f = fabs(autocvar_crosshair_effect_time);
759                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
760                 {
761                         wcross_changedonetime = time + f;
762                 }
763                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
764                 {
765                         wcross_name_changestarttime = time;
766                         wcross_name_changedonetime = time + f;
767                         if(wcross_name_goal_prev_prev)
768                                 strunzone(wcross_name_goal_prev_prev);
769                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
770                         wcross_name_goal_prev = strzone(wcross_name);
771                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
772                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
773                         wcross_resolution_goal_prev = wcross_resolution;
774                 }
775
776                 wcross_scale_goal_prev = wcross_scale;
777                 wcross_alpha_goal_prev = wcross_alpha;
778                 wcross_color_goal_prev = wcross_color;
779
780                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
781                 {
782                         wcross_blur = 1;
783                         wcross_alpha *= 0.75;
784                 }
785                 else
786                         wcross_blur = 0;
787                 // *_prev is at time-frametime
788                 // * is at wcross_changedonetime+f
789                 // what do we have at time?
790                 if(time < wcross_changedonetime)
791                 {
792                         f = frametime / (wcross_changedonetime - time + frametime);
793                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
794                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
795                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
796                 }
797
798                 wcross_scale_prev = wcross_scale;
799                 wcross_alpha_prev = wcross_alpha;
800                 wcross_color_prev = wcross_color;
801
802                 MUTATOR_CALLHOOK(UpdateCrosshair);
803
804                 wcross_scale *= 1 - autocvar__menu_alpha;
805                 wcross_alpha *= 1 - autocvar__menu_alpha;
806                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
807
808                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
809                 {
810                         // crosshair rings for weapon stats
811                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
812                         {
813                                 // declarations and stats
814                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
815                                 string ring_image = string_null, ring_inner_image = string_null;
816                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
817
818                                 ring_scale = autocvar_crosshair_ring_size;
819
820                                 float weapon_clipload, weapon_clipsize;
821                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
822                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
823
824                                 float ok_ammo_charge, ok_ammo_chargepool;
825                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
826                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
827
828                                 float vortex_charge, vortex_chargepool;
829                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
830                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
831
832                                 float arc_heat = STAT(ARC_HEAT);
833
834                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
835                                         vortex_charge_movingavg = vortex_charge;
836
837
838                                 // handle the values
839                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
840                                 {
841                                         if (vortex_chargepool || use_vortex_chargepool) {
842                                                 use_vortex_chargepool = 1;
843                                                 ring_inner_value = vortex_chargepool;
844                                         } else {
845                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
846                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
847                                         }
848
849                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
850                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
851                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
852
853                                         // draw the outer ring to show the current charge of the weapon
854                                         ring_value = vortex_charge;
855                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
856                                         ring_rgb = wcross_color;
857                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
858                                 }
859                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
860                                 {
861                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
862                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
863                                         ring_rgb = wcross_color;
864                                         ring_image = "gfx/crosshair_ring.tga";
865                                 }
866                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
867                                 {
868                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
869                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
870                                         ring_rgb = wcross_color;
871                                         ring_image = "gfx/crosshair_ring.tga";
872                                 }
873                                 else if (ok_ammo_charge)
874                                 {
875                                         ring_value = ok_ammo_chargepool;
876                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
877                                         ring_rgb = wcross_color;
878                                         ring_image = "gfx/crosshair_ring.tga";
879                                 }
880                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
881                                 {
882                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
883                                         ring_scale = autocvar_crosshair_ring_reload_size;
884                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
885                                         ring_rgb = wcross_color;
886
887                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
888                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
889                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
890                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
891                                         else
892                                                 ring_image = "gfx/crosshair_ring.tga";
893                                 }
894                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
895                                 {
896                                         ring_value = arc_heat;
897                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
898                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
899                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
900                                         ring_image = "gfx/crosshair_ring.tga";
901                                 }
902
903                                 // if in weapon switch animation, fade ring out/in
904                                 if(autocvar_crosshair_effect_time > 0)
905                                 {
906                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
907                                         if (f >= 1)
908                                         {
909                                                 wcross_ring_prev = ((ring_image) ? true : false);
910                                         }
911
912                                         if(wcross_ring_prev)
913                                         {
914                                                 if(f < 1)
915                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
916                                         }
917                                         else
918                                         {
919                                                 if(f < 1)
920                                                         ring_alpha *= bound(0, f, 1);
921                                         }
922                                 }
923
924                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
925                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
926
927                                 if (ring_value)
928                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
929                         }
930
931 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
932                         do \
933                         { \
934                                 if(wcross_blur > 0) \
935                                 { \
936                                         for(i = -2; i <= 2; ++i) \
937                                         for(j = -2; j <= 2; ++j) \
938                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
939                                 } \
940                                 else \
941                                 { \
942                                         M(0,0,sz,wcross_name,wcross_alpha); \
943                                 } \
944                         } \
945                         while(0)
946
947 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
948                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
949
950 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
951                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
952
953                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
954                         {
955                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
956                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
957                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
958                                 f = 1 - f;
959                         }
960                         else
961                         {
962                                 f = 1;
963                         }
964                         wcross_name_alpha_goal_prev = f;
965
966                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
967                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
968
969                         if(autocvar_crosshair_dot)
970                         {
971                                 vector wcross_color_old;
972                                 wcross_color_old = wcross_color;
973
974                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
975                                         wcross_color = stov(autocvar_crosshair_dot_color);
976
977                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
978                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
979                                 wcross_color = wcross_color_old;
980                         }
981                 }
982         }
983         else
984         {
985                 wcross_scale_prev = 0;
986                 wcross_alpha_prev = 0;
987                 wcross_scale_goal_prev = 0;
988                 wcross_alpha_goal_prev = 0;
989                 wcross_changedonetime = 0;
990                 if(wcross_name_goal_prev)
991                         strunzone(wcross_name_goal_prev);
992                 wcross_name_goal_prev = string_null;
993                 if(wcross_name_goal_prev_prev)
994                         strunzone(wcross_name_goal_prev_prev);
995                 wcross_name_goal_prev_prev = string_null;
996                 wcross_name_changestarttime = 0;
997                 wcross_name_changedonetime = 0;
998                 wcross_name_alpha_goal_prev = 0;
999                 wcross_name_alpha_goal_prev_prev = 0;
1000                 wcross_resolution_goal_prev = 0;
1001                 wcross_resolution_goal_prev_prev = 0;
1002         }
1003 }
1004
1005 void HUD_Draw()
1006 {
1007         vector rgb = '0 0 0';
1008         float a = 1;
1009         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1010         {
1011                 rgb = MUTATOR_ARGV(0, vector);
1012                 a = MUTATOR_ARGV(0, float);
1013         }
1014         else if(getstati(STAT_FROZEN))
1015         {
1016                 rgb = ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1017         }
1018         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1019         if(!intermission)
1020         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1021         {
1022                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1023                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1024         }
1025         else if(getstatf(STAT_REVIVE_PROGRESS))
1026         {
1027                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1028                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1029         }
1030
1031         if(autocvar_r_letterbox == 0)
1032                 if(autocvar_viewsize < 120)
1033                 {
1034                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1035                                 Accuracy_LoadLevels();
1036
1037                         HUD_Main();
1038                         HUD_DrawScoreboard();
1039                 }
1040
1041         // crosshair goes VERY LAST
1042         UpdateDamage();
1043         HUD_Crosshair();
1044         HitSound();
1045 }
1046
1047 bool ov_enabled;
1048 float oldr_nearclip;
1049 float oldr_farclip_base;
1050 float oldr_farclip_world;
1051 float oldr_novis;
1052 float oldr_useportalculling;
1053 float oldr_useinfinitefarclip;
1054
1055 const int BUTTON_3 = 4;
1056 const int BUTTON_4 = 8;
1057 float cl_notice_run();
1058 float prev_myteam;
1059 int lasthud;
1060 float vh_notice_time;
1061 void WaypointSprite_Load();
1062 void CSQC_UpdateView(float w, float h)
1063 {SELFPARAM();
1064         entity e;
1065         float fov;
1066         float f;
1067         vector vf_size, vf_min;
1068         float a;
1069
1070         execute_next_frame();
1071
1072         ++framecount;
1073
1074         stats_get();
1075         hud = getstati(STAT_HUD);
1076
1077         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1078                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1079
1080         lasthud = hud;
1081
1082         if(autocvar__hud_showbinds_reload) // menu can set this one
1083         {
1084                 db_close(binddb);
1085                 binddb = db_create();
1086                 cvar_set("_hud_showbinds_reload", "0");
1087         }
1088
1089         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1090                 view_quality = getproperty(VF_MINFPS_QUALITY);
1091         else
1092                 view_quality = 1;
1093
1094         button_attack2 = (input_buttons & BUTTON_3);
1095         button_zoom = (input_buttons & BUTTON_4);
1096
1097         vf_size = getpropertyvec(VF_SIZE);
1098         vf_min = getpropertyvec(VF_MIN);
1099         vid_width = vf_size.x;
1100         vid_height = vf_size.y;
1101
1102         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1103         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1104
1105         WaypointSprite_Load();
1106
1107         CSQCPlayer_SetCamera();
1108
1109         if(player_localentnum <= maxclients) // is it a client?
1110                 current_player = player_localentnum - 1;
1111         else // then player_localentnum is the vehicle I'm driving
1112                 current_player = player_localnum;
1113         myteam = GetPlayerColor(current_player);
1114
1115         if(myteam != prev_myteam)
1116         {
1117                 myteamcolors = colormapPaletteColor(myteam, 1);
1118                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1119                 prev_myteam = myteam;
1120         }
1121
1122         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1123
1124         float is_dead = (getstati(STAT_HEALTH) <= 0);
1125
1126         // FIXME do we need this hack?
1127         if(isdemo())
1128         {
1129                 // in demos, input_buttons do not work
1130                 button_zoom = (autocvar__togglezoom == "-");
1131         }
1132         else if(button_zoom
1133                 && autocvar_cl_unpress_zoom_on_death
1134                 && (spectatee_status >= 0)
1135                 && (is_dead || intermission))
1136         {
1137                 // no zoom while dead or in intermission please
1138                 localcmd("-zoom\n");
1139                 button_zoom = false;
1140         }
1141
1142         // event chase camera
1143         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1144         {
1145                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1146                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1147                 entity gen = world;
1148
1149                 if(ons_roundlost)
1150                 {
1151                         entity e;
1152                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1153                         {
1154                                 if(e.health <= 0)
1155                                 {
1156                                         gen = e;
1157                                         break;
1158                                 }
1159                         }
1160                         if(!gen)
1161                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1162                 }
1163                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1164                 {
1165                         eventchase_running = true;
1166
1167                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1168                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1169                         if(ons_roundlost) { current_view_origin = gen.origin; }
1170
1171                         // detect maximum viewoffset and use it
1172                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1173                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1174                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1175
1176                         if(view_offset)
1177                         {
1178                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1179                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1180                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1181                         }
1182
1183                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1184                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1185                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1186                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1187
1188                         // make the camera smooth back
1189                         float chase_distance = autocvar_cl_eventchase_distance;
1190                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1191                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1192
1193                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1194                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1195                         else if(eventchase_current_distance != chase_distance)
1196                                 eventchase_current_distance = chase_distance;
1197
1198                         makevectors(view_angles);
1199
1200                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1201                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1202
1203                         // If the boxtrace fails, revert back to line tracing.
1204                         if(!self.viewloc)
1205                         if(trace_startsolid)
1206                         {
1207                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1208                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1209                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1210                         }
1211                         else { setproperty(VF_ORIGIN, trace_endpos); }
1212
1213                         if(!self.viewloc)
1214                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1215                 }
1216                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1217                 {
1218                         eventchase_running = false;
1219                         cvar_set("chase_active", "0");
1220                         eventchase_current_distance = 0; // start from 0 next time
1221                 }
1222         }
1223         // workaround for camera stuck between player's legs when using chase_active 1
1224         // because the engine stops updating the chase_active camera when the game ends
1225         else if(intermission)
1226         {
1227                 cvar_settemp("chase_active", "-1");
1228                 eventchase_current_distance = 0;
1229         }
1230
1231         // do lockview after event chase camera so that it still applies whenever necessary.
1232         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1233         {
1234                 setproperty(VF_ORIGIN, freeze_org);
1235                 setproperty(VF_ANGLES, freeze_ang);
1236         }
1237         else
1238         {
1239                 freeze_org = getpropertyvec(VF_ORIGIN);
1240                 freeze_ang = getpropertyvec(VF_ANGLES);
1241         }
1242
1243         WarpZone_FixView();
1244         //WarpZone_FixPMove();
1245
1246         vector ov_org = '0 0 0';
1247         vector ov_mid = '0 0 0';
1248         vector ov_worldmin = '0 0 0';
1249         vector ov_worldmax = '0 0 0';
1250         if(autocvar_cl_orthoview)
1251         {
1252                 ov_worldmin = mi_picmin;
1253                 ov_worldmax = mi_picmax;
1254
1255                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1256                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1257                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1258
1259                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1260                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1261
1262                 float ov_nearest = vlen(ov_org - vec3(
1263                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1264                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1265                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1266                 ));
1267
1268                 float ov_furthest = 0;
1269                 float dist = 0;
1270
1271                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1272                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1273                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1274                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1275                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1276                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1277                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1278                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1279
1280                 if(!ov_enabled)
1281                 {
1282                         oldr_nearclip = cvar("r_nearclip");
1283                         oldr_farclip_base = cvar("r_farclip_base");
1284                         oldr_farclip_world = cvar("r_farclip_world");
1285                         oldr_novis = cvar("r_novis");
1286                         oldr_useportalculling = cvar("r_useportalculling");
1287                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1288                 }
1289
1290                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1291                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1292                 cvar_settemp("r_farclip_world", "0");
1293                 cvar_settemp("r_novis", "1");
1294                 cvar_settemp("r_useportalculling", "0");
1295                 cvar_settemp("r_useinfinitefarclip", "0");
1296
1297                 setproperty(VF_ORIGIN, ov_org);
1298                 setproperty(VF_ANGLES, '90 0 0');
1299
1300                 ov_enabled = true;
1301
1302                 #if 0
1303                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1304                         vtos(ov_org),
1305                         vtos(getpropertyvec(VF_ANGLES)),
1306                         ov_distance,
1307                         ov_nearest,
1308                         ov_furthest);
1309                 #endif
1310         }
1311         else
1312         {
1313                 if(ov_enabled)
1314                 {
1315                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1316                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1317                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1318                         cvar_set("r_novis", ftos(oldr_novis));
1319                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1320                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1321                 }
1322                 ov_enabled = false;
1323         }
1324
1325         // Render the Scene
1326         view_origin = getpropertyvec(VF_ORIGIN);
1327         view_angles = getpropertyvec(VF_ANGLES);
1328         makevectors(view_angles);
1329         view_forward = v_forward;
1330         view_right = v_right;
1331         view_up = v_up;
1332
1333 #ifdef BLURTEST
1334         if(time > blurtest_time0 && time < blurtest_time1)
1335         {
1336                 float r, t;
1337
1338                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1339                 r = t * blurtest_radius;
1340                 f = 1 / pow(t, blurtest_power) - 1;
1341
1342                 cvar_set("r_glsl_postprocess", "1");
1343                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1344         }
1345         else
1346         {
1347                 cvar_set("r_glsl_postprocess", "0");
1348                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1349         }
1350 #endif
1351
1352         TargetMusic_Advance();
1353         Fog_Force();
1354
1355         if(drawtime == 0)
1356                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1357         else
1358                 drawframetime = bound(0.000001, time - drawtime, 1);
1359         drawtime = time;
1360
1361         // watch for gametype changes here...
1362         // in ParseStuffCMD the cmd isn't executed yet :/
1363         // might even be better to add the gametype to TE_CSQC_INIT...?
1364         if(!postinit)
1365                 PostInit();
1366
1367         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1368         {
1369                 if(calledhooks & HOOK_START)
1370                 {
1371                         localcmd("\ncl_hook_gameend\n");
1372                         calledhooks |= HOOK_END;
1373                 }
1374         }
1375
1376         Announcer();
1377
1378         fov = autocvar_fov;
1379         if(fov <= 59.5)
1380         {
1381                 if(!zoomscript_caught)
1382                 {
1383                         localcmd("+button9\n");
1384                         zoomscript_caught = 1;
1385                 }
1386         }
1387         else
1388         {
1389                 if(zoomscript_caught)
1390                 {
1391                         localcmd("-button9\n");
1392                         zoomscript_caught = 0;
1393                 }
1394         }
1395
1396         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1397
1398         // currently switching-to weapon (for crosshair)
1399         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1400
1401         // actually active weapon (for zoom)
1402         activeweapon = getstati(STAT_ACTIVEWEAPON);
1403
1404         f = (serverflags & SERVERFLAG_TEAMPLAY);
1405         if(f != teamplay)
1406         {
1407                 teamplay = f;
1408                 HUD_InitScores();
1409         }
1410
1411         if(last_switchweapon != switchweapon)
1412         {
1413                 weapontime = time;
1414                 last_switchweapon = switchweapon;
1415                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1416                 {
1417                         localcmd("-zoom\n");
1418                         button_zoom = false;
1419                 }
1420                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1421                 {
1422                         localcmd("-fire\n");
1423                         localcmd("-fire2\n");
1424                         button_attack2 = false;
1425                 }
1426         }
1427         if(last_activeweapon != activeweapon)
1428         {
1429                 last_activeweapon = activeweapon;
1430
1431                 e = get_weaponinfo(activeweapon);
1432                 if(e.netname != "")
1433                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1434                 else
1435                         localcmd("\ncl_hook_activeweapon none\n");
1436         }
1437
1438         // ALWAYS Clear Current Scene First
1439         clearscene();
1440
1441         setproperty(VF_ORIGIN, view_origin);
1442         setproperty(VF_ANGLES, view_angles);
1443
1444         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1445         setproperty(VF_SIZE, vf_size);
1446         setproperty(VF_MIN, vf_min);
1447
1448         // Assign Standard Viewflags
1449         // Draw the World (and sky)
1450         setproperty(VF_DRAWWORLD, 1);
1451
1452         // Set the console size vars
1453         vid_conwidth = autocvar_vid_conwidth;
1454         vid_conheight = autocvar_vid_conheight;
1455         vid_pixelheight = autocvar_vid_pixelheight;
1456
1457         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1458         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1459         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1460
1461         // Camera for demo playback
1462         if(camera_active)
1463         {
1464                 if(autocvar_camera_enable)
1465                         CSQC_Demo_Camera();
1466                 else
1467                 {
1468                         cvar_set("chase_active", ftos(chase_active_backup));
1469                         cvar_set("cl_demo_mousegrab", "0");
1470                         camera_active = false;
1471                 }
1472         }
1473         else
1474         {
1475 #ifdef CAMERATEST
1476                 if(autocvar_camera_enable)
1477 #else
1478                 if(autocvar_camera_enable && isdemo())
1479 #endif
1480                 {
1481                         // Enable required Darkplaces cvars
1482                         chase_active_backup = autocvar_chase_active;
1483                         cvar_set("chase_active", "2");
1484                         cvar_set("cl_demo_mousegrab", "1");
1485                         camera_active = true;
1486                         camera_mode = false;
1487                 }
1488         }
1489
1490         // Draw the Crosshair
1491         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1492
1493         // Draw the Engine Status Bar (the default Quake HUD)
1494         setproperty(VF_DRAWENGINESBAR, 0);
1495
1496         // Update the mouse position
1497         /*
1498            mousepos_x = vid_conwidth;
1499            mousepos_y = vid_conheight;
1500            mousepos = mousepos*0.5 + getmousepos();
1501          */
1502
1503         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1504
1505         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1506         renderscene();
1507
1508         // now switch to 2D drawing mode by calling a 2D drawing function
1509         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1510         // next R_RenderScene call
1511         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1512
1513         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1514         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1515         {
1516                 // apply night vision effect
1517                 vector tc_00, tc_01, tc_10, tc_11;
1518                 vector rgb = '0 0 0';
1519
1520                 if(!nightvision_noise)
1521                 {
1522                         nightvision_noise = new(nightvision_noise);
1523                 }
1524                 if(!nightvision_noise2)
1525                 {
1526                         nightvision_noise2 = new(nightvision_noise2);
1527                 }
1528
1529                 // color tint in yellow
1530                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1531
1532                 // draw BG
1533                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1534                 rgb = '1 1 1';
1535                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1536                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1537                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1538                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1539                 tc_11 = tc_01 + tc_10 - tc_00;
1540                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1541                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1542                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1543                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1544                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1545                 R_EndPolygon();
1546
1547                 // draw FG
1548                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1549                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1550                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1551                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1552                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1553                 tc_11 = tc_01 + tc_10 - tc_00;
1554                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1555                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1556                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1557                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1558                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1559                 R_EndPolygon();
1560         }
1561
1562         if(autocvar_cl_reticle)
1563         {
1564                 Weapon wep = get_weaponinfo(activeweapon);
1565                 // Draw the aiming reticle for weapons that use it
1566                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1567                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1568                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1569                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1570                 {
1571                         // no zoom reticle while dead
1572                         reticle_type = 0;
1573                 }
1574                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1575                 {
1576                         if(reticle_image != "") { reticle_type = 2; }
1577                         else { reticle_type = 0; }
1578                 }
1579                 else if(button_zoom || zoomscript_caught)
1580                 {
1581                         // normal zoom
1582                         reticle_type = 1;
1583                 }
1584
1585                 if(reticle_type)
1586                 {
1587                         if(autocvar_cl_reticle_stretch)
1588                         {
1589                                 reticle_size.x = vid_conwidth;
1590                                 reticle_size.y = vid_conheight;
1591                                 reticle_pos.x = 0;
1592                                 reticle_pos.y = 0;
1593                         }
1594                         else
1595                         {
1596                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1597                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1598                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1599                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1600                         }
1601
1602                         if(zoomscript_caught)
1603                                 f = 1;
1604                         else
1605                                 f = current_zoomfraction;
1606
1607                         if(f)
1608                         {
1609                                 switch(reticle_type)
1610                                 {
1611                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1612                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1613                                 }
1614                         }
1615                 }
1616         }
1617         else
1618         {
1619                 if(reticle_type != 0) { reticle_type = 0; }
1620         }
1621
1622
1623         // improved polyblend
1624         if(autocvar_hud_contents)
1625         {
1626                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1627                 vector liquidcolor;
1628
1629                 switch(pointcontents(view_origin))
1630                 {
1631                         case CONTENT_WATER:
1632                                 liquidalpha = autocvar_hud_contents_water_alpha;
1633                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1634                                 incontent = 1;
1635                                 break;
1636
1637                         case CONTENT_LAVA:
1638                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1639                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1640                                 incontent = 1;
1641                                 break;
1642
1643                         case CONTENT_SLIME:
1644                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1645                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1646                                 incontent = 1;
1647                                 break;
1648
1649                         default:
1650                                 liquidalpha = 0;
1651                                 liquidcolor = '0 0 0';
1652                                 incontent = 0;
1653                                 break;
1654                 }
1655
1656                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1657                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1658                         contentfadetime = autocvar_hud_contents_fadeintime;
1659                         liquidalpha_prev = liquidalpha;
1660                         liquidcolor_prev = liquidcolor;
1661                 }
1662                 else
1663                         contentfadetime = autocvar_hud_contents_fadeouttime;
1664
1665                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1666                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1667
1668                 if(contentavgalpha)
1669                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1670
1671                 if(autocvar_hud_postprocessing)
1672                 {
1673                         if(autocvar_hud_contents_blur && contentavgalpha)
1674                         {
1675                                 content_blurpostprocess.x = 1;
1676                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1677                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1678                         }
1679                         else
1680                         {
1681                                 content_blurpostprocess.x = 0;
1682                                 content_blurpostprocess.y = 0;
1683                                 content_blurpostprocess.z = 0;
1684                         }
1685                 }
1686         }
1687
1688         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1689         {
1690                 splash_size.x = max(vid_conwidth, vid_conheight);
1691                 splash_size.y = max(vid_conwidth, vid_conheight);
1692                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1693                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1694
1695                 float myhealth_flash_temp;
1696                 myhealth = getstati(STAT_HEALTH);
1697
1698                 // fade out
1699                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1700                 // add new damage
1701                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1702
1703                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1704                 pain_threshold = autocvar_hud_damage_pain_threshold;
1705                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1706                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1707
1708                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1709                 {
1710                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1711                 }
1712
1713                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1714
1715                 if(myhealth_prev < 1)
1716                 {
1717                         if(myhealth >= 1)
1718                         {
1719                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1720                                 myhealth_flash_temp = 0;
1721                         }
1722                         else
1723                         {
1724                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1725                         }
1726                 }
1727
1728                 if(spectatee_status == -1 || intermission)
1729                 {
1730                         myhealth_flash = 0; // observing, or match ended
1731                         myhealth_flash_temp = 0;
1732                 }
1733
1734                 myhealth_prev = myhealth;
1735
1736                 // IDEA: change damage color/picture based on player model for robot/alien species?
1737                 // pro: matches model better
1738                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1739                 // maybe different reddish pics?
1740                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1741                 {
1742                         if(autocvar_cl_gentle_damage == 2)
1743                         {
1744                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1745                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1746                         }
1747                         else
1748                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1749
1750                         if(myhealth_flash_temp > 0)
1751                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1752                 }
1753                 else if(myhealth_flash_temp > 0)
1754                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1755
1756                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1757                 {
1758                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1759                         {
1760                                 damage_blurpostprocess.x = 1;
1761                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1762                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1763                         }
1764                         else
1765                         {
1766                                 damage_blurpostprocess.x = 0;
1767                                 damage_blurpostprocess.y = 0;
1768                                 damage_blurpostprocess.z = 0;
1769                         }
1770                 }
1771         }
1772
1773         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1774         float e2 = (autocvar_hud_powerup != 0);
1775         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1776         {
1777                 // enable or disable rendering types if they are used or not
1778                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1779                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1780
1781                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1782                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1783                 {
1784                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1785                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1786                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1787                         {
1788                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1789                                 old_blurradius = blurradius;
1790                                 old_bluralpha = bluralpha;
1791                         }
1792                 }
1793                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1794                 {
1795                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1796                         old_blurradius = 0;
1797                         old_bluralpha = 0;
1798                 }
1799
1800                 // edge detection postprocess handling done second (used by hud_powerup)
1801                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
1802                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1803                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1804
1805                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1806
1807                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1808                 {
1809                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1810                         {
1811                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1812                                 old_sharpen_intensity = sharpen_intensity;
1813                         }
1814                 }
1815                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1816                 {
1817                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1818                         old_sharpen_intensity = 0;
1819                 }
1820
1821                 if(cvar("r_glsl_postprocess") == 0)
1822                         cvar_set("r_glsl_postprocess", "2");
1823         }
1824         else if(cvar("r_glsl_postprocess") == 2)
1825                 cvar_set("r_glsl_postprocess", "0");
1826
1827         /*if(gametype == MAPINFO_TYPE_CTF)
1828           {
1829           ctf_view();
1830           } else */
1831
1832         // draw 2D entities
1833         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
1834         Draw_ShowNames_All();
1835         Debug_Draw();
1836
1837         scoreboard_active = HUD_WouldDrawScoreboard();
1838
1839         HUD_Draw();
1840
1841         if(NextFrameCommand)
1842         {
1843                 localcmd("\n", NextFrameCommand, "\n");
1844                 NextFrameCommand = string_null;
1845         }
1846
1847         // we must do this check AFTER a frame was rendered, or it won't work
1848         if(cs_project_is_b0rked == 0)
1849         {
1850                 string w0, h0;
1851                 w0 = ftos(autocvar_vid_conwidth);
1852                 h0 = ftos(autocvar_vid_conheight);
1853                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1854                 //setproperty(VF_FOV, '90 90 0');
1855                 setproperty(VF_ORIGIN, '0 0 0');
1856                 setproperty(VF_ANGLES, '0 0 0');
1857                 setproperty(VF_PERSPECTIVE, 1);
1858                 makevectors('0 0 0');
1859                 vector v1, v2;
1860                 cvar_set("vid_conwidth", "800");
1861                 cvar_set("vid_conheight", "600");
1862                 v1 = cs_project(v_forward);
1863                 cvar_set("vid_conwidth", "640");
1864                 cvar_set("vid_conheight", "480");
1865                 v2 = cs_project(v_forward);
1866                 if(v1 == v2)
1867                         cs_project_is_b0rked = 1;
1868                 else
1869                         cs_project_is_b0rked = -1;
1870                 cvar_set("vid_conwidth", w0);
1871                 cvar_set("vid_conheight", h0);
1872         }
1873
1874         if(autocvar__hud_configure)
1875                 HUD_Panel_Mouse();
1876         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1877                 HUD_Minigame_Mouse();
1878         else if(QuickMenu_IsOpened())
1879                 QuickMenu_Mouse();
1880         else
1881                 HUD_Radar_Mouse();
1882
1883         cl_notice_run();
1884
1885         // let's reset the view back to normal for the end
1886         setproperty(VF_MIN, '0 0 0');
1887         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1888 }
1889
1890
1891 // following vectors must be global to allow seamless switching between camera modes
1892 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1893 void CSQC_Demo_Camera()
1894 {
1895         float speed, attenuation, dimensions;
1896         vector tmp, delta;
1897
1898         if( autocvar_camera_reset || !camera_mode )
1899         {
1900                 camera_offset = '0 0 0';
1901                 current_angles = '0 0 0';
1902                 camera_direction = '0 0 0';
1903                 camera_offset.z += 30;
1904                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1905                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1906                 current_origin = view_origin;
1907                 current_camera_offset  = camera_offset;
1908                 cvar_set("camera_reset", "0");
1909                 camera_mode = CAMERA_CHASE;
1910         }
1911
1912         // Camera angles
1913         if( camera_roll )
1914                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1915
1916         if(autocvar_camera_look_player)
1917         {
1918                 vector dir;
1919                 float n;
1920
1921                 dir = normalize(view_origin - current_position);
1922                 n = mouse_angles.z;
1923                 mouse_angles = vectoangles(dir);
1924                 mouse_angles.x = mouse_angles.x * -1;
1925                 mouse_angles.z = n;
1926         }
1927         else
1928         {
1929                 tmp = getmousepos() * 0.1;
1930                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1931                 {
1932                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1933                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1934                 }
1935         }
1936
1937         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1938         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1939         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1940         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1941
1942         // Fix difference when angles don't have the same sign
1943         delta = '0 0 0';
1944         if(mouse_angles.y < -60 && current_angles.y > 60)
1945                 delta = '0 360 0';
1946         if(mouse_angles.y > 60 && current_angles.y < -60)
1947                 delta = '0 -360 0';
1948
1949         if(autocvar_camera_look_player)
1950                 attenuation = autocvar_camera_look_attenuation;
1951         else
1952                 attenuation = autocvar_camera_speed_attenuation;
1953
1954         attenuation = 1 / max(1, attenuation);
1955         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1956
1957         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1958         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1959         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1960         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1961
1962         // Camera position
1963         tmp = '0 0 0';
1964         dimensions = 0;
1965
1966         if( camera_direction.x )
1967         {
1968                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1969                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1970                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1971                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1972                 ++dimensions;
1973         }
1974
1975         if( camera_direction.y )
1976         {
1977                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1978                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1979                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1980                 ++dimensions;
1981         }
1982
1983         if( camera_direction.z )
1984         {
1985                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1986                 ++dimensions;
1987         }
1988
1989         if(autocvar_camera_free)
1990                 speed = autocvar_camera_speed_free;
1991         else
1992                 speed = autocvar_camera_speed_chase;
1993
1994         if(dimensions)
1995         {
1996                 speed = speed * sqrt(1 / dimensions);
1997                 camera_offset += tmp * speed;
1998         }
1999
2000         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2001
2002         // Camera modes
2003         if( autocvar_camera_free )
2004         {
2005                 if ( camera_mode == CAMERA_CHASE )
2006                 {
2007                         current_camera_offset = current_origin + current_camera_offset;
2008                         camera_offset = current_origin + camera_offset;
2009                 }
2010
2011                 camera_mode = CAMERA_FREE;
2012                 current_position = current_camera_offset;
2013         }
2014         else
2015         {
2016                 if ( camera_mode == CAMERA_FREE )
2017                 {
2018                         current_origin = view_origin;
2019                         camera_offset = camera_offset - current_origin;
2020                         current_camera_offset = current_camera_offset - current_origin;
2021                 }
2022
2023                 camera_mode = CAMERA_CHASE;
2024
2025                 if(autocvar_camera_chase_smoothly)
2026                         current_origin += (view_origin - current_origin) * attenuation;
2027                 else
2028                         current_origin = view_origin;
2029
2030                 current_position = current_origin + current_camera_offset;
2031         }
2032
2033         setproperty(VF_ANGLES, current_angles);
2034         setproperty(VF_ORIGIN, current_position);
2035 }