Merge branch 'master' into TimePath/csqc_viewmodels
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1
2 #include "announcer.qh"
3 #include "hook.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include "../common/anim.qh"
13 #include "../common/constants.qh"
14 #include "../common/debug.qh"
15 #include "../common/mapinfo.qh"
16 #include "../common/gamemodes/all.qh"
17 #include "../common/physics.qh"
18 #include "../common/stats.qh"
19 #include "../common/triggers/target/music.qh"
20 #include "../common/teams.qh"
21
22 #include "../common/vehicles/all.qh"
23 #include "../common/weapons/all.qh"
24 #include "../common/viewloc.qh"
25 #include "../common/minigames/cl_minigames.qh"
26 #include "../common/minigames/cl_minigames_hud.qh"
27
28 #include "../lib/csqcmodel/cl_player.qh"
29
30 #include "../lib/warpzone/client.qh"
31 #include "../lib/warpzone/common.qh"
32
33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
34
35 float autocvar_cl_viewmodel_scale;
36
37 bool autocvar_cl_bobmodel;
38 float autocvar_cl_bobmodel_speed;
39 float autocvar_cl_bobmodel_side;
40 float autocvar_cl_bobmodel_up;
41
42 float autocvar_cl_followmodel;
43 float autocvar_cl_followmodel_side_speed;
44 float autocvar_cl_followmodel_side_highpass;
45 float autocvar_cl_followmodel_side_highpass1;
46 float autocvar_cl_followmodel_side_limit;
47 float autocvar_cl_followmodel_side_lowpass;
48 float autocvar_cl_followmodel_up_speed;
49 float autocvar_cl_followmodel_up_highpass;
50 float autocvar_cl_followmodel_up_highpass1;
51 float autocvar_cl_followmodel_up_limit;
52 float autocvar_cl_followmodel_up_lowpass;
53
54 float autocvar_cl_leanmodel;
55 float autocvar_cl_leanmodel_side_speed;
56 float autocvar_cl_leanmodel_side_highpass;
57 float autocvar_cl_leanmodel_side_highpass1;
58 float autocvar_cl_leanmodel_side_lowpass;
59 float autocvar_cl_leanmodel_side_limit;
60 float autocvar_cl_leanmodel_up_speed;
61 float autocvar_cl_leanmodel_up_highpass;
62 float autocvar_cl_leanmodel_up_highpass1;
63 float autocvar_cl_leanmodel_up_lowpass;
64 float autocvar_cl_leanmodel_up_limit;
65
66 #define lowpass(value, frac, ref_store, ret) do \
67 { \
68         float __frac = bound(0, frac, 1); \
69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
70 } while (0)
71
72 #define lowpass_limited(value, frac, limit, ref_store, ret) do \
73 { \
74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
76 } while (0)
77
78 #define highpass(value, frac, ref_store, ret) do \
79 { \
80         float __f; lowpass(value, frac, ref_store, __f); \
81         ret = (value) - __f; \
82 } while (0)
83
84 #define highpass_limited(value, frac, limit, ref_store, ret) do \
85 { \
86         float __f; lowpass_limited(value, frac, limit, ref_store, __f); \
87         ret = (value) - __f; \
88 } while (0)
89
90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
91 { \
92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
95 } while (0)
96
97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
98 { \
99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
102 } while (0)
103
104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) do \
105 { \
106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
109 } while (0)
110
111 void viewmodel_animate(entity this)
112 {
113         static float prevtime;
114         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
115         prevtime = time;
116
117         if (autocvar_chase_active) return;
118         if (getstati(STAT_HEALTH) <= 0) return;
119
120         entity view = CSQCModel_server2csqc(player_localentnum - 1);
121
122         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
123         static bool oldonground;
124         static float hitgroundtime;
125         static float lastongroundtime;
126         if (clonground)
127         {
128                 float f = time; // cl.movecmd[0].time
129                 if (!oldonground)
130                         hitgroundtime = f;
131                 lastongroundtime = f;
132         }
133         oldonground = clonground;
134
135         vector gunorg = '0 0 0', gunangles = '0 0 0';
136         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
137
138         bool teleported = view.csqcmodel_teleported;
139
140         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
141         if (teleported)
142         {
143                 // try to fix the first highpass; result is NOT
144                 // perfect! TODO find a better fix
145                 gunangles_prev = view_angles;
146                 gunorg_prev = view_origin;
147         }
148
149         static vector gunorg_highpass = '0 0 0';
150
151         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
152         gunorg_highpass += gunorg_prev;
153         highpass3_limited(view_origin,
154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
155                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
156                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
157                 gunorg_highpass, gunorg);
158         gunorg_prev = view_origin;
159         gunorg_highpass -= gunorg_prev;
160
161         static vector gunangles_highpass = '0 0 0';
162
163         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
164         gunangles_highpass += gunangles_prev;
165         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
166         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
167         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
168         highpass3_limited(view_angles,
169                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
170                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
171                 0, 0,
172                 gunangles_highpass, gunangles);
173         gunangles_prev = view_angles;
174         gunangles_highpass -= gunangles_prev;
175
176         // 3. calculate the RAW adjustment vectors
177         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
178         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
179         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
180
181         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
182         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
183         ROLL(gunangles) = 0;
184
185         static vector gunorg_adjustment_highpass;
186         static vector gunorg_adjustment_lowpass;
187         static vector gunangles_adjustment_highpass;
188         static vector gunangles_adjustment_lowpass;
189
190         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
191         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
192         highpass3(gunorg,
193                 frametime * autocvar_cl_followmodel_side_highpass,
194                 frametime * autocvar_cl_followmodel_side_highpass,
195                 frametime * autocvar_cl_followmodel_up_highpass,
196                 gunorg_adjustment_highpass, gunorg);
197         lowpass3(gunorg,
198                 frametime * autocvar_cl_followmodel_side_lowpass,
199                 frametime * autocvar_cl_followmodel_side_lowpass,
200                 frametime * autocvar_cl_followmodel_up_lowpass,
201                 gunorg_adjustment_lowpass, gunorg);
202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
203         highpass3(gunangles,
204                 frametime * autocvar_cl_leanmodel_up_highpass,
205                 frametime * autocvar_cl_leanmodel_side_highpass,
206                 0,
207                 gunangles_adjustment_highpass, gunangles);
208         lowpass3(gunangles,
209                 frametime * autocvar_cl_leanmodel_up_lowpass,
210                 frametime * autocvar_cl_leanmodel_side_lowpass,
211                 0,
212                 gunangles_adjustment_lowpass, gunangles);
213         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
214
215         // vertical view bobbing code
216         // TODO: cl_bob
217
218         // horizontal view bobbing code
219         // TODO: cl_bob2
220
221         // fall bobbing code
222         // causes the view to swing down and back up when touching the ground
223         // TODO: cl_bobfall
224
225         // gun model bobbing code
226         if (autocvar_cl_bobmodel)
227         {
228                 // calculate for swinging gun model
229                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
230                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
231                 // for the most part, but for some reason when you go through a message trigger or
232                 // pick up an item or anything like that it will momentarily jolt the gun.
233                 vector forward, right, up;
234                 float bspeed;
235                 float t = 1;
236                 float s = time * autocvar_cl_bobmodel_speed;
237                 if (clonground)
238                 {
239                         if (time - hitgroundtime < 0.2)
240                         {
241                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
242                                 t = time - hitgroundtime;
243                                 t = bound(0, t, 0.2);
244                                 t *= 5;
245                         }
246                 }
247                 else
248                 {
249                         // recently left the ground, slow the bob down over the next 0.2 seconds
250                         t = time - lastongroundtime;
251                         t = 0.2 - bound(0, t, 0.2);
252                         t *= 5;
253                 }
254                 bspeed = xyspeed * 0.01;
255                 MAKEVECTORS(makevectors, gunangles, forward, right, up);
256                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
257                 gunorg += bobr * right;
258                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
259                 gunorg += bobu * up;
260         }
261         this.origin += view_forward * gunorg.x + view_right * gunorg.y + view_up * gunorg.z;
262         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
263         this.angles += gunangles;
264 }
265
266 .vector viewmodel_origin, viewmodel_angles;
267
268 void viewmodel_draw(entity this)
269 {
270         int mask = (intermission || (getstati(STAT_HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
271         float a = this.alpha;
272         int c = stof(getplayerkeyvalue(current_player, "colors"));
273         vector g = this.glowmod; // TODO: completely clientside: colormapPaletteColor(c & 0x0F, true) * 2;
274         entity me = CSQCModel_server2csqc(player_localentnum - 1);
275         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
276                 | EF_NODEPTHTEST)
277                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
278         for (entity e = this; e; e = e.weaponchild)
279         {
280                 e.drawmask = mask;
281                 e.alpha = a;
282                 e.colormap = c;
283                 e.glowmod = g;
284                 e.csqcmodel_effects = fx;
285                 WITH(entity, self, e, CSQCModel_Effects_Apply());
286         }
287         {
288                 static string name_last;
289                 string name = Weapons_from(activeweapon).mdl;
290                 if (name != name_last)
291                 {
292                         name_last = name;
293                         CL_WeaponEntity_SetModel(this, name);
294                         this.viewmodel_origin = this.origin;
295                         this.viewmodel_angles = this.angles;
296                 }
297                 anim_update(this);
298                 if (!this.animstate_override)
299                         anim_set(this, this.anim_idle, true, false, false);
300         }
301         float eta = (STAT(WEAPON_NEXTTHINK) - time); // TODO: / W_WeaponRateFactor();
302         float f = 0; // 0..1; 0: fully active
303         switch (this.state)
304         {
305                 case WS_RAISE:
306                 {
307                         // entity newwep = Weapons_from(activeweapon);
308                         float delay = 0.2; // TODO: newwep.switchdelay_raise;
309                         f = eta / max(eta, delay);
310                         break;
311                 }
312                 case WS_DROP:
313                 {
314                         // entity oldwep = Weapons_from(activeweapon);
315                         float delay = 0.2; // TODO: newwep.switchdelay_drop;
316                         f = 1 - eta / max(eta, delay);
317                         break;
318                 }
319                 case WS_CLEAR:
320                 {
321                         f = 1;
322                         break;
323                 }
324         }
325         this.origin = this.viewmodel_origin;
326         this.angles = this.viewmodel_angles;
327         this.angles_x = (-90 * f * f);
328         viewmodel_animate(this);
329         setorigin(this, this.origin);
330 }
331
332 entity viewmodel;
333 STATIC_INIT(viewmodel) {
334     viewmodel = new(viewmodel);
335         viewmodel.draw = viewmodel_draw;
336 }
337
338 entity porto;
339 vector polyline[16];
340 void Porto_Draw(entity this)
341 {
342         vector p, dir, ang, q, nextdir;
343         float portal_number, portal1_idx;
344
345         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
346                 return;
347         if(g_balance_porto_secondary)
348                 return;
349         if(intermission == 1)
350                 return;
351         if(intermission == 2)
352                 return;
353         if (getstati(STAT_HEALTH) <= 0)
354                 return;
355
356         dir = view_forward;
357
358         if(angles_held_status)
359         {
360                 makevectors(angles_held);
361                 dir = v_forward;
362         }
363
364         p = view_origin;
365
366         polyline[0] = p;
367         int idx = 1;
368         portal_number = 0;
369         nextdir = dir;
370
371         for (;;)
372         {
373                 dir = nextdir;
374                 traceline(p, p + 65536 * dir, true, porto);
375                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
376                         return;
377                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
378                 p = trace_endpos;
379                 polyline[idx] = p;
380                 ++idx;
381                 if(idx >= 16)
382                         return;
383                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
384                         continue;
385                 ++portal_number;
386                 ang = vectoangles2(trace_plane_normal, dir);
387                 ang.x = -ang.x;
388                 makevectors(ang);
389                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
390                         return;
391                 if(portal_number == 1)
392                 {
393                         portal1_idx = idx;
394                         if(portal_number >= 2)
395                                 break;
396                 }
397         }
398
399         while(idx >= 2)
400         {
401                 p = polyline[idx-2];
402                 q = polyline[idx-1];
403                 if(idx == 2)
404                         p = p - view_up * 16;
405                 if(idx-1 >= portal1_idx)
406                 {
407                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
408                 }
409                 else
410                 {
411                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
412                 }
413                 --idx;
414         }
415 }
416
417 void Porto_Init()
418 {
419         porto = new(porto);
420         make_pure(porto);
421         porto.draw = Porto_Draw;
422         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
423 }
424
425 float drawtime;
426 float avgspeed;
427 vector GetCurrentFov(float fov)
428 {
429         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
430         float velocityzoom, curspeed;
431         vector v;
432
433         zoomsensitivity = autocvar_cl_zoomsensitivity;
434         zoomfactor = autocvar_cl_zoomfactor;
435         if(zoomfactor < 1 || zoomfactor > 30)
436                 zoomfactor = 2.5;
437         zoomspeed = autocvar_cl_zoomspeed;
438         if(zoomspeed >= 0)
439         if(zoomspeed < 0.5 || zoomspeed > 16)
440                         zoomspeed = 3.5;
441
442         zoomdir = button_zoom;
443         if(hud == HUD_NORMAL)
444         if(switchweapon == activeweapon)
445         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
446                 zoomdir += button_attack2;
447         if(spectatee_status > 0 || isdemo())
448         {
449                 if(spectatorbutton_zoom)
450                 {
451                         if(zoomdir)
452                                 zoomdir = 0;
453                         else
454                                 zoomdir = 1;
455                 }
456                 // fteqcc failed twice here already, don't optimize this
457         }
458
459         if(zoomdir) { zoomin_effect = 0; }
460
461         if(camera_active)
462         {
463                 current_viewzoom = min(1, current_viewzoom + drawframetime);
464         }
465         else if(autocvar_cl_spawnzoom && zoomin_effect)
466         {
467                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
468
469                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
470                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
471                 if(current_viewzoom == 1) { zoomin_effect = 0; }
472         }
473         else
474         {
475                 if(zoomspeed < 0) // instant zoom
476                 {
477                         if(zoomdir)
478                                 current_viewzoom = 1 / zoomfactor;
479                         else
480                                 current_viewzoom = 1;
481                 }
482                 else
483                 {
484                         if(zoomdir)
485                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
486                         else
487                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
488                 }
489         }
490
491         if(almost_equals(current_viewzoom, 1))
492                 current_zoomfraction = 0;
493         else if(almost_equals(current_viewzoom, 1/zoomfactor))
494                 current_zoomfraction = 1;
495         else
496                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
497
498         if(zoomsensitivity < 1)
499                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
500         else
501                 setsensitivityscale(1);
502
503         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
504         {
505                 if(intermission) { curspeed = 0; }
506                 else
507                 {
508
509                         makevectors(view_angles);
510                         v = pmove_vel;
511                         if(csqcplayer)
512                                 v = csqcplayer.velocity;
513
514                         switch(autocvar_cl_velocityzoom_type)
515                         {
516                                 case 3: curspeed = max(0, v_forward * v); break;
517                                 case 2: curspeed = (v_forward * v); break;
518                                 case 1: default: curspeed = vlen(v); break;
519                         }
520                 }
521
522                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
523                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
524                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
525
526                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
527         }
528         else
529                 velocityzoom = 1;
530
531         float frustumx, frustumy, fovx, fovy;
532         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
533         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
534         fovx = atan2(frustumx, 1) / M_PI * 360.0;
535         fovy = atan2(frustumy, 1) / M_PI * 360.0;
536
537         return '1 0 0' * fovx + '0 1 0' * fovy;
538 }
539
540 vector GetViewLocationFOV(float fov)
541 {
542         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
543         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
544         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
545         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
546         return '1 0 0' * fovx + '0 1 0' * fovy;
547 }
548
549 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
550 {
551         float fovx, fovy;
552         float width = (ov_worldmax.x - ov_worldmin.x);
553         float height = (ov_worldmax.y - ov_worldmin.y);
554         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
555         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
556         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
557         return '1 0 0' * fovx + '0 1 0' * fovy;
558 }
559
560 // this function must match W_SetupShot!
561 float zoomscript_caught;
562
563 vector wcross_origin;
564 float wcross_scale_prev, wcross_alpha_prev;
565 vector wcross_color_prev;
566 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
567 vector wcross_color_goal_prev;
568 float wcross_changedonetime;
569
570 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
571 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
572 float wcross_name_changestarttime, wcross_name_changedonetime;
573 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
574
575 float wcross_ring_prev;
576
577 entity trueaim;
578 entity trueaim_rifle;
579
580 const float SHOTTYPE_HITTEAM = 1;
581 const float SHOTTYPE_HITOBSTRUCTION = 2;
582 const float SHOTTYPE_HITWORLD = 3;
583 const float SHOTTYPE_HITENEMY = 4;
584
585 void TrueAim_Init()
586 {
587         trueaim = new(trueaim);
588         make_pure(trueaim);
589         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
590         trueaim_rifle = new(trueaim_rifle);
591         make_pure(trueaim_rifle);
592         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
593 }
594
595 float EnemyHitCheck()
596 {
597         float t, n;
598         wcross_origin = project_3d_to_2d(trace_endpos);
599         wcross_origin.z = 0;
600         if(trace_ent)
601                 n = trace_ent.entnum;
602         else
603                 n = trace_networkentity;
604         if(n < 1)
605                 return SHOTTYPE_HITWORLD;
606         if(n > maxclients)
607                 return SHOTTYPE_HITWORLD;
608         t = GetPlayerColor(n - 1);
609         if(teamplay)
610                 if(t == myteam)
611                         return SHOTTYPE_HITTEAM;
612         if(t == NUM_SPECTATOR)
613                 return SHOTTYPE_HITWORLD;
614         return SHOTTYPE_HITENEMY;
615 }
616
617 float TrueAimCheck()
618 {
619         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
620         vector vecs, trueaimpoint, w_shotorg;
621         vector mi, ma, dv;
622         float shottype;
623         entity ta;
624         float mv;
625
626         mi = ma = '0 0 0';
627         ta = trueaim;
628         mv = MOVE_NOMONSTERS;
629
630         switch(activeweapon) // WEAPONTODO
631         {
632                 case WEP_TUBA.m_id: // no aim
633                 case WEP_PORTO.m_id: // shoots from eye
634                 case WEP_NEXBALL.m_id: // shoots from eye
635                 case WEP_HOOK.m_id: // no trueaim
636                 case WEP_MORTAR.m_id: // toss curve
637                         return SHOTTYPE_HITWORLD;
638                 case WEP_VORTEX.m_id:
639                 case WEP_VAPORIZER.m_id:
640                         mv = MOVE_NORMAL;
641                         break;
642                 case WEP_RIFLE.m_id:
643                         ta = trueaim_rifle;
644                         mv = MOVE_NORMAL;
645                         if(zoomscript_caught)
646                         {
647                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
648                                 return EnemyHitCheck();
649                         }
650                         break;
651                 case WEP_DEVASTATOR.m_id: // projectile has a size!
652                         mi = '-3 -3 -3';
653                         ma = '3 3 3';
654                         break;
655                 case WEP_FIREBALL.m_id: // projectile has a size!
656                         mi = '-16 -16 -16';
657                         ma = '16 16 16';
658                         break;
659                 case WEP_SEEKER.m_id: // projectile has a size!
660                         mi = '-2 -2 -2';
661                         ma = '2 2 2';
662                         break;
663                 case WEP_ELECTRO.m_id: // projectile has a size!
664                         mi = '0 0 -3';
665                         ma = '0 0 -3';
666                         break;
667         }
668
669         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * getstati(STAT_VIEWHEIGHT));
670
671         vecs = decompressShotOrigin(STAT(SHOTORG));
672
673         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
674         trueaimpoint = trace_endpos;
675
676         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
677                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
678
679         if(vecs.x > 0)
680                 vecs.y = -vecs.y;
681         else
682                 vecs = '0 0 0';
683
684         dv = view_right * vecs.y + view_up * vecs.z;
685         w_shotorg = traceorigin + dv;
686
687         // now move the vecs forward as much as requested if possible
688         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
689         w_shotorg = trace_endpos - view_forward * nudge;
690
691         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
692         shottype = EnemyHitCheck();
693         if(shottype != SHOTTYPE_HITWORLD)
694                 return shottype;
695
696 #if 0
697         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
698         // or rather, I know why, but see no fix
699         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
700                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
701                 return SHOTTYPE_HITOBSTRUCTION;
702 #endif
703
704         return SHOTTYPE_HITWORLD;
705 }
706
707 void PostInit();
708 void CSQC_Demo_Camera();
709 float HUD_WouldDrawScoreboard();
710 float camera_mode;
711 const float CAMERA_FREE = 1;
712 const float CAMERA_CHASE = 2;
713 float reticle_type;
714 string reticle_image;
715 string NextFrameCommand;
716
717 vector freeze_org, freeze_ang;
718 entity nightvision_noise, nightvision_noise2;
719
720 const float MAX_TIME_DIFF = 5;
721 float pickup_crosshair_time, pickup_crosshair_size;
722 float hitindication_crosshair_size;
723 float use_vortex_chargepool;
724
725 float myhealth, myhealth_prev;
726 float myhealth_flash;
727
728 float old_blurradius, old_bluralpha;
729 float old_sharpen_intensity;
730
731 vector myhealth_gentlergb;
732
733 float contentavgalpha, liquidalpha_prev;
734 vector liquidcolor_prev;
735
736 float eventchase_current_distance;
737 float eventchase_running;
738 bool WantEventchase()
739 {SELFPARAM();
740         if(autocvar_cl_orthoview)
741                 return false;
742         if(intermission)
743                 return true;
744         if(self.viewloc)
745                 return true;
746         if(spectatee_status >= 0)
747         {
748                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
749                         return true;
750                 if(MUTATOR_CALLHOOK(WantEventchase, self))
751                         return true;
752                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
753                         return true;
754                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
755                 {
756                         if(autocvar_cl_eventchase_death == 2)
757                         {
758                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
759                                 if(self.velocity == '0 0 0' || eventchase_running)
760                                         return true;
761                         }
762                         else return true;
763                 }
764         }
765         return false;
766 }
767
768 void HUD_Crosshair_Vehicle()
769 {
770         if(hud != HUD_BUMBLEBEE_GUN)
771         {
772                 Vehicle info = get_vehicleinfo(hud);
773                 info.vr_crosshair(info);
774         }
775 }
776
777 vector damage_blurpostprocess, content_blurpostprocess;
778
779 float unaccounted_damage = 0;
780 void UpdateDamage()
781 {
782         // accumulate damage with each stat update
783         static float damage_total_prev = 0;
784         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
785         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
786         damage_total_prev = damage_total;
787
788         static float damage_dealt_time_prev = 0;
789         float damage_dealt_time = STAT(HIT_TIME);
790         if (damage_dealt_time != damage_dealt_time_prev)
791         {
792                 unaccounted_damage += unaccounted_damage_new;
793                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
794         }
795         damage_dealt_time_prev = damage_dealt_time;
796
797         // prevent hitsound when switching spectatee
798         static float spectatee_status_prev = 0;
799         if (spectatee_status != spectatee_status_prev)
800                 unaccounted_damage = 0;
801         spectatee_status_prev = spectatee_status;
802 }
803
804 void HitSound()
805 {
806         // varying sound pitch
807
808         static float hitsound_time_prev = 0;
809         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
810         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
811         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
812         {
813                 if (autocvar_cl_hitsound && unaccounted_damage)
814                 {
815                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
816                         float a = autocvar_cl_hitsound_max_pitch;
817                         float b = autocvar_cl_hitsound_min_pitch;
818                         float c = autocvar_cl_hitsound_nom_damage;
819                         float x = unaccounted_damage;
820                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
821
822                         // if sound variation is disabled, set pitch_shift to 1
823                         if (autocvar_cl_hitsound == 1)
824                                 pitch_shift = 1;
825
826                         // if pitch shift is reversed, mirror in (max-min)/2 + min
827                         if (autocvar_cl_hitsound == 3)
828                         {
829                                 float mirror_value = (a-b)/2 + b;
830                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
831                         }
832
833                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
834
835                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
836                         // todo: normalize sound pressure levels? seems unnecessary
837
838                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
839                 }
840                 unaccounted_damage = 0;
841                 hitsound_time_prev = time;
842         }
843
844         static float typehit_time_prev = 0;
845         float typehit_time = STAT(TYPEHIT_TIME);
846         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
847         {
848                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
849                 typehit_time_prev = typehit_time;
850         }
851 }
852
853 void HUD_Crosshair()
854 {SELFPARAM();
855         static float rainbow_last_flicker;
856         static vector rainbow_prev_color;
857         entity e = self;
858         float f, i, j;
859         vector v;
860         if(!scoreboard_active && !camera_active && intermission != 2 &&
861                 spectatee_status != -1 && !csqcplayer.viewloc &&
862                 !HUD_MinigameMenu_IsOpened() )
863         {
864                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
865                         return;
866
867                 if (hud != HUD_NORMAL)
868                 {
869                         HUD_Crosshair_Vehicle();
870                         return;
871                 }
872
873                 string wcross_style;
874                 float wcross_alpha, wcross_resolution;
875                 wcross_style = autocvar_crosshair;
876                 if (wcross_style == "0")
877                         return;
878                 wcross_resolution = autocvar_crosshair_size;
879                 if (wcross_resolution == 0)
880                         return;
881                 wcross_alpha = autocvar_crosshair_alpha;
882                 if (wcross_alpha == 0)
883                         return;
884
885                 // TrueAim check
886                 float shottype;
887
888                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
889                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
890                 wcross_origin.z = 0;
891                 if(autocvar_crosshair_hittest)
892                 {
893                         vector wcross_oldorigin;
894                         wcross_oldorigin = wcross_origin;
895                         shottype = TrueAimCheck();
896                         if(shottype == SHOTTYPE_HITWORLD)
897                         {
898                                 v = wcross_origin - wcross_oldorigin;
899                                 v.x /= vid_conwidth;
900                                 v.y /= vid_conheight;
901                                 if(vlen(v) > 0.01)
902                                         shottype = SHOTTYPE_HITOBSTRUCTION;
903                         }
904                         if(!autocvar_crosshair_hittest_showimpact)
905                                 wcross_origin = wcross_oldorigin;
906                 }
907                 else
908                         shottype = SHOTTYPE_HITWORLD;
909
910                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
911                 string wcross_name = "";
912                 float wcross_scale, wcross_blur;
913
914                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
915                 {
916                         e = get_weaponinfo(switchingweapon);
917                         if(e)
918                         {
919                                 if(autocvar_crosshair_per_weapon)
920                                 {
921                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
922                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
923                                         //if (wcross_resolution == 0)
924                                                 //return;
925
926                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
927                                         wcross_resolution *= e.w_crosshair_size;
928                                         wcross_name = e.w_crosshair;
929                                 }
930                         }
931                 }
932
933                 if(wcross_name == "")
934                         wcross_name = strcat("gfx/crosshair", wcross_style);
935
936                 // MAIN CROSSHAIR COLOR DECISION
937                 switch(autocvar_crosshair_color_special)
938                 {
939                         case 1: // crosshair_color_per_weapon
940                         {
941                                 if(e)
942                                 {
943                                         wcross_color = e.wpcolor;
944                                         break;
945                                 }
946                                 else { goto normalcolor; }
947                         }
948
949                         case 2: // crosshair_color_by_health
950                         {
951                                 float x = getstati(STAT_HEALTH);
952
953                                 //x = red
954                                 //y = green
955                                 //z = blue
956
957                                 wcross_color.z = 0;
958
959                                 if(x > 200)
960                                 {
961                                         wcross_color.x = 0;
962                                         wcross_color.y = 1;
963                                 }
964                                 else if(x > 150)
965                                 {
966                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
967                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
968                                 }
969                                 else if(x > 100)
970                                 {
971                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
972                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
973                                         wcross_color.z = 1 - (x-100)*0.02;
974                                 }
975                                 else if(x > 50)
976                                 {
977                                         wcross_color.x = 1;
978                                         wcross_color.y = 1;
979                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
980                                 }
981                                 else if(x > 20)
982                                 {
983                                         wcross_color.x = 1;
984                                         wcross_color.y = (x-20)*90/27/100;
985                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
986                                 }
987                                 else
988                                 {
989                                         wcross_color.x = 1;
990                                         wcross_color.y = 0;
991                                 }
992                                 break;
993                         }
994
995                         case 3: // crosshair_color_rainbow
996                         {
997                                 if(time >= rainbow_last_flicker)
998                                 {
999                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1000                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1001                                 }
1002                                 wcross_color = rainbow_prev_color;
1003                                 break;
1004                         }
1005                         :normalcolor
1006                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1007                 }
1008
1009                 if(autocvar_crosshair_effect_scalefade)
1010                 {
1011                         wcross_scale = wcross_resolution;
1012                         wcross_resolution = 1;
1013                 }
1014                 else
1015                 {
1016                         wcross_scale = 1;
1017                 }
1018
1019                 if(autocvar_crosshair_pickup)
1020                 {
1021                         float stat_pickup_time = STAT(LAST_PICKUP);
1022
1023                         if(pickup_crosshair_time < stat_pickup_time)
1024                         {
1025                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1026                                         pickup_crosshair_size = 1;
1027
1028                                 pickup_crosshair_time = stat_pickup_time;
1029                         }
1030
1031                         if(pickup_crosshair_size > 0)
1032                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1033                         else
1034                                 pickup_crosshair_size = 0;
1035
1036                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1037                 }
1038
1039                 // todo: make crosshair hit indication dependent on damage dealt
1040                 if(autocvar_crosshair_hitindication)
1041                 {
1042                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1043
1044                         if(unaccounted_damage)
1045                         {
1046                                 hitindication_crosshair_size = 1;
1047                         }
1048
1049                         if(hitindication_crosshair_size > 0)
1050                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1051                         else
1052                                 hitindication_crosshair_size = 0;
1053
1054                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1055                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1056                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1057                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1058                 }
1059
1060                 if(shottype == SHOTTYPE_HITENEMY)
1061                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1062                 if(shottype == SHOTTYPE_HITTEAM)
1063                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1064
1065                 f = fabs(autocvar_crosshair_effect_time);
1066                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1067                 {
1068                         wcross_changedonetime = time + f;
1069                 }
1070                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1071                 {
1072                         wcross_name_changestarttime = time;
1073                         wcross_name_changedonetime = time + f;
1074                         if(wcross_name_goal_prev_prev)
1075                                 strunzone(wcross_name_goal_prev_prev);
1076                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1077                         wcross_name_goal_prev = strzone(wcross_name);
1078                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1079                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1080                         wcross_resolution_goal_prev = wcross_resolution;
1081                 }
1082
1083                 wcross_scale_goal_prev = wcross_scale;
1084                 wcross_alpha_goal_prev = wcross_alpha;
1085                 wcross_color_goal_prev = wcross_color;
1086
1087                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1088                 {
1089                         wcross_blur = 1;
1090                         wcross_alpha *= 0.75;
1091                 }
1092                 else
1093                         wcross_blur = 0;
1094                 // *_prev is at time-frametime
1095                 // * is at wcross_changedonetime+f
1096                 // what do we have at time?
1097                 if(time < wcross_changedonetime)
1098                 {
1099                         f = frametime / (wcross_changedonetime - time + frametime);
1100                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1101                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1102                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1103                 }
1104
1105                 wcross_scale_prev = wcross_scale;
1106                 wcross_alpha_prev = wcross_alpha;
1107                 wcross_color_prev = wcross_color;
1108
1109                 MUTATOR_CALLHOOK(UpdateCrosshair);
1110
1111                 wcross_scale *= 1 - autocvar__menu_alpha;
1112                 wcross_alpha *= 1 - autocvar__menu_alpha;
1113                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1114
1115                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1116                 {
1117                         // crosshair rings for weapon stats
1118                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1119                         {
1120                                 // declarations and stats
1121                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1122                                 string ring_image = string_null, ring_inner_image = string_null;
1123                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1124
1125                                 ring_scale = autocvar_crosshair_ring_size;
1126
1127                                 float weapon_clipload, weapon_clipsize;
1128                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1129                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1130
1131                                 float ok_ammo_charge, ok_ammo_chargepool;
1132                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1133                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1134
1135                                 float vortex_charge, vortex_chargepool;
1136                                 vortex_charge = STAT(VORTEX_CHARGE);
1137                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1138
1139                                 float arc_heat = STAT(ARC_HEAT);
1140
1141                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1142                                         vortex_charge_movingavg = vortex_charge;
1143
1144
1145                                 // handle the values
1146                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1147                                 {
1148                                         if (vortex_chargepool || use_vortex_chargepool) {
1149                                                 use_vortex_chargepool = 1;
1150                                                 ring_inner_value = vortex_chargepool;
1151                                         } else {
1152                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1153                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1154                                         }
1155
1156                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1157                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1158                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1159
1160                                         // draw the outer ring to show the current charge of the weapon
1161                                         ring_value = vortex_charge;
1162                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1165                                 }
1166                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1167                                 {
1168                                         ring_value = bound(0, STAT(LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1169                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1170                                         ring_rgb = wcross_color;
1171                                         ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173                                 else if (activeweapon == WEP_HAGAR.m_id && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1174                                 {
1175                                         ring_value = bound(0, STAT(HAGAR_LOAD) / hagar_maxrockets, 1);
1176                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1177                                         ring_rgb = wcross_color;
1178                                         ring_image = "gfx/crosshair_ring.tga";
1179                                 }
1180                                 else if (ok_ammo_charge)
1181                                 {
1182                                         ring_value = ok_ammo_chargepool;
1183                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1184                                         ring_rgb = wcross_color;
1185                                         ring_image = "gfx/crosshair_ring.tga";
1186                                 }
1187                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1188                                 {
1189                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1190                                         ring_scale = autocvar_crosshair_ring_reload_size;
1191                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1192                                         ring_rgb = wcross_color;
1193
1194                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1195                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1196                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
1197                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1198                                         else
1199                                                 ring_image = "gfx/crosshair_ring.tga";
1200                                 }
1201                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
1202                                 {
1203                                         ring_value = arc_heat;
1204                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1205                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1206                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1207                                         ring_image = "gfx/crosshair_ring.tga";
1208                                 }
1209
1210                                 // if in weapon switch animation, fade ring out/in
1211                                 if(autocvar_crosshair_effect_time > 0)
1212                                 {
1213                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1214                                         if (f >= 1)
1215                                         {
1216                                                 wcross_ring_prev = ((ring_image) ? true : false);
1217                                         }
1218
1219                                         if(wcross_ring_prev)
1220                                         {
1221                                                 if(f < 1)
1222                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1223                                         }
1224                                         else
1225                                         {
1226                                                 if(f < 1)
1227                                                         ring_alpha *= bound(0, f, 1);
1228                                         }
1229                                 }
1230
1231                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1232                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1233
1234                                 if (ring_value)
1235                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1236                         }
1237
1238 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1239                         do \
1240                         { \
1241                                 if(wcross_blur > 0) \
1242                                 { \
1243                                         for(i = -2; i <= 2; ++i) \
1244                                         for(j = -2; j <= 2; ++j) \
1245                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1246                                 } \
1247                                 else \
1248                                 { \
1249                                         M(0,0,sz,wcross_name,wcross_alpha); \
1250                                 } \
1251                         } \
1252                         while(0)
1253
1254 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1255                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1256
1257 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1258                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1259
1260                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1261                         {
1262                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1263                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1264                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1265                                 f = 1 - f;
1266                         }
1267                         else
1268                         {
1269                                 f = 1;
1270                         }
1271                         wcross_name_alpha_goal_prev = f;
1272
1273                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1274                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1275
1276                         if(autocvar_crosshair_dot)
1277                         {
1278                                 vector wcross_color_old;
1279                                 wcross_color_old = wcross_color;
1280
1281                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1282                                         wcross_color = stov(autocvar_crosshair_dot_color);
1283
1284                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1285                                 // FIXME why don't we use wcross_alpha here?
1286                                 wcross_color = wcross_color_old;
1287                         }
1288                 }
1289         }
1290         else
1291         {
1292                 wcross_scale_prev = 0;
1293                 wcross_alpha_prev = 0;
1294                 wcross_scale_goal_prev = 0;
1295                 wcross_alpha_goal_prev = 0;
1296                 wcross_changedonetime = 0;
1297                 if(wcross_name_goal_prev)
1298                         strunzone(wcross_name_goal_prev);
1299                 wcross_name_goal_prev = string_null;
1300                 if(wcross_name_goal_prev_prev)
1301                         strunzone(wcross_name_goal_prev_prev);
1302                 wcross_name_goal_prev_prev = string_null;
1303                 wcross_name_changestarttime = 0;
1304                 wcross_name_changedonetime = 0;
1305                 wcross_name_alpha_goal_prev = 0;
1306                 wcross_name_alpha_goal_prev_prev = 0;
1307                 wcross_resolution_goal_prev = 0;
1308                 wcross_resolution_goal_prev_prev = 0;
1309         }
1310 }
1311
1312 void HUD_Draw()
1313 {
1314         vector rgb = '0 0 0';
1315         float a = 1;
1316         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1317         {
1318                 rgb = MUTATOR_ARGV(0, vector);
1319                 a = MUTATOR_ARGV(0, float);
1320         }
1321         else if(STAT(FROZEN))
1322         {
1323                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1324         }
1325         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1326         if(!intermission)
1327         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1328         {
1329                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1330                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1331         }
1332         else if(STAT(REVIVE_PROGRESS))
1333         {
1334                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1335                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1336         }
1337
1338         if(autocvar_r_letterbox == 0)
1339                 if(autocvar_viewsize < 120)
1340                 {
1341                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1342                                 Accuracy_LoadLevels();
1343
1344                         HUD_Main();
1345                         HUD_DrawScoreboard();
1346                 }
1347
1348         // crosshair goes VERY LAST
1349         UpdateDamage();
1350         HUD_Crosshair();
1351         HitSound();
1352 }
1353
1354 bool ov_enabled;
1355 float oldr_nearclip;
1356 float oldr_farclip_base;
1357 float oldr_farclip_world;
1358 float oldr_novis;
1359 float oldr_useportalculling;
1360 float oldr_useinfinitefarclip;
1361
1362 void cl_notice_run();
1363 float prev_myteam;
1364 int lasthud;
1365 float vh_notice_time;
1366 void WaypointSprite_Load();
1367 void CSQC_UpdateView(float w, float h)
1368 {SELFPARAM();
1369         entity e;
1370         float fov;
1371         float f;
1372         vector vf_size, vf_min;
1373         float a;
1374
1375         execute_next_frame();
1376
1377         ++framecount;
1378
1379         stats_get();
1380         hud = STAT(HUD);
1381
1382         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1383                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1384
1385         lasthud = hud;
1386
1387         if(autocvar__hud_showbinds_reload) // menu can set this one
1388         {
1389                 db_close(binddb);
1390                 binddb = db_create();
1391                 cvar_set("_hud_showbinds_reload", "0");
1392         }
1393
1394         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1395                 view_quality = getproperty(VF_MINFPS_QUALITY);
1396         else
1397                 view_quality = 1;
1398
1399         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1400         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1401
1402         vf_size = getpropertyvec(VF_SIZE);
1403         vf_min = getpropertyvec(VF_MIN);
1404         vid_width = vf_size.x;
1405         vid_height = vf_size.y;
1406
1407         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1408         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1409
1410         WaypointSprite_Load();
1411
1412         CSQCPlayer_SetCamera();
1413
1414         if(player_localentnum <= maxclients) // is it a client?
1415                 current_player = player_localentnum - 1;
1416         else // then player_localentnum is the vehicle I'm driving
1417                 current_player = player_localnum;
1418         myteam = GetPlayerColor(current_player);
1419
1420         if(myteam != prev_myteam)
1421         {
1422                 myteamcolors = colormapPaletteColor(myteam, 1);
1423                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1424                 prev_myteam = myteam;
1425         }
1426
1427         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1428
1429         float is_dead = (getstati(STAT_HEALTH) <= 0);
1430
1431         // FIXME do we need this hack?
1432         if(isdemo())
1433         {
1434                 // in demos, input_buttons do not work
1435                 button_zoom = (autocvar__togglezoom == "-");
1436         }
1437         else if(button_zoom
1438                 && autocvar_cl_unpress_zoom_on_death
1439                 && (spectatee_status >= 0)
1440                 && (is_dead || intermission))
1441         {
1442                 // no zoom while dead or in intermission please
1443                 localcmd("-zoom\n");
1444                 button_zoom = false;
1445         }
1446
1447         // event chase camera
1448         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1449         {
1450                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1451                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1452                 entity gen = world;
1453
1454                 if(ons_roundlost)
1455                 {
1456                         entity e;
1457                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1458                         {
1459                                 if(e.health <= 0)
1460                                 {
1461                                         gen = e;
1462                                         break;
1463                                 }
1464                         }
1465                         if(!gen)
1466                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1467                 }
1468                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1469                 {
1470                         eventchase_running = true;
1471
1472                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1473                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1474                         if(ons_roundlost) { current_view_origin = gen.origin; }
1475
1476                         // detect maximum viewoffset and use it
1477                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1478                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1479                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1480
1481                         if(view_offset)
1482                         {
1483                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1484                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1485                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1486                         }
1487
1488                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1489                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1490                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1491                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1492
1493                         // make the camera smooth back
1494                         float chase_distance = autocvar_cl_eventchase_distance;
1495                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1496                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1497
1498                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1499                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1500                         else if(eventchase_current_distance != chase_distance)
1501                                 eventchase_current_distance = chase_distance;
1502
1503                         makevectors(view_angles);
1504
1505                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1506                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1507
1508                         // If the boxtrace fails, revert back to line tracing.
1509                         if(!self.viewloc)
1510                         if(trace_startsolid)
1511                         {
1512                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1513                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1514                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1515                         }
1516                         else { setproperty(VF_ORIGIN, trace_endpos); }
1517
1518                         if(!self.viewloc)
1519                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1520                 }
1521                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1522                 {
1523                         eventchase_running = false;
1524                         cvar_set("chase_active", "0");
1525                         eventchase_current_distance = 0; // start from 0 next time
1526                 }
1527         }
1528         // workaround for camera stuck between player's legs when using chase_active 1
1529         // because the engine stops updating the chase_active camera when the game ends
1530         else if(intermission)
1531         {
1532                 cvar_settemp("chase_active", "-1");
1533                 eventchase_current_distance = 0;
1534         }
1535
1536         // do lockview after event chase camera so that it still applies whenever necessary.
1537         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1538         {
1539                 setproperty(VF_ORIGIN, freeze_org);
1540                 setproperty(VF_ANGLES, freeze_ang);
1541         }
1542         else
1543         {
1544                 freeze_org = getpropertyvec(VF_ORIGIN);
1545                 freeze_ang = getpropertyvec(VF_ANGLES);
1546         }
1547
1548         WarpZone_FixView();
1549         //WarpZone_FixPMove();
1550
1551         vector ov_org = '0 0 0';
1552         vector ov_mid = '0 0 0';
1553         vector ov_worldmin = '0 0 0';
1554         vector ov_worldmax = '0 0 0';
1555         if(autocvar_cl_orthoview)
1556         {
1557                 ov_worldmin = mi_picmin;
1558                 ov_worldmax = mi_picmax;
1559
1560                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1561                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1562                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1563
1564                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1565                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1566
1567                 float ov_nearest = vlen(ov_org - vec3(
1568                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1569                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1570                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1571                 ));
1572
1573                 float ov_furthest = 0;
1574                 float dist = 0;
1575
1576                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1577                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1578                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1579                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1580                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1581                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1582                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1583                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1584
1585                 if(!ov_enabled)
1586                 {
1587                         oldr_nearclip = cvar("r_nearclip");
1588                         oldr_farclip_base = cvar("r_farclip_base");
1589                         oldr_farclip_world = cvar("r_farclip_world");
1590                         oldr_novis = cvar("r_novis");
1591                         oldr_useportalculling = cvar("r_useportalculling");
1592                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1593                 }
1594
1595                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1596                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1597                 cvar_settemp("r_farclip_world", "0");
1598                 cvar_settemp("r_novis", "1");
1599                 cvar_settemp("r_useportalculling", "0");
1600                 cvar_settemp("r_useinfinitefarclip", "0");
1601
1602                 setproperty(VF_ORIGIN, ov_org);
1603                 setproperty(VF_ANGLES, '90 0 0');
1604
1605                 ov_enabled = true;
1606
1607                 #if 0
1608                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1609                         vtos(ov_org),
1610                         vtos(getpropertyvec(VF_ANGLES)),
1611                         ov_distance,
1612                         ov_nearest,
1613                         ov_furthest);
1614                 #endif
1615         }
1616         else
1617         {
1618                 if(ov_enabled)
1619                 {
1620                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1621                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1622                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1623                         cvar_set("r_novis", ftos(oldr_novis));
1624                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1625                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1626                 }
1627                 ov_enabled = false;
1628         }
1629
1630         // Render the Scene
1631         view_origin = getpropertyvec(VF_ORIGIN);
1632         view_angles = getpropertyvec(VF_ANGLES);
1633         makevectors(view_angles);
1634         view_forward = v_forward;
1635         view_right = v_right;
1636         view_up = v_up;
1637
1638 #ifdef BLURTEST
1639         if(time > blurtest_time0 && time < blurtest_time1)
1640         {
1641                 float r, t;
1642
1643                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1644                 r = t * blurtest_radius;
1645                 f = 1 / pow(t, blurtest_power) - 1;
1646
1647                 cvar_set("r_glsl_postprocess", "1");
1648                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1649         }
1650         else
1651         {
1652                 cvar_set("r_glsl_postprocess", "0");
1653                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1654         }
1655 #endif
1656
1657         TargetMusic_Advance();
1658         Fog_Force();
1659
1660         if(drawtime == 0)
1661                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1662         else
1663                 drawframetime = bound(0.000001, time - drawtime, 1);
1664         drawtime = time;
1665
1666         // watch for gametype changes here...
1667         // in ParseStuffCMD the cmd isn't executed yet :/
1668         // might even be better to add the gametype to TE_CSQC_INIT...?
1669         if(!postinit)
1670                 PostInit();
1671
1672         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1673         {
1674                 if(calledhooks & HOOK_START)
1675                 {
1676                         localcmd("\ncl_hook_gameend\n");
1677                         calledhooks |= HOOK_END;
1678                 }
1679         }
1680
1681         Announcer();
1682
1683         fov = autocvar_fov;
1684         if(fov <= 59.5)
1685         {
1686                 if(!zoomscript_caught)
1687                 {
1688                         localcmd("+button9\n");
1689                         zoomscript_caught = 1;
1690                 }
1691         }
1692         else
1693         {
1694                 if(zoomscript_caught)
1695                 {
1696                         localcmd("-button9\n");
1697                         zoomscript_caught = 0;
1698                 }
1699         }
1700
1701         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1702
1703         // currently switching-to weapon (for crosshair)
1704         switchingweapon = STAT(SWITCHINGWEAPON);
1705
1706         // actually active weapon (for zoom)
1707         activeweapon = getstati(STAT_ACTIVEWEAPON);
1708
1709         f = (serverflags & SERVERFLAG_TEAMPLAY);
1710         if(f != teamplay)
1711         {
1712                 teamplay = f;
1713                 HUD_InitScores();
1714         }
1715
1716         if(last_switchweapon != switchweapon)
1717         {
1718                 weapontime = time;
1719                 last_switchweapon = switchweapon;
1720                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1721                 {
1722                         localcmd("-zoom\n");
1723                         button_zoom = false;
1724                 }
1725                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1726                 {
1727                         localcmd("-fire\n");
1728                         localcmd("-fire2\n");
1729                         button_attack2 = false;
1730                 }
1731         }
1732         if(last_activeweapon != activeweapon)
1733         {
1734                 last_activeweapon = activeweapon;
1735
1736                 e = get_weaponinfo(activeweapon);
1737                 if(e.netname != "")
1738                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1739                 else
1740                         localcmd("\ncl_hook_activeweapon none\n");
1741         }
1742
1743         // ALWAYS Clear Current Scene First
1744         clearscene();
1745
1746         setproperty(VF_ORIGIN, view_origin);
1747         setproperty(VF_ANGLES, view_angles);
1748
1749         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1750         setproperty(VF_SIZE, vf_size);
1751         setproperty(VF_MIN, vf_min);
1752
1753         // Assign Standard Viewflags
1754         // Draw the World (and sky)
1755         setproperty(VF_DRAWWORLD, 1);
1756
1757         // Set the console size vars
1758         vid_conwidth = autocvar_vid_conwidth;
1759         vid_conheight = autocvar_vid_conheight;
1760         vid_pixelheight = autocvar_vid_pixelheight;
1761
1762         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1763         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1764         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1765
1766         // Camera for demo playback
1767         if(camera_active)
1768         {
1769                 if(autocvar_camera_enable)
1770                         CSQC_Demo_Camera();
1771                 else
1772                 {
1773                         cvar_set("chase_active", ftos(chase_active_backup));
1774                         cvar_set("cl_demo_mousegrab", "0");
1775                         camera_active = false;
1776                 }
1777         }
1778         else
1779         {
1780 #ifdef CAMERATEST
1781                 if(autocvar_camera_enable)
1782 #else
1783                 if(autocvar_camera_enable && isdemo())
1784 #endif
1785                 {
1786                         // Enable required Darkplaces cvars
1787                         chase_active_backup = autocvar_chase_active;
1788                         cvar_set("chase_active", "2");
1789                         cvar_set("cl_demo_mousegrab", "1");
1790                         camera_active = true;
1791                         camera_mode = false;
1792                 }
1793         }
1794
1795         // Draw the Crosshair
1796         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1797
1798         // Draw the Engine Status Bar (the default Quake HUD)
1799         setproperty(VF_DRAWENGINESBAR, 0);
1800
1801         // Update the mouse position
1802         /*
1803            mousepos_x = vid_conwidth;
1804            mousepos_y = vid_conheight;
1805            mousepos = mousepos*0.5 + getmousepos();
1806          */
1807
1808         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1809
1810         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1811         renderscene();
1812
1813         // now switch to 2D drawing mode by calling a 2D drawing function
1814         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1815         // next R_RenderScene call
1816         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1817
1818         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1819         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1820         {
1821                 // apply night vision effect
1822                 vector tc_00, tc_01, tc_10, tc_11;
1823                 vector rgb = '0 0 0';
1824
1825                 if(!nightvision_noise)
1826                 {
1827                         nightvision_noise = new(nightvision_noise);
1828                 }
1829                 if(!nightvision_noise2)
1830                 {
1831                         nightvision_noise2 = new(nightvision_noise2);
1832                 }
1833
1834                 // color tint in yellow
1835                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1836
1837                 // draw BG
1838                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1839                 rgb = '1 1 1';
1840                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1841                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1842                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1843                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1844                 tc_11 = tc_01 + tc_10 - tc_00;
1845                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1846                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1847                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1848                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1849                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1850                 R_EndPolygon();
1851
1852                 // draw FG
1853                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1854                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1855                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1856                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1857                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1858                 tc_11 = tc_01 + tc_10 - tc_00;
1859                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1860                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1861                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1862                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1863                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1864                 R_EndPolygon();
1865         }
1866
1867         if(autocvar_cl_reticle)
1868         {
1869                 Weapon wep = get_weaponinfo(activeweapon);
1870                 // Draw the aiming reticle for weapons that use it
1871                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1872                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1873                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1874                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1875                 {
1876                         // no zoom reticle while dead
1877                         reticle_type = 0;
1878                 }
1879                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1880                 {
1881                         if(reticle_image != "") { reticle_type = 2; }
1882                         else { reticle_type = 0; }
1883                 }
1884                 else if(button_zoom || zoomscript_caught)
1885                 {
1886                         // normal zoom
1887                         reticle_type = 1;
1888                 }
1889
1890                 if(reticle_type)
1891                 {
1892                         if(autocvar_cl_reticle_stretch)
1893                         {
1894                                 reticle_size.x = vid_conwidth;
1895                                 reticle_size.y = vid_conheight;
1896                                 reticle_pos.x = 0;
1897                                 reticle_pos.y = 0;
1898                         }
1899                         else
1900                         {
1901                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1902                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1903                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1904                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1905                         }
1906
1907                         if(zoomscript_caught)
1908                                 f = 1;
1909                         else
1910                                 f = current_zoomfraction;
1911
1912                         if(f)
1913                         {
1914                                 switch(reticle_type)
1915                                 {
1916                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1917                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1918                                 }
1919                         }
1920                 }
1921         }
1922         else
1923         {
1924                 if(reticle_type != 0) { reticle_type = 0; }
1925         }
1926
1927
1928         // improved polyblend
1929         if(autocvar_hud_contents)
1930         {
1931                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1932                 vector liquidcolor;
1933
1934                 switch(pointcontents(view_origin))
1935                 {
1936                         case CONTENT_WATER:
1937                                 liquidalpha = autocvar_hud_contents_water_alpha;
1938                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1939                                 incontent = 1;
1940                                 break;
1941
1942                         case CONTENT_LAVA:
1943                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1944                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1945                                 incontent = 1;
1946                                 break;
1947
1948                         case CONTENT_SLIME:
1949                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1950                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1951                                 incontent = 1;
1952                                 break;
1953
1954                         default:
1955                                 liquidalpha = 0;
1956                                 liquidcolor = '0 0 0';
1957                                 incontent = 0;
1958                                 break;
1959                 }
1960
1961                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1962                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1963                         contentfadetime = autocvar_hud_contents_fadeintime;
1964                         liquidalpha_prev = liquidalpha;
1965                         liquidcolor_prev = liquidcolor;
1966                 }
1967                 else
1968                         contentfadetime = autocvar_hud_contents_fadeouttime;
1969
1970                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1971                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1972
1973                 if(contentavgalpha)
1974                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1975
1976                 if(autocvar_hud_postprocessing)
1977                 {
1978                         if(autocvar_hud_contents_blur && contentavgalpha)
1979                         {
1980                                 content_blurpostprocess.x = 1;
1981                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1982                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1983                         }
1984                         else
1985                         {
1986                                 content_blurpostprocess.x = 0;
1987                                 content_blurpostprocess.y = 0;
1988                                 content_blurpostprocess.z = 0;
1989                         }
1990                 }
1991         }
1992
1993         if(autocvar_hud_damage && !STAT(FROZEN))
1994         {
1995                 splash_size.x = max(vid_conwidth, vid_conheight);
1996                 splash_size.y = max(vid_conwidth, vid_conheight);
1997                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1998                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1999
2000                 float myhealth_flash_temp;
2001                 myhealth = getstati(STAT_HEALTH);
2002
2003                 // fade out
2004                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2005                 // add new damage
2006                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2007
2008                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2009                 pain_threshold = autocvar_hud_damage_pain_threshold;
2010                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2011                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2012
2013                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2014                 {
2015                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2016                 }
2017
2018                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2019
2020                 if(myhealth_prev < 1)
2021                 {
2022                         if(myhealth >= 1)
2023                         {
2024                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2025                                 myhealth_flash_temp = 0;
2026                         }
2027                         else
2028                         {
2029                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2030                         }
2031                 }
2032
2033                 if(spectatee_status == -1 || intermission)
2034                 {
2035                         myhealth_flash = 0; // observing, or match ended
2036                         myhealth_flash_temp = 0;
2037                 }
2038
2039                 myhealth_prev = myhealth;
2040
2041                 // IDEA: change damage color/picture based on player model for robot/alien species?
2042                 // pro: matches model better
2043                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2044                 // maybe different reddish pics?
2045                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2046                 {
2047                         if(autocvar_cl_gentle_damage == 2)
2048                         {
2049                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2050                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2051                         }
2052                         else
2053                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2054
2055                         if(myhealth_flash_temp > 0)
2056                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2057                 }
2058                 else if(myhealth_flash_temp > 0)
2059                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2060
2061                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2062                 {
2063                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2064                         {
2065                                 damage_blurpostprocess.x = 1;
2066                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2067                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2068                         }
2069                         else
2070                         {
2071                                 damage_blurpostprocess.x = 0;
2072                                 damage_blurpostprocess.y = 0;
2073                                 damage_blurpostprocess.z = 0;
2074                         }
2075                 }
2076         }
2077
2078         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2079         float e2 = (autocvar_hud_powerup != 0);
2080         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2081         {
2082                 // enable or disable rendering types if they are used or not
2083                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2084                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2085
2086                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2087                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2088                 {
2089                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2090                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2091                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2092                         {
2093                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2094                                 old_blurradius = blurradius;
2095                                 old_bluralpha = bluralpha;
2096                         }
2097                 }
2098                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2099                 {
2100                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2101                         old_blurradius = 0;
2102                         old_bluralpha = 0;
2103                 }
2104
2105                 // edge detection postprocess handling done second (used by hud_powerup)
2106                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2107                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2108                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2109
2110                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2111
2112                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2113                 {
2114                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2115                         {
2116                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2117                                 old_sharpen_intensity = sharpen_intensity;
2118                         }
2119                 }
2120                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2121                 {
2122                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2123                         old_sharpen_intensity = 0;
2124                 }
2125
2126                 if(cvar("r_glsl_postprocess") == 0)
2127                         cvar_set("r_glsl_postprocess", "2");
2128         }
2129         else if(cvar("r_glsl_postprocess") == 2)
2130                 cvar_set("r_glsl_postprocess", "0");
2131
2132         /*if(gametype == MAPINFO_TYPE_CTF)
2133           {
2134           ctf_view();
2135           } else */
2136
2137         // draw 2D entities
2138         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2139         Draw_ShowNames_All();
2140         Debug_Draw();
2141
2142         scoreboard_active = HUD_WouldDrawScoreboard();
2143
2144         HUD_Draw();
2145
2146         if(NextFrameCommand)
2147         {
2148                 localcmd("\n", NextFrameCommand, "\n");
2149                 NextFrameCommand = string_null;
2150         }
2151
2152         // we must do this check AFTER a frame was rendered, or it won't work
2153         if(cs_project_is_b0rked == 0)
2154         {
2155                 string w0, h0;
2156                 w0 = ftos(autocvar_vid_conwidth);
2157                 h0 = ftos(autocvar_vid_conheight);
2158                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2159                 //setproperty(VF_FOV, '90 90 0');
2160                 setproperty(VF_ORIGIN, '0 0 0');
2161                 setproperty(VF_ANGLES, '0 0 0');
2162                 setproperty(VF_PERSPECTIVE, 1);
2163                 makevectors('0 0 0');
2164                 vector v1, v2;
2165                 cvar_set("vid_conwidth", "800");
2166                 cvar_set("vid_conheight", "600");
2167                 v1 = cs_project(v_forward);
2168                 cvar_set("vid_conwidth", "640");
2169                 cvar_set("vid_conheight", "480");
2170                 v2 = cs_project(v_forward);
2171                 if(v1 == v2)
2172                         cs_project_is_b0rked = 1;
2173                 else
2174                         cs_project_is_b0rked = -1;
2175                 cvar_set("vid_conwidth", w0);
2176                 cvar_set("vid_conheight", h0);
2177         }
2178
2179         if(autocvar__hud_configure)
2180                 HUD_Panel_Mouse();
2181         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2182                 HUD_Minigame_Mouse();
2183         else if(QuickMenu_IsOpened())
2184                 QuickMenu_Mouse();
2185         else
2186                 HUD_Radar_Mouse();
2187
2188         cl_notice_run();
2189
2190         // let's reset the view back to normal for the end
2191         setproperty(VF_MIN, '0 0 0');
2192         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2193 }
2194
2195
2196 // following vectors must be global to allow seamless switching between camera modes
2197 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2198 void CSQC_Demo_Camera()
2199 {
2200         float speed, attenuation, dimensions;
2201         vector tmp, delta;
2202
2203         if( autocvar_camera_reset || !camera_mode )
2204         {
2205                 camera_offset = '0 0 0';
2206                 current_angles = '0 0 0';
2207                 camera_direction = '0 0 0';
2208                 camera_offset.z += 30;
2209                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2210                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2211                 current_origin = view_origin;
2212                 current_camera_offset  = camera_offset;
2213                 cvar_set("camera_reset", "0");
2214                 camera_mode = CAMERA_CHASE;
2215         }
2216
2217         // Camera angles
2218         if( camera_roll )
2219                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2220
2221         if(autocvar_camera_look_player)
2222         {
2223                 vector dir;
2224                 float n;
2225
2226                 dir = normalize(view_origin - current_position);
2227                 n = mouse_angles.z;
2228                 mouse_angles = vectoangles(dir);
2229                 mouse_angles.x = mouse_angles.x * -1;
2230                 mouse_angles.z = n;
2231         }
2232         else
2233         {
2234                 tmp = getmousepos() * 0.1;
2235                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2236                 {
2237                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2238                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2239                 }
2240         }
2241
2242         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2243         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2244         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2245         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2246
2247         // Fix difference when angles don't have the same sign
2248         delta = '0 0 0';
2249         if(mouse_angles.y < -60 && current_angles.y > 60)
2250                 delta = '0 360 0';
2251         if(mouse_angles.y > 60 && current_angles.y < -60)
2252                 delta = '0 -360 0';
2253
2254         if(autocvar_camera_look_player)
2255                 attenuation = autocvar_camera_look_attenuation;
2256         else
2257                 attenuation = autocvar_camera_speed_attenuation;
2258
2259         attenuation = 1 / max(1, attenuation);
2260         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2261
2262         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2263         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2264         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2265         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2266
2267         // Camera position
2268         tmp = '0 0 0';
2269         dimensions = 0;
2270
2271         if( camera_direction.x )
2272         {
2273                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2274                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2275                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2276                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2277                 ++dimensions;
2278         }
2279
2280         if( camera_direction.y )
2281         {
2282                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2283                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2284                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2285                 ++dimensions;
2286         }
2287
2288         if( camera_direction.z )
2289         {
2290                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2291                 ++dimensions;
2292         }
2293
2294         if(autocvar_camera_free)
2295                 speed = autocvar_camera_speed_free;
2296         else
2297                 speed = autocvar_camera_speed_chase;
2298
2299         if(dimensions)
2300         {
2301                 speed = speed * sqrt(1 / dimensions);
2302                 camera_offset += tmp * speed;
2303         }
2304
2305         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2306
2307         // Camera modes
2308         if( autocvar_camera_free )
2309         {
2310                 if ( camera_mode == CAMERA_CHASE )
2311                 {
2312                         current_camera_offset = current_origin + current_camera_offset;
2313                         camera_offset = current_origin + camera_offset;
2314                 }
2315
2316                 camera_mode = CAMERA_FREE;
2317                 current_position = current_camera_offset;
2318         }
2319         else
2320         {
2321                 if ( camera_mode == CAMERA_FREE )
2322                 {
2323                         current_origin = view_origin;
2324                         camera_offset = camera_offset - current_origin;
2325                         current_camera_offset = current_camera_offset - current_origin;
2326                 }
2327
2328                 camera_mode = CAMERA_CHASE;
2329
2330                 if(autocvar_camera_chase_smoothly)
2331                         current_origin += (view_origin - current_origin) * attenuation;
2332                 else
2333                         current_origin = view_origin;
2334
2335                 current_position = current_origin + current_camera_offset;
2336         }
2337
2338         setproperty(VF_ANGLES, current_angles);
2339         setproperty(VF_ORIGIN, current_position);
2340 }