738aca2cfbccba1fdec36b2bc315a0783f2f6eb8
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "announcer.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "hud/panel/quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include <common/animdecide.qh>
13 #include <common/ent_cs.qh>
14 #include <common/anim.qh>
15 #include <common/constants.qh>
16 #include <common/debug.qh>
17 #include <common/mapinfo.qh>
18 #include <common/gamemodes/all.qh>
19 #include <common/physics/player.qh>
20 #include <common/stats.qh>
21 #include <common/triggers/target/music.qh>
22 #include <common/teams.qh>
23
24 #include <common/vehicles/all.qh>
25 #include <common/weapons/all.qh>
26 #include <common/viewloc.qh>
27 #include <common/minigames/cl_minigames.qh>
28 #include <common/minigames/cl_minigames_hud.qh>
29
30 #include <lib/csqcmodel/cl_player.qh>
31 #include <lib/csqcmodel/cl_model.qh>
32 #include "csqcmodel_hooks.qh"
33
34 #include <lib/warpzone/client.qh>
35 #include <lib/warpzone/common.qh>
36
37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
38
39 float autocvar_cl_viewmodel_scale;
40
41 bool autocvar_cl_bobmodel;
42 float autocvar_cl_bobmodel_speed;
43 float autocvar_cl_bobmodel_side;
44 float autocvar_cl_bobmodel_up;
45
46 float autocvar_cl_followmodel;
47 float autocvar_cl_followmodel_speed = 0.3;
48 float autocvar_cl_followmodel_limit = 135;
49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
50 float autocvar_cl_followmodel_highpass = 0.05;
51 float autocvar_cl_followmodel_lowpass = 0.03;
52 bool autocvar_cl_followmodel_velocity_absolute;
53
54 float autocvar_cl_leanmodel;
55 float autocvar_cl_leanmodel_speed = 0.3;
56 float autocvar_cl_leanmodel_limit = 30;
57 float autocvar_cl_leanmodel_highpass1 = 0.2;
58 float autocvar_cl_leanmodel_highpass = 0.2;
59 float autocvar_cl_leanmodel_lowpass = 0.05;
60
61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
63 { \
64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
65 } MACRO_END
66
67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
68 { \
69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
71 } MACRO_END
72
73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
74 { \
75         float __f = 0; lowpass(value, frac, ref_store, __f); \
76         ret = (value) - __f; \
77 } MACRO_END
78
79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
80 { \
81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
82         ret = (value) - __f; \
83 } MACRO_END
84
85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
86 { \
87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
89 } MACRO_END
90
91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
92 { \
93         highpass(value.x, frac, ref_store.x, ref_out.x); \
94         highpass(value.y, frac, ref_store.y, ref_out.y); \
95 } MACRO_END
96
97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
98 { \
99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
101 } MACRO_END
102
103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
104 { \
105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
108 } MACRO_END
109
110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
111 { \
112         highpass(value.x, frac, ref_store.x, ref_out.x); \
113         highpass(value.y, frac, ref_store.y, ref_out.y); \
114         highpass(value.z, frac, ref_store.z, ref_out.z); \
115 } MACRO_END
116
117 void viewmodel_animate(entity this)
118 {
119         static float prevtime;
120         float frametime = (time - prevtime);
121         prevtime = time;
122
123         if (autocvar_chase_active) return;
124         if (STAT(HEALTH) <= 0) return;
125
126         entity view = CSQCModel_server2csqc(player_localentnum - 1);
127
128         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
129         static bool oldonground;
130         static float hitgroundtime;
131         if (clonground)
132         {
133                 float f = time; // cl.movecmd[0].time
134                 if (!oldonground)
135                         hitgroundtime = f;
136         }
137         oldonground = clonground;
138
139
140         bool teleported = view.csqcmodel_teleported;
141
142         float frac;
143         if(autocvar_cl_followmodel)
144         {
145                 vector gunorg = '0 0 0';
146                 static vector vel_average;
147                 static vector gunorg_prev = '0 0 0';
148                 static vector gunorg_adjustment_highpass;
149                 static vector gunorg_adjustment_lowpass;
150
151                 vector vel;
152                 if(autocvar_cl_followmodel_velocity_absolute)
153                         vel = view.velocity;
154                 else
155                 {
156                         vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
157                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
158                         vel.x = view.velocity * forward;
159                         vel.y = view.velocity * right * -1;
160                         vel.z = view.velocity * up;
161                 }
162
163                 vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
164                 vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
165                 vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
166
167                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
168                 lowpass3(vel, frac, vel_average, gunorg);
169
170                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
171
172                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
173                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
174                 frac = avg_factor(autocvar_cl_followmodel_highpass);
175                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
176                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
177                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
178
179                 if(autocvar_cl_followmodel_velocity_absolute)
180                 {
181                         vector fixed_gunorg;
182                         vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
183                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
184                         fixed_gunorg.x = gunorg * forward;
185                         fixed_gunorg.y = gunorg * right * -1;
186                         fixed_gunorg.z = gunorg * up;
187                         gunorg = fixed_gunorg;
188                 }
189
190                 this.origin += gunorg;
191         }
192
193         if(autocvar_cl_leanmodel)
194         {
195                 vector gunangles = '0 0 0';
196                 static vector gunangles_prev = '0 0 0';
197                 static vector gunangles_highpass = '0 0 0';
198                 static vector gunangles_adjustment_highpass;
199                 static vector gunangles_adjustment_lowpass;
200
201                 if (teleported)
202                         gunangles_prev = view_angles;
203
204                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
205                 gunangles_highpass += gunangles_prev;
206                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
207                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
208                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
209                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
210                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
211                 gunangles_prev = view_angles;
212                 gunangles_highpass -= gunangles_prev;
213
214                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
215                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
216
217                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
218                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
219                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
220                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
221                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
222
223                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
224                 this.angles += gunangles;
225         }
226
227         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
228
229         // vertical view bobbing code
230         // TODO: cl_bob
231
232         // horizontal view bobbing code
233         // TODO: cl_bob2
234
235         // fall bobbing code
236         // causes the view to swing down and back up when touching the ground
237         // TODO: cl_bobfall
238
239         // gun model bobbing code
240         if (autocvar_cl_bobmodel)
241         {
242                 // calculate for swinging gun model
243                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
244                 static float bobmodel_scale = 0;
245                 static float time_ofs = 0; // makes the effect always restart in the same way
246                 if (clonground)
247                 {
248                         if (time - hitgroundtime > 0.05)
249                                 bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
250                 }
251                 else
252                         bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
253                 if(bobmodel_scale && xyspeed)
254                 {
255                         float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
256                         float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
257                         vector gunorg = '0 0 0';
258                         gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
259                         gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
260
261                         this.origin += gunorg;
262                 }
263                 else
264                         time_ofs = time;
265         }
266 }
267
268 .vector viewmodel_origin, viewmodel_angles;
269 .float weapon_nextthink;
270 .float weapon_eta_last;
271 .float weapon_switchdelay;
272
273 void viewmodel_draw(entity this)
274 {
275         if(!activeweapon)
276                 return;
277         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
278         float a = this.alpha;
279         static bool wasinvehicle;
280         bool invehicle = player_localentnum > maxclients;
281         if (invehicle) a = -1;
282         else if (wasinvehicle) a = 1;
283         wasinvehicle = invehicle;
284         Weapon wep = activeweapon;
285         int c = stof(getplayerkeyvalue(current_player, "colors"));
286         vector g = weaponentity_glowmod(wep, c);
287         entity me = CSQCModel_server2csqc(player_localentnum - 1);
288         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
289                 | EF_NODEPTHTEST)
290                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
291         for (entity e = this; e; e = e.weaponchild)
292         {
293                 e.drawmask = mask;
294                 e.alpha = a;
295                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
296                 e.glowmod = g;
297                 e.csqcmodel_effects = fx;
298                 CSQCModel_Effects_Apply(e);
299         }
300         {
301                 static string name_last;
302                 string name = wep.mdl;
303                 bool swap = name != name_last;
304                 // if (swap)
305                 {
306                         name_last = name;
307                         CL_WeaponEntity_SetModel(this, name, swap);
308                         this.viewmodel_origin = this.origin;
309                         this.viewmodel_angles = this.angles;
310                 }
311                 anim_update(this);
312                 if (!this.animstate_override && !this.animstate_looping)
313                         anim_set(this, this.anim_idle, true, false, false);
314         }
315         float f = 0; // 0..1; 0: fully active
316         float rate = STAT(WEAPONRATEFACTOR);
317         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
318         if (eta <= 0) f = this.weapon_eta_last;
319         else switch (this.state)
320         {
321                 case WS_RAISE:
322                 {
323                         f = eta / max(eta, this.weapon_switchdelay);
324                         break;
325                 }
326                 case WS_DROP:
327                 {
328                         f = 1 - eta / max(eta, this.weapon_switchdelay);
329                         break;
330                 }
331                 case WS_CLEAR:
332                 {
333                         f = 1;
334                         break;
335                 }
336         }
337         this.weapon_eta_last = f;
338         this.origin = this.viewmodel_origin;
339         this.angles = this.viewmodel_angles;
340         this.angles_x = (-90 * f * f);
341         viewmodel_animate(this);
342         setorigin(this, this.origin);
343 }
344
345 entity viewmodel;
346 STATIC_INIT(viewmodel) {
347     viewmodel = new(viewmodel);
348 }
349
350 void Porto_Draw(entity this);
351 STATIC_INIT(Porto)
352 {
353         entity e = new_pure(porto);
354         e.draw = Porto_Draw;
355         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
356 }
357
358 const int polyline_length = 16;
359 vector polyline[polyline_length];
360 void Porto_Draw(entity this)
361 {
362         if (activeweapon != WEP_PORTO) return;
363         if (spectatee_status) return;
364         if (WEP_CVAR(porto, secondary)) return;
365         if (intermission == 1) return;
366         if (intermission == 2) return;
367         if (STAT(HEALTH) <= 0) return;
368
369         vector pos = view_origin;
370         vector dir = view_forward;
371         if (angles_held_status)
372         {
373                 makevectors(angles_held);
374                 dir = v_forward;
375         }
376
377         polyline[0] = pos;
378
379         int portal_number = 0, portal1_idx = 1, portal_max = 2;
380         int n = 1 + 2;  // 2 lines == 3 points
381         for (int idx = 0; idx < n && idx < polyline_length - 1; )
382         {
383                 traceline(pos, pos + 65536 * dir, true, this);
384                 dir = reflect(dir, trace_plane_normal);
385                 pos = trace_endpos;
386                 polyline[++idx] = pos;
387                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
388                 {
389                         n += 1;
390                         continue;
391                 }
392                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
393                 {
394                         n = max(2, idx);
395                         break;
396                 }
397                 // check size
398                 {
399                         vector ang = vectoangles2(trace_plane_normal, dir);
400                         ang.x = -ang.x;
401                         makevectors(ang);
402                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
403                         {
404                                 n = max(2, idx);
405                                 break;
406                         }
407                 }
408                 portal_number += 1;
409                 if (portal_number >= portal_max) break;
410                 if (portal_number == 1) portal1_idx = idx;
411         }
412         for (int idx = 0; idx < n - 1; ++idx)
413         {
414                 vector p = polyline[idx], q = polyline[idx + 1];
415                 if (idx == 0) p -= view_up * 16;  // line from player
416                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
417                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
418         }
419 }
420
421 float drawtime;
422 float avgspeed;
423 vector GetCurrentFov(float fov)
424 {
425         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
426         float velocityzoom, curspeed;
427         vector v;
428
429         zoomsensitivity = autocvar_cl_zoomsensitivity;
430         zoomfactor = autocvar_cl_zoomfactor;
431         if(zoomfactor < 1 || zoomfactor > 30)
432                 zoomfactor = 2.5;
433         zoomspeed = autocvar_cl_zoomspeed;
434         if(zoomspeed >= 0)
435         if(zoomspeed < 0.5 || zoomspeed > 16)
436                         zoomspeed = 3.5;
437
438         zoomdir = button_zoom;
439         if(hud == HUD_NORMAL)
440         if(switchweapon == activeweapon)
441         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
442                 zoomdir += button_attack2;
443         if(spectatee_status > 0 || isdemo())
444         {
445                 if(spectatorbutton_zoom)
446                 {
447                         if(zoomdir)
448                                 zoomdir = 0;
449                         else
450                                 zoomdir = 1;
451                 }
452                 // fteqcc failed twice here already, don't optimize this
453         }
454
455         if(zoomdir) { zoomin_effect = 0; }
456
457         if(camera_active)
458         {
459                 current_viewzoom = min(1, current_viewzoom + drawframetime);
460         }
461         else if(autocvar_cl_spawnzoom && zoomin_effect)
462         {
463                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
464
465                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
466                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
467                 if(current_viewzoom == 1) { zoomin_effect = 0; }
468         }
469         else
470         {
471                 if(zoomspeed < 0) // instant zoom
472                 {
473                         if(zoomdir)
474                                 current_viewzoom = 1 / zoomfactor;
475                         else
476                                 current_viewzoom = 1;
477                 }
478                 else
479                 {
480                         if(zoomdir)
481                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
482                         else
483                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
484                 }
485         }
486
487         if(almost_equals(current_viewzoom, 1))
488                 current_zoomfraction = 0;
489         else if(almost_equals(current_viewzoom, 1/zoomfactor))
490                 current_zoomfraction = 1;
491         else
492                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
493
494         if(zoomsensitivity < 1)
495                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
496         else
497                 setsensitivityscale(1);
498
499         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
500         {
501                 if(intermission) { curspeed = 0; }
502                 else
503                 {
504
505                         makevectors(view_angles);
506                         v = pmove_vel;
507                         if(csqcplayer)
508                                 v = csqcplayer.velocity;
509
510                         switch(autocvar_cl_velocityzoom_type)
511                         {
512                                 case 3: curspeed = max(0, v_forward * v); break;
513                                 case 2: curspeed = (v_forward * v); break;
514                                 case 1: default: curspeed = vlen(v); break;
515                         }
516                 }
517
518                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
519                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
520                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
521
522                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
523         }
524         else
525                 velocityzoom = 1;
526
527         float frustumx, frustumy, fovx, fovy;
528         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
529         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
530         fovx = atan2(frustumx, 1) / M_PI * 360.0;
531         fovy = atan2(frustumy, 1) / M_PI * 360.0;
532
533         return '1 0 0' * fovx + '0 1 0' * fovy;
534 }
535
536 vector GetViewLocationFOV(float fov)
537 {
538         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
539         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
540         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
541         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
542         return '1 0 0' * fovx + '0 1 0' * fovy;
543 }
544
545 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
546 {
547         float fovx, fovy;
548         float width = (ov_worldmax.x - ov_worldmin.x);
549         float height = (ov_worldmax.y - ov_worldmin.y);
550         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
551         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
552         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
553         return '1 0 0' * fovx + '0 1 0' * fovy;
554 }
555
556 // this function must match W_SetupShot!
557 float zoomscript_caught;
558
559 vector wcross_origin;
560 float wcross_scale_prev, wcross_alpha_prev;
561 vector wcross_color_prev;
562 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
563 vector wcross_color_goal_prev;
564 float wcross_changedonetime;
565
566 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
567 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
568 float wcross_name_changestarttime, wcross_name_changedonetime;
569 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
570
571 float wcross_ring_prev;
572
573 entity trueaim;
574 entity trueaim_rifle;
575
576 const float SHOTTYPE_HITTEAM = 1;
577 const float SHOTTYPE_HITOBSTRUCTION = 2;
578 const float SHOTTYPE_HITWORLD = 3;
579 const float SHOTTYPE_HITENEMY = 4;
580
581 void TrueAim_Init()
582 {
583         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
584         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
585 }
586
587 float EnemyHitCheck()
588 {
589         float t, n;
590         wcross_origin = project_3d_to_2d(trace_endpos);
591         wcross_origin.z = 0;
592         if(trace_ent)
593                 n = trace_ent.entnum;
594         else
595                 n = trace_networkentity;
596         if(n < 1)
597                 return SHOTTYPE_HITWORLD;
598         if(n > maxclients)
599                 return SHOTTYPE_HITWORLD;
600         t = entcs_GetTeam(n - 1);
601         if(teamplay)
602                 if(t == myteam)
603                         return SHOTTYPE_HITTEAM;
604         if(t == NUM_SPECTATOR)
605                 return SHOTTYPE_HITWORLD;
606         return SHOTTYPE_HITENEMY;
607 }
608
609 float TrueAimCheck()
610 {
611         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
612         vector vecs, trueaimpoint, w_shotorg;
613         vector mi, ma, dv;
614         float shottype;
615         entity ta;
616         float mv;
617
618         mi = ma = '0 0 0';
619         ta = trueaim;
620         mv = MOVE_NOMONSTERS;
621
622         switch(activeweapon) // WEAPONTODO
623         {
624                 case WEP_TUBA: // no aim
625                 case WEP_PORTO: // shoots from eye
626                 case WEP_NEXBALL: // shoots from eye
627                 case WEP_HOOK: // no trueaim
628                 case WEP_MORTAR: // toss curve
629                         return SHOTTYPE_HITWORLD;
630                 case WEP_VORTEX:
631                 case WEP_VAPORIZER:
632                         mv = MOVE_NORMAL;
633                         break;
634                 case WEP_RIFLE:
635                         ta = trueaim_rifle;
636                         mv = MOVE_NORMAL;
637                         if(zoomscript_caught)
638                         {
639                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
640                                 return EnemyHitCheck();
641                         }
642                         break;
643                 case WEP_DEVASTATOR: // projectile has a size!
644                         mi = '-3 -3 -3';
645                         ma = '3 3 3';
646                         break;
647                 case WEP_FIREBALL: // projectile has a size!
648                         mi = '-16 -16 -16';
649                         ma = '16 16 16';
650                         break;
651                 case WEP_SEEKER: // projectile has a size!
652                         mi = '-2 -2 -2';
653                         ma = '2 2 2';
654                         break;
655                 case WEP_ELECTRO: // projectile has a size!
656                         mi = '0 0 -3';
657                         ma = '0 0 -3';
658                         break;
659         }
660
661         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
662
663         vecs = decompressShotOrigin(STAT(SHOTORG));
664
665         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
666         trueaimpoint = trace_endpos;
667
668         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
669                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
670
671         if(vecs.x > 0)
672                 vecs.y = -vecs.y;
673         else
674                 vecs = '0 0 0';
675
676         dv = view_right * vecs.y + view_up * vecs.z;
677         w_shotorg = traceorigin + dv;
678
679         // now move the vecs forward as much as requested if possible
680         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
681         w_shotorg = trace_endpos - view_forward * nudge;
682
683         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
684         shottype = EnemyHitCheck();
685         if(shottype != SHOTTYPE_HITWORLD)
686                 return shottype;
687
688 #if 0
689         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
690         // or rather, I know why, but see no fix
691         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
692                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
693                 return SHOTTYPE_HITOBSTRUCTION;
694 #endif
695
696         return SHOTTYPE_HITWORLD;
697 }
698
699 void PostInit();
700 void CSQC_Demo_Camera();
701 float HUD_WouldDrawScoreboard();
702 float camera_mode;
703 const float CAMERA_FREE = 1;
704 const float CAMERA_CHASE = 2;
705 float reticle_type;
706 string reticle_image;
707 string NextFrameCommand;
708
709 vector freeze_org, freeze_ang;
710 entity nightvision_noise, nightvision_noise2;
711
712 const float MAX_TIME_DIFF = 5;
713 float pickup_crosshair_time, pickup_crosshair_size;
714 float hitindication_crosshair_size;
715 float use_vortex_chargepool;
716
717 float myhealth, myhealth_prev;
718 float myhealth_flash;
719
720 float old_blurradius, old_bluralpha;
721 float old_sharpen_intensity;
722
723 vector myhealth_gentlergb;
724
725 float contentavgalpha, liquidalpha_prev;
726 vector liquidcolor_prev;
727
728 float eventchase_current_distance;
729 float eventchase_running;
730 bool WantEventchase(entity this)
731 {
732         if(autocvar_cl_orthoview)
733                 return false;
734         if(intermission)
735                 return true;
736         if(this.viewloc)
737                 return true;
738         if(spectatee_status >= 0)
739         {
740                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
741                         return true;
742                 if(MUTATOR_CALLHOOK(WantEventchase, this))
743                         return true;
744                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
745                         return true;
746                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
747                 {
748                         if(autocvar_cl_eventchase_death == 2)
749                         {
750                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
751                                 if(this.velocity == '0 0 0' || eventchase_running)
752                                         return true;
753                         }
754                         else return true;
755                 }
756         }
757         return false;
758 }
759
760 void HUD_Crosshair_Vehicle()
761 {
762         if(hud != HUD_BUMBLEBEE_GUN)
763         {
764                 Vehicle info = Vehicles_from(hud);
765                 info.vr_crosshair(info);
766         }
767 }
768
769 vector damage_blurpostprocess, content_blurpostprocess;
770
771 float unaccounted_damage = 0;
772 void UpdateDamage()
773 {
774         // accumulate damage with each stat update
775         static float damage_total_prev = 0;
776         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
777         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
778         damage_total_prev = damage_total;
779
780         static float damage_dealt_time_prev = 0;
781         float damage_dealt_time = STAT(HIT_TIME);
782         if (damage_dealt_time != damage_dealt_time_prev)
783         {
784                 unaccounted_damage += unaccounted_damage_new;
785                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
786         }
787         damage_dealt_time_prev = damage_dealt_time;
788
789         // prevent hitsound when switching spectatee
790         static float spectatee_status_prev = 0;
791         if (spectatee_status != spectatee_status_prev)
792                 unaccounted_damage = 0;
793         spectatee_status_prev = spectatee_status;
794 }
795
796 void HitSound()
797 {
798         // varying sound pitch
799
800         static float hitsound_time_prev = 0;
801         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
802         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
803         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
804         {
805                 if (autocvar_cl_hitsound && unaccounted_damage)
806                 {
807                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
808                         float a = autocvar_cl_hitsound_max_pitch;
809                         float b = autocvar_cl_hitsound_min_pitch;
810                         float c = autocvar_cl_hitsound_nom_damage;
811                         float x = unaccounted_damage;
812                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
813
814                         // if sound variation is disabled, set pitch_shift to 1
815                         if (autocvar_cl_hitsound == 1)
816                                 pitch_shift = 1;
817
818                         // if pitch shift is reversed, mirror in (max-min)/2 + min
819                         if (autocvar_cl_hitsound == 3)
820                         {
821                                 float mirror_value = (a-b)/2 + b;
822                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
823                         }
824
825                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
826
827                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
828                         // todo: normalize sound pressure levels? seems unnecessary
829
830                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
831                 }
832                 unaccounted_damage = 0;
833                 hitsound_time_prev = time;
834         }
835
836         static float typehit_time_prev = 0;
837         float typehit_time = STAT(TYPEHIT_TIME);
838         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
839         {
840                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
841                 typehit_time_prev = typehit_time;
842         }
843 }
844
845 vector crosshair_getcolor(entity this, float health_stat)
846 {
847         static float rainbow_last_flicker;
848         static vector rainbow_prev_color;
849         vector wcross_color = '0 0 0';
850         switch(autocvar_crosshair_color_special)
851         {
852                 case 1: // crosshair_color_per_weapon
853                 {
854                         if(this)
855                         {
856                                 wcross_color = this.wpcolor;
857                                 break;
858                         }
859                         else { goto normalcolor; }
860                 }
861
862                 case 2: // crosshair_color_by_health
863                 {
864                         float x = health_stat;
865
866                         //x = red
867                         //y = green
868                         //z = blue
869
870                         wcross_color.z = 0;
871
872                         if(x > 200)
873                         {
874                                 wcross_color.x = 0;
875                                 wcross_color.y = 1;
876                         }
877                         else if(x > 150)
878                         {
879                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
880                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
881                         }
882                         else if(x > 100)
883                         {
884                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
885                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
886                                 wcross_color.z = 1 - (x-100)*0.02;
887                         }
888                         else if(x > 50)
889                         {
890                                 wcross_color.x = 1;
891                                 wcross_color.y = 1;
892                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
893                         }
894                         else if(x > 20)
895                         {
896                                 wcross_color.x = 1;
897                                 wcross_color.y = (x-20)*90/27/100;
898                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
899                         }
900                         else
901                         {
902                                 wcross_color.x = 1;
903                                 wcross_color.y = 0;
904                         }
905                         break;
906                 }
907
908                 case 3: // crosshair_color_rainbow
909                 {
910                         if(time >= rainbow_last_flicker)
911                         {
912                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
913                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
914                         }
915                         wcross_color = rainbow_prev_color;
916                         break;
917                 }
918 LABEL(normalcolor)
919                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
920         }
921
922         return wcross_color;
923 }
924
925 void HUD_Crosshair()
926 {SELFPARAM();
927         entity e = this;
928         float f, i, j;
929         vector v;
930         if(!scoreboard_active && !camera_active && intermission != 2 &&
931                 spectatee_status != -1 && !csqcplayer.viewloc &&
932                 !HUD_MinigameMenu_IsOpened() )
933         {
934                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
935                         return;
936
937                 if (hud != HUD_NORMAL)
938                 {
939                         HUD_Crosshair_Vehicle();
940                         return;
941                 }
942
943                 string wcross_style;
944                 float wcross_alpha, wcross_resolution;
945                 wcross_style = autocvar_crosshair;
946                 if (wcross_style == "0")
947                         return;
948                 wcross_resolution = autocvar_crosshair_size;
949                 if (wcross_resolution == 0)
950                         return;
951                 wcross_alpha = autocvar_crosshair_alpha;
952                 if (wcross_alpha == 0)
953                         return;
954
955                 // TrueAim check
956                 float shottype;
957
958                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
959                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
960                 wcross_origin.z = 0;
961                 if(autocvar_crosshair_hittest)
962                 {
963                         vector wcross_oldorigin;
964                         wcross_oldorigin = wcross_origin;
965                         shottype = TrueAimCheck();
966                         if(shottype == SHOTTYPE_HITWORLD)
967                         {
968                                 v = wcross_origin - wcross_oldorigin;
969                                 v.x /= vid_conwidth;
970                                 v.y /= vid_conheight;
971                                 if(vlen(v) > 0.01)
972                                         shottype = SHOTTYPE_HITOBSTRUCTION;
973                         }
974                         if(!autocvar_crosshair_hittest_showimpact)
975                                 wcross_origin = wcross_oldorigin;
976                 }
977                 else
978                         shottype = SHOTTYPE_HITWORLD;
979
980                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
981                 string wcross_name = "";
982                 float wcross_scale, wcross_blur;
983
984                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
985                 {
986                         e = switchingweapon;
987                         if(e)
988                         {
989                                 if(autocvar_crosshair_per_weapon)
990                                 {
991                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
992                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
993                                         //if (wcross_resolution == 0)
994                                                 //return;
995
996                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
997                                         wcross_resolution *= e.w_crosshair_size;
998                                         wcross_name = e.w_crosshair;
999                                 }
1000                         }
1001                 }
1002
1003                 if(wcross_name == "")
1004                         wcross_name = strcat("gfx/crosshair", wcross_style);
1005
1006                 // MAIN CROSSHAIR COLOR DECISION
1007                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1008
1009                 if(autocvar_crosshair_effect_scalefade)
1010                 {
1011                         wcross_scale = wcross_resolution;
1012                         wcross_resolution = 1;
1013                 }
1014                 else
1015                 {
1016                         wcross_scale = 1;
1017                 }
1018
1019                 if(autocvar_crosshair_pickup)
1020                 {
1021                         float stat_pickup_time = STAT(LAST_PICKUP);
1022
1023                         if(pickup_crosshair_time < stat_pickup_time)
1024                         {
1025                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1026                                         pickup_crosshair_size = 1;
1027
1028                                 pickup_crosshair_time = stat_pickup_time;
1029                         }
1030
1031                         if(pickup_crosshair_size > 0)
1032                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1033                         else
1034                                 pickup_crosshair_size = 0;
1035
1036                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1037                 }
1038
1039                 // todo: make crosshair hit indication dependent on damage dealt
1040                 if(autocvar_crosshair_hitindication)
1041                 {
1042                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1043
1044                         if(unaccounted_damage)
1045                         {
1046                                 hitindication_crosshair_size = 1;
1047                         }
1048
1049                         if(hitindication_crosshair_size > 0)
1050                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1051                         else
1052                                 hitindication_crosshair_size = 0;
1053
1054                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1055                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1056                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1057                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1058                 }
1059
1060                 if(shottype == SHOTTYPE_HITENEMY)
1061                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1062                 if(shottype == SHOTTYPE_HITTEAM)
1063                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1064
1065                 f = fabs(autocvar_crosshair_effect_time);
1066                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1067                 {
1068                         wcross_changedonetime = time + f;
1069                 }
1070                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1071                 {
1072                         wcross_name_changestarttime = time;
1073                         wcross_name_changedonetime = time + f;
1074                         if(wcross_name_goal_prev_prev)
1075                                 strunzone(wcross_name_goal_prev_prev);
1076                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1077                         wcross_name_goal_prev = strzone(wcross_name);
1078                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1079                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1080                         wcross_resolution_goal_prev = wcross_resolution;
1081                 }
1082
1083                 wcross_scale_goal_prev = wcross_scale;
1084                 wcross_alpha_goal_prev = wcross_alpha;
1085                 wcross_color_goal_prev = wcross_color;
1086
1087                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1088                 {
1089                         wcross_blur = 1;
1090                         wcross_alpha *= 0.75;
1091                 }
1092                 else
1093                         wcross_blur = 0;
1094                 // *_prev is at time-frametime
1095                 // * is at wcross_changedonetime+f
1096                 // what do we have at time?
1097                 if(time < wcross_changedonetime)
1098                 {
1099                         f = frametime / (wcross_changedonetime - time + frametime);
1100                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1101                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1102                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1103                 }
1104
1105                 wcross_scale_prev = wcross_scale;
1106                 wcross_alpha_prev = wcross_alpha;
1107                 wcross_color_prev = wcross_color;
1108
1109                 MUTATOR_CALLHOOK(UpdateCrosshair);
1110
1111                 wcross_scale *= 1 - autocvar__menu_alpha;
1112                 wcross_alpha *= 1 - autocvar__menu_alpha;
1113                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1114
1115                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1116                 {
1117                         // crosshair rings for weapon stats
1118                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1119                         {
1120                                 // declarations and stats
1121                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1122                                 string ring_image = string_null, ring_inner_image = string_null;
1123                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1124
1125                                 ring_scale = autocvar_crosshair_ring_size;
1126
1127                                 float weapon_clipload, weapon_clipsize;
1128                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1129                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1130
1131                                 float ok_ammo_charge, ok_ammo_chargepool;
1132                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1133                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1134
1135                                 float vortex_charge, vortex_chargepool;
1136                                 vortex_charge = STAT(VORTEX_CHARGE);
1137                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1138
1139                                 float arc_heat = STAT(ARC_HEAT);
1140
1141                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1142                                         vortex_charge_movingavg = vortex_charge;
1143
1144
1145                                 // handle the values
1146                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1147                                 {
1148                                         if (vortex_chargepool || use_vortex_chargepool) {
1149                                                 use_vortex_chargepool = 1;
1150                                                 ring_inner_value = vortex_chargepool;
1151                                         } else {
1152                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1153                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1154                                         }
1155
1156                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1157                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1158                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1159
1160                                         // draw the outer ring to show the current charge of the weapon
1161                                         ring_value = vortex_charge;
1162                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1165                                 }
1166                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1167                                 {
1168                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1169                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1170                                         ring_rgb = wcross_color;
1171                                         ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1174                                 {
1175                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1176                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1177                                         ring_rgb = wcross_color;
1178                                         ring_image = "gfx/crosshair_ring.tga";
1179                                 }
1180                                 else if (ok_ammo_charge)
1181                                 {
1182                                         ring_value = ok_ammo_chargepool;
1183                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1184                                         ring_rgb = wcross_color;
1185                                         ring_image = "gfx/crosshair_ring.tga";
1186                                 }
1187                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1188                                 {
1189                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1190                                         ring_scale = autocvar_crosshair_ring_reload_size;
1191                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1192                                         ring_rgb = wcross_color;
1193
1194                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1195                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1196                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1197                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1198                                         else
1199                                                 ring_image = "gfx/crosshair_ring.tga";
1200                                 }
1201                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1202                                 {
1203                                         ring_value = arc_heat;
1204                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1205                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1206                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1207                                         ring_image = "gfx/crosshair_ring.tga";
1208                                 }
1209
1210                                 // if in weapon switch animation, fade ring out/in
1211                                 if(autocvar_crosshair_effect_time > 0)
1212                                 {
1213                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1214                                         if (f >= 1)
1215                                         {
1216                                                 wcross_ring_prev = ((ring_image) ? true : false);
1217                                         }
1218
1219                                         if(wcross_ring_prev)
1220                                         {
1221                                                 if(f < 1)
1222                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1223                                         }
1224                                         else
1225                                         {
1226                                                 if(f < 1)
1227                                                         ring_alpha *= bound(0, f, 1);
1228                                         }
1229                                 }
1230
1231                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1232                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1233
1234                                 if (ring_value)
1235                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1236                         }
1237
1238 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1239                         MACRO_BEGIN { \
1240                                 if(wcross_blur > 0) \
1241                                 { \
1242                                         for(i = -2; i <= 2; ++i) \
1243                                         for(j = -2; j <= 2; ++j) \
1244                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1245                                 } \
1246                                 else \
1247                                 { \
1248                                         M(0,0,sz,wcross_name,wcross_alpha); \
1249                                 } \
1250                         } MACRO_END
1251
1252 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1253                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1254
1255 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1256                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1257
1258                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1259                         {
1260                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1261                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1262                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1263                                 f = 1 - f;
1264                         }
1265                         else
1266                         {
1267                                 f = 1;
1268                         }
1269                         wcross_name_alpha_goal_prev = f;
1270
1271                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1272                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1273
1274                         if(autocvar_crosshair_dot)
1275                         {
1276                                 vector wcross_color_old;
1277                                 wcross_color_old = wcross_color;
1278
1279                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1280                                         wcross_color = stov(autocvar_crosshair_dot_color);
1281
1282                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1283                                 // FIXME why don't we use wcross_alpha here?
1284                                 wcross_color = wcross_color_old;
1285                         }
1286                 }
1287         }
1288         else
1289         {
1290                 wcross_scale_prev = 0;
1291                 wcross_alpha_prev = 0;
1292                 wcross_scale_goal_prev = 0;
1293                 wcross_alpha_goal_prev = 0;
1294                 wcross_changedonetime = 0;
1295                 if(wcross_name_goal_prev)
1296                         strunzone(wcross_name_goal_prev);
1297                 wcross_name_goal_prev = string_null;
1298                 if(wcross_name_goal_prev_prev)
1299                         strunzone(wcross_name_goal_prev_prev);
1300                 wcross_name_goal_prev_prev = string_null;
1301                 wcross_name_changestarttime = 0;
1302                 wcross_name_changedonetime = 0;
1303                 wcross_name_alpha_goal_prev = 0;
1304                 wcross_name_alpha_goal_prev_prev = 0;
1305                 wcross_resolution_goal_prev = 0;
1306                 wcross_resolution_goal_prev_prev = 0;
1307         }
1308 }
1309
1310 void HUD_Draw()
1311 {
1312         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1313         {
1314                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, MUTATOR_ARGV(0, vector), autocvar_hud_colorflash_alpha * MUTATOR_ARGV(0, float), DRAWFLAG_ADDITIVE);
1315         }
1316         else if(STAT(FROZEN))
1317         {
1318                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1319         }
1320         if(!intermission)
1321         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1322         {
1323                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1324                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1325         }
1326         else if(STAT(REVIVE_PROGRESS))
1327         {
1328                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1329                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1330         }
1331
1332         if(autocvar_r_letterbox == 0)
1333                 if(autocvar_viewsize < 120)
1334                 {
1335                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1336                                 Accuracy_LoadLevels();
1337
1338                         HUD_Main();
1339                         HUD_DrawScoreboard();
1340                 }
1341
1342         // crosshair goes VERY LAST
1343         UpdateDamage();
1344         HUD_Crosshair();
1345         HitSound();
1346 }
1347
1348 bool ov_enabled;
1349 float oldr_nearclip;
1350 float oldr_farclip_base;
1351 float oldr_farclip_world;
1352 float oldr_novis;
1353 float oldr_useportalculling;
1354 float oldr_useinfinitefarclip;
1355
1356 void cl_notice_run();
1357 float prev_myteam;
1358 int lasthud;
1359 float vh_notice_time;
1360 void WaypointSprite_Load();
1361 void CSQC_UpdateView(float w, float h)
1362 {SELFPARAM();
1363     TC(int, w); TC(int, h);
1364         entity e;
1365         float fov;
1366         float f;
1367         vector vf_size, vf_min;
1368         float a;
1369
1370         execute_next_frame();
1371
1372         ++framecount;
1373
1374         stats_get();
1375         hud = STAT(HUD);
1376
1377         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1378                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1379
1380         lasthud = hud;
1381
1382         if(autocvar__hud_showbinds_reload) // menu can set this one
1383         {
1384                 db_close(binddb);
1385                 binddb = db_create();
1386                 cvar_set("_hud_showbinds_reload", "0");
1387         }
1388
1389         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1390                 view_quality = getproperty(VF_MINFPS_QUALITY);
1391         else
1392                 view_quality = 1;
1393
1394         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1395         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1396
1397         vf_size = getpropertyvec(VF_SIZE);
1398         vf_min = getpropertyvec(VF_MIN);
1399         vid_width = vf_size.x;
1400         vid_height = vf_size.y;
1401
1402         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1403         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1404
1405         WaypointSprite_Load();
1406
1407         CSQCPlayer_SetCamera();
1408
1409         if(player_localentnum <= maxclients) // is it a client?
1410                 current_player = player_localentnum - 1;
1411         else // then player_localentnum is the vehicle I'm driving
1412                 current_player = player_localnum;
1413         myteam = entcs_GetTeam(current_player);
1414
1415         if(myteam != prev_myteam)
1416         {
1417                 myteamcolors = colormapPaletteColor(myteam, 1);
1418                 FOREACH(hud_panels, true, it.update_time = time);
1419                 prev_myteam = myteam;
1420         }
1421
1422         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1423
1424         float is_dead = (STAT(HEALTH) <= 0);
1425
1426         // FIXME do we need this hack?
1427         if(isdemo())
1428         {
1429                 // in demos, input_buttons do not work
1430                 button_zoom = (autocvar__togglezoom == "-");
1431         }
1432         else if(button_zoom
1433                 && autocvar_cl_unpress_zoom_on_death
1434                 && (spectatee_status >= 0)
1435                 && (is_dead || intermission))
1436         {
1437                 // no zoom while dead or in intermission please
1438                 localcmd("-zoom\n");
1439                 button_zoom = false;
1440         }
1441
1442         // event chase camera
1443         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1444         {
1445                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1446                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1447                 entity gen = world;
1448
1449                 float vehicle_viewdist = 0;
1450                 vector vehicle_viewofs = '0 0 0';
1451
1452                 if(vehicle_chase)
1453                 {
1454                         if(hud != HUD_BUMBLEBEE_GUN)
1455                         {
1456                                 Vehicle info = Vehicles_from(hud);
1457                                 vehicle_viewdist = info.height;
1458                                 vehicle_viewofs = info.view_ofs;
1459                         }
1460                 }
1461
1462                 if(ons_roundlost)
1463                 {
1464                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1465                                 gen = it;
1466                                 break;
1467                         });
1468                         if(!gen)
1469                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1470                 }
1471                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1472                 {
1473                         eventchase_running = true;
1474
1475                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1476                         if(!local_player)
1477                                 local_player = self; // fall back!
1478
1479                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1480                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1481                         if(ons_roundlost) { current_view_origin = gen.origin; }
1482
1483                         // detect maximum viewoffset and use it
1484                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1485                         if(vehicle_chase)
1486                         {
1487                                 if(vehicle_viewofs)
1488                                         view_offset = vehicle_viewofs;
1489                                 else
1490                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1491                         }
1492                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1493
1494                         if(view_offset)
1495                         {
1496                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1497                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1498                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1499                         }
1500
1501                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1502                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1503                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1504                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1505
1506                         // make the camera smooth back
1507                         float chase_distance = autocvar_cl_eventchase_distance;
1508                         if(vehicle_chase)
1509                         {
1510                                 if(vehicle_viewofs)
1511                                         chase_distance = vehicle_viewdist;
1512                                 else
1513                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1514                         }
1515                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1516
1517                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1518                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1519                         else if(eventchase_current_distance != chase_distance)
1520                                 eventchase_current_distance = chase_distance;
1521
1522                         makevectors(view_angles);
1523
1524                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1525                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1526
1527                         // If the boxtrace fails, revert back to line tracing.
1528                         if(!local_player.viewloc)
1529                         if(trace_startsolid)
1530                         {
1531                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1532                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1533                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1534                         }
1535                         else { setproperty(VF_ORIGIN, trace_endpos); }
1536
1537                         if(!local_player.viewloc)
1538                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1539                 }
1540                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1541                 {
1542                         eventchase_running = false;
1543                         cvar_set("chase_active", "0");
1544                         eventchase_current_distance = 0; // start from 0 next time
1545                 }
1546         }
1547         // workaround for camera stuck between player's legs when using chase_active 1
1548         // because the engine stops updating the chase_active camera when the game ends
1549         else if(intermission)
1550         {
1551                 cvar_settemp("chase_active", "-1");
1552                 eventchase_current_distance = 0;
1553         }
1554
1555         // do lockview after event chase camera so that it still applies whenever necessary.
1556         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1557         {
1558                 setproperty(VF_ORIGIN, freeze_org);
1559                 setproperty(VF_ANGLES, freeze_ang);
1560         }
1561         else
1562         {
1563                 freeze_org = getpropertyvec(VF_ORIGIN);
1564                 freeze_ang = getpropertyvec(VF_ANGLES);
1565         }
1566
1567         WarpZone_FixView();
1568         //WarpZone_FixPMove();
1569
1570         vector ov_org = '0 0 0';
1571         vector ov_mid = '0 0 0';
1572         vector ov_worldmin = '0 0 0';
1573         vector ov_worldmax = '0 0 0';
1574         if(autocvar_cl_orthoview)
1575         {
1576                 ov_worldmin = mi_picmin;
1577                 ov_worldmax = mi_picmax;
1578
1579                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1580                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1581                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1582
1583                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1584                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1585
1586                 float ov_nearest = vlen(ov_org - vec3(
1587                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1588                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1589                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1590                 ));
1591
1592                 float ov_furthest = 0;
1593                 float dist = 0;
1594
1595                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1596                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1597                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1598                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1599                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1600                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1601                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1602                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1603
1604                 if(!ov_enabled)
1605                 {
1606                         oldr_nearclip = cvar("r_nearclip");
1607                         oldr_farclip_base = cvar("r_farclip_base");
1608                         oldr_farclip_world = cvar("r_farclip_world");
1609                         oldr_novis = cvar("r_novis");
1610                         oldr_useportalculling = cvar("r_useportalculling");
1611                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1612                 }
1613
1614                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1615                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1616                 cvar_settemp("r_farclip_world", "0");
1617                 cvar_settemp("r_novis", "1");
1618                 cvar_settemp("r_useportalculling", "0");
1619                 cvar_settemp("r_useinfinitefarclip", "0");
1620
1621                 setproperty(VF_ORIGIN, ov_org);
1622                 setproperty(VF_ANGLES, '90 0 0');
1623
1624                 ov_enabled = true;
1625
1626                 #if 0
1627                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1628                         vtos(ov_org),
1629                         vtos(getpropertyvec(VF_ANGLES)),
1630                         ov_distance,
1631                         ov_nearest,
1632                         ov_furthest);
1633                 #endif
1634         }
1635         else
1636         {
1637                 if(ov_enabled)
1638                 {
1639                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1640                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1641                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1642                         cvar_set("r_novis", ftos(oldr_novis));
1643                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1644                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1645                 }
1646                 ov_enabled = false;
1647         }
1648
1649         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1650         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1651         viewmodel_draw(viewmodel);
1652
1653         // Render the Scene
1654         view_origin = getpropertyvec(VF_ORIGIN);
1655         view_angles = getpropertyvec(VF_ANGLES);
1656         makevectors(view_angles);
1657         view_forward = v_forward;
1658         view_right = v_right;
1659         view_up = v_up;
1660
1661 #ifdef BLURTEST
1662         if(time > blurtest_time0 && time < blurtest_time1)
1663         {
1664                 float r, t;
1665
1666                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1667                 r = t * blurtest_radius;
1668                 f = 1 / pow(t, blurtest_power) - 1;
1669
1670                 cvar_set("r_glsl_postprocess", "1");
1671                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1672         }
1673         else
1674         {
1675                 cvar_set("r_glsl_postprocess", "0");
1676                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1677         }
1678 #endif
1679
1680         TargetMusic_Advance();
1681         Fog_Force();
1682
1683         if(drawtime == 0)
1684                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1685         else
1686                 drawframetime = bound(0.000001, time - drawtime, 1);
1687         drawtime = time;
1688
1689         // watch for gametype changes here...
1690         // in ParseStuffCMD the cmd isn't executed yet :/
1691         // might even be better to add the gametype to TE_CSQC_INIT...?
1692         if(!postinit)
1693                 PostInit();
1694
1695         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1696         {
1697                 if(calledhooks & HOOK_START)
1698                 {
1699                         localcmd("\ncl_hook_gameend\n");
1700                         calledhooks |= HOOK_END;
1701                 }
1702         }
1703
1704         Announcer();
1705
1706         fov = autocvar_fov;
1707         if(fov <= 59.5)
1708         {
1709                 if(!zoomscript_caught)
1710                 {
1711                         localcmd("+button9\n");
1712                         zoomscript_caught = 1;
1713                 }
1714         }
1715         else
1716         {
1717                 if(zoomscript_caught)
1718                 {
1719                         localcmd("-button9\n");
1720                         zoomscript_caught = 0;
1721                 }
1722         }
1723
1724         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1725
1726         // currently switching-to weapon (for crosshair)
1727         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1728
1729         // actually active weapon (for zoom)
1730         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1731
1732         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1733
1734         f = (serverflags & SERVERFLAG_TEAMPLAY);
1735         if(f != teamplay)
1736         {
1737                 teamplay = f;
1738                 HUD_InitScores();
1739         }
1740
1741         if(last_switchweapon != switchweapon)
1742         {
1743                 weapontime = time;
1744                 last_switchweapon = switchweapon;
1745                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1746                 {
1747                         localcmd("-zoom\n");
1748                         button_zoom = false;
1749                 }
1750                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1751                 {
1752                         localcmd("-fire\n");
1753                         localcmd("-fire2\n");
1754                         button_attack2 = false;
1755                 }
1756         }
1757         if(last_activeweapon != activeweapon)
1758         {
1759                 last_activeweapon = activeweapon;
1760
1761                 e = activeweapon;
1762                 if(e.netname != "")
1763                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1764                 else
1765                         localcmd("\ncl_hook_activeweapon none\n");
1766         }
1767
1768         // ALWAYS Clear Current Scene First
1769         clearscene();
1770
1771         setproperty(VF_ORIGIN, view_origin);
1772         setproperty(VF_ANGLES, view_angles);
1773
1774         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1775         setproperty(VF_SIZE, vf_size);
1776         setproperty(VF_MIN, vf_min);
1777
1778         // Assign Standard Viewflags
1779         // Draw the World (and sky)
1780         setproperty(VF_DRAWWORLD, 1);
1781
1782         // Set the console size vars
1783         vid_conwidth = autocvar_vid_conwidth;
1784         vid_conheight = autocvar_vid_conheight;
1785         vid_pixelheight = autocvar_vid_pixelheight;
1786
1787         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1788         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1789         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1790
1791         // Camera for demo playback
1792         if(camera_active)
1793         {
1794                 if(autocvar_camera_enable)
1795                         CSQC_Demo_Camera();
1796                 else
1797                 {
1798                         cvar_set("chase_active", ftos(chase_active_backup));
1799                         cvar_set("cl_demo_mousegrab", "0");
1800                         camera_active = false;
1801                 }
1802         }
1803         else
1804         {
1805 #ifdef CAMERATEST
1806                 if(autocvar_camera_enable)
1807 #else
1808                 if(autocvar_camera_enable && isdemo())
1809 #endif
1810                 {
1811                         // Enable required Darkplaces cvars
1812                         chase_active_backup = autocvar_chase_active;
1813                         cvar_set("chase_active", "2");
1814                         cvar_set("cl_demo_mousegrab", "1");
1815                         camera_active = true;
1816                         camera_mode = false;
1817                 }
1818         }
1819
1820         // Draw the Crosshair
1821         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1822
1823         // Draw the Engine Status Bar (the default Quake HUD)
1824         setproperty(VF_DRAWENGINESBAR, 0);
1825
1826         // Update the mouse position
1827         /*
1828            mousepos_x = vid_conwidth;
1829            mousepos_y = vid_conheight;
1830            mousepos = mousepos*0.5 + getmousepos();
1831          */
1832
1833         FOREACH_ENTITY(it.draw, it.draw(it));
1834
1835         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1836         renderscene();
1837
1838         // now switch to 2D drawing mode by calling a 2D drawing function
1839         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1840         // next R_RenderScene call
1841         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1842
1843         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1844         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1845         {
1846                 // apply night vision effect
1847                 vector tc_00, tc_01, tc_10, tc_11;
1848                 vector rgb = '0 0 0';
1849
1850                 if(!nightvision_noise)
1851                 {
1852                         nightvision_noise = new(nightvision_noise);
1853                 }
1854                 if(!nightvision_noise2)
1855                 {
1856                         nightvision_noise2 = new(nightvision_noise2);
1857                 }
1858
1859                 // color tint in yellow
1860                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1861
1862                 // draw BG
1863                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1864                 rgb = '1 1 1';
1865                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1866                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1867                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1868                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1869                 tc_11 = tc_01 + tc_10 - tc_00;
1870                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1871                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1872                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1873                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1874                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1875                 R_EndPolygon();
1876
1877                 // draw FG
1878                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1879                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1880                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1881                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1882                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1883                 tc_11 = tc_01 + tc_10 - tc_00;
1884                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1885                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1886                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1887                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1888                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1889                 R_EndPolygon();
1890         }
1891
1892         if(autocvar_cl_reticle)
1893         {
1894                 Weapon wep = activeweapon;
1895                 // Draw the aiming reticle for weapons that use it
1896                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1897                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1898                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1899                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1900                 {
1901                         // no zoom reticle while dead
1902                         reticle_type = 0;
1903                 }
1904                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1905                 {
1906                         if(reticle_image != "") { reticle_type = 2; }
1907                         else { reticle_type = 0; }
1908                 }
1909                 else if(button_zoom || zoomscript_caught)
1910                 {
1911                         // normal zoom
1912                         reticle_type = 1;
1913                 }
1914
1915                 if(reticle_type)
1916                 {
1917                         if(autocvar_cl_reticle_stretch)
1918                         {
1919                                 reticle_size.x = vid_conwidth;
1920                                 reticle_size.y = vid_conheight;
1921                                 reticle_pos.x = 0;
1922                                 reticle_pos.y = 0;
1923                         }
1924                         else
1925                         {
1926                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1927                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1928                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1929                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1930                         }
1931
1932                         if(zoomscript_caught)
1933                                 f = 1;
1934                         else
1935                                 f = current_zoomfraction;
1936
1937                         if(f)
1938                         {
1939                                 switch(reticle_type)
1940                                 {
1941                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1942                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1943                                 }
1944                         }
1945                 }
1946         }
1947         else
1948         {
1949                 if(reticle_type != 0) { reticle_type = 0; }
1950         }
1951
1952
1953         // improved polyblend
1954         if(autocvar_hud_contents)
1955         {
1956                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1957                 vector liquidcolor;
1958
1959                 switch(pointcontents(view_origin))
1960                 {
1961                         case CONTENT_WATER:
1962                                 liquidalpha = autocvar_hud_contents_water_alpha;
1963                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1964                                 incontent = 1;
1965                                 break;
1966
1967                         case CONTENT_LAVA:
1968                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1969                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1970                                 incontent = 1;
1971                                 break;
1972
1973                         case CONTENT_SLIME:
1974                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1975                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1976                                 incontent = 1;
1977                                 break;
1978
1979                         default:
1980                                 liquidalpha = 0;
1981                                 liquidcolor = '0 0 0';
1982                                 incontent = 0;
1983                                 break;
1984                 }
1985
1986                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1987                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1988                         contentfadetime = autocvar_hud_contents_fadeintime;
1989                         liquidalpha_prev = liquidalpha;
1990                         liquidcolor_prev = liquidcolor;
1991                 }
1992                 else
1993                         contentfadetime = autocvar_hud_contents_fadeouttime;
1994
1995                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1996                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1997
1998                 if(contentavgalpha)
1999                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2000
2001                 if(autocvar_hud_postprocessing)
2002                 {
2003                         if(autocvar_hud_contents_blur && contentavgalpha)
2004                         {
2005                                 content_blurpostprocess.x = 1;
2006                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2007                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2008                         }
2009                         else
2010                         {
2011                                 content_blurpostprocess.x = 0;
2012                                 content_blurpostprocess.y = 0;
2013                                 content_blurpostprocess.z = 0;
2014                         }
2015                 }
2016         }
2017
2018         if(autocvar_hud_damage && !STAT(FROZEN))
2019         {
2020                 splash_size.x = max(vid_conwidth, vid_conheight);
2021                 splash_size.y = max(vid_conwidth, vid_conheight);
2022                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2023                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2024
2025                 float myhealth_flash_temp;
2026                 myhealth = STAT(HEALTH);
2027
2028                 // fade out
2029                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2030                 // add new damage
2031                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2032
2033                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2034                 pain_threshold = autocvar_hud_damage_pain_threshold;
2035                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2036                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2037
2038                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2039                 {
2040                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2041                 }
2042
2043                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2044
2045                 if(myhealth_prev < 1)
2046                 {
2047                         if(myhealth >= 1)
2048                         {
2049                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2050                                 myhealth_flash_temp = 0;
2051                         }
2052                         else
2053                         {
2054                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2055                         }
2056                 }
2057
2058                 if(spectatee_status == -1 || intermission)
2059                 {
2060                         myhealth_flash = 0; // observing, or match ended
2061                         myhealth_flash_temp = 0;
2062                 }
2063
2064                 myhealth_prev = myhealth;
2065
2066                 // IDEA: change damage color/picture based on player model for robot/alien species?
2067                 // pro: matches model better
2068                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2069                 // maybe different reddish pics?
2070                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2071                 {
2072                         if(autocvar_cl_gentle_damage == 2)
2073                         {
2074                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2075                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2076                         }
2077                         else
2078                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2079
2080                         if(myhealth_flash_temp > 0)
2081                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2082                 }
2083                 else if(myhealth_flash_temp > 0)
2084                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2085
2086                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2087                 {
2088                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2089                         {
2090                                 damage_blurpostprocess.x = 1;
2091                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2092                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2093                         }
2094                         else
2095                         {
2096                                 damage_blurpostprocess.x = 0;
2097                                 damage_blurpostprocess.y = 0;
2098                                 damage_blurpostprocess.z = 0;
2099                         }
2100                 }
2101         }
2102
2103         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2104         float e2 = (autocvar_hud_powerup != 0);
2105         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2106         {
2107                 // enable or disable rendering types if they are used or not
2108                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2109                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2110
2111                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2112                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2113                 {
2114                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2115                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2116                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2117                         {
2118                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2119                                 old_blurradius = blurradius;
2120                                 old_bluralpha = bluralpha;
2121                         }
2122                 }
2123                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2124                 {
2125                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2126                         old_blurradius = 0;
2127                         old_bluralpha = 0;
2128                 }
2129
2130                 // edge detection postprocess handling done second (used by hud_powerup)
2131                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2132                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2133                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2134
2135                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2136
2137                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2138                 {
2139                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2140                         {
2141                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2142                                 old_sharpen_intensity = sharpen_intensity;
2143                         }
2144                 }
2145                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2146                 {
2147                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2148                         old_sharpen_intensity = 0;
2149                 }
2150
2151                 if(cvar("r_glsl_postprocess") == 0)
2152                         cvar_set("r_glsl_postprocess", "2");
2153         }
2154         else if(cvar("r_glsl_postprocess") == 2)
2155                 cvar_set("r_glsl_postprocess", "0");
2156
2157         /*if(gametype == MAPINFO_TYPE_CTF)
2158           {
2159           ctf_view();
2160           } else */
2161
2162         // draw 2D entities
2163         FOREACH_ENTITY(it.draw2d, it.draw2d(it));
2164         Draw_ShowNames_All();
2165         Debug_Draw();
2166
2167         scoreboard_active = HUD_WouldDrawScoreboard();
2168
2169         HUD_Draw();
2170
2171         if(NextFrameCommand)
2172         {
2173                 localcmd("\n", NextFrameCommand, "\n");
2174                 NextFrameCommand = string_null;
2175         }
2176
2177         // we must do this check AFTER a frame was rendered, or it won't work
2178         if(cs_project_is_b0rked == 0)
2179         {
2180                 string w0, h0;
2181                 w0 = ftos(autocvar_vid_conwidth);
2182                 h0 = ftos(autocvar_vid_conheight);
2183                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2184                 //setproperty(VF_FOV, '90 90 0');
2185                 setproperty(VF_ORIGIN, '0 0 0');
2186                 setproperty(VF_ANGLES, '0 0 0');
2187                 setproperty(VF_PERSPECTIVE, 1);
2188                 makevectors('0 0 0');
2189                 vector v1, v2;
2190                 cvar_set("vid_conwidth", "800");
2191                 cvar_set("vid_conheight", "600");
2192                 v1 = cs_project(v_forward);
2193                 cvar_set("vid_conwidth", "640");
2194                 cvar_set("vid_conheight", "480");
2195                 v2 = cs_project(v_forward);
2196                 if(v1 == v2)
2197                         cs_project_is_b0rked = 1;
2198                 else
2199                         cs_project_is_b0rked = -1;
2200                 cvar_set("vid_conwidth", w0);
2201                 cvar_set("vid_conheight", h0);
2202         }
2203
2204         if(autocvar__hud_configure)
2205                 HUD_Panel_Mouse();
2206         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2207                 HUD_Minigame_Mouse();
2208         else if(QuickMenu_IsOpened())
2209                 QuickMenu_Mouse();
2210         else
2211                 HUD_Radar_Mouse();
2212
2213         cl_notice_run();
2214         unpause_update();
2215         Net_Flush();
2216
2217         // let's reset the view back to normal for the end
2218         setproperty(VF_MIN, '0 0 0');
2219         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2220 }
2221
2222
2223 // following vectors must be global to allow seamless switching between camera modes
2224 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2225 void CSQC_Demo_Camera()
2226 {
2227         float speed, attenuation, dimensions;
2228         vector tmp, delta;
2229
2230         if( autocvar_camera_reset || !camera_mode )
2231         {
2232                 camera_offset = '0 0 0';
2233                 current_angles = '0 0 0';
2234                 camera_direction = '0 0 0';
2235                 camera_offset.z += 30;
2236                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2237                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2238                 current_origin = view_origin;
2239                 current_camera_offset  = camera_offset;
2240                 cvar_set("camera_reset", "0");
2241                 camera_mode = CAMERA_CHASE;
2242         }
2243
2244         // Camera angles
2245         if( camera_roll )
2246                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2247
2248         if(autocvar_camera_look_player)
2249         {
2250                 vector dir;
2251                 float n;
2252
2253                 dir = normalize(view_origin - current_position);
2254                 n = mouse_angles.z;
2255                 mouse_angles = vectoangles(dir);
2256                 mouse_angles.x = mouse_angles.x * -1;
2257                 mouse_angles.z = n;
2258         }
2259         else
2260         {
2261                 tmp = getmousepos() * 0.1;
2262                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2263                 {
2264                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2265                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2266                 }
2267         }
2268
2269         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2270         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2271         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2272         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2273
2274         // Fix difference when angles don't have the same sign
2275         delta = '0 0 0';
2276         if(mouse_angles.y < -60 && current_angles.y > 60)
2277                 delta = '0 360 0';
2278         if(mouse_angles.y > 60 && current_angles.y < -60)
2279                 delta = '0 -360 0';
2280
2281         if(autocvar_camera_look_player)
2282                 attenuation = autocvar_camera_look_attenuation;
2283         else
2284                 attenuation = autocvar_camera_speed_attenuation;
2285
2286         attenuation = 1 / max(1, attenuation);
2287         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2288
2289         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2290         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2291         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2292         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2293
2294         // Camera position
2295         tmp = '0 0 0';
2296         dimensions = 0;
2297
2298         if( camera_direction.x )
2299         {
2300                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2301                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2302                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2303                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2304                 ++dimensions;
2305         }
2306
2307         if( camera_direction.y )
2308         {
2309                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2310                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2311                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2312                 ++dimensions;
2313         }
2314
2315         if( camera_direction.z )
2316         {
2317                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2318                 ++dimensions;
2319         }
2320
2321         if(autocvar_camera_free)
2322                 speed = autocvar_camera_speed_free;
2323         else
2324                 speed = autocvar_camera_speed_chase;
2325
2326         if(dimensions)
2327         {
2328                 speed = speed * sqrt(1 / dimensions);
2329                 camera_offset += tmp * speed;
2330         }
2331
2332         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2333
2334         // Camera modes
2335         if( autocvar_camera_free )
2336         {
2337                 if ( camera_mode == CAMERA_CHASE )
2338                 {
2339                         current_camera_offset = current_origin + current_camera_offset;
2340                         camera_offset = current_origin + camera_offset;
2341                 }
2342
2343                 camera_mode = CAMERA_FREE;
2344                 current_position = current_camera_offset;
2345         }
2346         else
2347         {
2348                 if ( camera_mode == CAMERA_FREE )
2349                 {
2350                         current_origin = view_origin;
2351                         camera_offset = camera_offset - current_origin;
2352                         current_camera_offset = current_camera_offset - current_origin;
2353                 }
2354
2355                 camera_mode = CAMERA_CHASE;
2356
2357                 if(autocvar_camera_chase_smoothly)
2358                         current_origin += (view_origin - current_origin) * attenuation;
2359                 else
2360                         current_origin = view_origin;
2361
2362                 current_position = current_origin + current_camera_offset;
2363         }
2364
2365         setproperty(VF_ANGLES, current_angles);
2366         setproperty(VF_ORIGIN, current_position);
2367 }