Fix condition to show the cursor when the onslaught radar is active while dead: curso...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "autocvars.qh"
4 #include "miscfunctions.qh"
5 #include "announcer.qh"
6 #include "hud/_mod.qh"
7 #include "mapvoting.qh"
8 #include "shownames.qh"
9 #include "hud/panel/scoreboard.qh"
10 #include "hud/panel/quickmenu.qh"
11
12 #include <client/mutators/_mod.qh>
13
14 #include <common/animdecide.qh>
15 #include <common/deathtypes/all.qh>
16 #include <common/ent_cs.qh>
17 #include <common/anim.qh>
18 #include <common/constants.qh>
19 #include <common/net_linked.qh>
20 #include <common/net_notice.qh>
21 #include <common/debug.qh>
22 #include <common/mapinfo.qh>
23 #include <common/gamemodes/_mod.qh>
24 #include <common/physics/player.qh>
25 #include <common/stats.qh>
26 #include <common/mapobjects/target/music.qh>
27 #include <common/teams.qh>
28 #include <common/wepent.qh>
29
30 #include <common/weapons/weapon/tuba.qh>
31
32 #include <common/vehicles/all.qh>
33 #include <common/weapons/_all.qh>
34 #include <common/mutators/mutator/overkill/oknex.qh>
35 #include <common/mutators/mutator/waypoints/all.qh>
36 #include <common/viewloc.qh>
37 #include <common/mapobjects/trigger/viewloc.qh>
38 #include <common/minigames/cl_minigames.qh>
39 #include <common/minigames/cl_minigames_hud.qh>
40
41 #include <lib/csqcmodel/cl_player.qh>
42 #include <lib/csqcmodel/cl_model.qh>
43 #include "csqcmodel_hooks.qh"
44
45 #include <lib/warpzone/client.qh>
46 #include <lib/warpzone/common.qh>
47
48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
49
50 float autocvar_cl_viewmodel_scale;
51 float autocvar_cl_viewmodel_alpha;
52
53 bool autocvar_cl_bobmodel;
54 float autocvar_cl_bobmodel_speed;
55 float autocvar_cl_bobmodel_side;
56 float autocvar_cl_bobmodel_up;
57
58 float autocvar_cl_followmodel;
59 float autocvar_cl_followmodel_speed = 0.3;
60 float autocvar_cl_followmodel_limit = 135;
61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
62 float autocvar_cl_followmodel_highpass = 0.05;
63 float autocvar_cl_followmodel_lowpass = 0.03;
64 bool autocvar_cl_followmodel_velocity_absolute;
65
66 float autocvar_cl_leanmodel;
67 float autocvar_cl_leanmodel_speed = 0.3;
68 float autocvar_cl_leanmodel_limit = 30;
69 float autocvar_cl_leanmodel_highpass1 = 0.2;
70 float autocvar_cl_leanmodel_highpass = 0.2;
71 float autocvar_cl_leanmodel_lowpass = 0.05;
72
73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
74
75 #define lowpass(value, frac, ref_store, ret) \
76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
77
78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
79 { \
80         float __ignore; lowpass(value, frac, ref_store, __ignore); \
81         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
82 } MACRO_END
83
84 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
85 { \
86         float __f = 0; lowpass(value, frac, ref_store, __f); \
87         ret = (value) - __f; \
88 } MACRO_END
89
90 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
91 { \
92         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
93         ret = (value) - __f; \
94 } MACRO_END
95
96 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
97 { \
98         lowpass(value.x, frac, ref_store.x, ref_out.x); \
99         lowpass(value.y, frac, ref_store.y, ref_out.y); \
100 } MACRO_END
101
102 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
103 { \
104         highpass(value.x, frac, ref_store.x, ref_out.x); \
105         highpass(value.y, frac, ref_store.y, ref_out.y); \
106 } MACRO_END
107
108 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
109 { \
110         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
111         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
112 } MACRO_END
113
114 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
115 { \
116         lowpass(value.x, frac, ref_store.x, ref_out.x); \
117         lowpass(value.y, frac, ref_store.y, ref_out.y); \
118         lowpass(value.z, frac, ref_store.z, ref_out.z); \
119 } MACRO_END
120
121 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
122 { \
123         highpass(value.x, frac, ref_store.x, ref_out.x); \
124         highpass(value.y, frac, ref_store.y, ref_out.y); \
125         highpass(value.z, frac, ref_store.z, ref_out.z); \
126 } MACRO_END
127
128 void calc_followmodel_ofs(entity view)
129 {
130         if(cl_followmodel_time == time)
131                 return; // cl_followmodel_ofs already calculated for this frame
132
133         float frac;
134         vector gunorg = '0 0 0';
135         static vector vel_average;
136         static vector gunorg_adjustment_highpass;
137         static vector gunorg_adjustment_lowpass;
138
139         vector vel;
140         if (autocvar_cl_followmodel_velocity_absolute)
141                 vel = view.velocity;
142         else
143         {
144                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
145                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
146                 vel.x = view.velocity * forward;
147                 vel.y = view.velocity * right * -1;
148                 vel.z = view.velocity * up;
149         }
150
151         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
152         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
153         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
154
155         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
156         lowpass3(vel, frac, vel_average, gunorg);
157
158         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
159
160         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
161         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
162         frac = avg_factor(autocvar_cl_followmodel_highpass);
163         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
164         frac = avg_factor(autocvar_cl_followmodel_lowpass);
165         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
166
167         if (autocvar_cl_followmodel_velocity_absolute)
168         {
169                 vector fixed_gunorg;
170                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
171                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
172                 fixed_gunorg.x = gunorg * forward;
173                 fixed_gunorg.y = gunorg * right * -1;
174                 fixed_gunorg.z = gunorg * up;
175                 gunorg = fixed_gunorg;
176         }
177
178         cl_followmodel_ofs = gunorg;
179         cl_followmodel_time = time;
180 }
181
182 vector leanmodel_ofs(entity view)
183 {
184         float frac;
185         vector gunangles = '0 0 0';
186         static vector gunangles_prev = '0 0 0';
187         static vector gunangles_highpass = '0 0 0';
188         static vector gunangles_adjustment_highpass;
189         static vector gunangles_adjustment_lowpass;
190
191         if (view.csqcmodel_teleported)
192                 gunangles_prev = view_angles;
193
194         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
195         gunangles_highpass += gunangles_prev;
196         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
197         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
198         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
199         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
200         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
201         gunangles_prev = view_angles;
202         gunangles_highpass -= gunangles_prev;
203
204         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
205         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
206
207         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
208         frac = avg_factor(autocvar_cl_leanmodel_highpass);
209         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
210         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
211         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
212
213         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
214
215         return gunangles;
216 }
217
218 vector bobmodel_ofs(entity view)
219 {
220         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
221         static bool oldonground;
222         static float hitgroundtime;
223         if (clonground)
224         {
225                 float f = time; // cl.movecmd[0].time
226                 if (!oldonground)
227                         hitgroundtime = f;
228         }
229         oldonground = clonground;
230
231         // calculate for swinging gun model
232         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
233         vector gunorg = '0 0 0';
234         static float bobmodel_scale = 0;
235         static float time_ofs = 0; // makes the effect always restart in the same way
236         if (clonground)
237         {
238                 if (time - hitgroundtime > 0.05)
239                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
240         }
241         else
242                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
243
244         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
245         if (bobmodel_scale && xyspeed)
246         {
247                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
248                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
249                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
250                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
251         }
252         else
253                 time_ofs = time;
254
255         return gunorg;
256 }
257
258 void viewmodel_animate(entity this)
259 {
260         if (autocvar_chase_active) return;
261         if (STAT(HEALTH) <= 0) return;
262
263         entity view = CSQCModel_server2csqc(player_localentnum - 1);
264
265         if (autocvar_cl_followmodel)
266         {
267                 calc_followmodel_ofs(view);
268                 this.origin += cl_followmodel_ofs;
269         }
270
271         if (autocvar_cl_leanmodel)
272                 this.angles += leanmodel_ofs(view);
273
274         // vertical view bobbing code
275         // TODO: cl_bob
276
277         // horizontal view bobbing code
278         // TODO: cl_bob2
279
280         // fall bobbing code
281         // causes the view to swing down and back up when touching the ground
282         // TODO: cl_bobfall
283
284         // gun model bobbing code
285         if (autocvar_cl_bobmodel)
286                 this.origin += bobmodel_ofs(view);
287 }
288
289 .vector viewmodel_origin, viewmodel_angles;
290 .float weapon_nextthink;
291 .float weapon_eta_last;
292 .float weapon_switchdelay;
293
294 .string name_last;
295
296 void viewmodel_draw(entity this)
297 {
298         if(!this.activeweapon || !autocvar_r_drawviewmodel)
299                 return;
300         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
301         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
302         bool invehicle = player_localentnum > maxclients;
303         if (invehicle) a = -1;
304         Weapon wep = this.activeweapon;
305         int c = entcs_GetClientColors(current_player);
306         vector g = weaponentity_glowmod(wep, NULL, c, this);
307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
309                 | EF_NODEPTHTEST)
310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
311         for (entity e = this; e; e = e.weaponchild)
312         {
313                 e.drawmask = mask;
314                 e.alpha = a;
315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
316                 e.glowmod = g;
317                 e.csqcmodel_effects = fx;
318                 CSQCModel_Effects_Apply(e);
319         }
320         if(a >= 0)
321         {
322                 string name = wep.mdl;
323                 string newname = wep.wr_viewmodel(wep, this);
324                 if(newname)
325                         name = newname;
326                 bool swap = name != this.name_last;
327                 // if (swap)
328                 {
329                         this.name_last = name;
330                         CL_WeaponEntity_SetModel(this, name, swap);
331                         this.viewmodel_origin = this.origin;
332                         this.viewmodel_angles = this.angles;
333                 }
334                 anim_update(this);
335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
336                         anim_set(this, this.anim_idle, true, false, false);
337         }
338         float f = 0; // 0..1; 0: fully active
339         float rate = STAT(WEAPONRATEFACTOR);
340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
341         if (eta <= 0) f = this.weapon_eta_last;
342         else switch (this.state)
343         {
344                 case WS_RAISE:
345                 {
346                         f = eta / max(eta, this.weapon_switchdelay);
347                         break;
348                 }
349                 case WS_DROP:
350                 {
351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
352                         break;
353                 }
354                 case WS_CLEAR:
355                 {
356                         f = 1;
357                         break;
358                 }
359         }
360         this.weapon_eta_last = f;
361         this.origin = this.viewmodel_origin;
362         this.angles = this.viewmodel_angles;
363         this.angles_x = (-90 * f * f);
364         viewmodel_animate(this);
365         MUTATOR_CALLHOOK(DrawViewModel, this);
366         setorigin(this, this.origin);
367 }
368
369 STATIC_INIT(viewmodel) {
370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
371         viewmodels[slot] = new(viewmodel);
372 }
373
374 float showfps_prevfps;
375 float showfps_prevfps_time;
376 int showfps_framecounter;
377
378 void fpscounter_update()
379 {
380         if(!STAT(SHOWFPS))
381                 return;
382
383         float currentTime = gettime(GETTIME_REALTIME);
384         showfps_framecounter += 1;
385         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
386         {
387                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
388                 showfps_framecounter = 0;
389                 showfps_prevfps_time = currentTime;
390
391                 int channel = MSG_C2S;
392                 WriteHeader(channel, fpsreport);
393                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
394         }
395 }
396
397 STATIC_INIT(fpscounter_init)
398 {
399         float currentTime = gettime(GETTIME_REALTIME);
400         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
401 }
402
403 STATIC_INIT(Porto)
404 {
405         entity e = new_pure(porto);
406         e.draw = Porto_Draw;
407         IL_PUSH(g_drawables, e);
408         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
409 }
410
411 const int polyline_length = 16;
412 .vector polyline[polyline_length];
413 void Porto_Draw(entity this)
414 {
415         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
416         {
417                 entity wepent = viewmodels[slot];
418
419                 if (wepent.activeweapon != WEP_PORTO) continue;
420                 if (spectatee_status) continue;
421                 if (WEP_CVAR(porto, secondary)) continue;
422                 if (intermission == 1) continue;
423                 if (intermission == 2) continue;
424                 if (STAT(HEALTH) <= 0) continue;
425
426                 vector pos = view_origin;
427                 vector dir = view_forward;
428                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
429                 pos += v_right * -wepent.movedir.y
430                         +  v_up * wepent.movedir.z;
431
432                 if (wepent.angles_held_status)
433                 {
434                         makevectors(wepent.angles_held);
435                         dir = v_forward;
436                 }
437
438                 wepent.polyline[0] = pos;
439
440                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
441                 int n = 1 + 2;  // 2 lines == 3 points
442                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
443                 {
444                         traceline(pos, pos + 65536 * dir, true, this);
445                         dir = reflect(dir, trace_plane_normal);
446                         pos = trace_endpos;
447                         wepent.polyline[++idx] = pos;
448                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
449                         {
450                                 n += 1;
451                                 continue;
452                         }
453                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
454                         {
455                                 n = max(2, idx);
456                                 break;
457                         }
458                         // check size
459                         {
460                                 vector ang = vectoangles2(trace_plane_normal, dir);
461                                 ang.x = -ang.x;
462                                 makevectors(ang);
463                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
464                                 {
465                                         n = max(2, idx);
466                                         break;
467                                 }
468                         }
469                         portal_number += 1;
470                         if (portal_number >= portal_max) break;
471                         if (portal_number == 1) portal1_idx = idx;
472                 }
473                 for (int idx = 0; idx < n - 1; ++idx)
474                 {
475                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
476                         if (idx == 0) p -= view_up * 16;  // line from player
477                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
478                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
479                 }
480         }
481 }
482
483 float drawtime;
484 float avgspeed;
485 vector GetCurrentFov(float fov)
486 {
487         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
488         float velocityzoom, curspeed;
489         vector v;
490
491         zoomsensitivity = autocvar_cl_zoomsensitivity;
492         zoomfactor = autocvar_cl_zoomfactor;
493         if(zoomfactor < 1 || zoomfactor > 30)
494                 zoomfactor = 2.5;
495         zoomspeed = autocvar_cl_zoomspeed;
496         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
497                 zoomspeed = 3.5;
498
499         zoomdir = button_zoom;
500
501         if(hud == HUD_NORMAL && !spectatee_status)
502         {
503                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
504                 {
505                         entity wepent = viewmodels[slot];
506                         if(wepent.switchweapon != wepent.activeweapon)
507                                 continue;
508                         Weapon wep = wepent.activeweapon;
509                         if(wep != WEP_Null && wep.wr_zoomdir)
510                         {
511                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
512                                 zoomdir += do_zoom;
513                         }
514                 }
515         }
516         if(spectatee_status > 0 || isdemo())
517         {
518                 if(spectatorbutton_zoom)
519                 {
520                         if(zoomdir)
521                                 zoomdir = 0;
522                         else
523                                 zoomdir = 1;
524                 }
525                 // fteqcc failed twice here already, don't optimize this
526         }
527
528         if(zoomdir) { zoomin_effect = 0; }
529
530         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
531         {
532                 current_viewzoom = 1;
533         }
534         else if (camera_active)
535         {
536                 current_viewzoom = min(1, current_viewzoom + drawframetime);
537         }
538         else if(autocvar_cl_spawnzoom && zoomin_effect)
539         {
540                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
541
542                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
543                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
544                 if(current_viewzoom == 1) { zoomin_effect = 0; }
545         }
546         else
547         {
548                 if(zoomspeed < 0) // instant zoom
549                 {
550                         if(zoomdir)
551                                 current_viewzoom = 1 / zoomfactor;
552                         else
553                                 current_viewzoom = 1;
554                 }
555                 else
556                 {
557                         if(zoomdir)
558                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
559                         else
560                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
561                 }
562         }
563
564         if(almost_equals(current_viewzoom, 1))
565                 current_zoomfraction = 0;
566         else if(almost_equals(current_viewzoom, 1/zoomfactor))
567                 current_zoomfraction = 1;
568         else
569                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
570
571         if(zoomsensitivity < 1)
572                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
573         else
574                 setsensitivityscale(1);
575
576         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
577         {
578                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
579                         curspeed = 0;
580                 else
581                 {
582                         makevectors(view_angles);
583                         v = pmove_vel;
584                         if(csqcplayer)
585                                 v = csqcplayer.velocity;
586
587                         switch(autocvar_cl_velocityzoom_type)
588                         {
589                                 case 3: curspeed = max(0, v_forward * v); break;
590                                 case 2: curspeed = (v_forward * v); break;
591                                 case 1: default: curspeed = vlen(v); break;
592                         }
593                 }
594
595                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
596                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
597                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
598
599                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
600         }
601         else
602                 velocityzoom = 1;
603
604         float frustumx, frustumy, fovx, fovy;
605         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
606         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
607         fovx = atan2(frustumx, 1) / M_PI * 360.0;
608         fovy = atan2(frustumy, 1) / M_PI * 360.0;
609
610         return '1 0 0' * fovx + '0 1 0' * fovy;
611 }
612
613 vector GetViewLocationFOV(float fov)
614 {
615         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
616         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
617         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
618         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
619         return '1 0 0' * fovx + '0 1 0' * fovy;
620 }
621
622 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
623 {
624         float fovx, fovy;
625         float width = (ov_worldmax.x - ov_worldmin.x);
626         float height = (ov_worldmax.y - ov_worldmin.y);
627         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
628         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
629         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
630         return '1 0 0' * fovx + '0 1 0' * fovy;
631 }
632
633 // this function must match W_SetupShot!
634 float zoomscript_caught;
635
636 bool minigame_wasactive;
637
638 vector wcross_origin;
639 float wcross_scale_prev, wcross_alpha_prev;
640 vector wcross_color_prev;
641 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
642 vector wcross_color_goal_prev;
643 float wcross_changedonetime;
644
645 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
646 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
647 float wcross_name_changestarttime, wcross_name_changedonetime;
648 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
649
650 float wcross_ring_prev;
651
652 entity trueaim;
653 entity trueaim_rifle;
654
655 const float SHOTTYPE_HITTEAM = 1;
656 const float SHOTTYPE_HITOBSTRUCTION = 2;
657 const float SHOTTYPE_HITWORLD = 3;
658 const float SHOTTYPE_HITENEMY = 4;
659
660 void TrueAim_Init()
661 {
662         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
663         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
664 }
665
666 float EnemyHitCheck()
667 {
668         float t, n;
669         wcross_origin = project_3d_to_2d(trace_endpos);
670         wcross_origin.z = 0;
671         if(trace_ent)
672                 n = trace_ent.entnum;
673         else
674                 n = trace_networkentity;
675         if(n < 1)
676                 return SHOTTYPE_HITWORLD;
677         if(n > maxclients)
678                 return SHOTTYPE_HITWORLD;
679         t = entcs_GetTeam(n - 1);
680         if(teamplay)
681                 if(t == myteam)
682                         return SHOTTYPE_HITTEAM;
683         if(t == NUM_SPECTATOR)
684                 return SHOTTYPE_HITWORLD;
685         return SHOTTYPE_HITENEMY;
686 }
687
688 float TrueAimCheck(entity wepent)
689 {
690         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
691         vector vecs, trueaimpoint, w_shotorg;
692         vector mi, ma, dv;
693         float shottype;
694         entity ta;
695         float mv;
696
697         mi = ma = '0 0 0';
698         ta = trueaim;
699         mv = MOVE_NOMONSTERS;
700
701         switch(wepent.activeweapon) // WEAPONTODO
702         {
703                 case WEP_TUBA: // no aim
704                 case WEP_PORTO: // shoots from eye
705                 case WEP_NEXBALL: // shoots from eye
706                 case WEP_HOOK: // no trueaim
707                 case WEP_MORTAR: // toss curve
708                         return SHOTTYPE_HITWORLD;
709                 case WEP_VORTEX:
710                 case WEP_OVERKILL_NEX:
711                 case WEP_VAPORIZER:
712                         mv = MOVE_NORMAL;
713                         break;
714                 case WEP_RIFLE:
715                         ta = trueaim_rifle;
716                         mv = MOVE_NORMAL;
717                         if(zoomscript_caught)
718                         {
719                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
720                                 return EnemyHitCheck();
721                         }
722                         break;
723                 case WEP_DEVASTATOR: // projectile has a size!
724                         mi = '-3 -3 -3';
725                         ma = '3 3 3';
726                         break;
727                 case WEP_FIREBALL: // projectile has a size!
728                         mi = '-16 -16 -16';
729                         ma = '16 16 16';
730                         break;
731                 case WEP_SEEKER: // projectile has a size!
732                         mi = '-2 -2 -2';
733                         ma = '2 2 2';
734                         break;
735                 case WEP_ELECTRO: // projectile has a size!
736                         mi = '0 0 -3';
737                         ma = '0 0 -3';
738                         break;
739         }
740
741         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
742
743         vecs = decompressShotOrigin(STAT(SHOTORG));
744
745         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
746         trueaimpoint = trace_endpos;
747
748         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
749                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
750
751         if(vecs.x > 0)
752                 vecs.y = -vecs.y;
753         else
754                 vecs = '0 0 0';
755
756         dv = view_right * vecs.y + view_up * vecs.z;
757         w_shotorg = traceorigin + dv;
758
759         // now move the vecs forward as much as requested if possible
760         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
761         w_shotorg = trace_endpos - view_forward * nudge;
762
763         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
764         shottype = EnemyHitCheck();
765         if(shottype != SHOTTYPE_HITWORLD)
766                 return shottype;
767
768 #if 0
769         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
770         // or rather, I know why, but see no fix
771         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
772                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
773                 return SHOTTYPE_HITOBSTRUCTION;
774 #endif
775
776         return SHOTTYPE_HITWORLD;
777 }
778
779 float camera_mode;
780 const float CAMERA_FREE = 1;
781 const float CAMERA_CHASE = 2;
782 float reticle_type;
783 string NextFrameCommand;
784
785 vector freeze_org, freeze_ang;
786 entity nightvision_noise, nightvision_noise2;
787
788 const float MAX_TIME_DIFF = 5;
789 float pickup_crosshair_time, pickup_crosshair_size;
790 float hitindication_crosshair_size;
791 float use_vortex_chargepool;
792
793 float myhealth, myhealth_prev;
794 float myhealth_flash;
795
796 float old_blurradius, old_bluralpha;
797 float old_sharpen_intensity;
798
799 vector myhealth_gentlergb;
800
801 float contentavgalpha, liquidalpha_prev;
802 vector liquidcolor_prev;
803
804 float eventchase_current_distance;
805 float eventchase_running;
806 int WantEventchase(entity this)
807 {
808         if(autocvar_cl_orthoview)
809                 return 0;
810         if(STAT(GAME_STOPPED) || intermission)
811                 return 1;
812         if(this.viewloc)
813                 return 1;
814         if(spectatee_status >= 0)
815         {
816                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
817                         return 1;
818                 if(MUTATOR_CALLHOOK(WantEventchase, this))
819                         return 1;
820                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
821                         return 1;
822                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
823                 {
824                         if(autocvar_cl_eventchase_death == 2)
825                         {
826                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
827                                 if(this.velocity == '0 0 0' || eventchase_running)
828                                         return 1;
829                         }
830                         else return 1;
831                 }
832                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
833                 {
834                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
835                                 return 1;
836                         else if (eventchase_running)
837                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
838                 }
839         }
840         return 0;
841 }
842
843 void HUD_Crosshair_Vehicle(entity this)
844 {
845         if(hud != HUD_BUMBLEBEE_GUN)
846         {
847                 Vehicle info = Vehicles_from(hud);
848                 info.vr_crosshair(info, this);
849         }
850 }
851
852 vector damage_blurpostprocess, content_blurpostprocess;
853
854 float unaccounted_damage = 0;
855 void UpdateDamage()
856 {
857         // accumulate damage with each stat update
858         static float damage_total_prev = 0;
859         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
860         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
861         damage_total_prev = damage_total;
862
863         static float damage_dealt_time_prev = 0;
864         float damage_dealt_time = STAT(HIT_TIME);
865         if (damage_dealt_time != damage_dealt_time_prev)
866         {
867                 unaccounted_damage += unaccounted_damage_new;
868                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
869         }
870         damage_dealt_time_prev = damage_dealt_time;
871
872         // prevent hitsound when switching spectatee
873         static float spectatee_status_prev = 0;
874         if (spectatee_status != spectatee_status_prev)
875                 unaccounted_damage = 0;
876         spectatee_status_prev = spectatee_status;
877 }
878
879 void HitSound()
880 {
881         // varying sound pitch
882
883         bool have_arc = false;
884         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
885         {
886                 entity wepent = viewmodels[slot];
887
888                 if(wepent.activeweapon == WEP_ARC)
889                         have_arc = true;
890         }
891
892         static float hitsound_time_prev = 0;
893         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
894         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
895         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
896         {
897                 if (autocvar_cl_hitsound && unaccounted_damage)
898                 {
899                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
900                         float a = autocvar_cl_hitsound_max_pitch;
901                         float b = autocvar_cl_hitsound_min_pitch;
902                         float c = autocvar_cl_hitsound_nom_damage;
903                         float d = unaccounted_damage;
904                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
905
906                         // if sound variation is disabled, set pitch_shift to 1
907                         if (autocvar_cl_hitsound == 1)
908                                 pitch_shift = 1;
909
910                         // if pitch shift is reversed, mirror in (max-min)/2 + min
911                         if (autocvar_cl_hitsound == 3)
912                         {
913                                 float mirror_value = (a-b)/2 + b;
914                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
915                         }
916
917                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
918
919                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
920                         // todo: normalize sound pressure levels? seems unnecessary
921
922                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
923                 }
924                 unaccounted_damage = 0;
925                 hitsound_time_prev = time;
926         }
927
928         static float typehit_time_prev = 0;
929         float typehit_time = STAT(TYPEHIT_TIME);
930         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
931         {
932                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
933                 typehit_time_prev = typehit_time;
934         }
935
936         static float kill_time_prev = 0;
937         float kill_time = STAT(KILL_TIME);
938         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
939         {
940                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
941                 kill_time_prev = kill_time;
942         }
943 }
944
945 vector crosshair_getcolor(entity this, float health_stat)
946 {
947         static float rainbow_last_flicker;
948         static vector rainbow_prev_color;
949         vector wcross_color = '0 0 0';
950         switch(autocvar_crosshair_color_special)
951         {
952                 case 1: // crosshair_color_per_weapon
953                 {
954                         if(this != WEP_Null && hud == HUD_NORMAL)
955                         {
956                                 wcross_color = this.wpcolor;
957                                 break;
958                         }
959                         else { goto normalcolor; }
960                 }
961
962                 case 2: // crosshair_color_by_health
963                 {
964                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
965                         float hp = floor(v.x + 1);
966
967                         //x = red
968                         //y = green
969                         //z = blue
970
971                         wcross_color.z = 0;
972
973                         if(hp > 200)
974                         {
975                                 wcross_color.x = 0;
976                                 wcross_color.y = 1;
977                         }
978                         else if(hp > 150)
979                         {
980                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
981                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
982                         }
983                         else if(hp > 100)
984                         {
985                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
986                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
987                                 wcross_color.z = 1 - (hp-100)*0.02;
988                         }
989                         else if(hp > 50)
990                         {
991                                 wcross_color.x = 1;
992                                 wcross_color.y = 1;
993                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
994                         }
995                         else if(hp > 20)
996                         {
997                                 wcross_color.x = 1;
998                                 wcross_color.y = (hp-20)*90/27/100;
999                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
1000                         }
1001                         else
1002                         {
1003                                 wcross_color.x = 1;
1004                                 wcross_color.y = 0;
1005                         }
1006                         break;
1007                 }
1008
1009                 case 3: // crosshair_color_rainbow
1010                 {
1011                         if(time >= rainbow_last_flicker)
1012                         {
1013                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1014                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1015                         }
1016                         wcross_color = rainbow_prev_color;
1017                         break;
1018                 }
1019 LABEL(normalcolor)
1020                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1021         }
1022
1023         return wcross_color;
1024 }
1025
1026 void HUD_Crosshair(entity this)
1027 {
1028         float f, i, j;
1029         vector v;
1030         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1031                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1032                 !HUD_MinigameMenu_IsOpened() )
1033         {
1034                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1035                         return;
1036
1037                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1038                         return;
1039
1040                 if (hud != HUD_NORMAL)
1041                 {
1042                         HUD_Crosshair_Vehicle(this);
1043                         return;
1044                 }
1045
1046                 string wcross_style;
1047                 float wcross_alpha, wcross_resolution;
1048                 wcross_style = autocvar_crosshair;
1049                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1050                         wcross_style = autocvar_crosshair_2d;
1051                 if (wcross_style == "0")
1052                         return;
1053                 wcross_resolution = autocvar_crosshair_size;
1054                 if (wcross_resolution == 0)
1055                         return;
1056                 wcross_alpha = autocvar_crosshair_alpha;
1057                 if (wcross_alpha == 0)
1058                         return;
1059
1060                 // TrueAim check
1061                 float shottype;
1062
1063                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1064                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1065                         wcross_origin = viewloc_mousepos;
1066                 else
1067                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1068                 wcross_origin.z = 0;
1069                 if(autocvar_crosshair_hittest)
1070                 {
1071                         vector wcross_oldorigin;
1072                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1073                         wcross_oldorigin = wcross_origin;
1074                         shottype = TrueAimCheck(thiswep);
1075                         if(shottype == SHOTTYPE_HITWORLD)
1076                         {
1077                                 v = wcross_origin - wcross_oldorigin;
1078                                 v.x /= vid_conwidth;
1079                                 v.y /= vid_conheight;
1080                                 if(vdist(v, >, 0.01))
1081                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1082                         }
1083                         if(!autocvar_crosshair_hittest_showimpact)
1084                                 wcross_origin = wcross_oldorigin;
1085                 }
1086                 else
1087                         shottype = SHOTTYPE_HITWORLD;
1088
1089                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1090                 string wcross_name = "";
1091                 float wcross_scale, wcross_blur;
1092
1093         entity e = WEP_Null;
1094                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1095                 {
1096                         entity wepent = viewmodels[0]; // TODO: unhardcode
1097                         e = wepent.switchingweapon;
1098                         if(e)
1099                         {
1100                                 if(autocvar_crosshair_per_weapon)
1101                                 {
1102                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1103                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1104                                         //if (wcross_resolution == 0)
1105                                                 //return;
1106
1107                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1108                                         wcross_resolution *= e.w_crosshair_size;
1109                                         wcross_name = e.w_crosshair;
1110                                 }
1111                         }
1112                 }
1113
1114                 if(wcross_name == "")
1115                         wcross_name = strcat("gfx/crosshair", wcross_style);
1116
1117                 // MAIN CROSSHAIR COLOR DECISION
1118                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1119
1120                 if(autocvar_crosshair_effect_scalefade)
1121                 {
1122                         wcross_scale = wcross_resolution;
1123                         wcross_resolution = 1;
1124                 }
1125                 else
1126                 {
1127                         wcross_scale = 1;
1128                 }
1129
1130                 if(autocvar_crosshair_pickup)
1131                 {
1132                         float stat_pickup_time = STAT(LAST_PICKUP);
1133
1134                         if(pickup_crosshair_time < stat_pickup_time)
1135                         {
1136                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1137                                         pickup_crosshair_size = 1;
1138
1139                                 pickup_crosshair_time = stat_pickup_time;
1140                         }
1141
1142                         if(pickup_crosshair_size > 0)
1143                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1144                         else
1145                                 pickup_crosshair_size = 0;
1146
1147                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1148                 }
1149
1150                 // todo: make crosshair hit indication dependent on damage dealt
1151                 if(autocvar_crosshair_hitindication)
1152                 {
1153                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1154
1155                         if(unaccounted_damage)
1156                         {
1157                                 hitindication_crosshair_size = 1;
1158                         }
1159
1160                         if(hitindication_crosshair_size > 0)
1161                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1162                         else
1163                                 hitindication_crosshair_size = 0;
1164
1165                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1166                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1167                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1168                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1169                 }
1170
1171                 if(shottype == SHOTTYPE_HITENEMY)
1172                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1173                 if(shottype == SHOTTYPE_HITTEAM)
1174                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1175
1176                 f = fabs(autocvar_crosshair_effect_time);
1177                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1178                 {
1179                         wcross_changedonetime = time + f;
1180                 }
1181                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1182                 {
1183                         wcross_name_changestarttime = time;
1184                         wcross_name_changedonetime = time + f;
1185                         if(wcross_name_goal_prev_prev)
1186                                 strunzone(wcross_name_goal_prev_prev);
1187                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1188                         wcross_name_goal_prev = strzone(wcross_name);
1189                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1190                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1191                         wcross_resolution_goal_prev = wcross_resolution;
1192                 }
1193
1194                 wcross_scale_goal_prev = wcross_scale;
1195                 wcross_alpha_goal_prev = wcross_alpha;
1196                 wcross_color_goal_prev = wcross_color;
1197
1198                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1199                 {
1200                         wcross_blur = 1;
1201                         wcross_alpha *= 0.75;
1202                 }
1203                 else
1204                         wcross_blur = 0;
1205                 // *_prev is at time-frametime
1206                 // * is at wcross_changedonetime+f
1207                 // what do we have at time?
1208                 if(time < wcross_changedonetime)
1209                 {
1210                         f = frametime / (wcross_changedonetime - time + frametime);
1211                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1212                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1213                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1214                 }
1215
1216                 wcross_scale_prev = wcross_scale;
1217                 wcross_alpha_prev = wcross_alpha;
1218                 wcross_color_prev = wcross_color;
1219
1220                 MUTATOR_CALLHOOK(UpdateCrosshair);
1221
1222                 wcross_scale *= 1 - autocvar__menu_alpha;
1223                 wcross_alpha *= 1 - autocvar__menu_alpha;
1224                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1225
1226                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1227                 {
1228                         // crosshair rings for weapon stats
1229                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1230                         {
1231                                 // declarations and stats
1232                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1233                                 string ring_image = string_null, ring_inner_image = string_null;
1234                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1235
1236                                 ring_scale = autocvar_crosshair_ring_size;
1237
1238                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1239
1240                                 int weapon_clipload = wepent.clip_load;
1241                                 int weapon_clipsize = wepent.clip_size;
1242
1243                                 float arc_heat = wepent.arc_heat_percent;
1244                                 float vcharge = wepent.vortex_charge;
1245                                 float vchargepool = wepent.vortex_chargepool_ammo;
1246                                 float oknex_charge_ = wepent.oknex_charge;
1247                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1248
1249                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1250                                         vortex_charge_movingavg = vcharge;
1251
1252                                 // handle the values
1253                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1254                                 {
1255                                         if (vchargepool || use_vortex_chargepool) {
1256                                                 use_vortex_chargepool = 1;
1257                                                 ring_inner_value = vchargepool;
1258                                         } else {
1259                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1260                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1261                                         }
1262
1263                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1264                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1265                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1266
1267                                         // draw the outer ring to show the current charge of the weapon
1268                                         ring_value = vcharge;
1269                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1270                                         ring_rgb = wcross_color;
1271                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1272                                 }
1273                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1274                                 {
1275                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1276                                                 use_vortex_chargepool = 1;
1277                                                 ring_inner_value = oknex_chargepool_;
1278                                         } else {
1279                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1280                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1281                                         }
1282
1283                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1284                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1285                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1286
1287                                         // draw the outer ring to show the current charge of the weapon
1288                                         ring_value = oknex_charge_;
1289                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1290                                         ring_rgb = wcross_color;
1291                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1292                                 }
1293                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1294                                 {
1295                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1296                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1297                                         ring_rgb = wcross_color;
1298                                         ring_image = "gfx/crosshair_ring.tga";
1299                                 }
1300                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1301                                 {
1302                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1303                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1304                                         ring_rgb = wcross_color;
1305                                         ring_image = "gfx/crosshair_ring.tga";
1306                                 }
1307                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1308                                 {
1309                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1310                                         ring_scale = autocvar_crosshair_ring_reload_size;
1311                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1312                                         ring_rgb = wcross_color;
1313
1314                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1315                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1316                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1317                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1318                                         else
1319                                                 ring_image = "gfx/crosshair_ring.tga";
1320                                 }
1321                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1322                                 {
1323                                         ring_value = arc_heat;
1324                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1325                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1326                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1327                                         ring_image = "gfx/crosshair_ring.tga";
1328                                 }
1329
1330                                 // if in weapon switch animation, fade ring out/in
1331                                 if(autocvar_crosshair_effect_time > 0)
1332                                 {
1333                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1334                                         if (f >= 1)
1335                                         {
1336                                                 wcross_ring_prev = ((ring_image) ? true : false);
1337                                         }
1338
1339                                         if(wcross_ring_prev)
1340                                         {
1341                                                 if(f < 1)
1342                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1343                                         }
1344                                         else
1345                                         {
1346                                                 if(f < 1)
1347                                                         ring_alpha *= bound(0, f, 1);
1348                                         }
1349                                 }
1350
1351                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1352                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1353
1354                                 if (ring_value)
1355                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1356                         }
1357
1358 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1359                         MACRO_BEGIN { \
1360                                 vector scaled_sz = sz * wcross_size; \
1361                                 if(wcross_blur > 0) \
1362                                 { \
1363                                         for(i = -2; i <= 2; ++i) \
1364                                         for(j = -2; j <= 2; ++j) \
1365                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1366                                 } \
1367                                 else \
1368                                 { \
1369                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1370                                 } \
1371                         } MACRO_END
1372
1373 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1374                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1375
1376 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1377                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1378
1379                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1380                         {
1381                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1382                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1383                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1384                                 f = 1 - f;
1385                         }
1386                         else
1387                         {
1388                                 f = 1;
1389                         }
1390                         wcross_name_alpha_goal_prev = f;
1391
1392                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1393                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1394
1395                         if(autocvar_crosshair_dot)
1396                         {
1397                                 vector wcross_color_old;
1398                                 wcross_color_old = wcross_color;
1399
1400                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1401                                         wcross_color = stov(autocvar_crosshair_dot_color);
1402
1403                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1404                                 // FIXME why don't we use wcross_alpha here?
1405                                 wcross_color = wcross_color_old;
1406                         }
1407                 }
1408         }
1409         else
1410         {
1411                 wcross_scale_prev = 0;
1412                 wcross_alpha_prev = 0;
1413                 wcross_scale_goal_prev = 0;
1414                 wcross_alpha_goal_prev = 0;
1415                 wcross_changedonetime = 0;
1416                 strfree(wcross_name_goal_prev);
1417                 strfree(wcross_name_goal_prev_prev);
1418                 wcross_name_changestarttime = 0;
1419                 wcross_name_changedonetime = 0;
1420                 wcross_name_alpha_goal_prev = 0;
1421                 wcross_name_alpha_goal_prev_prev = 0;
1422                 wcross_resolution_goal_prev = 0;
1423                 wcross_resolution_goal_prev_prev = 0;
1424         }
1425 }
1426
1427 const int MAX_SPECIALCOMMAND = 15;
1428 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1429 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1430 const float SPECIALCOMMAND_SPEED = 150;
1431 const float SPECIALCOMMAND_TURNSPEED = 2;
1432 const float SPECIALCOMMAND_SIZE = 0.025;
1433 const float SPECIALCOMMAND_CHANCE = 0.35;
1434 float sc_spawntime, sc_changetime;
1435 vector sc_color = '1 1 1';
1436 void SpecialCommand()
1437 {
1438         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1439                 return;
1440
1441         if(time >= sc_changetime)
1442         {
1443                 sc_changetime = time + 1;
1444                 sc_color = randomvec() * 1.5;
1445                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1446                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1447                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1448         }
1449         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1450
1451         if(!precache_pic("gfx/smile"))
1452                 return; // damn party poopers
1453
1454         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1455         {
1456                 vector slot = specialcommand_slots[j];
1457                 if(slot.y)
1458                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1459                 //if(slot.z)
1460                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1461                 if(slot.y >= vid_conheight)
1462                         slot = '0 0 0';
1463
1464                 if(slot == '0 0 0')
1465                 {
1466                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1467                         {
1468                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1469                                 slot.y = 1; // start it off 0 so we can use it
1470                                 slot.z = floor(random() * Weapons_MAX);
1471                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1472                                 vector newcolor = randomvec() * 2;
1473                                 newcolor.x = bound(0.4, newcolor.x, 1);
1474                                 newcolor.y = bound(0.4, newcolor.y, 1);
1475                                 newcolor.z = bound(0.4, newcolor.z, 1);
1476                                 specialcommand_colors[j] = newcolor;
1477                         }
1478                 }
1479                 else
1480                 {
1481                         vector splash_size = '0 0 0';
1482                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1483                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1484                         entity wep = Weapons_from(slot.z);
1485                         if(wep == WEP_Null)
1486                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1487                         else
1488                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1489                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1490                 }
1491
1492                 specialcommand_slots[j] = slot;
1493         }
1494 }
1495
1496 void HUD_Draw(entity this)
1497 {
1498         // if we don't know gametype and scores yet avoid drawing the scoreboard
1499         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1500         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1501         // cl_deathscoreboard would show the scoreboard and so on
1502         if(!gametype)
1503                 return;
1504
1505         Hud_Dynamic_Frame();
1506
1507         if(!intermission)
1508         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1509         {
1510                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1511         }
1512         else if(STAT(FROZEN))
1513         {
1514                 vector col = '0.25 0.90 1';
1515                 if(STAT(REVIVE_PROGRESS))
1516                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1517                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1518         }
1519
1520         HUD_Scale_Enable();
1521         if(!intermission)
1522         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1523         {
1524                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1525                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1526                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1527         }
1528         else if(STAT(CAPTURE_PROGRESS))
1529         {
1530                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1531                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1532         }
1533         else if(STAT(REVIVE_PROGRESS))
1534         {
1535                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1536                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1537         }
1538         HUD_Scale_Disable();
1539
1540         if(autocvar_r_letterbox == 0)
1541                 if(autocvar_viewsize < 120)
1542                 {
1543                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1544                                 Accuracy_LoadLevels();
1545
1546                         HUD_Main();
1547                         HUD_Scale_Disable();
1548                 }
1549
1550         // crosshair goes VERY LAST
1551         SpecialCommand();
1552         UpdateDamage();
1553         HUD_Crosshair(this);
1554         HitSound();
1555 }
1556
1557 void ViewLocation_Mouse()
1558 {
1559         if(spectatee_status)
1560                 return; // don't draw it as spectator!
1561
1562         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1563         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1564         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1565
1566         //float cursor_alpha = 1 - autocvar__menu_alpha;
1567         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1568 }
1569
1570 void HUD_Cursor_Show()
1571 {
1572         float cursor_alpha = 1 - autocvar__menu_alpha;
1573         if(cursor_type == CURSOR_NORMAL)
1574                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1575         else if(cursor_type == CURSOR_MOVE)
1576                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1577         else if(cursor_type == CURSOR_RESIZE)
1578                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1579         else if(cursor_type == CURSOR_RESIZE2)
1580                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1581 }
1582
1583 void HUD_Mouse(entity player)
1584 {
1585         if(autocvar__menu_alpha == 1)
1586                 return;
1587
1588         if(!cursor_active)
1589         {
1590                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1591                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1592                 return;
1593         }
1594
1595         if(!autocvar_hud_cursormode)
1596                 update_mousepos();
1597
1598         if(autocvar__hud_configure)
1599                 HUD_Panel_Mouse();
1600         else
1601         {
1602                 if (HUD_MinigameMenu_IsOpened())
1603                         HUD_Minigame_Mouse();
1604                 if (QuickMenu_IsOpened())
1605                         QuickMenu_Mouse();
1606                 if (HUD_Radar_Clickable())
1607                         HUD_Radar_Mouse();
1608         }
1609
1610         prevMouseClicked = mouseClicked;
1611
1612         HUD_Cursor_Show();
1613 }
1614
1615 bool ov_enabled;
1616 float oldr_nearclip;
1617 float oldr_farclip_base;
1618 float oldr_farclip_world;
1619 float oldr_novis;
1620 float oldr_useportalculling;
1621 float oldr_useinfinitefarclip;
1622
1623 float prev_myteam;
1624 int lasthud;
1625 float vh_notice_time;
1626 void CSQC_UpdateView(entity this, float w, float h)
1627 {
1628         TC(int, w); TC(int, h);
1629         entity e;
1630         float fov;
1631         float f;
1632         vector vf_size, vf_min;
1633         float a;
1634
1635         execute_next_frame();
1636
1637         ++framecount;
1638
1639         stats_get();
1640         hud = STAT(HUD);
1641
1642         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1643                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1644
1645         lasthud = hud;
1646
1647         HUD_Scale_Disable();
1648
1649         if(autocvar__hud_showbinds_reload) // menu can set this one
1650         {
1651                 db_close(binddb);
1652                 binddb = db_create();
1653                 cvar_set("_hud_showbinds_reload", "0");
1654         }
1655
1656         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1657                 view_quality = getproperty(VF_MINFPS_QUALITY);
1658         else
1659                 view_quality = 1;
1660
1661         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1662         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1663
1664         vf_size = getpropertyvec(VF_SIZE);
1665         vf_min = getpropertyvec(VF_MIN);
1666         vid_width = vf_size.x;
1667         vid_height = vf_size.y;
1668
1669         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1670         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1671
1672         WaypointSprite_Load();
1673
1674         CSQCPlayer_SetCamera();
1675
1676         if(player_localentnum <= maxclients) // is it a client?
1677                 current_player = player_localentnum - 1;
1678         else // then player_localentnum is the vehicle I'm driving
1679                 current_player = player_localnum;
1680         myteam = entcs_GetTeam(current_player);
1681
1682         if(myteam != prev_myteam)
1683         {
1684                 myteamcolors = colormapPaletteColor(myteam, 1);
1685                 FOREACH(hud_panels, true, it.update_time = time);
1686                 prev_myteam = myteam;
1687         }
1688
1689         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1690
1691         float is_dead = (STAT(HEALTH) <= 0);
1692
1693         // FIXME do we need this hack?
1694         if(isdemo())
1695         {
1696                 // in demos, input_buttons do not work
1697                 button_zoom = (autocvar__togglezoom == "-");
1698         }
1699         else if(button_zoom
1700                 && autocvar_cl_unpress_zoom_on_death
1701                 && (spectatee_status >= 0)
1702                 && (is_dead || intermission))
1703         {
1704                 // no zoom while dead or in intermission please
1705                 localcmd("-zoom\n");
1706                 button_zoom = false;
1707         }
1708
1709         // abused multiple places below
1710         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1711         if(!local_player)
1712                 local_player = this; // fall back!
1713
1714         // event chase camera
1715         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1716         {
1717                 if(STAT(CAMERA_SPECTATOR))
1718                 {
1719                         if(spectatee_status > 0)
1720                         {
1721                                 if(!autocvar_chase_active)
1722                                 {
1723                                         cvar_set("chase_active", "-2");
1724                                         goto skip_eventchase_death;
1725                                 }
1726                         }
1727                         else if(autocvar_chase_active == -2)
1728                                 cvar_set("chase_active", "0");
1729
1730                         if(autocvar_chase_active == -2)
1731                                 goto skip_eventchase_death;
1732                 }
1733                 else if(autocvar_chase_active == -2)
1734                         cvar_set("chase_active", "0");
1735
1736                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1737
1738                 float vehicle_viewdist = 0;
1739                 vector vehicle_viewofs = '0 0 0';
1740
1741                 if(vehicle_chase)
1742                 {
1743                         if(hud != HUD_BUMBLEBEE_GUN)
1744                         {
1745                                 Vehicle info = Vehicles_from(hud);
1746                                 vehicle_viewdist = info.height;
1747                                 vehicle_viewofs = info.view_ofs;
1748                         }
1749                 }
1750
1751                 int eventchase = WantEventchase(this);
1752                 if (eventchase)
1753                 {
1754                         vector current_view_origin_override = '0 0 0';
1755                         vector view_offset_override = '0 0 0';
1756                         float chase_distance_override = 0;
1757                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1758                         if(custom_eventchase)
1759                         {
1760                                 current_view_origin_override = M_ARGV(0, vector);
1761                                 view_offset_override = M_ARGV(1, vector);
1762                                 chase_distance_override = M_ARGV(0, float);
1763                         }
1764                         eventchase_running = true;
1765
1766                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1767                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1768                         if (custom_eventchase)
1769                                 current_view_origin = current_view_origin_override;
1770
1771                         // detect maximum viewoffset and use it
1772                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1773                         if(vehicle_chase)
1774                         {
1775                                 if(vehicle_viewofs)
1776                                         view_offset = vehicle_viewofs;
1777                                 else
1778                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1779                         }
1780                         if (custom_eventchase)
1781                                 view_offset = view_offset_override;
1782
1783                         if(view_offset)
1784                         {
1785                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1786                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1787                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1788                         }
1789
1790                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1791                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1792                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1793                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1794
1795                         // make the camera smooth back
1796                         float chase_distance = autocvar_cl_eventchase_distance;
1797                         if(vehicle_chase)
1798                         {
1799                                 if(vehicle_viewofs)
1800                                         chase_distance = vehicle_viewdist;
1801                                 else
1802                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1803                         }
1804                         if (custom_eventchase)
1805                                 chase_distance = chase_distance_override;
1806
1807                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1808                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1809                         else if(eventchase_current_distance != chase_distance)
1810                                 eventchase_current_distance = chase_distance;
1811
1812                         makevectors(view_angles);
1813
1814                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1815                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1816
1817                         // If the boxtrace fails, revert back to line tracing.
1818                         if(!local_player.viewloc)
1819                         if(trace_startsolid)
1820                         {
1821                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1822                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1823                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1824                         }
1825                         else { setproperty(VF_ORIGIN, trace_endpos); }
1826
1827                         if(!local_player.viewloc)
1828                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1829                 }
1830
1831                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1832                 {
1833                         eventchase_running = false;
1834                         cvar_set("chase_active", "0");
1835                         eventchase_current_distance = 0; // start from 0 next time
1836                 }
1837         }
1838         // workaround for camera stuck between player's legs when using chase_active 1
1839         // because the engine stops updating the chase_active camera when the game ends
1840         else if(intermission)
1841         {
1842                 cvar_settemp("chase_active", "-1");
1843                 eventchase_current_distance = 0;
1844         }
1845
1846         LABEL(skip_eventchase_death);
1847
1848         // do lockview after event chase camera so that it still applies whenever necessary.
1849         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1850         {
1851                 setproperty(VF_ORIGIN, freeze_org);
1852                 setproperty(VF_ANGLES, freeze_ang);
1853         }
1854         else
1855         {
1856                 freeze_org = getpropertyvec(VF_ORIGIN);
1857                 freeze_ang = getpropertyvec(VF_ANGLES);
1858         }
1859
1860         WarpZone_FixView();
1861         //WarpZone_FixPMove();
1862
1863         vector ov_org = '0 0 0';
1864         vector ov_mid = '0 0 0';
1865         vector ov_worldmin = '0 0 0';
1866         vector ov_worldmax = '0 0 0';
1867         if(autocvar_cl_orthoview)
1868         {
1869                 ov_worldmin = mi_picmin;
1870                 ov_worldmax = mi_picmax;
1871
1872                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1873                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1874                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1875
1876                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1877                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1878
1879                 float ov_nearest = vlen(ov_org - vec3(
1880                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1881                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1882                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1883                 ));
1884
1885                 float ov_furthest = 0;
1886                 float dist = 0;
1887
1888                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1889                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1890                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1891                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1892                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1893                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1894                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1895                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1896
1897                 if(!ov_enabled)
1898                 {
1899                         oldr_nearclip = cvar("r_nearclip");
1900                         oldr_farclip_base = cvar("r_farclip_base");
1901                         oldr_farclip_world = cvar("r_farclip_world");
1902                         oldr_novis = cvar("r_novis");
1903                         oldr_useportalculling = cvar("r_useportalculling");
1904                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1905                 }
1906
1907                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1908                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1909                 cvar_settemp("r_farclip_world", "0");
1910                 cvar_settemp("r_novis", "1");
1911                 cvar_settemp("r_useportalculling", "0");
1912                 cvar_settemp("r_useinfinitefarclip", "0");
1913
1914                 setproperty(VF_ORIGIN, ov_org);
1915                 setproperty(VF_ANGLES, '90 0 0');
1916
1917                 ov_enabled = true;
1918
1919                 #if 0
1920                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1921                         vtos(ov_org),
1922                         vtos(getpropertyvec(VF_ANGLES)),
1923                         ov_distance,
1924                         ov_nearest,
1925                         ov_furthest);
1926                 #endif
1927         }
1928         else
1929         {
1930                 if(ov_enabled)
1931                 {
1932                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1933                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1934                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1935                         cvar_set("r_novis", ftos(oldr_novis));
1936                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1937                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1938                 }
1939                 ov_enabled = false;
1940         }
1941
1942         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1943         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1944         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1945                 viewmodel_draw(viewmodels[slot]);
1946
1947         // Render the Scene
1948         view_origin = getpropertyvec(VF_ORIGIN);
1949         view_angles = getpropertyvec(VF_ANGLES);
1950         MAKEVECTORS(makevectors, view_angles, view_forward, view_right, view_up);
1951
1952 #ifdef BLURTEST
1953         if(time > blurtest_time0 && time < blurtest_time1)
1954         {
1955                 float r, t;
1956
1957                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1958                 r = t * blurtest_radius;
1959                 f = 1 / (t ** blurtest_power) - 1;
1960
1961                 cvar_set("r_glsl_postprocess", "1");
1962                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1963         }
1964         else
1965         {
1966                 cvar_set("r_glsl_postprocess", "0");
1967                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1968         }
1969 #endif
1970
1971         TargetMusic_Advance();
1972         Fog_Force();
1973         fpscounter_update();
1974
1975         if(drawtime == 0)
1976                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1977         else
1978                 drawframetime = bound(0.000001, time - drawtime, 1);
1979         drawtime = time;
1980
1981         // watch for gametype changes here...
1982         // in ParseStuffCMD the cmd isn't executed yet :/
1983         // might even be better to add the gametype to TE_CSQC_INIT...?
1984         if(!postinit)
1985                 PostInit();
1986
1987         if(intermission && !intermission_time)
1988                 intermission_time = time;
1989
1990         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1991         {
1992                 if(calledhooks & HOOK_START)
1993                 {
1994                         localcmd("\ncl_hook_gameend\n");
1995                         calledhooks |= HOOK_END;
1996                 }
1997         }
1998
1999         Announcer();
2000
2001         fov = autocvar_fov;
2002         if(fov <= 59.5)
2003         {
2004                 if(!zoomscript_caught)
2005                 {
2006                         localcmd("+button9\n");
2007                         zoomscript_caught = 1;
2008                 }
2009         }
2010         else
2011         {
2012                 if(zoomscript_caught)
2013                 {
2014                         localcmd("-button9\n");
2015                         zoomscript_caught = 0;
2016                 }
2017         }
2018
2019         if(active_minigame && HUD_MinigameMenu_IsOpened())
2020         {
2021                 if(!minigame_wasactive)
2022                 {
2023                         localcmd("+button14\n");
2024                         minigame_wasactive = true;
2025                 }
2026         }
2027         else if(minigame_wasactive)
2028         {
2029                 localcmd("-button14\n");
2030                 minigame_wasactive = false;
2031         }
2032
2033         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2034
2035         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2036         {
2037                 entity wepent = viewmodels[slot];
2038
2039                 if(wepent.last_switchweapon != wepent.switchweapon)
2040                 {
2041                         weapontime = time;
2042                         wepent.last_switchweapon = wepent.switchweapon;
2043                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2044                         {
2045                                 localcmd("-zoom\n");
2046                                 button_zoom = false;
2047                         }
2048                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2049                         {
2050                                 localcmd("-fire\n");
2051                                 localcmd("-fire2\n");
2052                                 button_attack2 = false;
2053                         }
2054                 }
2055                 if(wepent.last_activeweapon != wepent.activeweapon)
2056                 {
2057                         wepent.last_activeweapon = wepent.activeweapon;
2058
2059                         e = wepent.activeweapon;
2060                         if(e.netname != "")
2061                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2062                         else if(slot == 0)
2063                                 localcmd("\ncl_hook_activeweapon none\n");
2064                 }
2065         }
2066
2067         // ALWAYS Clear Current Scene First
2068         clearscene();
2069
2070         setproperty(VF_ORIGIN, view_origin);
2071         setproperty(VF_ANGLES, view_angles);
2072
2073         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2074         setproperty(VF_SIZE, vf_size);
2075         setproperty(VF_MIN, vf_min);
2076
2077         // Assign Standard Viewflags
2078         // Draw the World (and sky)
2079         setproperty(VF_DRAWWORLD, 1);
2080
2081         // Set the console size vars
2082         vid_conwidth = autocvar_vid_conwidth;
2083         vid_conheight = autocvar_vid_conheight;
2084         vid_pixelheight = autocvar_vid_pixelheight;
2085
2086         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2087         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2088         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2089
2090         if(camera_active) // Camera for demo playback
2091         {
2092                 if(autocvar_camera_enable)
2093                         CSQC_Demo_Camera();
2094                 else
2095                 {
2096                         cvar_set("chase_active", ftos(chase_active_backup));
2097                         cvar_set("cl_demo_mousegrab", "0");
2098                         camera_active = false;
2099                 }
2100         }
2101         else
2102         {
2103 #ifdef CAMERATEST
2104                 if(autocvar_camera_enable)
2105 #else
2106                 if(autocvar_camera_enable && isdemo())
2107 #endif
2108                 {
2109                         // Enable required Darkplaces cvars
2110                         chase_active_backup = autocvar_chase_active;
2111                         cvar_set("chase_active", "2");
2112                         cvar_set("cl_demo_mousegrab", "1");
2113                         camera_active = true;
2114                         camera_mode = false;
2115                 }
2116         }
2117
2118         // Draw the Crosshair
2119         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2120
2121         // Draw the Engine Status Bar (the default Quake HUD)
2122         setproperty(VF_DRAWENGINESBAR, 0);
2123
2124         // Update the mouse position
2125         /*
2126            mousepos_x = vid_conwidth;
2127            mousepos_y = vid_conheight;
2128            mousepos = mousepos*0.5 + getmousepos();
2129          */
2130
2131         IL_EACH(g_drawables, it.draw, it.draw(it));
2132
2133         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2134         renderscene();
2135
2136         // now switch to 2D drawing mode by calling a 2D drawing function
2137         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2138         // next R_RenderScene call
2139         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2140
2141         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2142         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2143         {
2144                 // apply night vision effect
2145                 vector tc_00, tc_01, tc_10, tc_11;
2146                 vector rgb = '0 0 0';
2147
2148                 if(!nightvision_noise)
2149                 {
2150                         nightvision_noise = new(nightvision_noise);
2151                 }
2152                 if(!nightvision_noise2)
2153                 {
2154                         nightvision_noise2 = new(nightvision_noise2);
2155                 }
2156
2157                 // color tint in yellow
2158                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2159
2160                 // draw BG
2161                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2162                 rgb = '1 1 1';
2163                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2164                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2165                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2166                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2167                 tc_11 = tc_01 + tc_10 - tc_00;
2168                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2169                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2170                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2171                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2172                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2173                 R_EndPolygon();
2174
2175                 // draw FG
2176                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2177                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2178                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2179                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2180                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2181                 tc_11 = tc_01 + tc_10 - tc_00;
2182                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2183                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2184                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2185                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2186                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2187                 R_EndPolygon();
2188         }
2189
2190         if(autocvar_cl_reticle)
2191         {
2192                 string reticle_image = string_null;
2193                 bool wep_zoomed = false;
2194                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2195                 {
2196                         entity wepe = viewmodels[slot];
2197                         Weapon wep = wepe.activeweapon;
2198                         if(wep != WEP_Null && wep.wr_zoom)
2199                         {
2200                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2201                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2202                                         reticle_image = wep.w_reticle;
2203                                 wep_zoomed += do_zoom;
2204                         }
2205                 }
2206                 // Draw the aiming reticle for weapons that use it
2207                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2208                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2209                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2210                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2211                 {
2212                         // no zoom reticle while dead
2213                         reticle_type = 0;
2214                 }
2215                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2216                 {
2217                         if(reticle_image) { reticle_type = 2; }
2218                         else { reticle_type = 0; }
2219                 }
2220                 else if(button_zoom || zoomscript_caught)
2221                 {
2222                         // normal zoom
2223                         reticle_type = 1;
2224                 }
2225
2226                 if(reticle_type)
2227                 {
2228                         if(autocvar_cl_reticle_stretch)
2229                         {
2230                                 reticle_size.x = vid_conwidth;
2231                                 reticle_size.y = vid_conheight;
2232                                 reticle_pos.x = 0;
2233                                 reticle_pos.y = 0;
2234                         }
2235                         else
2236                         {
2237                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2238                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2239                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2240                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2241                         }
2242
2243                         if(zoomscript_caught)
2244                                 f = 1;
2245                         else
2246                                 f = current_zoomfraction;
2247
2248                         if(f)
2249                         {
2250                                 switch(reticle_type)
2251                                 {
2252                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2253                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2254                                 }
2255                         }
2256                 }
2257         }
2258         else
2259         {
2260                 if(reticle_type != 0) { reticle_type = 0; }
2261         }
2262
2263
2264         // improved polyblend
2265         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2266         {
2267                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2268                 vector liquidcolor;
2269
2270                 switch(pointcontents(view_origin))
2271                 {
2272                         case CONTENT_WATER:
2273                                 liquidalpha = autocvar_hud_contents_water_alpha;
2274                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2275                                 incontent = 1;
2276                                 break;
2277
2278                         case CONTENT_LAVA:
2279                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2280                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2281                                 incontent = 1;
2282                                 break;
2283
2284                         case CONTENT_SLIME:
2285                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2286                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2287                                 incontent = 1;
2288                                 break;
2289
2290                         default:
2291                                 liquidalpha = 0;
2292                                 liquidcolor = '0 0 0';
2293                                 incontent = 0;
2294                                 break;
2295                 }
2296
2297                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2298                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2299                         contentfadetime = autocvar_hud_contents_fadeintime;
2300                         liquidalpha_prev = liquidalpha;
2301                         liquidcolor_prev = liquidcolor;
2302                 }
2303                 else
2304                         contentfadetime = autocvar_hud_contents_fadeouttime;
2305
2306                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2307                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2308
2309                 if(contentavgalpha)
2310                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2311
2312                 if(autocvar_hud_postprocessing)
2313                 {
2314                         if(autocvar_hud_contents_blur && contentavgalpha)
2315                         {
2316                                 content_blurpostprocess.x = 1;
2317                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2318                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2319                         }
2320                         else
2321                         {
2322                                 content_blurpostprocess.x = 0;
2323                                 content_blurpostprocess.y = 0;
2324                                 content_blurpostprocess.z = 0;
2325                         }
2326                 }
2327         }
2328
2329         if(autocvar_hud_damage && !STAT(FROZEN))
2330         {
2331                 splash_size.x = max(vid_conwidth, vid_conheight);
2332                 splash_size.y = max(vid_conwidth, vid_conheight);
2333                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2334                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2335
2336                 float myhealth_flash_temp;
2337                 myhealth = STAT(HEALTH);
2338
2339                 // fade out
2340                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2341                 // add new damage
2342                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2343
2344                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2345                 pain_threshold = autocvar_hud_damage_pain_threshold;
2346                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2347                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2348
2349                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2350                 {
2351                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2352                 }
2353
2354                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2355
2356                 if(myhealth_prev < 1)
2357                 {
2358                         if(myhealth >= 1)
2359                         {
2360                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2361                                 myhealth_flash_temp = 0;
2362                         }
2363                         else
2364                         {
2365                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2366                         }
2367                 }
2368
2369                 if(spectatee_status == -1 || intermission)
2370                 {
2371                         myhealth_flash = 0; // observing, or match ended
2372                         myhealth_flash_temp = 0;
2373                 }
2374
2375                 myhealth_prev = myhealth;
2376
2377                 // IDEA: change damage color/picture based on player model for robot/alien species?
2378                 // pro: matches model better
2379                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2380                 // maybe different reddish pics?
2381                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2382                 {
2383                         if(autocvar_cl_gentle_damage == 2)
2384                         {
2385                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2386                                         myhealth_gentlergb = randomvec();
2387                         }
2388                         else
2389                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2390
2391                         if(myhealth_flash_temp > 0)
2392                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2393                 }
2394                 else if(myhealth_flash_temp > 0)
2395                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2396
2397                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2398                 {
2399                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2400                         {
2401                                 damage_blurpostprocess.x = 1;
2402                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2403                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2404                         }
2405                         else
2406                         {
2407                                 damage_blurpostprocess.x = 0;
2408                                 damage_blurpostprocess.y = 0;
2409                                 damage_blurpostprocess.z = 0;
2410                         }
2411                 }
2412         }
2413
2414         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2415         float e2 = (autocvar_hud_powerup != 0);
2416         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2417         {
2418                 // enable or disable rendering types if they are used or not
2419                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2420                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2421
2422                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2423                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2424                 {
2425                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2426                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2427                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2428                         {
2429                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2430                                 old_blurradius = blurradius;
2431                                 old_bluralpha = bluralpha;
2432                         }
2433                 }
2434                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2435                 {
2436                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2437                         old_blurradius = 0;
2438                         old_bluralpha = 0;
2439                 }
2440
2441                 // edge detection postprocess handling done second (used by hud_powerup)
2442                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2443                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2444                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2445
2446                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2447
2448                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2449                 {
2450                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2451                         {
2452                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2453                                 old_sharpen_intensity = sharpen_intensity;
2454                         }
2455                 }
2456                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2457                 {
2458                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2459                         old_sharpen_intensity = 0;
2460                 }
2461
2462                 if(cvar("r_glsl_postprocess") == 0)
2463                         cvar_set("r_glsl_postprocess", "2");
2464         }
2465         else if(cvar("r_glsl_postprocess") == 2)
2466                 cvar_set("r_glsl_postprocess", "0");
2467
2468         /*if(ISGAMETYPE(CTF))
2469           {
2470           ctf_view();
2471           } else */
2472
2473         // draw 2D entities
2474         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2475         Draw_ShowNames_All();
2476 #if ENABLE_DEBUGDRAW
2477         Debug_Draw();
2478 #endif
2479
2480         scoreboard_active = Scoreboard_WouldDraw();
2481
2482         HUD_Draw(this); // this parameter for deep vehicle function
2483
2484         if(NextFrameCommand)
2485         {
2486                 localcmd("\n", NextFrameCommand, "\n");
2487                 NextFrameCommand = string_null;
2488         }
2489
2490         // we must do this check AFTER a frame was rendered, or it won't work
2491         if(cs_project_is_b0rked == 0)
2492         {
2493                 string w0, h0;
2494                 w0 = ftos(autocvar_vid_conwidth);
2495                 h0 = ftos(autocvar_vid_conheight);
2496                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2497                 //setproperty(VF_FOV, '90 90 0');
2498                 setproperty(VF_ORIGIN, '0 0 0');
2499                 setproperty(VF_ANGLES, '0 0 0');
2500                 setproperty(VF_PERSPECTIVE, 1);
2501                 makevectors('0 0 0');
2502                 vector v1, v2;
2503                 cvar_set("vid_conwidth", "800");
2504                 cvar_set("vid_conheight", "600");
2505                 v1 = cs_project(v_forward);
2506                 cvar_set("vid_conwidth", "640");
2507                 cvar_set("vid_conheight", "480");
2508                 v2 = cs_project(v_forward);
2509                 if(v1 == v2)
2510                         cs_project_is_b0rked = 1;
2511                 else
2512                         cs_project_is_b0rked = -1;
2513                 cvar_set("vid_conwidth", w0);
2514                 cvar_set("vid_conheight", h0);
2515         }
2516
2517         HUD_Mouse(local_player);
2518
2519         cl_notice_run();
2520         unpause_update();
2521         Net_Flush();
2522
2523         // let's reset the view back to normal for the end
2524         setproperty(VF_MIN, '0 0 0');
2525         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2526
2527         IL_ENDFRAME();
2528 }
2529
2530
2531 // following vectors must be global to allow seamless switching between camera modes
2532 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2533 void CSQC_Demo_Camera()
2534 {
2535         float speed, attenuation, dimensions;
2536         vector tmp, delta;
2537
2538         if( autocvar_camera_reset || !camera_mode )
2539         {
2540                 camera_offset = '0 0 0';
2541                 current_angles = '0 0 0';
2542                 camera_direction = '0 0 0';
2543                 camera_offset.z += 30;
2544                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2545                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2546                 current_origin = view_origin;
2547                 current_camera_offset  = camera_offset;
2548                 cvar_set("camera_reset", "0");
2549                 camera_mode = CAMERA_CHASE;
2550         }
2551
2552         // Camera angles
2553         if( camera_roll )
2554                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2555
2556         if(autocvar_camera_look_player)
2557         {
2558                 vector dir;
2559                 float n;
2560
2561                 dir = normalize(view_origin - current_position);
2562                 n = mouse_angles.z;
2563                 mouse_angles = vectoangles(dir);
2564                 mouse_angles.x = mouse_angles.x * -1;
2565                 mouse_angles.z = n;
2566         }
2567         else
2568         {
2569                 tmp = getmousepos() * 0.1;
2570                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2571                 {
2572                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2573                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2574                 }
2575         }
2576
2577         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2578         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2579         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2580         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2581
2582         // Fix difference when angles don't have the same sign
2583         delta = '0 0 0';
2584         if(mouse_angles.y < -60 && current_angles.y > 60)
2585                 delta = '0 360 0';
2586         if(mouse_angles.y > 60 && current_angles.y < -60)
2587                 delta = '0 -360 0';
2588
2589         if(autocvar_camera_look_player)
2590                 attenuation = autocvar_camera_look_attenuation;
2591         else
2592                 attenuation = autocvar_camera_speed_attenuation;
2593
2594         attenuation = 1 / max(1, attenuation);
2595         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2596
2597         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2598         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2599         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2600         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2601
2602         // Camera position
2603         tmp = '0 0 0';
2604         dimensions = 0;
2605
2606         if( camera_direction.x )
2607         {
2608                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2609                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2610                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2611                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2612                 ++dimensions;
2613         }
2614
2615         if( camera_direction.y )
2616         {
2617                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2618                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2619                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2620                 ++dimensions;
2621         }
2622
2623         if( camera_direction.z )
2624         {
2625                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2626                 ++dimensions;
2627         }
2628
2629         if(autocvar_camera_free)
2630                 speed = autocvar_camera_speed_free;
2631         else
2632                 speed = autocvar_camera_speed_chase;
2633
2634         if(dimensions)
2635         {
2636                 speed = speed * sqrt(1 / dimensions);
2637                 camera_offset += tmp * speed;
2638         }
2639
2640         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2641
2642         // Camera modes
2643         if( autocvar_camera_free )
2644         {
2645                 if ( camera_mode == CAMERA_CHASE )
2646                 {
2647                         current_camera_offset = current_origin + current_camera_offset;
2648                         camera_offset = current_origin + camera_offset;
2649                 }
2650
2651                 camera_mode = CAMERA_FREE;
2652                 current_position = current_camera_offset;
2653         }
2654         else
2655         {
2656                 if ( camera_mode == CAMERA_FREE )
2657                 {
2658                         current_origin = view_origin;
2659                         camera_offset = camera_offset - current_origin;
2660                         current_camera_offset = current_camera_offset - current_origin;
2661                 }
2662
2663                 camera_mode = CAMERA_CHASE;
2664
2665                 if(autocvar_camera_chase_smoothly)
2666                         current_origin += (view_origin - current_origin) * attenuation;
2667                 else
2668                         current_origin = view_origin;
2669
2670                 current_position = current_origin + current_camera_offset;
2671         }
2672
2673         setproperty(VF_ANGLES, current_angles);
2674         setproperty(VF_ORIGIN, current_position);
2675 }