Allow servers to define custom help messages for votes
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "autocvars.qh"
4 #include "miscfunctions.qh"
5 #include "announcer.qh"
6 #include "hud/_mod.qh"
7 #include "mapvoting.qh"
8 #include "shownames.qh"
9 #include "hud/panel/scoreboard.qh"
10 #include "hud/panel/quickmenu.qh"
11
12 #include "mutators/events.qh"
13
14 #include <common/animdecide.qh>
15 #include <common/deathtypes/all.qh>
16 #include <common/ent_cs.qh>
17 #include <common/anim.qh>
18 #include <common/constants.qh>
19 #include <common/net_linked.qh>
20 #include <common/debug.qh>
21 #include <common/mapinfo.qh>
22 #include <common/gamemodes/_mod.qh>
23 #include <common/physics/player.qh>
24 #include <common/stats.qh>
25 #include <common/triggers/target/music.qh>
26 #include <common/teams.qh>
27 #include <common/wepent.qh>
28
29 #include <common/weapons/weapon/tuba.qh>
30
31 #include <common/vehicles/all.qh>
32 #include <common/weapons/_all.qh>
33 #include <common/viewloc.qh>
34 #include <common/triggers/trigger/viewloc.qh>
35 #include <common/minigames/cl_minigames.qh>
36 #include <common/minigames/cl_minigames_hud.qh>
37
38 #include <lib/csqcmodel/cl_player.qh>
39 #include <lib/csqcmodel/cl_model.qh>
40 #include "csqcmodel_hooks.qh"
41
42 #include <lib/warpzone/client.qh>
43 #include <lib/warpzone/common.qh>
44
45 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
46
47 float autocvar_cl_viewmodel_scale;
48
49 bool autocvar_cl_bobmodel;
50 float autocvar_cl_bobmodel_speed;
51 float autocvar_cl_bobmodel_side;
52 float autocvar_cl_bobmodel_up;
53
54 float autocvar_cl_followmodel;
55 float autocvar_cl_followmodel_speed = 0.3;
56 float autocvar_cl_followmodel_limit = 135;
57 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
58 float autocvar_cl_followmodel_highpass = 0.05;
59 float autocvar_cl_followmodel_lowpass = 0.03;
60 bool autocvar_cl_followmodel_velocity_absolute;
61
62 float autocvar_cl_leanmodel;
63 float autocvar_cl_leanmodel_speed = 0.3;
64 float autocvar_cl_leanmodel_limit = 30;
65 float autocvar_cl_leanmodel_highpass1 = 0.2;
66 float autocvar_cl_leanmodel_highpass = 0.2;
67 float autocvar_cl_leanmodel_lowpass = 0.05;
68
69 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
70
71 #define lowpass(value, frac, ref_store, ret) \
72         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
73
74 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
75 { \
76         float __ignore; lowpass(value, frac, ref_store, __ignore); \
77         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
78 } MACRO_END
79
80 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
81 { \
82         float __f = 0; lowpass(value, frac, ref_store, __f); \
83         ret = (value) - __f; \
84 } MACRO_END
85
86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
87 { \
88         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
89         ret = (value) - __f; \
90 } MACRO_END
91
92 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
93 { \
94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
96 } MACRO_END
97
98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
99 { \
100         highpass(value.x, frac, ref_store.x, ref_out.x); \
101         highpass(value.y, frac, ref_store.y, ref_out.y); \
102 } MACRO_END
103
104 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
105 { \
106         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
107         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
108 } MACRO_END
109
110 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
111 { \
112         lowpass(value.x, frac, ref_store.x, ref_out.x); \
113         lowpass(value.y, frac, ref_store.y, ref_out.y); \
114         lowpass(value.z, frac, ref_store.z, ref_out.z); \
115 } MACRO_END
116
117 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
118 { \
119         highpass(value.x, frac, ref_store.x, ref_out.x); \
120         highpass(value.y, frac, ref_store.y, ref_out.y); \
121         highpass(value.z, frac, ref_store.z, ref_out.z); \
122 } MACRO_END
123
124 void calc_followmodel_ofs(entity view)
125 {
126         if(cl_followmodel_time == time)
127                 return; // cl_followmodel_ofs already calculated for this frame
128
129         float frac;
130         vector gunorg = '0 0 0';
131         static vector vel_average;
132         static vector gunorg_adjustment_highpass;
133         static vector gunorg_adjustment_lowpass;
134
135         vector vel;
136         if (autocvar_cl_followmodel_velocity_absolute)
137                 vel = view.velocity;
138         else
139         {
140                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
141                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
142                 vel.x = view.velocity * forward;
143                 vel.y = view.velocity * right * -1;
144                 vel.z = view.velocity * up;
145         }
146
147         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
148         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
149         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
150
151         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
152         lowpass3(vel, frac, vel_average, gunorg);
153
154         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
155
156         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
157         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
158         frac = avg_factor(autocvar_cl_followmodel_highpass);
159         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
160         frac = avg_factor(autocvar_cl_followmodel_lowpass);
161         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
162
163         if (autocvar_cl_followmodel_velocity_absolute)
164         {
165                 vector fixed_gunorg;
166                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
167                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
168                 fixed_gunorg.x = gunorg * forward;
169                 fixed_gunorg.y = gunorg * right * -1;
170                 fixed_gunorg.z = gunorg * up;
171                 gunorg = fixed_gunorg;
172         }
173
174         cl_followmodel_ofs = gunorg;
175         cl_followmodel_time = time;
176 }
177
178 vector leanmodel_ofs(entity view)
179 {
180         float frac;
181         vector gunangles = '0 0 0';
182         static vector gunangles_prev = '0 0 0';
183         static vector gunangles_highpass = '0 0 0';
184         static vector gunangles_adjustment_highpass;
185         static vector gunangles_adjustment_lowpass;
186
187         if (view.csqcmodel_teleported)
188                 gunangles_prev = view_angles;
189
190         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
191         gunangles_highpass += gunangles_prev;
192         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
193         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
194         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
195         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
196         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
197         gunangles_prev = view_angles;
198         gunangles_highpass -= gunangles_prev;
199
200         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
201         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
202
203         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
204         frac = avg_factor(autocvar_cl_leanmodel_highpass);
205         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
206         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
207         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
208
209         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
210
211         return gunangles;
212 }
213
214 vector bobmodel_ofs(entity view)
215 {
216         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
217         static bool oldonground;
218         static float hitgroundtime;
219         if (clonground)
220         {
221                 float f = time; // cl.movecmd[0].time
222                 if (!oldonground)
223                         hitgroundtime = f;
224         }
225         oldonground = clonground;
226
227         // calculate for swinging gun model
228         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
229         vector gunorg = '0 0 0';
230         static float bobmodel_scale = 0;
231         static float time_ofs = 0; // makes the effect always restart in the same way
232         if (clonground)
233         {
234                 if (time - hitgroundtime > 0.05)
235                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
236         }
237         else
238                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
239
240         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
241         if (bobmodel_scale && xyspeed)
242         {
243                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
244                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
245                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
246                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
247         }
248         else
249                 time_ofs = time;
250
251         return gunorg;
252 }
253
254 void viewmodel_animate(entity this)
255 {
256         if (autocvar_chase_active) return;
257         if (STAT(HEALTH) <= 0) return;
258
259         entity view = CSQCModel_server2csqc(player_localentnum - 1);
260
261         if (autocvar_cl_followmodel)
262         {
263                 calc_followmodel_ofs(view);
264                 this.origin += cl_followmodel_ofs;
265         }
266
267         if (autocvar_cl_leanmodel)
268                 this.angles += leanmodel_ofs(view);
269
270         // vertical view bobbing code
271         // TODO: cl_bob
272
273         // horizontal view bobbing code
274         // TODO: cl_bob2
275
276         // fall bobbing code
277         // causes the view to swing down and back up when touching the ground
278         // TODO: cl_bobfall
279
280         // gun model bobbing code
281         if (autocvar_cl_bobmodel)
282                 this.origin += bobmodel_ofs(view);
283 }
284
285 .vector viewmodel_origin, viewmodel_angles;
286 .float weapon_nextthink;
287 .float weapon_eta_last;
288 .float weapon_switchdelay;
289
290 .string name_last;
291
292 void viewmodel_draw(entity this)
293 {
294         if(!this.activeweapon || !autocvar_r_drawviewmodel)
295                 return;
296         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
297         float a = this.alpha;
298         static bool wasinvehicle;
299         bool invehicle = player_localentnum > maxclients;
300         if (invehicle) a = -1;
301         else if (wasinvehicle) a = 1;
302         wasinvehicle = invehicle;
303         Weapon wep = this.activeweapon;
304         int c = entcs_GetClientColors(current_player);
305         vector g = weaponentity_glowmod(wep, NULL, c, this);
306         entity me = CSQCModel_server2csqc(player_localentnum - 1);
307         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
308                 | EF_NODEPTHTEST)
309                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
310         for (entity e = this; e; e = e.weaponchild)
311         {
312                 e.drawmask = mask;
313                 e.alpha = a;
314                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
315                 e.glowmod = g;
316                 e.csqcmodel_effects = fx;
317                 CSQCModel_Effects_Apply(e);
318         }
319         if(a >= 0)
320         {
321                 string name = wep.mdl;
322                 string newname = wep.wr_viewmodel(wep, this);
323                 if(newname)
324                         name = newname;
325                 bool swap = name != this.name_last;
326                 // if (swap)
327                 {
328                         this.name_last = name;
329                         CL_WeaponEntity_SetModel(this, name, swap);
330                         this.viewmodel_origin = this.origin;
331                         this.viewmodel_angles = this.angles;
332                 }
333                 anim_update(this);
334                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
335                         anim_set(this, this.anim_idle, true, false, false);
336         }
337         float f = 0; // 0..1; 0: fully active
338         float rate = STAT(WEAPONRATEFACTOR);
339         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
340         if (eta <= 0) f = this.weapon_eta_last;
341         else switch (this.state)
342         {
343                 case WS_RAISE:
344                 {
345                         f = eta / max(eta, this.weapon_switchdelay);
346                         break;
347                 }
348                 case WS_DROP:
349                 {
350                         f = 1 - eta / max(eta, this.weapon_switchdelay);
351                         break;
352                 }
353                 case WS_CLEAR:
354                 {
355                         f = 1;
356                         break;
357                 }
358         }
359         this.weapon_eta_last = f;
360         this.origin = this.viewmodel_origin;
361         this.angles = this.viewmodel_angles;
362         this.angles_x = (-90 * f * f);
363         viewmodel_animate(this);
364         MUTATOR_CALLHOOK(DrawViewModel, this);
365         setorigin(this, this.origin);
366 }
367
368 STATIC_INIT(viewmodel) {
369     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
370         viewmodels[slot] = new(viewmodel);
371 }
372
373 void Porto_Draw(entity this);
374 STATIC_INIT(Porto)
375 {
376         entity e = new_pure(porto);
377         e.draw = Porto_Draw;
378         IL_PUSH(g_drawables, e);
379         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
380 }
381
382 const int polyline_length = 16;
383 .vector polyline[polyline_length];
384 void Porto_Draw(entity this)
385 {
386         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
387         {
388                 entity wepent = viewmodels[slot];
389
390                 if (wepent.activeweapon != WEP_PORTO) continue;
391                 if (spectatee_status) continue;
392                 if (WEP_CVAR(porto, secondary)) continue;
393                 if (intermission == 1) continue;
394                 if (intermission == 2) continue;
395                 if (STAT(HEALTH) <= 0) continue;
396
397                 vector pos = view_origin;
398                 vector dir = view_forward;
399                 if (wepent.angles_held_status)
400                 {
401                         makevectors(wepent.angles_held);
402                         dir = v_forward;
403                 }
404
405                 wepent.polyline[0] = pos;
406
407                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
408                 int n = 1 + 2;  // 2 lines == 3 points
409                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
410                 {
411                         traceline(pos, pos + 65536 * dir, true, this);
412                         dir = reflect(dir, trace_plane_normal);
413                         pos = trace_endpos;
414                         wepent.polyline[++idx] = pos;
415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
416                         {
417                                 n += 1;
418                                 continue;
419                         }
420                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
421                         {
422                                 n = max(2, idx);
423                                 break;
424                         }
425                         // check size
426                         {
427                                 vector ang = vectoangles2(trace_plane_normal, dir);
428                                 ang.x = -ang.x;
429                                 makevectors(ang);
430                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
431                                 {
432                                         n = max(2, idx);
433                                         break;
434                                 }
435                         }
436                         portal_number += 1;
437                         if (portal_number >= portal_max) break;
438                         if (portal_number == 1) portal1_idx = idx;
439                 }
440                 for (int idx = 0; idx < n - 1; ++idx)
441                 {
442                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
443                         if (idx == 0) p -= view_up * 16;  // line from player
444                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
445                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
446                 }
447         }
448 }
449
450 float drawtime;
451 float avgspeed;
452 vector GetCurrentFov(float fov)
453 {
454         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
455         float velocityzoom, curspeed;
456         vector v;
457
458         zoomsensitivity = autocvar_cl_zoomsensitivity;
459         zoomfactor = autocvar_cl_zoomfactor;
460         if(zoomfactor < 1 || zoomfactor > 30)
461                 zoomfactor = 2.5;
462         zoomspeed = autocvar_cl_zoomspeed;
463         if(zoomspeed >= 0)
464         if(zoomspeed < 0.5 || zoomspeed > 16)
465                         zoomspeed = 3.5;
466
467         zoomdir = button_zoom;
468
469         if(hud == HUD_NORMAL && !spectatee_status)
470         {
471                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
472                 {
473                         entity wepent = viewmodels[slot];
474                         if(wepent.switchweapon != wepent.activeweapon)
475                                 continue;
476                         Weapon wep = wepent.activeweapon;
477                         if(wep != WEP_Null && wep.wr_zoomdir)
478                         {
479                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
480                                 zoomdir += do_zoom;
481                         }
482                 }
483         }
484         if(spectatee_status > 0 || isdemo())
485         {
486                 if(spectatorbutton_zoom)
487                 {
488                         if(zoomdir)
489                                 zoomdir = 0;
490                         else
491                                 zoomdir = 1;
492                 }
493                 // fteqcc failed twice here already, don't optimize this
494         }
495
496         if(zoomdir) { zoomin_effect = 0; }
497
498         if(camera_active)
499         {
500                 current_viewzoom = min(1, current_viewzoom + drawframetime);
501         }
502         else if(autocvar_cl_spawnzoom && zoomin_effect)
503         {
504                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
505
506                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
507                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
508                 if(current_viewzoom == 1) { zoomin_effect = 0; }
509         }
510         else
511         {
512                 if(zoomspeed < 0) // instant zoom
513                 {
514                         if(zoomdir)
515                                 current_viewzoom = 1 / zoomfactor;
516                         else
517                                 current_viewzoom = 1;
518                 }
519                 else
520                 {
521                         if(zoomdir)
522                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
523                         else
524                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
525                 }
526         }
527
528         if(almost_equals(current_viewzoom, 1))
529                 current_zoomfraction = 0;
530         else if(almost_equals(current_viewzoom, 1/zoomfactor))
531                 current_zoomfraction = 1;
532         else
533                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
534
535         if(zoomsensitivity < 1)
536                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
537         else
538                 setsensitivityscale(1);
539
540         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
541         {
542                 if(intermission) { curspeed = 0; }
543                 else
544                 {
545
546                         makevectors(view_angles);
547                         v = pmove_vel;
548                         if(csqcplayer)
549                                 v = csqcplayer.velocity;
550
551                         switch(autocvar_cl_velocityzoom_type)
552                         {
553                                 case 3: curspeed = max(0, v_forward * v); break;
554                                 case 2: curspeed = (v_forward * v); break;
555                                 case 1: default: curspeed = vlen(v); break;
556                         }
557                 }
558
559                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
560                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
561                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
562
563                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
564         }
565         else
566                 velocityzoom = 1;
567
568         float frustumx, frustumy, fovx, fovy;
569         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
570         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
571         fovx = atan2(frustumx, 1) / M_PI * 360.0;
572         fovy = atan2(frustumy, 1) / M_PI * 360.0;
573
574         return '1 0 0' * fovx + '0 1 0' * fovy;
575 }
576
577 vector GetViewLocationFOV(float fov)
578 {
579         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
580         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
581         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
582         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
583         return '1 0 0' * fovx + '0 1 0' * fovy;
584 }
585
586 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
587 {
588         float fovx, fovy;
589         float width = (ov_worldmax.x - ov_worldmin.x);
590         float height = (ov_worldmax.y - ov_worldmin.y);
591         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
592         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
593         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
594         return '1 0 0' * fovx + '0 1 0' * fovy;
595 }
596
597 // this function must match W_SetupShot!
598 float zoomscript_caught;
599
600 vector wcross_origin;
601 float wcross_scale_prev, wcross_alpha_prev;
602 vector wcross_color_prev;
603 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
604 vector wcross_color_goal_prev;
605 float wcross_changedonetime;
606
607 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
608 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
609 float wcross_name_changestarttime, wcross_name_changedonetime;
610 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
611
612 float wcross_ring_prev;
613
614 entity trueaim;
615 entity trueaim_rifle;
616
617 const float SHOTTYPE_HITTEAM = 1;
618 const float SHOTTYPE_HITOBSTRUCTION = 2;
619 const float SHOTTYPE_HITWORLD = 3;
620 const float SHOTTYPE_HITENEMY = 4;
621
622 void TrueAim_Init()
623 {
624         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
625         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
626 }
627
628 float EnemyHitCheck()
629 {
630         float t, n;
631         wcross_origin = project_3d_to_2d(trace_endpos);
632         wcross_origin.z = 0;
633         if(trace_ent)
634                 n = trace_ent.entnum;
635         else
636                 n = trace_networkentity;
637         if(n < 1)
638                 return SHOTTYPE_HITWORLD;
639         if(n > maxclients)
640                 return SHOTTYPE_HITWORLD;
641         t = entcs_GetTeam(n - 1);
642         if(teamplay)
643                 if(t == myteam)
644                         return SHOTTYPE_HITTEAM;
645         if(t == NUM_SPECTATOR)
646                 return SHOTTYPE_HITWORLD;
647         return SHOTTYPE_HITENEMY;
648 }
649
650 float TrueAimCheck(entity wepent)
651 {
652         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
653         vector vecs, trueaimpoint, w_shotorg;
654         vector mi, ma, dv;
655         float shottype;
656         entity ta;
657         float mv;
658
659         mi = ma = '0 0 0';
660         ta = trueaim;
661         mv = MOVE_NOMONSTERS;
662
663         switch(wepent.activeweapon) // WEAPONTODO
664         {
665                 case WEP_TUBA: // no aim
666                 case WEP_PORTO: // shoots from eye
667                 case WEP_NEXBALL: // shoots from eye
668                 case WEP_HOOK: // no trueaim
669                 case WEP_MORTAR: // toss curve
670                         return SHOTTYPE_HITWORLD;
671                 case WEP_VORTEX:
672                 case WEP_VAPORIZER:
673                         mv = MOVE_NORMAL;
674                         break;
675                 case WEP_RIFLE:
676                         ta = trueaim_rifle;
677                         mv = MOVE_NORMAL;
678                         if(zoomscript_caught)
679                         {
680                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
681                                 return EnemyHitCheck();
682                         }
683                         break;
684                 case WEP_DEVASTATOR: // projectile has a size!
685                         mi = '-3 -3 -3';
686                         ma = '3 3 3';
687                         break;
688                 case WEP_FIREBALL: // projectile has a size!
689                         mi = '-16 -16 -16';
690                         ma = '16 16 16';
691                         break;
692                 case WEP_SEEKER: // projectile has a size!
693                         mi = '-2 -2 -2';
694                         ma = '2 2 2';
695                         break;
696                 case WEP_ELECTRO: // projectile has a size!
697                         mi = '0 0 -3';
698                         ma = '0 0 -3';
699                         break;
700         }
701
702         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
703
704         vecs = decompressShotOrigin(STAT(SHOTORG));
705
706         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
707         trueaimpoint = trace_endpos;
708
709         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
710                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
711
712         if(vecs.x > 0)
713                 vecs.y = -vecs.y;
714         else
715                 vecs = '0 0 0';
716
717         dv = view_right * vecs.y + view_up * vecs.z;
718         w_shotorg = traceorigin + dv;
719
720         // now move the vecs forward as much as requested if possible
721         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
722         w_shotorg = trace_endpos - view_forward * nudge;
723
724         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
725         shottype = EnemyHitCheck();
726         if(shottype != SHOTTYPE_HITWORLD)
727                 return shottype;
728
729 #if 0
730         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
731         // or rather, I know why, but see no fix
732         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
733                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
734                 return SHOTTYPE_HITOBSTRUCTION;
735 #endif
736
737         return SHOTTYPE_HITWORLD;
738 }
739
740 void PostInit();
741 void CSQC_Demo_Camera();
742 float camera_mode;
743 const float CAMERA_FREE = 1;
744 const float CAMERA_CHASE = 2;
745 float reticle_type;
746 string NextFrameCommand;
747
748 vector freeze_org, freeze_ang;
749 entity nightvision_noise, nightvision_noise2;
750
751 const float MAX_TIME_DIFF = 5;
752 float pickup_crosshair_time, pickup_crosshair_size;
753 float hitindication_crosshair_size;
754 float use_vortex_chargepool;
755
756 float myhealth, myhealth_prev;
757 float myhealth_flash;
758
759 float old_blurradius, old_bluralpha;
760 float old_sharpen_intensity;
761
762 vector myhealth_gentlergb;
763
764 float contentavgalpha, liquidalpha_prev;
765 vector liquidcolor_prev;
766
767 float eventchase_current_distance;
768 float eventchase_running;
769 bool WantEventchase(entity this)
770 {
771         if(autocvar_cl_orthoview)
772                 return false;
773         if(STAT(GAME_STOPPED) || intermission)
774                 return true;
775         if(this.viewloc)
776                 return true;
777         if(spectatee_status >= 0)
778         {
779                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
780                         return true;
781                 if(MUTATOR_CALLHOOK(WantEventchase, this))
782                         return true;
783                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
784                         return true;
785                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
786                 {
787                         if(autocvar_cl_eventchase_death == 2)
788                         {
789                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
790                                 if(this.velocity == '0 0 0' || eventchase_running)
791                                         return true;
792                         }
793                         else return true;
794                 }
795         }
796         return false;
797 }
798
799 void HUD_Crosshair_Vehicle(entity this)
800 {
801         if(hud != HUD_BUMBLEBEE_GUN)
802         {
803                 Vehicle info = Vehicles_from(hud);
804                 info.vr_crosshair(info, this);
805         }
806 }
807
808 vector damage_blurpostprocess, content_blurpostprocess;
809
810 float unaccounted_damage = 0;
811 void UpdateDamage()
812 {
813         // accumulate damage with each stat update
814         static float damage_total_prev = 0;
815         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
816         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
817         damage_total_prev = damage_total;
818
819         static float damage_dealt_time_prev = 0;
820         float damage_dealt_time = STAT(HIT_TIME);
821         if (damage_dealt_time != damage_dealt_time_prev)
822         {
823                 unaccounted_damage += unaccounted_damage_new;
824                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
825         }
826         damage_dealt_time_prev = damage_dealt_time;
827
828         // prevent hitsound when switching spectatee
829         static float spectatee_status_prev = 0;
830         if (spectatee_status != spectatee_status_prev)
831                 unaccounted_damage = 0;
832         spectatee_status_prev = spectatee_status;
833 }
834
835 void HitSound()
836 {
837         // varying sound pitch
838
839         bool have_arc = false;
840         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
841         {
842                 entity wepent = viewmodels[slot];
843
844                 if(wepent.activeweapon == WEP_ARC)
845                         have_arc = true;
846         }
847
848         static float hitsound_time_prev = 0;
849         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
850         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
851         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
852         {
853                 if (autocvar_cl_hitsound && unaccounted_damage)
854                 {
855                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
856                         float a = autocvar_cl_hitsound_max_pitch;
857                         float b = autocvar_cl_hitsound_min_pitch;
858                         float c = autocvar_cl_hitsound_nom_damage;
859                         float d = unaccounted_damage;
860                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
861
862                         // if sound variation is disabled, set pitch_shift to 1
863                         if (autocvar_cl_hitsound == 1)
864                                 pitch_shift = 1;
865
866                         // if pitch shift is reversed, mirror in (max-min)/2 + min
867                         if (autocvar_cl_hitsound == 3)
868                         {
869                                 float mirror_value = (a-b)/2 + b;
870                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
871                         }
872
873                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
874
875                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
876                         // todo: normalize sound pressure levels? seems unnecessary
877
878                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
879                 }
880                 unaccounted_damage = 0;
881                 hitsound_time_prev = time;
882         }
883
884         static float typehit_time_prev = 0;
885         float typehit_time = STAT(TYPEHIT_TIME);
886         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
887         {
888                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
889                 typehit_time_prev = typehit_time;
890         }
891
892         static float kill_time_prev = 0;
893         float kill_time = STAT(KILL_TIME);
894         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
895         {
896                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
897                 kill_time_prev = kill_time;
898         }
899 }
900
901 vector crosshair_getcolor(entity this, float health_stat)
902 {
903         static float rainbow_last_flicker;
904         static vector rainbow_prev_color;
905         vector wcross_color = '0 0 0';
906         switch(autocvar_crosshair_color_special)
907         {
908                 case 1: // crosshair_color_per_weapon
909                 {
910                         if(this != WEP_Null && hud == HUD_NORMAL)
911                         {
912                                 wcross_color = this.wpcolor;
913                                 break;
914                         }
915                         else { goto normalcolor; }
916                 }
917
918                 case 2: // crosshair_color_by_health
919                 {
920                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
921                         float hp = floor(v.x + 1);
922
923                         //x = red
924                         //y = green
925                         //z = blue
926
927                         wcross_color.z = 0;
928
929                         if(hp > 200)
930                         {
931                                 wcross_color.x = 0;
932                                 wcross_color.y = 1;
933                         }
934                         else if(hp > 150)
935                         {
936                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
937                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
938                         }
939                         else if(hp > 100)
940                         {
941                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
942                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
943                                 wcross_color.z = 1 - (hp-100)*0.02;
944                         }
945                         else if(hp > 50)
946                         {
947                                 wcross_color.x = 1;
948                                 wcross_color.y = 1;
949                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
950                         }
951                         else if(hp > 20)
952                         {
953                                 wcross_color.x = 1;
954                                 wcross_color.y = (hp-20)*90/27/100;
955                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
956                         }
957                         else
958                         {
959                                 wcross_color.x = 1;
960                                 wcross_color.y = 0;
961                         }
962                         break;
963                 }
964
965                 case 3: // crosshair_color_rainbow
966                 {
967                         if(time >= rainbow_last_flicker)
968                         {
969                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
970                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
971                         }
972                         wcross_color = rainbow_prev_color;
973                         break;
974                 }
975 LABEL(normalcolor)
976                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
977         }
978
979         return wcross_color;
980 }
981
982 void HUD_Crosshair(entity this)
983 {
984         float f, i, j;
985         vector v;
986         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
987                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
988                 !HUD_MinigameMenu_IsOpened() )
989         {
990                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
991                         return;
992
993                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
994                         return;
995
996                 if (hud != HUD_NORMAL)
997                 {
998                         HUD_Crosshair_Vehicle(this);
999                         return;
1000                 }
1001
1002                 string wcross_style;
1003                 float wcross_alpha, wcross_resolution;
1004                 wcross_style = autocvar_crosshair;
1005                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1006                         wcross_style = autocvar_crosshair_2d;
1007                 if (wcross_style == "0")
1008                         return;
1009                 wcross_resolution = autocvar_crosshair_size;
1010                 if (wcross_resolution == 0)
1011                         return;
1012                 wcross_alpha = autocvar_crosshair_alpha;
1013                 if (wcross_alpha == 0)
1014                         return;
1015
1016                 // TrueAim check
1017                 float shottype;
1018
1019                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1020                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1021                         wcross_origin = viewloc_mousepos;
1022                 else
1023                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1024                 wcross_origin.z = 0;
1025                 if(autocvar_crosshair_hittest)
1026                 {
1027                         vector wcross_oldorigin;
1028                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1029                         wcross_oldorigin = wcross_origin;
1030                         shottype = TrueAimCheck(thiswep);
1031                         if(shottype == SHOTTYPE_HITWORLD)
1032                         {
1033                                 v = wcross_origin - wcross_oldorigin;
1034                                 v.x /= vid_conwidth;
1035                                 v.y /= vid_conheight;
1036                                 if(vdist(v, >, 0.01))
1037                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1038                         }
1039                         if(!autocvar_crosshair_hittest_showimpact)
1040                                 wcross_origin = wcross_oldorigin;
1041                 }
1042                 else
1043                         shottype = SHOTTYPE_HITWORLD;
1044
1045                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1046                 string wcross_name = "";
1047                 float wcross_scale, wcross_blur;
1048
1049         entity e = WEP_Null;
1050                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1051                 {
1052                         entity wepent = viewmodels[0]; // TODO: unhardcode
1053                         e = wepent.switchingweapon;
1054                         if(e)
1055                         {
1056                                 if(autocvar_crosshair_per_weapon)
1057                                 {
1058                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1059                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1060                                         //if (wcross_resolution == 0)
1061                                                 //return;
1062
1063                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1064                                         wcross_resolution *= e.w_crosshair_size;
1065                                         wcross_name = e.w_crosshair;
1066                                 }
1067                         }
1068                 }
1069
1070                 if(wcross_name == "")
1071                         wcross_name = strcat("gfx/crosshair", wcross_style);
1072
1073                 // MAIN CROSSHAIR COLOR DECISION
1074                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1075
1076                 if(autocvar_crosshair_effect_scalefade)
1077                 {
1078                         wcross_scale = wcross_resolution;
1079                         wcross_resolution = 1;
1080                 }
1081                 else
1082                 {
1083                         wcross_scale = 1;
1084                 }
1085
1086                 if(autocvar_crosshair_pickup)
1087                 {
1088                         float stat_pickup_time = STAT(LAST_PICKUP);
1089
1090                         if(pickup_crosshair_time < stat_pickup_time)
1091                         {
1092                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1093                                         pickup_crosshair_size = 1;
1094
1095                                 pickup_crosshair_time = stat_pickup_time;
1096                         }
1097
1098                         if(pickup_crosshair_size > 0)
1099                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1100                         else
1101                                 pickup_crosshair_size = 0;
1102
1103                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1104                 }
1105
1106                 // todo: make crosshair hit indication dependent on damage dealt
1107                 if(autocvar_crosshair_hitindication)
1108                 {
1109                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1110
1111                         if(unaccounted_damage)
1112                         {
1113                                 hitindication_crosshair_size = 1;
1114                         }
1115
1116                         if(hitindication_crosshair_size > 0)
1117                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1118                         else
1119                                 hitindication_crosshair_size = 0;
1120
1121                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1122                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1123                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1124                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1125                 }
1126
1127                 if(shottype == SHOTTYPE_HITENEMY)
1128                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1129                 if(shottype == SHOTTYPE_HITTEAM)
1130                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1131
1132                 f = fabs(autocvar_crosshair_effect_time);
1133                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1134                 {
1135                         wcross_changedonetime = time + f;
1136                 }
1137                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1138                 {
1139                         wcross_name_changestarttime = time;
1140                         wcross_name_changedonetime = time + f;
1141                         if(wcross_name_goal_prev_prev)
1142                                 strunzone(wcross_name_goal_prev_prev);
1143                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1144                         wcross_name_goal_prev = strzone(wcross_name);
1145                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1146                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1147                         wcross_resolution_goal_prev = wcross_resolution;
1148                 }
1149
1150                 wcross_scale_goal_prev = wcross_scale;
1151                 wcross_alpha_goal_prev = wcross_alpha;
1152                 wcross_color_goal_prev = wcross_color;
1153
1154                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1155                 {
1156                         wcross_blur = 1;
1157                         wcross_alpha *= 0.75;
1158                 }
1159                 else
1160                         wcross_blur = 0;
1161                 // *_prev is at time-frametime
1162                 // * is at wcross_changedonetime+f
1163                 // what do we have at time?
1164                 if(time < wcross_changedonetime)
1165                 {
1166                         f = frametime / (wcross_changedonetime - time + frametime);
1167                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1168                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1169                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1170                 }
1171
1172                 wcross_scale_prev = wcross_scale;
1173                 wcross_alpha_prev = wcross_alpha;
1174                 wcross_color_prev = wcross_color;
1175
1176                 MUTATOR_CALLHOOK(UpdateCrosshair);
1177
1178                 wcross_scale *= 1 - autocvar__menu_alpha;
1179                 wcross_alpha *= 1 - autocvar__menu_alpha;
1180                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1181
1182                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1183                 {
1184                         // crosshair rings for weapon stats
1185                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1186                         {
1187                                 // declarations and stats
1188                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1189                                 string ring_image = string_null, ring_inner_image = string_null;
1190                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1191
1192                                 ring_scale = autocvar_crosshair_ring_size;
1193
1194                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1195
1196                                 int weapon_clipload = wepent.clip_load;
1197                                 int weapon_clipsize = wepent.clip_size;
1198
1199                                 float arc_heat = wepent.arc_heat_percent;
1200                                 float vcharge = wepent.vortex_charge;
1201                                 float vchargepool = wepent.vortex_chargepool_ammo;
1202
1203                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1204                                         vortex_charge_movingavg = vcharge;
1205
1206                                 // handle the values
1207                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1208                                 {
1209                                         if (vchargepool || use_vortex_chargepool) {
1210                                                 use_vortex_chargepool = 1;
1211                                                 ring_inner_value = vchargepool;
1212                                         } else {
1213                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1214                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1215                                         }
1216
1217                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1218                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1219                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1220
1221                                         // draw the outer ring to show the current charge of the weapon
1222                                         ring_value = vcharge;
1223                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1224                                         ring_rgb = wcross_color;
1225                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1226                                 }
1227                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1228                                 {
1229                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1230                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1231                                         ring_rgb = wcross_color;
1232                                         ring_image = "gfx/crosshair_ring.tga";
1233                                 }
1234                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1235                                 {
1236                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1237                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1238                                         ring_rgb = wcross_color;
1239                                         ring_image = "gfx/crosshair_ring.tga";
1240                                 }
1241                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1242                                 {
1243                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1244                                         ring_scale = autocvar_crosshair_ring_reload_size;
1245                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1246                                         ring_rgb = wcross_color;
1247
1248                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1249                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1250                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1251                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1252                                         else
1253                                                 ring_image = "gfx/crosshair_ring.tga";
1254                                 }
1255                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1256                                 {
1257                                         ring_value = arc_heat;
1258                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1259                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1260                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1261                                         ring_image = "gfx/crosshair_ring.tga";
1262                                 }
1263
1264                                 // if in weapon switch animation, fade ring out/in
1265                                 if(autocvar_crosshair_effect_time > 0)
1266                                 {
1267                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1268                                         if (f >= 1)
1269                                         {
1270                                                 wcross_ring_prev = ((ring_image) ? true : false);
1271                                         }
1272
1273                                         if(wcross_ring_prev)
1274                                         {
1275                                                 if(f < 1)
1276                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1277                                         }
1278                                         else
1279                                         {
1280                                                 if(f < 1)
1281                                                         ring_alpha *= bound(0, f, 1);
1282                                         }
1283                                 }
1284
1285                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1286                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1287
1288                                 if (ring_value)
1289                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1290                         }
1291
1292 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1293                         MACRO_BEGIN { \
1294                                 if(wcross_blur > 0) \
1295                                 { \
1296                                         for(i = -2; i <= 2; ++i) \
1297                                         for(j = -2; j <= 2; ++j) \
1298                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1299                                 } \
1300                                 else \
1301                                 { \
1302                                         M(0,0,sz,wcross_name,wcross_alpha); \
1303                                 } \
1304                         } MACRO_END
1305
1306 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1307                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1308
1309 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1310                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1311
1312                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1313                         {
1314                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1315                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1316                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1317                                 f = 1 - f;
1318                         }
1319                         else
1320                         {
1321                                 f = 1;
1322                         }
1323                         wcross_name_alpha_goal_prev = f;
1324
1325                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1326                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1327
1328                         if(autocvar_crosshair_dot)
1329                         {
1330                                 vector wcross_color_old;
1331                                 wcross_color_old = wcross_color;
1332
1333                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1334                                         wcross_color = stov(autocvar_crosshair_dot_color);
1335
1336                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1337                                 // FIXME why don't we use wcross_alpha here?
1338                                 wcross_color = wcross_color_old;
1339                         }
1340                 }
1341         }
1342         else
1343         {
1344                 wcross_scale_prev = 0;
1345                 wcross_alpha_prev = 0;
1346                 wcross_scale_goal_prev = 0;
1347                 wcross_alpha_goal_prev = 0;
1348                 wcross_changedonetime = 0;
1349                 if(wcross_name_goal_prev)
1350                         strunzone(wcross_name_goal_prev);
1351                 wcross_name_goal_prev = string_null;
1352                 if(wcross_name_goal_prev_prev)
1353                         strunzone(wcross_name_goal_prev_prev);
1354                 wcross_name_goal_prev_prev = string_null;
1355                 wcross_name_changestarttime = 0;
1356                 wcross_name_changedonetime = 0;
1357                 wcross_name_alpha_goal_prev = 0;
1358                 wcross_name_alpha_goal_prev_prev = 0;
1359                 wcross_resolution_goal_prev = 0;
1360                 wcross_resolution_goal_prev_prev = 0;
1361         }
1362 }
1363
1364 const int MAX_SPECIALCOMMAND = 15;
1365 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1366 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1367 const float SPECIALCOMMAND_SPEED = 150;
1368 const float SPECIALCOMMAND_TURNSPEED = 2;
1369 const float SPECIALCOMMAND_SIZE = 0.025;
1370 const float SPECIALCOMMAND_CHANCE = 0.35;
1371 float sc_spawntime, sc_changetime;
1372 vector sc_color = '1 1 1';
1373 void SpecialCommand()
1374 {
1375         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1376                 return;
1377
1378         if(time >= sc_changetime)
1379         {
1380                 sc_changetime = time + 1;
1381                 sc_color = randomvec() * 1.5;
1382                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1383                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1384                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1385         }
1386         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1387
1388         if(!precache_pic("gfx/smile"))
1389                 return; // damn party poopers
1390
1391         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1392         {
1393                 vector slot = specialcommand_slots[j];
1394                 if(slot.y)
1395                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1396                 if(slot.z)
1397                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1398                 if(slot.y >= vid_conheight)
1399                         slot = '0 0 0';
1400
1401                 if(slot == '0 0 0')
1402                 {
1403                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1404                         {
1405                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1406                                 slot.y = 1; // start it off 0 so we can use it
1407                                 slot.z = random();
1408                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1409                                 vector newcolor = randomvec() * 2;
1410                                 newcolor.x = bound(0.4, newcolor.x, 1);
1411                                 newcolor.y = bound(0.4, newcolor.y, 1);
1412                                 newcolor.z = bound(0.4, newcolor.z, 1);
1413                                 specialcommand_colors[j] = newcolor;
1414                         }
1415                 }
1416                 else
1417                 {
1418                         vector splash_size = '0 0 0';
1419                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1420                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1421                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1422                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1423                 }
1424
1425                 specialcommand_slots[j] = slot;
1426         }
1427 }
1428
1429 void HUD_Draw(entity this)
1430 {
1431         // if we don't know gametype and scores yet avoid drawing the scoreboard
1432         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1433         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1434         // cl_deathscoreboard would show the scoreboard and so on
1435         if(!gametype)
1436                 return;
1437
1438         Hud_Dynamic_Frame();
1439
1440         if(!intermission)
1441         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1442         {
1443                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1444         }
1445         else if(STAT(FROZEN))
1446         {
1447                 vector col = '0.25 0.90 1';
1448                 if(STAT(REVIVE_PROGRESS))
1449                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1450                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1451         }
1452
1453         HUD_Scale_Enable();
1454         if(!intermission)
1455         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1456         {
1457                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1458                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1459                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1460         }
1461         else if(STAT(CAPTURE_PROGRESS))
1462         {
1463                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1464                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1465         }
1466         else if(STAT(REVIVE_PROGRESS))
1467         {
1468                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1469                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1470         }
1471         HUD_Scale_Disable();
1472
1473         if(autocvar_r_letterbox == 0)
1474                 if(autocvar_viewsize < 120)
1475                 {
1476                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1477                                 Accuracy_LoadLevels();
1478
1479                         HUD_Main();
1480                         HUD_Scale_Disable();
1481                 }
1482
1483         // crosshair goes VERY LAST
1484         SpecialCommand();
1485         UpdateDamage();
1486         HUD_Crosshair(this);
1487         HitSound();
1488 }
1489
1490 void ViewLocation_Mouse()
1491 {
1492         if(spectatee_status)
1493                 return; // don't draw it as spectator!
1494
1495         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1496         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1497         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1498
1499         //float cursor_alpha = 1 - autocvar__menu_alpha;
1500         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1501 }
1502
1503 bool ov_enabled;
1504 float oldr_nearclip;
1505 float oldr_farclip_base;
1506 float oldr_farclip_world;
1507 float oldr_novis;
1508 float oldr_useportalculling;
1509 float oldr_useinfinitefarclip;
1510
1511 void cl_notice_run();
1512
1513 float prev_myteam;
1514 int lasthud;
1515 float vh_notice_time;
1516 void WaypointSprite_Load();
1517 void CSQC_UpdateView(entity this, float w, float h)
1518 {
1519     TC(int, w); TC(int, h);
1520         entity e;
1521         float fov;
1522         float f;
1523         vector vf_size, vf_min;
1524         float a;
1525
1526         execute_next_frame();
1527
1528         ++framecount;
1529
1530         stats_get();
1531         hud = STAT(HUD);
1532
1533         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1534                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1535
1536         lasthud = hud;
1537
1538         HUD_Scale_Disable();
1539
1540         if(autocvar__hud_showbinds_reload) // menu can set this one
1541         {
1542                 db_close(binddb);
1543                 binddb = db_create();
1544                 cvar_set("_hud_showbinds_reload", "0");
1545         }
1546
1547         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1548                 view_quality = getproperty(VF_MINFPS_QUALITY);
1549         else
1550                 view_quality = 1;
1551
1552         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1553         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1554
1555         vf_size = getpropertyvec(VF_SIZE);
1556         vf_min = getpropertyvec(VF_MIN);
1557         vid_width = vf_size.x;
1558         vid_height = vf_size.y;
1559
1560         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1561         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1562
1563         WaypointSprite_Load();
1564
1565         CSQCPlayer_SetCamera();
1566
1567         if(player_localentnum <= maxclients) // is it a client?
1568                 current_player = player_localentnum - 1;
1569         else // then player_localentnum is the vehicle I'm driving
1570                 current_player = player_localnum;
1571         myteam = entcs_GetTeam(current_player);
1572
1573         if(myteam != prev_myteam)
1574         {
1575                 myteamcolors = colormapPaletteColor(myteam, 1);
1576                 FOREACH(hud_panels, true, it.update_time = time);
1577                 prev_myteam = myteam;
1578         }
1579
1580         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1581
1582         float is_dead = (STAT(HEALTH) <= 0);
1583
1584         // FIXME do we need this hack?
1585         if(isdemo())
1586         {
1587                 // in demos, input_buttons do not work
1588                 button_zoom = (autocvar__togglezoom == "-");
1589         }
1590         else if(button_zoom
1591                 && autocvar_cl_unpress_zoom_on_death
1592                 && (spectatee_status >= 0)
1593                 && (is_dead || intermission))
1594         {
1595                 // no zoom while dead or in intermission please
1596                 localcmd("-zoom\n");
1597                 button_zoom = false;
1598         }
1599
1600         // abused multiple places below
1601         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1602         if(!local_player)
1603                 local_player = this; // fall back!
1604
1605         // event chase camera
1606         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1607         {
1608                 if(STAT(CAMERA_SPECTATOR))
1609                 {
1610                         if(spectatee_status > 0)
1611                         {
1612                                 if(!autocvar_chase_active)
1613                                 {
1614                                         cvar_set("chase_active", "-2");
1615                                         goto skip_eventchase_death;
1616                                 }
1617                         }
1618                         else if(autocvar_chase_active == -2)
1619                                 cvar_set("chase_active", "0");
1620
1621                         if(autocvar_chase_active == -2)
1622                                 goto skip_eventchase_death;
1623                 }
1624                 else if(autocvar_chase_active == -2)
1625                         cvar_set("chase_active", "0");
1626
1627                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1628
1629                 float vehicle_viewdist = 0;
1630                 vector vehicle_viewofs = '0 0 0';
1631
1632                 if(vehicle_chase)
1633                 {
1634                         if(hud != HUD_BUMBLEBEE_GUN)
1635                         {
1636                                 Vehicle info = Vehicles_from(hud);
1637                                 vehicle_viewdist = info.height;
1638                                 vehicle_viewofs = info.view_ofs;
1639                         }
1640                 }
1641
1642                 if(WantEventchase(this))
1643                 {
1644                         vector current_view_origin_override = '0 0 0';
1645                         vector view_offset_override = '0 0 0';
1646                         float chase_distance_override = 0;
1647                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1648                         if(custom_eventchase)
1649                         {
1650                                 current_view_origin_override = M_ARGV(0, vector);
1651                                 view_offset_override = M_ARGV(1, vector);
1652                                 chase_distance_override = M_ARGV(0, float);
1653                         }
1654                         eventchase_running = true;
1655
1656                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1657                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1658                         if (custom_eventchase)
1659                                 current_view_origin = current_view_origin_override;
1660
1661                         // detect maximum viewoffset and use it
1662                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1663                         if(vehicle_chase)
1664                         {
1665                                 if(vehicle_viewofs)
1666                                         view_offset = vehicle_viewofs;
1667                                 else
1668                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1669                         }
1670                         if (custom_eventchase)
1671                                 view_offset = view_offset_override;
1672
1673                         if(view_offset)
1674                         {
1675                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1676                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1677                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1678                         }
1679
1680                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1681                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1682                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1683                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1684
1685                         // make the camera smooth back
1686                         float chase_distance = autocvar_cl_eventchase_distance;
1687                         if(vehicle_chase)
1688                         {
1689                                 if(vehicle_viewofs)
1690                                         chase_distance = vehicle_viewdist;
1691                                 else
1692                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1693                         }
1694                         if (custom_eventchase)
1695                                 chase_distance = chase_distance_override;
1696
1697                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1698                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1699                         else if(eventchase_current_distance != chase_distance)
1700                                 eventchase_current_distance = chase_distance;
1701
1702                         makevectors(view_angles);
1703
1704                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1705                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1706
1707                         // If the boxtrace fails, revert back to line tracing.
1708                         if(!local_player.viewloc)
1709                         if(trace_startsolid)
1710                         {
1711                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1712                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1713                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1714                         }
1715                         else { setproperty(VF_ORIGIN, trace_endpos); }
1716
1717                         if(!local_player.viewloc)
1718                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1719                 }
1720                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1721                 {
1722                         eventchase_running = false;
1723                         cvar_set("chase_active", "0");
1724                         eventchase_current_distance = 0; // start from 0 next time
1725                 }
1726         }
1727         // workaround for camera stuck between player's legs when using chase_active 1
1728         // because the engine stops updating the chase_active camera when the game ends
1729         else if(intermission)
1730         {
1731                 cvar_settemp("chase_active", "-1");
1732                 eventchase_current_distance = 0;
1733         }
1734
1735         LABEL(skip_eventchase_death);
1736
1737         // do lockview after event chase camera so that it still applies whenever necessary.
1738         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1739         {
1740                 setproperty(VF_ORIGIN, freeze_org);
1741                 setproperty(VF_ANGLES, freeze_ang);
1742         }
1743         else
1744         {
1745                 freeze_org = getpropertyvec(VF_ORIGIN);
1746                 freeze_ang = getpropertyvec(VF_ANGLES);
1747         }
1748
1749         WarpZone_FixView();
1750         //WarpZone_FixPMove();
1751
1752         vector ov_org = '0 0 0';
1753         vector ov_mid = '0 0 0';
1754         vector ov_worldmin = '0 0 0';
1755         vector ov_worldmax = '0 0 0';
1756         if(autocvar_cl_orthoview)
1757         {
1758                 ov_worldmin = mi_picmin;
1759                 ov_worldmax = mi_picmax;
1760
1761                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1762                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1763                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1764
1765                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1766                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1767
1768                 float ov_nearest = vlen(ov_org - vec3(
1769                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1770                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1771                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1772                 ));
1773
1774                 float ov_furthest = 0;
1775                 float dist = 0;
1776
1777                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1778                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1779                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1780                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1781                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1782                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1783                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1784                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1785
1786                 if(!ov_enabled)
1787                 {
1788                         oldr_nearclip = cvar("r_nearclip");
1789                         oldr_farclip_base = cvar("r_farclip_base");
1790                         oldr_farclip_world = cvar("r_farclip_world");
1791                         oldr_novis = cvar("r_novis");
1792                         oldr_useportalculling = cvar("r_useportalculling");
1793                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1794                 }
1795
1796                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1797                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1798                 cvar_settemp("r_farclip_world", "0");
1799                 cvar_settemp("r_novis", "1");
1800                 cvar_settemp("r_useportalculling", "0");
1801                 cvar_settemp("r_useinfinitefarclip", "0");
1802
1803                 setproperty(VF_ORIGIN, ov_org);
1804                 setproperty(VF_ANGLES, '90 0 0');
1805
1806                 ov_enabled = true;
1807
1808                 #if 0
1809                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1810                         vtos(ov_org),
1811                         vtos(getpropertyvec(VF_ANGLES)),
1812                         ov_distance,
1813                         ov_nearest,
1814                         ov_furthest);
1815                 #endif
1816         }
1817         else
1818         {
1819                 if(ov_enabled)
1820                 {
1821                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1822                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1823                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1824                         cvar_set("r_novis", ftos(oldr_novis));
1825                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1826                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1827                 }
1828                 ov_enabled = false;
1829         }
1830
1831         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1832         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1833         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1834                 viewmodel_draw(viewmodels[slot]);
1835
1836         // Render the Scene
1837         view_origin = getpropertyvec(VF_ORIGIN);
1838         view_angles = getpropertyvec(VF_ANGLES);
1839         makevectors(view_angles);
1840         view_forward = v_forward;
1841         view_right = v_right;
1842         view_up = v_up;
1843
1844 #ifdef BLURTEST
1845         if(time > blurtest_time0 && time < blurtest_time1)
1846         {
1847                 float r, t;
1848
1849                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1850                 r = t * blurtest_radius;
1851                 f = 1 / (t ** blurtest_power) - 1;
1852
1853                 cvar_set("r_glsl_postprocess", "1");
1854                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1855         }
1856         else
1857         {
1858                 cvar_set("r_glsl_postprocess", "0");
1859                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1860         }
1861 #endif
1862
1863         TargetMusic_Advance();
1864         Fog_Force();
1865
1866         if(drawtime == 0)
1867                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1868         else
1869                 drawframetime = bound(0.000001, time - drawtime, 1);
1870         drawtime = time;
1871
1872         // watch for gametype changes here...
1873         // in ParseStuffCMD the cmd isn't executed yet :/
1874         // might even be better to add the gametype to TE_CSQC_INIT...?
1875         if(!postinit)
1876                 PostInit();
1877
1878         if(intermission && !intermission_time)
1879                 intermission_time = time;
1880
1881         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1882         {
1883                 if(calledhooks & HOOK_START)
1884                 {
1885                         localcmd("\ncl_hook_gameend\n");
1886                         calledhooks |= HOOK_END;
1887                 }
1888         }
1889
1890         Announcer();
1891
1892         fov = autocvar_fov;
1893         if(fov <= 59.5)
1894         {
1895                 if(!zoomscript_caught)
1896                 {
1897                         localcmd("+button9\n");
1898                         zoomscript_caught = 1;
1899                 }
1900         }
1901         else
1902         {
1903                 if(zoomscript_caught)
1904                 {
1905                         localcmd("-button9\n");
1906                         zoomscript_caught = 0;
1907                 }
1908         }
1909
1910         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1911
1912         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1913         {
1914                 entity wepent = viewmodels[slot];
1915
1916                 if(wepent.last_switchweapon != wepent.switchweapon)
1917                 {
1918                         weapontime = time;
1919                         wepent.last_switchweapon = wepent.switchweapon;
1920                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1921                         {
1922                                 localcmd("-zoom\n");
1923                                 button_zoom = false;
1924                         }
1925                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1926                         {
1927                                 localcmd("-fire\n");
1928                                 localcmd("-fire2\n");
1929                                 button_attack2 = false;
1930                         }
1931                 }
1932                 if(wepent.last_activeweapon != wepent.activeweapon)
1933                 {
1934                         wepent.last_activeweapon = wepent.activeweapon;
1935
1936                         e = wepent.activeweapon;
1937                         if(e.netname != "")
1938                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1939                         else if(slot == 0)
1940                                 localcmd("\ncl_hook_activeweapon none\n");
1941                 }
1942         }
1943
1944         // ALWAYS Clear Current Scene First
1945         clearscene();
1946
1947         setproperty(VF_ORIGIN, view_origin);
1948         setproperty(VF_ANGLES, view_angles);
1949
1950         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1951         setproperty(VF_SIZE, vf_size);
1952         setproperty(VF_MIN, vf_min);
1953
1954         // Assign Standard Viewflags
1955         // Draw the World (and sky)
1956         setproperty(VF_DRAWWORLD, 1);
1957
1958         // Set the console size vars
1959         vid_conwidth = autocvar_vid_conwidth;
1960         vid_conheight = autocvar_vid_conheight;
1961         vid_pixelheight = autocvar_vid_pixelheight;
1962
1963         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1964         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1965         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1966
1967         if(camera_active) // Camera for demo playback
1968         {
1969                 if(autocvar_camera_enable)
1970                         CSQC_Demo_Camera();
1971                 else
1972                 {
1973                         cvar_set("chase_active", ftos(chase_active_backup));
1974                         cvar_set("cl_demo_mousegrab", "0");
1975                         camera_active = false;
1976                 }
1977         }
1978         else
1979         {
1980 #ifdef CAMERATEST
1981                 if(autocvar_camera_enable)
1982 #else
1983                 if(autocvar_camera_enable && isdemo())
1984 #endif
1985                 {
1986                         // Enable required Darkplaces cvars
1987                         chase_active_backup = autocvar_chase_active;
1988                         cvar_set("chase_active", "2");
1989                         cvar_set("cl_demo_mousegrab", "1");
1990                         camera_active = true;
1991                         camera_mode = false;
1992                 }
1993         }
1994
1995         // Draw the Crosshair
1996         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1997
1998         // Draw the Engine Status Bar (the default Quake HUD)
1999         setproperty(VF_DRAWENGINESBAR, 0);
2000
2001         // Update the mouse position
2002         /*
2003            mousepos_x = vid_conwidth;
2004            mousepos_y = vid_conheight;
2005            mousepos = mousepos*0.5 + getmousepos();
2006          */
2007
2008         IL_EACH(g_drawables, it.draw, it.draw(it));
2009
2010         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2011         renderscene();
2012
2013         // now switch to 2D drawing mode by calling a 2D drawing function
2014         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2015         // next R_RenderScene call
2016         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2017
2018         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2019         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2020         {
2021                 // apply night vision effect
2022                 vector tc_00, tc_01, tc_10, tc_11;
2023                 vector rgb = '0 0 0';
2024
2025                 if(!nightvision_noise)
2026                 {
2027                         nightvision_noise = new(nightvision_noise);
2028                 }
2029                 if(!nightvision_noise2)
2030                 {
2031                         nightvision_noise2 = new(nightvision_noise2);
2032                 }
2033
2034                 // color tint in yellow
2035                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2036
2037                 // draw BG
2038                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2039                 rgb = '1 1 1';
2040                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2041                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2042                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2043                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2044                 tc_11 = tc_01 + tc_10 - tc_00;
2045                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2046                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2047                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2048                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2049                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2050                 R_EndPolygon();
2051
2052                 // draw FG
2053                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2054                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2055                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2056                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2057                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2058                 tc_11 = tc_01 + tc_10 - tc_00;
2059                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2060                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2061                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2062                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2063                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2064                 R_EndPolygon();
2065         }
2066
2067         if(autocvar_cl_reticle)
2068         {
2069                 string reticle_image = string_null;
2070                 bool wep_zoomed = false;
2071                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2072                 {
2073                         entity wepe = viewmodels[slot];
2074                         Weapon wep = wepe.activeweapon;
2075                         if(wep != WEP_Null && wep.wr_zoom)
2076                         {
2077                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2078                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2079                                         reticle_image = wep.w_reticle;
2080                                 wep_zoomed += do_zoom;
2081                         }
2082                 }
2083                 // Draw the aiming reticle for weapons that use it
2084                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2085                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2086                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2087                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2088                 {
2089                         // no zoom reticle while dead
2090                         reticle_type = 0;
2091                 }
2092                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2093                 {
2094                         if(reticle_image) { reticle_type = 2; }
2095                         else { reticle_type = 0; }
2096                 }
2097                 else if(button_zoom || zoomscript_caught)
2098                 {
2099                         // normal zoom
2100                         reticle_type = 1;
2101                 }
2102
2103                 if(reticle_type)
2104                 {
2105                         if(autocvar_cl_reticle_stretch)
2106                         {
2107                                 reticle_size.x = vid_conwidth;
2108                                 reticle_size.y = vid_conheight;
2109                                 reticle_pos.x = 0;
2110                                 reticle_pos.y = 0;
2111                         }
2112                         else
2113                         {
2114                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2115                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2116                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2117                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2118                         }
2119
2120                         if(zoomscript_caught)
2121                                 f = 1;
2122                         else
2123                                 f = current_zoomfraction;
2124
2125                         if(f)
2126                         {
2127                                 switch(reticle_type)
2128                                 {
2129                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2130                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2131                                 }
2132                         }
2133                 }
2134         }
2135         else
2136         {
2137                 if(reticle_type != 0) { reticle_type = 0; }
2138         }
2139
2140
2141         // improved polyblend
2142         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2143         {
2144                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2145                 vector liquidcolor;
2146
2147                 switch(pointcontents(view_origin))
2148                 {
2149                         case CONTENT_WATER:
2150                                 liquidalpha = autocvar_hud_contents_water_alpha;
2151                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2152                                 incontent = 1;
2153                                 break;
2154
2155                         case CONTENT_LAVA:
2156                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2157                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2158                                 incontent = 1;
2159                                 break;
2160
2161                         case CONTENT_SLIME:
2162                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2163                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2164                                 incontent = 1;
2165                                 break;
2166
2167                         default:
2168                                 liquidalpha = 0;
2169                                 liquidcolor = '0 0 0';
2170                                 incontent = 0;
2171                                 break;
2172                 }
2173
2174                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2175                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2176                         contentfadetime = autocvar_hud_contents_fadeintime;
2177                         liquidalpha_prev = liquidalpha;
2178                         liquidcolor_prev = liquidcolor;
2179                 }
2180                 else
2181                         contentfadetime = autocvar_hud_contents_fadeouttime;
2182
2183                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2184                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2185
2186                 if(contentavgalpha)
2187                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2188
2189                 if(autocvar_hud_postprocessing)
2190                 {
2191                         if(autocvar_hud_contents_blur && contentavgalpha)
2192                         {
2193                                 content_blurpostprocess.x = 1;
2194                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2195                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2196                         }
2197                         else
2198                         {
2199                                 content_blurpostprocess.x = 0;
2200                                 content_blurpostprocess.y = 0;
2201                                 content_blurpostprocess.z = 0;
2202                         }
2203                 }
2204         }
2205
2206         if(autocvar_hud_damage && !STAT(FROZEN))
2207         {
2208                 splash_size.x = max(vid_conwidth, vid_conheight);
2209                 splash_size.y = max(vid_conwidth, vid_conheight);
2210                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2211                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2212
2213                 float myhealth_flash_temp;
2214                 myhealth = STAT(HEALTH);
2215
2216                 // fade out
2217                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2218                 // add new damage
2219                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2220
2221                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2222                 pain_threshold = autocvar_hud_damage_pain_threshold;
2223                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2224                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2225
2226                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2227                 {
2228                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2229                 }
2230
2231                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2232
2233                 if(myhealth_prev < 1)
2234                 {
2235                         if(myhealth >= 1)
2236                         {
2237                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2238                                 myhealth_flash_temp = 0;
2239                         }
2240                         else
2241                         {
2242                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2243                         }
2244                 }
2245
2246                 if(spectatee_status == -1 || intermission)
2247                 {
2248                         myhealth_flash = 0; // observing, or match ended
2249                         myhealth_flash_temp = 0;
2250                 }
2251
2252                 myhealth_prev = myhealth;
2253
2254                 // IDEA: change damage color/picture based on player model for robot/alien species?
2255                 // pro: matches model better
2256                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2257                 // maybe different reddish pics?
2258                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2259                 {
2260                         if(autocvar_cl_gentle_damage == 2)
2261                         {
2262                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2263                                         myhealth_gentlergb = randomvec();
2264                         }
2265                         else
2266                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2267
2268                         if(myhealth_flash_temp > 0)
2269                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2270                 }
2271                 else if(myhealth_flash_temp > 0)
2272                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2273
2274                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2275                 {
2276                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2277                         {
2278                                 damage_blurpostprocess.x = 1;
2279                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2280                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2281                         }
2282                         else
2283                         {
2284                                 damage_blurpostprocess.x = 0;
2285                                 damage_blurpostprocess.y = 0;
2286                                 damage_blurpostprocess.z = 0;
2287                         }
2288                 }
2289         }
2290
2291         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2292         float e2 = (autocvar_hud_powerup != 0);
2293         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2294         {
2295                 // enable or disable rendering types if they are used or not
2296                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2297                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2298
2299                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2300                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2301                 {
2302                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2303                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2304                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2305                         {
2306                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2307                                 old_blurradius = blurradius;
2308                                 old_bluralpha = bluralpha;
2309                         }
2310                 }
2311                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2312                 {
2313                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2314                         old_blurradius = 0;
2315                         old_bluralpha = 0;
2316                 }
2317
2318                 // edge detection postprocess handling done second (used by hud_powerup)
2319                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2320                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2321                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2322
2323                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2324
2325                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2326                 {
2327                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2328                         {
2329                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2330                                 old_sharpen_intensity = sharpen_intensity;
2331                         }
2332                 }
2333                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2334                 {
2335                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2336                         old_sharpen_intensity = 0;
2337                 }
2338
2339                 if(cvar("r_glsl_postprocess") == 0)
2340                         cvar_set("r_glsl_postprocess", "2");
2341         }
2342         else if(cvar("r_glsl_postprocess") == 2)
2343                 cvar_set("r_glsl_postprocess", "0");
2344
2345         /*if(gametype == MAPINFO_TYPE_CTF)
2346           {
2347           ctf_view();
2348           } else */
2349
2350         // draw 2D entities
2351         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2352         Draw_ShowNames_All();
2353 #if ENABLE_DEBUGDRAW
2354         Debug_Draw();
2355 #endif
2356
2357         scoreboard_active = Scoreboard_WouldDraw();
2358
2359         HUD_Draw(this); // this parameter for deep vehicle function
2360
2361         if(NextFrameCommand)
2362         {
2363                 localcmd("\n", NextFrameCommand, "\n");
2364                 NextFrameCommand = string_null;
2365         }
2366
2367         // we must do this check AFTER a frame was rendered, or it won't work
2368         if(cs_project_is_b0rked == 0)
2369         {
2370                 string w0, h0;
2371                 w0 = ftos(autocvar_vid_conwidth);
2372                 h0 = ftos(autocvar_vid_conheight);
2373                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2374                 //setproperty(VF_FOV, '90 90 0');
2375                 setproperty(VF_ORIGIN, '0 0 0');
2376                 setproperty(VF_ANGLES, '0 0 0');
2377                 setproperty(VF_PERSPECTIVE, 1);
2378                 makevectors('0 0 0');
2379                 vector v1, v2;
2380                 cvar_set("vid_conwidth", "800");
2381                 cvar_set("vid_conheight", "600");
2382                 v1 = cs_project(v_forward);
2383                 cvar_set("vid_conwidth", "640");
2384                 cvar_set("vid_conheight", "480");
2385                 v2 = cs_project(v_forward);
2386                 if(v1 == v2)
2387                         cs_project_is_b0rked = 1;
2388                 else
2389                         cs_project_is_b0rked = -1;
2390                 cvar_set("vid_conwidth", w0);
2391                 cvar_set("vid_conheight", h0);
2392         }
2393
2394         if(autocvar__hud_configure)
2395                 HUD_Panel_Mouse();
2396         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2397                 HUD_Minigame_Mouse();
2398         else if(QuickMenu_IsOpened())
2399                 QuickMenu_Mouse();
2400         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2401                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2402         else
2403                 HUD_Radar_Mouse();
2404
2405         cl_notice_run();
2406         unpause_update();
2407         Net_Flush();
2408
2409         // let's reset the view back to normal for the end
2410         setproperty(VF_MIN, '0 0 0');
2411         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2412
2413         IL_ENDFRAME();
2414 }
2415
2416
2417 // following vectors must be global to allow seamless switching between camera modes
2418 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2419 void CSQC_Demo_Camera()
2420 {
2421         float speed, attenuation, dimensions;
2422         vector tmp, delta;
2423
2424         if( autocvar_camera_reset || !camera_mode )
2425         {
2426                 camera_offset = '0 0 0';
2427                 current_angles = '0 0 0';
2428                 camera_direction = '0 0 0';
2429                 camera_offset.z += 30;
2430                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2431                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2432                 current_origin = view_origin;
2433                 current_camera_offset  = camera_offset;
2434                 cvar_set("camera_reset", "0");
2435                 camera_mode = CAMERA_CHASE;
2436         }
2437
2438         // Camera angles
2439         if( camera_roll )
2440                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2441
2442         if(autocvar_camera_look_player)
2443         {
2444                 vector dir;
2445                 float n;
2446
2447                 dir = normalize(view_origin - current_position);
2448                 n = mouse_angles.z;
2449                 mouse_angles = vectoangles(dir);
2450                 mouse_angles.x = mouse_angles.x * -1;
2451                 mouse_angles.z = n;
2452         }
2453         else
2454         {
2455                 tmp = getmousepos() * 0.1;
2456                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2457                 {
2458                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2459                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2460                 }
2461         }
2462
2463         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2464         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2465         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2466         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2467
2468         // Fix difference when angles don't have the same sign
2469         delta = '0 0 0';
2470         if(mouse_angles.y < -60 && current_angles.y > 60)
2471                 delta = '0 360 0';
2472         if(mouse_angles.y > 60 && current_angles.y < -60)
2473                 delta = '0 -360 0';
2474
2475         if(autocvar_camera_look_player)
2476                 attenuation = autocvar_camera_look_attenuation;
2477         else
2478                 attenuation = autocvar_camera_speed_attenuation;
2479
2480         attenuation = 1 / max(1, attenuation);
2481         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2482
2483         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2484         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2485         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2486         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2487
2488         // Camera position
2489         tmp = '0 0 0';
2490         dimensions = 0;
2491
2492         if( camera_direction.x )
2493         {
2494                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2495                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2496                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2497                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2498                 ++dimensions;
2499         }
2500
2501         if( camera_direction.y )
2502         {
2503                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2504                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2505                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2506                 ++dimensions;
2507         }
2508
2509         if( camera_direction.z )
2510         {
2511                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2512                 ++dimensions;
2513         }
2514
2515         if(autocvar_camera_free)
2516                 speed = autocvar_camera_speed_free;
2517         else
2518                 speed = autocvar_camera_speed_chase;
2519
2520         if(dimensions)
2521         {
2522                 speed = speed * sqrt(1 / dimensions);
2523                 camera_offset += tmp * speed;
2524         }
2525
2526         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2527
2528         // Camera modes
2529         if( autocvar_camera_free )
2530         {
2531                 if ( camera_mode == CAMERA_CHASE )
2532                 {
2533                         current_camera_offset = current_origin + current_camera_offset;
2534                         camera_offset = current_origin + camera_offset;
2535                 }
2536
2537                 camera_mode = CAMERA_FREE;
2538                 current_position = current_camera_offset;
2539         }
2540         else
2541         {
2542                 if ( camera_mode == CAMERA_FREE )
2543                 {
2544                         current_origin = view_origin;
2545                         camera_offset = camera_offset - current_origin;
2546                         current_camera_offset = current_camera_offset - current_origin;
2547                 }
2548
2549                 camera_mode = CAMERA_CHASE;
2550
2551                 if(autocvar_camera_chase_smoothly)
2552                         current_origin += (view_origin - current_origin) * attenuation;
2553                 else
2554                         current_origin = view_origin;
2555
2556                 current_position = current_origin + current_camera_offset;
2557         }
2558
2559         setproperty(VF_ANGLES, current_angles);
2560         setproperty(VF_ORIGIN, current_position);
2561 }