qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 1000;
  44 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47
  48 float autocvar_cl_leanmodel;
  49 float autocvar_cl_leanmodel_speed = 0.3;
  50 float autocvar_cl_leanmodel_limit = 1000;
  51 float autocvar_cl_leanmodel_highpass1 = 0.2;
  52 float autocvar_cl_leanmodel_highpass = 0.2;
  53 float autocvar_cl_leanmodel_lowpass = 0.05;
  54
  55 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  56 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  57 { \
  58         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  59 } MACRO_END
  60
  61 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  62 { \
  63         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  64         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  65 } MACRO_END
  66
  67 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __f = 0; lowpass(value, frac, ref_store, __f); \
  70         ret = (value) - __f; \
  71 } MACRO_END
  72
  73 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  80 { \
  81         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  82         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  83 } MACRO_END
  84
  85 #define lowpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  88         lowpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 #define highpass3_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 118 { \
 119         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 120         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 121         highpass_limited(value.z, frac, limit, ref_store.z, ref_out.z); \
 122 } MACRO_END
 123
 124 #define lowpass3_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 125 { \
 126         lowpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 127         lowpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 128         lowpass_limited(value.z, frac, limit, ref_store.z, ref_out.z); \
 129 } MACRO_END
 130
 131 bool autocvar_cl_followmodel_velocity_absolute;
 132 void viewmodel_animate(entity this)
 133 {
 134         static float prevtime;
 135         float frametime = (time - prevtime);
 136         prevtime = time;
 137
 138         if (autocvar_chase_active) return;
 139         if (STAT(HEALTH) <= 0) return;
 140
 141         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 142
 143         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 144         static bool oldonground;
 145         static float hitgroundtime;
 146         static float lastongroundtime;
 147         if (clonground)
 148         {
 149                 float f = time; // cl.movecmd[0].time
 150                 if (!oldonground)
 151                         hitgroundtime = f;
 152                 lastongroundtime = f;
 153         }
 154         oldonground = clonground;
 155
 156
 157         bool teleported = view.csqcmodel_teleported;
 158
 159         float frac;
 160         if(autocvar_cl_followmodel)
 161         {
 162                 vector gunorg = '0 0 0';
 163                 static vector vel_average;
 164                 static vector gunorg_prev = '0 0 0';
 165                 static vector gunorg_adjustment_highpass;
 166                 static vector gunorg_adjustment_lowpass;
 167
 168                 vector vel;
 169                 if(autocvar_cl_followmodel_velocity_absolute)
 170                         vel = view.velocity;
 171                 else
 172                 {
 173                         vector forward, right = '0 0 0', up = '0 0 0';
 174                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 175                         vel.x = view.velocity * forward;
 176                         vel.y = view.velocity * right * -1;
 177                         vel.z = view.velocity * up;
 178                 }
 179
 180                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 181                 lowpass3_limited(vel, frac, autocvar_cl_followmodel_limit, vel_average, gunorg);
 182
 183                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 184
 185                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 186                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 187                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 188                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 189                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 190                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 191
 192                 if(autocvar_cl_followmodel_velocity_absolute)
 193                 {
 194                         vector fixed_gunorg;
 195                         vector forward, right = '0 0 0', up = '0 0 0';
 196                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 197                         fixed_gunorg.x = gunorg * forward;
 198                         fixed_gunorg.y = gunorg * right * -1;
 199                         fixed_gunorg.z = gunorg * up;
 200                         gunorg = fixed_gunorg;
 201                 }
 202
 203                 this.origin += gunorg;
 204         }
 205
 206         if(autocvar_cl_leanmodel)
 207         {
 208                 vector gunangles = '0 0 0';
 209                 static vector gunangles_prev = '0 0 0';
 210                 static vector gunangles_highpass = '0 0 0';
 211                 static vector gunangles_adjustment_highpass;
 212                 static vector gunangles_adjustment_lowpass;
 213
 214                 if (teleported)
 215                         gunangles_prev = view_angles;
 216
 217                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 218                 gunangles_highpass += gunangles_prev;
 219                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 220                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 221                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 222                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 223                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 224                 gunangles_prev = view_angles;
 225                 gunangles_highpass -= gunangles_prev;
 226
 227                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 228                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 229
 230                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 231                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 232                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 233                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 234                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 235
 236                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 237                 this.angles += gunangles;
 238         }
 239
 240         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 241
 242         // vertical view bobbing code
 243         // TODO: cl_bob
 244
 245         // horizontal view bobbing code
 246         // TODO: cl_bob2
 247
 248         // fall bobbing code
 249         // causes the view to swing down and back up when touching the ground
 250         // TODO: cl_bobfall
 251
 252         // gun model bobbing code
 253         if (autocvar_cl_bobmodel)
 254         {
 255                 // calculate for swinging gun model
 256                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 257                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 258                 // for the most part, but for some reason when you go through a message trigger or
 259                 // pick up an item or anything like that it will momentarily jolt the gun.
 260                 float bspeed;
 261                 float t = 1;
 262                 float s = time * autocvar_cl_bobmodel_speed;
 263                 if (clonground)
 264                 {
 265                         if (time - hitgroundtime < 0.2)
 266                         {
 267                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 268                                 t = time - hitgroundtime;
 269                                 t = bound(0, t, 0.2);
 270                                 t *= 5;
 271                         }
 272                 }
 273                 else
 274                 {
 275                         // recently left the ground, slow the bob down over the next 0.2 seconds
 276                         t = time - lastongroundtime;
 277                         t = 0.2 - bound(0, t, 0.2);
 278                         t *= 5;
 279                 }
 280                 bspeed = xyspeed * 0.01;
 281                 vector gunorg = '0 0 0';
 282                 gunorg.y += bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 283                 gunorg.z += bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 284
 285                 this.origin += gunorg;
 286         }
 287 }
 288
 289 .vector viewmodel_origin, viewmodel_angles;
 290 .float weapon_nextthink;
 291 .float weapon_eta_last;
 292 .float weapon_switchdelay;
 293
 294 void viewmodel_draw(entity this)
 295 {
 296         if(!activeweapon)
 297                 return;
 298         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 299         float a = this.alpha;
 300         static bool wasinvehicle;
 301         bool invehicle = player_localentnum > maxclients;
 302         if (invehicle) a = -1;
 303         else if (wasinvehicle) a = 1;
 304         wasinvehicle = invehicle;
 305         Weapon wep = activeweapon;
 306         int c = stof(getplayerkeyvalue(current_player, "colors"));
 307         vector g = weaponentity_glowmod(wep, c);
 308         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 309         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 310                 | EF_NODEPTHTEST)
 311                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 312         for (entity e = this; e; e = e.weaponchild)
 313         {
 314                 e.drawmask = mask;
 315                 e.alpha = a;
 316                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 317                 e.glowmod = g;
 318                 e.csqcmodel_effects = fx;
 319                 CSQCModel_Effects_Apply(e);
 320         }
 321         {
 322                 static string name_last;
 323                 string name = wep.mdl;
 324                 if (name != name_last)
 325                 {
 326                         name_last = name;
 327                         CL_WeaponEntity_SetModel(this, name);
 328                         this.viewmodel_origin = this.origin;
 329                         this.viewmodel_angles = this.angles;
 330                 }
 331                 anim_update(this);
 332                 if (!this.animstate_override && !this.animstate_looping)
 333                         anim_set(this, this.anim_idle, true, false, false);
 334         }
 335         float f = 0; // 0..1; 0: fully active
 336         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 337         if (eta <= 0) f = this.weapon_eta_last;
 338         else switch (this.state)
 339         {
 340                 case WS_RAISE:
 341                 {
 342                         f = eta / max(eta, this.weapon_switchdelay);
 343                         break;
 344                 }
 345                 case WS_DROP:
 346                 {
 347                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 348                         break;
 349                 }
 350                 case WS_CLEAR:
 351                 {
 352                         f = 1;
 353                         break;
 354                 }
 355         }
 356         this.weapon_eta_last = f;
 357         this.origin = this.viewmodel_origin;
 358         this.angles = this.viewmodel_angles;
 359         this.angles_x = (-90 * f * f);
 360         viewmodel_animate(this);
 361         setorigin(this, this.origin);
 362 }
 363
 364 entity viewmodel;
 365 STATIC_INIT(viewmodel) {
 366     viewmodel = new(viewmodel);
 367     make_pure(viewmodel);
 368 }
 369
 370 entity porto;
 371 vector polyline[16];
 372 void Porto_Draw(entity this)
 373 {
 374         vector p, dir, ang, q, nextdir;
 375         float portal_number, portal1_idx;
 376
 377         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 378                 return;
 379         if(WEP_CVAR(porto, secondary))
 380                 return;
 381         if(intermission == 1)
 382                 return;
 383         if(intermission == 2)
 384                 return;
 385         if (STAT(HEALTH) <= 0)
 386                 return;
 387
 388         dir = view_forward;
 389
 390         if(angles_held_status)
 391         {
 392                 makevectors(angles_held);
 393                 dir = v_forward;
 394         }
 395
 396         p = view_origin;
 397
 398         polyline[0] = p;
 399         int idx = 1;
 400         portal_number = 0;
 401         nextdir = dir;
 402
 403         for (;;)
 404         {
 405                 dir = nextdir;
 406                 traceline(p, p + 65536 * dir, true, porto);
 407                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 408                         return;
 409                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 410                 p = trace_endpos;
 411                 polyline[idx] = p;
 412                 ++idx;
 413                 if(idx >= 16)
 414                         return;
 415                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 416                         continue;
 417                 ++portal_number;
 418                 ang = vectoangles2(trace_plane_normal, dir);
 419                 ang.x = -ang.x;
 420                 makevectors(ang);
 421                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 422                         return;
 423                 if(portal_number == 1)
 424                 {
 425                         portal1_idx = idx;
 426                         if(portal_number >= 2)
 427                                 break;
 428                 }
 429         }
 430
 431         while(idx >= 2)
 432         {
 433                 p = polyline[idx-2];
 434                 q = polyline[idx-1];
 435                 if(idx == 2)
 436                         p = p - view_up * 16;
 437                 if(idx-1 >= portal1_idx)
 438                 {
 439                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 440                 }
 441                 else
 442                 {
 443                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 444                 }
 445                 --idx;
 446         }
 447 }
 448
 449 void Porto_Init()
 450 {
 451         porto = new(porto);
 452         make_pure(porto);
 453         porto.draw = Porto_Draw;
 454         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 455 }
 456
 457 float drawtime;
 458 float avgspeed;
 459 vector GetCurrentFov(float fov)
 460 {
 461         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 462         float velocityzoom, curspeed;
 463         vector v;
 464
 465         zoomsensitivity = autocvar_cl_zoomsensitivity;
 466         zoomfactor = autocvar_cl_zoomfactor;
 467         if(zoomfactor < 1 || zoomfactor > 30)
 468                 zoomfactor = 2.5;
 469         zoomspeed = autocvar_cl_zoomspeed;
 470         if(zoomspeed >= 0)
 471         if(zoomspeed < 0.5 || zoomspeed > 16)
 472                         zoomspeed = 3.5;
 473
 474         zoomdir = button_zoom;
 475         if(hud == HUD_NORMAL)
 476         if(switchweapon == activeweapon)
 477         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 478                 zoomdir += button_attack2;
 479         if(spectatee_status > 0 || isdemo())
 480         {
 481                 if(spectatorbutton_zoom)
 482                 {
 483                         if(zoomdir)
 484                                 zoomdir = 0;
 485                         else
 486                                 zoomdir = 1;
 487                 }
 488                 // fteqcc failed twice here already, don't optimize this
 489         }
 490
 491         if(zoomdir) { zoomin_effect = 0; }
 492
 493         if(camera_active)
 494         {
 495                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 496         }
 497         else if(autocvar_cl_spawnzoom && zoomin_effect)
 498         {
 499                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 500
 501                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 502                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 503                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 504         }
 505         else
 506         {
 507                 if(zoomspeed < 0) // instant zoom
 508                 {
 509                         if(zoomdir)
 510                                 current_viewzoom = 1 / zoomfactor;
 511                         else
 512                                 current_viewzoom = 1;
 513                 }
 514                 else
 515                 {
 516                         if(zoomdir)
 517                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 518                         else
 519                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 520                 }
 521         }
 522
 523         if(almost_equals(current_viewzoom, 1))
 524                 current_zoomfraction = 0;
 525         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 526                 current_zoomfraction = 1;
 527         else
 528                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 529
 530         if(zoomsensitivity < 1)
 531                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 532         else
 533                 setsensitivityscale(1);
 534
 535         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 536         {
 537                 if(intermission) { curspeed = 0; }
 538                 else
 539                 {
 540
 541                         makevectors(view_angles);
 542                         v = pmove_vel;
 543                         if(csqcplayer)
 544                                 v = csqcplayer.velocity;
 545
 546                         switch(autocvar_cl_velocityzoom_type)
 547                         {
 548                                 case 3: curspeed = max(0, v_forward * v); break;
 549                                 case 2: curspeed = (v_forward * v); break;
 550                                 case 1: default: curspeed = vlen(v); break;
 551                         }
 552                 }
 553
 554                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 555                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 556                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 557
 558                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 559         }
 560         else
 561                 velocityzoom = 1;
 562
 563         float frustumx, frustumy, fovx, fovy;
 564         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 565         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 566         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 567         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 568
 569         return '1 0 0' * fovx + '0 1 0' * fovy;
 570 }
 571
 572 vector GetViewLocationFOV(float fov)
 573 {
 574         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 575         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 576         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 577         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 578         return '1 0 0' * fovx + '0 1 0' * fovy;
 579 }
 580
 581 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 582 {
 583         float fovx, fovy;
 584         float width = (ov_worldmax.x - ov_worldmin.x);
 585         float height = (ov_worldmax.y - ov_worldmin.y);
 586         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 587         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 588         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 589         return '1 0 0' * fovx + '0 1 0' * fovy;
 590 }
 591
 592 // this function must match W_SetupShot!
 593 float zoomscript_caught;
 594
 595 vector wcross_origin;
 596 float wcross_scale_prev, wcross_alpha_prev;
 597 vector wcross_color_prev;
 598 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 599 vector wcross_color_goal_prev;
 600 float wcross_changedonetime;
 601
 602 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 603 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 604 float wcross_name_changestarttime, wcross_name_changedonetime;
 605 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 606
 607 float wcross_ring_prev;
 608
 609 entity trueaim;
 610 entity trueaim_rifle;
 611
 612 const float SHOTTYPE_HITTEAM = 1;
 613 const float SHOTTYPE_HITOBSTRUCTION = 2;
 614 const float SHOTTYPE_HITWORLD = 3;
 615 const float SHOTTYPE_HITENEMY = 4;
 616
 617 void TrueAim_Init()
 618 {
 619         trueaim = new(trueaim);
 620         make_pure(trueaim);
 621         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 622         trueaim_rifle = new(trueaim_rifle);
 623         make_pure(trueaim_rifle);
 624         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 625 }
 626
 627 float EnemyHitCheck()
 628 {
 629         float t, n;
 630         wcross_origin = project_3d_to_2d(trace_endpos);
 631         wcross_origin.z = 0;
 632         if(trace_ent)
 633                 n = trace_ent.entnum;
 634         else
 635                 n = trace_networkentity;
 636         if(n < 1)
 637                 return SHOTTYPE_HITWORLD;
 638         if(n > maxclients)
 639                 return SHOTTYPE_HITWORLD;
 640         t = entcs_GetTeam(n - 1);
 641         if(teamplay)
 642                 if(t == myteam)
 643                         return SHOTTYPE_HITTEAM;
 644         if(t == NUM_SPECTATOR)
 645                 return SHOTTYPE_HITWORLD;
 646         return SHOTTYPE_HITENEMY;
 647 }
 648
 649 float TrueAimCheck()
 650 {
 651         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 652         vector vecs, trueaimpoint, w_shotorg;
 653         vector mi, ma, dv;
 654         float shottype;
 655         entity ta;
 656         float mv;
 657
 658         mi = ma = '0 0 0';
 659         ta = trueaim;
 660         mv = MOVE_NOMONSTERS;
 661
 662         switch(activeweapon) // WEAPONTODO
 663         {
 664                 case WEP_TUBA: // no aim
 665                 case WEP_PORTO: // shoots from eye
 666                 case WEP_NEXBALL: // shoots from eye
 667                 case WEP_HOOK: // no trueaim
 668                 case WEP_MORTAR: // toss curve
 669                         return SHOTTYPE_HITWORLD;
 670                 case WEP_VORTEX:
 671                 case WEP_VAPORIZER:
 672                         mv = MOVE_NORMAL;
 673                         break;
 674                 case WEP_RIFLE:
 675                         ta = trueaim_rifle;
 676                         mv = MOVE_NORMAL;
 677                         if(zoomscript_caught)
 678                         {
 679                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 680                                 return EnemyHitCheck();
 681                         }
 682                         break;
 683                 case WEP_DEVASTATOR: // projectile has a size!
 684                         mi = '-3 -3 -3';
 685                         ma = '3 3 3';
 686                         break;
 687                 case WEP_FIREBALL: // projectile has a size!
 688                         mi = '-16 -16 -16';
 689                         ma = '16 16 16';
 690                         break;
 691                 case WEP_SEEKER: // projectile has a size!
 692                         mi = '-2 -2 -2';
 693                         ma = '2 2 2';
 694                         break;
 695                 case WEP_ELECTRO: // projectile has a size!
 696                         mi = '0 0 -3';
 697                         ma = '0 0 -3';
 698                         break;
 699         }
 700
 701         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 702
 703         vecs = decompressShotOrigin(STAT(SHOTORG));
 704
 705         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 706         trueaimpoint = trace_endpos;
 707
 708         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 709                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 710
 711         if(vecs.x > 0)
 712                 vecs.y = -vecs.y;
 713         else
 714                 vecs = '0 0 0';
 715
 716         dv = view_right * vecs.y + view_up * vecs.z;
 717         w_shotorg = traceorigin + dv;
 718
 719         // now move the vecs forward as much as requested if possible
 720         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 721         w_shotorg = trace_endpos - view_forward * nudge;
 722
 723         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 724         shottype = EnemyHitCheck();
 725         if(shottype != SHOTTYPE_HITWORLD)
 726                 return shottype;
 727
 728 #if 0
 729         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 730         // or rather, I know why, but see no fix
 731         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 732                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 733                 return SHOTTYPE_HITOBSTRUCTION;
 734 #endif
 735
 736         return SHOTTYPE_HITWORLD;
 737 }
 738
 739 void PostInit();
 740 void CSQC_Demo_Camera();
 741 float HUD_WouldDrawScoreboard();
 742 float camera_mode;
 743 const float CAMERA_FREE = 1;
 744 const float CAMERA_CHASE = 2;
 745 float reticle_type;
 746 string reticle_image;
 747 string NextFrameCommand;
 748
 749 vector freeze_org, freeze_ang;
 750 entity nightvision_noise, nightvision_noise2;
 751
 752 const float MAX_TIME_DIFF = 5;
 753 float pickup_crosshair_time, pickup_crosshair_size;
 754 float hitindication_crosshair_size;
 755 float use_vortex_chargepool;
 756
 757 float myhealth, myhealth_prev;
 758 float myhealth_flash;
 759
 760 float old_blurradius, old_bluralpha;
 761 float old_sharpen_intensity;
 762
 763 vector myhealth_gentlergb;
 764
 765 float contentavgalpha, liquidalpha_prev;
 766 vector liquidcolor_prev;
 767
 768 float eventchase_current_distance;
 769 float eventchase_running;
 770 bool WantEventchase(entity this)
 771 {
 772         if(autocvar_cl_orthoview)
 773                 return false;
 774         if(intermission)
 775                 return true;
 776         if(this.viewloc)
 777                 return true;
 778         if(spectatee_status >= 0)
 779         {
 780                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 781                         return true;
 782                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 783                         return true;
 784                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 785                         return true;
 786                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 787                 {
 788                         if(autocvar_cl_eventchase_death == 2)
 789                         {
 790                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 791                                 if(this.velocity == '0 0 0' || eventchase_running)
 792                                         return true;
 793                         }
 794                         else return true;
 795                 }
 796         }
 797         return false;
 798 }
 799
 800 void HUD_Crosshair_Vehicle()
 801 {
 802         if(hud != HUD_BUMBLEBEE_GUN)
 803         {
 804                 Vehicle info = Vehicles_from(hud);
 805                 info.vr_crosshair(info);
 806         }
 807 }
 808
 809 vector damage_blurpostprocess, content_blurpostprocess;
 810
 811 float unaccounted_damage = 0;
 812 void UpdateDamage()
 813 {
 814         // accumulate damage with each stat update
 815         static float damage_total_prev = 0;
 816         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 817         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 818         damage_total_prev = damage_total;
 819
 820         static float damage_dealt_time_prev = 0;
 821         float damage_dealt_time = STAT(HIT_TIME);
 822         if (damage_dealt_time != damage_dealt_time_prev)
 823         {
 824                 unaccounted_damage += unaccounted_damage_new;
 825                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 826         }
 827         damage_dealt_time_prev = damage_dealt_time;
 828
 829         // prevent hitsound when switching spectatee
 830         static float spectatee_status_prev = 0;
 831         if (spectatee_status != spectatee_status_prev)
 832                 unaccounted_damage = 0;
 833         spectatee_status_prev = spectatee_status;
 834 }
 835
 836 void HitSound()
 837 {
 838         // varying sound pitch
 839
 840         static float hitsound_time_prev = 0;
 841         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 842         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 843         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 844         {
 845                 if (autocvar_cl_hitsound && unaccounted_damage)
 846                 {
 847                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 848                         float a = autocvar_cl_hitsound_max_pitch;
 849                         float b = autocvar_cl_hitsound_min_pitch;
 850                         float c = autocvar_cl_hitsound_nom_damage;
 851                         float x = unaccounted_damage;
 852                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 853
 854                         // if sound variation is disabled, set pitch_shift to 1
 855                         if (autocvar_cl_hitsound == 1)
 856                                 pitch_shift = 1;
 857
 858                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 859                         if (autocvar_cl_hitsound == 3)
 860                         {
 861                                 float mirror_value = (a-b)/2 + b;
 862                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 863                         }
 864
 865                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 866
 867                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 868                         // todo: normalize sound pressure levels? seems unnecessary
 869
 870                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 871                 }
 872                 unaccounted_damage = 0;
 873                 hitsound_time_prev = time;
 874         }
 875
 876         static float typehit_time_prev = 0;
 877         float typehit_time = STAT(TYPEHIT_TIME);
 878         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 879         {
 880                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 881                 typehit_time_prev = typehit_time;
 882         }
 883 }
 884
 885 void HUD_Crosshair()
 886 {SELFPARAM();
 887         static float rainbow_last_flicker;
 888         static vector rainbow_prev_color;
 889         entity e = this;
 890         float f, i, j;
 891         vector v;
 892         if(!scoreboard_active && !camera_active && intermission != 2 &&
 893                 spectatee_status != -1 && !csqcplayer.viewloc &&
 894                 !HUD_MinigameMenu_IsOpened() )
 895         {
 896                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 897                         return;
 898
 899                 if (hud != HUD_NORMAL)
 900                 {
 901                         HUD_Crosshair_Vehicle();
 902                         return;
 903                 }
 904
 905                 string wcross_style;
 906                 float wcross_alpha, wcross_resolution;
 907                 wcross_style = autocvar_crosshair;
 908                 if (wcross_style == "0")
 909                         return;
 910                 wcross_resolution = autocvar_crosshair_size;
 911                 if (wcross_resolution == 0)
 912                         return;
 913                 wcross_alpha = autocvar_crosshair_alpha;
 914                 if (wcross_alpha == 0)
 915                         return;
 916
 917                 // TrueAim check
 918                 float shottype;
 919
 920                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 921                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 922                 wcross_origin.z = 0;
 923                 if(autocvar_crosshair_hittest)
 924                 {
 925                         vector wcross_oldorigin;
 926                         wcross_oldorigin = wcross_origin;
 927                         shottype = TrueAimCheck();
 928                         if(shottype == SHOTTYPE_HITWORLD)
 929                         {
 930                                 v = wcross_origin - wcross_oldorigin;
 931                                 v.x /= vid_conwidth;
 932                                 v.y /= vid_conheight;
 933                                 if(vlen(v) > 0.01)
 934                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 935                         }
 936                         if(!autocvar_crosshair_hittest_showimpact)
 937                                 wcross_origin = wcross_oldorigin;
 938                 }
 939                 else
 940                         shottype = SHOTTYPE_HITWORLD;
 941
 942                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 943                 string wcross_name = "";
 944                 float wcross_scale, wcross_blur;
 945
 946                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 947                 {
 948                         e = switchingweapon;
 949                         if(e)
 950                         {
 951                                 if(autocvar_crosshair_per_weapon)
 952                                 {
 953                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 954                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 955                                         //if (wcross_resolution == 0)
 956                                                 //return;
 957
 958                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 959                                         wcross_resolution *= e.w_crosshair_size;
 960                                         wcross_name = e.w_crosshair;
 961                                 }
 962                         }
 963                 }
 964
 965                 if(wcross_name == "")
 966                         wcross_name = strcat("gfx/crosshair", wcross_style);
 967
 968                 // MAIN CROSSHAIR COLOR DECISION
 969                 switch(autocvar_crosshair_color_special)
 970                 {
 971                         case 1: // crosshair_color_per_weapon
 972                         {
 973                                 if(e)
 974                                 {
 975                                         wcross_color = e.wpcolor;
 976                                         break;
 977                                 }
 978                                 else { goto normalcolor; }
 979                         }
 980
 981                         case 2: // crosshair_color_by_health
 982                         {
 983                                 float x = STAT(HEALTH);
 984
 985                                 //x = red
 986                                 //y = green
 987                                 //z = blue
 988
 989                                 wcross_color.z = 0;
 990
 991                                 if(x > 200)
 992                                 {
 993                                         wcross_color.x = 0;
 994                                         wcross_color.y = 1;
 995                                 }
 996                                 else if(x > 150)
 997                                 {
 998                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 999                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
1000                                 }
1001                                 else if(x > 100)
1002                                 {
1003                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
1004                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
1005                                         wcross_color.z = 1 - (x-100)*0.02;
1006                                 }
1007                                 else if(x > 50)
1008                                 {
1009                                         wcross_color.x = 1;
1010                                         wcross_color.y = 1;
1011                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
1012                                 }
1013                                 else if(x > 20)
1014                                 {
1015                                         wcross_color.x = 1;
1016                                         wcross_color.y = (x-20)*90/27/100;
1017                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
1018                                 }
1019                                 else
1020                                 {
1021                                         wcross_color.x = 1;
1022                                         wcross_color.y = 0;
1023                                 }
1024                                 break;
1025                         }
1026
1027                         case 3: // crosshair_color_rainbow
1028                         {
1029                                 if(time >= rainbow_last_flicker)
1030                                 {
1031                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1032                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1033                                 }
1034                                 wcross_color = rainbow_prev_color;
1035                                 break;
1036                         }
1037                         :normalcolor
1038                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1039                 }
1040
1041                 if(autocvar_crosshair_effect_scalefade)
1042                 {
1043                         wcross_scale = wcross_resolution;
1044                         wcross_resolution = 1;
1045                 }
1046                 else
1047                 {
1048                         wcross_scale = 1;
1049                 }
1050
1051                 if(autocvar_crosshair_pickup)
1052                 {
1053                         float stat_pickup_time = STAT(LAST_PICKUP);
1054
1055                         if(pickup_crosshair_time < stat_pickup_time)
1056                         {
1057                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1058                                         pickup_crosshair_size = 1;
1059
1060                                 pickup_crosshair_time = stat_pickup_time;
1061                         }
1062
1063                         if(pickup_crosshair_size > 0)
1064                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1065                         else
1066                                 pickup_crosshair_size = 0;
1067
1068                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1069                 }
1070
1071                 // todo: make crosshair hit indication dependent on damage dealt
1072                 if(autocvar_crosshair_hitindication)
1073                 {
1074                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1075
1076                         if(unaccounted_damage)
1077                         {
1078                                 hitindication_crosshair_size = 1;
1079                         }
1080
1081                         if(hitindication_crosshair_size > 0)
1082                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1083                         else
1084                                 hitindication_crosshair_size = 0;
1085
1086                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1087                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1088                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1089                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1090                 }
1091
1092                 if(shottype == SHOTTYPE_HITENEMY)
1093                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1094                 if(shottype == SHOTTYPE_HITTEAM)
1095                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1096
1097                 f = fabs(autocvar_crosshair_effect_time);
1098                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1099                 {
1100                         wcross_changedonetime = time + f;
1101                 }
1102                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1103                 {
1104                         wcross_name_changestarttime = time;
1105                         wcross_name_changedonetime = time + f;
1106                         if(wcross_name_goal_prev_prev)
1107                                 strunzone(wcross_name_goal_prev_prev);
1108                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1109                         wcross_name_goal_prev = strzone(wcross_name);
1110                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1111                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1112                         wcross_resolution_goal_prev = wcross_resolution;
1113                 }
1114
1115                 wcross_scale_goal_prev = wcross_scale;
1116                 wcross_alpha_goal_prev = wcross_alpha;
1117                 wcross_color_goal_prev = wcross_color;
1118
1119                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1120                 {
1121                         wcross_blur = 1;
1122                         wcross_alpha *= 0.75;
1123                 }
1124                 else
1125                         wcross_blur = 0;
1126                 // *_prev is at time-frametime
1127                 // * is at wcross_changedonetime+f
1128                 // what do we have at time?
1129                 if(time < wcross_changedonetime)
1130                 {
1131                         f = frametime / (wcross_changedonetime - time + frametime);
1132                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1133                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1134                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1135                 }
1136
1137                 wcross_scale_prev = wcross_scale;
1138                 wcross_alpha_prev = wcross_alpha;
1139                 wcross_color_prev = wcross_color;
1140
1141                 MUTATOR_CALLHOOK(UpdateCrosshair);
1142
1143                 wcross_scale *= 1 - autocvar__menu_alpha;
1144                 wcross_alpha *= 1 - autocvar__menu_alpha;
1145                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1146
1147                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1148                 {
1149                         // crosshair rings for weapon stats
1150                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1151                         {
1152                                 // declarations and stats
1153                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1154                                 string ring_image = string_null, ring_inner_image = string_null;
1155                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1156
1157                                 ring_scale = autocvar_crosshair_ring_size;
1158
1159                                 float weapon_clipload, weapon_clipsize;
1160                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1161                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1162
1163                                 float ok_ammo_charge, ok_ammo_chargepool;
1164                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1165                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1166
1167                                 float vortex_charge, vortex_chargepool;
1168                                 vortex_charge = STAT(VORTEX_CHARGE);
1169                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1170
1171                                 float arc_heat = STAT(ARC_HEAT);
1172
1173                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1174                                         vortex_charge_movingavg = vortex_charge;
1175
1176
1177                                 // handle the values
1178                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1179                                 {
1180                                         if (vortex_chargepool || use_vortex_chargepool) {
1181                                                 use_vortex_chargepool = 1;
1182                                                 ring_inner_value = vortex_chargepool;
1183                                         } else {
1184                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1185                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1186                                         }
1187
1188                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1189                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1190                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1191
1192                                         // draw the outer ring to show the current charge of the weapon
1193                                         ring_value = vortex_charge;
1194                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1195                                         ring_rgb = wcross_color;
1196                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1197                                 }
1198                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1199                                 {
1200                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1201                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1202                                         ring_rgb = wcross_color;
1203                                         ring_image = "gfx/crosshair_ring.tga";
1204                                 }
1205                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1206                                 {
1207                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1208                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1209                                         ring_rgb = wcross_color;
1210                                         ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212                                 else if (ok_ammo_charge)
1213                                 {
1214                                         ring_value = ok_ammo_chargepool;
1215                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1216                                         ring_rgb = wcross_color;
1217                                         ring_image = "gfx/crosshair_ring.tga";
1218                                 }
1219                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1220                                 {
1221                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1222                                         ring_scale = autocvar_crosshair_ring_reload_size;
1223                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1224                                         ring_rgb = wcross_color;
1225
1226                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1227                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1228                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1229                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1230                                         else
1231                                                 ring_image = "gfx/crosshair_ring.tga";
1232                                 }
1233                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1234                                 {
1235                                         ring_value = arc_heat;
1236                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1237                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1238                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1239                                         ring_image = "gfx/crosshair_ring.tga";
1240                                 }
1241
1242                                 // if in weapon switch animation, fade ring out/in
1243                                 if(autocvar_crosshair_effect_time > 0)
1244                                 {
1245                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1246                                         if (f >= 1)
1247                                         {
1248                                                 wcross_ring_prev = ((ring_image) ? true : false);
1249                                         }
1250
1251                                         if(wcross_ring_prev)
1252                                         {
1253                                                 if(f < 1)
1254                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1255                                         }
1256                                         else
1257                                         {
1258                                                 if(f < 1)
1259                                                         ring_alpha *= bound(0, f, 1);
1260                                         }
1261                                 }
1262
1263                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1264                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1265
1266                                 if (ring_value)
1267                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1268                         }
1269
1270 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1271                         MACRO_BEGIN { \
1272                                 if(wcross_blur > 0) \
1273                                 { \
1274                                         for(i = -2; i <= 2; ++i) \
1275                                         for(j = -2; j <= 2; ++j) \
1276                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1277                                 } \
1278                                 else \
1279                                 { \
1280                                         M(0,0,sz,wcross_name,wcross_alpha); \
1281                                 } \
1282                         } MACRO_END
1283
1284 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1285                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1286
1287 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1288                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1289
1290                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1291                         {
1292                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1293                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1294                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1295                                 f = 1 - f;
1296                         }
1297                         else
1298                         {
1299                                 f = 1;
1300                         }
1301                         wcross_name_alpha_goal_prev = f;
1302
1303                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1304                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1305
1306                         if(autocvar_crosshair_dot)
1307                         {
1308                                 vector wcross_color_old;
1309                                 wcross_color_old = wcross_color;
1310
1311                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1312                                         wcross_color = stov(autocvar_crosshair_dot_color);
1313
1314                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1315                                 // FIXME why don't we use wcross_alpha here?
1316                                 wcross_color = wcross_color_old;
1317                         }
1318                 }
1319         }
1320         else
1321         {
1322                 wcross_scale_prev = 0;
1323                 wcross_alpha_prev = 0;
1324                 wcross_scale_goal_prev = 0;
1325                 wcross_alpha_goal_prev = 0;
1326                 wcross_changedonetime = 0;
1327                 if(wcross_name_goal_prev)
1328                         strunzone(wcross_name_goal_prev);
1329                 wcross_name_goal_prev = string_null;
1330                 if(wcross_name_goal_prev_prev)
1331                         strunzone(wcross_name_goal_prev_prev);
1332                 wcross_name_goal_prev_prev = string_null;
1333                 wcross_name_changestarttime = 0;
1334                 wcross_name_changedonetime = 0;
1335                 wcross_name_alpha_goal_prev = 0;
1336                 wcross_name_alpha_goal_prev_prev = 0;
1337                 wcross_resolution_goal_prev = 0;
1338                 wcross_resolution_goal_prev_prev = 0;
1339         }
1340 }
1341
1342 void HUD_Draw()
1343 {
1344         vector rgb = '0 0 0';
1345         float a = 1;
1346         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1347         {
1348                 rgb = MUTATOR_ARGV(0, vector);
1349                 a = MUTATOR_ARGV(0, float);
1350         }
1351         else if(STAT(FROZEN))
1352         {
1353                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1354         }
1355         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1356         if(!intermission)
1357         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1358         {
1359                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1360                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1361         }
1362         else if(STAT(REVIVE_PROGRESS))
1363         {
1364                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1365                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1366         }
1367
1368         if(autocvar_r_letterbox == 0)
1369                 if(autocvar_viewsize < 120)
1370                 {
1371                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1372                                 Accuracy_LoadLevels();
1373
1374                         HUD_Main();
1375                         HUD_DrawScoreboard();
1376                 }
1377
1378         // crosshair goes VERY LAST
1379         UpdateDamage();
1380         HUD_Crosshair();
1381         HitSound();
1382 }
1383
1384 bool ov_enabled;
1385 float oldr_nearclip;
1386 float oldr_farclip_base;
1387 float oldr_farclip_world;
1388 float oldr_novis;
1389 float oldr_useportalculling;
1390 float oldr_useinfinitefarclip;
1391
1392 void cl_notice_run();
1393 float prev_myteam;
1394 int lasthud;
1395 float vh_notice_time;
1396 void WaypointSprite_Load();
1397 void CSQC_UpdateView(float w, float h)
1398 {SELFPARAM();
1399         entity e;
1400         float fov;
1401         float f;
1402         vector vf_size, vf_min;
1403         float a;
1404
1405         execute_next_frame();
1406
1407         ++framecount;
1408
1409         stats_get();
1410         hud = STAT(HUD);
1411
1412         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1413                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1414
1415         lasthud = hud;
1416
1417         if(autocvar__hud_showbinds_reload) // menu can set this one
1418         {
1419                 db_close(binddb);
1420                 binddb = db_create();
1421                 cvar_set("_hud_showbinds_reload", "0");
1422         }
1423
1424         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1425                 view_quality = getproperty(VF_MINFPS_QUALITY);
1426         else
1427                 view_quality = 1;
1428
1429         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1430         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1431
1432         vf_size = getpropertyvec(VF_SIZE);
1433         vf_min = getpropertyvec(VF_MIN);
1434         vid_width = vf_size.x;
1435         vid_height = vf_size.y;
1436
1437         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1438         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1439
1440         WaypointSprite_Load();
1441
1442         CSQCPlayer_SetCamera();
1443
1444         if(player_localentnum <= maxclients) // is it a client?
1445                 current_player = player_localentnum - 1;
1446         else // then player_localentnum is the vehicle I'm driving
1447                 current_player = player_localnum;
1448         myteam = entcs_GetTeam(current_player);
1449
1450         if(myteam != prev_myteam)
1451         {
1452                 myteamcolors = colormapPaletteColor(myteam, 1);
1453                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1454                 prev_myteam = myteam;
1455         }
1456
1457         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1458
1459         float is_dead = (STAT(HEALTH) <= 0);
1460
1461         // FIXME do we need this hack?
1462         if(isdemo())
1463         {
1464                 // in demos, input_buttons do not work
1465                 button_zoom = (autocvar__togglezoom == "-");
1466         }
1467         else if(button_zoom
1468                 && autocvar_cl_unpress_zoom_on_death
1469                 && (spectatee_status >= 0)
1470                 && (is_dead || intermission))
1471         {
1472                 // no zoom while dead or in intermission please
1473                 localcmd("-zoom\n");
1474                 button_zoom = false;
1475         }
1476
1477         // event chase camera
1478         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1479         {
1480                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1481                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1482                 entity gen = world;
1483
1484                 float vehicle_viewdist = 0;
1485                 vector vehicle_viewofs = '0 0 0';
1486
1487                 if(vehicle_chase)
1488                 {
1489                         if(hud != HUD_BUMBLEBEE_GUN)
1490                         {
1491                                 Vehicle info = Vehicles_from(hud);
1492                                 vehicle_viewdist = info.height;
1493                                 vehicle_viewofs = info.view_ofs;
1494                         }
1495                 }
1496
1497                 if(ons_roundlost)
1498                 {
1499                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1500                                 gen = it;
1501                                 break;
1502                         ));
1503                         if(!gen)
1504                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1505                 }
1506                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1507                 {
1508                         eventchase_running = true;
1509
1510                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1511                         if(!local_player)
1512                                 local_player = self; // fall back!
1513
1514                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1515                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1516                         if(ons_roundlost) { current_view_origin = gen.origin; }
1517
1518                         // detect maximum viewoffset and use it
1519                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1520                         if(vehicle_chase)
1521                         {
1522                                 if(vehicle_viewofs)
1523                                         view_offset = vehicle_viewofs;
1524                                 else
1525                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1526                         }
1527                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1528
1529                         if(view_offset)
1530                         {
1531                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1532                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1533                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1534                         }
1535
1536                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1537                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1538                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1539                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1540
1541                         // make the camera smooth back
1542                         float chase_distance = autocvar_cl_eventchase_distance;
1543                         if(vehicle_chase)
1544                         {
1545                                 if(vehicle_viewofs)
1546                                         chase_distance = vehicle_viewdist;
1547                                 else
1548                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1549                         }
1550                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1551
1552                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1553                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1554                         else if(eventchase_current_distance != chase_distance)
1555                                 eventchase_current_distance = chase_distance;
1556
1557                         makevectors(view_angles);
1558
1559                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1560                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1561
1562                         // If the boxtrace fails, revert back to line tracing.
1563                         if(!local_player.viewloc)
1564                         if(trace_startsolid)
1565                         {
1566                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1567                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1568                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1569                         }
1570                         else { setproperty(VF_ORIGIN, trace_endpos); }
1571
1572                         if(!local_player.viewloc)
1573                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1574                 }
1575                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1576                 {
1577                         eventchase_running = false;
1578                         cvar_set("chase_active", "0");
1579                         eventchase_current_distance = 0; // start from 0 next time
1580                 }
1581         }
1582         // workaround for camera stuck between player's legs when using chase_active 1
1583         // because the engine stops updating the chase_active camera when the game ends
1584         else if(intermission)
1585         {
1586                 cvar_settemp("chase_active", "-1");
1587                 eventchase_current_distance = 0;
1588         }
1589
1590         // do lockview after event chase camera so that it still applies whenever necessary.
1591         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1592         {
1593                 setproperty(VF_ORIGIN, freeze_org);
1594                 setproperty(VF_ANGLES, freeze_ang);
1595         }
1596         else
1597         {
1598                 freeze_org = getpropertyvec(VF_ORIGIN);
1599                 freeze_ang = getpropertyvec(VF_ANGLES);
1600         }
1601
1602         WarpZone_FixView();
1603         //WarpZone_FixPMove();
1604
1605         vector ov_org = '0 0 0';
1606         vector ov_mid = '0 0 0';
1607         vector ov_worldmin = '0 0 0';
1608         vector ov_worldmax = '0 0 0';
1609         if(autocvar_cl_orthoview)
1610         {
1611                 ov_worldmin = mi_picmin;
1612                 ov_worldmax = mi_picmax;
1613
1614                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1615                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1616                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1617
1618                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1619                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1620
1621                 float ov_nearest = vlen(ov_org - vec3(
1622                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1623                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1624                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1625                 ));
1626
1627                 float ov_furthest = 0;
1628                 float dist = 0;
1629
1630                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1631                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1632                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1633                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1634                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1635                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1636                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1637                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1638
1639                 if(!ov_enabled)
1640                 {
1641                         oldr_nearclip = cvar("r_nearclip");
1642                         oldr_farclip_base = cvar("r_farclip_base");
1643                         oldr_farclip_world = cvar("r_farclip_world");
1644                         oldr_novis = cvar("r_novis");
1645                         oldr_useportalculling = cvar("r_useportalculling");
1646                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1647                 }
1648
1649                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1650                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1651                 cvar_settemp("r_farclip_world", "0");
1652                 cvar_settemp("r_novis", "1");
1653                 cvar_settemp("r_useportalculling", "0");
1654                 cvar_settemp("r_useinfinitefarclip", "0");
1655
1656                 setproperty(VF_ORIGIN, ov_org);
1657                 setproperty(VF_ANGLES, '90 0 0');
1658
1659                 ov_enabled = true;
1660
1661                 #if 0
1662                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1663                         vtos(ov_org),
1664                         vtos(getpropertyvec(VF_ANGLES)),
1665                         ov_distance,
1666                         ov_nearest,
1667                         ov_furthest);
1668                 #endif
1669         }
1670         else
1671         {
1672                 if(ov_enabled)
1673                 {
1674                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1675                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1676                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1677                         cvar_set("r_novis", ftos(oldr_novis));
1678                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1679                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1680                 }
1681                 ov_enabled = false;
1682         }
1683
1684         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1685         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1686         viewmodel_draw(viewmodel);
1687
1688         // Render the Scene
1689         view_origin = getpropertyvec(VF_ORIGIN);
1690         view_angles = getpropertyvec(VF_ANGLES);
1691         makevectors(view_angles);
1692         view_forward = v_forward;
1693         view_right = v_right;
1694         view_up = v_up;
1695
1696 #ifdef BLURTEST
1697         if(time > blurtest_time0 && time < blurtest_time1)
1698         {
1699                 float r, t;
1700
1701                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1702                 r = t * blurtest_radius;
1703                 f = 1 / pow(t, blurtest_power) - 1;
1704
1705                 cvar_set("r_glsl_postprocess", "1");
1706                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1707         }
1708         else
1709         {
1710                 cvar_set("r_glsl_postprocess", "0");
1711                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1712         }
1713 #endif
1714
1715         TargetMusic_Advance();
1716         Fog_Force();
1717
1718         if(drawtime == 0)
1719                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1720         else
1721                 drawframetime = bound(0.000001, time - drawtime, 1);
1722         drawtime = time;
1723
1724         // watch for gametype changes here...
1725         // in ParseStuffCMD the cmd isn't executed yet :/
1726         // might even be better to add the gametype to TE_CSQC_INIT...?
1727         if(!postinit)
1728                 PostInit();
1729
1730         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1731         {
1732                 if(calledhooks & HOOK_START)
1733                 {
1734                         localcmd("\ncl_hook_gameend\n");
1735                         calledhooks |= HOOK_END;
1736                 }
1737         }
1738
1739         Announcer();
1740
1741         fov = autocvar_fov;
1742         if(fov <= 59.5)
1743         {
1744                 if(!zoomscript_caught)
1745                 {
1746                         localcmd("+button9\n");
1747                         zoomscript_caught = 1;
1748                 }
1749         }
1750         else
1751         {
1752                 if(zoomscript_caught)
1753                 {
1754                         localcmd("-button9\n");
1755                         zoomscript_caught = 0;
1756                 }
1757         }
1758
1759         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1760
1761         // currently switching-to weapon (for crosshair)
1762         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1763
1764         // actually active weapon (for zoom)
1765         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1766
1767         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1768
1769         f = (serverflags & SERVERFLAG_TEAMPLAY);
1770         if(f != teamplay)
1771         {
1772                 teamplay = f;
1773                 HUD_InitScores();
1774         }
1775
1776         if(last_switchweapon != switchweapon)
1777         {
1778                 weapontime = time;
1779                 last_switchweapon = switchweapon;
1780                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1781                 {
1782                         localcmd("-zoom\n");
1783                         button_zoom = false;
1784                 }
1785                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1786                 {
1787                         localcmd("-fire\n");
1788                         localcmd("-fire2\n");
1789                         button_attack2 = false;
1790                 }
1791         }
1792         if(last_activeweapon != activeweapon)
1793         {
1794                 last_activeweapon = activeweapon;
1795
1796                 e = activeweapon;
1797                 if(e.netname != "")
1798                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1799                 else
1800                         localcmd("\ncl_hook_activeweapon none\n");
1801         }
1802
1803         // ALWAYS Clear Current Scene First
1804         clearscene();
1805
1806         setproperty(VF_ORIGIN, view_origin);
1807         setproperty(VF_ANGLES, view_angles);
1808
1809         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1810         setproperty(VF_SIZE, vf_size);
1811         setproperty(VF_MIN, vf_min);
1812
1813         // Assign Standard Viewflags
1814         // Draw the World (and sky)
1815         setproperty(VF_DRAWWORLD, 1);
1816
1817         // Set the console size vars
1818         vid_conwidth = autocvar_vid_conwidth;
1819         vid_conheight = autocvar_vid_conheight;
1820         vid_pixelheight = autocvar_vid_pixelheight;
1821
1822         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1823         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1824         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1825
1826         // Camera for demo playback
1827         if(camera_active)
1828         {
1829                 if(autocvar_camera_enable)
1830                         CSQC_Demo_Camera();
1831                 else
1832                 {
1833                         cvar_set("chase_active", ftos(chase_active_backup));
1834                         cvar_set("cl_demo_mousegrab", "0");
1835                         camera_active = false;
1836                 }
1837         }
1838         else
1839         {
1840 #ifdef CAMERATEST
1841                 if(autocvar_camera_enable)
1842 #else
1843                 if(autocvar_camera_enable && isdemo())
1844 #endif
1845                 {
1846                         // Enable required Darkplaces cvars
1847                         chase_active_backup = autocvar_chase_active;
1848                         cvar_set("chase_active", "2");
1849                         cvar_set("cl_demo_mousegrab", "1");
1850                         camera_active = true;
1851                         camera_mode = false;
1852                 }
1853         }
1854
1855         // Draw the Crosshair
1856         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1857
1858         // Draw the Engine Status Bar (the default Quake HUD)
1859         setproperty(VF_DRAWENGINESBAR, 0);
1860
1861         // Update the mouse position
1862         /*
1863            mousepos_x = vid_conwidth;
1864            mousepos_y = vid_conheight;
1865            mousepos = mousepos*0.5 + getmousepos();
1866          */
1867
1868         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1869
1870         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1871         renderscene();
1872
1873         // now switch to 2D drawing mode by calling a 2D drawing function
1874         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1875         // next R_RenderScene call
1876         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1877
1878         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1879         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1880         {
1881                 // apply night vision effect
1882                 vector tc_00, tc_01, tc_10, tc_11;
1883                 vector rgb = '0 0 0';
1884
1885                 if(!nightvision_noise)
1886                 {
1887                         nightvision_noise = new(nightvision_noise);
1888                 }
1889                 if(!nightvision_noise2)
1890                 {
1891                         nightvision_noise2 = new(nightvision_noise2);
1892                 }
1893
1894                 // color tint in yellow
1895                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1896
1897                 // draw BG
1898                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1899                 rgb = '1 1 1';
1900                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1901                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1902                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1903                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1904                 tc_11 = tc_01 + tc_10 - tc_00;
1905                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1906                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1907                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1908                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1909                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1910                 R_EndPolygon();
1911
1912                 // draw FG
1913                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1914                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1915                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1916                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1917                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1918                 tc_11 = tc_01 + tc_10 - tc_00;
1919                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1920                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1921                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1922                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1923                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1924                 R_EndPolygon();
1925         }
1926
1927         if(autocvar_cl_reticle)
1928         {
1929                 Weapon wep = activeweapon;
1930                 // Draw the aiming reticle for weapons that use it
1931                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1932                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1933                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1934                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1935                 {
1936                         // no zoom reticle while dead
1937                         reticle_type = 0;
1938                 }
1939                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1940                 {
1941                         if(reticle_image != "") { reticle_type = 2; }
1942                         else { reticle_type = 0; }
1943                 }
1944                 else if(button_zoom || zoomscript_caught)
1945                 {
1946                         // normal zoom
1947                         reticle_type = 1;
1948                 }
1949
1950                 if(reticle_type)
1951                 {
1952                         if(autocvar_cl_reticle_stretch)
1953                         {
1954                                 reticle_size.x = vid_conwidth;
1955                                 reticle_size.y = vid_conheight;
1956                                 reticle_pos.x = 0;
1957                                 reticle_pos.y = 0;
1958                         }
1959                         else
1960                         {
1961                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1962                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1963                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1964                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1965                         }
1966
1967                         if(zoomscript_caught)
1968                                 f = 1;
1969                         else
1970                                 f = current_zoomfraction;
1971
1972                         if(f)
1973                         {
1974                                 switch(reticle_type)
1975                                 {
1976                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1977                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1978                                 }
1979                         }
1980                 }
1981         }
1982         else
1983         {
1984                 if(reticle_type != 0) { reticle_type = 0; }
1985         }
1986
1987
1988         // improved polyblend
1989         if(autocvar_hud_contents)
1990         {
1991                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1992                 vector liquidcolor;
1993
1994                 switch(pointcontents(view_origin))
1995                 {
1996                         case CONTENT_WATER:
1997                                 liquidalpha = autocvar_hud_contents_water_alpha;
1998                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1999                                 incontent = 1;
2000                                 break;
2001
2002                         case CONTENT_LAVA:
2003                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2004                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2005                                 incontent = 1;
2006                                 break;
2007
2008                         case CONTENT_SLIME:
2009                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2010                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2011                                 incontent = 1;
2012                                 break;
2013
2014                         default:
2015                                 liquidalpha = 0;
2016                                 liquidcolor = '0 0 0';
2017                                 incontent = 0;
2018                                 break;
2019                 }
2020
2021                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2022                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2023                         contentfadetime = autocvar_hud_contents_fadeintime;
2024                         liquidalpha_prev = liquidalpha;
2025                         liquidcolor_prev = liquidcolor;
2026                 }
2027                 else
2028                         contentfadetime = autocvar_hud_contents_fadeouttime;
2029
2030                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2031                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2032
2033                 if(contentavgalpha)
2034                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2035
2036                 if(autocvar_hud_postprocessing)
2037                 {
2038                         if(autocvar_hud_contents_blur && contentavgalpha)
2039                         {
2040                                 content_blurpostprocess.x = 1;
2041                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2042                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2043                         }
2044                         else
2045                         {
2046                                 content_blurpostprocess.x = 0;
2047                                 content_blurpostprocess.y = 0;
2048                                 content_blurpostprocess.z = 0;
2049                         }
2050                 }
2051         }
2052
2053         if(autocvar_hud_damage && !STAT(FROZEN))
2054         {
2055                 splash_size.x = max(vid_conwidth, vid_conheight);
2056                 splash_size.y = max(vid_conwidth, vid_conheight);
2057                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2058                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2059
2060                 float myhealth_flash_temp;
2061                 myhealth = STAT(HEALTH);
2062
2063                 // fade out
2064                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2065                 // add new damage
2066                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2067
2068                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2069                 pain_threshold = autocvar_hud_damage_pain_threshold;
2070                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2071                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2072
2073                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2074                 {
2075                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2076                 }
2077
2078                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2079
2080                 if(myhealth_prev < 1)
2081                 {
2082                         if(myhealth >= 1)
2083                         {
2084                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2085                                 myhealth_flash_temp = 0;
2086                         }
2087                         else
2088                         {
2089                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2090                         }
2091                 }
2092
2093                 if(spectatee_status == -1 || intermission)
2094                 {
2095                         myhealth_flash = 0; // observing, or match ended
2096                         myhealth_flash_temp = 0;
2097                 }
2098
2099                 myhealth_prev = myhealth;
2100
2101                 // IDEA: change damage color/picture based on player model for robot/alien species?
2102                 // pro: matches model better
2103                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2104                 // maybe different reddish pics?
2105                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2106                 {
2107                         if(autocvar_cl_gentle_damage == 2)
2108                         {
2109                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2110                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2111                         }
2112                         else
2113                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2114
2115                         if(myhealth_flash_temp > 0)
2116                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2117                 }
2118                 else if(myhealth_flash_temp > 0)
2119                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2120
2121                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2122                 {
2123                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2124                         {
2125                                 damage_blurpostprocess.x = 1;
2126                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2127                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2128                         }
2129                         else
2130                         {
2131                                 damage_blurpostprocess.x = 0;
2132                                 damage_blurpostprocess.y = 0;
2133                                 damage_blurpostprocess.z = 0;
2134                         }
2135                 }
2136         }
2137
2138         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2139         float e2 = (autocvar_hud_powerup != 0);
2140         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2141         {
2142                 // enable or disable rendering types if they are used or not
2143                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2144                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2145
2146                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2147                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2148                 {
2149                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2150                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2151                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2152                         {
2153                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2154                                 old_blurradius = blurradius;
2155                                 old_bluralpha = bluralpha;
2156                         }
2157                 }
2158                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2159                 {
2160                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2161                         old_blurradius = 0;
2162                         old_bluralpha = 0;
2163                 }
2164
2165                 // edge detection postprocess handling done second (used by hud_powerup)
2166                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2167                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2168                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2169
2170                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2171
2172                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2173                 {
2174                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2175                         {
2176                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2177                                 old_sharpen_intensity = sharpen_intensity;
2178                         }
2179                 }
2180                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2181                 {
2182                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2183                         old_sharpen_intensity = 0;
2184                 }
2185
2186                 if(cvar("r_glsl_postprocess") == 0)
2187                         cvar_set("r_glsl_postprocess", "2");
2188         }
2189         else if(cvar("r_glsl_postprocess") == 2)
2190                 cvar_set("r_glsl_postprocess", "0");
2191
2192         /*if(gametype == MAPINFO_TYPE_CTF)
2193           {
2194           ctf_view();
2195           } else */
2196
2197         // draw 2D entities
2198         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2199         Draw_ShowNames_All();
2200         Debug_Draw();
2201
2202         scoreboard_active = HUD_WouldDrawScoreboard();
2203
2204         HUD_Draw();
2205
2206         if(NextFrameCommand)
2207         {
2208                 localcmd("\n", NextFrameCommand, "\n");
2209                 NextFrameCommand = string_null;
2210         }
2211
2212         // we must do this check AFTER a frame was rendered, or it won't work
2213         if(cs_project_is_b0rked == 0)
2214         {
2215                 string w0, h0;
2216                 w0 = ftos(autocvar_vid_conwidth);
2217                 h0 = ftos(autocvar_vid_conheight);
2218                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2219                 //setproperty(VF_FOV, '90 90 0');
2220                 setproperty(VF_ORIGIN, '0 0 0');
2221                 setproperty(VF_ANGLES, '0 0 0');
2222                 setproperty(VF_PERSPECTIVE, 1);
2223                 makevectors('0 0 0');
2224                 vector v1, v2;
2225                 cvar_set("vid_conwidth", "800");
2226                 cvar_set("vid_conheight", "600");
2227                 v1 = cs_project(v_forward);
2228                 cvar_set("vid_conwidth", "640");
2229                 cvar_set("vid_conheight", "480");
2230                 v2 = cs_project(v_forward);
2231                 if(v1 == v2)
2232                         cs_project_is_b0rked = 1;
2233                 else
2234                         cs_project_is_b0rked = -1;
2235                 cvar_set("vid_conwidth", w0);
2236                 cvar_set("vid_conheight", h0);
2237         }
2238
2239         if(autocvar__hud_configure)
2240                 HUD_Panel_Mouse();
2241         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2242                 HUD_Minigame_Mouse();
2243         else if(QuickMenu_IsOpened())
2244                 QuickMenu_Mouse();
2245         else
2246                 HUD_Radar_Mouse();
2247
2248         cl_notice_run();
2249         unpause_update();
2250         Net_Flush();
2251
2252         // let's reset the view back to normal for the end
2253         setproperty(VF_MIN, '0 0 0');
2254         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2255 }
2256
2257
2258 // following vectors must be global to allow seamless switching between camera modes
2259 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2260 void CSQC_Demo_Camera()
2261 {
2262         float speed, attenuation, dimensions;
2263         vector tmp, delta;
2264
2265         if( autocvar_camera_reset || !camera_mode )
2266         {
2267                 camera_offset = '0 0 0';
2268                 current_angles = '0 0 0';
2269                 camera_direction = '0 0 0';
2270                 camera_offset.z += 30;
2271                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2272                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2273                 current_origin = view_origin;
2274                 current_camera_offset  = camera_offset;
2275                 cvar_set("camera_reset", "0");
2276                 camera_mode = CAMERA_CHASE;
2277         }
2278
2279         // Camera angles
2280         if( camera_roll )
2281                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2282
2283         if(autocvar_camera_look_player)
2284         {
2285                 vector dir;
2286                 float n;
2287
2288                 dir = normalize(view_origin - current_position);
2289                 n = mouse_angles.z;
2290                 mouse_angles = vectoangles(dir);
2291                 mouse_angles.x = mouse_angles.x * -1;
2292                 mouse_angles.z = n;
2293         }
2294         else
2295         {
2296                 tmp = getmousepos() * 0.1;
2297                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2298                 {
2299                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2300                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2301                 }
2302         }
2303
2304         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2305         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2306         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2307         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2308
2309         // Fix difference when angles don't have the same sign
2310         delta = '0 0 0';
2311         if(mouse_angles.y < -60 && current_angles.y > 60)
2312                 delta = '0 360 0';
2313         if(mouse_angles.y > 60 && current_angles.y < -60)
2314                 delta = '0 -360 0';
2315
2316         if(autocvar_camera_look_player)
2317                 attenuation = autocvar_camera_look_attenuation;
2318         else
2319                 attenuation = autocvar_camera_speed_attenuation;
2320
2321         attenuation = 1 / max(1, attenuation);
2322         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2323
2324         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2325         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2326         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2327         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2328
2329         // Camera position
2330         tmp = '0 0 0';
2331         dimensions = 0;
2332
2333         if( camera_direction.x )
2334         {
2335                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2336                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2337                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2338                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2339                 ++dimensions;
2340         }
2341
2342         if( camera_direction.y )
2343         {
2344                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2345                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2346                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2347                 ++dimensions;
2348         }
2349
2350         if( camera_direction.z )
2351         {
2352                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2353                 ++dimensions;
2354         }
2355
2356         if(autocvar_camera_free)
2357                 speed = autocvar_camera_speed_free;
2358         else
2359                 speed = autocvar_camera_speed_chase;
2360
2361         if(dimensions)
2362         {
2363                 speed = speed * sqrt(1 / dimensions);
2364                 camera_offset += tmp * speed;
2365         }
2366
2367         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2368
2369         // Camera modes
2370         if( autocvar_camera_free )
2371         {
2372                 if ( camera_mode == CAMERA_CHASE )
2373                 {
2374                         current_camera_offset = current_origin + current_camera_offset;
2375                         camera_offset = current_origin + camera_offset;
2376                 }
2377
2378                 camera_mode = CAMERA_FREE;
2379                 current_position = current_camera_offset;
2380         }
2381         else
2382         {
2383                 if ( camera_mode == CAMERA_FREE )
2384                 {
2385                         current_origin = view_origin;
2386                         camera_offset = camera_offset - current_origin;
2387                         current_camera_offset = current_camera_offset - current_origin;
2388                 }
2389
2390                 camera_mode = CAMERA_CHASE;
2391
2392                 if(autocvar_camera_chase_smoothly)
2393                         current_origin += (view_origin - current_origin) * attenuation;
2394                 else
2395                         current_origin = view_origin;
2396
2397                 current_position = current_origin + current_camera_offset;
2398         }
2399
2400         setproperty(VF_ANGLES, current_angles);
2401         setproperty(VF_ORIGIN, current_position);
2402 }