qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/all.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 void viewmodel_draw(entity this)
 285 {
 286         if(!activeweapon || !autocvar_r_drawviewmodel)
 287                 return;
 288         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 289         float a = this.alpha;
 290         static bool wasinvehicle;
 291         bool invehicle = player_localentnum > maxclients;
 292         if (invehicle) a = -1;
 293         else if (wasinvehicle) a = 1;
 294         wasinvehicle = invehicle;
 295         Weapon wep = activeweapon;
 296         int c = stof(getplayerkeyvalue(current_player, "colors"));
 297         vector g = weaponentity_glowmod(wep, c);
 298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 300                 | EF_NODEPTHTEST)
 301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 302         for (entity e = this; e; e = e.weaponchild)
 303         {
 304                 e.drawmask = mask;
 305                 e.alpha = a;
 306                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 307                 e.glowmod = g;
 308                 e.csqcmodel_effects = fx;
 309                 CSQCModel_Effects_Apply(e);
 310         }
 311         {
 312                 static string name_last;
 313                 string name = wep.mdl;
 314                 bool swap = name != name_last;
 315                 // if (swap)
 316                 {
 317                         name_last = name;
 318                         CL_WeaponEntity_SetModel(this, name, swap);
 319                         this.viewmodel_origin = this.origin;
 320                         this.viewmodel_angles = this.angles;
 321                 }
 322                 anim_update(this);
 323                 if (!this.animstate_override && !this.animstate_looping)
 324                         anim_set(this, this.anim_idle, true, false, false);
 325         }
 326         float f = 0; // 0..1; 0: fully active
 327         float rate = STAT(WEAPONRATEFACTOR);
 328         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 329         if (eta <= 0) f = this.weapon_eta_last;
 330         else switch (this.state)
 331         {
 332                 case WS_RAISE:
 333                 {
 334                         f = eta / max(eta, this.weapon_switchdelay);
 335                         break;
 336                 }
 337                 case WS_DROP:
 338                 {
 339                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 340                         break;
 341                 }
 342                 case WS_CLEAR:
 343                 {
 344                         f = 1;
 345                         break;
 346                 }
 347         }
 348         this.weapon_eta_last = f;
 349         this.origin = this.viewmodel_origin;
 350         this.angles = this.viewmodel_angles;
 351         this.angles_x = (-90 * f * f);
 352         viewmodel_animate(this);
 353         setorigin(this, this.origin);
 354 }
 355
 356 entity viewmodel;
 357 STATIC_INIT(viewmodel) {
 358     viewmodel = new(viewmodel);
 359 }
 360
 361 void Porto_Draw(entity this);
 362 STATIC_INIT(Porto)
 363 {
 364         entity e = new_pure(porto);
 365         e.draw = Porto_Draw;
 366         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 367 }
 368
 369 const int polyline_length = 16;
 370 vector polyline[polyline_length];
 371 void Porto_Draw(entity this)
 372 {
 373         if (activeweapon != WEP_PORTO) return;
 374         if (spectatee_status) return;
 375         if (WEP_CVAR(porto, secondary)) return;
 376         if (intermission == 1) return;
 377         if (intermission == 2) return;
 378         if (STAT(HEALTH) <= 0) return;
 379
 380         vector pos = view_origin;
 381         vector dir = view_forward;
 382         if (angles_held_status)
 383         {
 384                 makevectors(angles_held);
 385                 dir = v_forward;
 386         }
 387
 388         polyline[0] = pos;
 389
 390         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 391         int n = 1 + 2;  // 2 lines == 3 points
 392         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 393         {
 394                 traceline(pos, pos + 65536 * dir, true, this);
 395                 dir = reflect(dir, trace_plane_normal);
 396                 pos = trace_endpos;
 397                 polyline[++idx] = pos;
 398                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 399                 {
 400                         n += 1;
 401                         continue;
 402                 }
 403                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 404                 {
 405                         n = max(2, idx);
 406                         break;
 407                 }
 408                 // check size
 409                 {
 410                         vector ang = vectoangles2(trace_plane_normal, dir);
 411                         ang.x = -ang.x;
 412                         makevectors(ang);
 413                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 414                         {
 415                                 n = max(2, idx);
 416                                 break;
 417                         }
 418                 }
 419                 portal_number += 1;
 420                 if (portal_number >= portal_max) break;
 421                 if (portal_number == 1) portal1_idx = idx;
 422         }
 423         for (int idx = 0; idx < n - 1; ++idx)
 424         {
 425                 vector p = polyline[idx], q = polyline[idx + 1];
 426                 if (idx == 0) p -= view_up * 16;  // line from player
 427                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 428                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 429         }
 430 }
 431
 432 float drawtime;
 433 float avgspeed;
 434 vector GetCurrentFov(float fov)
 435 {
 436         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 437         float velocityzoom, curspeed;
 438         vector v;
 439
 440         zoomsensitivity = autocvar_cl_zoomsensitivity;
 441         zoomfactor = autocvar_cl_zoomfactor;
 442         if(zoomfactor < 1 || zoomfactor > 30)
 443                 zoomfactor = 2.5;
 444         zoomspeed = autocvar_cl_zoomspeed;
 445         if(zoomspeed >= 0)
 446         if(zoomspeed < 0.5 || zoomspeed > 16)
 447                         zoomspeed = 3.5;
 448
 449         zoomdir = button_zoom;
 450         if(hud == HUD_NORMAL)
 451         if(switchweapon == activeweapon)
 452         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 453                 zoomdir += button_attack2;
 454         if(spectatee_status > 0 || isdemo())
 455         {
 456                 if(spectatorbutton_zoom)
 457                 {
 458                         if(zoomdir)
 459                                 zoomdir = 0;
 460                         else
 461                                 zoomdir = 1;
 462                 }
 463                 // fteqcc failed twice here already, don't optimize this
 464         }
 465
 466         if(zoomdir) { zoomin_effect = 0; }
 467
 468         if(camera_active)
 469         {
 470                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 471         }
 472         else if(autocvar_cl_spawnzoom && zoomin_effect)
 473         {
 474                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 475
 476                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 477                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 478                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 479         }
 480         else
 481         {
 482                 if(zoomspeed < 0) // instant zoom
 483                 {
 484                         if(zoomdir)
 485                                 current_viewzoom = 1 / zoomfactor;
 486                         else
 487                                 current_viewzoom = 1;
 488                 }
 489                 else
 490                 {
 491                         if(zoomdir)
 492                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 493                         else
 494                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 495                 }
 496         }
 497
 498         if(almost_equals(current_viewzoom, 1))
 499                 current_zoomfraction = 0;
 500         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 501                 current_zoomfraction = 1;
 502         else
 503                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 504
 505         if(zoomsensitivity < 1)
 506                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 507         else
 508                 setsensitivityscale(1);
 509
 510         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 511         {
 512                 if(intermission) { curspeed = 0; }
 513                 else
 514                 {
 515
 516                         makevectors(view_angles);
 517                         v = pmove_vel;
 518                         if(csqcplayer)
 519                                 v = csqcplayer.velocity;
 520
 521                         switch(autocvar_cl_velocityzoom_type)
 522                         {
 523                                 case 3: curspeed = max(0, v_forward * v); break;
 524                                 case 2: curspeed = (v_forward * v); break;
 525                                 case 1: default: curspeed = vlen(v); break;
 526                         }
 527                 }
 528
 529                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 530                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 531                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 532
 533                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 534         }
 535         else
 536                 velocityzoom = 1;
 537
 538         float frustumx, frustumy, fovx, fovy;
 539         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 540         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 541         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 542         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 543
 544         return '1 0 0' * fovx + '0 1 0' * fovy;
 545 }
 546
 547 vector GetViewLocationFOV(float fov)
 548 {
 549         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 550         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 551         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 552         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 553         return '1 0 0' * fovx + '0 1 0' * fovy;
 554 }
 555
 556 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 557 {
 558         float fovx, fovy;
 559         float width = (ov_worldmax.x - ov_worldmin.x);
 560         float height = (ov_worldmax.y - ov_worldmin.y);
 561         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 562         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 563         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 // this function must match W_SetupShot!
 568 float zoomscript_caught;
 569
 570 vector wcross_origin;
 571 float wcross_scale_prev, wcross_alpha_prev;
 572 vector wcross_color_prev;
 573 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 574 vector wcross_color_goal_prev;
 575 float wcross_changedonetime;
 576
 577 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 578 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 579 float wcross_name_changestarttime, wcross_name_changedonetime;
 580 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 581
 582 float wcross_ring_prev;
 583
 584 entity trueaim;
 585 entity trueaim_rifle;
 586
 587 const float SHOTTYPE_HITTEAM = 1;
 588 const float SHOTTYPE_HITOBSTRUCTION = 2;
 589 const float SHOTTYPE_HITWORLD = 3;
 590 const float SHOTTYPE_HITENEMY = 4;
 591
 592 void TrueAim_Init()
 593 {
 594         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 595         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 596 }
 597
 598 float EnemyHitCheck()
 599 {
 600         float t, n;
 601         wcross_origin = project_3d_to_2d(trace_endpos);
 602         wcross_origin.z = 0;
 603         if(trace_ent)
 604                 n = trace_ent.entnum;
 605         else
 606                 n = trace_networkentity;
 607         if(n < 1)
 608                 return SHOTTYPE_HITWORLD;
 609         if(n > maxclients)
 610                 return SHOTTYPE_HITWORLD;
 611         t = entcs_GetTeam(n - 1);
 612         if(teamplay)
 613                 if(t == myteam)
 614                         return SHOTTYPE_HITTEAM;
 615         if(t == NUM_SPECTATOR)
 616                 return SHOTTYPE_HITWORLD;
 617         return SHOTTYPE_HITENEMY;
 618 }
 619
 620 float TrueAimCheck()
 621 {
 622         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 623         vector vecs, trueaimpoint, w_shotorg;
 624         vector mi, ma, dv;
 625         float shottype;
 626         entity ta;
 627         float mv;
 628
 629         mi = ma = '0 0 0';
 630         ta = trueaim;
 631         mv = MOVE_NOMONSTERS;
 632
 633         switch(activeweapon) // WEAPONTODO
 634         {
 635                 case WEP_TUBA: // no aim
 636                 case WEP_PORTO: // shoots from eye
 637                 case WEP_NEXBALL: // shoots from eye
 638                 case WEP_HOOK: // no trueaim
 639                 case WEP_MORTAR: // toss curve
 640                         return SHOTTYPE_HITWORLD;
 641                 case WEP_VORTEX:
 642                 case WEP_VAPORIZER:
 643                         mv = MOVE_NORMAL;
 644                         break;
 645                 case WEP_RIFLE:
 646                         ta = trueaim_rifle;
 647                         mv = MOVE_NORMAL;
 648                         if(zoomscript_caught)
 649                         {
 650                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 651                                 return EnemyHitCheck();
 652                         }
 653                         break;
 654                 case WEP_DEVASTATOR: // projectile has a size!
 655                         mi = '-3 -3 -3';
 656                         ma = '3 3 3';
 657                         break;
 658                 case WEP_FIREBALL: // projectile has a size!
 659                         mi = '-16 -16 -16';
 660                         ma = '16 16 16';
 661                         break;
 662                 case WEP_SEEKER: // projectile has a size!
 663                         mi = '-2 -2 -2';
 664                         ma = '2 2 2';
 665                         break;
 666                 case WEP_ELECTRO: // projectile has a size!
 667                         mi = '0 0 -3';
 668                         ma = '0 0 -3';
 669                         break;
 670         }
 671
 672         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 673
 674         vecs = decompressShotOrigin(STAT(SHOTORG));
 675
 676         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 677         trueaimpoint = trace_endpos;
 678
 679         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 680                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 681
 682         if(vecs.x > 0)
 683                 vecs.y = -vecs.y;
 684         else
 685                 vecs = '0 0 0';
 686
 687         dv = view_right * vecs.y + view_up * vecs.z;
 688         w_shotorg = traceorigin + dv;
 689
 690         // now move the vecs forward as much as requested if possible
 691         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 692         w_shotorg = trace_endpos - view_forward * nudge;
 693
 694         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 695         shottype = EnemyHitCheck();
 696         if(shottype != SHOTTYPE_HITWORLD)
 697                 return shottype;
 698
 699 #if 0
 700         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 701         // or rather, I know why, but see no fix
 702         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 703                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 704                 return SHOTTYPE_HITOBSTRUCTION;
 705 #endif
 706
 707         return SHOTTYPE_HITWORLD;
 708 }
 709
 710 void PostInit();
 711 void CSQC_Demo_Camera();
 712 float HUD_WouldDrawScoreboard();
 713 float camera_mode;
 714 const float CAMERA_FREE = 1;
 715 const float CAMERA_CHASE = 2;
 716 float reticle_type;
 717 string reticle_image;
 718 string NextFrameCommand;
 719
 720 vector freeze_org, freeze_ang;
 721 entity nightvision_noise, nightvision_noise2;
 722
 723 const float MAX_TIME_DIFF = 5;
 724 float pickup_crosshair_time, pickup_crosshair_size;
 725 float hitindication_crosshair_size;
 726 float use_vortex_chargepool;
 727
 728 float myhealth, myhealth_prev;
 729 float myhealth_flash;
 730
 731 float old_blurradius, old_bluralpha;
 732 float old_sharpen_intensity;
 733
 734 vector myhealth_gentlergb;
 735
 736 float contentavgalpha, liquidalpha_prev;
 737 vector liquidcolor_prev;
 738
 739 float eventchase_current_distance;
 740 float eventchase_running;
 741 bool WantEventchase(entity this)
 742 {
 743         if(autocvar_cl_orthoview)
 744                 return false;
 745         if(intermission)
 746                 return true;
 747         if(this.viewloc)
 748                 return true;
 749         if(spectatee_status >= 0)
 750         {
 751                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 752                         return true;
 753                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 754                         return true;
 755                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 756                 {
 757                         if(autocvar_cl_eventchase_death == 2)
 758                         {
 759                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 760                                 if(this.velocity == '0 0 0' || eventchase_running)
 761                                         return true;
 762                         }
 763                         else return true;
 764                 }
 765         }
 766         return false;
 767 }
 768
 769 void HUD_Crosshair_Vehicle(entity this)
 770 {
 771         if(hud != HUD_BUMBLEBEE_GUN)
 772         {
 773                 Vehicle info = Vehicles_from(hud);
 774                 info.vr_crosshair(info, this);
 775         }
 776 }
 777
 778 vector damage_blurpostprocess, content_blurpostprocess;
 779
 780 float unaccounted_damage = 0;
 781 void UpdateDamage()
 782 {
 783         // accumulate damage with each stat update
 784         static float damage_total_prev = 0;
 785         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 786         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 787         damage_total_prev = damage_total;
 788
 789         static float damage_dealt_time_prev = 0;
 790         float damage_dealt_time = STAT(HIT_TIME);
 791         if (damage_dealt_time != damage_dealt_time_prev)
 792         {
 793                 unaccounted_damage += unaccounted_damage_new;
 794                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 795         }
 796         damage_dealt_time_prev = damage_dealt_time;
 797
 798         // prevent hitsound when switching spectatee
 799         static float spectatee_status_prev = 0;
 800         if (spectatee_status != spectatee_status_prev)
 801                 unaccounted_damage = 0;
 802         spectatee_status_prev = spectatee_status;
 803 }
 804
 805 void HitSound()
 806 {
 807         // varying sound pitch
 808
 809         static float hitsound_time_prev = 0;
 810         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 811         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 812         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 813         {
 814                 if (autocvar_cl_hitsound && unaccounted_damage)
 815                 {
 816                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 817                         float a = autocvar_cl_hitsound_max_pitch;
 818                         float b = autocvar_cl_hitsound_min_pitch;
 819                         float c = autocvar_cl_hitsound_nom_damage;
 820                         float x = unaccounted_damage;
 821                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 822
 823                         // if sound variation is disabled, set pitch_shift to 1
 824                         if (autocvar_cl_hitsound == 1)
 825                                 pitch_shift = 1;
 826
 827                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 828                         if (autocvar_cl_hitsound == 3)
 829                         {
 830                                 float mirror_value = (a-b)/2 + b;
 831                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 832                         }
 833
 834                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 835
 836                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 837                         // todo: normalize sound pressure levels? seems unnecessary
 838
 839                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 840                 }
 841                 unaccounted_damage = 0;
 842                 hitsound_time_prev = time;
 843         }
 844
 845         static float typehit_time_prev = 0;
 846         float typehit_time = STAT(TYPEHIT_TIME);
 847         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 848         {
 849                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 850                 typehit_time_prev = typehit_time;
 851         }
 852 }
 853
 854 vector crosshair_getcolor(entity this, float health_stat)
 855 {
 856         static float rainbow_last_flicker;
 857         static vector rainbow_prev_color;
 858         vector wcross_color = '0 0 0';
 859         switch(autocvar_crosshair_color_special)
 860         {
 861                 case 1: // crosshair_color_per_weapon
 862                 {
 863                         if(this != WEP_Null)
 864                         {
 865                                 wcross_color = this.wpcolor;
 866                                 break;
 867                         }
 868                         else { goto normalcolor; }
 869                 }
 870
 871                 case 2: // crosshair_color_by_health
 872                 {
 873                         float x = health_stat;
 874
 875                         //x = red
 876                         //y = green
 877                         //z = blue
 878
 879                         wcross_color.z = 0;
 880
 881                         if(x > 200)
 882                         {
 883                                 wcross_color.x = 0;
 884                                 wcross_color.y = 1;
 885                         }
 886                         else if(x > 150)
 887                         {
 888                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 889                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 890                         }
 891                         else if(x > 100)
 892                         {
 893                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 894                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 895                                 wcross_color.z = 1 - (x-100)*0.02;
 896                         }
 897                         else if(x > 50)
 898                         {
 899                                 wcross_color.x = 1;
 900                                 wcross_color.y = 1;
 901                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 902                         }
 903                         else if(x > 20)
 904                         {
 905                                 wcross_color.x = 1;
 906                                 wcross_color.y = (x-20)*90/27/100;
 907                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 908                         }
 909                         else
 910                         {
 911                                 wcross_color.x = 1;
 912                                 wcross_color.y = 0;
 913                         }
 914                         break;
 915                 }
 916
 917                 case 3: // crosshair_color_rainbow
 918                 {
 919                         if(time >= rainbow_last_flicker)
 920                         {
 921                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 922                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 923                         }
 924                         wcross_color = rainbow_prev_color;
 925                         break;
 926                 }
 927 LABEL(normalcolor)
 928                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 929         }
 930
 931         return wcross_color;
 932 }
 933
 934 void HUD_Crosshair(entity this)
 935 {
 936         float f, i, j;
 937         vector v;
 938         if(!scoreboard_active && !camera_active && intermission != 2 &&
 939                 spectatee_status != -1 && !csqcplayer.viewloc &&
 940                 !HUD_MinigameMenu_IsOpened() )
 941         {
 942                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 943                         return;
 944
 945                 if (hud != HUD_NORMAL)
 946                 {
 947                         HUD_Crosshair_Vehicle(this);
 948                         return;
 949                 }
 950
 951                 string wcross_style;
 952                 float wcross_alpha, wcross_resolution;
 953                 wcross_style = autocvar_crosshair;
 954                 if (wcross_style == "0")
 955                         return;
 956                 wcross_resolution = autocvar_crosshair_size;
 957                 if (wcross_resolution == 0)
 958                         return;
 959                 wcross_alpha = autocvar_crosshair_alpha;
 960                 if (wcross_alpha == 0)
 961                         return;
 962
 963                 // TrueAim check
 964                 float shottype;
 965
 966                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 967                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 968                 wcross_origin.z = 0;
 969                 if(autocvar_crosshair_hittest)
 970                 {
 971                         vector wcross_oldorigin;
 972                         wcross_oldorigin = wcross_origin;
 973                         shottype = TrueAimCheck();
 974                         if(shottype == SHOTTYPE_HITWORLD)
 975                         {
 976                                 v = wcross_origin - wcross_oldorigin;
 977                                 v.x /= vid_conwidth;
 978                                 v.y /= vid_conheight;
 979                                 if(vlen(v) > 0.01)
 980                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 981                         }
 982                         if(!autocvar_crosshair_hittest_showimpact)
 983                                 wcross_origin = wcross_oldorigin;
 984                 }
 985                 else
 986                         shottype = SHOTTYPE_HITWORLD;
 987
 988                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 989                 string wcross_name = "";
 990                 float wcross_scale, wcross_blur;
 991
 992         entity e = WEP_Null;
 993                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 994                 {
 995                         e = switchingweapon;
 996                         if(e)
 997                         {
 998                                 if(autocvar_crosshair_per_weapon)
 999                                 {
1000                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1001                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1002                                         //if (wcross_resolution == 0)
1003                                                 //return;
1004
1005                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1006                                         wcross_resolution *= e.w_crosshair_size;
1007                                         wcross_name = e.w_crosshair;
1008                                 }
1009                         }
1010                 }
1011
1012                 if(wcross_name == "")
1013                         wcross_name = strcat("gfx/crosshair", wcross_style);
1014
1015                 // MAIN CROSSHAIR COLOR DECISION
1016                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1017
1018                 if(autocvar_crosshair_effect_scalefade)
1019                 {
1020                         wcross_scale = wcross_resolution;
1021                         wcross_resolution = 1;
1022                 }
1023                 else
1024                 {
1025                         wcross_scale = 1;
1026                 }
1027
1028                 if(autocvar_crosshair_pickup)
1029                 {
1030                         float stat_pickup_time = STAT(LAST_PICKUP);
1031
1032                         if(pickup_crosshair_time < stat_pickup_time)
1033                         {
1034                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1035                                         pickup_crosshair_size = 1;
1036
1037                                 pickup_crosshair_time = stat_pickup_time;
1038                         }
1039
1040                         if(pickup_crosshair_size > 0)
1041                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1042                         else
1043                                 pickup_crosshair_size = 0;
1044
1045                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1046                 }
1047
1048                 // todo: make crosshair hit indication dependent on damage dealt
1049                 if(autocvar_crosshair_hitindication)
1050                 {
1051                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1052
1053                         if(unaccounted_damage)
1054                         {
1055                                 hitindication_crosshair_size = 1;
1056                         }
1057
1058                         if(hitindication_crosshair_size > 0)
1059                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1060                         else
1061                                 hitindication_crosshair_size = 0;
1062
1063                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1064                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1065                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1066                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1067                 }
1068
1069                 if(shottype == SHOTTYPE_HITENEMY)
1070                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1071                 if(shottype == SHOTTYPE_HITTEAM)
1072                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1073
1074                 f = fabs(autocvar_crosshair_effect_time);
1075                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1076                 {
1077                         wcross_changedonetime = time + f;
1078                 }
1079                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1080                 {
1081                         wcross_name_changestarttime = time;
1082                         wcross_name_changedonetime = time + f;
1083                         if(wcross_name_goal_prev_prev)
1084                                 strunzone(wcross_name_goal_prev_prev);
1085                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1086                         wcross_name_goal_prev = strzone(wcross_name);
1087                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1088                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1089                         wcross_resolution_goal_prev = wcross_resolution;
1090                 }
1091
1092                 wcross_scale_goal_prev = wcross_scale;
1093                 wcross_alpha_goal_prev = wcross_alpha;
1094                 wcross_color_goal_prev = wcross_color;
1095
1096                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1097                 {
1098                         wcross_blur = 1;
1099                         wcross_alpha *= 0.75;
1100                 }
1101                 else
1102                         wcross_blur = 0;
1103                 // *_prev is at time-frametime
1104                 // * is at wcross_changedonetime+f
1105                 // what do we have at time?
1106                 if(time < wcross_changedonetime)
1107                 {
1108                         f = frametime / (wcross_changedonetime - time + frametime);
1109                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1110                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1111                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1112                 }
1113
1114                 wcross_scale_prev = wcross_scale;
1115                 wcross_alpha_prev = wcross_alpha;
1116                 wcross_color_prev = wcross_color;
1117
1118                 MUTATOR_CALLHOOK(UpdateCrosshair);
1119
1120                 wcross_scale *= 1 - autocvar__menu_alpha;
1121                 wcross_alpha *= 1 - autocvar__menu_alpha;
1122                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1123
1124                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1125                 {
1126                         // crosshair rings for weapon stats
1127                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1128                         {
1129                                 // declarations and stats
1130                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1131                                 string ring_image = string_null, ring_inner_image = string_null;
1132                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1133
1134                                 ring_scale = autocvar_crosshair_ring_size;
1135
1136                                 float weapon_clipload, weapon_clipsize;
1137                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1138                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1139
1140                                 float ok_ammo_charge, ok_ammo_chargepool;
1141                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1142                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1143
1144                                 float vortex_charge, vortex_chargepool;
1145                                 vortex_charge = STAT(VORTEX_CHARGE);
1146                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1147
1148                                 float arc_heat = STAT(ARC_HEAT);
1149
1150                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1151                                         vortex_charge_movingavg = vortex_charge;
1152
1153
1154                                 // handle the values
1155                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1156                                 {
1157                                         if (vortex_chargepool || use_vortex_chargepool) {
1158                                                 use_vortex_chargepool = 1;
1159                                                 ring_inner_value = vortex_chargepool;
1160                                         } else {
1161                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1162                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1163                                         }
1164
1165                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1166                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1167                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1168
1169                                         // draw the outer ring to show the current charge of the weapon
1170                                         ring_value = vortex_charge;
1171                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1172                                         ring_rgb = wcross_color;
1173                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1174                                 }
1175                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1176                                 {
1177                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1178                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1179                                         ring_rgb = wcross_color;
1180                                         ring_image = "gfx/crosshair_ring.tga";
1181                                 }
1182                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1183                                 {
1184                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1185                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1186                                         ring_rgb = wcross_color;
1187                                         ring_image = "gfx/crosshair_ring.tga";
1188                                 }
1189                                 else if (ok_ammo_charge)
1190                                 {
1191                                         ring_value = ok_ammo_chargepool;
1192                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1193                                         ring_rgb = wcross_color;
1194                                         ring_image = "gfx/crosshair_ring.tga";
1195                                 }
1196                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1197                                 {
1198                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1199                                         ring_scale = autocvar_crosshair_ring_reload_size;
1200                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1201                                         ring_rgb = wcross_color;
1202
1203                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1204                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1205                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1206                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1207                                         else
1208                                                 ring_image = "gfx/crosshair_ring.tga";
1209                                 }
1210                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1211                                 {
1212                                         ring_value = arc_heat;
1213                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1214                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1215                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1216                                         ring_image = "gfx/crosshair_ring.tga";
1217                                 }
1218
1219                                 // if in weapon switch animation, fade ring out/in
1220                                 if(autocvar_crosshair_effect_time > 0)
1221                                 {
1222                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1223                                         if (f >= 1)
1224                                         {
1225                                                 wcross_ring_prev = ((ring_image) ? true : false);
1226                                         }
1227
1228                                         if(wcross_ring_prev)
1229                                         {
1230                                                 if(f < 1)
1231                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1232                                         }
1233                                         else
1234                                         {
1235                                                 if(f < 1)
1236                                                         ring_alpha *= bound(0, f, 1);
1237                                         }
1238                                 }
1239
1240                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1241                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1242
1243                                 if (ring_value)
1244                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1245                         }
1246
1247 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1248                         MACRO_BEGIN { \
1249                                 if(wcross_blur > 0) \
1250                                 { \
1251                                         for(i = -2; i <= 2; ++i) \
1252                                         for(j = -2; j <= 2; ++j) \
1253                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1254                                 } \
1255                                 else \
1256                                 { \
1257                                         M(0,0,sz,wcross_name,wcross_alpha); \
1258                                 } \
1259                         } MACRO_END
1260
1261 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1262                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1263
1264 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1265                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1266
1267                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1268                         {
1269                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1270                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1271                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1272                                 f = 1 - f;
1273                         }
1274                         else
1275                         {
1276                                 f = 1;
1277                         }
1278                         wcross_name_alpha_goal_prev = f;
1279
1280                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1281                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1282
1283                         if(autocvar_crosshair_dot)
1284                         {
1285                                 vector wcross_color_old;
1286                                 wcross_color_old = wcross_color;
1287
1288                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1289                                         wcross_color = stov(autocvar_crosshair_dot_color);
1290
1291                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1292                                 // FIXME why don't we use wcross_alpha here?
1293                                 wcross_color = wcross_color_old;
1294                         }
1295                 }
1296         }
1297         else
1298         {
1299                 wcross_scale_prev = 0;
1300                 wcross_alpha_prev = 0;
1301                 wcross_scale_goal_prev = 0;
1302                 wcross_alpha_goal_prev = 0;
1303                 wcross_changedonetime = 0;
1304                 if(wcross_name_goal_prev)
1305                         strunzone(wcross_name_goal_prev);
1306                 wcross_name_goal_prev = string_null;
1307                 if(wcross_name_goal_prev_prev)
1308                         strunzone(wcross_name_goal_prev_prev);
1309                 wcross_name_goal_prev_prev = string_null;
1310                 wcross_name_changestarttime = 0;
1311                 wcross_name_changedonetime = 0;
1312                 wcross_name_alpha_goal_prev = 0;
1313                 wcross_name_alpha_goal_prev_prev = 0;
1314                 wcross_resolution_goal_prev = 0;
1315                 wcross_resolution_goal_prev_prev = 0;
1316         }
1317 }
1318
1319 void HUD_Draw(entity this)
1320 {
1321         if(!intermission)
1322         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1323         {
1324                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1325         }
1326         else if(STAT(FROZEN))
1327         {
1328                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1329         }
1330         if(!intermission)
1331         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1332         {
1333                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1334                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1335         }
1336         else if(STAT(REVIVE_PROGRESS))
1337         {
1338                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1339                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1340         }
1341
1342         if(autocvar_r_letterbox == 0)
1343                 if(autocvar_viewsize < 120)
1344                 {
1345                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1346                                 Accuracy_LoadLevels();
1347
1348                         HUD_Main();
1349                         HUD_DrawScoreboard();
1350                         HUD_Scale_Disable();
1351                 }
1352
1353         // crosshair goes VERY LAST
1354         UpdateDamage();
1355         HUD_Crosshair(this);
1356         HitSound();
1357 }
1358
1359 bool ov_enabled;
1360 float oldr_nearclip;
1361 float oldr_farclip_base;
1362 float oldr_farclip_world;
1363 float oldr_novis;
1364 float oldr_useportalculling;
1365 float oldr_useinfinitefarclip;
1366
1367 void cl_notice_run();
1368 float prev_myteam;
1369 int lasthud;
1370 float vh_notice_time;
1371 void WaypointSprite_Load();
1372 void CSQC_UpdateView(float w, float h)
1373 {ENGINE_EVENT();
1374     TC(int, w); TC(int, h);
1375         entity e;
1376         float fov;
1377         float f;
1378         vector vf_size, vf_min;
1379         float a;
1380
1381         execute_next_frame();
1382
1383         ++framecount;
1384
1385         stats_get();
1386         hud = STAT(HUD);
1387
1388         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1389                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1390
1391         lasthud = hud;
1392
1393         HUD_Scale_Disable();
1394
1395         if(autocvar__hud_showbinds_reload) // menu can set this one
1396         {
1397                 db_close(binddb);
1398                 binddb = db_create();
1399                 cvar_set("_hud_showbinds_reload", "0");
1400         }
1401
1402         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1403                 view_quality = getproperty(VF_MINFPS_QUALITY);
1404         else
1405                 view_quality = 1;
1406
1407         // this needs to be updated manually now due to the destruction of engine physics stats
1408         if(!isdemo() && autocvar_slowmo != STAT(MOVEVARS_TIMESCALE))
1409                 cvar_set("slowmo", ftos(STAT(MOVEVARS_TIMESCALE)));
1410
1411         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1412         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1413
1414         vf_size = getpropertyvec(VF_SIZE);
1415         vf_min = getpropertyvec(VF_MIN);
1416         vid_width = vf_size.x;
1417         vid_height = vf_size.y;
1418
1419         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1420         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1421
1422         WaypointSprite_Load();
1423
1424         CSQCPlayer_SetCamera();
1425
1426         if(player_localentnum <= maxclients) // is it a client?
1427                 current_player = player_localentnum - 1;
1428         else // then player_localentnum is the vehicle I'm driving
1429                 current_player = player_localnum;
1430         myteam = entcs_GetTeam(current_player);
1431
1432         if(myteam != prev_myteam)
1433         {
1434                 myteamcolors = colormapPaletteColor(myteam, 1);
1435                 FOREACH(hud_panels, true, it.update_time = time);
1436                 prev_myteam = myteam;
1437         }
1438
1439         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1440
1441         float is_dead = (STAT(HEALTH) <= 0);
1442
1443         // FIXME do we need this hack?
1444         if(isdemo())
1445         {
1446                 // in demos, input_buttons do not work
1447                 button_zoom = (autocvar__togglezoom == "-");
1448         }
1449         else if(button_zoom
1450                 && autocvar_cl_unpress_zoom_on_death
1451                 && (spectatee_status >= 0)
1452                 && (is_dead || intermission))
1453         {
1454                 // no zoom while dead or in intermission please
1455                 localcmd("-zoom\n");
1456                 button_zoom = false;
1457         }
1458
1459         // event chase camera
1460         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1461         {
1462                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1463                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1464                 entity gen = NULL;
1465
1466                 float vehicle_viewdist = 0;
1467                 vector vehicle_viewofs = '0 0 0';
1468
1469                 if(vehicle_chase)
1470                 {
1471                         if(hud != HUD_BUMBLEBEE_GUN)
1472                         {
1473                                 Vehicle info = Vehicles_from(hud);
1474                                 vehicle_viewdist = info.height;
1475                                 vehicle_viewofs = info.view_ofs;
1476                         }
1477                 }
1478
1479                 if(ons_roundlost)
1480                 {
1481                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1482                                 gen = it;
1483                                 break;
1484                         });
1485                         if(!gen)
1486                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1487                 }
1488                 if(WantEventchase(this) || (!autocvar_cl_orthoview && ons_roundlost))
1489                 {
1490                         eventchase_running = true;
1491
1492                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1493                         if(!local_player)
1494                                 local_player = this; // fall back!
1495
1496                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1497                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1498                         if(ons_roundlost) { current_view_origin = gen.origin; }
1499
1500                         // detect maximum viewoffset and use it
1501                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1502                         if(vehicle_chase)
1503                         {
1504                                 if(vehicle_viewofs)
1505                                         view_offset = vehicle_viewofs;
1506                                 else
1507                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1508                         }
1509                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1510
1511                         if(view_offset)
1512                         {
1513                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1514                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1515                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1516                         }
1517
1518                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1519                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1520                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1521                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1522
1523                         // make the camera smooth back
1524                         float chase_distance = autocvar_cl_eventchase_distance;
1525                         if(vehicle_chase)
1526                         {
1527                                 if(vehicle_viewofs)
1528                                         chase_distance = vehicle_viewdist;
1529                                 else
1530                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1531                         }
1532                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1533
1534                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1535                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1536                         else if(eventchase_current_distance != chase_distance)
1537                                 eventchase_current_distance = chase_distance;
1538
1539                         makevectors(view_angles);
1540
1541                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1542                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1543
1544                         // If the boxtrace fails, revert back to line tracing.
1545                         if(!local_player.viewloc)
1546                         if(trace_startsolid)
1547                         {
1548                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1549                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1550                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1551                         }
1552                         else { setproperty(VF_ORIGIN, trace_endpos); }
1553
1554                         if(!local_player.viewloc)
1555                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1556                 }
1557                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1558                 {
1559                         eventchase_running = false;
1560                         cvar_set("chase_active", "0");
1561                         eventchase_current_distance = 0; // start from 0 next time
1562                 }
1563         }
1564         // workaround for camera stuck between player's legs when using chase_active 1
1565         // because the engine stops updating the chase_active camera when the game ends
1566         else if(intermission)
1567         {
1568                 cvar_settemp("chase_active", "-1");
1569                 eventchase_current_distance = 0;
1570         }
1571
1572         // do lockview after event chase camera so that it still applies whenever necessary.
1573         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1574         {
1575                 setproperty(VF_ORIGIN, freeze_org);
1576                 setproperty(VF_ANGLES, freeze_ang);
1577         }
1578         else
1579         {
1580                 freeze_org = getpropertyvec(VF_ORIGIN);
1581                 freeze_ang = getpropertyvec(VF_ANGLES);
1582         }
1583
1584         WarpZone_FixView();
1585         //WarpZone_FixPMove();
1586
1587         vector ov_org = '0 0 0';
1588         vector ov_mid = '0 0 0';
1589         vector ov_worldmin = '0 0 0';
1590         vector ov_worldmax = '0 0 0';
1591         if(autocvar_cl_orthoview)
1592         {
1593                 ov_worldmin = mi_picmin;
1594                 ov_worldmax = mi_picmax;
1595
1596                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1597                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1598                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1599
1600                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1601                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1602
1603                 float ov_nearest = vlen(ov_org - vec3(
1604                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1605                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1606                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1607                 ));
1608
1609                 float ov_furthest = 0;
1610                 float dist = 0;
1611
1612                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1613                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1614                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1615                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1616                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1617                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1618                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1619                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1620
1621                 if(!ov_enabled)
1622                 {
1623                         oldr_nearclip = cvar("r_nearclip");
1624                         oldr_farclip_base = cvar("r_farclip_base");
1625                         oldr_farclip_world = cvar("r_farclip_world");
1626                         oldr_novis = cvar("r_novis");
1627                         oldr_useportalculling = cvar("r_useportalculling");
1628                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1629                 }
1630
1631                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1632                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1633                 cvar_settemp("r_farclip_world", "0");
1634                 cvar_settemp("r_novis", "1");
1635                 cvar_settemp("r_useportalculling", "0");
1636                 cvar_settemp("r_useinfinitefarclip", "0");
1637
1638                 setproperty(VF_ORIGIN, ov_org);
1639                 setproperty(VF_ANGLES, '90 0 0');
1640
1641                 ov_enabled = true;
1642
1643                 #if 0
1644                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1645                         vtos(ov_org),
1646                         vtos(getpropertyvec(VF_ANGLES)),
1647                         ov_distance,
1648                         ov_nearest,
1649                         ov_furthest);
1650                 #endif
1651         }
1652         else
1653         {
1654                 if(ov_enabled)
1655                 {
1656                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1657                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1658                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1659                         cvar_set("r_novis", ftos(oldr_novis));
1660                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1661                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1662                 }
1663                 ov_enabled = false;
1664         }
1665
1666         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1667         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1668         viewmodel_draw(viewmodel);
1669
1670         // Render the Scene
1671         view_origin = getpropertyvec(VF_ORIGIN);
1672         view_angles = getpropertyvec(VF_ANGLES);
1673         makevectors(view_angles);
1674         view_forward = v_forward;
1675         view_right = v_right;
1676         view_up = v_up;
1677
1678 #ifdef BLURTEST
1679         if(time > blurtest_time0 && time < blurtest_time1)
1680         {
1681                 float r, t;
1682
1683                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1684                 r = t * blurtest_radius;
1685                 f = 1 / pow(t, blurtest_power) - 1;
1686
1687                 cvar_set("r_glsl_postprocess", "1");
1688                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1689         }
1690         else
1691         {
1692                 cvar_set("r_glsl_postprocess", "0");
1693                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1694         }
1695 #endif
1696
1697         TargetMusic_Advance();
1698         Fog_Force();
1699
1700         if(drawtime == 0)
1701                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1702         else
1703                 drawframetime = bound(0.000001, time - drawtime, 1);
1704         drawtime = time;
1705
1706         // watch for gametype changes here...
1707         // in ParseStuffCMD the cmd isn't executed yet :/
1708         // might even be better to add the gametype to TE_CSQC_INIT...?
1709         if(!postinit)
1710                 PostInit();
1711
1712         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1713         {
1714                 if(calledhooks & HOOK_START)
1715                 {
1716                         localcmd("\ncl_hook_gameend\n");
1717                         calledhooks |= HOOK_END;
1718                 }
1719         }
1720
1721         Announcer();
1722
1723         fov = autocvar_fov;
1724         if(fov <= 59.5)
1725         {
1726                 if(!zoomscript_caught)
1727                 {
1728                         localcmd("+button9\n");
1729                         zoomscript_caught = 1;
1730                 }
1731         }
1732         else
1733         {
1734                 if(zoomscript_caught)
1735                 {
1736                         localcmd("-button9\n");
1737                         zoomscript_caught = 0;
1738                 }
1739         }
1740
1741         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1742
1743         // currently switching-to weapon (for crosshair)
1744         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1745
1746         // actually active weapon (for zoom)
1747         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1748
1749         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1750
1751         f = (serverflags & SERVERFLAG_TEAMPLAY);
1752         if(f != teamplay)
1753         {
1754                 teamplay = f;
1755                 HUD_InitScores();
1756         }
1757
1758         if(last_switchweapon != switchweapon)
1759         {
1760                 weapontime = time;
1761                 last_switchweapon = switchweapon;
1762                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1763                 {
1764                         localcmd("-zoom\n");
1765                         button_zoom = false;
1766                 }
1767                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1768                 {
1769                         localcmd("-fire\n");
1770                         localcmd("-fire2\n");
1771                         button_attack2 = false;
1772                 }
1773         }
1774         if(last_activeweapon != activeweapon)
1775         {
1776                 last_activeweapon = activeweapon;
1777
1778                 e = activeweapon;
1779                 if(e.netname != "")
1780                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1781                 else
1782                         localcmd("\ncl_hook_activeweapon none\n");
1783         }
1784
1785         // ALWAYS Clear Current Scene First
1786         clearscene();
1787
1788         setproperty(VF_ORIGIN, view_origin);
1789         setproperty(VF_ANGLES, view_angles);
1790
1791         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1792         setproperty(VF_SIZE, vf_size);
1793         setproperty(VF_MIN, vf_min);
1794
1795         // Assign Standard Viewflags
1796         // Draw the World (and sky)
1797         setproperty(VF_DRAWWORLD, 1);
1798
1799         // Set the console size vars
1800         vid_conwidth = autocvar_vid_conwidth;
1801         vid_conheight = autocvar_vid_conheight;
1802         vid_pixelheight = autocvar_vid_pixelheight;
1803
1804         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1805         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1806         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1807
1808         // Camera for demo playback
1809         if(camera_active)
1810         {
1811                 if(autocvar_camera_enable)
1812                         CSQC_Demo_Camera();
1813                 else
1814                 {
1815                         cvar_set("chase_active", ftos(chase_active_backup));
1816                         cvar_set("cl_demo_mousegrab", "0");
1817                         camera_active = false;
1818                 }
1819         }
1820         else
1821         {
1822 #ifdef CAMERATEST
1823                 if(autocvar_camera_enable)
1824 #else
1825                 if(autocvar_camera_enable && isdemo())
1826 #endif
1827                 {
1828                         // Enable required Darkplaces cvars
1829                         chase_active_backup = autocvar_chase_active;
1830                         cvar_set("chase_active", "2");
1831                         cvar_set("cl_demo_mousegrab", "1");
1832                         camera_active = true;
1833                         camera_mode = false;
1834                 }
1835         }
1836
1837         // Draw the Crosshair
1838         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1839
1840         // Draw the Engine Status Bar (the default Quake HUD)
1841         setproperty(VF_DRAWENGINESBAR, 0);
1842
1843         // Update the mouse position
1844         /*
1845            mousepos_x = vid_conwidth;
1846            mousepos_y = vid_conheight;
1847            mousepos = mousepos*0.5 + getmousepos();
1848          */
1849
1850         FOREACH_ENTITY(it.draw, it.draw(it));
1851
1852         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1853         renderscene();
1854
1855         // now switch to 2D drawing mode by calling a 2D drawing function
1856         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1857         // next R_RenderScene call
1858         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1859
1860         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1861         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1862         {
1863                 // apply night vision effect
1864                 vector tc_00, tc_01, tc_10, tc_11;
1865                 vector rgb = '0 0 0';
1866
1867                 if(!nightvision_noise)
1868                 {
1869                         nightvision_noise = new(nightvision_noise);
1870                 }
1871                 if(!nightvision_noise2)
1872                 {
1873                         nightvision_noise2 = new(nightvision_noise2);
1874                 }
1875
1876                 // color tint in yellow
1877                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1878
1879                 // draw BG
1880                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1881                 rgb = '1 1 1';
1882                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1883                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1884                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1885                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1886                 tc_11 = tc_01 + tc_10 - tc_00;
1887                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1888                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1889                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1890                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1891                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1892                 R_EndPolygon();
1893
1894                 // draw FG
1895                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1896                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1897                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1898                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1899                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1900                 tc_11 = tc_01 + tc_10 - tc_00;
1901                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1902                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1903                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1904                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1905                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1906                 R_EndPolygon();
1907         }
1908
1909         if(autocvar_cl_reticle)
1910         {
1911                 Weapon wep = activeweapon;
1912                 // Draw the aiming reticle for weapons that use it
1913                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1914                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1915                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1916                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1917                 {
1918                         // no zoom reticle while dead
1919                         reticle_type = 0;
1920                 }
1921                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1922                 {
1923                         if(reticle_image != "") { reticle_type = 2; }
1924                         else { reticle_type = 0; }
1925                 }
1926                 else if(button_zoom || zoomscript_caught)
1927                 {
1928                         // normal zoom
1929                         reticle_type = 1;
1930                 }
1931
1932                 if(reticle_type)
1933                 {
1934                         if(autocvar_cl_reticle_stretch)
1935                         {
1936                                 reticle_size.x = vid_conwidth;
1937                                 reticle_size.y = vid_conheight;
1938                                 reticle_pos.x = 0;
1939                                 reticle_pos.y = 0;
1940                         }
1941                         else
1942                         {
1943                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1944                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1945                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1946                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1947                         }
1948
1949                         if(zoomscript_caught)
1950                                 f = 1;
1951                         else
1952                                 f = current_zoomfraction;
1953
1954                         if(f)
1955                         {
1956                                 switch(reticle_type)
1957                                 {
1958                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1959                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1960                                 }
1961                         }
1962                 }
1963         }
1964         else
1965         {
1966                 if(reticle_type != 0) { reticle_type = 0; }
1967         }
1968
1969
1970         // improved polyblend
1971         if(autocvar_hud_contents)
1972         {
1973                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1974                 vector liquidcolor;
1975
1976                 switch(pointcontents(view_origin))
1977                 {
1978                         case CONTENT_WATER:
1979                                 liquidalpha = autocvar_hud_contents_water_alpha;
1980                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1981                                 incontent = 1;
1982                                 break;
1983
1984                         case CONTENT_LAVA:
1985                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1986                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1987                                 incontent = 1;
1988                                 break;
1989
1990                         case CONTENT_SLIME:
1991                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1992                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1993                                 incontent = 1;
1994                                 break;
1995
1996                         default:
1997                                 liquidalpha = 0;
1998                                 liquidcolor = '0 0 0';
1999                                 incontent = 0;
2000                                 break;
2001                 }
2002
2003                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2004                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2005                         contentfadetime = autocvar_hud_contents_fadeintime;
2006                         liquidalpha_prev = liquidalpha;
2007                         liquidcolor_prev = liquidcolor;
2008                 }
2009                 else
2010                         contentfadetime = autocvar_hud_contents_fadeouttime;
2011
2012                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2013                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2014
2015                 if(contentavgalpha)
2016                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2017
2018                 if(autocvar_hud_postprocessing)
2019                 {
2020                         if(autocvar_hud_contents_blur && contentavgalpha)
2021                         {
2022                                 content_blurpostprocess.x = 1;
2023                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2024                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2025                         }
2026                         else
2027                         {
2028                                 content_blurpostprocess.x = 0;
2029                                 content_blurpostprocess.y = 0;
2030                                 content_blurpostprocess.z = 0;
2031                         }
2032                 }
2033         }
2034
2035         if(autocvar_hud_damage && !STAT(FROZEN))
2036         {
2037                 splash_size.x = max(vid_conwidth, vid_conheight);
2038                 splash_size.y = max(vid_conwidth, vid_conheight);
2039                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2040                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2041
2042                 float myhealth_flash_temp;
2043                 myhealth = STAT(HEALTH);
2044
2045                 // fade out
2046                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2047                 // add new damage
2048                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2049
2050                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2051                 pain_threshold = autocvar_hud_damage_pain_threshold;
2052                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2053                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2054
2055                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2056                 {
2057                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2058                 }
2059
2060                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2061
2062                 if(myhealth_prev < 1)
2063                 {
2064                         if(myhealth >= 1)
2065                         {
2066                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2067                                 myhealth_flash_temp = 0;
2068                         }
2069                         else
2070                         {
2071                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2072                         }
2073                 }
2074
2075                 if(spectatee_status == -1 || intermission)
2076                 {
2077                         myhealth_flash = 0; // observing, or match ended
2078                         myhealth_flash_temp = 0;
2079                 }
2080
2081                 myhealth_prev = myhealth;
2082
2083                 // IDEA: change damage color/picture based on player model for robot/alien species?
2084                 // pro: matches model better
2085                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2086                 // maybe different reddish pics?
2087                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2088                 {
2089                         if(autocvar_cl_gentle_damage == 2)
2090                         {
2091                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2092                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2093                         }
2094                         else
2095                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2096
2097                         if(myhealth_flash_temp > 0)
2098                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2099                 }
2100                 else if(myhealth_flash_temp > 0)
2101                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2102
2103                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2104                 {
2105                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2106                         {
2107                                 damage_blurpostprocess.x = 1;
2108                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2109                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2110                         }
2111                         else
2112                         {
2113                                 damage_blurpostprocess.x = 0;
2114                                 damage_blurpostprocess.y = 0;
2115                                 damage_blurpostprocess.z = 0;
2116                         }
2117                 }
2118         }
2119
2120         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2121         float e2 = (autocvar_hud_powerup != 0);
2122         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2123         {
2124                 // enable or disable rendering types if they are used or not
2125                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2126                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2127
2128                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2129                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2130                 {
2131                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2132                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2133                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2134                         {
2135                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2136                                 old_blurradius = blurradius;
2137                                 old_bluralpha = bluralpha;
2138                         }
2139                 }
2140                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2141                 {
2142                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2143                         old_blurradius = 0;
2144                         old_bluralpha = 0;
2145                 }
2146
2147                 // edge detection postprocess handling done second (used by hud_powerup)
2148                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2149                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2150                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2151
2152                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2153
2154                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2155                 {
2156                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2157                         {
2158                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2159                                 old_sharpen_intensity = sharpen_intensity;
2160                         }
2161                 }
2162                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2163                 {
2164                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2165                         old_sharpen_intensity = 0;
2166                 }
2167
2168                 if(cvar("r_glsl_postprocess") == 0)
2169                         cvar_set("r_glsl_postprocess", "2");
2170         }
2171         else if(cvar("r_glsl_postprocess") == 2)
2172                 cvar_set("r_glsl_postprocess", "0");
2173
2174         /*if(gametype == MAPINFO_TYPE_CTF)
2175           {
2176           ctf_view();
2177           } else */
2178
2179         // draw 2D entities
2180         FOREACH_ENTITY(it.draw2d, it.draw2d(it));
2181         Draw_ShowNames_All();
2182         Debug_Draw();
2183
2184         scoreboard_active = HUD_WouldDrawScoreboard();
2185
2186         HUD_Draw(this); // this parameter for deep vehicle function
2187
2188         if(NextFrameCommand)
2189         {
2190                 localcmd("\n", NextFrameCommand, "\n");
2191                 NextFrameCommand = string_null;
2192         }
2193
2194         // we must do this check AFTER a frame was rendered, or it won't work
2195         if(cs_project_is_b0rked == 0)
2196         {
2197                 string w0, h0;
2198                 w0 = ftos(autocvar_vid_conwidth);
2199                 h0 = ftos(autocvar_vid_conheight);
2200                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2201                 //setproperty(VF_FOV, '90 90 0');
2202                 setproperty(VF_ORIGIN, '0 0 0');
2203                 setproperty(VF_ANGLES, '0 0 0');
2204                 setproperty(VF_PERSPECTIVE, 1);
2205                 makevectors('0 0 0');
2206                 vector v1, v2;
2207                 cvar_set("vid_conwidth", "800");
2208                 cvar_set("vid_conheight", "600");
2209                 v1 = cs_project(v_forward);
2210                 cvar_set("vid_conwidth", "640");
2211                 cvar_set("vid_conheight", "480");
2212                 v2 = cs_project(v_forward);
2213                 if(v1 == v2)
2214                         cs_project_is_b0rked = 1;
2215                 else
2216                         cs_project_is_b0rked = -1;
2217                 cvar_set("vid_conwidth", w0);
2218                 cvar_set("vid_conheight", h0);
2219         }
2220
2221         if(autocvar__hud_configure)
2222                 HUD_Panel_Mouse();
2223         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2224                 HUD_Minigame_Mouse();
2225         else if(QuickMenu_IsOpened())
2226                 QuickMenu_Mouse();
2227         else
2228                 HUD_Radar_Mouse();
2229
2230         cl_notice_run();
2231         unpause_update();
2232         Net_Flush();
2233
2234         // let's reset the view back to normal for the end
2235         setproperty(VF_MIN, '0 0 0');
2236         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2237 }
2238
2239
2240 // following vectors must be global to allow seamless switching between camera modes
2241 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2242 void CSQC_Demo_Camera()
2243 {
2244         float speed, attenuation, dimensions;
2245         vector tmp, delta;
2246
2247         if( autocvar_camera_reset || !camera_mode )
2248         {
2249                 camera_offset = '0 0 0';
2250                 current_angles = '0 0 0';
2251                 camera_direction = '0 0 0';
2252                 camera_offset.z += 30;
2253                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2254                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2255                 current_origin = view_origin;
2256                 current_camera_offset  = camera_offset;
2257                 cvar_set("camera_reset", "0");
2258                 camera_mode = CAMERA_CHASE;
2259         }
2260
2261         // Camera angles
2262         if( camera_roll )
2263                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2264
2265         if(autocvar_camera_look_player)
2266         {
2267                 vector dir;
2268                 float n;
2269
2270                 dir = normalize(view_origin - current_position);
2271                 n = mouse_angles.z;
2272                 mouse_angles = vectoangles(dir);
2273                 mouse_angles.x = mouse_angles.x * -1;
2274                 mouse_angles.z = n;
2275         }
2276         else
2277         {
2278                 tmp = getmousepos() * 0.1;
2279                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2280                 {
2281                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2282                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2283                 }
2284         }
2285
2286         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2287         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2288         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2289         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2290
2291         // Fix difference when angles don't have the same sign
2292         delta = '0 0 0';
2293         if(mouse_angles.y < -60 && current_angles.y > 60)
2294                 delta = '0 360 0';
2295         if(mouse_angles.y > 60 && current_angles.y < -60)
2296                 delta = '0 -360 0';
2297
2298         if(autocvar_camera_look_player)
2299                 attenuation = autocvar_camera_look_attenuation;
2300         else
2301                 attenuation = autocvar_camera_speed_attenuation;
2302
2303         attenuation = 1 / max(1, attenuation);
2304         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2305
2306         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2307         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2308         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2309         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2310
2311         // Camera position
2312         tmp = '0 0 0';
2313         dimensions = 0;
2314
2315         if( camera_direction.x )
2316         {
2317                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2318                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2319                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2320                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2321                 ++dimensions;
2322         }
2323
2324         if( camera_direction.y )
2325         {
2326                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2327                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2328                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2329                 ++dimensions;
2330         }
2331
2332         if( camera_direction.z )
2333         {
2334                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2335                 ++dimensions;
2336         }
2337
2338         if(autocvar_camera_free)
2339                 speed = autocvar_camera_speed_free;
2340         else
2341                 speed = autocvar_camera_speed_chase;
2342
2343         if(dimensions)
2344         {
2345                 speed = speed * sqrt(1 / dimensions);
2346                 camera_offset += tmp * speed;
2347         }
2348
2349         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2350
2351         // Camera modes
2352         if( autocvar_camera_free )
2353         {
2354                 if ( camera_mode == CAMERA_CHASE )
2355                 {
2356                         current_camera_offset = current_origin + current_camera_offset;
2357                         camera_offset = current_origin + camera_offset;
2358                 }
2359
2360                 camera_mode = CAMERA_FREE;
2361                 current_position = current_camera_offset;
2362         }
2363         else
2364         {
2365                 if ( camera_mode == CAMERA_FREE )
2366                 {
2367                         current_origin = view_origin;
2368                         camera_offset = camera_offset - current_origin;
2369                         current_camera_offset = current_camera_offset - current_origin;
2370                 }
2371
2372                 camera_mode = CAMERA_CHASE;
2373
2374                 if(autocvar_camera_chase_smoothly)
2375                         current_origin += (view_origin - current_origin) * attenuation;
2376                 else
2377                         current_origin = view_origin;
2378
2379                 current_position = current_origin + current_camera_offset;
2380         }
2381
2382         setproperty(VF_ANGLES, current_angles);
2383         setproperty(VF_ORIGIN, current_position);
2384 }