Merge branch 'master' into terencehill/quickmenu
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "_all.qh"
2
3 #include "announcer.qh"
4 #include "hook.qh"
5 #include "hud.qh"
6 #include "hud_config.qh"
7 #include "mapvoting.qh"
8 #include "scoreboard.qh"
9 #include "shownames.qh"
10
11 #include "mutators/events.qh"
12
13 #include "../common/constants.qh"
14 #include "../common/mapinfo.qh"
15 #include "../common/nades.qh"
16 #include "../common/stats.qh"
17 #include "../common/triggers/target/music.qh"
18 #include "../common/teams.qh"
19 #include "../common/util.qh"
20
21 #include "../common/weapons/all.qh"
22
23 #include "../csqcmodellib/cl_player.qh"
24
25 #include "../warpzonelib/client.qh"
26 #include "../warpzonelib/common.qh"
27
28 entity porto;
29 vector polyline[16];
30 void Porto_Draw()
31 {
32         vector p, dir, ang, q, nextdir;
33         float portal_number, portal1_idx;
34
35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
36                 return;
37         if(g_balance_porto_secondary)
38                 return;
39         if(intermission == 1)
40                 return;
41         if(intermission == 2)
42                 return;
43         if (getstati(STAT_HEALTH) <= 0)
44                 return;
45
46         dir = view_forward;
47
48         if(angles_held_status)
49         {
50                 makevectors(angles_held);
51                 dir = v_forward;
52         }
53
54         p = view_origin;
55
56         polyline[0] = p;
57         int idx = 1;
58         portal_number = 0;
59         nextdir = dir;
60
61         for (;;)
62         {
63                 dir = nextdir;
64                 traceline(p, p + 65536 * dir, true, porto);
65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
66                         return;
67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
68                 p = trace_endpos;
69                 polyline[idx] = p;
70                 ++idx;
71                 if(idx >= 16)
72                         return;
73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
74                         continue;
75                 ++portal_number;
76                 ang = vectoangles2(trace_plane_normal, dir);
77                 ang.x = -ang.x;
78                 makevectors(ang);
79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
80                         return;
81                 if(portal_number == 1)
82                 {
83                         portal1_idx = idx;
84                         if(portal_number >= 2)
85                                 break;
86                 }
87         }
88
89         while(idx >= 2)
90         {
91                 p = polyline[idx-2];
92                 q = polyline[idx-1];
93                 if(idx == 2)
94                         p = p - view_up * 16;
95                 if(idx-1 >= portal1_idx)
96                 {
97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
98                 }
99                 else
100                 {
101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
102                 }
103                 --idx;
104         }
105 }
106
107 void Porto_Init()
108 {
109         porto = spawn();
110         porto.classname = "porto";
111         porto.draw = Porto_Draw;
112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
113 }
114
115 float drawtime;
116 float avgspeed;
117 vector GetCurrentFov(float fov)
118 {
119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
120         float velocityzoom, curspeed;
121         vector v;
122
123         zoomsensitivity = autocvar_cl_zoomsensitivity;
124         zoomfactor = autocvar_cl_zoomfactor;
125         if(zoomfactor < 1 || zoomfactor > 30)
126                 zoomfactor = 2.5;
127         zoomspeed = autocvar_cl_zoomspeed;
128         if(zoomspeed >= 0)
129         if(zoomspeed < 0.5 || zoomspeed > 16)
130                         zoomspeed = 3.5;
131
132         zoomdir = button_zoom;
133         if(hud == HUD_NORMAL)
134         if(switchweapon == activeweapon)
135         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
136                 zoomdir += button_attack2;
137         if(spectatee_status > 0 || isdemo())
138         {
139                 if(spectatorbutton_zoom)
140                 {
141                         if(zoomdir)
142                                 zoomdir = 0;
143                         else
144                                 zoomdir = 1;
145                 }
146                 // fteqcc failed twice here already, don't optimize this
147         }
148
149         if(zoomdir) { zoomin_effect = 0; }
150
151         if(camera_active)
152         {
153                 current_viewzoom = min(1, current_viewzoom + drawframetime);
154         }
155         else if(autocvar_cl_spawnzoom && zoomin_effect)
156         {
157                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
158
159                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
160                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
161                 if(current_viewzoom == 1) { zoomin_effect = 0; }
162         }
163         else
164         {
165                 if(zoomspeed < 0) // instant zoom
166                 {
167                         if(zoomdir)
168                                 current_viewzoom = 1 / zoomfactor;
169                         else
170                                 current_viewzoom = 1;
171                 }
172                 else
173                 {
174                         if(zoomdir)
175                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
176                         else
177                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
178                 }
179         }
180
181         if(almost_equals(current_viewzoom, 1))
182                 current_zoomfraction = 0;
183         else if(almost_equals(current_viewzoom, 1/zoomfactor))
184                 current_zoomfraction = 1;
185         else
186                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
187
188         if(zoomsensitivity < 1)
189                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
190         else
191                 setsensitivityscale(1);
192
193         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
194         {
195                 if(intermission) { curspeed = 0; }
196                 else
197                 {
198
199                         makevectors(view_angles);
200                         v = pmove_vel;
201                         if(csqcplayer)
202                                 v = csqcplayer.velocity;
203
204                         switch(autocvar_cl_velocityzoom_type)
205                         {
206                                 case 3: curspeed = max(0, v_forward * v); break;
207                                 case 2: curspeed = (v_forward * v); break;
208                                 case 1: default: curspeed = vlen(v); break;
209                         }
210                 }
211
212                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
213                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
214                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
215
216                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
217         }
218         else
219                 velocityzoom = 1;
220
221         float frustumx, frustumy, fovx, fovy;
222         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
223         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
224         fovx = atan2(frustumx, 1) / M_PI * 360.0;
225         fovy = atan2(frustumy, 1) / M_PI * 360.0;
226
227         return '1 0 0' * fovx + '0 1 0' * fovy;
228 }
229
230 vector GetViewLocationFOV(float fov)
231 {
232         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
233         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
234         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
235         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
236         return '1 0 0' * fovx + '0 1 0' * fovy;
237 }
238
239 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
240 {
241         float fovx, fovy;
242         float width = (ov_worldmax.x - ov_worldmin.x);
243         float height = (ov_worldmax.y - ov_worldmin.y);
244         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
245         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
246         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
247         return '1 0 0' * fovx + '0 1 0' * fovy;
248 }
249
250 // this function must match W_SetupShot!
251 float zoomscript_caught;
252
253 vector wcross_origin;
254 float wcross_scale_prev, wcross_alpha_prev;
255 vector wcross_color_prev;
256 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
257 vector wcross_color_goal_prev;
258 float wcross_changedonetime;
259
260 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
261 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
262 float wcross_name_changestarttime, wcross_name_changedonetime;
263 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
264
265 float wcross_ring_prev;
266
267 entity trueaim;
268 entity trueaim_rifle;
269
270 const float SHOTTYPE_HITTEAM = 1;
271 const float SHOTTYPE_HITOBSTRUCTION = 2;
272 const float SHOTTYPE_HITWORLD = 3;
273 const float SHOTTYPE_HITENEMY = 4;
274
275 void TrueAim_Init()
276 {
277         trueaim = spawn();
278         trueaim.classname = "trueaim";
279         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
280         trueaim_rifle = spawn();
281         trueaim_rifle.classname = "trueaim_rifle";
282         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
283 }
284
285 float EnemyHitCheck()
286 {
287         float t, n;
288         wcross_origin = project_3d_to_2d(trace_endpos);
289         wcross_origin.z = 0;
290         if(trace_ent)
291                 n = trace_ent.entnum;
292         else
293                 n = trace_networkentity;
294         if(n < 1)
295                 return SHOTTYPE_HITWORLD;
296         if(n > maxclients)
297                 return SHOTTYPE_HITWORLD;
298         t = GetPlayerColor(n - 1);
299         if(teamplay)
300                 if(t == myteam)
301                         return SHOTTYPE_HITTEAM;
302         if(t == NUM_SPECTATOR)
303                 return SHOTTYPE_HITWORLD;
304         return SHOTTYPE_HITENEMY;
305 }
306
307 float TrueAimCheck()
308 {
309         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
310         vector vecs, trueaimpoint, w_shotorg;
311         vector mi, ma, dv;
312         float shottype;
313         entity ta;
314         float mv;
315
316         mi = ma = '0 0 0';
317         ta = trueaim;
318         mv = MOVE_NOMONSTERS;
319
320         switch(activeweapon) // WEAPONTODO
321         {
322                 case WEP_TUBA.m_id: // no aim
323                 case WEP_PORTO.m_id: // shoots from eye
324                 case WEP_HOOK.m_id: // no trueaim
325                 case WEP_MORTAR.m_id: // toss curve
326                         return SHOTTYPE_HITWORLD;
327                 case WEP_VORTEX.m_id:
328                 case WEP_VAPORIZER.m_id:
329                         mv = MOVE_NORMAL;
330                         break;
331                 case WEP_RIFLE.m_id:
332                         ta = trueaim_rifle;
333                         mv = MOVE_NORMAL;
334                         if(zoomscript_caught)
335                         {
336                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
337                                 return EnemyHitCheck();
338                         }
339                         break;
340                 case WEP_DEVASTATOR.m_id: // projectile has a size!
341                         mi = '-3 -3 -3';
342                         ma = '3 3 3';
343                         break;
344                 case WEP_FIREBALL.m_id: // projectile has a size!
345                         mi = '-16 -16 -16';
346                         ma = '16 16 16';
347                         break;
348                 case WEP_SEEKER.m_id: // projectile has a size!
349                         mi = '-2 -2 -2';
350                         ma = '2 2 2';
351                         break;
352                 case WEP_ELECTRO.m_id: // projectile has a size!
353                         mi = '0 0 -3';
354                         ma = '0 0 -3';
355                         break;
356         }
357
358         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
359
360         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
361
362         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
363         trueaimpoint = trace_endpos;
364
365         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
366                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
367
368         if(vecs.x > 0)
369                 vecs.y = -vecs.y;
370         else
371                 vecs = '0 0 0';
372
373         dv = view_right * vecs.y + view_up * vecs.z;
374         w_shotorg = traceorigin + dv;
375
376         // now move the vecs forward as much as requested if possible
377         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
378         w_shotorg = trace_endpos - view_forward * nudge;
379
380         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
381         shottype = EnemyHitCheck();
382         if(shottype != SHOTTYPE_HITWORLD)
383                 return shottype;
384
385 #if 0
386         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
387         // or rather, I know why, but see no fix
388         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
389                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
390                 return SHOTTYPE_HITOBSTRUCTION;
391 #endif
392
393         return SHOTTYPE_HITWORLD;
394 }
395
396 void CSQC_common_hud(void);
397
398 void PostInit(void);
399 void CSQC_Demo_Camera();
400 float HUD_WouldDrawScoreboard();
401 float camera_mode;
402 const float CAMERA_FREE = 1;
403 const float CAMERA_CHASE = 2;
404 float reticle_type;
405 string reticle_image;
406 string NextFrameCommand;
407
408 vector freeze_org, freeze_ang;
409 entity nightvision_noise, nightvision_noise2;
410
411 const float MAX_TIME_DIFF = 5;
412 float pickup_crosshair_time, pickup_crosshair_size;
413 float hitindication_crosshair_size;
414 float use_vortex_chargepool;
415
416 float myhealth, myhealth_prev;
417 float myhealth_flash;
418
419 float old_blurradius, old_bluralpha;
420 float old_sharpen_intensity;
421
422 vector myhealth_gentlergb;
423
424 float contentavgalpha, liquidalpha_prev;
425 vector liquidcolor_prev;
426
427 float eventchase_current_distance;
428 float eventchase_running;
429 bool WantEventchase()
430 {
431         if(autocvar_cl_orthoview)
432                 return false;
433         if(intermission)
434                 return true;
435         if(self.viewloc)
436                 return true;
437         if(spectatee_status >= 0)
438         {
439                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
440                         return true;
441                 if(MUTATOR_CALLHOOK(WantEventchase, self))
442                         return true;
443                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO.m_id)))
444                         return true;
445                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
446                 {
447                         if(autocvar_cl_eventchase_death == 2)
448                         {
449                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
450                                 if(self.velocity == '0 0 0' || eventchase_running)
451                                         return true;
452                         }
453                         else return true;
454                 }
455         }
456         return false;
457 }
458
459 vector damage_blurpostprocess, content_blurpostprocess;
460
461 float unaccounted_damage = 0;
462 void UpdateDamage()
463 {
464         // accumulate damage with each stat update
465         static float damage_total_prev = 0;
466         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
467         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
468         damage_total_prev = damage_total;
469
470         static float damage_dealt_time_prev = 0;
471         float damage_dealt_time = getstatf(STAT_HIT_TIME);
472         if (damage_dealt_time != damage_dealt_time_prev)
473         {
474                 unaccounted_damage += unaccounted_damage_new;
475                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
476         }
477         damage_dealt_time_prev = damage_dealt_time;
478
479         // prevent hitsound when switching spectatee
480         static float spectatee_status_prev = 0;
481         if (spectatee_status != spectatee_status_prev)
482                 unaccounted_damage = 0;
483         spectatee_status_prev = spectatee_status;
484 }
485
486 void UpdateHitsound()
487 {
488         // varying sound pitch
489
490         static float hitsound_time_prev = 0;
491         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
492         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
493         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
494         {
495                 if (autocvar_cl_hitsound && unaccounted_damage)
496                 {
497                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
498                         float a = autocvar_cl_hitsound_max_pitch;
499                         float b = autocvar_cl_hitsound_min_pitch;
500                         float c = autocvar_cl_hitsound_nom_damage;
501                         float x = unaccounted_damage;
502                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
503
504                         // if sound variation is disabled, set pitch_shift to 1
505                         if (autocvar_cl_hitsound == 1)
506                                 pitch_shift = 1;
507
508                         // if pitch shift is reversed, mirror in (max-min)/2 + min
509                         if (autocvar_cl_hitsound == 3)
510                         {
511                                 float mirror_value = (a-b)/2 + b;
512                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
513                         }
514
515                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
516
517                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
518                         // todo: normalize sound pressure levels? seems unnecessary
519
520                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
521                 }
522                 unaccounted_damage = 0;
523                 hitsound_time_prev = time;
524         }
525
526         static float typehit_time_prev = 0;
527         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
528         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
529         {
530                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
531                 typehit_time_prev = typehit_time;
532         }
533 }
534
535 void UpdateCrosshair()
536 {
537         static float rainbow_last_flicker;
538     static vector rainbow_prev_color;
539         entity e = self;
540         float f, i, j;
541         vector v;
542         if(getstati(STAT_FROZEN))
543                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
544         else if (getstatf(STAT_HEALING_ORB)>time)
545                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
546         if(!intermission)
547         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
548         {
549                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
550                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
551         }
552         else if(getstatf(STAT_REVIVE_PROGRESS))
553         {
554                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
555                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
556         }
557
558         if(autocvar_r_letterbox == 0)
559                 if(autocvar_viewsize < 120)
560                         CSQC_common_hud();
561
562         // crosshair goes VERY LAST
563         if(!scoreboard_active && !camera_active && intermission != 2 && 
564                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
565                 !HUD_MinigameMenu_IsOpened() )
566         {
567                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
568                         return;
569
570                 string wcross_style;
571                 float wcross_alpha, wcross_resolution;
572                 wcross_style = autocvar_crosshair;
573                 if (wcross_style == "0")
574                         return;
575                 wcross_resolution = autocvar_crosshair_size;
576                 if (wcross_resolution == 0)
577                         return;
578                 wcross_alpha = autocvar_crosshair_alpha;
579                 if (wcross_alpha == 0)
580                         return;
581
582                 // TrueAim check
583                 float shottype;
584
585                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
586                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
587                 wcross_origin.z = 0;
588                 if(autocvar_crosshair_hittest)
589                 {
590                         vector wcross_oldorigin;
591                         wcross_oldorigin = wcross_origin;
592                         shottype = TrueAimCheck();
593                         if(shottype == SHOTTYPE_HITWORLD)
594                         {
595                                 v = wcross_origin - wcross_oldorigin;
596                                 v.x /= vid_conwidth;
597                                 v.y /= vid_conheight;
598                                 if(vlen(v) > 0.01)
599                                         shottype = SHOTTYPE_HITOBSTRUCTION;
600                         }
601                         if(!autocvar_crosshair_hittest_showimpact)
602                                 wcross_origin = wcross_oldorigin;
603                 }
604                 else
605                         shottype = SHOTTYPE_HITWORLD;
606
607                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
608                 string wcross_name = "";
609                 float wcross_scale, wcross_blur;
610
611                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
612                 {
613                         e = get_weaponinfo(switchingweapon);
614                         if(e)
615                         {
616                                 if(autocvar_crosshair_per_weapon)
617                                 {
618                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
619                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
620                                         //if (wcross_resolution == 0)
621                                                 //return;
622
623                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
624                                         wcross_resolution *= e.w_crosshair_size;
625                                         wcross_name = e.w_crosshair;
626                                 }
627                         }
628                 }
629
630                 if(wcross_name == "")
631                         wcross_name = strcat("gfx/crosshair", wcross_style);
632
633                 // MAIN CROSSHAIR COLOR DECISION
634                 switch(autocvar_crosshair_color_special)
635                 {
636                         case 1: // crosshair_color_per_weapon
637                         {
638                                 if(e)
639                                 {
640                                         wcross_color = e.wpcolor;
641                                         break;
642                                 }
643                                 else { goto normalcolor; }
644                         }
645
646                         case 2: // crosshair_color_by_health
647                         {
648                                 float x = getstati(STAT_HEALTH);
649
650                                 //x = red
651                                 //y = green
652                                 //z = blue
653
654                                 wcross_color.z = 0;
655
656                                 if(x > 200)
657                                 {
658                                         wcross_color.x = 0;
659                                         wcross_color.y = 1;
660                                 }
661                                 else if(x > 150)
662                                 {
663                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
664                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
665                                 }
666                                 else if(x > 100)
667                                 {
668                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
669                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
670                                         wcross_color.z = 1 - (x-100)*0.02;
671                                 }
672                                 else if(x > 50)
673                                 {
674                                         wcross_color.x = 1;
675                                         wcross_color.y = 1;
676                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
677                                 }
678                                 else if(x > 20)
679                                 {
680                                         wcross_color.x = 1;
681                                         wcross_color.y = (x-20)*90/27/100;
682                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
683                                 }
684                                 else
685                                 {
686                                         wcross_color.x = 1;
687                                         wcross_color.y = 0;
688                                 }
689                                 break;
690                         }
691
692                         case 3: // crosshair_color_rainbow
693                         {
694                                 if(time >= rainbow_last_flicker)
695                                 {
696                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
697                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
698                                 }
699                                 wcross_color = rainbow_prev_color;
700                                 break;
701                         }
702                         :normalcolor
703                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
704                 }
705
706                 if(autocvar_crosshair_effect_scalefade)
707                 {
708                         wcross_scale = wcross_resolution;
709                         wcross_resolution = 1;
710                 }
711                 else
712                 {
713                         wcross_scale = 1;
714                 }
715
716                 if(autocvar_crosshair_pickup)
717                 {
718                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
719
720                         if(pickup_crosshair_time < stat_pickup_time)
721                         {
722                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
723                                         pickup_crosshair_size = 1;
724
725                                 pickup_crosshair_time = stat_pickup_time;
726                         }
727
728                         if(pickup_crosshair_size > 0)
729                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
730                         else
731                                 pickup_crosshair_size = 0;
732
733                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
734                 }
735
736                 // todo: make crosshair hit indication dependent on damage dealt
737                 if(autocvar_crosshair_hitindication)
738                 {
739                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
740
741                         if(unaccounted_damage)
742                         {
743                                 hitindication_crosshair_size = 1;
744                         }
745
746                         if(hitindication_crosshair_size > 0)
747                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
748                         else
749                                 hitindication_crosshair_size = 0;
750
751                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
752                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
753                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
754                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
755                 }
756
757                 if(shottype == SHOTTYPE_HITENEMY)
758                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
759                 if(shottype == SHOTTYPE_HITTEAM)
760                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
761
762                 f = fabs(autocvar_crosshair_effect_time);
763                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
764                 {
765                         wcross_changedonetime = time + f;
766                 }
767                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
768                 {
769                         wcross_name_changestarttime = time;
770                         wcross_name_changedonetime = time + f;
771                         if(wcross_name_goal_prev_prev)
772                                 strunzone(wcross_name_goal_prev_prev);
773                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
774                         wcross_name_goal_prev = strzone(wcross_name);
775                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
776                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
777                         wcross_resolution_goal_prev = wcross_resolution;
778                 }
779
780                 wcross_scale_goal_prev = wcross_scale;
781                 wcross_alpha_goal_prev = wcross_alpha;
782                 wcross_color_goal_prev = wcross_color;
783
784                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
785                 {
786                         wcross_blur = 1;
787                         wcross_alpha *= 0.75;
788                 }
789                 else
790                         wcross_blur = 0;
791                 // *_prev is at time-frametime
792                 // * is at wcross_changedonetime+f
793                 // what do we have at time?
794                 if(time < wcross_changedonetime)
795                 {
796                         f = frametime / (wcross_changedonetime - time + frametime);
797                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
798                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
799                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
800                 }
801
802                 wcross_scale_prev = wcross_scale;
803                 wcross_alpha_prev = wcross_alpha;
804                 wcross_color_prev = wcross_color;
805
806                 MUTATOR_CALLHOOK(UpdateCrosshair);
807
808                 wcross_scale *= 1 - autocvar__menu_alpha;
809                 wcross_alpha *= 1 - autocvar__menu_alpha;
810                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
811
812                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
813                 {
814                         // crosshair rings for weapon stats
815                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
816                         {
817                                 // declarations and stats
818                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
819                                 string ring_image = string_null, ring_inner_image = string_null;
820                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
821
822                                 ring_scale = autocvar_crosshair_ring_size;
823
824                                 float weapon_clipload, weapon_clipsize;
825                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
826                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
827
828                                 float ok_ammo_charge, ok_ammo_chargepool;
829                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
830                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
831
832                                 float vortex_charge, vortex_chargepool;
833                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
834                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
835
836                                 float arc_heat = getstatf(STAT_ARC_HEAT);
837
838                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
839                                         vortex_charge_movingavg = vortex_charge;
840
841
842                                 // handle the values
843                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
844                                 {
845                                         if (vortex_chargepool || use_vortex_chargepool) {
846                                                 use_vortex_chargepool = 1;
847                                                 ring_inner_value = vortex_chargepool;
848                                         } else {
849                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
850                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
851                                         }
852
853                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
854                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
855                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
856
857                                         // draw the outer ring to show the current charge of the weapon
858                                         ring_value = vortex_charge;
859                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
860                                         ring_rgb = wcross_color;
861                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
862                                 }
863                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
864                                 {
865                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
866                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
867                                         ring_rgb = wcross_color;
868                                         ring_image = "gfx/crosshair_ring.tga";
869                                 }
870                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
871                                 {
872                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
873                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
874                                         ring_rgb = wcross_color;
875                                         ring_image = "gfx/crosshair_ring.tga";
876                                 }
877                                 else if (ok_ammo_charge)
878                                 {
879                                         ring_value = ok_ammo_chargepool;
880                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
881                                         ring_rgb = wcross_color;
882                                         ring_image = "gfx/crosshair_ring.tga";
883                                 }
884                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
885                                 {
886                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
887                                         ring_scale = autocvar_crosshair_ring_reload_size;
888                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
889                                         ring_rgb = wcross_color;
890
891                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
892                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
893                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
894                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
895                                         else
896                                                 ring_image = "gfx/crosshair_ring.tga";
897                                 }
898                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
899                                 {
900                                         ring_value = arc_heat;
901                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
902                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
903                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
904                                         ring_image = "gfx/crosshair_ring.tga";
905                                 }
906
907                                 // if in weapon switch animation, fade ring out/in
908                                 if(autocvar_crosshair_effect_time > 0)
909                                 {
910                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
911                                         if (f >= 1)
912                                         {
913                                                 wcross_ring_prev = ((ring_image) ? true : false);
914                                         }
915
916                                         if(wcross_ring_prev)
917                                         {
918                                                 if(f < 1)
919                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
920                                         }
921                                         else
922                                         {
923                                                 if(f < 1)
924                                                         ring_alpha *= bound(0, f, 1);
925                                         }
926                                 }
927
928                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
929                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
930
931                                 if (ring_value)
932                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
933                         }
934
935 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
936                         do \
937                         { \
938                                 if(wcross_blur > 0) \
939                                 { \
940                                         for(i = -2; i <= 2; ++i) \
941                                         for(j = -2; j <= 2; ++j) \
942                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
943                                 } \
944                                 else \
945                                 { \
946                                         M(0,0,sz,wcross_name,wcross_alpha); \
947                                 } \
948                         } \
949                         while(0)
950
951 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
952                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
953
954 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
955                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
956
957                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
958                         {
959                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
960                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
961                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
962                                 f = 1 - f;
963                         }
964                         else
965                         {
966                                 f = 1;
967                         }
968                         wcross_name_alpha_goal_prev = f;
969
970                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
971                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
972
973                         if(autocvar_crosshair_dot)
974                         {
975                                 vector wcross_color_old;
976                                 wcross_color_old = wcross_color;
977
978                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
979                                         wcross_color = stov(autocvar_crosshair_dot_color);
980
981                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
982                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
983                                 wcross_color = wcross_color_old;
984                         }
985                 }
986         }
987         else
988         {
989                 wcross_scale_prev = 0;
990                 wcross_alpha_prev = 0;
991                 wcross_scale_goal_prev = 0;
992                 wcross_alpha_goal_prev = 0;
993                 wcross_changedonetime = 0;
994                 if(wcross_name_goal_prev)
995                         strunzone(wcross_name_goal_prev);
996                 wcross_name_goal_prev = string_null;
997                 if(wcross_name_goal_prev_prev)
998                         strunzone(wcross_name_goal_prev_prev);
999                 wcross_name_goal_prev_prev = string_null;
1000                 wcross_name_changestarttime = 0;
1001                 wcross_name_changedonetime = 0;
1002                 wcross_name_alpha_goal_prev = 0;
1003                 wcross_name_alpha_goal_prev_prev = 0;
1004                 wcross_resolution_goal_prev = 0;
1005                 wcross_resolution_goal_prev_prev = 0;
1006         }
1007 }
1008
1009 bool ov_enabled;
1010 float oldr_nearclip;
1011 float oldr_farclip_base;
1012 float oldr_farclip_world;
1013 float oldr_novis;
1014 float oldr_useportalculling;
1015 float oldr_useinfinitefarclip;
1016
1017 const int BUTTON_3 = 4;
1018 const int BUTTON_4 = 8;
1019 float cl_notice_run();
1020 float prev_myteam;
1021 int lasthud;
1022 float vh_notice_time;
1023 void WaypointSprite_Load();
1024 void CSQC_UpdateView(float w, float h)
1025 {
1026         entity e;
1027         float fov;
1028         float f;
1029         int i;
1030         vector vf_size, vf_min;
1031         float a;
1032
1033         execute_next_frame();
1034
1035         ++framecount;
1036
1037         hud = getstati(STAT_HUD);
1038
1039         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1040                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1041
1042         lasthud = hud;
1043
1044         if(autocvar__hud_showbinds_reload) // menu can set this one
1045         {
1046                 db_close(binddb);
1047                 binddb = db_create();
1048                 cvar_set("_hud_showbinds_reload", "0");
1049         }
1050
1051         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1052                 view_quality = getproperty(VF_MINFPS_QUALITY);
1053         else
1054                 view_quality = 1;
1055
1056         button_attack2 = (input_buttons & BUTTON_3);
1057         button_zoom = (input_buttons & BUTTON_4);
1058
1059         vf_size = getpropertyvec(VF_SIZE);
1060         vf_min = getpropertyvec(VF_MIN);
1061         vid_width = vf_size.x;
1062         vid_height = vf_size.y;
1063
1064         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1065         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1066
1067         WaypointSprite_Load();
1068
1069         CSQCPlayer_SetCamera();
1070
1071         if(player_localentnum <= maxclients) // is it a client?
1072                 current_player = player_localentnum - 1;
1073         else // then player_localentnum is the vehicle I'm driving
1074                 current_player = player_localnum;
1075         myteam = GetPlayerColor(current_player);
1076
1077         if(myteam != prev_myteam)
1078         {
1079                 myteamcolors = colormapPaletteColor(myteam, 1);
1080                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1081                         hud_panel[i].update_time = time;
1082                 prev_myteam = myteam;
1083         }
1084
1085         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1086
1087         float is_dead = (getstati(STAT_HEALTH) <= 0);
1088
1089         // FIXME do we need this hack?
1090         if(isdemo())
1091         {
1092                 // in demos, input_buttons do not work
1093                 button_zoom = (autocvar__togglezoom == "-");
1094         }
1095         else if(button_zoom
1096                 && autocvar_cl_unpress_zoom_on_death
1097                 && (spectatee_status >= 0)
1098                 && (is_dead || intermission))
1099         {
1100                 // no zoom while dead or in intermission please
1101                 localcmd("-zoom\n");
1102                 button_zoom = false;
1103         }
1104
1105         // event chase camera
1106         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1107         {
1108                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1109                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1110                 entity gen = world;
1111
1112                 if(ons_roundlost)
1113                 {
1114                         entity e;
1115                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1116                         {
1117                                 if(e.health <= 0)
1118                                 {
1119                                         gen = e;
1120                                         break;
1121                                 }
1122                         }
1123                         if(!gen)
1124                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1125                 }
1126                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1127                 {
1128                         eventchase_running = true;
1129
1130                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1131                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1132                         if(ons_roundlost) { current_view_origin = gen.origin; }
1133
1134                         // detect maximum viewoffset and use it
1135                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1136                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1137                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1138
1139                         if(view_offset)
1140                         {
1141                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1142                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1143                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1144                         }
1145
1146                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1147                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1148                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1149                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1150
1151                         // make the camera smooth back
1152                         float chase_distance = autocvar_cl_eventchase_distance;
1153                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1154                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1155
1156                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1157                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1158                         else if(eventchase_current_distance != chase_distance)
1159                                 eventchase_current_distance = chase_distance;
1160
1161                         makevectors(view_angles);
1162
1163                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1164                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1165
1166                         // If the boxtrace fails, revert back to line tracing.
1167                         if(!self.viewloc)
1168                         if(trace_startsolid)
1169                         {
1170                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1171                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1172                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1173                         }
1174                         else { setproperty(VF_ORIGIN, trace_endpos); }
1175
1176                         if(!self.viewloc)
1177                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1178                 }
1179                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1180                 {
1181                         eventchase_running = false;
1182                         cvar_set("chase_active", "0");
1183                         eventchase_current_distance = 0; // start from 0 next time
1184                 }
1185         }
1186         // workaround for camera stuck between player's legs when using chase_active 1
1187         // because the engine stops updating the chase_active camera when the game ends
1188         else if(intermission)
1189         {
1190                 cvar_settemp("chase_active", "-1");
1191                 eventchase_current_distance = 0;
1192         }
1193
1194         // do lockview after event chase camera so that it still applies whenever necessary.
1195         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1196         {
1197                 setproperty(VF_ORIGIN, freeze_org);
1198                 setproperty(VF_ANGLES, freeze_ang);
1199         }
1200         else
1201         {
1202                 freeze_org = getpropertyvec(VF_ORIGIN);
1203                 freeze_ang = getpropertyvec(VF_ANGLES);
1204         }
1205
1206         WarpZone_FixView();
1207         //WarpZone_FixPMove();
1208
1209         vector ov_org = '0 0 0';
1210         vector ov_mid = '0 0 0';
1211         vector ov_worldmin = '0 0 0';
1212         vector ov_worldmax = '0 0 0';
1213         if(autocvar_cl_orthoview)
1214         {
1215                 ov_worldmin = mi_picmin;
1216                 ov_worldmax = mi_picmax;
1217
1218                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1219                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1220                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1221
1222                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1223                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1224
1225                 float ov_nearest = vlen(ov_org - vec3(
1226                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1227                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1228                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1229                 ));
1230
1231                 float ov_furthest = 0;
1232                 float dist = 0;
1233
1234                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1235                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1236                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1237                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1238                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1239                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1240                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1241                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1242
1243                 if(!ov_enabled)
1244                 {
1245                         oldr_nearclip = cvar("r_nearclip");
1246                         oldr_farclip_base = cvar("r_farclip_base");
1247                         oldr_farclip_world = cvar("r_farclip_world");
1248                         oldr_novis = cvar("r_novis");
1249                         oldr_useportalculling = cvar("r_useportalculling");
1250                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1251                 }
1252
1253                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1254                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1255                 cvar_settemp("r_farclip_world", "0");
1256                 cvar_settemp("r_novis", "1");
1257                 cvar_settemp("r_useportalculling", "0");
1258                 cvar_settemp("r_useinfinitefarclip", "0");
1259
1260                 setproperty(VF_ORIGIN, ov_org);
1261                 setproperty(VF_ANGLES, '90 0 0');
1262
1263                 ov_enabled = true;
1264
1265                 #if 0
1266                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1267                         vtos(ov_org),
1268                         vtos(getpropertyvec(VF_ANGLES)),
1269                         ov_distance,
1270                         ov_nearest,
1271                         ov_furthest);
1272                 #endif
1273         }
1274         else
1275         {
1276                 if(ov_enabled)
1277                 {
1278                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1279                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1280                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1281                         cvar_set("r_novis", ftos(oldr_novis));
1282                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1283                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1284                 }
1285                 ov_enabled = false;
1286         }
1287
1288         // Render the Scene
1289         view_origin = getpropertyvec(VF_ORIGIN);
1290         view_angles = getpropertyvec(VF_ANGLES);
1291         makevectors(view_angles);
1292         view_forward = v_forward;
1293         view_right = v_right;
1294         view_up = v_up;
1295
1296 #ifdef BLURTEST
1297         if(time > blurtest_time0 && time < blurtest_time1)
1298         {
1299                 float r, t;
1300
1301                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1302                 r = t * blurtest_radius;
1303                 f = 1 / pow(t, blurtest_power) - 1;
1304
1305                 cvar_set("r_glsl_postprocess", "1");
1306                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1307         }
1308         else
1309         {
1310                 cvar_set("r_glsl_postprocess", "0");
1311                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1312         }
1313 #endif
1314
1315         TargetMusic_Advance();
1316         Fog_Force();
1317
1318         if(drawtime == 0)
1319                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1320         else
1321                 drawframetime = bound(0.000001, time - drawtime, 1);
1322         drawtime = time;
1323
1324         // watch for gametype changes here...
1325         // in ParseStuffCMD the cmd isn't executed yet :/
1326         // might even be better to add the gametype to TE_CSQC_INIT...?
1327         if(!postinit)
1328                 PostInit();
1329
1330         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1331         {
1332                 if(calledhooks & HOOK_START)
1333                 {
1334                         localcmd("\ncl_hook_gameend\n");
1335                         calledhooks |= HOOK_END;
1336                 }
1337         }
1338
1339         Announcer();
1340
1341         fov = autocvar_fov;
1342         if(fov <= 59.5)
1343         {
1344                 if(!zoomscript_caught)
1345                 {
1346                         localcmd("+button9\n");
1347                         zoomscript_caught = 1;
1348                 }
1349         }
1350         else
1351         {
1352                 if(zoomscript_caught)
1353                 {
1354                         localcmd("-button9\n");
1355                         zoomscript_caught = 0;
1356                 }
1357         }
1358
1359         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1360
1361         // next WANTED weapon (for HUD)
1362         switchweapon = getstati(STAT_SWITCHWEAPON);
1363
1364         // currently switching-to weapon (for crosshair)
1365         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1366
1367         // actually active weapon (for zoom)
1368         activeweapon = getstati(STAT_ACTIVEWEAPON);
1369
1370         f = (serverflags & SERVERFLAG_TEAMPLAY);
1371         if(f != teamplay)
1372         {
1373                 teamplay = f;
1374                 HUD_InitScores();
1375         }
1376
1377         if(last_switchweapon != switchweapon)
1378         {
1379                 weapontime = time;
1380                 last_switchweapon = switchweapon;
1381                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1382                 {
1383                         localcmd("-zoom\n");
1384                         button_zoom = false;
1385                 }
1386                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1387                 {
1388                         localcmd("-fire\n");
1389                         localcmd("-fire2\n");
1390                         button_attack2 = false;
1391                 }
1392         }
1393         if(last_activeweapon != activeweapon)
1394         {
1395                 last_activeweapon = activeweapon;
1396
1397                 e = get_weaponinfo(activeweapon);
1398                 if(e.netname != "")
1399                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1400                 else
1401                         localcmd("\ncl_hook_activeweapon none\n");
1402         }
1403
1404         // ALWAYS Clear Current Scene First
1405         clearscene();
1406
1407         setproperty(VF_ORIGIN, view_origin);
1408         setproperty(VF_ANGLES, view_angles);
1409
1410         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1411         setproperty(VF_SIZE, vf_size);
1412         setproperty(VF_MIN, vf_min);
1413
1414         // Assign Standard Viewflags
1415         // Draw the World (and sky)
1416         setproperty(VF_DRAWWORLD, 1);
1417
1418         // Set the console size vars
1419         vid_conwidth = autocvar_vid_conwidth;
1420         vid_conheight = autocvar_vid_conheight;
1421         vid_pixelheight = autocvar_vid_pixelheight;
1422
1423         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1424         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1425         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1426
1427         // Camera for demo playback
1428         if(camera_active)
1429         {
1430                 if(autocvar_camera_enable)
1431                         CSQC_Demo_Camera();
1432                 else
1433                 {
1434                         cvar_set("chase_active", ftos(chase_active_backup));
1435                         cvar_set("cl_demo_mousegrab", "0");
1436                         camera_active = false;
1437                 }
1438         }
1439         else
1440         {
1441 #ifdef CAMERATEST
1442                 if(autocvar_camera_enable)
1443 #else
1444                 if(autocvar_camera_enable && isdemo())
1445 #endif
1446                 {
1447                         // Enable required Darkplaces cvars
1448                         chase_active_backup = autocvar_chase_active;
1449                         cvar_set("chase_active", "2");
1450                         cvar_set("cl_demo_mousegrab", "1");
1451                         camera_active = true;
1452                         camera_mode = false;
1453                 }
1454         }
1455
1456         // Draw the Crosshair
1457         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1458
1459         // Draw the Engine Status Bar (the default Quake HUD)
1460         setproperty(VF_DRAWENGINESBAR, 0);
1461
1462         // Update the mouse position
1463         /*
1464            mousepos_x = vid_conwidth;
1465            mousepos_y = vid_conheight;
1466            mousepos = mousepos*0.5 + getmousepos();
1467          */
1468
1469         e = self;
1470         for(self = world; (self = nextent(self)); )
1471                 if(self.draw)
1472                         self.draw();
1473         self = e;
1474
1475         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1476         renderscene();
1477
1478         // now switch to 2D drawing mode by calling a 2D drawing function
1479         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1480         // next R_RenderScene call
1481         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1482
1483         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1484         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1485         {
1486                 // apply night vision effect
1487                 vector tc_00, tc_01, tc_10, tc_11;
1488                 vector rgb = '0 0 0';
1489
1490                 if(!nightvision_noise)
1491                 {
1492                         nightvision_noise = spawn();
1493                         nightvision_noise.classname = "nightvision_noise";
1494                 }
1495                 if(!nightvision_noise2)
1496                 {
1497                         nightvision_noise2 = spawn();
1498                         nightvision_noise2.classname = "nightvision_noise2";
1499                 }
1500
1501                 // color tint in yellow
1502                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1503
1504                 // draw BG
1505                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1506                 rgb = '1 1 1';
1507                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1508                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1509                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1510                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1511                 tc_11 = tc_01 + tc_10 - tc_00;
1512                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1513                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1514                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1515                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1516                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1517                 R_EndPolygon();
1518
1519                 // draw FG
1520                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1521                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1522                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1523                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1524                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1525                 tc_11 = tc_01 + tc_10 - tc_00;
1526                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1527                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1528                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1529                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1530                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1531                 R_EndPolygon();
1532         }
1533
1534         if(autocvar_cl_reticle)
1535         {
1536                 // Draw the aiming reticle for weapons that use it
1537                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1538                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1539                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1540                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1541                 {
1542                         // no zoom reticle while dead
1543                         reticle_type = 0;
1544                 }
1545                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1546                 {
1547                         if(reticle_image != "") { reticle_type = 2; }
1548                         else { reticle_type = 0; }
1549                 }
1550                 else if(button_zoom || zoomscript_caught)
1551                 {
1552                         // normal zoom
1553                         reticle_type = 1;
1554                 }
1555
1556                 if(reticle_type)
1557                 {
1558                         if(autocvar_cl_reticle_stretch)
1559                         {
1560                                 reticle_size.x = vid_conwidth;
1561                                 reticle_size.y = vid_conheight;
1562                                 reticle_pos.x = 0;
1563                                 reticle_pos.y = 0;
1564                         }
1565                         else
1566                         {
1567                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1568                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1569                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1570                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1571                         }
1572
1573                         if(zoomscript_caught)
1574                                 f = 1;
1575                         else
1576                                 f = current_zoomfraction;
1577
1578                         if(f)
1579                         {
1580                                 switch(reticle_type)
1581                                 {
1582                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1583                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1584                                 }
1585                         }
1586                 }
1587         }
1588         else
1589         {
1590                 if(reticle_type != 0) { reticle_type = 0; }
1591         }
1592
1593
1594         // improved polyblend
1595         if(autocvar_hud_contents)
1596         {
1597                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1598                 vector liquidcolor;
1599
1600                 switch(pointcontents(view_origin))
1601                 {
1602                         case CONTENT_WATER:
1603                                 liquidalpha = autocvar_hud_contents_water_alpha;
1604                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1605                                 incontent = 1;
1606                                 break;
1607
1608                         case CONTENT_LAVA:
1609                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1610                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1611                                 incontent = 1;
1612                                 break;
1613
1614                         case CONTENT_SLIME:
1615                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1616                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1617                                 incontent = 1;
1618                                 break;
1619
1620                         default:
1621                                 liquidalpha = 0;
1622                                 liquidcolor = '0 0 0';
1623                                 incontent = 0;
1624                                 break;
1625                 }
1626
1627                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1628                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1629                         contentfadetime = autocvar_hud_contents_fadeintime;
1630                         liquidalpha_prev = liquidalpha;
1631                         liquidcolor_prev = liquidcolor;
1632                 }
1633                 else
1634                         contentfadetime = autocvar_hud_contents_fadeouttime;
1635
1636                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1637                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1638
1639                 if(contentavgalpha)
1640                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1641
1642                 if(autocvar_hud_postprocessing)
1643                 {
1644                         if(autocvar_hud_contents_blur && contentavgalpha)
1645                         {
1646                                 content_blurpostprocess.x = 1;
1647                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1648                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1649                         }
1650                         else
1651                         {
1652                                 content_blurpostprocess.x = 0;
1653                                 content_blurpostprocess.y = 0;
1654                                 content_blurpostprocess.z = 0;
1655                         }
1656                 }
1657         }
1658
1659         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1660         {
1661                 splash_size.x = max(vid_conwidth, vid_conheight);
1662                 splash_size.y = max(vid_conwidth, vid_conheight);
1663                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1664                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1665
1666                 float myhealth_flash_temp;
1667                 myhealth = getstati(STAT_HEALTH);
1668
1669                 // fade out
1670                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1671                 // add new damage
1672                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1673
1674                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1675                 pain_threshold = autocvar_hud_damage_pain_threshold;
1676                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1677                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1678
1679                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1680                 {
1681                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1682                 }
1683
1684                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1685
1686                 if(myhealth_prev < 1)
1687                 {
1688                         if(myhealth >= 1)
1689                         {
1690                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1691                                 myhealth_flash_temp = 0;
1692                         }
1693                         else
1694                         {
1695                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1696                         }
1697                 }
1698
1699                 if(spectatee_status == -1 || intermission)
1700                 {
1701                         myhealth_flash = 0; // observing, or match ended
1702                         myhealth_flash_temp = 0;
1703                 }
1704
1705                 myhealth_prev = myhealth;
1706
1707                 // IDEA: change damage color/picture based on player model for robot/alien species?
1708                 // pro: matches model better
1709                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1710                 // maybe different reddish pics?
1711                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1712                 {
1713                         if(autocvar_cl_gentle_damage == 2)
1714                         {
1715                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1716                                 {
1717                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1718                                 }
1719                         }
1720                         else
1721                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1722
1723                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1724                 }
1725                 else
1726                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1727
1728                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1729                 {
1730                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1731                         {
1732                                 damage_blurpostprocess.x = 1;
1733                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1734                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1735                         }
1736                         else
1737                         {
1738                                 damage_blurpostprocess.x = 0;
1739                                 damage_blurpostprocess.y = 0;
1740                                 damage_blurpostprocess.z = 0;
1741                         }
1742                 }
1743         }
1744
1745         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1746         float e2 = (autocvar_hud_powerup != 0);
1747         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1748         {
1749                 // enable or disable rendering types if they are used or not
1750                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1751                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1752
1753                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1754                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1755                 {
1756                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1757                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1758                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1759                         {
1760                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1761                                 old_blurradius = blurradius;
1762                                 old_bluralpha = bluralpha;
1763                         }
1764                 }
1765                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1766                 {
1767                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1768                         old_blurradius = 0;
1769                         old_bluralpha = 0;
1770                 }
1771
1772                 // edge detection postprocess handling done second (used by hud_powerup)
1773                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1774                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1775                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1776
1777                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1778
1779                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1780                 {
1781                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1782                         {
1783                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1784                                 old_sharpen_intensity = sharpen_intensity;
1785                         }
1786                 }
1787                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1788                 {
1789                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1790                         old_sharpen_intensity = 0;
1791                 }
1792
1793                 if(cvar("r_glsl_postprocess") == 0)
1794                         cvar_set("r_glsl_postprocess", "2");
1795         }
1796         else if(cvar("r_glsl_postprocess") == 2)
1797                 cvar_set("r_glsl_postprocess", "0");
1798
1799         if(menu_visible)
1800                 menu_show();
1801
1802         /*if(gametype == MAPINFO_TYPE_CTF)
1803           {
1804           ctf_view();
1805           } else */
1806
1807         // draw 2D entities
1808         e = self;
1809         for(self = world; (self = nextent(self)); )
1810                 if(self.draw2d)
1811                         self.draw2d();
1812         self = e;
1813         Draw_ShowNames_All();
1814
1815         scoreboard_active = HUD_WouldDrawScoreboard();
1816
1817         UpdateDamage();
1818         UpdateCrosshair();
1819         UpdateHitsound();
1820
1821         if(NextFrameCommand)
1822         {
1823                 localcmd("\n", NextFrameCommand, "\n");
1824                 NextFrameCommand = string_null;
1825         }
1826
1827         // we must do this check AFTER a frame was rendered, or it won't work
1828         if(cs_project_is_b0rked == 0)
1829         {
1830                 string w0, h0;
1831                 w0 = ftos(autocvar_vid_conwidth);
1832                 h0 = ftos(autocvar_vid_conheight);
1833                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1834                 //setproperty(VF_FOV, '90 90 0');
1835                 setproperty(VF_ORIGIN, '0 0 0');
1836                 setproperty(VF_ANGLES, '0 0 0');
1837                 setproperty(VF_PERSPECTIVE, 1);
1838                 makevectors('0 0 0');
1839                 vector v1, v2;
1840                 cvar_set("vid_conwidth", "800");
1841                 cvar_set("vid_conheight", "600");
1842                 v1 = cs_project(v_forward);
1843                 cvar_set("vid_conwidth", "640");
1844                 cvar_set("vid_conheight", "480");
1845                 v2 = cs_project(v_forward);
1846                 if(v1 == v2)
1847                         cs_project_is_b0rked = 1;
1848                 else
1849                         cs_project_is_b0rked = -1;
1850                 cvar_set("vid_conwidth", w0);
1851                 cvar_set("vid_conheight", h0);
1852         }
1853
1854         if(autocvar__hud_configure)
1855                 HUD_Panel_Mouse();
1856         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1857                 HUD_Minigame_Mouse();
1858         else if(QuickMenu_IsOpened())
1859                 QuickMenu_Mouse();
1860         else
1861                 HUD_Radar_Mouse();
1862
1863     if(hud && !intermission)
1864     if(hud == HUD_BUMBLEBEE_GUN)
1865         CSQC_BUMBLE_GUN_HUD();
1866     else
1867                 VEH_ACTION(hud, VR_HUD);
1868
1869         cl_notice_run();
1870
1871         // let's reset the view back to normal for the end
1872         setproperty(VF_MIN, '0 0 0');
1873         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1874 }
1875
1876
1877 void CSQC_common_hud(void)
1878 {
1879         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1880                 Accuracy_LoadLevels();
1881
1882         HUD_Main(); // always run these functions for alpha checks
1883         HUD_DrawScoreboard();
1884
1885         // scoreboard/accuracy, map/gametype voting screen
1886         if (scoreboard_active || intermission == 2)
1887                 HUD_Reset();
1888 }
1889
1890
1891 // following vectors must be global to allow seamless switching between camera modes
1892 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1893 void CSQC_Demo_Camera()
1894 {
1895         float speed, attenuation, dimensions;
1896         vector tmp, delta;
1897
1898         if( autocvar_camera_reset || !camera_mode )
1899         {
1900                 camera_offset = '0 0 0';
1901                 current_angles = '0 0 0';
1902                 camera_direction = '0 0 0';
1903                 camera_offset.z += 30;
1904                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1905                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1906                 current_origin = view_origin;
1907                 current_camera_offset  = camera_offset;
1908                 cvar_set("camera_reset", "0");
1909                 camera_mode = CAMERA_CHASE;
1910         }
1911
1912         // Camera angles
1913         if( camera_roll )
1914                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1915
1916         if(autocvar_camera_look_player)
1917         {
1918                 vector dir;
1919                 float n;
1920
1921                 dir = normalize(view_origin - current_position);
1922                 n = mouse_angles.z;
1923                 mouse_angles = vectoangles(dir);
1924                 mouse_angles.x = mouse_angles.x * -1;
1925                 mouse_angles.z = n;
1926         }
1927         else
1928         {
1929                 tmp = getmousepos() * 0.1;
1930                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1931                 {
1932                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1933                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1934                 }
1935         }
1936
1937         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1938         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1939         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1940         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1941
1942         // Fix difference when angles don't have the same sign
1943         delta = '0 0 0';
1944         if(mouse_angles.y < -60 && current_angles.y > 60)
1945                 delta = '0 360 0';
1946         if(mouse_angles.y > 60 && current_angles.y < -60)
1947                 delta = '0 -360 0';
1948
1949         if(autocvar_camera_look_player)
1950                 attenuation = autocvar_camera_look_attenuation;
1951         else
1952                 attenuation = autocvar_camera_speed_attenuation;
1953
1954         attenuation = 1 / max(1, attenuation);
1955         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1956
1957         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1958         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1959         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1960         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1961
1962         // Camera position
1963         tmp = '0 0 0';
1964         dimensions = 0;
1965
1966         if( camera_direction.x )
1967         {
1968                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1969                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1970                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1971                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1972                 ++dimensions;
1973         }
1974
1975         if( camera_direction.y )
1976         {
1977                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1978                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1979                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1980                 ++dimensions;
1981         }
1982
1983         if( camera_direction.z )
1984         {
1985                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1986                 ++dimensions;
1987         }
1988
1989         if(autocvar_camera_free)
1990                 speed = autocvar_camera_speed_free;
1991         else
1992                 speed = autocvar_camera_speed_chase;
1993
1994         if(dimensions)
1995         {
1996                 speed = speed * sqrt(1 / dimensions);
1997                 camera_offset += tmp * speed;
1998         }
1999
2000         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2001
2002         // Camera modes
2003         if( autocvar_camera_free )
2004         {
2005                 if ( camera_mode == CAMERA_CHASE )
2006                 {
2007                         current_camera_offset = current_origin + current_camera_offset;
2008                         camera_offset = current_origin + camera_offset;
2009                 }
2010
2011                 camera_mode = CAMERA_FREE;
2012                 current_position = current_camera_offset;
2013         }
2014         else
2015         {
2016                 if ( camera_mode == CAMERA_FREE )
2017                 {
2018                         current_origin = view_origin;
2019                         camera_offset = camera_offset - current_origin;
2020                         current_camera_offset = current_camera_offset - current_origin;
2021                 }
2022
2023                 camera_mode = CAMERA_CHASE;
2024
2025                 if(autocvar_camera_chase_smoothly)
2026                         current_origin += (view_origin - current_origin) * attenuation;
2027                 else
2028                         current_origin = view_origin;
2029
2030                 current_position = current_origin + current_camera_offset;
2031         }
2032
2033         setproperty(VF_ANGLES, current_angles);
2034         setproperty(VF_ORIGIN, current_position);
2035 }