7808ebce29026c16ad0806988fadc6170e9133e7
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "autocvars.qh"
4 #include "miscfunctions.qh"
5 #include "announcer.qh"
6 #include "hud/_mod.qh"
7 #include "mapvoting.qh"
8 #include "shownames.qh"
9 #include "hud/panel/scoreboard.qh"
10 #include "hud/panel/quickmenu.qh"
11
12 #include "mutators/events.qh"
13
14 #include <common/animdecide.qh>
15 #include <common/deathtypes/all.qh>
16 #include <common/ent_cs.qh>
17 #include <common/anim.qh>
18 #include <common/constants.qh>
19 #include <common/net_linked.qh>
20 #include <common/debug.qh>
21 #include <common/mapinfo.qh>
22 #include <common/gamemodes/_mod.qh>
23 #include <common/physics/player.qh>
24 #include <common/stats.qh>
25 #include <common/triggers/target/music.qh>
26 #include <common/teams.qh>
27 #include <common/wepent.qh>
28
29 #include <common/weapons/weapon/tuba.qh>
30
31 #include <common/vehicles/all.qh>
32 #include <common/weapons/_all.qh>
33 #include <common/mutators/mutator/overkill/okvortex.qh>
34 #include <common/viewloc.qh>
35 #include <common/triggers/trigger/viewloc.qh>
36 #include <common/minigames/cl_minigames.qh>
37 #include <common/minigames/cl_minigames_hud.qh>
38
39 #include <lib/csqcmodel/cl_player.qh>
40 #include <lib/csqcmodel/cl_model.qh>
41 #include "csqcmodel_hooks.qh"
42
43 #include <lib/warpzone/client.qh>
44 #include <lib/warpzone/common.qh>
45
46 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
47
48 float autocvar_cl_viewmodel_scale;
49
50 bool autocvar_cl_bobmodel;
51 float autocvar_cl_bobmodel_speed;
52 float autocvar_cl_bobmodel_side;
53 float autocvar_cl_bobmodel_up;
54
55 float autocvar_cl_followmodel;
56 float autocvar_cl_followmodel_speed = 0.3;
57 float autocvar_cl_followmodel_limit = 135;
58 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
59 float autocvar_cl_followmodel_highpass = 0.05;
60 float autocvar_cl_followmodel_lowpass = 0.03;
61 bool autocvar_cl_followmodel_velocity_absolute;
62
63 float autocvar_cl_leanmodel;
64 float autocvar_cl_leanmodel_speed = 0.3;
65 float autocvar_cl_leanmodel_limit = 30;
66 float autocvar_cl_leanmodel_highpass1 = 0.2;
67 float autocvar_cl_leanmodel_highpass = 0.2;
68 float autocvar_cl_leanmodel_lowpass = 0.05;
69
70 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
71
72 #define lowpass(value, frac, ref_store, ret) \
73         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
74
75 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
76 { \
77         float __ignore; lowpass(value, frac, ref_store, __ignore); \
78         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
79 } MACRO_END
80
81 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
82 { \
83         float __f = 0; lowpass(value, frac, ref_store, __f); \
84         ret = (value) - __f; \
85 } MACRO_END
86
87 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
88 { \
89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
90         ret = (value) - __f; \
91 } MACRO_END
92
93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
94 { \
95         lowpass(value.x, frac, ref_store.x, ref_out.x); \
96         lowpass(value.y, frac, ref_store.y, ref_out.y); \
97 } MACRO_END
98
99 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
100 { \
101         highpass(value.x, frac, ref_store.x, ref_out.x); \
102         highpass(value.y, frac, ref_store.y, ref_out.y); \
103 } MACRO_END
104
105 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
106 { \
107         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
108         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
109 } MACRO_END
110
111 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
112 { \
113         lowpass(value.x, frac, ref_store.x, ref_out.x); \
114         lowpass(value.y, frac, ref_store.y, ref_out.y); \
115         lowpass(value.z, frac, ref_store.z, ref_out.z); \
116 } MACRO_END
117
118 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
119 { \
120         highpass(value.x, frac, ref_store.x, ref_out.x); \
121         highpass(value.y, frac, ref_store.y, ref_out.y); \
122         highpass(value.z, frac, ref_store.z, ref_out.z); \
123 } MACRO_END
124
125 void calc_followmodel_ofs(entity view)
126 {
127         if(cl_followmodel_time == time)
128                 return; // cl_followmodel_ofs already calculated for this frame
129
130         float frac;
131         vector gunorg = '0 0 0';
132         static vector vel_average;
133         static vector gunorg_adjustment_highpass;
134         static vector gunorg_adjustment_lowpass;
135
136         vector vel;
137         if (autocvar_cl_followmodel_velocity_absolute)
138                 vel = view.velocity;
139         else
140         {
141                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
142                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
143                 vel.x = view.velocity * forward;
144                 vel.y = view.velocity * right * -1;
145                 vel.z = view.velocity * up;
146         }
147
148         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
149         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
150         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
151
152         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
153         lowpass3(vel, frac, vel_average, gunorg);
154
155         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
156
157         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
158         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
159         frac = avg_factor(autocvar_cl_followmodel_highpass);
160         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
161         frac = avg_factor(autocvar_cl_followmodel_lowpass);
162         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
163
164         if (autocvar_cl_followmodel_velocity_absolute)
165         {
166                 vector fixed_gunorg;
167                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
168                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
169                 fixed_gunorg.x = gunorg * forward;
170                 fixed_gunorg.y = gunorg * right * -1;
171                 fixed_gunorg.z = gunorg * up;
172                 gunorg = fixed_gunorg;
173         }
174
175         cl_followmodel_ofs = gunorg;
176         cl_followmodel_time = time;
177 }
178
179 vector leanmodel_ofs(entity view)
180 {
181         float frac;
182         vector gunangles = '0 0 0';
183         static vector gunangles_prev = '0 0 0';
184         static vector gunangles_highpass = '0 0 0';
185         static vector gunangles_adjustment_highpass;
186         static vector gunangles_adjustment_lowpass;
187
188         if (view.csqcmodel_teleported)
189                 gunangles_prev = view_angles;
190
191         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
192         gunangles_highpass += gunangles_prev;
193         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
194         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
195         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
196         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
197         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
198         gunangles_prev = view_angles;
199         gunangles_highpass -= gunangles_prev;
200
201         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
202         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
203
204         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
205         frac = avg_factor(autocvar_cl_leanmodel_highpass);
206         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
207         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
208         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
209
210         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
211
212         return gunangles;
213 }
214
215 vector bobmodel_ofs(entity view)
216 {
217         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
218         static bool oldonground;
219         static float hitgroundtime;
220         if (clonground)
221         {
222                 float f = time; // cl.movecmd[0].time
223                 if (!oldonground)
224                         hitgroundtime = f;
225         }
226         oldonground = clonground;
227
228         // calculate for swinging gun model
229         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
230         vector gunorg = '0 0 0';
231         static float bobmodel_scale = 0;
232         static float time_ofs = 0; // makes the effect always restart in the same way
233         if (clonground)
234         {
235                 if (time - hitgroundtime > 0.05)
236                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
237         }
238         else
239                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
240
241         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
242         if (bobmodel_scale && xyspeed)
243         {
244                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
245                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
246                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
247                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
248         }
249         else
250                 time_ofs = time;
251
252         return gunorg;
253 }
254
255 void viewmodel_animate(entity this)
256 {
257         if (autocvar_chase_active) return;
258         if (STAT(HEALTH) <= 0) return;
259
260         entity view = CSQCModel_server2csqc(player_localentnum - 1);
261
262         if (autocvar_cl_followmodel)
263         {
264                 calc_followmodel_ofs(view);
265                 this.origin += cl_followmodel_ofs;
266         }
267
268         if (autocvar_cl_leanmodel)
269                 this.angles += leanmodel_ofs(view);
270
271         // vertical view bobbing code
272         // TODO: cl_bob
273
274         // horizontal view bobbing code
275         // TODO: cl_bob2
276
277         // fall bobbing code
278         // causes the view to swing down and back up when touching the ground
279         // TODO: cl_bobfall
280
281         // gun model bobbing code
282         if (autocvar_cl_bobmodel)
283                 this.origin += bobmodel_ofs(view);
284 }
285
286 .vector viewmodel_origin, viewmodel_angles;
287 .float weapon_nextthink;
288 .float weapon_eta_last;
289 .float weapon_switchdelay;
290
291 .string name_last;
292
293 void viewmodel_draw(entity this)
294 {
295         if(!this.activeweapon || !autocvar_r_drawviewmodel)
296                 return;
297         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
298         float a = this.alpha;
299         static bool wasinvehicle;
300         bool invehicle = player_localentnum > maxclients;
301         if (invehicle) a = -1;
302         else if (wasinvehicle) a = 1;
303         wasinvehicle = invehicle;
304         Weapon wep = this.activeweapon;
305         int c = entcs_GetClientColors(current_player);
306         vector g = weaponentity_glowmod(wep, NULL, c, this);
307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
309                 | EF_NODEPTHTEST)
310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
311         for (entity e = this; e; e = e.weaponchild)
312         {
313                 e.drawmask = mask;
314                 e.alpha = a;
315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
316                 e.glowmod = g;
317                 e.csqcmodel_effects = fx;
318                 CSQCModel_Effects_Apply(e);
319         }
320         if(a >= 0)
321         {
322                 string name = wep.mdl;
323                 string newname = wep.wr_viewmodel(wep, this);
324                 if(newname)
325                         name = newname;
326                 bool swap = name != this.name_last;
327                 // if (swap)
328                 {
329                         this.name_last = name;
330                         CL_WeaponEntity_SetModel(this, name, swap);
331                         this.viewmodel_origin = this.origin;
332                         this.viewmodel_angles = this.angles;
333                 }
334                 anim_update(this);
335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
336                         anim_set(this, this.anim_idle, true, false, false);
337         }
338         float f = 0; // 0..1; 0: fully active
339         float rate = STAT(WEAPONRATEFACTOR);
340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
341         if (eta <= 0) f = this.weapon_eta_last;
342         else switch (this.state)
343         {
344                 case WS_RAISE:
345                 {
346                         f = eta / max(eta, this.weapon_switchdelay);
347                         break;
348                 }
349                 case WS_DROP:
350                 {
351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
352                         break;
353                 }
354                 case WS_CLEAR:
355                 {
356                         f = 1;
357                         break;
358                 }
359         }
360         this.weapon_eta_last = f;
361         this.origin = this.viewmodel_origin;
362         this.angles = this.viewmodel_angles;
363         this.angles_x = (-90 * f * f);
364         viewmodel_animate(this);
365         MUTATOR_CALLHOOK(DrawViewModel, this);
366         setorigin(this, this.origin);
367 }
368
369 STATIC_INIT(viewmodel) {
370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
371         viewmodels[slot] = new(viewmodel);
372 }
373
374 void Porto_Draw(entity this);
375 STATIC_INIT(Porto)
376 {
377         entity e = new_pure(porto);
378         e.draw = Porto_Draw;
379         IL_PUSH(g_drawables, e);
380         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
381 }
382
383 const int polyline_length = 16;
384 .vector polyline[polyline_length];
385 void Porto_Draw(entity this)
386 {
387         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
388         {
389                 entity wepent = viewmodels[slot];
390
391                 if (wepent.activeweapon != WEP_PORTO) continue;
392                 if (spectatee_status) continue;
393                 if (WEP_CVAR(porto, secondary)) continue;
394                 if (intermission == 1) continue;
395                 if (intermission == 2) continue;
396                 if (STAT(HEALTH) <= 0) continue;
397
398                 vector pos = view_origin;
399                 vector dir = view_forward;
400                 if (wepent.angles_held_status)
401                 {
402                         makevectors(wepent.angles_held);
403                         dir = v_forward;
404                 }
405
406                 wepent.polyline[0] = pos;
407
408                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
409                 int n = 1 + 2;  // 2 lines == 3 points
410                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
411                 {
412                         traceline(pos, pos + 65536 * dir, true, this);
413                         dir = reflect(dir, trace_plane_normal);
414                         pos = trace_endpos;
415                         wepent.polyline[++idx] = pos;
416                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
417                         {
418                                 n += 1;
419                                 continue;
420                         }
421                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
422                         {
423                                 n = max(2, idx);
424                                 break;
425                         }
426                         // check size
427                         {
428                                 vector ang = vectoangles2(trace_plane_normal, dir);
429                                 ang.x = -ang.x;
430                                 makevectors(ang);
431                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
432                                 {
433                                         n = max(2, idx);
434                                         break;
435                                 }
436                         }
437                         portal_number += 1;
438                         if (portal_number >= portal_max) break;
439                         if (portal_number == 1) portal1_idx = idx;
440                 }
441                 for (int idx = 0; idx < n - 1; ++idx)
442                 {
443                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
444                         if (idx == 0) p -= view_up * 16;  // line from player
445                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
446                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
447                 }
448         }
449 }
450
451 float drawtime;
452 float avgspeed;
453 vector GetCurrentFov(float fov)
454 {
455         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
456         float velocityzoom, curspeed;
457         vector v;
458
459         zoomsensitivity = autocvar_cl_zoomsensitivity;
460         zoomfactor = autocvar_cl_zoomfactor;
461         if(zoomfactor < 1 || zoomfactor > 30)
462                 zoomfactor = 2.5;
463         zoomspeed = autocvar_cl_zoomspeed;
464         if(zoomspeed >= 0)
465         if(zoomspeed < 0.5 || zoomspeed > 16)
466                         zoomspeed = 3.5;
467
468         zoomdir = button_zoom;
469
470         if(hud == HUD_NORMAL && !spectatee_status)
471         {
472                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
473                 {
474                         entity wepent = viewmodels[slot];
475                         if(wepent.switchweapon == wepent.activeweapon)
476                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary)) || (wepent.activeweapon == WEP_OVERKILL_VORTEX && !WEP_CVAR(okvortex, secondary))) // do NOT use switchweapon here
477                                 zoomdir += button_attack2;
478                 }
479         }
480         if(spectatee_status > 0 || isdemo())
481         {
482                 if(spectatorbutton_zoom)
483                 {
484                         if(zoomdir)
485                                 zoomdir = 0;
486                         else
487                                 zoomdir = 1;
488                 }
489                 // fteqcc failed twice here already, don't optimize this
490         }
491
492         if(zoomdir) { zoomin_effect = 0; }
493
494         if(camera_active)
495         {
496                 current_viewzoom = min(1, current_viewzoom + drawframetime);
497         }
498         else if(autocvar_cl_spawnzoom && zoomin_effect)
499         {
500                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
501
502                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
503                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
504                 if(current_viewzoom == 1) { zoomin_effect = 0; }
505         }
506         else
507         {
508                 if(zoomspeed < 0) // instant zoom
509                 {
510                         if(zoomdir)
511                                 current_viewzoom = 1 / zoomfactor;
512                         else
513                                 current_viewzoom = 1;
514                 }
515                 else
516                 {
517                         if(zoomdir)
518                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
519                         else
520                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
521                 }
522         }
523
524         if(almost_equals(current_viewzoom, 1))
525                 current_zoomfraction = 0;
526         else if(almost_equals(current_viewzoom, 1/zoomfactor))
527                 current_zoomfraction = 1;
528         else
529                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
530
531         if(zoomsensitivity < 1)
532                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
533         else
534                 setsensitivityscale(1);
535
536         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
537         {
538                 if(intermission) { curspeed = 0; }
539                 else
540                 {
541
542                         makevectors(view_angles);
543                         v = pmove_vel;
544                         if(csqcplayer)
545                                 v = csqcplayer.velocity;
546
547                         switch(autocvar_cl_velocityzoom_type)
548                         {
549                                 case 3: curspeed = max(0, v_forward * v); break;
550                                 case 2: curspeed = (v_forward * v); break;
551                                 case 1: default: curspeed = vlen(v); break;
552                         }
553                 }
554
555                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
556                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
557                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
558
559                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
560         }
561         else
562                 velocityzoom = 1;
563
564         float frustumx, frustumy, fovx, fovy;
565         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
566         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
567         fovx = atan2(frustumx, 1) / M_PI * 360.0;
568         fovy = atan2(frustumy, 1) / M_PI * 360.0;
569
570         return '1 0 0' * fovx + '0 1 0' * fovy;
571 }
572
573 vector GetViewLocationFOV(float fov)
574 {
575         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
576         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
577         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
578         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
579         return '1 0 0' * fovx + '0 1 0' * fovy;
580 }
581
582 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
583 {
584         float fovx, fovy;
585         float width = (ov_worldmax.x - ov_worldmin.x);
586         float height = (ov_worldmax.y - ov_worldmin.y);
587         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
588         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
589         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
590         return '1 0 0' * fovx + '0 1 0' * fovy;
591 }
592
593 // this function must match W_SetupShot!
594 float zoomscript_caught;
595
596 vector wcross_origin;
597 float wcross_scale_prev, wcross_alpha_prev;
598 vector wcross_color_prev;
599 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
600 vector wcross_color_goal_prev;
601 float wcross_changedonetime;
602
603 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
604 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
605 float wcross_name_changestarttime, wcross_name_changedonetime;
606 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
607
608 float wcross_ring_prev;
609
610 entity trueaim;
611 entity trueaim_rifle;
612
613 const float SHOTTYPE_HITTEAM = 1;
614 const float SHOTTYPE_HITOBSTRUCTION = 2;
615 const float SHOTTYPE_HITWORLD = 3;
616 const float SHOTTYPE_HITENEMY = 4;
617
618 void TrueAim_Init()
619 {
620         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
621         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
622 }
623
624 float EnemyHitCheck()
625 {
626         float t, n;
627         wcross_origin = project_3d_to_2d(trace_endpos);
628         wcross_origin.z = 0;
629         if(trace_ent)
630                 n = trace_ent.entnum;
631         else
632                 n = trace_networkentity;
633         if(n < 1)
634                 return SHOTTYPE_HITWORLD;
635         if(n > maxclients)
636                 return SHOTTYPE_HITWORLD;
637         t = entcs_GetTeam(n - 1);
638         if(teamplay)
639                 if(t == myteam)
640                         return SHOTTYPE_HITTEAM;
641         if(t == NUM_SPECTATOR)
642                 return SHOTTYPE_HITWORLD;
643         return SHOTTYPE_HITENEMY;
644 }
645
646 float TrueAimCheck(entity wepent)
647 {
648         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
649         vector vecs, trueaimpoint, w_shotorg;
650         vector mi, ma, dv;
651         float shottype;
652         entity ta;
653         float mv;
654
655         mi = ma = '0 0 0';
656         ta = trueaim;
657         mv = MOVE_NOMONSTERS;
658
659         switch(wepent.activeweapon) // WEAPONTODO
660         {
661                 case WEP_TUBA: // no aim
662                 case WEP_PORTO: // shoots from eye
663                 case WEP_NEXBALL: // shoots from eye
664                 case WEP_HOOK: // no trueaim
665                 case WEP_MORTAR: // toss curve
666                         return SHOTTYPE_HITWORLD;
667                 case WEP_VORTEX:
668                 case WEP_OVERKILL_VORTEX:
669                 case WEP_VAPORIZER:
670                         mv = MOVE_NORMAL;
671                         break;
672                 case WEP_RIFLE:
673                         ta = trueaim_rifle;
674                         mv = MOVE_NORMAL;
675                         if(zoomscript_caught)
676                         {
677                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
678                                 return EnemyHitCheck();
679                         }
680                         break;
681                 case WEP_DEVASTATOR: // projectile has a size!
682                         mi = '-3 -3 -3';
683                         ma = '3 3 3';
684                         break;
685                 case WEP_FIREBALL: // projectile has a size!
686                         mi = '-16 -16 -16';
687                         ma = '16 16 16';
688                         break;
689                 case WEP_SEEKER: // projectile has a size!
690                         mi = '-2 -2 -2';
691                         ma = '2 2 2';
692                         break;
693                 case WEP_ELECTRO: // projectile has a size!
694                         mi = '0 0 -3';
695                         ma = '0 0 -3';
696                         break;
697         }
698
699         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
700
701         vecs = decompressShotOrigin(STAT(SHOTORG));
702
703         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
704         trueaimpoint = trace_endpos;
705
706         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
707                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
708
709         if(vecs.x > 0)
710                 vecs.y = -vecs.y;
711         else
712                 vecs = '0 0 0';
713
714         dv = view_right * vecs.y + view_up * vecs.z;
715         w_shotorg = traceorigin + dv;
716
717         // now move the vecs forward as much as requested if possible
718         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
719         w_shotorg = trace_endpos - view_forward * nudge;
720
721         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
722         shottype = EnemyHitCheck();
723         if(shottype != SHOTTYPE_HITWORLD)
724                 return shottype;
725
726 #if 0
727         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
728         // or rather, I know why, but see no fix
729         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
730                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
731                 return SHOTTYPE_HITOBSTRUCTION;
732 #endif
733
734         return SHOTTYPE_HITWORLD;
735 }
736
737 void PostInit();
738 void CSQC_Demo_Camera();
739 float camera_mode;
740 const float CAMERA_FREE = 1;
741 const float CAMERA_CHASE = 2;
742 float reticle_type;
743 string NextFrameCommand;
744
745 vector freeze_org, freeze_ang;
746 entity nightvision_noise, nightvision_noise2;
747
748 const float MAX_TIME_DIFF = 5;
749 float pickup_crosshair_time, pickup_crosshair_size;
750 float hitindication_crosshair_size;
751 float use_vortex_chargepool;
752
753 float myhealth, myhealth_prev;
754 float myhealth_flash;
755
756 float old_blurradius, old_bluralpha;
757 float old_sharpen_intensity;
758
759 vector myhealth_gentlergb;
760
761 float contentavgalpha, liquidalpha_prev;
762 vector liquidcolor_prev;
763
764 float eventchase_current_distance;
765 float eventchase_running;
766 bool WantEventchase(entity this)
767 {
768         if(autocvar_cl_orthoview)
769                 return false;
770         if(STAT(GAME_STOPPED) || intermission)
771                 return true;
772         if(this.viewloc)
773                 return true;
774         if(spectatee_status >= 0)
775         {
776                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
777                         return true;
778                 if(MUTATOR_CALLHOOK(WantEventchase, this))
779                         return true;
780                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
781                         return true;
782                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
783                 {
784                         if(autocvar_cl_eventchase_death == 2)
785                         {
786                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
787                                 if(this.velocity == '0 0 0' || eventchase_running)
788                                         return true;
789                         }
790                         else return true;
791                 }
792         }
793         return false;
794 }
795
796 void HUD_Crosshair_Vehicle(entity this)
797 {
798         if(hud != HUD_BUMBLEBEE_GUN)
799         {
800                 Vehicle info = Vehicles_from(hud);
801                 info.vr_crosshair(info, this);
802         }
803 }
804
805 vector damage_blurpostprocess, content_blurpostprocess;
806
807 float unaccounted_damage = 0;
808 void UpdateDamage()
809 {
810         // accumulate damage with each stat update
811         static float damage_total_prev = 0;
812         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
813         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
814         damage_total_prev = damage_total;
815
816         static float damage_dealt_time_prev = 0;
817         float damage_dealt_time = STAT(HIT_TIME);
818         if (damage_dealt_time != damage_dealt_time_prev)
819         {
820                 unaccounted_damage += unaccounted_damage_new;
821                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
822         }
823         damage_dealt_time_prev = damage_dealt_time;
824
825         // prevent hitsound when switching spectatee
826         static float spectatee_status_prev = 0;
827         if (spectatee_status != spectatee_status_prev)
828                 unaccounted_damage = 0;
829         spectatee_status_prev = spectatee_status;
830 }
831
832 void HitSound()
833 {
834         // varying sound pitch
835
836         bool have_arc = false;
837         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
838         {
839                 entity wepent = viewmodels[slot];
840
841                 if(wepent.activeweapon == WEP_ARC)
842                         have_arc = true;
843         }
844
845         static float hitsound_time_prev = 0;
846         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
847         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
848         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
849         {
850                 if (autocvar_cl_hitsound && unaccounted_damage)
851                 {
852                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
853                         float a = autocvar_cl_hitsound_max_pitch;
854                         float b = autocvar_cl_hitsound_min_pitch;
855                         float c = autocvar_cl_hitsound_nom_damage;
856                         float d = unaccounted_damage;
857                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
858
859                         // if sound variation is disabled, set pitch_shift to 1
860                         if (autocvar_cl_hitsound == 1)
861                                 pitch_shift = 1;
862
863                         // if pitch shift is reversed, mirror in (max-min)/2 + min
864                         if (autocvar_cl_hitsound == 3)
865                         {
866                                 float mirror_value = (a-b)/2 + b;
867                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
868                         }
869
870                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
871
872                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
873                         // todo: normalize sound pressure levels? seems unnecessary
874
875                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
876                 }
877                 unaccounted_damage = 0;
878                 hitsound_time_prev = time;
879         }
880
881         static float typehit_time_prev = 0;
882         float typehit_time = STAT(TYPEHIT_TIME);
883         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
884         {
885                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
886                 typehit_time_prev = typehit_time;
887         }
888
889         static float kill_time_prev = 0;
890         float kill_time = STAT(KILL_TIME);
891         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
892         {
893                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
894                 kill_time_prev = kill_time;
895         }
896 }
897
898 vector crosshair_getcolor(entity this, float health_stat)
899 {
900         static float rainbow_last_flicker;
901         static vector rainbow_prev_color;
902         vector wcross_color = '0 0 0';
903         switch(autocvar_crosshair_color_special)
904         {
905                 case 1: // crosshair_color_per_weapon
906                 {
907                         if(this != WEP_Null && hud == HUD_NORMAL)
908                         {
909                                 wcross_color = this.wpcolor;
910                                 break;
911                         }
912                         else { goto normalcolor; }
913                 }
914
915                 case 2: // crosshair_color_by_health
916                 {
917                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
918                         float hp = floor(v.x + 1);
919
920                         //x = red
921                         //y = green
922                         //z = blue
923
924                         wcross_color.z = 0;
925
926                         if(hp > 200)
927                         {
928                                 wcross_color.x = 0;
929                                 wcross_color.y = 1;
930                         }
931                         else if(hp > 150)
932                         {
933                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
934                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
935                         }
936                         else if(hp > 100)
937                         {
938                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
939                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
940                                 wcross_color.z = 1 - (hp-100)*0.02;
941                         }
942                         else if(hp > 50)
943                         {
944                                 wcross_color.x = 1;
945                                 wcross_color.y = 1;
946                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
947                         }
948                         else if(hp > 20)
949                         {
950                                 wcross_color.x = 1;
951                                 wcross_color.y = (hp-20)*90/27/100;
952                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
953                         }
954                         else
955                         {
956                                 wcross_color.x = 1;
957                                 wcross_color.y = 0;
958                         }
959                         break;
960                 }
961
962                 case 3: // crosshair_color_rainbow
963                 {
964                         if(time >= rainbow_last_flicker)
965                         {
966                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
967                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
968                         }
969                         wcross_color = rainbow_prev_color;
970                         break;
971                 }
972 LABEL(normalcolor)
973                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
974         }
975
976         return wcross_color;
977 }
978
979 void HUD_Crosshair(entity this)
980 {
981         float f, i, j;
982         vector v;
983         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
984                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
985                 !HUD_MinigameMenu_IsOpened() )
986         {
987                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
988                         return;
989
990                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
991                         return;
992
993                 if (hud != HUD_NORMAL)
994                 {
995                         HUD_Crosshair_Vehicle(this);
996                         return;
997                 }
998
999                 string wcross_style;
1000                 float wcross_alpha, wcross_resolution;
1001                 wcross_style = autocvar_crosshair;
1002                 if (wcross_style == "0")
1003                         return;
1004                 wcross_resolution = autocvar_crosshair_size;
1005                 if (wcross_resolution == 0)
1006                         return;
1007                 wcross_alpha = autocvar_crosshair_alpha;
1008                 if (wcross_alpha == 0)
1009                         return;
1010
1011                 // TrueAim check
1012                 float shottype;
1013
1014                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1015                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1016                 wcross_origin.z = 0;
1017                 if(autocvar_crosshair_hittest)
1018                 {
1019                         vector wcross_oldorigin;
1020                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1021                         wcross_oldorigin = wcross_origin;
1022                         shottype = TrueAimCheck(thiswep);
1023                         if(shottype == SHOTTYPE_HITWORLD)
1024                         {
1025                                 v = wcross_origin - wcross_oldorigin;
1026                                 v.x /= vid_conwidth;
1027                                 v.y /= vid_conheight;
1028                                 if(vdist(v, >, 0.01))
1029                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1030                         }
1031                         if(!autocvar_crosshair_hittest_showimpact)
1032                                 wcross_origin = wcross_oldorigin;
1033                 }
1034                 else
1035                         shottype = SHOTTYPE_HITWORLD;
1036
1037                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1038                 string wcross_name = "";
1039                 float wcross_scale, wcross_blur;
1040
1041         entity e = WEP_Null;
1042                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1043                 {
1044                         entity wepent = viewmodels[0]; // TODO: unhardcode
1045                         e = wepent.switchingweapon;
1046                         if(e)
1047                         {
1048                                 if(autocvar_crosshair_per_weapon)
1049                                 {
1050                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1051                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1052                                         //if (wcross_resolution == 0)
1053                                                 //return;
1054
1055                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1056                                         wcross_resolution *= e.w_crosshair_size;
1057                                         wcross_name = e.w_crosshair;
1058                                 }
1059                         }
1060                 }
1061
1062                 if(wcross_name == "")
1063                         wcross_name = strcat("gfx/crosshair", wcross_style);
1064
1065                 // MAIN CROSSHAIR COLOR DECISION
1066                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1067
1068                 if(autocvar_crosshair_effect_scalefade)
1069                 {
1070                         wcross_scale = wcross_resolution;
1071                         wcross_resolution = 1;
1072                 }
1073                 else
1074                 {
1075                         wcross_scale = 1;
1076                 }
1077
1078                 if(autocvar_crosshair_pickup)
1079                 {
1080                         float stat_pickup_time = STAT(LAST_PICKUP);
1081
1082                         if(pickup_crosshair_time < stat_pickup_time)
1083                         {
1084                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1085                                         pickup_crosshair_size = 1;
1086
1087                                 pickup_crosshair_time = stat_pickup_time;
1088                         }
1089
1090                         if(pickup_crosshair_size > 0)
1091                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1092                         else
1093                                 pickup_crosshair_size = 0;
1094
1095                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1096                 }
1097
1098                 // todo: make crosshair hit indication dependent on damage dealt
1099                 if(autocvar_crosshair_hitindication)
1100                 {
1101                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1102
1103                         if(unaccounted_damage)
1104                         {
1105                                 hitindication_crosshair_size = 1;
1106                         }
1107
1108                         if(hitindication_crosshair_size > 0)
1109                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1110                         else
1111                                 hitindication_crosshair_size = 0;
1112
1113                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1114                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1115                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1116                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1117                 }
1118
1119                 if(shottype == SHOTTYPE_HITENEMY)
1120                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1121                 if(shottype == SHOTTYPE_HITTEAM)
1122                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1123
1124                 f = fabs(autocvar_crosshair_effect_time);
1125                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1126                 {
1127                         wcross_changedonetime = time + f;
1128                 }
1129                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1130                 {
1131                         wcross_name_changestarttime = time;
1132                         wcross_name_changedonetime = time + f;
1133                         if(wcross_name_goal_prev_prev)
1134                                 strunzone(wcross_name_goal_prev_prev);
1135                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1136                         wcross_name_goal_prev = strzone(wcross_name);
1137                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1138                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1139                         wcross_resolution_goal_prev = wcross_resolution;
1140                 }
1141
1142                 wcross_scale_goal_prev = wcross_scale;
1143                 wcross_alpha_goal_prev = wcross_alpha;
1144                 wcross_color_goal_prev = wcross_color;
1145
1146                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1147                 {
1148                         wcross_blur = 1;
1149                         wcross_alpha *= 0.75;
1150                 }
1151                 else
1152                         wcross_blur = 0;
1153                 // *_prev is at time-frametime
1154                 // * is at wcross_changedonetime+f
1155                 // what do we have at time?
1156                 if(time < wcross_changedonetime)
1157                 {
1158                         f = frametime / (wcross_changedonetime - time + frametime);
1159                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1160                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1161                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1162                 }
1163
1164                 wcross_scale_prev = wcross_scale;
1165                 wcross_alpha_prev = wcross_alpha;
1166                 wcross_color_prev = wcross_color;
1167
1168                 MUTATOR_CALLHOOK(UpdateCrosshair);
1169
1170                 wcross_scale *= 1 - autocvar__menu_alpha;
1171                 wcross_alpha *= 1 - autocvar__menu_alpha;
1172                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1173
1174                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1175                 {
1176                         // crosshair rings for weapon stats
1177                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1178                         {
1179                                 // declarations and stats
1180                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1181                                 string ring_image = string_null, ring_inner_image = string_null;
1182                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1183
1184                                 ring_scale = autocvar_crosshair_ring_size;
1185
1186                                 float weapon_clipload, weapon_clipsize;
1187                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1188                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1189
1190                                 float vortex_charge, vortex_chargepool;
1191                                 vortex_charge = STAT(VORTEX_CHARGE);
1192                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1193
1194                                 float okvortex_charge, okvortex_chargepool;
1195                                 okvortex_charge = STAT(OVERKILL_VORTEX_CHARGE);
1196                                 okvortex_chargepool = STAT(OVERKILL_VORTEX_CHARGEPOOL);
1197
1198                                 float arc_heat = STAT(ARC_HEAT);
1199
1200                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1201                                         vortex_charge_movingavg = vortex_charge;
1202
1203                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1204
1205                                 // handle the values
1206                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1207                                 {
1208                                         if (vortex_chargepool || use_vortex_chargepool) {
1209                                                 use_vortex_chargepool = 1;
1210                                                 ring_inner_value = vortex_chargepool;
1211                                         } else {
1212                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1213                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1214                                         }
1215
1216                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1217                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1218                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1219
1220                                         // draw the outer ring to show the current charge of the weapon
1221                                         ring_value = vortex_charge;
1222                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1223                                         ring_rgb = wcross_color;
1224                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1225                                 }
1226                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_VORTEX) && okvortex_charge && autocvar_crosshair_ring_vortex)
1227                                 {
1228                                         if (okvortex_chargepool || use_vortex_chargepool) {
1229                                                 use_vortex_chargepool = 1;
1230                                                 ring_inner_value = okvortex_chargepool;
1231                                         } else {
1232                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * okvortex_charge;
1233                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (okvortex_charge - vortex_charge_movingavg), 1);
1234                                         }
1235
1236                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1237                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1238                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1239
1240                                         // draw the outer ring to show the current charge of the weapon
1241                                         ring_value = okvortex_charge;
1242                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1243                                         ring_rgb = wcross_color;
1244                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1245                                 }
1246                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1247                                 {
1248                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1249                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1250                                         ring_rgb = wcross_color;
1251                                         ring_image = "gfx/crosshair_ring.tga";
1252                                 }
1253                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1254                                 {
1255                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1256                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1257                                         ring_rgb = wcross_color;
1258                                         ring_image = "gfx/crosshair_ring.tga";
1259                                 }
1260                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1261                                 {
1262                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1263                                         ring_scale = autocvar_crosshair_ring_reload_size;
1264                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1265                                         ring_rgb = wcross_color;
1266
1267                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1268                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1269                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1270                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1271                                         else
1272                                                 ring_image = "gfx/crosshair_ring.tga";
1273                                 }
1274                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1275                                 {
1276                                         ring_value = arc_heat;
1277                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1278                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1279                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1280                                         ring_image = "gfx/crosshair_ring.tga";
1281                                 }
1282
1283                                 // if in weapon switch animation, fade ring out/in
1284                                 if(autocvar_crosshair_effect_time > 0)
1285                                 {
1286                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1287                                         if (f >= 1)
1288                                         {
1289                                                 wcross_ring_prev = ((ring_image) ? true : false);
1290                                         }
1291
1292                                         if(wcross_ring_prev)
1293                                         {
1294                                                 if(f < 1)
1295                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1296                                         }
1297                                         else
1298                                         {
1299                                                 if(f < 1)
1300                                                         ring_alpha *= bound(0, f, 1);
1301                                         }
1302                                 }
1303
1304                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1305                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1306
1307                                 if (ring_value)
1308                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1309                         }
1310
1311 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1312                         MACRO_BEGIN { \
1313                                 if(wcross_blur > 0) \
1314                                 { \
1315                                         for(i = -2; i <= 2; ++i) \
1316                                         for(j = -2; j <= 2; ++j) \
1317                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1318                                 } \
1319                                 else \
1320                                 { \
1321                                         M(0,0,sz,wcross_name,wcross_alpha); \
1322                                 } \
1323                         } MACRO_END
1324
1325 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1326                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1327
1328 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1329                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1330
1331                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1332                         {
1333                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1334                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1335                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1336                                 f = 1 - f;
1337                         }
1338                         else
1339                         {
1340                                 f = 1;
1341                         }
1342                         wcross_name_alpha_goal_prev = f;
1343
1344                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1345                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1346
1347                         if(autocvar_crosshair_dot)
1348                         {
1349                                 vector wcross_color_old;
1350                                 wcross_color_old = wcross_color;
1351
1352                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1353                                         wcross_color = stov(autocvar_crosshair_dot_color);
1354
1355                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1356                                 // FIXME why don't we use wcross_alpha here?
1357                                 wcross_color = wcross_color_old;
1358                         }
1359                 }
1360         }
1361         else
1362         {
1363                 wcross_scale_prev = 0;
1364                 wcross_alpha_prev = 0;
1365                 wcross_scale_goal_prev = 0;
1366                 wcross_alpha_goal_prev = 0;
1367                 wcross_changedonetime = 0;
1368                 if(wcross_name_goal_prev)
1369                         strunzone(wcross_name_goal_prev);
1370                 wcross_name_goal_prev = string_null;
1371                 if(wcross_name_goal_prev_prev)
1372                         strunzone(wcross_name_goal_prev_prev);
1373                 wcross_name_goal_prev_prev = string_null;
1374                 wcross_name_changestarttime = 0;
1375                 wcross_name_changedonetime = 0;
1376                 wcross_name_alpha_goal_prev = 0;
1377                 wcross_name_alpha_goal_prev_prev = 0;
1378                 wcross_resolution_goal_prev = 0;
1379                 wcross_resolution_goal_prev_prev = 0;
1380         }
1381 }
1382
1383 const int MAX_SPECIALCOMMAND = 15;
1384 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1385 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1386 const float SPECIALCOMMAND_SPEED = 150;
1387 const float SPECIALCOMMAND_TURNSPEED = 2;
1388 const float SPECIALCOMMAND_SIZE = 0.025;
1389 const float SPECIALCOMMAND_CHANCE = 0.35;
1390 float sc_spawntime, sc_changetime;
1391 vector sc_color = '1 1 1';
1392 void SpecialCommand()
1393 {
1394         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1395                 return;
1396
1397         if(time >= sc_changetime)
1398         {
1399                 sc_changetime = time + 1;
1400                 sc_color = randomvec() * 1.5;
1401                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1402                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1403                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1404         }
1405         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1406
1407         if(!precache_pic("gfx/smile"))
1408                 return; // damn party poopers
1409
1410         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1411         {
1412                 vector slot = specialcommand_slots[j];
1413                 if(slot.y)
1414                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1415                 if(slot.z)
1416                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1417                 if(slot.y >= vid_conheight)
1418                         slot = '0 0 0';
1419
1420                 if(slot == '0 0 0')
1421                 {
1422                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1423                         {
1424                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1425                                 slot.y = 1; // start it off 0 so we can use it
1426                                 slot.z = random();
1427                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1428                                 vector newcolor = randomvec() * 2;
1429                                 newcolor.x = bound(0.4, newcolor.x, 1);
1430                                 newcolor.y = bound(0.4, newcolor.y, 1);
1431                                 newcolor.z = bound(0.4, newcolor.z, 1);
1432                                 specialcommand_colors[j] = newcolor;
1433                         }
1434                 }
1435                 else
1436                 {
1437                         vector splash_size = '0 0 0';
1438                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1439                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1440                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1441                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1442                 }
1443
1444                 specialcommand_slots[j] = slot;
1445         }
1446 }
1447
1448 void HUD_Draw(entity this)
1449 {
1450         // if we don't know gametype and scores yet avoid drawing the scoreboard
1451         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1452         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1453         // cl_deathscoreboard would show the scoreboard and so on
1454         if(!gametype)
1455                 return;
1456
1457         Hud_Dynamic_Frame();
1458
1459         if(!intermission)
1460         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1461         {
1462                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1463         }
1464         else if(STAT(FROZEN))
1465         {
1466                 vector col = '0.25 0.90 1';
1467                 if(STAT(REVIVE_PROGRESS))
1468                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1469                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1470         }
1471
1472         HUD_Scale_Enable();
1473         if(!intermission)
1474         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1475         {
1476                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1477                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1478                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1479         }
1480         else if(STAT(CAPTURE_PROGRESS))
1481         {
1482                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1483                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1484         }
1485         else if(STAT(REVIVE_PROGRESS))
1486         {
1487                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1488                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1489         }
1490         HUD_Scale_Disable();
1491
1492         if(autocvar_r_letterbox == 0)
1493                 if(autocvar_viewsize < 120)
1494                 {
1495                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1496                                 Accuracy_LoadLevels();
1497
1498                         HUD_Main();
1499                         HUD_Scale_Disable();
1500                 }
1501
1502         // crosshair goes VERY LAST
1503         SpecialCommand();
1504         UpdateDamage();
1505         HUD_Crosshair(this);
1506         HitSound();
1507 }
1508
1509 void ViewLocation_Mouse()
1510 {
1511         if(spectatee_status)
1512                 return; // don't draw it as spectator!
1513
1514         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1515         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1516         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1517
1518         float cursor_alpha = 1 - autocvar__menu_alpha;
1519         draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1520 }
1521
1522 bool ov_enabled;
1523 float oldr_nearclip;
1524 float oldr_farclip_base;
1525 float oldr_farclip_world;
1526 float oldr_novis;
1527 float oldr_useportalculling;
1528 float oldr_useinfinitefarclip;
1529
1530 void cl_notice_run();
1531
1532 float prev_myteam;
1533 int lasthud;
1534 float vh_notice_time;
1535 void WaypointSprite_Load();
1536 void CSQC_UpdateView(entity this, float w, float h)
1537 {
1538     TC(int, w); TC(int, h);
1539         entity e;
1540         float fov;
1541         float f;
1542         vector vf_size, vf_min;
1543         float a;
1544
1545         execute_next_frame();
1546
1547         ++framecount;
1548
1549         stats_get();
1550         hud = STAT(HUD);
1551
1552         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1553                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1554
1555         lasthud = hud;
1556
1557         HUD_Scale_Disable();
1558
1559         if(autocvar__hud_showbinds_reload) // menu can set this one
1560         {
1561                 db_close(binddb);
1562                 binddb = db_create();
1563                 cvar_set("_hud_showbinds_reload", "0");
1564         }
1565
1566         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1567                 view_quality = getproperty(VF_MINFPS_QUALITY);
1568         else
1569                 view_quality = 1;
1570
1571         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1572         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1573
1574         vf_size = getpropertyvec(VF_SIZE);
1575         vf_min = getpropertyvec(VF_MIN);
1576         vid_width = vf_size.x;
1577         vid_height = vf_size.y;
1578
1579         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1580         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1581
1582         WaypointSprite_Load();
1583
1584         CSQCPlayer_SetCamera();
1585
1586         if(player_localentnum <= maxclients) // is it a client?
1587                 current_player = player_localentnum - 1;
1588         else // then player_localentnum is the vehicle I'm driving
1589                 current_player = player_localnum;
1590         myteam = entcs_GetTeam(current_player);
1591
1592         if(myteam != prev_myteam)
1593         {
1594                 myteamcolors = colormapPaletteColor(myteam, 1);
1595                 FOREACH(hud_panels, true, it.update_time = time);
1596                 prev_myteam = myteam;
1597         }
1598
1599         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1600
1601         float is_dead = (STAT(HEALTH) <= 0);
1602
1603         // FIXME do we need this hack?
1604         if(isdemo())
1605         {
1606                 // in demos, input_buttons do not work
1607                 button_zoom = (autocvar__togglezoom == "-");
1608         }
1609         else if(button_zoom
1610                 && autocvar_cl_unpress_zoom_on_death
1611                 && (spectatee_status >= 0)
1612                 && (is_dead || intermission))
1613         {
1614                 // no zoom while dead or in intermission please
1615                 localcmd("-zoom\n");
1616                 button_zoom = false;
1617         }
1618
1619         // abused multiple places below
1620         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1621         if(!local_player)
1622                 local_player = this; // fall back!
1623
1624         // event chase camera
1625         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1626         {
1627                 if(STAT(CAMERA_SPECTATOR))
1628                 {
1629                         if(spectatee_status > 0)
1630                         {
1631                                 if(!autocvar_chase_active)
1632                                 {
1633                                         cvar_set("chase_active", "-2");
1634                                         goto skip_eventchase_death;
1635                                 }
1636                         }
1637                         else if(autocvar_chase_active == -2)
1638                                 cvar_set("chase_active", "0");
1639
1640                         if(autocvar_chase_active == -2)
1641                                 goto skip_eventchase_death;
1642                 }
1643                 else if(autocvar_chase_active == -2)
1644                         cvar_set("chase_active", "0");
1645
1646                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1647
1648                 float vehicle_viewdist = 0;
1649                 vector vehicle_viewofs = '0 0 0';
1650
1651                 if(vehicle_chase)
1652                 {
1653                         if(hud != HUD_BUMBLEBEE_GUN)
1654                         {
1655                                 Vehicle info = Vehicles_from(hud);
1656                                 vehicle_viewdist = info.height;
1657                                 vehicle_viewofs = info.view_ofs;
1658                         }
1659                 }
1660
1661                 if(WantEventchase(this))
1662                 {
1663                         vector current_view_origin_override = '0 0 0';
1664                         vector view_offset_override = '0 0 0';
1665                         float chase_distance_override = 0;
1666                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1667                         if(custom_eventchase)
1668                         {
1669                                 current_view_origin_override = M_ARGV(0, vector);
1670                                 view_offset_override = M_ARGV(1, vector);
1671                                 chase_distance_override = M_ARGV(0, float);
1672                         }
1673                         eventchase_running = true;
1674
1675                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1676                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1677                         if (custom_eventchase)
1678                                 current_view_origin = current_view_origin_override;
1679
1680                         // detect maximum viewoffset and use it
1681                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1682                         if(vehicle_chase)
1683                         {
1684                                 if(vehicle_viewofs)
1685                                         view_offset = vehicle_viewofs;
1686                                 else
1687                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1688                         }
1689                         if (custom_eventchase)
1690                                 view_offset = view_offset_override;
1691
1692                         if(view_offset)
1693                         {
1694                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1695                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1696                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1697                         }
1698
1699                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1700                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1701                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1702                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1703
1704                         // make the camera smooth back
1705                         float chase_distance = autocvar_cl_eventchase_distance;
1706                         if(vehicle_chase)
1707                         {
1708                                 if(vehicle_viewofs)
1709                                         chase_distance = vehicle_viewdist;
1710                                 else
1711                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1712                         }
1713                         if (custom_eventchase)
1714                                 chase_distance = chase_distance_override;
1715
1716                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1717                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1718                         else if(eventchase_current_distance != chase_distance)
1719                                 eventchase_current_distance = chase_distance;
1720
1721                         makevectors(view_angles);
1722
1723                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1724                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1725
1726                         // If the boxtrace fails, revert back to line tracing.
1727                         if(!local_player.viewloc)
1728                         if(trace_startsolid)
1729                         {
1730                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1731                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1732                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1733                         }
1734                         else { setproperty(VF_ORIGIN, trace_endpos); }
1735
1736                         if(!local_player.viewloc)
1737                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1738                 }
1739                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1740                 {
1741                         eventchase_running = false;
1742                         cvar_set("chase_active", "0");
1743                         eventchase_current_distance = 0; // start from 0 next time
1744                 }
1745         }
1746         // workaround for camera stuck between player's legs when using chase_active 1
1747         // because the engine stops updating the chase_active camera when the game ends
1748         else if(intermission)
1749         {
1750                 cvar_settemp("chase_active", "-1");
1751                 eventchase_current_distance = 0;
1752         }
1753
1754         LABEL(skip_eventchase_death);
1755
1756         // do lockview after event chase camera so that it still applies whenever necessary.
1757         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1758         {
1759                 setproperty(VF_ORIGIN, freeze_org);
1760                 setproperty(VF_ANGLES, freeze_ang);
1761         }
1762         else
1763         {
1764                 freeze_org = getpropertyvec(VF_ORIGIN);
1765                 freeze_ang = getpropertyvec(VF_ANGLES);
1766         }
1767
1768         WarpZone_FixView();
1769         //WarpZone_FixPMove();
1770
1771         vector ov_org = '0 0 0';
1772         vector ov_mid = '0 0 0';
1773         vector ov_worldmin = '0 0 0';
1774         vector ov_worldmax = '0 0 0';
1775         if(autocvar_cl_orthoview)
1776         {
1777                 ov_worldmin = mi_picmin;
1778                 ov_worldmax = mi_picmax;
1779
1780                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1781                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1782                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1783
1784                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1785                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1786
1787                 float ov_nearest = vlen(ov_org - vec3(
1788                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1789                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1790                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1791                 ));
1792
1793                 float ov_furthest = 0;
1794                 float dist = 0;
1795
1796                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1797                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1798                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1799                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1800                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1801                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1802                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1803                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1804
1805                 if(!ov_enabled)
1806                 {
1807                         oldr_nearclip = cvar("r_nearclip");
1808                         oldr_farclip_base = cvar("r_farclip_base");
1809                         oldr_farclip_world = cvar("r_farclip_world");
1810                         oldr_novis = cvar("r_novis");
1811                         oldr_useportalculling = cvar("r_useportalculling");
1812                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1813                 }
1814
1815                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1816                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1817                 cvar_settemp("r_farclip_world", "0");
1818                 cvar_settemp("r_novis", "1");
1819                 cvar_settemp("r_useportalculling", "0");
1820                 cvar_settemp("r_useinfinitefarclip", "0");
1821
1822                 setproperty(VF_ORIGIN, ov_org);
1823                 setproperty(VF_ANGLES, '90 0 0');
1824
1825                 ov_enabled = true;
1826
1827                 #if 0
1828                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1829                         vtos(ov_org),
1830                         vtos(getpropertyvec(VF_ANGLES)),
1831                         ov_distance,
1832                         ov_nearest,
1833                         ov_furthest);
1834                 #endif
1835         }
1836         else
1837         {
1838                 if(ov_enabled)
1839                 {
1840                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1841                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1842                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1843                         cvar_set("r_novis", ftos(oldr_novis));
1844                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1845                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1846                 }
1847                 ov_enabled = false;
1848         }
1849
1850         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1851         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1852         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1853                 viewmodel_draw(viewmodels[slot]);
1854
1855         // Render the Scene
1856         view_origin = getpropertyvec(VF_ORIGIN);
1857         view_angles = getpropertyvec(VF_ANGLES);
1858         makevectors(view_angles);
1859         view_forward = v_forward;
1860         view_right = v_right;
1861         view_up = v_up;
1862
1863 #ifdef BLURTEST
1864         if(time > blurtest_time0 && time < blurtest_time1)
1865         {
1866                 float r, t;
1867
1868                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1869                 r = t * blurtest_radius;
1870                 f = 1 / (t ** blurtest_power) - 1;
1871
1872                 cvar_set("r_glsl_postprocess", "1");
1873                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1874         }
1875         else
1876         {
1877                 cvar_set("r_glsl_postprocess", "0");
1878                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1879         }
1880 #endif
1881
1882         TargetMusic_Advance();
1883         Fog_Force();
1884
1885         if(drawtime == 0)
1886                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1887         else
1888                 drawframetime = bound(0.000001, time - drawtime, 1);
1889         drawtime = time;
1890
1891         // watch for gametype changes here...
1892         // in ParseStuffCMD the cmd isn't executed yet :/
1893         // might even be better to add the gametype to TE_CSQC_INIT...?
1894         if(!postinit)
1895                 PostInit();
1896
1897         if(intermission && !intermission_time)
1898                 intermission_time = time;
1899
1900         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1901         {
1902                 if(calledhooks & HOOK_START)
1903                 {
1904                         localcmd("\ncl_hook_gameend\n");
1905                         calledhooks |= HOOK_END;
1906                 }
1907         }
1908
1909         Announcer();
1910
1911         fov = autocvar_fov;
1912         if(fov <= 59.5)
1913         {
1914                 if(!zoomscript_caught)
1915                 {
1916                         localcmd("+button9\n");
1917                         zoomscript_caught = 1;
1918                 }
1919         }
1920         else
1921         {
1922                 if(zoomscript_caught)
1923                 {
1924                         localcmd("-button9\n");
1925                         zoomscript_caught = 0;
1926                 }
1927         }
1928
1929         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1930
1931         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1932         {
1933                 entity wepent = viewmodels[slot];
1934
1935                 if(wepent.last_switchweapon != wepent.switchweapon)
1936                 {
1937                         weapontime = time;
1938                         wepent.last_switchweapon = wepent.switchweapon;
1939                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1940                         {
1941                                 localcmd("-zoom\n");
1942                                 button_zoom = false;
1943                         }
1944                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1945                         {
1946                                 localcmd("-fire\n");
1947                                 localcmd("-fire2\n");
1948                                 button_attack2 = false;
1949                         }
1950                 }
1951                 if(wepent.last_activeweapon != wepent.activeweapon)
1952                 {
1953                         wepent.last_activeweapon = wepent.activeweapon;
1954
1955                         e = wepent.activeweapon;
1956                         if(e.netname != "")
1957                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1958                         else if(slot == 0)
1959                                 localcmd("\ncl_hook_activeweapon none\n");
1960                 }
1961         }
1962
1963         // ALWAYS Clear Current Scene First
1964         clearscene();
1965
1966         setproperty(VF_ORIGIN, view_origin);
1967         setproperty(VF_ANGLES, view_angles);
1968
1969         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1970         setproperty(VF_SIZE, vf_size);
1971         setproperty(VF_MIN, vf_min);
1972
1973         // Assign Standard Viewflags
1974         // Draw the World (and sky)
1975         setproperty(VF_DRAWWORLD, 1);
1976
1977         // Set the console size vars
1978         vid_conwidth = autocvar_vid_conwidth;
1979         vid_conheight = autocvar_vid_conheight;
1980         vid_pixelheight = autocvar_vid_pixelheight;
1981
1982         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1983         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1984         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1985
1986         if(camera_active) // Camera for demo playback
1987         {
1988                 if(autocvar_camera_enable)
1989                         CSQC_Demo_Camera();
1990                 else
1991                 {
1992                         cvar_set("chase_active", ftos(chase_active_backup));
1993                         cvar_set("cl_demo_mousegrab", "0");
1994                         camera_active = false;
1995                 }
1996         }
1997         else
1998         {
1999 #ifdef CAMERATEST
2000                 if(autocvar_camera_enable)
2001 #else
2002                 if(autocvar_camera_enable && isdemo())
2003 #endif
2004                 {
2005                         // Enable required Darkplaces cvars
2006                         chase_active_backup = autocvar_chase_active;
2007                         cvar_set("chase_active", "2");
2008                         cvar_set("cl_demo_mousegrab", "1");
2009                         camera_active = true;
2010                         camera_mode = false;
2011                 }
2012         }
2013
2014         // Draw the Crosshair
2015         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2016
2017         // Draw the Engine Status Bar (the default Quake HUD)
2018         setproperty(VF_DRAWENGINESBAR, 0);
2019
2020         // Update the mouse position
2021         /*
2022            mousepos_x = vid_conwidth;
2023            mousepos_y = vid_conheight;
2024            mousepos = mousepos*0.5 + getmousepos();
2025          */
2026
2027         IL_EACH(g_drawables, it.draw, it.draw(it));
2028
2029         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2030         renderscene();
2031
2032         // now switch to 2D drawing mode by calling a 2D drawing function
2033         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2034         // next R_RenderScene call
2035         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2036
2037         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2038         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2039         {
2040                 // apply night vision effect
2041                 vector tc_00, tc_01, tc_10, tc_11;
2042                 vector rgb = '0 0 0';
2043
2044                 if(!nightvision_noise)
2045                 {
2046                         nightvision_noise = new(nightvision_noise);
2047                 }
2048                 if(!nightvision_noise2)
2049                 {
2050                         nightvision_noise2 = new(nightvision_noise2);
2051                 }
2052
2053                 // color tint in yellow
2054                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2055
2056                 // draw BG
2057                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2058                 rgb = '1 1 1';
2059                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2060                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2061                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2062                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2063                 tc_11 = tc_01 + tc_10 - tc_00;
2064                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2065                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2066                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2067                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2068                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2069                 R_EndPolygon();
2070
2071                 // draw FG
2072                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2073                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2074                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2075                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2076                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2077                 tc_11 = tc_01 + tc_10 - tc_00;
2078                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2079                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2080                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2081                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2082                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2083                 R_EndPolygon();
2084         }
2085
2086         if(autocvar_cl_reticle)
2087         {
2088                 string reticle_image = string_null;
2089                 bool wep_zoomed = false;
2090                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2091                 {
2092                         entity wepe = viewmodels[slot];
2093                         Weapon wep = wepe.activeweapon;
2094                         if(wep != WEP_Null && wep.wr_zoom)
2095                         {
2096                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2097                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2098                                         reticle_image = wep.w_reticle;
2099                                 wep_zoomed += do_zoom;
2100                         }
2101                 }
2102                 // Draw the aiming reticle for weapons that use it
2103                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2104                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2105                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2106                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2107                 {
2108                         // no zoom reticle while dead
2109                         reticle_type = 0;
2110                 }
2111                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2112                 {
2113                         if(reticle_image) { reticle_type = 2; }
2114                         else { reticle_type = 0; }
2115                 }
2116                 else if(button_zoom || zoomscript_caught)
2117                 {
2118                         // normal zoom
2119                         reticle_type = 1;
2120                 }
2121
2122                 if(reticle_type)
2123                 {
2124                         if(autocvar_cl_reticle_stretch)
2125                         {
2126                                 reticle_size.x = vid_conwidth;
2127                                 reticle_size.y = vid_conheight;
2128                                 reticle_pos.x = 0;
2129                                 reticle_pos.y = 0;
2130                         }
2131                         else
2132                         {
2133                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2134                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2135                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2136                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2137                         }
2138
2139                         if(zoomscript_caught)
2140                                 f = 1;
2141                         else
2142                                 f = current_zoomfraction;
2143
2144                         if(f)
2145                         {
2146                                 switch(reticle_type)
2147                                 {
2148                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2149                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2150                                 }
2151                         }
2152                 }
2153         }
2154         else
2155         {
2156                 if(reticle_type != 0) { reticle_type = 0; }
2157         }
2158
2159
2160         // improved polyblend
2161         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2162         {
2163                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2164                 vector liquidcolor;
2165
2166                 switch(pointcontents(view_origin))
2167                 {
2168                         case CONTENT_WATER:
2169                                 liquidalpha = autocvar_hud_contents_water_alpha;
2170                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2171                                 incontent = 1;
2172                                 break;
2173
2174                         case CONTENT_LAVA:
2175                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2176                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2177                                 incontent = 1;
2178                                 break;
2179
2180                         case CONTENT_SLIME:
2181                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2182                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2183                                 incontent = 1;
2184                                 break;
2185
2186                         default:
2187                                 liquidalpha = 0;
2188                                 liquidcolor = '0 0 0';
2189                                 incontent = 0;
2190                                 break;
2191                 }
2192
2193                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2194                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2195                         contentfadetime = autocvar_hud_contents_fadeintime;
2196                         liquidalpha_prev = liquidalpha;
2197                         liquidcolor_prev = liquidcolor;
2198                 }
2199                 else
2200                         contentfadetime = autocvar_hud_contents_fadeouttime;
2201
2202                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2203                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2204
2205                 if(contentavgalpha)
2206                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2207
2208                 if(autocvar_hud_postprocessing)
2209                 {
2210                         if(autocvar_hud_contents_blur && contentavgalpha)
2211                         {
2212                                 content_blurpostprocess.x = 1;
2213                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2214                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2215                         }
2216                         else
2217                         {
2218                                 content_blurpostprocess.x = 0;
2219                                 content_blurpostprocess.y = 0;
2220                                 content_blurpostprocess.z = 0;
2221                         }
2222                 }
2223         }
2224
2225         if(autocvar_hud_damage && !STAT(FROZEN))
2226         {
2227                 splash_size.x = max(vid_conwidth, vid_conheight);
2228                 splash_size.y = max(vid_conwidth, vid_conheight);
2229                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2230                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2231
2232                 float myhealth_flash_temp;
2233                 myhealth = STAT(HEALTH);
2234
2235                 // fade out
2236                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2237                 // add new damage
2238                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2239
2240                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2241                 pain_threshold = autocvar_hud_damage_pain_threshold;
2242                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2243                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2244
2245                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2246                 {
2247                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2248                 }
2249
2250                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2251
2252                 if(myhealth_prev < 1)
2253                 {
2254                         if(myhealth >= 1)
2255                         {
2256                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2257                                 myhealth_flash_temp = 0;
2258                         }
2259                         else
2260                         {
2261                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2262                         }
2263                 }
2264
2265                 if(spectatee_status == -1 || intermission)
2266                 {
2267                         myhealth_flash = 0; // observing, or match ended
2268                         myhealth_flash_temp = 0;
2269                 }
2270
2271                 myhealth_prev = myhealth;
2272
2273                 // IDEA: change damage color/picture based on player model for robot/alien species?
2274                 // pro: matches model better
2275                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2276                 // maybe different reddish pics?
2277                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2278                 {
2279                         if(autocvar_cl_gentle_damage == 2)
2280                         {
2281                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2282                                         myhealth_gentlergb = randomvec();
2283                         }
2284                         else
2285                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2286
2287                         if(myhealth_flash_temp > 0)
2288                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2289                 }
2290                 else if(myhealth_flash_temp > 0)
2291                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2292
2293                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2294                 {
2295                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2296                         {
2297                                 damage_blurpostprocess.x = 1;
2298                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2299                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2300                         }
2301                         else
2302                         {
2303                                 damage_blurpostprocess.x = 0;
2304                                 damage_blurpostprocess.y = 0;
2305                                 damage_blurpostprocess.z = 0;
2306                         }
2307                 }
2308         }
2309
2310         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2311         float e2 = (autocvar_hud_powerup != 0);
2312         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2313         {
2314                 // enable or disable rendering types if they are used or not
2315                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2316                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2317
2318                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2319                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2320                 {
2321                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2322                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2323                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2324                         {
2325                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2326                                 old_blurradius = blurradius;
2327                                 old_bluralpha = bluralpha;
2328                         }
2329                 }
2330                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2331                 {
2332                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2333                         old_blurradius = 0;
2334                         old_bluralpha = 0;
2335                 }
2336
2337                 // edge detection postprocess handling done second (used by hud_powerup)
2338                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2339                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2340                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2341
2342                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2343
2344                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2345                 {
2346                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2347                         {
2348                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2349                                 old_sharpen_intensity = sharpen_intensity;
2350                         }
2351                 }
2352                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2353                 {
2354                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2355                         old_sharpen_intensity = 0;
2356                 }
2357
2358                 if(cvar("r_glsl_postprocess") == 0)
2359                         cvar_set("r_glsl_postprocess", "2");
2360         }
2361         else if(cvar("r_glsl_postprocess") == 2)
2362                 cvar_set("r_glsl_postprocess", "0");
2363
2364         /*if(gametype == MAPINFO_TYPE_CTF)
2365           {
2366           ctf_view();
2367           } else */
2368
2369         // draw 2D entities
2370         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2371         Draw_ShowNames_All();
2372 #if ENABLE_DEBUGDRAW
2373         Debug_Draw();
2374 #endif
2375
2376         scoreboard_active = Scoreboard_WouldDraw();
2377
2378         HUD_Draw(this); // this parameter for deep vehicle function
2379
2380         if(NextFrameCommand)
2381         {
2382                 localcmd("\n", NextFrameCommand, "\n");
2383                 NextFrameCommand = string_null;
2384         }
2385
2386         // we must do this check AFTER a frame was rendered, or it won't work
2387         if(cs_project_is_b0rked == 0)
2388         {
2389                 string w0, h0;
2390                 w0 = ftos(autocvar_vid_conwidth);
2391                 h0 = ftos(autocvar_vid_conheight);
2392                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2393                 //setproperty(VF_FOV, '90 90 0');
2394                 setproperty(VF_ORIGIN, '0 0 0');
2395                 setproperty(VF_ANGLES, '0 0 0');
2396                 setproperty(VF_PERSPECTIVE, 1);
2397                 makevectors('0 0 0');
2398                 vector v1, v2;
2399                 cvar_set("vid_conwidth", "800");
2400                 cvar_set("vid_conheight", "600");
2401                 v1 = cs_project(v_forward);
2402                 cvar_set("vid_conwidth", "640");
2403                 cvar_set("vid_conheight", "480");
2404                 v2 = cs_project(v_forward);
2405                 if(v1 == v2)
2406                         cs_project_is_b0rked = 1;
2407                 else
2408                         cs_project_is_b0rked = -1;
2409                 cvar_set("vid_conwidth", w0);
2410                 cvar_set("vid_conheight", h0);
2411         }
2412
2413         if(autocvar__hud_configure)
2414                 HUD_Panel_Mouse();
2415         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2416                 HUD_Minigame_Mouse();
2417         else if(QuickMenu_IsOpened())
2418                 QuickMenu_Mouse();
2419         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2420                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2421         else
2422                 HUD_Radar_Mouse();
2423
2424         cl_notice_run();
2425         unpause_update();
2426         Net_Flush();
2427
2428         // let's reset the view back to normal for the end
2429         setproperty(VF_MIN, '0 0 0');
2430         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2431
2432         IL_ENDFRAME();
2433 }
2434
2435
2436 // following vectors must be global to allow seamless switching between camera modes
2437 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2438 void CSQC_Demo_Camera()
2439 {
2440         float speed, attenuation, dimensions;
2441         vector tmp, delta;
2442
2443         if( autocvar_camera_reset || !camera_mode )
2444         {
2445                 camera_offset = '0 0 0';
2446                 current_angles = '0 0 0';
2447                 camera_direction = '0 0 0';
2448                 camera_offset.z += 30;
2449                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2450                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2451                 current_origin = view_origin;
2452                 current_camera_offset  = camera_offset;
2453                 cvar_set("camera_reset", "0");
2454                 camera_mode = CAMERA_CHASE;
2455         }
2456
2457         // Camera angles
2458         if( camera_roll )
2459                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2460
2461         if(autocvar_camera_look_player)
2462         {
2463                 vector dir;
2464                 float n;
2465
2466                 dir = normalize(view_origin - current_position);
2467                 n = mouse_angles.z;
2468                 mouse_angles = vectoangles(dir);
2469                 mouse_angles.x = mouse_angles.x * -1;
2470                 mouse_angles.z = n;
2471         }
2472         else
2473         {
2474                 tmp = getmousepos() * 0.1;
2475                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2476                 {
2477                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2478                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2479                 }
2480         }
2481
2482         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2483         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2484         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2485         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2486
2487         // Fix difference when angles don't have the same sign
2488         delta = '0 0 0';
2489         if(mouse_angles.y < -60 && current_angles.y > 60)
2490                 delta = '0 360 0';
2491         if(mouse_angles.y > 60 && current_angles.y < -60)
2492                 delta = '0 -360 0';
2493
2494         if(autocvar_camera_look_player)
2495                 attenuation = autocvar_camera_look_attenuation;
2496         else
2497                 attenuation = autocvar_camera_speed_attenuation;
2498
2499         attenuation = 1 / max(1, attenuation);
2500         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2501
2502         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2503         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2504         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2505         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2506
2507         // Camera position
2508         tmp = '0 0 0';
2509         dimensions = 0;
2510
2511         if( camera_direction.x )
2512         {
2513                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2514                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2515                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2516                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2517                 ++dimensions;
2518         }
2519
2520         if( camera_direction.y )
2521         {
2522                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2523                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2524                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2525                 ++dimensions;
2526         }
2527
2528         if( camera_direction.z )
2529         {
2530                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2531                 ++dimensions;
2532         }
2533
2534         if(autocvar_camera_free)
2535                 speed = autocvar_camera_speed_free;
2536         else
2537                 speed = autocvar_camera_speed_chase;
2538
2539         if(dimensions)
2540         {
2541                 speed = speed * sqrt(1 / dimensions);
2542                 camera_offset += tmp * speed;
2543         }
2544
2545         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2546
2547         // Camera modes
2548         if( autocvar_camera_free )
2549         {
2550                 if ( camera_mode == CAMERA_CHASE )
2551                 {
2552                         current_camera_offset = current_origin + current_camera_offset;
2553                         camera_offset = current_origin + camera_offset;
2554                 }
2555
2556                 camera_mode = CAMERA_FREE;
2557                 current_position = current_camera_offset;
2558         }
2559         else
2560         {
2561                 if ( camera_mode == CAMERA_FREE )
2562                 {
2563                         current_origin = view_origin;
2564                         camera_offset = camera_offset - current_origin;
2565                         current_camera_offset = current_camera_offset - current_origin;
2566                 }
2567
2568                 camera_mode = CAMERA_CHASE;
2569
2570                 if(autocvar_camera_chase_smoothly)
2571                         current_origin += (view_origin - current_origin) * attenuation;
2572                 else
2573                         current_origin = view_origin;
2574
2575                 current_position = current_origin + current_camera_offset;
2576         }
2577
2578         setproperty(VF_ANGLES, current_angles);
2579         setproperty(VF_ORIGIN, current_position);
2580 }