qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  66 { \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  68 } MACRO_END
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71 { \
  72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  74 } MACRO_END
  75
  76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  77 { \
  78         float __f = 0; lowpass(value, frac, ref_store, __f); \
  79         ret = (value) - __f; \
  80 } MACRO_END
  81
  82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  83 { \
  84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  85         ret = (value) - __f; \
  86 } MACRO_END
  87
  88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89 { \
  90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  92 } MACRO_END
  93
  94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  95 { \
  96         highpass(value.x, frac, ref_store.x, ref_out.x); \
  97         highpass(value.y, frac, ref_store.y, ref_out.y); \
  98 } MACRO_END
  99
 100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 101 { \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 } MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_prev = '0 0 0';
 129         static vector gunorg_adjustment_highpass;
 130         static vector gunorg_adjustment_lowpass;
 131
 132         vector vel;
 133         if (autocvar_cl_followmodel_velocity_absolute)
 134                 vel = view.velocity;
 135         else
 136         {
 137                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 138                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 139                 vel.x = view.velocity * forward;
 140                 vel.y = view.velocity * right * -1;
 141                 vel.z = view.velocity * up;
 142         }
 143
 144         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 145         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 146         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 147
 148         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 149         lowpass3(vel, frac, vel_average, gunorg);
 150
 151         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 152
 153         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 154         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 155         frac = avg_factor(autocvar_cl_followmodel_highpass);
 156         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 157         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 158         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 159
 160         if (autocvar_cl_followmodel_velocity_absolute)
 161         {
 162                 vector fixed_gunorg;
 163                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 164                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 165                 fixed_gunorg.x = gunorg * forward;
 166                 fixed_gunorg.y = gunorg * right * -1;
 167                 fixed_gunorg.z = gunorg * up;
 168                 gunorg = fixed_gunorg;
 169         }
 170
 171         cl_followmodel_ofs = gunorg;
 172         cl_followmodel_time = time;
 173 }
 174
 175 vector leanmodel_ofs(entity view)
 176 {
 177         float frac;
 178         vector gunangles = '0 0 0';
 179         static vector gunangles_prev = '0 0 0';
 180         static vector gunangles_highpass = '0 0 0';
 181         static vector gunangles_adjustment_highpass;
 182         static vector gunangles_adjustment_lowpass;
 183
 184         if (view.csqcmodel_teleported)
 185                 gunangles_prev = view_angles;
 186
 187         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 188         gunangles_highpass += gunangles_prev;
 189         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 190         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 191         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 193         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 194         gunangles_prev = view_angles;
 195         gunangles_highpass -= gunangles_prev;
 196
 197         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 198         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 199
 200         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 201         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 202         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 203         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 204         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 205
 206         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 207
 208         return gunangles;
 209 }
 210
 211 vector bobmodel_ofs(entity view)
 212 {
 213         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 214         static bool oldonground;
 215         static float hitgroundtime;
 216         if (clonground)
 217         {
 218                 float f = time; // cl.movecmd[0].time
 219                 if (!oldonground)
 220                         hitgroundtime = f;
 221         }
 222         oldonground = clonground;
 223
 224         // calculate for swinging gun model
 225         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 226         vector gunorg = '0 0 0';
 227         static float bobmodel_scale = 0;
 228         static float time_ofs = 0; // makes the effect always restart in the same way
 229         if (clonground)
 230         {
 231                 if (time - hitgroundtime > 0.05)
 232                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 233         }
 234         else
 235                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 236
 237         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 238         if (bobmodel_scale && xyspeed)
 239         {
 240                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 241                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 242                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 243                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 244         }
 245         else
 246                 time_ofs = time;
 247
 248         return gunorg;
 249 }
 250
 251 void viewmodel_animate(entity this)
 252 {
 253         if (autocvar_chase_active) return;
 254         if (STAT(HEALTH) <= 0) return;
 255
 256         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 257
 258         if (autocvar_cl_followmodel)
 259         {
 260                 calc_followmodel_ofs(view);
 261                 this.origin += cl_followmodel_ofs;
 262         }
 263
 264         if (autocvar_cl_leanmodel)
 265                 this.angles += leanmodel_ofs(view);
 266
 267         // vertical view bobbing code
 268         // TODO: cl_bob
 269
 270         // horizontal view bobbing code
 271         // TODO: cl_bob2
 272
 273         // fall bobbing code
 274         // causes the view to swing down and back up when touching the ground
 275         // TODO: cl_bobfall
 276
 277         // gun model bobbing code
 278         if (autocvar_cl_bobmodel)
 279                 this.origin += bobmodel_ofs(view);
 280 }
 281
 282 .vector viewmodel_origin, viewmodel_angles;
 283 .float weapon_nextthink;
 284 .float weapon_eta_last;
 285 .float weapon_switchdelay;
 286
 287 .string name_last;
 288
 289 void viewmodel_draw(entity this)
 290 {
 291         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 292                 return;
 293         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 294         float a = this.alpha;
 295         static bool wasinvehicle;
 296         bool invehicle = player_localentnum > maxclients;
 297         if (invehicle) a = -1;
 298         else if (wasinvehicle) a = 1;
 299         wasinvehicle = invehicle;
 300         Weapon wep = this.activeweapon;
 301         int c = entcs_GetClientColors(current_player);
 302         vector g = weaponentity_glowmod(wep, NULL, c, this);
 303         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 304         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 305                 | EF_NODEPTHTEST)
 306                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 307         for (entity e = this; e; e = e.weaponchild)
 308         {
 309                 e.drawmask = mask;
 310                 e.alpha = a;
 311                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 312                 e.glowmod = g;
 313                 e.csqcmodel_effects = fx;
 314                 CSQCModel_Effects_Apply(e);
 315         }
 316         {
 317                 string name = wep.mdl;
 318                 if(wep == WEP_TUBA)
 319                 {
 320                         name = (this.tuba_instrument == 0) ? "tuba" :
 321                            (this.tuba_instrument == 1) ? "akordeon" :
 322                                                      "kleinbottle";
 323                 }
 324                 bool swap = name != this.name_last;
 325                 // if (swap)
 326                 {
 327                         this.name_last = name;
 328                         CL_WeaponEntity_SetModel(this, name, swap);
 329                         this.viewmodel_origin = this.origin;
 330                         this.viewmodel_angles = this.angles;
 331                 }
 332                 anim_update(this);
 333                 if (!this.animstate_override && !this.animstate_looping)
 334                         anim_set(this, this.anim_idle, true, false, false);
 335         }
 336         float f = 0; // 0..1; 0: fully active
 337         float rate = STAT(WEAPONRATEFACTOR);
 338         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 339         if (eta <= 0) f = this.weapon_eta_last;
 340         else switch (this.state)
 341         {
 342                 case WS_RAISE:
 343                 {
 344                         f = eta / max(eta, this.weapon_switchdelay);
 345                         break;
 346                 }
 347                 case WS_DROP:
 348                 {
 349                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 350                         break;
 351                 }
 352                 case WS_CLEAR:
 353                 {
 354                         f = 1;
 355                         break;
 356                 }
 357         }
 358         this.weapon_eta_last = f;
 359         this.origin = this.viewmodel_origin;
 360         this.angles = this.viewmodel_angles;
 361         this.angles_x = (-90 * f * f);
 362         viewmodel_animate(this);
 363         setorigin(this, this.origin);
 364 }
 365
 366 STATIC_INIT(viewmodel) {
 367     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 368         viewmodels[slot] = new(viewmodel);
 369 }
 370
 371 void Porto_Draw(entity this);
 372 STATIC_INIT(Porto)
 373 {
 374         entity e = new_pure(porto);
 375         e.draw = Porto_Draw;
 376         IL_PUSH(g_drawables, e);
 377         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 378 }
 379
 380 const int polyline_length = 16;
 381 .vector polyline[polyline_length];
 382 void Porto_Draw(entity this)
 383 {
 384         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 385         {
 386                 entity wepent = viewmodels[slot];
 387
 388                 if (wepent.activeweapon != WEP_PORTO) continue;
 389                 if (spectatee_status) continue;
 390                 if (WEP_CVAR(porto, secondary)) continue;
 391                 if (intermission == 1) continue;
 392                 if (intermission == 2) continue;
 393                 if (STAT(HEALTH) <= 0) continue;
 394
 395                 vector pos = view_origin;
 396                 vector dir = view_forward;
 397                 if (wepent.angles_held_status)
 398                 {
 399                         makevectors(wepent.angles_held);
 400                         dir = v_forward;
 401                 }
 402
 403                 wepent.polyline[0] = pos;
 404
 405                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 406                 int n = 1 + 2;  // 2 lines == 3 points
 407                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 408                 {
 409                         traceline(pos, pos + 65536 * dir, true, this);
 410                         dir = reflect(dir, trace_plane_normal);
 411                         pos = trace_endpos;
 412                         wepent.polyline[++idx] = pos;
 413                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 414                         {
 415                                 n += 1;
 416                                 continue;
 417                         }
 418                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 419                         {
 420                                 n = max(2, idx);
 421                                 break;
 422                         }
 423                         // check size
 424                         {
 425                                 vector ang = vectoangles2(trace_plane_normal, dir);
 426                                 ang.x = -ang.x;
 427                                 makevectors(ang);
 428                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 429                                 {
 430                                         n = max(2, idx);
 431                                         break;
 432                                 }
 433                         }
 434                         portal_number += 1;
 435                         if (portal_number >= portal_max) break;
 436                         if (portal_number == 1) portal1_idx = idx;
 437                 }
 438                 for (int idx = 0; idx < n - 1; ++idx)
 439                 {
 440                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 441                         if (idx == 0) p -= view_up * 16;  // line from player
 442                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 443                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 444                 }
 445         }
 446 }
 447
 448 float drawtime;
 449 float avgspeed;
 450 vector GetCurrentFov(float fov)
 451 {
 452         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 453         float velocityzoom, curspeed;
 454         vector v;
 455
 456         zoomsensitivity = autocvar_cl_zoomsensitivity;
 457         zoomfactor = autocvar_cl_zoomfactor;
 458         if(zoomfactor < 1 || zoomfactor > 30)
 459                 zoomfactor = 2.5;
 460         zoomspeed = autocvar_cl_zoomspeed;
 461         if(zoomspeed >= 0)
 462         if(zoomspeed < 0.5 || zoomspeed > 16)
 463                         zoomspeed = 3.5;
 464
 465         zoomdir = button_zoom;
 466
 467         if(hud == HUD_NORMAL && !spectatee_status)
 468         {
 469                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 470                 {
 471                         entity wepent = viewmodels[slot];
 472                         if(wepent.switchweapon == wepent.activeweapon)
 473                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 474                                 zoomdir += button_attack2;
 475                 }
 476         }
 477         if(spectatee_status > 0 || isdemo())
 478         {
 479                 if(spectatorbutton_zoom)
 480                 {
 481                         if(zoomdir)
 482                                 zoomdir = 0;
 483                         else
 484                                 zoomdir = 1;
 485                 }
 486                 // fteqcc failed twice here already, don't optimize this
 487         }
 488
 489         if(zoomdir) { zoomin_effect = 0; }
 490
 491         if(camera_active)
 492         {
 493                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 494         }
 495         else if(autocvar_cl_spawnzoom && zoomin_effect)
 496         {
 497                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 498
 499                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 500                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 501                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 502         }
 503         else
 504         {
 505                 if(zoomspeed < 0) // instant zoom
 506                 {
 507                         if(zoomdir)
 508                                 current_viewzoom = 1 / zoomfactor;
 509                         else
 510                                 current_viewzoom = 1;
 511                 }
 512                 else
 513                 {
 514                         if(zoomdir)
 515                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 516                         else
 517                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 518                 }
 519         }
 520
 521         if(almost_equals(current_viewzoom, 1))
 522                 current_zoomfraction = 0;
 523         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 524                 current_zoomfraction = 1;
 525         else
 526                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 527
 528         if(zoomsensitivity < 1)
 529                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 530         else
 531                 setsensitivityscale(1);
 532
 533         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 534         {
 535                 if(intermission) { curspeed = 0; }
 536                 else
 537                 {
 538
 539                         makevectors(view_angles);
 540                         v = pmove_vel;
 541                         if(csqcplayer)
 542                                 v = csqcplayer.velocity;
 543
 544                         switch(autocvar_cl_velocityzoom_type)
 545                         {
 546                                 case 3: curspeed = max(0, v_forward * v); break;
 547                                 case 2: curspeed = (v_forward * v); break;
 548                                 case 1: default: curspeed = vlen(v); break;
 549                         }
 550                 }
 551
 552                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 553                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 554                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 555
 556                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 557         }
 558         else
 559                 velocityzoom = 1;
 560
 561         float frustumx, frustumy, fovx, fovy;
 562         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 563         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 564         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 565         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 566
 567         return '1 0 0' * fovx + '0 1 0' * fovy;
 568 }
 569
 570 vector GetViewLocationFOV(float fov)
 571 {
 572         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 573         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 574         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 575         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 576         return '1 0 0' * fovx + '0 1 0' * fovy;
 577 }
 578
 579 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 580 {
 581         float fovx, fovy;
 582         float width = (ov_worldmax.x - ov_worldmin.x);
 583         float height = (ov_worldmax.y - ov_worldmin.y);
 584         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 585         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 586         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 587         return '1 0 0' * fovx + '0 1 0' * fovy;
 588 }
 589
 590 // this function must match W_SetupShot!
 591 float zoomscript_caught;
 592
 593 vector wcross_origin;
 594 float wcross_scale_prev, wcross_alpha_prev;
 595 vector wcross_color_prev;
 596 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 597 vector wcross_color_goal_prev;
 598 float wcross_changedonetime;
 599
 600 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 601 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 602 float wcross_name_changestarttime, wcross_name_changedonetime;
 603 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 604
 605 float wcross_ring_prev;
 606
 607 entity trueaim;
 608 entity trueaim_rifle;
 609
 610 const float SHOTTYPE_HITTEAM = 1;
 611 const float SHOTTYPE_HITOBSTRUCTION = 2;
 612 const float SHOTTYPE_HITWORLD = 3;
 613 const float SHOTTYPE_HITENEMY = 4;
 614
 615 void TrueAim_Init()
 616 {
 617         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 618         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 619 }
 620
 621 float EnemyHitCheck()
 622 {
 623         float t, n;
 624         wcross_origin = project_3d_to_2d(trace_endpos);
 625         wcross_origin.z = 0;
 626         if(trace_ent)
 627                 n = trace_ent.entnum;
 628         else
 629                 n = trace_networkentity;
 630         if(n < 1)
 631                 return SHOTTYPE_HITWORLD;
 632         if(n > maxclients)
 633                 return SHOTTYPE_HITWORLD;
 634         t = entcs_GetTeam(n - 1);
 635         if(teamplay)
 636                 if(t == myteam)
 637                         return SHOTTYPE_HITTEAM;
 638         if(t == NUM_SPECTATOR)
 639                 return SHOTTYPE_HITWORLD;
 640         return SHOTTYPE_HITENEMY;
 641 }
 642
 643 float TrueAimCheck(entity wepent)
 644 {
 645         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 646         vector vecs, trueaimpoint, w_shotorg;
 647         vector mi, ma, dv;
 648         float shottype;
 649         entity ta;
 650         float mv;
 651
 652         mi = ma = '0 0 0';
 653         ta = trueaim;
 654         mv = MOVE_NOMONSTERS;
 655
 656         switch(wepent.activeweapon) // WEAPONTODO
 657         {
 658                 case WEP_TUBA: // no aim
 659                 case WEP_PORTO: // shoots from eye
 660                 case WEP_NEXBALL: // shoots from eye
 661                 case WEP_HOOK: // no trueaim
 662                 case WEP_MORTAR: // toss curve
 663                         return SHOTTYPE_HITWORLD;
 664                 case WEP_VORTEX:
 665                 case WEP_VAPORIZER:
 666                         mv = MOVE_NORMAL;
 667                         break;
 668                 case WEP_RIFLE:
 669                         ta = trueaim_rifle;
 670                         mv = MOVE_NORMAL;
 671                         if(zoomscript_caught)
 672                         {
 673                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 674                                 return EnemyHitCheck();
 675                         }
 676                         break;
 677                 case WEP_DEVASTATOR: // projectile has a size!
 678                         mi = '-3 -3 -3';
 679                         ma = '3 3 3';
 680                         break;
 681                 case WEP_FIREBALL: // projectile has a size!
 682                         mi = '-16 -16 -16';
 683                         ma = '16 16 16';
 684                         break;
 685                 case WEP_SEEKER: // projectile has a size!
 686                         mi = '-2 -2 -2';
 687                         ma = '2 2 2';
 688                         break;
 689                 case WEP_ELECTRO: // projectile has a size!
 690                         mi = '0 0 -3';
 691                         ma = '0 0 -3';
 692                         break;
 693         }
 694
 695         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 696
 697         vecs = decompressShotOrigin(STAT(SHOTORG));
 698
 699         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 700         trueaimpoint = trace_endpos;
 701
 702         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 703                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 704
 705         if(vecs.x > 0)
 706                 vecs.y = -vecs.y;
 707         else
 708                 vecs = '0 0 0';
 709
 710         dv = view_right * vecs.y + view_up * vecs.z;
 711         w_shotorg = traceorigin + dv;
 712
 713         // now move the vecs forward as much as requested if possible
 714         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 715         w_shotorg = trace_endpos - view_forward * nudge;
 716
 717         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 718         shottype = EnemyHitCheck();
 719         if(shottype != SHOTTYPE_HITWORLD)
 720                 return shottype;
 721
 722 #if 0
 723         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 724         // or rather, I know why, but see no fix
 725         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 726                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 727                 return SHOTTYPE_HITOBSTRUCTION;
 728 #endif
 729
 730         return SHOTTYPE_HITWORLD;
 731 }
 732
 733 void PostInit();
 734 void CSQC_Demo_Camera();
 735 float camera_mode;
 736 const float CAMERA_FREE = 1;
 737 const float CAMERA_CHASE = 2;
 738 float reticle_type;
 739 string NextFrameCommand;
 740
 741 vector freeze_org, freeze_ang;
 742 entity nightvision_noise, nightvision_noise2;
 743
 744 const float MAX_TIME_DIFF = 5;
 745 float pickup_crosshair_time, pickup_crosshair_size;
 746 float hitindication_crosshair_size;
 747 float use_vortex_chargepool;
 748
 749 float myhealth, myhealth_prev;
 750 float myhealth_flash;
 751
 752 float old_blurradius, old_bluralpha;
 753 float old_sharpen_intensity;
 754
 755 vector myhealth_gentlergb;
 756
 757 float contentavgalpha, liquidalpha_prev;
 758 vector liquidcolor_prev;
 759
 760 float eventchase_current_distance;
 761 float eventchase_running;
 762 bool WantEventchase(entity this)
 763 {
 764         if(autocvar_cl_orthoview)
 765                 return false;
 766         if(intermission)
 767                 return true;
 768         if(this.viewloc)
 769                 return true;
 770         if(spectatee_status >= 0)
 771         {
 772                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 773                         return true;
 774                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 775                         return true;
 776                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 777                 {
 778                         if(autocvar_cl_eventchase_death == 2)
 779                         {
 780                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 781                                 if(this.velocity == '0 0 0' || eventchase_running)
 782                                         return true;
 783                         }
 784                         else return true;
 785                 }
 786         }
 787         return false;
 788 }
 789
 790 void HUD_Crosshair_Vehicle(entity this)
 791 {
 792         if(hud != HUD_BUMBLEBEE_GUN)
 793         {
 794                 Vehicle info = Vehicles_from(hud);
 795                 info.vr_crosshair(info, this);
 796         }
 797 }
 798
 799 vector damage_blurpostprocess, content_blurpostprocess;
 800
 801 float unaccounted_damage = 0;
 802 void UpdateDamage()
 803 {
 804         // accumulate damage with each stat update
 805         static float damage_total_prev = 0;
 806         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 807         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 808         damage_total_prev = damage_total;
 809
 810         static float damage_dealt_time_prev = 0;
 811         float damage_dealt_time = STAT(HIT_TIME);
 812         if (damage_dealt_time != damage_dealt_time_prev)
 813         {
 814                 unaccounted_damage += unaccounted_damage_new;
 815                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 816         }
 817         damage_dealt_time_prev = damage_dealt_time;
 818
 819         // prevent hitsound when switching spectatee
 820         static float spectatee_status_prev = 0;
 821         if (spectatee_status != spectatee_status_prev)
 822                 unaccounted_damage = 0;
 823         spectatee_status_prev = spectatee_status;
 824 }
 825
 826 void HitSound()
 827 {
 828         // varying sound pitch
 829
 830         bool have_arc = false;
 831         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 832         {
 833                 entity wepent = viewmodels[slot];
 834
 835                 if(wepent.activeweapon == WEP_ARC)
 836                         have_arc = true;
 837         }
 838
 839         static float hitsound_time_prev = 0;
 840         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 841         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 842         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 843         {
 844                 if (autocvar_cl_hitsound && unaccounted_damage)
 845                 {
 846                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 847                         float a = autocvar_cl_hitsound_max_pitch;
 848                         float b = autocvar_cl_hitsound_min_pitch;
 849                         float c = autocvar_cl_hitsound_nom_damage;
 850                         float x = unaccounted_damage;
 851                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 852
 853                         // if sound variation is disabled, set pitch_shift to 1
 854                         if (autocvar_cl_hitsound == 1)
 855                                 pitch_shift = 1;
 856
 857                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 858                         if (autocvar_cl_hitsound == 3)
 859                         {
 860                                 float mirror_value = (a-b)/2 + b;
 861                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 862                         }
 863
 864                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 865
 866                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 867                         // todo: normalize sound pressure levels? seems unnecessary
 868
 869                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 870                 }
 871                 unaccounted_damage = 0;
 872                 hitsound_time_prev = time;
 873         }
 874
 875         static float typehit_time_prev = 0;
 876         float typehit_time = STAT(TYPEHIT_TIME);
 877         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 878         {
 879                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 880                 typehit_time_prev = typehit_time;
 881         }
 882 }
 883
 884 vector crosshair_getcolor(entity this, float health_stat)
 885 {
 886         static float rainbow_last_flicker;
 887         static vector rainbow_prev_color;
 888         vector wcross_color = '0 0 0';
 889         switch(autocvar_crosshair_color_special)
 890         {
 891                 case 1: // crosshair_color_per_weapon
 892                 {
 893                         if(this != WEP_Null && hud == HUD_NORMAL)
 894                         {
 895                                 wcross_color = this.wpcolor;
 896                                 break;
 897                         }
 898                         else { goto normalcolor; }
 899                 }
 900
 901                 case 2: // crosshair_color_by_health
 902                 {
 903                         float x = health_stat;
 904
 905                         //x = red
 906                         //y = green
 907                         //z = blue
 908
 909                         wcross_color.z = 0;
 910
 911                         if(x > 200)
 912                         {
 913                                 wcross_color.x = 0;
 914                                 wcross_color.y = 1;
 915                         }
 916                         else if(x > 150)
 917                         {
 918                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 919                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 920                         }
 921                         else if(x > 100)
 922                         {
 923                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 924                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 925                                 wcross_color.z = 1 - (x-100)*0.02;
 926                         }
 927                         else if(x > 50)
 928                         {
 929                                 wcross_color.x = 1;
 930                                 wcross_color.y = 1;
 931                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 932                         }
 933                         else if(x > 20)
 934                         {
 935                                 wcross_color.x = 1;
 936                                 wcross_color.y = (x-20)*90/27/100;
 937                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 938                         }
 939                         else
 940                         {
 941                                 wcross_color.x = 1;
 942                                 wcross_color.y = 0;
 943                         }
 944                         break;
 945                 }
 946
 947                 case 3: // crosshair_color_rainbow
 948                 {
 949                         if(time >= rainbow_last_flicker)
 950                         {
 951                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 952                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 953                         }
 954                         wcross_color = rainbow_prev_color;
 955                         break;
 956                 }
 957 LABEL(normalcolor)
 958                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 959         }
 960
 961         return wcross_color;
 962 }
 963
 964 void HUD_Crosshair(entity this)
 965 {
 966         float f, i, j;
 967         vector v;
 968         if(!scoreboard_active && !camera_active && intermission != 2 &&
 969                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 970                 !HUD_MinigameMenu_IsOpened() )
 971         {
 972                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 973                         return;
 974
 975                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 976                         return;
 977
 978                 if (hud != HUD_NORMAL)
 979                 {
 980                         HUD_Crosshair_Vehicle(this);
 981                         return;
 982                 }
 983
 984                 string wcross_style;
 985                 float wcross_alpha, wcross_resolution;
 986                 wcross_style = autocvar_crosshair;
 987                 if (wcross_style == "0")
 988                         return;
 989                 wcross_resolution = autocvar_crosshair_size;
 990                 if (wcross_resolution == 0)
 991                         return;
 992                 wcross_alpha = autocvar_crosshair_alpha;
 993                 if (wcross_alpha == 0)
 994                         return;
 995
 996                 // TrueAim check
 997                 float shottype;
 998
 999                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1000                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1001                 wcross_origin.z = 0;
1002                 if(autocvar_crosshair_hittest)
1003                 {
1004                         vector wcross_oldorigin;
1005                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1006                         wcross_oldorigin = wcross_origin;
1007                         shottype = TrueAimCheck(thiswep);
1008                         if(shottype == SHOTTYPE_HITWORLD)
1009                         {
1010                                 v = wcross_origin - wcross_oldorigin;
1011                                 v.x /= vid_conwidth;
1012                                 v.y /= vid_conheight;
1013                                 if(vdist(v, >, 0.01))
1014                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1015                         }
1016                         if(!autocvar_crosshair_hittest_showimpact)
1017                                 wcross_origin = wcross_oldorigin;
1018                 }
1019                 else
1020                         shottype = SHOTTYPE_HITWORLD;
1021
1022                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1023                 string wcross_name = "";
1024                 float wcross_scale, wcross_blur;
1025
1026         entity e = WEP_Null;
1027                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1028                 {
1029                         entity wepent = viewmodels[0]; // TODO: unhardcode
1030                         e = wepent.switchingweapon;
1031                         if(e)
1032                         {
1033                                 if(autocvar_crosshair_per_weapon)
1034                                 {
1035                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1036                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1037                                         //if (wcross_resolution == 0)
1038                                                 //return;
1039
1040                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1041                                         wcross_resolution *= e.w_crosshair_size;
1042                                         wcross_name = e.w_crosshair;
1043                                 }
1044                         }
1045                 }
1046
1047                 if(wcross_name == "")
1048                         wcross_name = strcat("gfx/crosshair", wcross_style);
1049
1050                 // MAIN CROSSHAIR COLOR DECISION
1051                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1052
1053                 if(autocvar_crosshair_effect_scalefade)
1054                 {
1055                         wcross_scale = wcross_resolution;
1056                         wcross_resolution = 1;
1057                 }
1058                 else
1059                 {
1060                         wcross_scale = 1;
1061                 }
1062
1063                 if(autocvar_crosshair_pickup)
1064                 {
1065                         float stat_pickup_time = STAT(LAST_PICKUP);
1066
1067                         if(pickup_crosshair_time < stat_pickup_time)
1068                         {
1069                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1070                                         pickup_crosshair_size = 1;
1071
1072                                 pickup_crosshair_time = stat_pickup_time;
1073                         }
1074
1075                         if(pickup_crosshair_size > 0)
1076                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1077                         else
1078                                 pickup_crosshair_size = 0;
1079
1080                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1081                 }
1082
1083                 // todo: make crosshair hit indication dependent on damage dealt
1084                 if(autocvar_crosshair_hitindication)
1085                 {
1086                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1087
1088                         if(unaccounted_damage)
1089                         {
1090                                 hitindication_crosshair_size = 1;
1091                         }
1092
1093                         if(hitindication_crosshair_size > 0)
1094                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1095                         else
1096                                 hitindication_crosshair_size = 0;
1097
1098                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1099                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1100                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1101                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1102                 }
1103
1104                 if(shottype == SHOTTYPE_HITENEMY)
1105                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1106                 if(shottype == SHOTTYPE_HITTEAM)
1107                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1108
1109                 f = fabs(autocvar_crosshair_effect_time);
1110                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1111                 {
1112                         wcross_changedonetime = time + f;
1113                 }
1114                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1115                 {
1116                         wcross_name_changestarttime = time;
1117                         wcross_name_changedonetime = time + f;
1118                         if(wcross_name_goal_prev_prev)
1119                                 strunzone(wcross_name_goal_prev_prev);
1120                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1121                         wcross_name_goal_prev = strzone(wcross_name);
1122                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1123                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1124                         wcross_resolution_goal_prev = wcross_resolution;
1125                 }
1126
1127                 wcross_scale_goal_prev = wcross_scale;
1128                 wcross_alpha_goal_prev = wcross_alpha;
1129                 wcross_color_goal_prev = wcross_color;
1130
1131                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1132                 {
1133                         wcross_blur = 1;
1134                         wcross_alpha *= 0.75;
1135                 }
1136                 else
1137                         wcross_blur = 0;
1138                 // *_prev is at time-frametime
1139                 // * is at wcross_changedonetime+f
1140                 // what do we have at time?
1141                 if(time < wcross_changedonetime)
1142                 {
1143                         f = frametime / (wcross_changedonetime - time + frametime);
1144                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1145                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1146                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1147                 }
1148
1149                 wcross_scale_prev = wcross_scale;
1150                 wcross_alpha_prev = wcross_alpha;
1151                 wcross_color_prev = wcross_color;
1152
1153                 MUTATOR_CALLHOOK(UpdateCrosshair);
1154
1155                 wcross_scale *= 1 - autocvar__menu_alpha;
1156                 wcross_alpha *= 1 - autocvar__menu_alpha;
1157                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1158
1159                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1160                 {
1161                         // crosshair rings for weapon stats
1162                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1163                         {
1164                                 // declarations and stats
1165                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1166                                 string ring_image = string_null, ring_inner_image = string_null;
1167                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1168
1169                                 ring_scale = autocvar_crosshair_ring_size;
1170
1171                                 float weapon_clipload, weapon_clipsize;
1172                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1173                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1174
1175                                 float vortex_charge, vortex_chargepool;
1176                                 vortex_charge = STAT(VORTEX_CHARGE);
1177                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1178
1179                                 float arc_heat = STAT(ARC_HEAT);
1180
1181                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1182                                         vortex_charge_movingavg = vortex_charge;
1183
1184                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1185
1186                                 // handle the values
1187                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1188                                 {
1189                                         if (vortex_chargepool || use_vortex_chargepool) {
1190                                                 use_vortex_chargepool = 1;
1191                                                 ring_inner_value = vortex_chargepool;
1192                                         } else {
1193                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1194                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1195                                         }
1196
1197                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1198                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1199                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1200
1201                                         // draw the outer ring to show the current charge of the weapon
1202                                         ring_value = vortex_charge;
1203                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1204                                         ring_rgb = wcross_color;
1205                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1206                                 }
1207                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1208                                 {
1209                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1210                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1211                                         ring_rgb = wcross_color;
1212                                         ring_image = "gfx/crosshair_ring.tga";
1213                                 }
1214                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1215                                 {
1216                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1217                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1218                                         ring_rgb = wcross_color;
1219                                         ring_image = "gfx/crosshair_ring.tga";
1220                                 }
1221                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1222                                 {
1223                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1224                                         ring_scale = autocvar_crosshair_ring_reload_size;
1225                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1226                                         ring_rgb = wcross_color;
1227
1228                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1229                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1230                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1231                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1232                                         else
1233                                                 ring_image = "gfx/crosshair_ring.tga";
1234                                 }
1235                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1236                                 {
1237                                         ring_value = arc_heat;
1238                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1239                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1240                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1241                                         ring_image = "gfx/crosshair_ring.tga";
1242                                 }
1243
1244                                 // if in weapon switch animation, fade ring out/in
1245                                 if(autocvar_crosshair_effect_time > 0)
1246                                 {
1247                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1248                                         if (f >= 1)
1249                                         {
1250                                                 wcross_ring_prev = ((ring_image) ? true : false);
1251                                         }
1252
1253                                         if(wcross_ring_prev)
1254                                         {
1255                                                 if(f < 1)
1256                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1257                                         }
1258                                         else
1259                                         {
1260                                                 if(f < 1)
1261                                                         ring_alpha *= bound(0, f, 1);
1262                                         }
1263                                 }
1264
1265                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1266                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1267
1268                                 if (ring_value)
1269                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1270                         }
1271
1272 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1273                         MACRO_BEGIN { \
1274                                 if(wcross_blur > 0) \
1275                                 { \
1276                                         for(i = -2; i <= 2; ++i) \
1277                                         for(j = -2; j <= 2; ++j) \
1278                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1279                                 } \
1280                                 else \
1281                                 { \
1282                                         M(0,0,sz,wcross_name,wcross_alpha); \
1283                                 } \
1284                         } MACRO_END
1285
1286 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1287                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1288
1289 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1290                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1291
1292                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1293                         {
1294                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1295                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1296                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1297                                 f = 1 - f;
1298                         }
1299                         else
1300                         {
1301                                 f = 1;
1302                         }
1303                         wcross_name_alpha_goal_prev = f;
1304
1305                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1306                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1307
1308                         if(autocvar_crosshair_dot)
1309                         {
1310                                 vector wcross_color_old;
1311                                 wcross_color_old = wcross_color;
1312
1313                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1314                                         wcross_color = stov(autocvar_crosshair_dot_color);
1315
1316                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1317                                 // FIXME why don't we use wcross_alpha here?
1318                                 wcross_color = wcross_color_old;
1319                         }
1320                 }
1321         }
1322         else
1323         {
1324                 wcross_scale_prev = 0;
1325                 wcross_alpha_prev = 0;
1326                 wcross_scale_goal_prev = 0;
1327                 wcross_alpha_goal_prev = 0;
1328                 wcross_changedonetime = 0;
1329                 if(wcross_name_goal_prev)
1330                         strunzone(wcross_name_goal_prev);
1331                 wcross_name_goal_prev = string_null;
1332                 if(wcross_name_goal_prev_prev)
1333                         strunzone(wcross_name_goal_prev_prev);
1334                 wcross_name_goal_prev_prev = string_null;
1335                 wcross_name_changestarttime = 0;
1336                 wcross_name_changedonetime = 0;
1337                 wcross_name_alpha_goal_prev = 0;
1338                 wcross_name_alpha_goal_prev_prev = 0;
1339                 wcross_resolution_goal_prev = 0;
1340                 wcross_resolution_goal_prev_prev = 0;
1341         }
1342 }
1343
1344 void HUD_Draw(entity this)
1345 {
1346         // if we don't know gametype and scores yet avoid drawing the scoreboard
1347         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1348         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1349         // cl_deathscoreboard would show the scoreboard and so on
1350         if(!gametype)
1351                 return;
1352
1353         if(!intermission)
1354         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1355         {
1356                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1357         }
1358         else if(STAT(FROZEN))
1359         {
1360                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1361         }
1362         if(!intermission)
1363         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1364         {
1365                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1366                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1367         }
1368         else if(STAT(CAPTURE_PROGRESS))
1369         {
1370                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1371                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1372         }
1373         else if(STAT(REVIVE_PROGRESS))
1374         {
1375                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1376                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1377         }
1378
1379         if(autocvar_r_letterbox == 0)
1380                 if(autocvar_viewsize < 120)
1381                 {
1382                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1383                                 Accuracy_LoadLevels();
1384
1385                         HUD_Main();
1386                         HUD_Scale_Disable();
1387                 }
1388
1389         // crosshair goes VERY LAST
1390         UpdateDamage();
1391         HUD_Crosshair(this);
1392         HitSound();
1393 }
1394
1395 bool ov_enabled;
1396 float oldr_nearclip;
1397 float oldr_farclip_base;
1398 float oldr_farclip_world;
1399 float oldr_novis;
1400 float oldr_useportalculling;
1401 float oldr_useinfinitefarclip;
1402
1403 void cl_notice_run();
1404
1405 float prev_myteam;
1406 int lasthud;
1407 float vh_notice_time;
1408 void WaypointSprite_Load();
1409 void CSQC_UpdateView(entity this, float w, float h)
1410 {
1411     TC(int, w); TC(int, h);
1412         entity e;
1413         float fov;
1414         float f;
1415         vector vf_size, vf_min;
1416         float a;
1417
1418         execute_next_frame();
1419
1420         ++framecount;
1421
1422         stats_get();
1423         hud = STAT(HUD);
1424
1425         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1426                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1427
1428         lasthud = hud;
1429
1430         HUD_Scale_Disable();
1431
1432         if(autocvar__hud_showbinds_reload) // menu can set this one
1433         {
1434                 db_close(binddb);
1435                 binddb = db_create();
1436                 cvar_set("_hud_showbinds_reload", "0");
1437         }
1438
1439         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1440                 view_quality = getproperty(VF_MINFPS_QUALITY);
1441         else
1442                 view_quality = 1;
1443
1444         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1445         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1446
1447         vf_size = getpropertyvec(VF_SIZE);
1448         vf_min = getpropertyvec(VF_MIN);
1449         vid_width = vf_size.x;
1450         vid_height = vf_size.y;
1451
1452         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1453         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1454
1455         WaypointSprite_Load();
1456
1457         CSQCPlayer_SetCamera();
1458
1459         if(player_localentnum <= maxclients) // is it a client?
1460                 current_player = player_localentnum - 1;
1461         else // then player_localentnum is the vehicle I'm driving
1462                 current_player = player_localnum;
1463         myteam = entcs_GetTeam(current_player);
1464
1465         if(myteam != prev_myteam)
1466         {
1467                 myteamcolors = colormapPaletteColor(myteam, 1);
1468                 FOREACH(hud_panels, true, it.update_time = time);
1469                 prev_myteam = myteam;
1470         }
1471
1472         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1473
1474         float is_dead = (STAT(HEALTH) <= 0);
1475
1476         // FIXME do we need this hack?
1477         if(isdemo())
1478         {
1479                 // in demos, input_buttons do not work
1480                 button_zoom = (autocvar__togglezoom == "-");
1481         }
1482         else if(button_zoom
1483                 && autocvar_cl_unpress_zoom_on_death
1484                 && (spectatee_status >= 0)
1485                 && (is_dead || intermission))
1486         {
1487                 // no zoom while dead or in intermission please
1488                 localcmd("-zoom\n");
1489                 button_zoom = false;
1490         }
1491
1492         // event chase camera
1493         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1494         {
1495                 if(STAT(CAMERA_SPECTATOR))
1496                 {
1497                         if(spectatee_status > 0)
1498                         {
1499                                 if(!autocvar_chase_active)
1500                                 {
1501                                         cvar_set("chase_active", "-2");
1502                                         goto skip_eventchase_death;
1503                                 }
1504                         }
1505                         else if(autocvar_chase_active == -2)
1506                                 cvar_set("chase_active", "0");
1507
1508                         if(autocvar_chase_active == -2)
1509                                 goto skip_eventchase_death;
1510                 }
1511                 else if(autocvar_chase_active == -2)
1512                         cvar_set("chase_active", "0");
1513
1514                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1515
1516                 float vehicle_viewdist = 0;
1517                 vector vehicle_viewofs = '0 0 0';
1518
1519                 if(vehicle_chase)
1520                 {
1521                         if(hud != HUD_BUMBLEBEE_GUN)
1522                         {
1523                                 Vehicle info = Vehicles_from(hud);
1524                                 vehicle_viewdist = info.height;
1525                                 vehicle_viewofs = info.view_ofs;
1526                         }
1527                 }
1528
1529                 if(WantEventchase(this))
1530                 {
1531                         vector current_view_origin_override = '0 0 0';
1532                         vector view_offset_override = '0 0 0';
1533                         float chase_distance_override = 0;
1534                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1535                         if(custom_eventchase)
1536                         {
1537                                 current_view_origin_override = M_ARGV(0, vector);
1538                                 view_offset_override = M_ARGV(1, vector);
1539                                 chase_distance_override = M_ARGV(0, float);
1540                         }
1541                         eventchase_running = true;
1542
1543                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1544                         if(!local_player)
1545                                 local_player = this; // fall back!
1546
1547                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1548                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1549                         if (custom_eventchase)
1550                                 current_view_origin = current_view_origin_override;
1551
1552                         // detect maximum viewoffset and use it
1553                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1554                         if(vehicle_chase)
1555                         {
1556                                 if(vehicle_viewofs)
1557                                         view_offset = vehicle_viewofs;
1558                                 else
1559                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1560                         }
1561                         if (custom_eventchase)
1562                                 view_offset = view_offset_override;
1563
1564                         if(view_offset)
1565                         {
1566                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1567                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1568                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1569                         }
1570
1571                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1572                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1573                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1574                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1575
1576                         // make the camera smooth back
1577                         float chase_distance = autocvar_cl_eventchase_distance;
1578                         if(vehicle_chase)
1579                         {
1580                                 if(vehicle_viewofs)
1581                                         chase_distance = vehicle_viewdist;
1582                                 else
1583                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1584                         }
1585                         if (custom_eventchase)
1586                                 chase_distance = chase_distance_override;
1587
1588                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1589                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1590                         else if(eventchase_current_distance != chase_distance)
1591                                 eventchase_current_distance = chase_distance;
1592
1593                         makevectors(view_angles);
1594
1595                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1596                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1597
1598                         // If the boxtrace fails, revert back to line tracing.
1599                         if(!local_player.viewloc)
1600                         if(trace_startsolid)
1601                         {
1602                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1603                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1604                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1605                         }
1606                         else { setproperty(VF_ORIGIN, trace_endpos); }
1607
1608                         if(!local_player.viewloc)
1609                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1610                 }
1611                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1612                 {
1613                         eventchase_running = false;
1614                         cvar_set("chase_active", "0");
1615                         eventchase_current_distance = 0; // start from 0 next time
1616                 }
1617         }
1618         // workaround for camera stuck between player's legs when using chase_active 1
1619         // because the engine stops updating the chase_active camera when the game ends
1620         else if(intermission)
1621         {
1622                 cvar_settemp("chase_active", "-1");
1623                 eventchase_current_distance = 0;
1624         }
1625
1626         LABEL(skip_eventchase_death);
1627
1628         // do lockview after event chase camera so that it still applies whenever necessary.
1629         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1630         {
1631                 setproperty(VF_ORIGIN, freeze_org);
1632                 setproperty(VF_ANGLES, freeze_ang);
1633         }
1634         else
1635         {
1636                 freeze_org = getpropertyvec(VF_ORIGIN);
1637                 freeze_ang = getpropertyvec(VF_ANGLES);
1638         }
1639
1640         WarpZone_FixView();
1641         //WarpZone_FixPMove();
1642
1643         vector ov_org = '0 0 0';
1644         vector ov_mid = '0 0 0';
1645         vector ov_worldmin = '0 0 0';
1646         vector ov_worldmax = '0 0 0';
1647         if(autocvar_cl_orthoview)
1648         {
1649                 ov_worldmin = mi_picmin;
1650                 ov_worldmax = mi_picmax;
1651
1652                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1653                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1654                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1655
1656                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1657                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1658
1659                 float ov_nearest = vlen(ov_org - vec3(
1660                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1661                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1662                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1663                 ));
1664
1665                 float ov_furthest = 0;
1666                 float dist = 0;
1667
1668                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1669                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1670                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1671                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1672                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1673                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1674                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1675                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1676
1677                 if(!ov_enabled)
1678                 {
1679                         oldr_nearclip = cvar("r_nearclip");
1680                         oldr_farclip_base = cvar("r_farclip_base");
1681                         oldr_farclip_world = cvar("r_farclip_world");
1682                         oldr_novis = cvar("r_novis");
1683                         oldr_useportalculling = cvar("r_useportalculling");
1684                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1685                 }
1686
1687                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1688                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1689                 cvar_settemp("r_farclip_world", "0");
1690                 cvar_settemp("r_novis", "1");
1691                 cvar_settemp("r_useportalculling", "0");
1692                 cvar_settemp("r_useinfinitefarclip", "0");
1693
1694                 setproperty(VF_ORIGIN, ov_org);
1695                 setproperty(VF_ANGLES, '90 0 0');
1696
1697                 ov_enabled = true;
1698
1699                 #if 0
1700                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1701                         vtos(ov_org),
1702                         vtos(getpropertyvec(VF_ANGLES)),
1703                         ov_distance,
1704                         ov_nearest,
1705                         ov_furthest);
1706                 #endif
1707         }
1708         else
1709         {
1710                 if(ov_enabled)
1711                 {
1712                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1713                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1714                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1715                         cvar_set("r_novis", ftos(oldr_novis));
1716                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1717                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1718                 }
1719                 ov_enabled = false;
1720         }
1721
1722         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1723         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1724         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1725                 viewmodel_draw(viewmodels[slot]);
1726
1727         // Render the Scene
1728         view_origin = getpropertyvec(VF_ORIGIN);
1729         view_angles = getpropertyvec(VF_ANGLES);
1730         makevectors(view_angles);
1731         view_forward = v_forward;
1732         view_right = v_right;
1733         view_up = v_up;
1734
1735 #ifdef BLURTEST
1736         if(time > blurtest_time0 && time < blurtest_time1)
1737         {
1738                 float r, t;
1739
1740                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1741                 r = t * blurtest_radius;
1742                 f = 1 / pow(t, blurtest_power) - 1;
1743
1744                 cvar_set("r_glsl_postprocess", "1");
1745                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1746         }
1747         else
1748         {
1749                 cvar_set("r_glsl_postprocess", "0");
1750                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1751         }
1752 #endif
1753
1754         TargetMusic_Advance();
1755         Fog_Force();
1756
1757         if(drawtime == 0)
1758                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1759         else
1760                 drawframetime = bound(0.000001, time - drawtime, 1);
1761         drawtime = time;
1762
1763         // watch for gametype changes here...
1764         // in ParseStuffCMD the cmd isn't executed yet :/
1765         // might even be better to add the gametype to TE_CSQC_INIT...?
1766         if(!postinit)
1767                 PostInit();
1768
1769         if(intermission && !gameover_time)
1770                 gameover_time = time;
1771
1772         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1773         {
1774                 if(calledhooks & HOOK_START)
1775                 {
1776                         localcmd("\ncl_hook_gameend\n");
1777                         calledhooks |= HOOK_END;
1778                 }
1779         }
1780
1781         Announcer();
1782
1783         fov = autocvar_fov;
1784         if(fov <= 59.5)
1785         {
1786                 if(!zoomscript_caught)
1787                 {
1788                         localcmd("+button9\n");
1789                         zoomscript_caught = 1;
1790                 }
1791         }
1792         else
1793         {
1794                 if(zoomscript_caught)
1795                 {
1796                         localcmd("-button9\n");
1797                         zoomscript_caught = 0;
1798                 }
1799         }
1800
1801         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1802
1803         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1804         {
1805                 entity wepent = viewmodels[slot];
1806
1807                 if(wepent.last_switchweapon != wepent.switchweapon)
1808                 {
1809                         weapontime = time;
1810                         wepent.last_switchweapon = wepent.switchweapon;
1811                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1812                         {
1813                                 localcmd("-zoom\n");
1814                                 button_zoom = false;
1815                         }
1816                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1817                         {
1818                                 localcmd("-fire\n");
1819                                 localcmd("-fire2\n");
1820                                 button_attack2 = false;
1821                         }
1822                 }
1823                 if(wepent.last_activeweapon != wepent.activeweapon)
1824                 {
1825                         wepent.last_activeweapon = wepent.activeweapon;
1826
1827                         e = wepent.activeweapon;
1828                         if(e.netname != "")
1829                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1830                         else if(slot == 0)
1831                                 localcmd("\ncl_hook_activeweapon none\n");
1832                 }
1833         }
1834
1835         // ALWAYS Clear Current Scene First
1836         clearscene();
1837
1838         setproperty(VF_ORIGIN, view_origin);
1839         setproperty(VF_ANGLES, view_angles);
1840
1841         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1842         setproperty(VF_SIZE, vf_size);
1843         setproperty(VF_MIN, vf_min);
1844
1845         // Assign Standard Viewflags
1846         // Draw the World (and sky)
1847         setproperty(VF_DRAWWORLD, 1);
1848
1849         // Set the console size vars
1850         vid_conwidth = autocvar_vid_conwidth;
1851         vid_conheight = autocvar_vid_conheight;
1852         vid_pixelheight = autocvar_vid_pixelheight;
1853
1854         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1855         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1856         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1857
1858         if(camera_active) // Camera for demo playback
1859         {
1860                 if(autocvar_camera_enable)
1861                         CSQC_Demo_Camera();
1862                 else
1863                 {
1864                         cvar_set("chase_active", ftos(chase_active_backup));
1865                         cvar_set("cl_demo_mousegrab", "0");
1866                         camera_active = false;
1867                 }
1868         }
1869         else
1870         {
1871 #ifdef CAMERATEST
1872                 if(autocvar_camera_enable)
1873 #else
1874                 if(autocvar_camera_enable && isdemo())
1875 #endif
1876                 {
1877                         // Enable required Darkplaces cvars
1878                         chase_active_backup = autocvar_chase_active;
1879                         cvar_set("chase_active", "2");
1880                         cvar_set("cl_demo_mousegrab", "1");
1881                         camera_active = true;
1882                         camera_mode = false;
1883                 }
1884         }
1885
1886         // Draw the Crosshair
1887         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1888
1889         // Draw the Engine Status Bar (the default Quake HUD)
1890         setproperty(VF_DRAWENGINESBAR, 0);
1891
1892         // Update the mouse position
1893         /*
1894            mousepos_x = vid_conwidth;
1895            mousepos_y = vid_conheight;
1896            mousepos = mousepos*0.5 + getmousepos();
1897          */
1898
1899         IL_EACH(g_drawables, it.draw, it.draw(it));
1900
1901         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1902         renderscene();
1903
1904         // now switch to 2D drawing mode by calling a 2D drawing function
1905         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1906         // next R_RenderScene call
1907         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1908
1909         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1910         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1911         {
1912                 // apply night vision effect
1913                 vector tc_00, tc_01, tc_10, tc_11;
1914                 vector rgb = '0 0 0';
1915
1916                 if(!nightvision_noise)
1917                 {
1918                         nightvision_noise = new(nightvision_noise);
1919                 }
1920                 if(!nightvision_noise2)
1921                 {
1922                         nightvision_noise2 = new(nightvision_noise2);
1923                 }
1924
1925                 // color tint in yellow
1926                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1927
1928                 // draw BG
1929                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1930                 rgb = '1 1 1';
1931                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1932                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1933                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1934                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1935                 tc_11 = tc_01 + tc_10 - tc_00;
1936                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1937                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1938                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1939                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1940                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1941                 R_EndPolygon();
1942
1943                 // draw FG
1944                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1945                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1946                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1947                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1948                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1949                 tc_11 = tc_01 + tc_10 - tc_00;
1950                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1951                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1952                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1953                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1954                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1955                 R_EndPolygon();
1956         }
1957
1958         if(autocvar_cl_reticle)
1959         {
1960                 string reticle_image = "";
1961                 bool wep_zoomed = false;
1962                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1963                 {
1964                         entity wepe = viewmodels[slot];
1965                         Weapon wep = wepe.activeweapon;
1966                         if(wep != WEP_Null && wep.wr_zoom)
1967                         {
1968                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1969                                 if(wep.w_reticle && wep.w_reticle != "")
1970                                         reticle_image = wep.w_reticle;
1971                                 wep_zoomed += do_zoom;
1972                         }
1973                 }
1974                 // Draw the aiming reticle for weapons that use it
1975                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1976                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1977                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1978                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1979                 {
1980                         // no zoom reticle while dead
1981                         reticle_type = 0;
1982                 }
1983                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1984                 {
1985                         if(reticle_image && reticle_image != "") { reticle_type = 2; }
1986                         else { reticle_type = 0; }
1987                 }
1988                 else if(button_zoom || zoomscript_caught)
1989                 {
1990                         // normal zoom
1991                         reticle_type = 1;
1992                 }
1993
1994                 if(reticle_type)
1995                 {
1996                         if(autocvar_cl_reticle_stretch)
1997                         {
1998                                 reticle_size.x = vid_conwidth;
1999                                 reticle_size.y = vid_conheight;
2000                                 reticle_pos.x = 0;
2001                                 reticle_pos.y = 0;
2002                         }
2003                         else
2004                         {
2005                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2006                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2007                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2008                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2009                         }
2010
2011                         if(zoomscript_caught)
2012                                 f = 1;
2013                         else
2014                                 f = current_zoomfraction;
2015
2016                         if(f)
2017                         {
2018                                 switch(reticle_type)
2019                                 {
2020                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2021                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2022                                 }
2023                         }
2024                 }
2025         }
2026         else
2027         {
2028                 if(reticle_type != 0) { reticle_type = 0; }
2029         }
2030
2031
2032         // improved polyblend
2033         if(autocvar_hud_contents)
2034         {
2035                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2036                 vector liquidcolor;
2037
2038                 switch(pointcontents(view_origin))
2039                 {
2040                         case CONTENT_WATER:
2041                                 liquidalpha = autocvar_hud_contents_water_alpha;
2042                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2043                                 incontent = 1;
2044                                 break;
2045
2046                         case CONTENT_LAVA:
2047                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2048                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2049                                 incontent = 1;
2050                                 break;
2051
2052                         case CONTENT_SLIME:
2053                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2054                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2055                                 incontent = 1;
2056                                 break;
2057
2058                         default:
2059                                 liquidalpha = 0;
2060                                 liquidcolor = '0 0 0';
2061                                 incontent = 0;
2062                                 break;
2063                 }
2064
2065                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2066                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2067                         contentfadetime = autocvar_hud_contents_fadeintime;
2068                         liquidalpha_prev = liquidalpha;
2069                         liquidcolor_prev = liquidcolor;
2070                 }
2071                 else
2072                         contentfadetime = autocvar_hud_contents_fadeouttime;
2073
2074                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2075                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2076
2077                 if(contentavgalpha)
2078                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2079
2080                 if(autocvar_hud_postprocessing)
2081                 {
2082                         if(autocvar_hud_contents_blur && contentavgalpha)
2083                         {
2084                                 content_blurpostprocess.x = 1;
2085                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2086                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2087                         }
2088                         else
2089                         {
2090                                 content_blurpostprocess.x = 0;
2091                                 content_blurpostprocess.y = 0;
2092                                 content_blurpostprocess.z = 0;
2093                         }
2094                 }
2095         }
2096
2097         if(autocvar_hud_damage && !STAT(FROZEN))
2098         {
2099                 splash_size.x = max(vid_conwidth, vid_conheight);
2100                 splash_size.y = max(vid_conwidth, vid_conheight);
2101                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2102                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2103
2104                 float myhealth_flash_temp;
2105                 myhealth = STAT(HEALTH);
2106
2107                 // fade out
2108                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2109                 // add new damage
2110                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2111
2112                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2113                 pain_threshold = autocvar_hud_damage_pain_threshold;
2114                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2115                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2116
2117                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2118                 {
2119                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2120                 }
2121
2122                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2123
2124                 if(myhealth_prev < 1)
2125                 {
2126                         if(myhealth >= 1)
2127                         {
2128                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2129                                 myhealth_flash_temp = 0;
2130                         }
2131                         else
2132                         {
2133                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2134                         }
2135                 }
2136
2137                 if(spectatee_status == -1 || intermission)
2138                 {
2139                         myhealth_flash = 0; // observing, or match ended
2140                         myhealth_flash_temp = 0;
2141                 }
2142
2143                 myhealth_prev = myhealth;
2144
2145                 // IDEA: change damage color/picture based on player model for robot/alien species?
2146                 // pro: matches model better
2147                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2148                 // maybe different reddish pics?
2149                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2150                 {
2151                         if(autocvar_cl_gentle_damage == 2)
2152                         {
2153                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2154                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2155                         }
2156                         else
2157                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2158
2159                         if(myhealth_flash_temp > 0)
2160                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2161                 }
2162                 else if(myhealth_flash_temp > 0)
2163                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2164
2165                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2166                 {
2167                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2168                         {
2169                                 damage_blurpostprocess.x = 1;
2170                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2171                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2172                         }
2173                         else
2174                         {
2175                                 damage_blurpostprocess.x = 0;
2176                                 damage_blurpostprocess.y = 0;
2177                                 damage_blurpostprocess.z = 0;
2178                         }
2179                 }
2180         }
2181
2182         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2183         float e2 = (autocvar_hud_powerup != 0);
2184         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2185         {
2186                 // enable or disable rendering types if they are used or not
2187                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2188                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2189
2190                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2191                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2192                 {
2193                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2194                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2195                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2196                         {
2197                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2198                                 old_blurradius = blurradius;
2199                                 old_bluralpha = bluralpha;
2200                         }
2201                 }
2202                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2203                 {
2204                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2205                         old_blurradius = 0;
2206                         old_bluralpha = 0;
2207                 }
2208
2209                 // edge detection postprocess handling done second (used by hud_powerup)
2210                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2211                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2212                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2213
2214                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2215
2216                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2217                 {
2218                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2219                         {
2220                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2221                                 old_sharpen_intensity = sharpen_intensity;
2222                         }
2223                 }
2224                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2225                 {
2226                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2227                         old_sharpen_intensity = 0;
2228                 }
2229
2230                 if(cvar("r_glsl_postprocess") == 0)
2231                         cvar_set("r_glsl_postprocess", "2");
2232         }
2233         else if(cvar("r_glsl_postprocess") == 2)
2234                 cvar_set("r_glsl_postprocess", "0");
2235
2236         /*if(gametype == MAPINFO_TYPE_CTF)
2237           {
2238           ctf_view();
2239           } else */
2240
2241         // draw 2D entities
2242         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2243         Draw_ShowNames_All();
2244         Debug_Draw();
2245
2246         scoreboard_active = Scoreboard_WouldDraw();
2247
2248         HUD_Draw(this); // this parameter for deep vehicle function
2249
2250         if(NextFrameCommand)
2251         {
2252                 localcmd("\n", NextFrameCommand, "\n");
2253                 NextFrameCommand = string_null;
2254         }
2255
2256         // we must do this check AFTER a frame was rendered, or it won't work
2257         if(cs_project_is_b0rked == 0)
2258         {
2259                 string w0, h0;
2260                 w0 = ftos(autocvar_vid_conwidth);
2261                 h0 = ftos(autocvar_vid_conheight);
2262                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2263                 //setproperty(VF_FOV, '90 90 0');
2264                 setproperty(VF_ORIGIN, '0 0 0');
2265                 setproperty(VF_ANGLES, '0 0 0');
2266                 setproperty(VF_PERSPECTIVE, 1);
2267                 makevectors('0 0 0');
2268                 vector v1, v2;
2269                 cvar_set("vid_conwidth", "800");
2270                 cvar_set("vid_conheight", "600");
2271                 v1 = cs_project(v_forward);
2272                 cvar_set("vid_conwidth", "640");
2273                 cvar_set("vid_conheight", "480");
2274                 v2 = cs_project(v_forward);
2275                 if(v1 == v2)
2276                         cs_project_is_b0rked = 1;
2277                 else
2278                         cs_project_is_b0rked = -1;
2279                 cvar_set("vid_conwidth", w0);
2280                 cvar_set("vid_conheight", h0);
2281         }
2282
2283         if(autocvar__hud_configure)
2284                 HUD_Panel_Mouse();
2285         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2286                 HUD_Minigame_Mouse();
2287         else if(QuickMenu_IsOpened())
2288                 QuickMenu_Mouse();
2289         else
2290                 HUD_Radar_Mouse();
2291
2292         cl_notice_run();
2293         unpause_update();
2294         Net_Flush();
2295
2296         // let's reset the view back to normal for the end
2297         setproperty(VF_MIN, '0 0 0');
2298         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2299
2300         IL_ENDFRAME();
2301 }
2302
2303
2304 // following vectors must be global to allow seamless switching between camera modes
2305 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2306 void CSQC_Demo_Camera()
2307 {
2308         float speed, attenuation, dimensions;
2309         vector tmp, delta;
2310
2311         if( autocvar_camera_reset || !camera_mode )
2312         {
2313                 camera_offset = '0 0 0';
2314                 current_angles = '0 0 0';
2315                 camera_direction = '0 0 0';
2316                 camera_offset.z += 30;
2317                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2318                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2319                 current_origin = view_origin;
2320                 current_camera_offset  = camera_offset;
2321                 cvar_set("camera_reset", "0");
2322                 camera_mode = CAMERA_CHASE;
2323         }
2324
2325         // Camera angles
2326         if( camera_roll )
2327                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2328
2329         if(autocvar_camera_look_player)
2330         {
2331                 vector dir;
2332                 float n;
2333
2334                 dir = normalize(view_origin - current_position);
2335                 n = mouse_angles.z;
2336                 mouse_angles = vectoangles(dir);
2337                 mouse_angles.x = mouse_angles.x * -1;
2338                 mouse_angles.z = n;
2339         }
2340         else
2341         {
2342                 tmp = getmousepos() * 0.1;
2343                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2344                 {
2345                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2346                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2347                 }
2348         }
2349
2350         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2351         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2352         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2353         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2354
2355         // Fix difference when angles don't have the same sign
2356         delta = '0 0 0';
2357         if(mouse_angles.y < -60 && current_angles.y > 60)
2358                 delta = '0 360 0';
2359         if(mouse_angles.y > 60 && current_angles.y < -60)
2360                 delta = '0 -360 0';
2361
2362         if(autocvar_camera_look_player)
2363                 attenuation = autocvar_camera_look_attenuation;
2364         else
2365                 attenuation = autocvar_camera_speed_attenuation;
2366
2367         attenuation = 1 / max(1, attenuation);
2368         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2369
2370         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2371         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2372         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2373         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2374
2375         // Camera position
2376         tmp = '0 0 0';
2377         dimensions = 0;
2378
2379         if( camera_direction.x )
2380         {
2381                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2382                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2383                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2384                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2385                 ++dimensions;
2386         }
2387
2388         if( camera_direction.y )
2389         {
2390                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2391                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2392                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2393                 ++dimensions;
2394         }
2395
2396         if( camera_direction.z )
2397         {
2398                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2399                 ++dimensions;
2400         }
2401
2402         if(autocvar_camera_free)
2403                 speed = autocvar_camera_speed_free;
2404         else
2405                 speed = autocvar_camera_speed_chase;
2406
2407         if(dimensions)
2408         {
2409                 speed = speed * sqrt(1 / dimensions);
2410                 camera_offset += tmp * speed;
2411         }
2412
2413         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2414
2415         // Camera modes
2416         if( autocvar_camera_free )
2417         {
2418                 if ( camera_mode == CAMERA_CHASE )
2419                 {
2420                         current_camera_offset = current_origin + current_camera_offset;
2421                         camera_offset = current_origin + camera_offset;
2422                 }
2423
2424                 camera_mode = CAMERA_FREE;
2425                 current_position = current_camera_offset;
2426         }
2427         else
2428         {
2429                 if ( camera_mode == CAMERA_FREE )
2430                 {
2431                         current_origin = view_origin;
2432                         camera_offset = camera_offset - current_origin;
2433                         current_camera_offset = current_camera_offset - current_origin;
2434                 }
2435
2436                 camera_mode = CAMERA_CHASE;
2437
2438                 if(autocvar_camera_chase_smoothly)
2439                         current_origin += (view_origin - current_origin) * attenuation;
2440                 else
2441                         current_origin = view_origin;
2442
2443                 current_position = current_origin + current_camera_offset;
2444         }
2445
2446         setproperty(VF_ANGLES, current_angles);
2447         setproperty(VF_ORIGIN, current_position);
2448 }